lisp/generic.el

   1 ;;; generic.el --- defining simple major modes with comment and font-lock
   2 ;;
   3 ;; Copyright (C) 1997, 1999, 2004, 2005 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author:  Peter Breton <pbreton@cs.umb.edu>
   6 ;; Created: Fri Sep 27 1996
   7 ;; Keywords: generic, comment, font-lock
   8
   9 ;; This file is part of GNU Emacs.
  10
  11 ;; GNU Emacs is free software; you can redistribute it and/or modify
  12 ;; it under the terms of the GNU General Public License as published by
  13 ;; the Free Software Foundation; either version 2, or (at your option)
  14 ;; any later version.
  15
  16 ;; GNU Emacs is distributed in the hope that it will be useful,
  17 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 ;; GNU General Public License for more details.
  20
  21 ;; You should have received a copy of the GNU General Public License
  22 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  23 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  24 ;; Boston, MA 02111-1307, USA.
  25
  26 ;; Purpose:
  27
  28 ;; Meta-mode to create simple major modes
  29 ;; with basic comment and font-lock support
  30
  31 ;;; Commentary:
  32
  33 ;; INTRODUCTION:
  34
  35 ;; Generic-mode is a meta-mode which can be used to define small modes
  36 ;; which provide basic comment and font-lock support.  These modes are
  37 ;; intended for the many configuration files and such which are too
  38 ;; small for a "real" mode, but still have a regular syntax, comment
  39 ;; characters and the like.
  40 ;;
  41 ;; Each generic mode can define the following:
  42 ;;
  43 ;; * List of comment-characters.  The entries in this list should be
  44 ;;   either a character, a one or two character string or a cons pair.
  45 ;;   If the entry is a character or a string, it is added to the
  46 ;;   mode's syntax table with `comment-start' syntax.  If the entry is
  47 ;;   a cons pair, the elements of the pair are considered to be
  48 ;;   `comment-start' and `comment-end' respectively.  (The latter
  49 ;;   should be nil if you want comments to end at end of line.)
  50 ;;   LIMITATIONS: Emacs does not support comment strings of more than
  51 ;;   two characters in length.
  52 ;;
  53 ;; * List of keywords to font-lock.  Each keyword should be a string.
  54 ;;   If you have additional keywords which should be highlighted in a
  55 ;;   face different from `font-lock-keyword-face', you can use the
  56 ;;   convenience function `generic-make-keywords-list' (which see),
  57 ;;   and add the result to the following list:
  58 ;;
  59 ;; * Additional expressions to font-lock.  This should be a list of
  60 ;;   expressions, each of which should be of the same form as those in
  61 ;;   `font-lock-keywords'.
  62 ;;
  63 ;; * List of regular expressions to be placed in auto-mode-alist.
  64 ;;
  65 ;; * List of functions to call to do some additional setup
  66 ;;
  67 ;; This should pretty much cover basic functionality; if you need much
  68 ;; more than this, or you find yourself writing extensive customizations,
  69 ;; perhaps you should be writing a major mode instead!
  70 ;;
  71 ;; LOCAL VARIABLES:
  72 ;;
  73 ;; To put a file into generic mode using local variables, use a line
  74 ;; like this in a Local Variables block:
  75 ;;
  76 ;;   mode: default-generic
  77 ;;
  78 ;; Do NOT use "mode: generic"!
  79 ;; See also "AUTOMATICALLY ENTERING GENERIC MODE" below.
  80 ;;
  81 ;; DEFINING NEW GENERIC MODES:
  82 ;;
  83 ;; Use the `define-generic-mode' function to define new modes.
  84 ;; For example:
  85 ;;
  86 ;;   (define-generic-mode 'foo-generic-mode
  87 ;;     (list ?%)
  88 ;;     (list "keyword")
  89 ;;     nil
  90 ;;     (list "\\.FOO\\'")
  91 ;;     (list 'foo-setup-function))
  92 ;;
  93 ;; defines a new generic-mode `foo-generic-mode', which has '%' as a
  94 ;; comment character, and "keyword" as a keyword.  When files which
  95 ;; end in '.FOO' are loaded, Emacs will go into foo-generic-mode and
  96 ;; call foo-setup-function.  You can also use the function
  97 ;; `foo-generic-mode' (which is interactive) to put a buffer into
  98 ;; foo-generic-mode.
  99 ;;
 100 ;; AUTOMATICALLY ENTERING GENERIC MODE:
 101 ;;
 102 ;; Generic-mode provides a hook which automatically puts a file into
 103 ;; default-generic-mode if the first few lines of a file in
 104 ;; fundamental mode start with a hash comment character.  To disable
 105 ;; this functionality, set the variable `generic-use-find-file-hook'
 106 ;; to nil BEFORE loading generic-mode.  See the variables
 107 ;; `generic-lines-to-scan' and `generic-find-file-regexp' for
 108 ;; customization options.
 109 ;;
 110 ;; GOTCHAS:
 111 ;;
 112 ;; Be careful that your font-lock definitions are correct.  Getting
 113 ;; them wrong can cause Emacs to continually attempt to fontify! This
 114 ;; problem is not specific to generic-mode.
 115 ;;
 116
 117 ;; Credit for suggestions, brainstorming, help with debugging:
 118 ;;   ACorreir@pervasive-sw.com (Alfred Correira)
 119 ;; Extensive cleanup by:
 120 ;;   Stefan Monnier (monnier+gnu/emacs@flint.cs.yale.edu)
 121 ;;
 122 ;;; Code:
 123
 124 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 125 ;; Internal Variables
 126 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 127
 128 (defvar generic-font-lock-defaults nil
 129   "Global defaults for font-lock in a generic mode.")
 130 (make-variable-buffer-local 'generic-font-lock-defaults)
 131
 132 ;;;###autoload
 133 (defvar generic-mode-list nil
 134   "A list of mode names for `generic-mode'.
 135 Do not add entries to this list directly; use `define-generic-mode'
 136 instead (which see).")
 137
 138 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 139 ;; Customization Variables
 140 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 141
 142 (defgroup generic nil
 143   "Define simple major modes with comment and font-lock support."
 144   :prefix "generic-"
 145   :group 'extensions)
 146
 147 (defcustom generic-use-find-file-hook t
 148   "*If non-nil, add a hook to enter `default-generic-mode' automatically.
 149 This is done if the first few lines of a file in fundamental mode
 150 start with a hash comment character."
 151   :group 'generic
 152   :type  'boolean)
 153
 154 (defcustom generic-lines-to-scan 3
 155   "*Number of lines that `generic-mode-find-file-hook' looks at.
 156 Relevant when deciding whether to enter Default-Generic mode automatically.
 157 This variable should be set to a small positive number."
 158   :group 'generic
 159   :type  'integer)
 160
 161 (defcustom generic-find-file-regexp "^#"
 162   "*Regular expression used by `generic-mode-find-file-hook'.
 163 Files in fundamental mode whose first few lines contain a match
 164 for this regexp, should be put into Default-Generic mode instead.
 165 The number of lines tested for the matches is specified by the
 166 value of the variable `generic-lines-to-scan', which see."
 167   :group 'generic
 168   :type  'regexp)
 169
 170 (defcustom generic-ignore-files-regexp "[Tt][Aa][Gg][Ss]\\'"
 171   "*Regular expression used by `generic-mode-find-file-hook'.
 172 Files whose names match this regular expression should not be put
 173 into Default-Generic mode, even if they have lines which match
 174 the regexp in `generic-find-file-regexp'.  If the value is nil,
 175 `generic-mode-find-file-hook' does not check the file names."
 176   :group 'generic
 177   :type  '(choice (const :tag "Don't check file names" nil) regexp))
 178
 179 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 180 ;; Functions
 181 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
 182
 183 ;;;###autoload
 184 (defmacro define-generic-mode (mode comment-list keyword-list
 185                                     font-lock-list auto-mode-list
 186                                     function-list &optional docstring)
 187   "Create a new generic mode MODE.
 188
 189 MODE is the name of the command for the generic mode; it need not
 190 be quoted.  The optional DOCSTRING is the documentation for the
 191 mode command.  If you do not supply it, a default documentation
 192 string will be used instead.
 193
 194 COMMENT-LIST is a list, whose entries are either a single
 195 character, a one or two character string or a cons pair.  If the
 196 entry is a character or a string, it is added to the mode's
 197 syntax table with `comment-start' syntax.  If the entry is a cons
 198 pair, the elements of the pair are considered to be
 199 `comment-start' and `comment-end' respectively.  (The latter
 200 should be nil if you want comments to end at end of line.)  Note
 201 that Emacs has limitations regarding comment characters.
 202
 203 KEYWORD-LIST is a list of keywords to highlight with
 204 `font-lock-keyword-face'.  Each keyword should be a string.
 205
 206 FONT-LOCK-LIST is a list of additional expressions to highlight.
 207 Each entry in the list should have the same form as an entry in
 208 `font-lock-keywords'.
 209
 210 AUTO-MODE-LIST is a list of regular expressions to add to
 211 `auto-mode-alist'.  These regexps are added to `auto-mode-alist'
 212 as soon as `define-generic-mode' is called.
 213
 214 FUNCTION-LIST is a list of functions to call to do some
 215 additional setup.
 216
 217 See the file generic-x.el for some examples of `define-generic-mode'."
 218   (let* ((name-unquoted (if (eq (car-safe mode) 'quote) ; Backward compatibility.
 219                             (eval mode)
 220                           mode))
 221          (name-string (symbol-name name-unquoted))
 222          (pretty-name (capitalize (replace-regexp-in-string
 223                                    "-mode\\'" "" name-string))))
 224
 225     `(progn
 226        ;; Add a new entry.
 227        (add-to-list 'generic-mode-list ,name-string)
 228
 229        ;; Add it to auto-mode-alist
 230        (dolist (re ,auto-mode-list)
 231          (add-to-list 'auto-mode-alist (cons re ',name-unquoted)))
 232
 233        (defun ,name-unquoted ()
 234          ,(or docstring
 235               (concat pretty-name " mode.\n"
 236                       "This a generic mode defined with `define-generic-mode'."))
 237          (interactive)
 238          (generic-mode-internal ',name-unquoted ,comment-list ,keyword-list
 239                                 ,font-lock-list ,function-list)))))
 240
 241 ;;;###autoload
 242 (defun generic-mode-internal (mode comments keywords font-lock-list funs)
 243   "Go into the generic mode MODE."
 244   (let* ((modename (symbol-name mode))
 245          (generic-mode-hooks (intern (concat modename "-hook")))
 246          (pretty-name (capitalize (replace-regexp-in-string
 247                                    "-mode\\'" "" modename))))
 248
 249     (kill-all-local-variables)
 250
 251     (setq major-mode mode
 252           mode-name pretty-name)
 253
 254     (generic-mode-set-comments comments)
 255
 256     ;; Font-lock functionality
 257     ;; Font-lock-defaults are always set even if there are no keywords
 258     ;; or font-lock expressions, so comments can be highlighted.
 259     (setq generic-font-lock-defaults nil)
 260     (generic-mode-set-font-lock  keywords font-lock-list)
 261     (make-local-variable 'font-lock-defaults)
 262     (setq font-lock-defaults (list 'generic-font-lock-defaults nil))
 263
 264     ;; Call a list of functions
 265     (mapcar 'funcall funs)
 266
 267     (run-hooks generic-mode-hooks)))
 268
 269 ;;;###autoload
 270 (defun generic-mode (mode)
 271   "Enter generic mode MODE.
 272
 273 Generic modes provide basic comment and font-lock functionality
 274 for \"generic\" files.  (Files which are too small to warrant their
 275 own mode, but have comment characters, keywords, and the like.)
 276
 277 To define a generic-mode, use the function `define-generic-mode'.
 278 Some generic modes are defined in `generic-x.el'."
 279   (interactive
 280    (list (completing-read "Generic mode: " generic-mode-list nil t)))
 281   (funcall (intern mode)))
 282
 283 ;;; Comment Functionality
 284 (defun generic-mode-set-comments (comment-list)
 285   "Set up comment functionality for generic mode."
 286   (let ((st (make-syntax-table))
 287         (chars nil)
 288         (comstyles))
 289     (make-local-variable 'comment-start)
 290     (make-local-variable 'comment-start-skip)
 291     (make-local-variable 'comment-end)
 292
 293     ;; Go through all the comments
 294     (dolist (start comment-list)
 295       (let (end (comstyle ""))
 296         ;; Normalize
 297         (when (consp start)
 298           (setq end (cdr start))
 299           (setq start (car start)))
 300         (when (char-valid-p start) (setq start (char-to-string start)))
 301         (cond
 302          ((char-valid-p end)   (setq end (char-to-string end)))
 303          ((zerop (length end)) (setq end "\n")))
 304
 305         ;; Setup the vars for `comment-region'
 306         (if comment-start
 307             ;; We have already setup a comment-style, so use style b
 308             (progn
 309               (setq comstyle "b")
 310               (setq comment-start-skip
 311                     (concat comment-start-skip "\\|" (regexp-quote start) "+\\s-*")))
 312           ;; First comment-style
 313           (setq comment-start start)
 314           (setq comment-end (if (string-equal end "\n") "" end))
 315           (setq comment-start-skip (concat (regexp-quote start) "+\\s-*")))
 316
 317        ;; Reuse comstyles if necessary
 318        (setq comstyle
 319              (or (cdr (assoc start comstyles))
 320                  (cdr (assoc end comstyles))
 321                  comstyle))
 322        (push (cons start comstyle) comstyles)
 323        (push (cons end comstyle) comstyles)
 324
 325         ;; Setup the syntax table
 326         (if (= (length start) 1)
 327             (modify-syntax-entry (string-to-char start)
 328                                  (concat "< " comstyle) st)
 329           (let ((c0 (elt start 0)) (c1 (elt start 1)))
 330             ;; Store the relevant info but don't update yet
 331             (push (cons c0 (concat (cdr (assoc c0 chars)) "1")) chars)
 332             (push (cons c1 (concat (cdr (assoc c1 chars))
 333                                    (concat "2" comstyle))) chars)))
 334         (if (= (length end) 1)
 335             (modify-syntax-entry (string-to-char end)
 336                                  (concat ">" comstyle) st)
 337           (let ((c0 (elt end 0)) (c1 (elt end 1)))
 338             ;; Store the relevant info but don't update yet
 339             (push (cons c0 (concat (cdr (assoc c0 chars))
 340                                    (concat "3" comstyle))) chars)
 341             (push (cons c1 (concat (cdr (assoc c1 chars)) "4")) chars)))))
 342
 343     ;; Process the chars that were part of a 2-char comment marker
 344     (dolist (cs (nreverse chars))
 345       (modify-syntax-entry (car cs)
 346                            (concat (char-to-string (char-syntax (car cs)))
 347                                    " " (cdr cs))
 348                            st))
 349     (set-syntax-table st)))
 350
 351 (defun generic-mode-set-font-lock (keywords font-lock-expressions)
 352   "Set up font-lock functionality for generic mode."
 353   (setq generic-font-lock-defaults
 354         (append
 355          (when keywords
 356            (list (generic-make-keywords-list keywords font-lock-keyword-face)))
 357          font-lock-expressions)))
 358
 359 ;; Support for [KEYWORD] constructs found in INF, INI and Samba files
 360 (defun generic-bracket-support ()
 361   (setq imenu-generic-expression
 362         '((nil "^\\[\\(.*\\)\\]" 1))
 363         imenu-case-fold-search t))
 364
 365 ;; This generic mode is always defined
 366 (define-generic-mode default-generic-mode (list ?#) nil nil nil nil)
 367
 368 ;; A more general solution would allow us to enter generic-mode for
 369 ;; *any* comment character, but would require us to synthesize a new
 370 ;; generic-mode on the fly. I think this gives us most of what we
 371 ;; want.
 372 (defun generic-mode-find-file-hook ()
 373   "Hook function to enter Default-Generic mode automatically.
 374
 375 Done if the first few lines of a file in Fundamental mode start
 376 with a match for the regexp in `generic-find-file-regexp', unless
 377 the file's name matches the regexp which is the value of the
 378 variable `generic-ignore-files-regexp'.
 379
 380 This hook will be installed if the variable
 381 `generic-use-find-file-hook' is non-nil.  The variable
 382 `generic-lines-to-scan' determines the number of lines to look at."
 383   (when (and (eq major-mode 'fundamental-mode)
 384              (or (null generic-ignore-files-regexp)
 385                  (not (string-match
 386                        generic-ignore-files-regexp
 387                        (file-name-sans-versions buffer-file-name)))))
 388     (save-excursion
 389       (goto-char (point-min))
 390       (when (re-search-forward generic-find-file-regexp
 391                                (save-excursion
 392                                  (forward-line generic-lines-to-scan)
 393                                  (point)) t)
 394         (goto-char (point-min))
 395         (default-generic-mode)))))
 396
 397 (defun generic-mode-ini-file-find-file-hook ()
 398   "Hook function to enter Default-Generic mode automatically for INI files.
 399 Done if the first few lines of a file in Fundamental mode look like an
 400 INI file.  This hook is NOT installed by default."
 401   (and (eq major-mode 'fundamental-mode)
 402        (save-excursion
 403          (goto-char (point-min))
 404          (and (looking-at "^\\s-*\\[.*\\]")
 405               (ini-generic-mode)))))
 406
 407 (and generic-use-find-file-hook
 408     (add-hook 'find-file-hooks 'generic-mode-find-file-hook))
 409
 410 (defun generic-make-keywords-list (keywords-list face &optional prefix suffix)
 411   "Return a regular expression matching the specified KEYWORDS-LIST.
 412 The regexp is highlighted with FACE."
 413   (unless (listp keywords-list)
 414     (error "Keywords argument must be a list of strings"))
 415   (list (concat prefix "\\_<"
 416                 ;; Use an optimized regexp.
 417                 (regexp-opt keywords-list t)
 418                 "\\_>" suffix)
 419         1
 420         face))
 421
 422 (provide 'generic)
 423
 424 ;; arch-tag: 239c1fc4-1303-48d9-9ac0-657d655669ea
 425 ;;; generic.el ends here