configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.53)
   3 AC_REVISION(0.2.3)
   4 AC_INIT(themes/default/README)
   5 AM_INIT_AUTOMAKE(fvwm-themes, 0.7.1)
   6
   7 REQUIRED_FVWM_VERSION=2.5.8
   8 AC_SUBST(REQUIRED_FVWM_VERSION)dnl
   9 REQUIRED_PERL_VERSION=5.004
  10 AC_SUBST(REQUIRED_PERL_VERSION)dnl
  11 AC_CONFIG_HEADERS("")
  12
  13 mg_ARG_WITH(fvwm-bindir,
  14         [  --with-fvwm-bindir=DIR    specify fvwm bin directory, if not in PATH],
  15         FVWM_BINDIR, ""
  16 )
  17
  18 mg_ARG_WITH(ft-datadir,
  19         [  --with-ft-datadir=DIR     specify data dir, if different from fvwm],
  20         FT_DATADIR, ""
  21 )
  22
  23 AC_ARG_ENABLE(gnome-icons,
  24         [  --enable-gnome-icons      convert gnome icons to xpm icons ],
  25         GNOME_ICONS=yes, GNOME_ICONS=no
  26 )
  27 AC_SUBST(GNOME_ICONS)dnl
  28
  29 AC_ARG_ENABLE(kde2-icons,
  30         [  --enable-kde2-icons       convert kde2 icons to xpm icons ],
  31         KDE2_ICONS=yes, KDE2_ICONS=no
  32 )
  33 AC_SUBST(KDE2_ICONS)dnl
  34
  35 AC_ARG_ENABLE(build-menus,
  36         [  --disable-build-menus     disable the rebuilding of the user menus ],
  37         [ if test "$enableval" = yes; then
  38                 BUILD_MENUS=yes
  39         else
  40                 BUILD_MENUS=no
  41         fi ],
  42         [ BUILD_MENUS=yes ]
  43 )
  44 AC_SUBST(BUILD_MENUS)
  45
  46 # disabled menu system stuff even if present in the machine
  47 AC_ARG_ENABLE(menu-system,
  48         [  --disable-menu-system     disable (Debian) menu system support ],
  49         [ if test "$enableval" = yes; then
  50                 MENU_SYSTEM=yes
  51         else
  52                 MENU_SYSTEM=no
  53         fi ],
  54         [ MENU_SYSTEM=yes ]
  55 )
  56
  57 # do not run update-menu at install even if menu-system is enabled
  58 AC_ARG_ENABLE(run-updatemenu,
  59         [  --disable-run-updatemenu  do not run (Debian) update-menu during installation even if detected ],
  60         [ if test "$enableval" = yes; then
  61                 RUN_UPDATEMENU=yes
  62         else
  63                 RUN_UPDATEMENU=no
  64         fi ],
  65         [ RUN_UPDATEMENU=yes ]
  66 )
  67
  68 dnl 'unset' is not portable, but setting to null is not enough to avoid using
  69 dnl the cached value!  For ancient shells "rm config.cache" is a solution.
  70 UNSET=true
  71 if unset UNSET 2>/dev/null; then UNSET=unset; fi
  72
  73 AC_PROG_INSTALL
  74 dnl Reports are that INSTALL is set incorrectly on Solaris.
  75 if test "`echo $INSTALL | cut -c1-2`" = ".."; then
  76         AC_MSG_ERROR([
  77         It seems that ./configure can't automatically set INSTALL.
  78         Please set this environment var yourself and rerun ./configure.
  79         For example: env INSTALL='/usr/ucb/install -c' ./configure])
  80 fi
  81
  82 AC_PATH_PROG(PERL, perl)
  83 if test -z "$PERL"; then
  84         AC_MSG_WARN(Perl is not found; you will have fatal problems using this package!)
  85         PERL=/usr/bin/perl
  86 fi
  87 AC_SUBST(PERL)dnl
  88
  89 AC_PATH_PROG(AWK, gawk)
  90 if test -z "$AWK"; then
  91         AC_PATH_PROG(AWK, nawk)
  92 fi
  93 if test -z "$AWK"; then
  94         AC_PATH_PROG(AWK, mawk)
  95 fi
  96 if test -z "$AWK"; then
  97         AWK=awk
  98 fi
  99 AC_SUBST(AWK)dnl
 100
 101 AC_PATH_PROG(TAR, gtar)
 102 if test -z "$TAR"; then
 103         AC_PATH_PROG(TAR, gnutar)
 104 fi
 105 if test -z "$TAR"; then
 106         TAR=tar
 107 fi
 108 AC_SUBST(TAR)dnl
 109
 110 AC_PATH_PROG(MKFIFO, mkfifo)
 111 if test -z "$MKFIFO"; then
 112         AC_MSG_WARN([
 113         mkfifo is not found; you will have some problems with GUI!])
 114 fi
 115
 116 # we check for FvwmM4 below
 117 AC_PATH_PROG(M4, m4)
 118 if test -z "$M4"; then
 119         AC_MSG_WARN([
 120         m4 is not found; you will have a few problems using this package!])
 121 fi
 122
 123 # Solaris is not shipped with xmessage...
 124 AC_PATH_PROG(XMESSAGE, xmessage)
 125 if test -z "$XMESSAGE"; then
 126         additional_msg=""
 127         if test "`uname`" = "SunOS"; then additional_msg="
 128         You may find the binary at http://sunfreeware.com/ ."
 129         fi
 130         AC_MSG_WARN([
 131         xmessage is not found; you will have some problems; please install it.$additional_msg])
 132 fi
 133
 134 # debian menu system
 135 AC_PATH_PROG(UPDATE_MENU, update-menus)
 136 if test -z "$UPDATE_MENU"; then
 137         MENU_SYSTEM=no
 138 fi
 139 if test "$MENU_SYSTEM" = yes; then
 140         MENU_SYSTEM_PREFIX='${ROOT_PREFIX}'"/etc/menu-methods"
 141         MENU_SYSTEM_BINSCRIPTS='fvwm_themes'
 142         MENU_SYSTEM_CONFIGDATA='fvwm_themes.h fvwm_themes_data.h'
 143         AC_SUBST(MENU_SYSTEM_PREFIX)
 144         AC_SUBST(MENU_SYSTEM_BINSCRIPTS)
 145         AC_SUBST(MENU_SYSTEM_CONFIGDATA)
 146 else
 147         RUN_UPDATEMENU=no
 148         UPDATE_MENU=false
 149 fi
 150 AC_SUBST(RUN_UPDATEMENU)
 151 AC_SUBST(UPDATE_MENU)
 152
 153 # fvwm-themes-images needs to know where the rgb.txt file is
 154 AC_PATH_XTRA
 155 if test -z "$X_LIBS"; then
 156         if test -f /usr/share/X11/rgb.txt; then
 157                 X_LIBS=-L/usr/share
 158         else
 159                 AC_MSG_WARN([
 160         Xlib is not found; fvwm-themes-images will not fully work!])
 161         fi
 162 fi
 163
 164 # FIXME: a better way to find GNOME_IMAGES_DIR?
 165 # I've no gnome-config on my machine.
 166 AC_PATH_PROG(GNOME_SESSION, gnome-session)
 167 if test -z "$GNOME_SESSION"; then
 168         GNOME_SESSION=/usr/bin/gnome-session
 169 fi
 170 GNOME_IMAGES_DIR=`echo $GNOME_SESSION | sed -e "s,/[[^/]]*/gnome-session$,,"`/share/pixmaps
 171 AC_SUBST(GNOME_IMAGES_DIR)dnl
 172
 173 $UNSET ac_cv_path_FVWM_CONFIG
 174 AC_PATH_PROG(FVWM_CONFIG, fvwm-config --version, , [$FVWM_BINDIR:${PATH}])
 175 if test -z "$FVWM_CONFIG"; then
 176         AC_MSG_ERROR([
 177         fvwm-config is not found; try --with-fvwm-bindir
 178         You need at least fvwm-$REQUIRED_FVWM_VERSION])
 179 fi
 180 AC_SUBST(FVWM_CONFIG)dnl
 181
 182 FVWM_BINDIR=`$FVWM_CONFIG --bindir`
 183 AC_SUBST(FVWM_BINDIR)dnl
 184 FVWM_DEFAULT_USERDIR=`$FVWM_CONFIG --default-userdir`
 185 AC_SUBST(FVWM_DEFAULT_USERDIR)dnl
 186 FVWM_DEFAULT_IMAGEPATH=`$FVWM_CONFIG --default-imagepath`
 187 AC_SUBST(FVWM_DEFAULT_IMAGEPATH)dnl
 188 FVWM_MODULEDIR=`$FVWM_CONFIG --fvwm-moduledir`
 189
 190 $UNSET ac_cv_path_FVWM_M4
 191 AC_PATH_PROG(FVWM_M4, FvwmM4, ,"$FVWM_MODULEDIR")
 192 if test -z "$FVWM_M4"; then
 193         AC_MSG_WARN([
 194         FvwmM4 is not found; you will have a few problems using this package!])
 195 fi
 196
 197 FVWM_VERSION=`$FVWM_CONFIG --version`
 198 if test "x$FVWM_VERSION" = "x"; then FVWM_VERSION=unknown; fi
 199 AC_SUBST(FVWM_VERSION)dnl
 200
 201 # Hopefully this "sort" is portable (after many tries using awk and expr)
 202 if (echo $REQUIRED_FVWM_VERSION; echo $FVWM_VERSION) \
 203 | sed 's/\./ /g' | uniq | sort -n -k 1 -k 2 -k 3 -c 2>/dev/null; then
 204         :
 205         # fvwm version is ok
 206 else
 207         AC_MSG_ERROR([
 208         You have fvwm-$FVWM_VERSION, which is not up to date
 209         You need at least fvwm-$REQUIRED_FVWM_VERSION])
 210 fi
 211
 212 ROOT_PREFIX=""
 213 AC_SUBST(ROOT_PREFIX)dnl
 214
 215 if echo "${prefix}NONE" | awk '/^NONE/ { exit 1 }'; then
 216         mg_DEFAULT_DIR_ARG(bindir,     '${prefix}/bin')
 217         mg_DEFAULT_DIR_ARG(mandir,     '${prefix}/man')
 218         mg_DEFAULT_DIR_ARG(datadir,    '${prefix}/share')
 219         mg_DEFAULT_DIR_ARG(FT_DATADIR, '${datadir}/fvwm')
 220 else
 221         mg_DEFAULT_DIR_ARG(bindir,     '${ROOT_PREFIX}'"`$FVWM_CONFIG --bindir`")
 222         mg_DEFAULT_DIR_ARG(mandir,     '${ROOT_PREFIX}'"`$FVWM_CONFIG --mandir`")
 223         mg_DEFAULT_DIR_ARG(datadir,    '${ROOT_PREFIX}'"`$FVWM_CONFIG --datadir`")
 224         mg_DEFAULT_DIR_ARG(FT_DATADIR, '${ROOT_PREFIX}'"`$FVWM_CONFIG --fvwm-datadir`")
 225 fi
 226
 227 #FT_FVWMSCRIPT_DIR='${FT_DATADIR}/scripts'
 228 #FT_FVWMFORM_DIR='${FT_DATADIR}/forms'
 229 FT_FVWMSCRIPT_DIR='${FT_DATADIR}'
 230 FT_FVWMFORM_DIR='${FT_DATADIR}'
 231 FT_LOCALE_DIR='${FT_DATADIR}/locale'
 232
 233 AC_SUBST(FT_DATADIR)dnl
 234 AC_SUBST(FT_FVWMSCRIPT_DIR)dnl
 235 AC_SUBST(FT_FVWMFORM_DIR)dnl
 236 AC_SUBST(FT_LOCALE_DIR)dnl
 237
 238 # migo: to match the one in FVWM...
 239 FT_VERSION_INFO="fvwm-themes $VERSION built on `date +'%b %d %Y at %T'`"
 240 AC_SUBST(FT_VERSION_INFO)dnl
 241 FT_BUILD_ID=`date '+build %d-%b-%Y %T'`
 242 AC_SUBST(FT_BUILD_ID)dnl
 243
 244 SETTINGS_FILE='${FT_DATADIR}/themes/default/settings.cfg'
 245 AC_SUBST(SETTINGS_FILE)dnl
 246
 247 # 3 lists: all themes, base and extra
 248 ALL_THEMES=`ls -d ./themes/* | grep -v /CVS | grep -v /Makefile | cut -d/ -f3`
 249 ALL_THEMES=`echo $ALL_THEMES`
 250 BASE_THEMES="afterstep cde default luthien migo multichoice olicha redmond98 redmondxp"
 251 mg_LIST_MINUS(ALL_THEMES, BASE_THEMES, EXTRA_THEMES)
 252 AC_SUBST(ALL_THEMES)AC_SUBST(BASE_THEMES)AC_SUBST(EXTRA_THEMES)dnl
 253
 254 AC_OUTPUT(
 255         Makefile
 256         bin/Makefile
 257         doc/Makefile
 258         forms/Makefile
 259         scripts/Makefile
 260         locale/Makefile
 261         locale/en/Makefile
 262         locale/fr/Makefile
 263         locale/ru/Makefile
 264         locale/ja/Makefile
 265         locale/de/Makefile
 266         locale/pl/Makefile
 267         bin/fvwm-themes-config
 268         bin/fvwm-themes-start
 269         bin/fvwm-themes-xrdb
 270         bin/fvwm-themes-menuapp
 271         bin/fvwm-themes-com
 272         bin/fvwm-themes-script
 273         bin/fvwm-themes-images
 274         bin/fvwm-themes-root
 275         debian/Makefile
 276         debian/full-control
 277         debian/extra-control
 278         debian/base-control
 279         doc/fvwm-themes.lsm
 280         rpm/fvwm-themes.spec
 281         rpm/fvwm-themes-base.spec
 282         rpm/fvwm-themes-extra.spec
 283         rpm/fvwm-themes-themes.spec
 284         rpm/Makefile
 285         menu-system/Makefile
 286 )
 287
 288 if test -n "$DEBUG"; then
 289         echo '--------------------------------- ( Debug ) ---------------------------------'
 290         echo "[prefix:            ${prefix}]"
 291         echo "[bindir:            ${bindir}]"
 292         echo "[mandir:            ${mandir}]"
 293         echo "[datadir:           ${datadir}]"
 294         echo "[ft-datadir:        ${FT_DATADIR}]"
 295         echo "[ft-fvwmscript-dir: ${FT_FVWMSCRIPT_DIR}]"
 296         echo "[ft-fvwmform-dir:   ${FT_FVWMFORM_DIR}]"
 297         echo "[menu-system:       ${MENU_SYSTEM},${MENU_SYSTEM_PREFIX},${UPDATE_MENU}]"
 298         echo "[gnome-icons:       ${GNOME_ICONS}]"
 299         echo "[gnome-session:     ${GNOME_SESSION}]"
 300         echo "[gnome-images-dir:  ${GNOME_IMAGES_DIR}]"
 301         echo "[kde2-icons:        ${KDE2_ICONS}]"
 302         echo "[settings-file:     ${SETTINGS_FILE}]"
 303         echo "[x-libs:            ${X_LIBS}]"
 304         echo "[x-extra-libs:      ${X_EXTRA_LIBS}]"
 305         echo '-----------------------------------------------------------------------------'
 306         echo "  All   themes: [${ALL_THEMES}]"
 307         echo "  Base  themes: [${BASE_THEMES}]"
 308         echo "  Extra themes: [${EXTRA_THEMES}]"
 309         echo '============================================================================='
 310 fi
 311
 312 echo "
 313 -----------------------------------------------------------------------------
 314 FVWM Themes Version:    $VERSION
 315 FVWM Version:           $FVWM_VERSION
 316 =============================================================================
 317
 318 Run 'make; su; make install' to install $PACKAGE.
 319 "