lisp/startup.el

   1 ;;; startup.el --- process Emacs shell arguments
   2
   3 ;; Copyright (C) 1985, 1986, 1992 Free Software Foundation, Inc.
   4
   5 ;; Maintainer: FSF
   6 ;; Keywords: internal
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software; you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation; either version 2, or (at your option)
  13 ;; any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs; see the file COPYING.  If not, write to
  22 ;; the Free Software Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.
  23
  24 ;;; Commentary:
  25
  26 ; These are processed only at the beginning of the argument list.
  27 ; -batch                execute noninteractively (messages go to stdout,
  28 ;                        variable noninteractive set to t)
  29 ;                        This option must be the first in the arglist.
  30 ;                        Processed by `main' in emacs.c -- never seen by lisp
  31 ; -t file               Specify to use file rather than stdin/stdout
  32 ;                        as the terminal.
  33 ;                        This option must be the first in the arglist.
  34 ;                        Processed by `main' in emacs.c -- never seen by lisp
  35 ; -nw                   Inhibit the use of any window-system-specific display
  36 ;                        code; use the current virtual terminal.
  37 ;                        This option must be the first in the arglist.
  38 ;                        Processed by `main' in emacs.c -- never seen by lisp
  39 ; -q                    load no init file
  40 ; -no-init-file         same
  41 ; -u user               load user's init file
  42 ; -user user            same
  43 ; -debug-init           Don't catch errors in init file; let debugger run.
  44
  45 ; These are processed in the order encountered.
  46 ; -f function           execute function
  47 ; -funcall function     same
  48 ; -l file               load file
  49 ; -load file            same
  50 ; -insert file          same
  51 ; file                  visit file
  52 ; -kill                 kill (exit) emacs
  53
  54 ;;; Code:
  55
  56 (setq top-level '(normal-top-level))
  57
  58 (defvar command-line-processed nil "t once command line has been processed")
  59
  60 (defconst inhibit-startup-message nil
  61   "*Non-nil inhibits the initial startup messages.
  62 This is for use in your personal init file, once you are familiar
  63 with the contents of the startup message.")
  64
  65 (defconst inhibit-default-init nil
  66   "*Non-nil inhibits loading the `default' library.")
  67
  68 (defconst command-switch-alist nil
  69   "Alist of command-line switches.
  70 Elements look like (SWITCH-STRING . HANDLER-FUNCTION).
  71 HANDLER-FUNCTION receives switch name as sole arg;
  72 remaining command-line args are in the variable `command-line-args-left'.")
  73
  74 (defvar command-line-functions nil    ;; lrs 7/31/89
  75   "List of functions to process unrecognized command-line arguments.
  76 Each function should access the dynamically bound variables
  77 argi (the current argument) and command-line-args-left (the remaining
  78 arguments).  The function should return non-nil only if it recognizes and
  79 processes argi.  If it does so, it may consume successive arguments by
  80 altering command-line-args-left to remove them.")
  81
  82 (defvar before-init-hook nil
  83   "Functions to call after handling urgent options but before loading init file.
  84 The frame system uses this to open frames to display messages while
  85 Emacs loads the user's initialization file.")
  86
  87 (defvar after-init-hook nil
  88   "Functions to call after loading the init file (`~/.emacs').
  89 The call is not protected by a condition-case, so you can set `debug-on-error'
  90 in `.emacs', and put all the actual code on `after-init-hook'.")
  91
  92 (defvar term-setup-hook nil
  93   "Functions to be called after loading terminal-specific lisp code.
  94 See `run-hooks'.  This variable exists for users to set,
  95 so as to override the definitions made by the terminal-specific file.
  96 Emacs never sets this variable itself.")
  97
  98 (defvar keyboard-type nil
  99   "The brand of keyboard you are using.  This variable is used to define
 100 the proper function and keypad keys for use under X.  It is used in a
 101 fashion analogous to the environment value TERM.")
 102
 103 (defvar window-setup-hook nil
 104   "Function called to initialize window system display.
 105 Emacs calls this after processing the command line arguments and loading
 106 the user's init file.
 107
 108 Users should not set this variable; use term-setup-hook instead.")
 109
 110 (defconst initial-major-mode 'lisp-interaction-mode
 111   "Major mode command symbol to use for the initial *scratch* buffer.")
 112
 113 (defvar init-file-user nil
 114   "Identity of user whose `.emacs' file is or was read.
 115 The value may be the null string or a string containing a user's name.
 116 If the value is a null string, it means that the init file was taken from
 117 the user that originally logged in.
 118
 119 In all cases, `(concat \"~\" init-file-user \"/\")' evaluates to the
 120 directory name of the directory where the `.emacs' file was looked for.")
 121
 122 (defvar site-run-file "site-start"
 123   "File containing site-wide run-time initializations.
 124 This file is loaded at run-time before `~/.emacs'.  It contains inits
 125 that need to be in place for the entire site, but which, due to their
 126 higher incidence of change, don't make sense to load into emacs'
 127 dumped image.  Thus, the run-time load order is: 1. file described in
 128 this variable, if non-nil; 2. `~/.emacs'; 3. `default.el'.")
 129
 130 (defvar init-file-debug nil)
 131
 132 (defun normal-top-level ()
 133   (if command-line-processed
 134       (message "Back to top level.")
 135     (setq command-line-processed t)
 136     (if (not (eq system-type 'vax-vms))
 137         (progn
 138           ;; If the PWD environment variable isn't accurate, delete it.
 139           (let ((pwd (getenv "PWD")))
 140             (and (stringp pwd)
 141                  ;; Use FOO/., so that if FOO is a symlink, file-attributes
 142                  ;; describes the directory linked to, not FOO itself.
 143                  (or (equal (file-attributes
 144                              (concat (file-name-as-directory pwd) "."))
 145                             (file-attributes
 146                              (concat (file-name-as-directory default-directory)
 147                                      ".")))
 148                      (setq process-environment
 149                            (delete (concat "PWD=" pwd)
 150                                    process-environment)))))))
 151     (setq default-directory (abbreviate-file-name default-directory))
 152     (unwind-protect
 153         (command-line)
 154       ;; Do this again, in case .emacs defined more abbreviations.
 155       (setq default-directory (abbreviate-file-name default-directory))
 156       (run-hooks 'emacs-startup-hook)
 157       (and term-setup-hook
 158            (run-hooks 'term-setup-hook))
 159       ;; Modify the initial frame based on what .emacs puts into
 160       ;; ...-frame-alist.
 161       (if (fboundp 'frame-notice-user-settings)
 162           (frame-notice-user-settings))
 163       ;; Now we know the user's default font, so add it to the menu.
 164       (if (fboundp 'font-menu-add-default)
 165           (font-menu-add-default))
 166       (and window-setup-hook
 167            (run-hooks 'window-setup-hook)))))
 168
 169 (defun command-line ()
 170   ;; See if we should import version-control from the environment variable.
 171   (let ((vc (getenv "VERSION_CONTROL")))
 172     (cond ((eq vc nil))                 ;don't do anything if not set
 173           ((or (string= vc "t")
 174                (string= vc "numbered"))
 175            (setq version-control t))
 176           ((or (string= vc "nil")
 177                (string= vc "existing"))
 178            (setq version-control nil))
 179           ((or (string= vc "never")
 180                (string= vc "simple"))
 181            (setq version-control 'never))))
 182
 183   ;;! This has been commented out; I currently find the behavior when
 184   ;;! split-window-keep-point is nil disturbing, but if I can get used
 185   ;;! to it, then it would be better to eliminate the option.
 186   ;;! ;; Choose a good default value for split-window-keep-point.
 187   ;;! (setq split-window-keep-point (> baud-rate 2400))
 188
 189   ;; Read window system's init file if using a window system.
 190   (if (and window-system (not noninteractive))
 191       (load (concat term-file-prefix
 192                     (symbol-name window-system)
 193                     "-win")
 194             ;; Every window system should have a startup file;
 195             ;; barf if we can't find it.
 196             nil t))
 197
 198   (let ((done nil)
 199         (args (cdr command-line-args)))
 200
 201     ;; Figure out which user's init file to load,
 202     ;; either from the environment or from the options.
 203     (setq init-file-user (if noninteractive nil (user-login-name)))
 204     ;; If user has not done su, use current $HOME to find .emacs.
 205     (and init-file-user (string= init-file-user (user-real-login-name))
 206          (setq init-file-user ""))
 207
 208     ;; Process the command-line args, and delete the arguments
 209     ;; processed.  This is consistent with the way main in emacs.c
 210     ;; does things.
 211     (while (and (not done) args)
 212       (let ((argi (car args)))
 213         (cond
 214          ((or (string-equal argi "-q")
 215               (string-equal argi "-no-init-file"))
 216           (setq init-file-user nil
 217                 args (cdr args)))
 218          ((or (string-equal argi "-u")
 219               (string-equal argi "-user"))
 220           (setq args (cdr args)
 221                 init-file-user (car args)
 222                 args (cdr args)))
 223          ((string-equal argi "-no-site-file")
 224           (setq site-run-file nil
 225                 args (cdr args)))
 226          ((string-equal argi "-debug-init")
 227           (setq init-file-debug t
 228                 args (cdr args)))
 229          (t (setq done t)))))
 230
 231     ;; Re-attach the program name to the front of the arg list.
 232     (setcdr command-line-args args))
 233
 234   ;; Under X Windows, this creates the X frame and deletes the terminal frame.
 235   (if (fboundp 'frame-initialize)
 236       (frame-initialize))
 237   (if (fboundp 'face-initialize)
 238       (face-initialize))
 239
 240   (run-hooks 'before-init-hook)
 241
 242   ;; Run the site-start library if it exists.  The point of this file is
 243   ;; that it is run before .emacs.  There is no point in doing this after
 244   ;; .emacs; that is useless.
 245   (if site-run-file
 246       (load site-run-file t t))
 247
 248   ;; Sites should not disable this.  Only individuals should disable
 249   ;; the startup message.
 250   (setq inhibit-startup-message nil)
 251
 252   ;; Load that user's init file, or the default one, or none.
 253   (let ((debug-on-error init-file-debug)
 254         ;; This function actually reads the init files.
 255         (inner
 256          (function
 257           (lambda ()
 258             (if init-file-user
 259                 (progn (load (if (eq system-type 'vax-vms)
 260                                  "sys$login:.emacs"
 261                                (concat "~" init-file-user "/.emacs"))
 262                              t t t)
 263                        (or inhibit-default-init
 264                            (let ((inhibit-startup-message nil))
 265                              ;; Users are supposed to be told their rights.
 266                              ;; (Plus how to get help and how to undo.)
 267                              ;; Don't you dare turn this off for anyone
 268                              ;; except yourself.
 269                              (load "default" t t)))))))))
 270     (if init-file-debug
 271         ;; Do this without a condition-case if the user wants to debug.
 272         (funcall inner)
 273       (condition-case error
 274           (funcall inner)
 275         (error (message "Error in init file: %s%s%s"
 276                         (get (car error) 'error-message)
 277                         (if (cdr error) ": ")
 278                         (mapconcat 'prin1-to-string (cdr error) ", "))))))
 279
 280   (run-hooks 'after-init-hook)
 281
 282   ;; If *scratch* exists and init file didn't change its mode, initialize it.
 283   (if (get-buffer "*scratch*")
 284       (save-excursion
 285         (set-buffer "*scratch*")
 286         (if (eq major-mode 'fundamental-mode)
 287             (funcall initial-major-mode))))
 288   ;; Load library for our terminal type.
 289   ;; User init file can set term-file-prefix to nil to prevent this.
 290   (and term-file-prefix (not noninteractive) (not window-system)
 291        (let ((term (getenv "TERM"))
 292              hyphend)
 293          (while (and term
 294                      (not (load (concat term-file-prefix term) t t)))
 295            ;; Strip off last hyphen and what follows, then try again
 296            (if (setq hyphend (string-match "[-_][^-_]+$" term))
 297                (setq term (substring term 0 hyphend))
 298              (setq term nil)))))
 299
 300   ;; Process the remaining args.
 301   (command-line-1 (cdr command-line-args))
 302
 303   ;; If -batch, terminate after processing the command options.
 304   (if noninteractive (kill-emacs t)))
 305
 306 (defun command-line-1 (command-line-args-left)
 307   (if (null command-line-args-left)
 308       (cond ((and (not inhibit-startup-message) (not noninteractive)
 309                   ;; Don't clobber a non-scratch buffer if init file
 310                   ;; has selected it.
 311                   (string= (buffer-name) "*scratch*")
 312                   (not (input-pending-p)))
 313              ;; If there are no switches to process, we might as well
 314              ;; run this hook now, and there may be some need to do it
 315              ;; before doing any output.
 316              (and term-setup-hook
 317                   (run-hooks 'term-setup-hook))
 318              ;; Don't let the hook be run twice.
 319              (setq term-setup-hook nil)
 320
 321              ;; It's important to notice the user settings before we
 322              ;; display the startup message; otherwise, the settings
 323              ;; won't take effect until the user gives the first
 324              ;; keystroke, and that's distracting.
 325              (if (fboundp 'frame-notice-user-settings)
 326                  (frame-notice-user-settings))
 327
 328              (and window-setup-hook
 329                   (run-hooks 'window-setup-hook))
 330              (setq window-setup-hook nil)
 331              (unwind-protect
 332                  (progn
 333                    (insert (emacs-version)
 334                            "
 335 Copyright (C) 1993 Free Software Foundation, Inc.\n\n")
 336                    ;; If keys have their default meanings,
 337                    ;; use precomputed string to save lots of time.
 338                    (if (and (eq (key-binding "\C-h") 'help-command)
 339                             (eq (key-binding "\C-xu") 'advertised-undo)
 340                             (eq (key-binding "\C-x\C-c") 'save-buffers-kill-emacs)
 341                             (eq (key-binding "\C-h\C-c") 'describe-copying)
 342                             (eq (key-binding "\C-h\C-d") 'describe-distribution)
 343                             (eq (key-binding "\C-h\C-w") 'describe-no-warranty)
 344                             (eq (key-binding "\C-ht") 'help-with-tutorial))
 345                        (insert
 346        "Type C-h for help; C-x u to undo changes.  (`C-' means use CTRL key.)
 347 To kill the Emacs job, type C-x C-c.
 348 Type C-h t for a tutorial on using Emacs.
 349 Type C-h i to enter Info, which you can use to read GNU documentation.
 350
 351 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type C-h C-w for full details.
 352 You may give out copies of Emacs; type C-h C-c to see the conditions.
 353 Type C-h C-d for information on getting the latest version.")
 354                      (insert (substitute-command-keys
 355        "Type \\[help-command] for help; \\[advertised-undo] to undo changes.  (`C-' means use CTRL key.)
 356 To kill the Emacs job, type \\[save-buffers-kill-emacs].
 357 Type \\[help-with-tutorial] for a tutorial on using Emacs.
 358 Type \\[info] to enter Info, which you can use to read GNU documentation.
 359
 360 GNU Emacs comes with ABSOLUTELY NO WARRANTY; type \\[describe-no-warranty] for full details.
 361 You may give out copies of Emacs; type \\[describe-copying] to see the conditions.
 362 Type \\[describe-distribution] for information on getting the latest version.")))
 363                    (set-buffer-modified-p nil)
 364                    (sit-for 120))
 365                (save-excursion
 366                  ;; In case the Emacs server has already selected
 367                  ;; another buffer, erase the one our message is in.
 368                  (set-buffer (get-buffer "*scratch*"))
 369                  (erase-buffer)
 370                  (set-buffer-modified-p nil)))))
 371     (let ((dir default-directory)
 372           (file-count 0)
 373           first-file-buffer
 374           (line 0))
 375       (while command-line-args-left
 376         (let ((argi (car command-line-args-left))
 377               tem)
 378           (setq command-line-args-left (cdr command-line-args-left))
 379           (cond ((setq tem (assoc argi command-switch-alist))
 380                  (funcall (cdr tem) argi))
 381                 ((or (string-equal argi "-f")  ;what the manual claims
 382                      (string-equal argi "-funcall")
 383                      (string-equal argi "-e")) ; what the source used to say
 384                  (setq tem (intern (car command-line-args-left)))
 385                  (setq command-line-args-left (cdr command-line-args-left))
 386                  (funcall tem))
 387                 ((or (string-equal argi "-l")
 388                      (string-equal argi "-load"))
 389                  (let ((file (car command-line-args-left)))
 390                    ;; Take file from default dir if it exists there;
 391                    ;; otherwise let `load' search for it.
 392                    (if (file-exists-p (expand-file-name file))
 393                        (setq file (expand-file-name file)))
 394                    (load file nil t))
 395                  (setq command-line-args-left (cdr command-line-args-left)))
 396                 ((string-equal argi "-insert")
 397                  (or (stringp (car command-line-args-left))
 398                      (error "filename omitted from `-insert' option"))
 399                  (insert-file-contents (car command-line-args-left))
 400                  (setq command-line-args-left (cdr command-line-args-left)))
 401                 ((string-equal argi "-kill")
 402                  (kill-emacs t))
 403                 ((string-match "^\\+[0-9]+\\'" argi)
 404                  (setq line (string-to-int argi)))
 405                 (t
 406                  ;; We have almost exhausted our options. See if the
 407                  ;; user has made any other command-line options available
 408                  (let ((hooks command-line-functions);; lrs 7/31/89
 409                        (did-hook nil))
 410                    (while (and hooks
 411                                (not (setq did-hook (funcall (car hooks)))))
 412                      (setq hooks (cdr hooks)))
 413                    (if (not did-hook)
 414                        ;; Ok, presume that the argument is a file name
 415                        (progn
 416                          (setq file-count (1+ file-count))
 417                          (cond ((= file-count 1)
 418                                 (setq first-file-buffer
 419                                       (find-file (expand-file-name argi dir))))
 420                                (t
 421                                 (find-file-other-window (expand-file-name argi dir))))
 422                          (or (zerop line)
 423                              (goto-line line))
 424                          (setq line 0))))))))
 425       ;; If 3 or more files visited, and not all visible,
 426       ;; show user what they all are.
 427       (if (> file-count 2)
 428           (or (get-buffer-window first-file-buffer)
 429               (progn (other-window 1)
 430                      (buffer-menu)))))))
 431
 432 ;;; startup.el ends here