lisp/wid-edit.el

   1 ;;; wid-edit.el --- Functions for creating and using widgets.
   2 ;;
   3 ;; Copyright (C) 1996, 1997 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Per Abrahamsen <abraham@dina.kvl.dk>
   6 ;; Keywords: extensions
   7 ;; Version: 1.9945
   8 ;; X-URL: http://www.dina.kvl.dk/~abraham/custom/
   9
  10 ;; This file is part of GNU Emacs.
  11
  12 ;; GNU Emacs is free software; you can redistribute it and/or modify
  13 ;; it under the terms of the GNU General Public License as published by
  14 ;; the Free Software Foundation; either version 2, or (at your option)
  15 ;; any later version.
  16
  17 ;; GNU Emacs is distributed in the hope that it will be useful,
  18 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  19 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  20 ;; GNU General Public License for more details.
  21
  22 ;; You should have received a copy of the GNU General Public License
  23 ;; along with GNU Emacs; see the file COPYING.  If not, write to the
  24 ;; Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  25 ;; Boston, MA 02111-1307, USA.
  26
  27 ;;; Commentary:
  28 ;;
  29 ;; See `widget.el'.
  30
  31 ;;; Code:
  32
  33 (require 'widget)
  34 (eval-when-compile (require 'cl))
  35
  36 ;;; Compatibility.
  37
  38 (eval-and-compile
  39   (autoload 'pp-to-string "pp")
  40   (autoload 'Info-goto-node "info")
  41
  42   (when (string-match "XEmacs" emacs-version)
  43     (condition-case nil
  44         (require 'overlay)
  45       (error (load-library "x-overlay"))))
  46
  47   (if (string-match "XEmacs" emacs-version)
  48       (defun widget-event-point (event)
  49         "Character position of the end of event if that exists, or nil."
  50         (if (mouse-event-p event)
  51             (event-point event)
  52           nil))
  53     (defun widget-event-point (event)
  54       "Character position of the end of event if that exists, or nil."
  55       (posn-point (event-end event))))
  56
  57   (defalias 'widget-read-event (if (string-match "XEmacs" emacs-version)
  58                                    'next-event
  59                                  'read-event))
  60
  61   ;; The following should go away when bundled with Emacs.
  62   (condition-case ()
  63       (require 'custom)
  64     (error nil))
  65
  66   (unless (and (featurep 'custom) (fboundp 'custom-declare-variable))
  67     ;; We have the old custom-library, hack around it!
  68     (defmacro defgroup (&rest args) nil)
  69     (defmacro defcustom (var value doc &rest args)
  70       (` (defvar (, var) (, value) (, doc))))
  71     (defmacro defface (&rest args) nil)
  72     (define-widget-keywords :prefix :tag :load :link :options :type :group)
  73     (when (fboundp 'copy-face)
  74       (copy-face 'default 'widget-documentation-face)
  75       (copy-face 'bold 'widget-button-face)
  76       (copy-face 'italic 'widget-field-face)))
  77
  78   (unless (fboundp 'button-release-event-p)
  79     ;; XEmacs function missing from Emacs.
  80     (defun button-release-event-p (event)
  81       "Non-nil if EVENT is a mouse-button-release event object."
  82       (and (eventp event)
  83            (memq (event-basic-type event) '(mouse-1 mouse-2 mouse-3))
  84            (or (memq 'click (event-modifiers event))
  85                (memq  'drag (event-modifiers event))))))
  86
  87   (unless (fboundp 'functionp)
  88     ;; Missing from Emacs 19.34 and earlier.
  89     (defun functionp (object)
  90       "Non-nil of OBJECT is a type of object that can be called as a function."
  91       (or (subrp object) (byte-code-function-p object)
  92           (eq (car-safe object) 'lambda)
  93           (and (symbolp object) (fboundp object)))))
  94
  95   (unless (fboundp 'error-message-string)
  96     ;; Emacs function missing in XEmacs.
  97     (defun error-message-string (obj)
  98       "Convert an error value to an error message."
  99       (let ((buf (get-buffer-create " *error-message*")))
 100         (erase-buffer buf)
 101         (display-error obj buf)
 102         (buffer-string buf)))))
 103
 104 (when (let ((a "foo"))
 105         (put-text-property 1 2 'foo 1 a)
 106         (put-text-property 1 2 'bar 2 a)
 107         (set-text-properties 1 2 nil a)
 108         (text-properties-at 1 a))
 109   ;; XEmacs 20.2 and earlier had a buggy set-text-properties.
 110   (defun set-text-properties (start end props &optional buffer-or-string)
 111     "Completely replace properties of text from START to END.
 112 The third argument PROPS is the new property list.
 113 The optional fourth argument, BUFFER-OR-STRING,
 114 is the string or buffer containing the text."
 115     (map-extents #'(lambda (extent ignored)
 116                      (remove-text-properties
 117                       start end
 118                       (list (extent-property extent 'text-prop)
 119                             nil)
 120                       buffer-or-string)
 121                      nil)
 122                  buffer-or-string start end nil nil 'text-prop)
 123     (add-text-properties start end props buffer-or-string)))
 124
 125 ;;; Customization.
 126
 127 (defgroup widgets nil
 128   "Customization support for the Widget Library."
 129   :link '(custom-manual "(widget)Top")
 130   :link '(url-link :tag "Development Page"
 131                    "http://www.dina.kvl.dk/~abraham/custom/")
 132   :link '(emacs-library-link :tag "Lisp File" "widget.el")
 133   :prefix "widget-"
 134   :group 'extensions
 135   :group 'hypermedia)
 136
 137 (defgroup widget-documentation nil
 138   "Options controling the display of documentation strings."
 139   :group 'widgets)
 140
 141 (defgroup widget-faces nil
 142   "Faces used by the widget library."
 143   :group 'widgets
 144   :group 'faces)
 145
 146 (defvar widget-documentation-face 'widget-documentation-face
 147   "Face used for documentation strings in widges.
 148 This exists as a variable so it can be set locally in certain buffers.")
 149
 150 (defface widget-documentation-face '((((class color)
 151                                        (background dark))
 152                                       (:foreground "lime green"))
 153                                      (((class color)
 154                                        (background light))
 155                                       (:foreground "dark green"))
 156                                      (t nil))
 157   "Face used for documentation text."
 158   :group 'widget-documentation
 159   :group 'widget-faces)
 160
 161 (defvar widget-button-face 'widget-button-face
 162   "Face used for buttons in widges.
 163 This exists as a variable so it can be set locally in certain buffers.")
 164
 165 (defface widget-button-face '((t (:bold t)))
 166   "Face used for widget buttons."
 167   :group 'widget-faces)
 168
 169 (defcustom widget-mouse-face 'highlight
 170   "Face used for widget buttons when the mouse is above them."
 171   :type 'face
 172   :group 'widget-faces)
 173
 174 (defface widget-field-face '((((class grayscale color)
 175                                (background light))
 176                               (:background "gray85"))
 177                              (((class grayscale color)
 178                                (background dark))
 179                               (:background "dim gray"))
 180                              (t
 181                               (:italic t)))
 182   "Face used for editable fields."
 183   :group 'widget-faces)
 184
 185 (defface widget-single-line-field-face '((((class grayscale color)
 186                                            (background light))
 187                                           (:background "gray85"))
 188                                          (((class grayscale color)
 189                                            (background dark))
 190                                           (:background "dim gray"))
 191                                          (t
 192                                           (:italic t)))
 193   "Face used for editable fields spanning only a single line."
 194   :group 'widget-faces)
 195
 196 (defvar widget-single-line-display-table
 197   (let ((table (make-display-table)))
 198     (aset table 9  "^I")
 199     (aset table 10 "^J")
 200     table)
 201   "Display table used for single-line editable fields.")
 202
 203 (when (fboundp 'set-face-display-table)
 204   (set-face-display-table 'widget-single-line-field-face
 205                           widget-single-line-display-table))
 206
 207 ;;; Utility functions.
 208 ;;
 209 ;; These are not really widget specific.
 210
 211 (defsubst widget-plist-member (plist prop)
 212   ;; Return non-nil if PLIST has the property PROP.
 213   ;; PLIST is a property list, which is a list of the form
 214   ;; (PROP1 VALUE1 PROP2 VALUE2 ...).  PROP is a symbol.
 215   ;; Unlike `plist-get', this allows you to distinguish between a missing
 216   ;; property and a property with the value nil.
 217   ;; The value is actually the tail of PLIST whose car is PROP.
 218   (while (and plist (not (eq (car plist) prop)))
 219     (setq plist (cdr (cdr plist))))
 220   plist)
 221
 222 (defun widget-princ-to-string (object)
 223   ;; Return string representation of OBJECT, any Lisp object.
 224   ;; No quoting characters are used; no delimiters are printed around
 225   ;; the contents of strings.
 226   (save-excursion
 227     (set-buffer (get-buffer-create " *widget-tmp*"))
 228     (erase-buffer)
 229     (let ((standard-output (current-buffer)))
 230       (princ object))
 231     (buffer-string)))
 232
 233 (defun widget-clear-undo ()
 234   "Clear all undo information."
 235   (buffer-disable-undo (current-buffer))
 236   (buffer-enable-undo))
 237
 238 (defcustom widget-menu-max-size 40
 239   "Largest number of items allowed in a popup-menu.
 240 Larger menus are read through the minibuffer."
 241   :group 'widgets
 242   :type 'integer)
 243
 244 (defcustom widget-menu-minibuffer-flag (string-match "XEmacs" emacs-version)
 245   "*Control how to ask for a choice from the keyboard.
 246 Non-nil means use the minibuffer;
 247 nil means read a single character."
 248   :group 'widgets
 249   :type 'boolean)
 250
 251 (defun widget-choose (title items &optional event)
 252   "Choose an item from a list.
 253
 254 First argument TITLE is the name of the list.
 255 Second argument ITEMS is an list whose members are either
 256  (NAME . VALUE), to indicate selectable items, or just strings to
 257  indicate unselectable items.
 258 Optional third argument EVENT is an input event.
 259
 260 The user is asked to choose between each NAME from the items alist,
 261 and the VALUE of the chosen element will be returned.  If EVENT is a
 262 mouse event, and the number of elements in items is less than
 263 `widget-menu-max-size', a popup menu will be used, otherwise the
 264 minibuffer."
 265   (cond ((and (< (length items) widget-menu-max-size)
 266               event (fboundp 'x-popup-menu) window-system)
 267          ;; We are in Emacs-19, pressed by the mouse
 268          (x-popup-menu event
 269                        (list title (cons "" items))))
 270         ((and (< (length items) widget-menu-max-size)
 271               event (fboundp 'popup-menu) window-system)
 272          ;; We are in XEmacs, pressed by the mouse
 273          (let ((val (get-popup-menu-response
 274                      (cons title
 275                            (mapcar
 276                             (function
 277                              (lambda (x)
 278                                (if (stringp x)
 279                                    (vector x nil nil)
 280                                  (vector (car x) (list (car x)) t))))
 281                             items)))))
 282            (setq val (and val
 283                           (listp (event-object val))
 284                           (stringp (car-safe (event-object val)))
 285                           (car (event-object val))))
 286            (cdr (assoc val items))))
 287         (widget-menu-minibuffer-flag
 288          ;; Read the choice of name from the minibuffer.
 289          (setq items (widget-remove-if 'stringp items))
 290          (let ((val (completing-read (concat title ": ") items nil t)))
 291            (if (stringp val)
 292                (let ((try (try-completion val items)))
 293                  (when (stringp try)
 294                    (setq val try))
 295                  (cdr (assoc val items)))
 296              nil)))
 297         (t
 298          ;; Construct a menu of the choices
 299          ;; and then use it for prompting for a single character.
 300          (let* ((overriding-terminal-local-map
 301                  (make-sparse-keymap))
 302                 map choice (next-digit ?0)
 303                 some-choice-enabled
 304                 value)
 305            ;; Define SPC as a prefix char to get to this menu.
 306            (define-key overriding-terminal-local-map " "
 307              (setq map (make-sparse-keymap title)))
 308            (save-excursion
 309              (set-buffer (get-buffer-create " widget-choose"))
 310              (erase-buffer)
 311              (insert "Available choices:\n\n")
 312              (while items
 313                (setq choice (car items) items (cdr items))
 314                (if (consp choice)
 315                    (let* ((name (car choice))
 316                          (function (cdr choice)))
 317                      (insert (format "%c = %s\n" next-digit name))
 318                      (define-key map (vector next-digit) function)
 319                      (setq some-choice-enabled t)))
 320                ;; Allocate digits to disabled alternatives
 321                ;; so that the digit of a given alternative never varies.
 322                (setq next-digit (1+ next-digit)))
 323              (insert "\nC-g = Quit"))
 324            (or some-choice-enabled
 325                (error "None of the choices is currently meaningful"))
 326            (define-key map [?\C-g] 'keyboard-quit)
 327            (define-key map [t] 'keyboard-quit)
 328            (setcdr map (nreverse (cdr map)))
 329            ;; Unread a SPC to lead to our new menu.
 330            (setq unread-command-events (cons ?\ unread-command-events))
 331            ;; Read a char with the menu, and return the result
 332            ;; that corresponds to it.
 333            (save-window-excursion
 334              (display-buffer (get-buffer " widget-choose"))
 335              (let ((cursor-in-echo-area t))
 336                (setq value
 337                      (lookup-key overriding-terminal-local-map
 338                                  (read-key-sequence title) t))))
 339            (when (eq value 'keyboard-quit)
 340              (error "Canceled"))
 341            value))))
 342
 343 (defun widget-remove-if (predictate list)
 344   (let (result (tail list))
 345     (while tail
 346       (or (funcall predictate (car tail))
 347           (setq result (cons (car tail) result)))
 348       (setq tail (cdr tail)))
 349     (nreverse result)))
 350
 351 ;;; Widget text specifications.
 352 ;;
 353 ;; These functions are for specifying text properties.
 354
 355 (defun widget-specify-none (from to)
 356   ;; Clear all text properties between FROM and TO.
 357   (set-text-properties from to nil))
 358
 359 (defun widget-specify-text (from to)
 360   ;; Default properties.
 361   (add-text-properties from to (list 'read-only t
 362                                      'front-sticky t
 363                                      'rear-nonsticky nil
 364                                      'start-open nil
 365                                      'end-open nil)))
 366
 367 (defcustom widget-field-add-space
 368   (or (< emacs-major-version 20)
 369       (and (eq emacs-major-version 20)
 370            (< emacs-minor-version 3))
 371       (not (string-match "XEmacs" emacs-version)))
 372   "Non-nil means add extra space at the end of editable text fields.
 373
 374 This is needed on all versions of Emacs, and on XEmacs before 20.3.
 375 If you don't add the space, it will become impossible to edit a zero
 376 size field."
 377   :type 'boolean
 378   :group 'widgets)
 379
 380 (defcustom widget-field-use-before-change
 381   (or (> emacs-minor-version 34)
 382       (>= emacs-major-version 20)
 383       (string-match "XEmacs" emacs-version))
 384   "Non-nil means use `before-change-functions' to track editable fields.
 385 This enables the use of undo, but doesn't work on Emacs 19.34 and earlier.
 386 Using before hooks also means that the :notify function can't know the
 387 new value."
 388   :type 'boolean
 389   :group 'widgets)
 390
 391 (defun widget-specify-field (widget from to)
 392   "Specify editable button for WIDGET between FROM and TO."
 393   (put-text-property from to 'read-only nil)
 394   ;; Terminating space is not part of the field, but necessary in
 395   ;; order for local-map to work.  Remove next sexp if local-map works
 396   ;; at the end of the overlay.
 397   (save-excursion
 398     (goto-char to)
 399     (cond ((null (widget-get widget :size))
 400            (forward-char 1))
 401           (widget-field-add-space
 402            (insert-and-inherit " ")))
 403     (setq to (point)))
 404   (if (or widget-field-add-space
 405           (null (widget-get widget :size)))
 406       (add-text-properties (1- to) to
 407                            '(front-sticky nil start-open t read-only to))
 408     (add-text-properties to (1+ to)
 409                          '(front-sticky nil start-open t read-only to)))
 410   (add-text-properties (1- from) from
 411                        '(rear-nonsticky t end-open t read-only from))
 412   (let ((map (widget-get widget :keymap))
 413         (face (or (widget-get widget :value-face) 'widget-field-face))
 414         (help-echo (widget-get widget :help-echo))
 415         (overlay (make-overlay from to nil
 416                                nil (or (not widget-field-add-space)
 417                                        (widget-get widget :size)))))
 418     (unless (or (stringp help-echo) (null help-echo))
 419       (setq help-echo 'widget-mouse-help))
 420     (widget-put widget :field-overlay overlay)
 421     (overlay-put overlay 'detachable nil)
 422     (overlay-put overlay 'field widget)
 423     (overlay-put overlay 'local-map map)
 424     (overlay-put overlay 'keymap map)
 425     (overlay-put overlay 'face face)
 426     (overlay-put overlay 'balloon-help help-echo)
 427     (overlay-put overlay 'help-echo help-echo)))
 428
 429 (defun widget-specify-button (widget from to)
 430   "Specify button for WIDGET between FROM and TO."
 431   (let ((face (widget-apply widget :button-face-get))
 432         (help-echo (widget-get widget :help-echo))
 433         (overlay (make-overlay from to nil t nil)))
 434     (widget-put widget :button-overlay overlay)
 435     (unless (or (null help-echo) (stringp help-echo))
 436       (setq help-echo 'widget-mouse-help))
 437     (overlay-put overlay 'button widget)
 438     (overlay-put overlay 'mouse-face widget-mouse-face)
 439     (overlay-put overlay 'balloon-help help-echo)
 440     (overlay-put overlay 'help-echo help-echo)
 441     (overlay-put overlay 'face face)))
 442
 443 (defun widget-mouse-help (extent)
 444   "Find mouse help string for button in extent."
 445   (let* ((widget (widget-at (extent-start-position extent)))
 446          (help-echo (and widget (widget-get widget :help-echo))))
 447     (cond ((stringp help-echo)
 448            help-echo)
 449           ((and (symbolp help-echo) (fboundp help-echo)
 450                 (stringp (setq help-echo (funcall help-echo widget))))
 451            help-echo)
 452           (t
 453            (format "(widget %S :help-echo %S)" widget help-echo)))))
 454
 455 (defun widget-specify-sample (widget from to)
 456   ;; Specify sample for WIDGET between FROM and TO.
 457   (let ((face (widget-apply widget :sample-face-get))
 458         (overlay (make-overlay from to nil t nil)))
 459     (overlay-put overlay 'face face)
 460     (widget-put widget :sample-overlay overlay)))
 461
 462 (defun widget-specify-doc (widget from to)
 463   ;; Specify documentation for WIDGET between FROM and TO.
 464   (add-text-properties from to (list 'widget-doc widget
 465                                      'face widget-documentation-face)))
 466
 467 (defmacro widget-specify-insert (&rest form)
 468   ;; Execute FORM without inheriting any text properties.
 469   (`
 470    (save-restriction
 471      (let ((inhibit-read-only t)
 472            result
 473            before-change-functions
 474            after-change-functions)
 475        (insert "<>")
 476        (narrow-to-region (- (point) 2) (point))
 477        (widget-specify-none (point-min) (point-max))
 478        (goto-char (1+ (point-min)))
 479        (setq result (progn (,@ form)))
 480        (delete-region (point-min) (1+ (point-min)))
 481        (delete-region (1- (point-max)) (point-max))
 482        (goto-char (point-max))
 483        result))))
 484
 485 (defface widget-inactive-face '((((class grayscale color)
 486                                   (background dark))
 487                                  (:foreground "light gray"))
 488                                 (((class grayscale color)
 489                                   (background light))
 490                                  (:foreground "dim gray"))
 491                                 (t
 492                                  (:italic t)))
 493   "Face used for inactive widgets."
 494   :group 'widget-faces)
 495
 496 (defun widget-specify-inactive (widget from to)
 497   "Make WIDGET inactive for user modifications."
 498   (unless (widget-get widget :inactive)
 499     (let ((overlay (make-overlay from to nil t nil)))
 500       (overlay-put overlay 'face 'widget-inactive-face)
 501       ;; This is disabled, as it makes the mouse cursor change shape.
 502       ;; (overlay-put overlay 'mouse-face 'widget-inactive-face)
 503       (overlay-put overlay 'evaporate t)
 504       (overlay-put overlay 'priority 100)
 505       (overlay-put overlay (if (string-match "XEmacs" emacs-version)
 506                                'read-only
 507                              'modification-hooks) '(widget-overlay-inactive))
 508       (widget-put widget :inactive overlay))))
 509
 510 (defun widget-overlay-inactive (&rest junk)
 511   "Ignoring the arguments, signal an error."
 512   (unless inhibit-read-only
 513     (error "Attempt to modify inactive widget")))
 514
 515
 516 (defun widget-specify-active (widget)
 517   "Make WIDGET active for user modifications."
 518   (let ((inactive (widget-get widget :inactive)))
 519     (when inactive
 520       (delete-overlay inactive)
 521       (widget-put widget :inactive nil))))
 522
 523 ;;; Widget Properties.
 524
 525 (defsubst widget-type (widget)
 526   "Return the type of WIDGET, a symbol."
 527   (car widget))
 528
 529 (defun widget-put (widget property value)
 530   "In WIDGET set PROPERTY to VALUE.
 531 The value can later be retrived with `widget-get'."
 532   (setcdr widget (plist-put (cdr widget) property value)))
 533
 534 (defun widget-get (widget property)
 535   "In WIDGET, get the value of PROPERTY.
 536 The value could either be specified when the widget was created, or
 537 later with `widget-put'."
 538   (let ((missing t)
 539         value tmp)
 540     (while missing
 541       (cond ((setq tmp (widget-plist-member (cdr widget) property))
 542              (setq value (car (cdr tmp))
 543                    missing nil))
 544             ((setq tmp (car widget))
 545              (setq widget (get tmp 'widget-type)))
 546             (t
 547              (setq missing nil))))
 548     value))
 549
 550 (defun widget-get-indirect (widget property)
 551   "In WIDGET, get the value of PROPERTY.
 552 If the value is a symbol, return its binding.
 553 Otherwise, just return the value."
 554   (let ((value (widget-get widget property)))
 555     (if (symbolp value)
 556         (symbol-value value)
 557       value)))
 558
 559 (defun widget-member (widget property)
 560   "Non-nil iff there is a definition in WIDGET for PROPERTY."
 561   (cond ((widget-plist-member (cdr widget) property)
 562          t)
 563         ((car widget)
 564          (widget-member (get (car widget) 'widget-type) property))
 565         (t nil)))
 566
 567 ;;;###autoload
 568 (defun widget-apply (widget property &rest args)
 569   "Apply the value of WIDGET's PROPERTY to the widget itself.
 570 ARGS are passed as extra arguments to the function."
 571   (apply (widget-get widget property) widget args))
 572
 573 (defun widget-value (widget)
 574   "Extract the current value of WIDGET."
 575   (widget-apply widget
 576                 :value-to-external (widget-apply widget :value-get)))
 577
 578 (defun widget-value-set (widget value)
 579   "Set the current value of WIDGET to VALUE."
 580   (widget-apply widget
 581                 :value-set (widget-apply widget
 582                                          :value-to-internal value)))
 583
 584 (defun widget-match-inline (widget vals)
 585   ;; In WIDGET, match the start of VALS.
 586   (cond ((widget-get widget :inline)
 587          (widget-apply widget :match-inline vals))
 588         ((and vals
 589               (widget-apply widget :match (car vals)))
 590          (cons (list (car vals)) (cdr vals)))
 591         (t nil)))
 592
 593 (defun widget-apply-action (widget &optional event)
 594   "Apply :action in WIDGET in response to EVENT."
 595   (if (widget-apply widget :active)
 596       (widget-apply widget :action event)
 597     (error "Attempt to perform action on inactive widget")))
 598
 599 ;;; Helper functions.
 600 ;;
 601 ;; These are widget specific.
 602
 603 ;;;###autoload
 604 (defun widget-prompt-value (widget prompt &optional value unbound)
 605   "Prompt for a value matching WIDGET, using PROMPT.
 606 The current value is assumed to be VALUE, unless UNBOUND is non-nil."
 607   (unless (listp widget)
 608     (setq widget (list widget)))
 609   (setq prompt (format "[%s] %s" (widget-type widget) prompt))
 610   (setq widget (widget-convert widget))
 611   (let ((answer (widget-apply widget :prompt-value prompt value unbound)))
 612     (unless (widget-apply widget :match answer)
 613       (error "Value does not match %S type." (car widget)))
 614     answer))
 615
 616 (defun widget-get-sibling (widget)
 617   "Get the item WIDGET is assumed to toggle.
 618 This is only meaningful for radio buttons or checkboxes in a list."
 619   (let* ((parent (widget-get widget :parent))
 620          (children (widget-get parent :children))
 621          child)
 622     (catch 'child
 623       (while children
 624         (setq child (car children)
 625               children (cdr children))
 626         (when (eq (widget-get child :button) widget)
 627           (throw 'child child)))
 628       nil)))
 629
 630 (defun widget-map-buttons (function &optional buffer maparg)
 631   "Map FUNCTION over the buttons in BUFFER.
 632 FUNCTION is called with the arguments WIDGET and MAPARG.
 633
 634 If FUNCTION returns non-nil, the walk is cancelled.
 635
 636 The arguments MAPARG, and BUFFER default to nil and (current-buffer),
 637 respectively."
 638   (let ((cur (point-min))
 639         (widget nil)
 640         (parent nil)
 641         (overlays (if buffer
 642                       (save-excursion (set-buffer buffer) (overlay-lists))
 643                     (overlay-lists))))
 644     (setq overlays (append (car overlays) (cdr overlays)))
 645     (while (setq cur (pop overlays))
 646       (setq widget (overlay-get cur 'button))
 647       (if (and widget (funcall function widget maparg))
 648           (setq overlays nil)))))
 649
 650 ;;; Glyphs.
 651
 652 (defcustom widget-glyph-directory (concat data-directory "custom/")
 653   "Where widget glyphs are located.
 654 If this variable is nil, widget will try to locate the directory
 655 automatically."
 656   :group 'widgets
 657   :type 'directory)
 658
 659 (defcustom widget-glyph-enable t
 660   "If non nil, use glyphs in images when available."
 661   :group 'widgets
 662   :type 'boolean)
 663
 664 (defcustom widget-image-conversion
 665   '((xpm ".xpm") (gif ".gif") (png ".png") (jpeg ".jpg" ".jpeg")
 666     (xbm ".xbm"))
 667   "Conversion alist from image formats to file name suffixes."
 668   :group 'widgets
 669   :type '(repeat (cons :format "%v"
 670                        (symbol :tag "Image Format" unknown)
 671                        (repeat :tag "Suffixes"
 672                                (string :format "%v")))))
 673
 674 (defun widget-glyph-find (image tag)
 675   "Create a glyph corresponding to IMAGE with string TAG as fallback.
 676 IMAGE should either already be a glyph, or be a file name sans
 677 extension (xpm, xbm, gif, jpg, or png) located in
 678 `widget-glyph-directory'."
 679   (cond ((not (and image
 680                    (string-match "XEmacs" emacs-version)
 681                    widget-glyph-enable
 682                    (fboundp 'make-glyph)
 683                    (fboundp 'locate-file)
 684                    image))
 685          ;; We don't want or can't use glyphs.
 686          nil)
 687         ((and (fboundp 'glyphp)
 688               (glyphp image))
 689          ;; Already a glyph.  Use it.
 690          image)
 691         ((stringp image)
 692          ;; A string.  Look it up in relevant directories.
 693          (let* ((dirlist (list (or widget-glyph-directory
 694                                    (concat data-directory
 695                                            "custom/"))
 696                                data-directory))
 697                 (formats widget-image-conversion)
 698                 file)
 699            (while (and formats (not file))
 700              (when (valid-image-instantiator-format-p (car (car formats)))
 701                (setq file (locate-file image dirlist
 702                                        (mapconcat 'identity
 703                                                   (cdr (car formats))
 704                                                   ":"))))
 705              (unless file
 706                (setq formats (cdr formats))))
 707            (and file
 708                 ;; We create a glyph with the file as the default image
 709                 ;; instantiator, and the TAG fallback
 710                 (make-glyph (list (vector (car (car formats)) ':file file)
 711                                   (vector 'string ':data tag))))))
 712         ((valid-instantiator-p image 'image)
 713          ;; A valid image instantiator (e.g. [gif :file "somefile"] etc.)
 714          (make-glyph (list image
 715                            (vector 'string ':data tag))))
 716         ((consp image)
 717          ;; This could be virtually anything.  Let `make-glyph' sort it out.
 718          (make-glyph image))
 719         (t
 720          ;; Oh well.
 721          nil)))
 722
 723 (defun widget-glyph-insert (widget tag image &optional down inactive)
 724   "In WIDGET, insert the text TAG or, if supported, IMAGE.
 725 IMAGE should either be a glyph, an image instantiator, or an image file
 726 name sans extension (xpm, xbm, gif, jpg, or png) located in
 727 `widget-glyph-directory'.
 728
 729 Optional arguments DOWN and INACTIVE is used instead of IMAGE when the
 730 glyph is pressed or inactive, respectively.
 731
 732 WARNING: If you call this with a glyph, and you want the user to be
 733 able to invoke the glyph, make sure it is unique.  If you use the
 734 same glyph for multiple widgets, invoking any of the glyphs will
 735 cause the last created widget to be invoked.
 736
 737 Instead of an instantiator, you can also use a list of instantiators,
 738 or whatever `make-glyph' will accept.  However, in that case you must
 739 provide the fallback TAG as a part of the instantiator yourself."
 740   (let ((glyph (widget-glyph-find image tag)))
 741     (if glyph
 742         (widget-glyph-insert-glyph widget
 743                                    glyph
 744                                    (widget-glyph-find down tag)
 745                                    (widget-glyph-find inactive tag))
 746       (insert tag))))
 747
 748 (defun widget-glyph-insert-glyph (widget glyph &optional down inactive)
 749   "In WIDGET, insert GLYPH.
 750 If optional arguments DOWN and INACTIVE are given, they should be
 751 glyphs used when the widget is pushed and inactive, respectively."
 752   (when widget
 753     (set-glyph-property glyph 'widget widget)
 754     (when down
 755       (set-glyph-property down 'widget widget))
 756     (when inactive
 757       (set-glyph-property inactive 'widget widget)))
 758   (insert "*")
 759   (let ((ext (make-extent (point) (1- (point))))
 760         (help-echo (and widget (widget-get widget :help-echo))))
 761     (set-extent-property ext 'invisible t)
 762     (set-extent-property ext 'start-open t)
 763     (set-extent-property ext 'end-open t)
 764     (set-extent-end-glyph ext glyph)
 765     (when help-echo
 766       (set-extent-property ext 'balloon-help help-echo)
 767       (set-extent-property ext 'help-echo help-echo)))
 768   (when widget
 769     (widget-put widget :glyph-up glyph)
 770     (when down (widget-put widget :glyph-down down))
 771     (when inactive (widget-put widget :glyph-inactive inactive))))
 772
 773 ;;; Buttons.
 774
 775 (defgroup widget-button nil
 776   "The look of various kinds of buttons."
 777   :group 'widgets)
 778
 779 (defcustom widget-button-prefix ""
 780   "String used as prefix for buttons."
 781   :type 'string
 782   :group 'widget-button)
 783
 784 (defcustom widget-button-suffix ""
 785   "String used as suffix for buttons."
 786   :type 'string
 787   :group 'widget-button)
 788
 789 ;;; Creating Widgets.
 790
 791 ;;;###autoload
 792 (defun widget-create (type &rest args)
 793   "Create widget of TYPE.
 794 The optional ARGS are additional keyword arguments."
 795   (let ((widget (apply 'widget-convert type args)))
 796     (widget-apply widget :create)
 797     widget))
 798
 799 (defun widget-create-child-and-convert (parent type &rest args)
 800   "As part of the widget PARENT, create a child widget TYPE.
 801 The child is converted, using the keyword arguments ARGS."
 802   (let ((widget (apply 'widget-convert type args)))
 803     (widget-put widget :parent parent)
 804     (unless (widget-get widget :indent)
 805       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 806                                     (or (widget-get widget :extra-offset) 0)
 807                                     (widget-get parent :offset))))
 808     (widget-apply widget :create)
 809     widget))
 810
 811 (defun widget-create-child (parent type)
 812   "Create widget of TYPE."
 813   (let ((widget (copy-sequence type)))
 814     (widget-put widget :parent parent)
 815     (unless (widget-get widget :indent)
 816       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 817                                     (or (widget-get widget :extra-offset) 0)
 818                                     (widget-get parent :offset))))
 819     (widget-apply widget :create)
 820     widget))
 821
 822 (defun widget-create-child-value (parent type value)
 823   "Create widget of TYPE with value VALUE."
 824   (let ((widget (copy-sequence type)))
 825     (widget-put widget :value (widget-apply widget :value-to-internal value))
 826     (widget-put widget :parent parent)
 827     (unless (widget-get widget :indent)
 828       (widget-put widget :indent (+ (or (widget-get parent :indent) 0)
 829                                     (or (widget-get widget :extra-offset) 0)
 830                                     (widget-get parent :offset))))
 831     (widget-apply widget :create)
 832     widget))
 833
 834 ;;;###autoload
 835 (defun widget-delete (widget)
 836   "Delete WIDGET."
 837   (widget-apply widget :delete))
 838
 839 (defun widget-convert (type &rest args)
 840   "Convert TYPE to a widget without inserting it in the buffer.
 841 The optional ARGS are additional keyword arguments."
 842   ;; Don't touch the type.
 843   (let* ((widget (if (symbolp type)
 844                      (list type)
 845                    (copy-sequence type)))
 846          (current widget)
 847          (keys args))
 848     ;; First set the :args keyword.
 849     (while (cdr current)                ;Look in the type.
 850       (let ((next (car (cdr current))))
 851         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 852             (setq current (cdr (cdr current)))
 853           (setcdr current (list :args (cdr current)))
 854           (setq current nil))))
 855     (while args                         ;Look in the args.
 856       (let ((next (nth 0 args)))
 857         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 858             (setq args (nthcdr 2 args))
 859           (widget-put widget :args args)
 860           (setq args nil))))
 861     ;; Then Convert the widget.
 862     (setq type widget)
 863     (while type
 864       (let ((convert-widget (plist-get (cdr type) :convert-widget)))
 865         (if convert-widget
 866             (setq widget (funcall convert-widget widget))))
 867       (setq type (get (car type) 'widget-type)))
 868     ;; Finally set the keyword args.
 869     (while keys
 870       (let ((next (nth 0 keys)))
 871         (if (and (symbolp next) (eq (aref (symbol-name next) 0) ?:))
 872             (progn
 873               (widget-put widget next (nth 1 keys))
 874               (setq keys (nthcdr 2 keys)))
 875           (setq keys nil))))
 876     ;; Convert the :value to internal format.
 877     (if (widget-member widget :value)
 878         (let ((value (widget-get widget :value)))
 879           (widget-put widget
 880                       :value (widget-apply widget :value-to-internal value))))
 881     ;; Return the newly create widget.
 882     widget))
 883
 884 (defun widget-insert (&rest args)
 885   "Call `insert' with ARGS and make the text read only."
 886   (let ((inhibit-read-only t)
 887         before-change-functions
 888         after-change-functions
 889         (from (point)))
 890     (apply 'insert args)
 891     (widget-specify-text from (point))))
 892
 893 (defun widget-convert-text (type from to
 894                                  &optional button-from button-to
 895                                  &rest args)
 896   "Return a widget of type TYPE with endpoint FROM TO.
 897 Optional ARGS are extra keyword arguments for TYPE.
 898 and TO will be used as the widgets end points. If optional arguments
 899 BUTTON-FROM and BUTTON-TO are given, these will be used as the widgets
 900 button end points.
 901 Optional ARGS are extra keyword arguments for TYPE."
 902   (let ((widget (apply 'widget-convert type :delete 'widget-leave-text args))
 903         (from (copy-marker from))
 904         (to (copy-marker to)))
 905     (widget-specify-text from to)
 906     (set-marker-insertion-type from t)
 907     (set-marker-insertion-type to nil)
 908     (widget-put widget :from from)
 909     (widget-put widget :to to)
 910     (when button-from
 911       (widget-specify-button widget button-from button-to))
 912     widget))
 913
 914 (defun widget-convert-button (type from to &rest args)
 915   "Return a widget of type TYPE with endpoint FROM TO.
 916 Optional ARGS are extra keyword arguments for TYPE.
 917 No text will be inserted to the buffer, instead the text between FROM
 918 and TO will be used as the widgets end points, as well as the widgets
 919 button end points."
 920   (apply 'widget-convert-text type from to from to args))
 921
 922 (defun widget-leave-text (widget)
 923   "Remove markers and overlays from WIDGET and its children."
 924   (let ((from (widget-get widget :from))
 925         (to (widget-get widget :to))
 926         (button (widget-get widget :button-overlay))
 927         (sample (widget-get widget :sample-overlay))
 928         (field (widget-get widget :field-overlay))
 929         (children (widget-get widget :children)))
 930     (set-marker from nil)
 931     (set-marker to nil)
 932     (when button
 933       (delete-overlay button))
 934     (when sample
 935       (delete-overlay sample))
 936     (when field
 937       (delete-overlay field))
 938     (mapcar 'widget-leave-text children)))
 939
 940 ;;; Keymap and Commands.
 941
 942 (defvar widget-keymap nil
 943   "Keymap containing useful binding for buffers containing widgets.
 944 Recommended as a parent keymap for modes using widgets.")
 945
 946 (unless widget-keymap
 947   (setq widget-keymap (make-sparse-keymap))
 948   (define-key widget-keymap "\t" 'widget-forward)
 949   (define-key widget-keymap [(shift tab)] 'widget-backward)
 950   (define-key widget-keymap [backtab] 'widget-backward)
 951   (if (string-match "XEmacs" emacs-version)
 952       (progn
 953         ;;Glyph support.
 954         (define-key widget-keymap [button1] 'widget-button1-click)
 955         (define-key widget-keymap [button2] 'widget-button-click))
 956     (define-key widget-keymap [down-mouse-2] 'widget-button-click))
 957   (define-key widget-keymap "\C-m" 'widget-button-press))
 958
 959 (defvar widget-global-map global-map
 960   "Keymap used for events the widget does not handle themselves.")
 961 (make-variable-buffer-local 'widget-global-map)
 962
 963 (defvar widget-field-keymap nil
 964   "Keymap used inside an editable field.")
 965
 966 (unless widget-field-keymap
 967   (setq widget-field-keymap (copy-keymap widget-keymap))
 968   (unless (string-match "XEmacs" (emacs-version))
 969     (define-key widget-field-keymap [menu-bar] 'nil))
 970   (define-key widget-field-keymap "\C-k" 'widget-kill-line)
 971   (define-key widget-field-keymap "\M-\t" 'widget-complete)
 972   (define-key widget-field-keymap "\C-m" 'widget-field-activate)
 973   (define-key widget-field-keymap "\C-a" 'widget-beginning-of-line)
 974   (define-key widget-field-keymap "\C-e" 'widget-end-of-line)
 975   (set-keymap-parent widget-field-keymap global-map))
 976
 977 (defvar widget-text-keymap nil
 978   "Keymap used inside a text field.")
 979
 980 (unless widget-text-keymap
 981   (setq widget-text-keymap (copy-keymap widget-keymap))
 982   (unless (string-match "XEmacs" (emacs-version))
 983     (define-key widget-text-keymap [menu-bar] 'nil))
 984   (define-key widget-text-keymap "\C-a" 'widget-beginning-of-line)
 985   (define-key widget-text-keymap "\C-e" 'widget-end-of-line)
 986   (set-keymap-parent widget-text-keymap global-map))
 987
 988 (defun widget-field-activate (pos &optional event)
 989   "Invoke the ediable field at point."
 990   (interactive "@d")
 991   (let ((field (get-char-property pos 'field)))
 992     (if field
 993         (widget-apply-action field event)
 994       (call-interactively
 995        (lookup-key widget-global-map (this-command-keys))))))
 996
 997 (defface widget-button-pressed-face
 998   '((((class color))
 999      (:foreground "red"))
1000     (t
1001      (:bold t :underline t)))
1002   "Face used for pressed buttons."
1003   :group 'widget-faces)
1004
1005 (defun widget-button-click (event)
1006   "Invoke button below mouse pointer."
1007   (interactive "@e")
1008   (cond ((and (fboundp 'event-glyph)
1009               (event-glyph event))
1010          (widget-glyph-click event))
1011         ((widget-event-point event)
1012          (let* ((pos (widget-event-point event))
1013                 (button (get-char-property pos 'button)))
1014            (if button
1015                (let* ((overlay (widget-get button :button-overlay))
1016                       (face (overlay-get overlay 'face))
1017                       (mouse-face (overlay-get overlay 'mouse-face)))
1018                  (unwind-protect
1019                      (let ((track-mouse t))
1020                        (overlay-put overlay
1021                                     'face 'widget-button-pressed-face)
1022                        (overlay-put overlay
1023                                     'mouse-face 'widget-button-pressed-face)
1024                        (unless (widget-apply button :mouse-down-action event)
1025                          (while (not (button-release-event-p event))
1026                            (setq event (widget-read-event)
1027                                  pos (widget-event-point event))
1028                            (if (and pos
1029                                     (eq (get-char-property pos 'button)
1030                                         button))
1031                                (progn
1032                                  (overlay-put overlay
1033                                               'face
1034                                               'widget-button-pressed-face)
1035                                  (overlay-put overlay
1036                                               'mouse-face
1037                                               'widget-button-pressed-face))
1038                              (overlay-put overlay 'face face)
1039                              (overlay-put overlay 'mouse-face mouse-face))))
1040                        (when (and pos
1041                                   (eq (get-char-property pos 'button) button))
1042                          (widget-apply-action button event)))
1043                    (overlay-put overlay 'face face)
1044                    (overlay-put overlay 'mouse-face mouse-face)))
1045              (let ((up t)
1046                    command)
1047                ;; Find the global command to run, and check whether it
1048                ;; is bound to an up event.
1049                (cond ((setq command     ;down event
1050                             (lookup-key widget-global-map [ button2 ]))
1051                       (setq up nil))
1052                      ((setq command     ;down event
1053                             (lookup-key widget-global-map [ down-mouse-2 ]))
1054                       (setq up nil))
1055                      ((setq command     ;up event
1056                             (lookup-key widget-global-map [ button2up ])))
1057                      ((setq command     ;up event
1058                             (lookup-key widget-global-map [ mouse-2]))))
1059                (when up
1060                  ;; Don't execute up events twice.
1061                  (while (not (button-release-event-p event))
1062                    (setq event (widget-read-event))))
1063                (when command
1064                  (call-interactively command))))))
1065         (t
1066          (message "You clicked somewhere weird."))))
1067
1068 (defun widget-button1-click (event)
1069   "Invoke glyph below mouse pointer."
1070   (interactive "@e")
1071   (if (and (fboundp 'event-glyph)
1072            (event-glyph event))
1073       (widget-glyph-click event)
1074     (call-interactively (lookup-key widget-global-map (this-command-keys)))))
1075
1076 (defun widget-glyph-click (event)
1077   "Handle click on a glyph."
1078   (let* ((glyph (event-glyph event))
1079          (widget (glyph-property glyph 'widget))
1080          (extent (event-glyph-extent event))
1081          (down-glyph (or (and widget (widget-get widget :glyph-down)) glyph))
1082          (up-glyph (or (and widget (widget-get widget :glyph-up)) glyph))
1083          (last event))
1084     ;; Wait for the release.
1085     (while (not (button-release-event-p last))
1086       (if (eq extent (event-glyph-extent last))
1087           (set-extent-property extent 'end-glyph down-glyph)
1088         (set-extent-property extent 'end-glyph up-glyph))
1089       (setq last (next-event event)))
1090     ;; Release glyph.
1091     (when down-glyph
1092       (set-extent-property extent 'end-glyph up-glyph))
1093     ;; Apply widget action.
1094     (when (eq extent (event-glyph-extent last))
1095       (let ((widget (glyph-property (event-glyph event) 'widget)))
1096         (cond ((null widget)
1097                (message "You clicked on a glyph."))
1098               ((not (widget-apply widget :active))
1099                (message "This glyph is inactive."))
1100               (t
1101                (widget-apply-action widget event)))))))
1102
1103 (defun widget-button-press (pos &optional event)
1104   "Invoke button at POS."
1105   (interactive "@d")
1106   (let ((button (get-char-property pos 'button)))
1107     (if button
1108         (widget-apply-action button event)
1109       (let ((command (lookup-key widget-global-map (this-command-keys))))
1110         (when (commandp command)
1111           (call-interactively command))))))
1112
1113 (defun widget-tabable-at (&optional pos)
1114   "Return the tabable widget at POS, or nil.
1115 POS defaults to the value of (point)."
1116   (unless pos
1117     (setq pos (point)))
1118   (let ((widget (or (get-char-property (point) 'button)
1119                     (get-char-property (point) 'field))))
1120     (if widget
1121         (let ((order (widget-get widget :tab-order)))
1122           (if order
1123               (if (>= order 0)
1124                   widget
1125                 nil)
1126             widget))
1127       nil)))
1128
1129 (defun widget-move (arg)
1130   "Move point to the ARG next field or button.
1131 ARG may be negative to move backward."
1132   (or (bobp) (> arg 0) (backward-char))
1133   (let ((pos (point))
1134         (number arg)
1135         (old (widget-tabable-at))
1136         new)
1137     ;; Forward.
1138     (while (> arg 0)
1139       (if (eobp)
1140           (goto-char (point-min))
1141         (forward-char 1))
1142       (and (eq pos (point))
1143            (eq arg number)
1144            (error "No buttons or fields found"))
1145       (let ((new (widget-tabable-at)))
1146         (when new
1147           (unless (eq new old)
1148             (setq arg (1- arg))
1149             (setq old new)))))
1150     ;; Backward.
1151     (while (< arg 0)
1152       (if (bobp)
1153           (goto-char (point-max))
1154         (backward-char 1))
1155       (and (eq pos (point))
1156            (eq arg number)
1157            (error "No buttons or fields found"))
1158       (let ((new (widget-tabable-at)))
1159         (when new
1160           (unless (eq new old)
1161             (setq arg (1+ arg))))))
1162     (let ((new (widget-tabable-at)))
1163       (while (eq (widget-tabable-at) new)
1164         (backward-char)))
1165     (forward-char))
1166   (widget-echo-help (point))
1167   (run-hooks 'widget-move-hook))
1168
1169 (defun widget-forward (arg)
1170   "Move point to the next field or button.
1171 With optional ARG, move across that many fields."
1172   (interactive "p")
1173   (run-hooks 'widget-forward-hook)
1174   (widget-move arg))
1175
1176 (defun widget-backward (arg)
1177   "Move point to the previous field or button.
1178 With optional ARG, move across that many fields."
1179   (interactive "p")
1180   (run-hooks 'widget-backward-hook)
1181   (widget-move (- arg)))
1182
1183 (defun widget-beginning-of-line ()
1184   "Go to beginning of field or beginning of line, whichever is first."
1185   (interactive)
1186   (let* ((field (widget-field-find (point)))
1187          (start (and field (widget-field-start field))))
1188     (if (and start (not (eq start (point))))
1189         (goto-char start)
1190       (call-interactively 'beginning-of-line))))
1191
1192 (defun widget-end-of-line ()
1193   "Go to end of field or end of line, whichever is first."
1194   (interactive)
1195   (let* ((field (widget-field-find (point)))
1196          (end (and field (widget-field-end field))))
1197     (if (and end (not (eq end (point))))
1198         (goto-char end)
1199       (call-interactively 'end-of-line))))
1200
1201 (defun widget-kill-line ()
1202   "Kill to end of field or end of line, whichever is first."
1203   (interactive)
1204   (let* ((field (widget-field-find (point)))
1205          (newline (save-excursion (forward-line 1) (point)))
1206          (end (and field (widget-field-end field))))
1207     (if (and field (> newline end))
1208         (kill-region (point) end)
1209       (call-interactively 'kill-line))))
1210
1211 (defcustom widget-complete-field (lookup-key global-map "\M-\t")
1212   "Default function to call for completion inside fields."
1213   :options '(ispell-complete-word complete-tag lisp-complete-symbol)
1214   :type 'function
1215   :group 'widgets)
1216
1217 (defun widget-complete ()
1218   "Complete content of editable field from point.
1219 When not inside a field, move to the previous button or field."
1220   (interactive)
1221   (let ((field (widget-field-find (point))))
1222     (if field
1223         (widget-apply field :complete)
1224       (error "Not in an editable field"))))
1225
1226 ;;; Setting up the buffer.
1227
1228 (defvar widget-field-new nil)
1229 ;; List of all newly created editable fields in the buffer.
1230 (make-variable-buffer-local 'widget-field-new)
1231
1232 (defvar widget-field-list nil)
1233 ;; List of all editable fields in the buffer.
1234 (make-variable-buffer-local 'widget-field-list)
1235
1236 (defun widget-setup ()
1237   "Setup current buffer so editing string widgets works."
1238   (let ((inhibit-read-only t)
1239         (after-change-functions nil)
1240         before-change-functions
1241         field)
1242     (while widget-field-new
1243       (setq field (car widget-field-new)
1244             widget-field-new (cdr widget-field-new)
1245             widget-field-list (cons field widget-field-list))
1246       (let ((from (car (widget-get field :field-overlay)))
1247             (to (cdr (widget-get field :field-overlay))))
1248         (widget-specify-field field
1249                               (marker-position from) (marker-position to))
1250         (set-marker from nil)
1251         (set-marker to nil))))
1252   (widget-clear-undo)
1253   ;; We need to maintain text properties and size of the editing fields.
1254   (make-local-variable 'after-change-functions)
1255   (setq after-change-functions
1256         (if widget-field-list '(widget-after-change) nil))
1257   (when widget-field-use-before-change
1258     (make-local-variable 'before-change-functions)
1259     (setq before-change-functions
1260           (if widget-field-list '(widget-before-change) nil))))
1261
1262 (defvar widget-field-last nil)
1263 ;; Last field containing point.
1264 (make-variable-buffer-local 'widget-field-last)
1265
1266 (defvar widget-field-was nil)
1267 ;; The widget data before the change.
1268 (make-variable-buffer-local 'widget-field-was)
1269
1270 (defun widget-field-buffer (widget)
1271   "Return the start of WIDGET's editing field."
1272   (let ((overlay (widget-get widget :field-overlay)))
1273     (and overlay (overlay-buffer overlay))))
1274
1275 (defun widget-field-start (widget)
1276   "Return the start of WIDGET's editing field."
1277   (let ((overlay (widget-get widget :field-overlay)))
1278     (and overlay (overlay-start overlay))))
1279
1280 (defun widget-field-end (widget)
1281   "Return the end of WIDGET's editing field."
1282   (let ((overlay (widget-get widget :field-overlay)))
1283     ;; Don't subtract one if local-map works at the end of the overlay.
1284     (and overlay (if (or widget-field-add-space
1285                          (null (widget-get widget :size)))
1286                      (1- (overlay-end overlay))
1287                    (overlay-end overlay)))))
1288
1289 (defun widget-field-find (pos)
1290   "Return the field at POS.
1291 Unlike (get-char-property POS 'field) this, works with empty fields too."
1292   (let ((fields widget-field-list)
1293         field found)
1294     (while fields
1295       (setq field (car fields)
1296             fields (cdr fields))
1297       (let ((start (widget-field-start field))
1298             (end (widget-field-end field)))
1299         (when (and (<= start pos) (<= pos end))
1300           (when found
1301             (debug "Overlapping fields"))
1302           (setq found field))))
1303     found))
1304
1305 (defun widget-before-change (from &rest ignore)
1306   ;; This is how, for example, a variable changes its state to `modified'.
1307   ;; when it is being edited.
1308   (condition-case nil
1309       (let ((field (widget-field-find from)))
1310         (widget-apply field :notify field))
1311     (error (debug "Before Change"))))
1312
1313 (defun widget-after-change (from to old)
1314   ;; Adjust field size and text properties.
1315   (condition-case nil
1316       (let ((field (widget-field-find from))
1317             (other (widget-field-find to)))
1318         (when field
1319           (unless (eq field other)
1320             (debug "Change in different fields"))
1321           (let ((size (widget-get field :size))
1322                 (secret (widget-get field :secret)))
1323             (when size
1324               (let ((begin (widget-field-start field))
1325                     (end (widget-field-end field)))
1326                 (cond ((< (- end begin) size)
1327                        ;; Field too small.
1328                        (save-excursion
1329                          (goto-char end)
1330                          (insert-char ?\  (- (+ begin size) end))))
1331                       ((> (- end begin) size)
1332                        ;; Field too large and
1333                        (if (or (< (point) (+ begin size))
1334                                (> (point) end))
1335                            ;; Point is outside extra space.
1336                            (setq begin (+ begin size))
1337                          ;; Point is within the extra space.
1338                          (setq begin (point)))
1339                        (save-excursion
1340                          (goto-char end)
1341                          (while (and (eq (preceding-char) ?\ )
1342                                      (> (point) begin))
1343                            (delete-backward-char 1)))))))
1344             (when secret
1345               (let ((begin (widget-field-start field))
1346                     (end (widget-field-end field)))
1347                 (when size
1348                   (while (and (> end begin)
1349                               (eq (char-after (1- end)) ?\ ))
1350                     (setq end (1- end))))
1351                 (while (< begin end)
1352                   (let ((old (char-after begin)))
1353                     (unless (eq old secret)
1354                       (subst-char-in-region begin (1+ begin) old secret)
1355                       (put-text-property begin (1+ begin) 'secret old))
1356                     (setq begin (1+ begin)))))))
1357           (widget-apply field :notify field)))
1358     (error (debug "After Change"))))
1359
1360 ;;; Widget Functions
1361 ;;
1362 ;; These functions are used in the definition of multiple widgets.
1363
1364 (defun widget-parent-action (widget &optional event)
1365   "Tell :parent of WIDGET to handle the :action.
1366 Optional EVENT is the event that triggered the action."
1367   (widget-apply (widget-get widget :parent) :action event))
1368
1369 (defun widget-children-value-delete (widget)
1370   "Delete all :children and :buttons in WIDGET."
1371   (mapcar 'widget-delete (widget-get widget :children))
1372   (widget-put widget :children nil)
1373   (mapcar 'widget-delete (widget-get widget :buttons))
1374   (widget-put widget :buttons nil))
1375
1376 (defun widget-children-validate (widget)
1377   "All the :children must be valid."
1378   (let ((children (widget-get widget :children))
1379         child found)
1380     (while (and children (not found))
1381       (setq child (car children)
1382             children (cdr children)
1383             found (widget-apply child :validate)))
1384     found))
1385
1386 (defun widget-types-convert-widget (widget)
1387   "Convert :args as widget types in WIDGET."
1388   (widget-put widget :args (mapcar 'widget-convert (widget-get widget :args)))
1389   widget)
1390
1391 (defun widget-value-convert-widget (widget)
1392   "Initialize :value from :args in WIDGET."
1393   (let ((args (widget-get widget :args)))
1394     (when args
1395       (widget-put widget :value (car args))
1396       ;; Don't convert :value here, as this is done in `widget-convert'.
1397       ;; (widget-put widget :value (widget-apply widget
1398       ;;                                      :value-to-internal (car args)))
1399       (widget-put widget :args nil)))
1400   widget)
1401
1402 (defun widget-value-value-get (widget)
1403   "Return the :value property of WIDGET."
1404   (widget-get widget :value))
1405
1406 ;;; The `default' Widget.
1407
1408 (define-widget 'default nil
1409   "Basic widget other widgets are derived from."
1410   :value-to-internal (lambda (widget value) value)
1411   :value-to-external (lambda (widget value) value)
1412   :button-prefix 'widget-button-prefix
1413   :button-suffix 'widget-button-suffix
1414   :complete 'widget-default-complete
1415   :create 'widget-default-create
1416   :indent nil
1417   :offset 0
1418   :format-handler 'widget-default-format-handler
1419   :button-face-get 'widget-default-button-face-get
1420   :sample-face-get 'widget-default-sample-face-get
1421   :delete 'widget-default-delete
1422   :value-set 'widget-default-value-set
1423   :value-inline 'widget-default-value-inline
1424   :menu-tag-get 'widget-default-menu-tag-get
1425   :validate (lambda (widget) nil)
1426   :active 'widget-default-active
1427   :activate 'widget-specify-active
1428   :deactivate 'widget-default-deactivate
1429   :mouse-down-action (lambda (widget event) nil)
1430   :action 'widget-default-action
1431   :notify 'widget-default-notify
1432   :prompt-value 'widget-default-prompt-value)
1433
1434 (defun widget-default-complete (widget)
1435   "Call the value of the :complete-function property of WIDGET.
1436 If that does not exists, call the value of `widget-complete-field'."
1437   (let ((fun (widget-get widget :complete-function)))
1438     (call-interactively (or fun widget-complete-field))))
1439
1440 (defun widget-default-create (widget)
1441   "Create WIDGET at point in the current buffer."
1442   (widget-specify-insert
1443    (let ((from (point))
1444          button-begin button-end
1445          sample-begin sample-end
1446          doc-begin doc-end
1447          value-pos)
1448      (insert (widget-get widget :format))
1449      (goto-char from)
1450      ;; Parse escapes in format.
1451      (while (re-search-forward "%\\(.\\)" nil t)
1452        (let ((escape (aref (match-string 1) 0)))
1453          (replace-match "" t t)
1454          (cond ((eq escape ?%)
1455                 (insert "%"))
1456                ((eq escape ?\[)
1457                 (setq button-begin (point))
1458                 (insert (widget-get-indirect widget :button-prefix)))
1459                ((eq escape ?\])
1460                 (insert (widget-get-indirect widget :button-suffix))
1461                 (setq button-end (point)))
1462                ((eq escape ?\{)
1463                 (setq sample-begin (point)))
1464                ((eq escape ?\})
1465                 (setq sample-end (point)))
1466                ((eq escape ?n)
1467                 (when (widget-get widget :indent)
1468                   (insert "\n")
1469                   (insert-char ?  (widget-get widget :indent))))
1470                ((eq escape ?t)
1471                 (let ((glyph (widget-get widget :tag-glyph))
1472                       (tag (widget-get widget :tag)))
1473                   (cond (glyph
1474                          (widget-glyph-insert widget (or tag "image") glyph))
1475                         (tag
1476                          (insert tag))
1477                         (t
1478                          (let ((standard-output (current-buffer)))
1479                            (princ (widget-get widget :value)))))))
1480                ((eq escape ?d)
1481                 (let ((doc (widget-get widget :doc)))
1482                   (when doc
1483                     (setq doc-begin (point))
1484                     (insert doc)
1485                     (while (eq (preceding-char) ?\n)
1486                       (delete-backward-char 1))
1487                     (insert "\n")
1488                     (setq doc-end (point)))))
1489                ((eq escape ?v)
1490                 (if (and button-begin (not button-end))
1491                     (widget-apply widget :value-create)
1492                   (setq value-pos (point))))
1493                (t
1494                 (widget-apply widget :format-handler escape)))))
1495      ;; Specify button, sample, and doc, and insert value.
1496      (and button-begin button-end
1497           (widget-specify-button widget button-begin button-end))
1498      (and sample-begin sample-end
1499           (widget-specify-sample widget sample-begin sample-end))
1500      (and doc-begin doc-end
1501           (widget-specify-doc widget doc-begin doc-end))
1502      (when value-pos
1503        (goto-char value-pos)
1504        (widget-apply widget :value-create)))
1505    (let ((from (copy-marker (point-min)))
1506          (to (copy-marker (point-max))))
1507      (widget-specify-text from to)
1508      (set-marker-insertion-type from t)
1509      (set-marker-insertion-type to nil)
1510      (widget-put widget :from from)
1511      (widget-put widget :to to)))
1512   (widget-clear-undo))
1513
1514 (defun widget-default-format-handler (widget escape)
1515   ;; We recognize the %h escape by default.
1516   (let* ((buttons (widget-get widget :buttons)))
1517     (cond ((eq escape ?h)
1518            (let* ((doc-property (widget-get widget :documentation-property))
1519                   (doc-try (cond ((widget-get widget :doc))
1520                                  ((symbolp doc-property)
1521                                   (documentation-property
1522                                    (widget-get widget :value)
1523                                    doc-property))
1524                                  (t
1525                                   (funcall doc-property
1526                                            (widget-get widget :value)))))
1527                   (doc-text (and (stringp doc-try)
1528                                  (> (length doc-try) 1)
1529                                  doc-try))
1530                   (doc-indent (widget-get widget :documentation-indent)))
1531              (when doc-text
1532                (and (eq (preceding-char) ?\n)
1533                     (widget-get widget :indent)
1534                     (insert-char ?  (widget-get widget :indent)))
1535                ;; The `*' in the beginning is redundant.
1536                (when (eq (aref doc-text  0) ?*)
1537                  (setq doc-text (substring doc-text 1)))
1538                ;; Get rid of trailing newlines.
1539                (when (string-match "\n+\\'" doc-text)
1540                  (setq doc-text (substring doc-text 0 (match-beginning 0))))
1541                (push (widget-create-child-and-convert
1542                       widget 'documentation-string
1543                       :indent (cond ((numberp doc-indent )
1544                                      doc-indent)
1545                                     ((null doc-indent)
1546                                      nil)
1547                                     (t 0))
1548                       doc-text)
1549                      buttons))))
1550           (t
1551            (error "Unknown escape `%c'" escape)))
1552     (widget-put widget :buttons buttons)))
1553
1554 (defun widget-default-button-face-get (widget)
1555   ;; Use :button-face or widget-button-face
1556   (or (widget-get widget :button-face)
1557       (let ((parent (widget-get widget :parent)))
1558         (if parent
1559             (widget-apply parent :button-face-get)
1560           widget-button-face))))
1561
1562 (defun widget-default-sample-face-get (widget)
1563   ;; Use :sample-face.
1564   (widget-get widget :sample-face))
1565
1566 (defun widget-default-delete (widget)
1567   ;; Remove widget from the buffer.
1568   (let ((from (widget-get widget :from))
1569         (to (widget-get widget :to))
1570         (inactive-overlay (widget-get widget :inactive))
1571         (button-overlay (widget-get widget :button-overlay))
1572         (sample-overlay (widget-get widget :sample-overlay))
1573         before-change-functions
1574         after-change-functions
1575         (inhibit-read-only t))
1576     (widget-apply widget :value-delete)
1577     (when inactive-overlay
1578       (delete-overlay inactive-overlay))
1579     (when button-overlay
1580       (delete-overlay button-overlay))
1581     (when sample-overlay
1582       (delete-overlay sample-overlay))
1583     (when (< from to)
1584       ;; Kludge: this doesn't need to be true for empty formats.
1585       (delete-region from to))
1586     (set-marker from nil)
1587     (set-marker to nil))
1588   (widget-clear-undo))
1589
1590 (defun widget-default-value-set (widget value)
1591   ;; Recreate widget with new value.
1592   (let* ((old-pos (point))
1593          (from (copy-marker (widget-get widget :from)))
1594          (to (copy-marker (widget-get widget :to)))
1595          (offset (if (and (<= from old-pos) (<= old-pos to))
1596                      (if (>= old-pos (1- to))
1597                          (- old-pos to 1)
1598                        (- old-pos from)))))
1599     ;;??? Bug: this ought to insert the new value before deleting the old one,
1600     ;; so that markers on either side of the value automatically
1601     ;; stay on the same side.  -- rms.
1602     (save-excursion
1603       (goto-char (widget-get widget :from))
1604       (widget-apply widget :delete)
1605       (widget-put widget :value value)
1606       (widget-apply widget :create))
1607     (if offset
1608         (if (< offset 0)
1609             (goto-char (+ (widget-get widget :to) offset 1))
1610           (goto-char (min (+ from offset) (1- (widget-get widget :to))))))))
1611
1612 (defun widget-default-value-inline (widget)
1613   ;; Wrap value in a list unless it is inline.
1614   (if (widget-get widget :inline)
1615       (widget-value widget)
1616     (list (widget-value widget))))
1617
1618 (defun widget-default-menu-tag-get (widget)
1619   ;; Use tag or value for menus.
1620   (or (widget-get widget :menu-tag)
1621       (widget-get widget :tag)
1622       (widget-princ-to-string (widget-get widget :value))))
1623
1624 (defun widget-default-active (widget)
1625   "Return t iff this widget active (user modifiable)."
1626   (and (not (widget-get widget :inactive))
1627        (let ((parent (widget-get widget :parent)))
1628          (or (null parent)
1629              (widget-apply parent :active)))))
1630
1631 (defun widget-default-deactivate (widget)
1632   "Make WIDGET inactive for user modifications."
1633   (widget-specify-inactive widget
1634                            (widget-get widget :from)
1635                            (widget-get widget :to)))
1636
1637 (defun widget-default-action (widget &optional event)
1638   ;; Notify the parent when a widget change
1639   (let ((parent (widget-get widget :parent)))
1640     (when parent
1641       (widget-apply parent :notify widget event))))
1642
1643 (defun widget-default-notify (widget child &optional event)
1644   ;; Pass notification to parent.
1645   (widget-default-action widget event))
1646
1647 (defun widget-default-prompt-value (widget prompt value unbound)
1648   ;; Read an arbitrary value.  Stolen from `set-variable'.
1649 ;;  (let ((initial (if unbound
1650 ;;                   nil
1651 ;;                 ;; It would be nice if we could do a `(cons val 1)' here.
1652 ;;                 (prin1-to-string (custom-quote value))))))
1653   (eval-minibuffer prompt ))
1654
1655 ;;; The `item' Widget.
1656
1657 (define-widget 'item 'default
1658   "Constant items for inclusion in other widgets."
1659   :convert-widget 'widget-value-convert-widget
1660   :value-create 'widget-item-value-create
1661   :value-delete 'ignore
1662   :value-get 'widget-value-value-get
1663   :match 'widget-item-match
1664   :match-inline 'widget-item-match-inline
1665   :action 'widget-item-action
1666   :format "%t\n")
1667
1668 (defun widget-item-value-create (widget)
1669   ;; Insert the printed representation of the value.
1670   (let ((standard-output (current-buffer)))
1671     (princ (widget-get widget :value))))
1672
1673 (defun widget-item-match (widget value)
1674   ;; Match if the value is the same.
1675   (equal (widget-get widget :value) value))
1676
1677 (defun widget-item-match-inline (widget values)
1678   ;; Match if the value is the same.
1679   (let ((value (widget-get widget :value)))
1680     (and (listp value)
1681          (<= (length value) (length values))
1682          (let ((head (widget-sublist values 0 (length value))))
1683            (and (equal head value)
1684                 (cons head (widget-sublist values (length value))))))))
1685
1686 (defun widget-sublist (list start &optional end)
1687   "Return the sublist of LIST from START to END.
1688 If END is omitted, it defaults to the length of LIST."
1689   (if (> start 0) (setq list (nthcdr start list)))
1690   (if end
1691       (if (<= end start)
1692           nil
1693         (setq list (copy-sequence list))
1694         (setcdr (nthcdr (- end start 1) list) nil)
1695         list)
1696     (copy-sequence list)))
1697
1698 (defun widget-item-action (widget &optional event)
1699   ;; Just notify itself.
1700   (widget-apply widget :notify widget event))
1701
1702 ;;; The `push-button' Widget.
1703
1704 (defcustom widget-push-button-gui t
1705   "If non nil, use GUI push buttons when available."
1706   :group 'widgets
1707   :type 'boolean)
1708
1709 ;; Cache already created GUI objects.
1710 (defvar widget-push-button-cache nil)
1711
1712 (defcustom widget-push-button-prefix "["
1713   "String used as prefix for buttons."
1714   :type 'string
1715   :group 'widget-button)
1716
1717 (defcustom widget-push-button-suffix "]"
1718   "String used as suffix for buttons."
1719   :type 'string
1720   :group 'widget-button)
1721
1722 (define-widget 'push-button 'item
1723   "A pushable button."
1724   :button-prefix ""
1725   :button-suffix ""
1726   :value-create 'widget-push-button-value-create
1727   :format "%[%v%]")
1728
1729 (defun widget-push-button-value-create (widget)
1730   ;; Insert text representing the `on' and `off' states.
1731   (let* ((tag (or (widget-get widget :tag)
1732                   (widget-get widget :value)))
1733          (tag-glyph (widget-get widget :tag-glyph))
1734          (text (concat widget-push-button-prefix
1735                        tag widget-push-button-suffix))
1736          (gui (cdr (assoc tag widget-push-button-cache))))
1737     (cond (tag-glyph
1738            (widget-glyph-insert widget text tag-glyph))
1739           ((and (fboundp 'make-gui-button)
1740              (fboundp 'make-glyph)
1741              widget-push-button-gui
1742              (fboundp 'device-on-window-system-p)
1743              (device-on-window-system-p)
1744              (string-match "XEmacs" emacs-version))
1745            (unless gui
1746              (setq gui (make-gui-button tag 'widget-gui-action widget))
1747              (push (cons tag gui) widget-push-button-cache))
1748            (widget-glyph-insert-glyph widget
1749                                       (make-glyph
1750                                        (list (nth 0 (aref gui 1))
1751                                              (vector 'string ':data text)))
1752                                       (make-glyph
1753                                        (list (nth 1 (aref gui 1))
1754                                              (vector 'string ':data text)))
1755                                       (make-glyph
1756                                        (list (nth 2 (aref gui 1))
1757                                              (vector 'string ':data text)))))
1758           (t
1759            (insert text)))))
1760
1761 (defun widget-gui-action (widget)
1762   "Apply :action for WIDGET."
1763   (widget-apply-action widget (this-command-keys)))
1764
1765 ;;; The `link' Widget.
1766
1767 (defcustom widget-link-prefix "["
1768   "String used as prefix for links."
1769   :type 'string
1770   :group 'widget-button)
1771
1772 (defcustom widget-link-suffix "]"
1773   "String used as suffix for links."
1774   :type 'string
1775   :group 'widget-button)
1776
1777 (define-widget 'link 'item
1778   "An embedded link."
1779   :button-prefix 'widget-link-prefix
1780   :button-suffix 'widget-link-suffix
1781   :help-echo "Follow the link."
1782   :format "%[%t%]")
1783
1784 ;;; The `info-link' Widget.
1785
1786 (define-widget 'info-link 'link
1787   "A link to an info file."
1788   :action 'widget-info-link-action)
1789
1790 (defun widget-info-link-action (widget &optional event)
1791   "Open the info node specified by WIDGET."
1792   (Info-goto-node (widget-value widget)))
1793
1794 ;;; The `url-link' Widget.
1795
1796 (define-widget 'url-link 'link
1797   "A link to an www page."
1798   :action 'widget-url-link-action)
1799
1800 (defun widget-url-link-action (widget &optional event)
1801   "Open the url specified by WIDGET."
1802   (require 'browse-url)
1803   (funcall browse-url-browser-function (widget-value widget)))
1804
1805 ;;; The `file-link' Widget.
1806
1807 (define-widget 'file-link 'link
1808   "A link to a file."
1809   :action 'widget-file-link-action)
1810
1811 (defun widget-file-link-action (widget &optional event)
1812   "Find the file specified by WIDGET."
1813   (find-file (widget-value widget)))
1814
1815 ;;; The `emacs-library-link' Widget.
1816
1817 (define-widget 'emacs-library-link 'link
1818   "A link to an Emacs Lisp library file."
1819   :action 'widget-emacs-library-link-action)
1820
1821 (defun widget-emacs-library-link-action (widget &optional event)
1822   "Find the Emacs Library file specified by WIDGET."
1823   (find-file (locate-library (widget-value widget))))
1824
1825 ;;; The `editable-field' Widget.
1826
1827 (define-widget 'editable-field 'default
1828   "An editable text field."
1829   :convert-widget 'widget-value-convert-widget
1830   :keymap widget-field-keymap
1831   :format "%v"
1832   :value ""
1833   :prompt-internal 'widget-field-prompt-internal
1834   :prompt-history 'widget-field-history
1835   :prompt-value 'widget-field-prompt-value
1836   :action 'widget-field-action
1837   :validate 'widget-field-validate
1838   :valid-regexp ""
1839   :error "No match"
1840   :value-create 'widget-field-value-create
1841   :value-delete 'widget-field-value-delete
1842   :value-get 'widget-field-value-get
1843   :match 'widget-field-match)
1844
1845 (defvar widget-field-history nil
1846   "History of field minibuffer edits.")
1847
1848 (defun widget-field-prompt-internal (widget prompt initial history)
1849   ;; Read string for WIDGET promptinhg with PROMPT.
1850   ;; INITIAL is the initial input and HISTORY is a symbol containing
1851   ;; the earlier input.
1852   (read-string prompt initial history))
1853
1854 (defun widget-field-prompt-value (widget prompt value unbound)
1855   ;; Prompt for a string.
1856   (let ((initial (if unbound
1857                      nil
1858                    (cons (widget-apply widget :value-to-internal
1859                                        value) 0)))
1860         (history (widget-get widget :prompt-history)))
1861     (let ((answer (widget-apply widget
1862                                 :prompt-internal prompt initial history)))
1863       (widget-apply widget :value-to-external answer))))
1864
1865 (defvar widget-edit-functions nil)
1866
1867 (defun widget-field-action (widget &optional event)
1868   ;; Move to next field.
1869   (widget-forward 1)
1870   (run-hook-with-args 'widget-edit-functions widget))
1871
1872 (defun widget-field-validate (widget)
1873   ;; Valid if the content matches `:valid-regexp'.
1874   (save-excursion
1875     (let ((value (widget-apply widget :value-get))
1876           (regexp (widget-get widget :valid-regexp)))
1877       (if (string-match regexp value)
1878           nil
1879         widget))))
1880
1881 (defun widget-field-value-create (widget)
1882   ;; Create an editable text field.
1883   (let ((size (widget-get widget :size))
1884         (value (widget-get widget :value))
1885         (from (point))
1886         ;; This is changed to a real overlay in `widget-setup'.  We
1887         ;; need the end points to behave differently until
1888         ;; `widget-setup' is called.
1889         (overlay (cons (make-marker) (make-marker))))
1890     (widget-put widget :field-overlay overlay)
1891     (insert value)
1892     (and size
1893          (< (length value) size)
1894          (insert-char ?\  (- size (length value))))
1895     (unless (memq widget widget-field-list)
1896       (setq widget-field-new (cons widget widget-field-new)))
1897     (move-marker (cdr overlay) (point))
1898     (set-marker-insertion-type (cdr overlay) nil)
1899     (when (null size)
1900       (insert ?\n))
1901     (move-marker (car overlay) from)
1902     (set-marker-insertion-type (car overlay) t)))
1903
1904 (defun widget-field-value-delete (widget)
1905   ;; Remove the widget from the list of active editing fields.
1906   (setq widget-field-list (delq widget widget-field-list))
1907   ;; These are nil if the :format string doesn't contain `%v'.
1908   (let ((overlay (widget-get widget :field-overlay)))
1909     (when overlay
1910       (delete-overlay overlay))))
1911
1912 (defun widget-field-value-get (widget)
1913   ;; Return current text in editing field.
1914   (let ((from (widget-field-start widget))
1915         (to (widget-field-end widget))
1916         (buffer (widget-field-buffer widget))
1917         (size (widget-get widget :size))
1918         (secret (widget-get widget :secret))
1919         (old (current-buffer)))
1920     (if (and from to)
1921         (progn
1922           (set-buffer buffer)
1923           (while (and size
1924                       (not (zerop size))
1925                       (> to from)
1926                       (eq (char-after (1- to)) ?\ ))
1927             (setq to (1- to)))
1928           (let ((result (buffer-substring-no-properties from to)))
1929             (when secret
1930               (let ((index 0))
1931                 (while (< (+ from index) to)
1932                   (aset result index
1933                         (get-char-property (+ from index) 'secret))
1934                   (setq index (1+ index)))))
1935             (set-buffer old)
1936             result))
1937       (widget-get widget :value))))
1938
1939 (defun widget-field-match (widget value)
1940   ;; Match any string.
1941   (stringp value))
1942
1943 ;;; The `text' Widget.
1944
1945 (define-widget 'text 'editable-field
1946   :keymap widget-text-keymap
1947   "A multiline text area.")
1948
1949 ;;; The `menu-choice' Widget.
1950
1951 (define-widget 'menu-choice 'default
1952   "A menu of options."
1953   :convert-widget  'widget-types-convert-widget
1954   :format "%[%t%]: %v"
1955   :case-fold t
1956   :tag "choice"
1957   :void '(item :format "invalid (%t)\n")
1958   :value-create 'widget-choice-value-create
1959   :value-delete 'widget-children-value-delete
1960   :value-get 'widget-choice-value-get
1961   :value-inline 'widget-choice-value-inline
1962   :mouse-down-action 'widget-choice-mouse-down-action
1963   :action 'widget-choice-action
1964   :error "Make a choice"
1965   :validate 'widget-choice-validate
1966   :match 'widget-choice-match
1967   :match-inline 'widget-choice-match-inline)
1968
1969 (defun widget-choice-value-create (widget)
1970   ;; Insert the first choice that matches the value.
1971   (let ((value (widget-get widget :value))
1972         (args (widget-get widget :args))
1973         current)
1974     (while args
1975       (setq current (car args)
1976             args (cdr args))
1977       (when (widget-apply current :match value)
1978         (widget-put widget :children (list (widget-create-child-value
1979                                             widget current value)))
1980         (widget-put widget :choice current)
1981         (setq args nil
1982               current nil)))
1983     (when current
1984       (let ((void (widget-get widget :void)))
1985         (widget-put widget :children (list (widget-create-child-and-convert
1986                                             widget void :value value)))
1987         (widget-put widget :choice void)))))
1988
1989 (defun widget-choice-value-get (widget)
1990   ;; Get value of the child widget.
1991   (widget-value (car (widget-get widget :children))))
1992
1993 (defun widget-choice-value-inline (widget)
1994   ;; Get value of the child widget.
1995   (widget-apply (car (widget-get widget :children)) :value-inline))
1996
1997 (defcustom widget-choice-toggle nil
1998   "If non-nil, a binary choice will just toggle between the values.
1999 Otherwise, the user will explicitly have to choose between the values
2000 when he invoked the menu."
2001   :type 'boolean
2002   :group 'widgets)
2003
2004 (defun widget-choice-mouse-down-action (widget &optional event)
2005   ;; Return non-nil if we need a menu.
2006   (let ((args (widget-get widget :args))
2007         (old (widget-get widget :choice)))
2008     (cond ((not window-system)
2009            ;; No place to pop up a menu.
2010            nil)
2011           ((not (or (fboundp 'x-popup-menu) (fboundp 'popup-menu)))
2012            ;; No way to pop up a menu.
2013            nil)
2014           ((< (length args) 2)
2015            ;; Empty or singleton list, just return the value.
2016            nil)
2017           ((> (length args) widget-menu-max-size)
2018            ;; Too long, prompt.
2019            nil)
2020           ((> (length args) 2)
2021            ;; Reasonable sized list, use menu.
2022            t)
2023           ((and widget-choice-toggle (memq old args))
2024            ;; We toggle.
2025            nil)
2026           (t
2027            ;; Ask which of the two.
2028            t))))
2029
2030 (defun widget-choice-action (widget &optional event)
2031   ;; Make a choice.
2032   (let ((args (widget-get widget :args))
2033         (old (widget-get widget :choice))
2034         (tag (widget-apply widget :menu-tag-get))
2035         (completion-ignore-case (widget-get widget :case-fold))
2036         current choices)
2037     ;; Remember old value.
2038     (if (and old (not (widget-apply widget :validate)))
2039         (let* ((external (widget-value widget))
2040                (internal (widget-apply old :value-to-internal external)))
2041           (widget-put old :value internal)))
2042     ;; Find new choice.
2043     (setq current
2044           (cond ((= (length args) 0)
2045                  nil)
2046                 ((= (length args) 1)
2047                  (nth 0 args))
2048                 ((and widget-choice-toggle
2049                       (= (length args) 2)
2050                       (memq old args))
2051                  (if (eq old (nth 0 args))
2052                      (nth 1 args)
2053                    (nth 0 args)))
2054                 (t
2055                  (while args
2056                    (setq current (car args)
2057                          args (cdr args))
2058                    (setq choices
2059                          (cons (cons (widget-apply current :menu-tag-get)
2060                                      current)
2061                                choices)))
2062                  (widget-choose tag (reverse choices) event))))
2063     (when current
2064       (widget-value-set widget
2065                         (widget-apply current :value-to-external
2066                                       (widget-get current :value)))
2067       (widget-setup)
2068       (widget-apply widget :notify widget event)))
2069   (run-hook-with-args 'widget-edit-functions widget))
2070
2071 (defun widget-choice-validate (widget)
2072   ;; Valid if we have made a valid choice.
2073   (let ((void (widget-get widget :void))
2074         (choice (widget-get widget :choice))
2075         (child (car (widget-get widget :children))))
2076     (if (eq void choice)
2077         widget
2078       (widget-apply child :validate))))
2079
2080 (defun widget-choice-match (widget value)
2081   ;; Matches if one of the choices matches.
2082   (let ((args (widget-get widget :args))
2083         current found)
2084     (while (and args (not found))
2085       (setq current (car args)
2086             args (cdr args)
2087             found (widget-apply current :match value)))
2088     found))
2089
2090 (defun widget-choice-match-inline (widget values)
2091   ;; Matches if one of the choices matches.
2092   (let ((args (widget-get widget :args))
2093         current found)
2094     (while (and args (null found))
2095       (setq current (car args)
2096             args (cdr args)
2097             found (widget-match-inline current values)))
2098     found))
2099
2100 ;;; The `toggle' Widget.
2101
2102 (define-widget 'toggle 'item
2103   "Toggle between two states."
2104   :format "%[%v%]\n"
2105   :value-create 'widget-toggle-value-create
2106   :action 'widget-toggle-action
2107   :match (lambda (widget value) t)
2108   :on "on"
2109   :off "off")
2110
2111 (defun widget-toggle-value-create (widget)
2112   ;; Insert text representing the `on' and `off' states.
2113   (if (widget-value widget)
2114       (widget-glyph-insert widget
2115                            (widget-get widget :on)
2116                            (widget-get widget :on-glyph))
2117     (widget-glyph-insert widget
2118                          (widget-get widget :off)
2119                          (widget-get widget :off-glyph))))
2120
2121 (defun widget-toggle-action (widget &optional event)
2122   ;; Toggle value.
2123   (widget-value-set widget (not (widget-value widget)))
2124   (widget-apply widget :notify widget event)
2125   (run-hook-with-args 'widget-edit-functions widget))
2126
2127 ;;; The `checkbox' Widget.
2128
2129 (define-widget 'checkbox 'toggle
2130   "A checkbox toggle."
2131   :button-suffix ""
2132   :button-prefix ""
2133   :format "%[%v%]"
2134   :on "[X]"
2135   :on-glyph "check1"
2136   :off "[ ]"
2137   :off-glyph "check0"
2138   :action 'widget-checkbox-action)
2139
2140 (defun widget-checkbox-action (widget &optional event)
2141   "Toggle checkbox, notify parent, and set active state of sibling."
2142   (widget-toggle-action widget event)
2143   (let ((sibling (widget-get-sibling widget)))
2144     (when sibling
2145       (if (widget-value widget)
2146           (widget-apply sibling :activate)
2147         (widget-apply sibling :deactivate)))))
2148
2149 ;;; The `checklist' Widget.
2150
2151 (define-widget 'checklist 'default
2152   "A multiple choice widget."
2153   :convert-widget 'widget-types-convert-widget
2154   :format "%v"
2155   :offset 4
2156   :entry-format "%b %v"
2157   :menu-tag "checklist"
2158   :greedy nil
2159   :value-create 'widget-checklist-value-create
2160   :value-delete 'widget-children-value-delete
2161   :value-get 'widget-checklist-value-get
2162   :validate 'widget-checklist-validate
2163   :match 'widget-checklist-match
2164   :match-inline 'widget-checklist-match-inline)
2165
2166 (defun widget-checklist-value-create (widget)
2167   ;; Insert all values
2168   (let ((alist (widget-checklist-match-find widget (widget-get widget :value)))
2169         (args (widget-get widget :args)))
2170     (while args
2171       (widget-checklist-add-item widget (car args) (assq (car args) alist))
2172       (setq args (cdr args)))
2173     (widget-put widget :children (nreverse (widget-get widget :children)))))
2174
2175 (defun widget-checklist-add-item (widget type chosen)
2176   ;; Create checklist item in WIDGET of type TYPE.
2177   ;; If the item is checked, CHOSEN is a cons whose cdr is the value.
2178   (and (eq (preceding-char) ?\n)
2179        (widget-get widget :indent)
2180        (insert-char ?  (widget-get widget :indent)))
2181   (widget-specify-insert
2182    (let* ((children (widget-get widget :children))
2183           (buttons (widget-get widget :buttons))
2184           (button-args (or (widget-get type :sibling-args)
2185                            (widget-get widget :button-args)))
2186           (from (point))
2187           child button)
2188      (insert (widget-get widget :entry-format))
2189      (goto-char from)
2190      ;; Parse % escapes in format.
2191      (while (re-search-forward "%\\([bv%]\\)" nil t)
2192        (let ((escape (aref (match-string 1) 0)))
2193          (replace-match "" t t)
2194          (cond ((eq escape ?%)
2195                 (insert "%"))
2196                ((eq escape ?b)
2197                 (setq button (apply 'widget-create-child-and-convert
2198                                     widget 'checkbox
2199                                     :value (not (null chosen))
2200                                     button-args)))
2201                ((eq escape ?v)
2202                 (setq child
2203                       (cond ((not chosen)
2204                              (let ((child (widget-create-child widget type)))
2205                                (widget-apply child :deactivate)
2206                                child))
2207                             ((widget-get type :inline)
2208                              (widget-create-child-value
2209                               widget type (cdr chosen)))
2210                             (t
2211                              (widget-create-child-value
2212                               widget type (car (cdr chosen)))))))
2213                (t
2214                 (error "Unknown escape `%c'" escape)))))
2215      ;; Update properties.
2216      (and button child (widget-put child :button button))
2217      (and button (widget-put widget :buttons (cons button buttons)))
2218      (and child (widget-put widget :children (cons child children))))))
2219
2220 (defun widget-checklist-match (widget values)
2221   ;; All values must match a type in the checklist.
2222   (and (listp values)
2223        (null (cdr (widget-checklist-match-inline widget values)))))
2224
2225 (defun widget-checklist-match-inline (widget values)
2226   ;; Find the values which match a type in the checklist.
2227   (let ((greedy (widget-get widget :greedy))
2228         (args (copy-sequence (widget-get widget :args)))
2229         found rest)
2230     (while values
2231       (let ((answer (widget-checklist-match-up args values)))
2232         (cond (answer
2233                (let ((vals (widget-match-inline answer values)))
2234                  (setq found (append found (car vals))
2235                        values (cdr vals)
2236                        args (delq answer args))))
2237               (greedy
2238                (setq rest (append rest (list (car values)))
2239                      values (cdr values)))
2240               (t
2241                (setq rest (append rest values)
2242                      values nil)))))
2243     (cons found rest)))
2244
2245 (defun widget-checklist-match-find (widget vals)
2246   ;; Find the vals which match a type in the checklist.
2247   ;; Return an alist of (TYPE MATCH).
2248   (let ((greedy (widget-get widget :greedy))
2249         (args (copy-sequence (widget-get widget :args)))
2250         found)
2251     (while vals
2252       (let ((answer (widget-checklist-match-up args vals)))
2253         (cond (answer
2254                (let ((match (widget-match-inline answer vals)))
2255                  (setq found (cons (cons answer (car match)) found)
2256                        vals (cdr match)
2257                        args (delq answer args))))
2258               (greedy
2259                (setq vals (cdr vals)))
2260               (t
2261                (setq vals nil)))))
2262     found))
2263
2264 (defun widget-checklist-match-up (args vals)
2265   ;; Rerturn the first type from ARGS that matches VALS.
2266   (let (current found)
2267     (while (and args (null found))
2268       (setq current (car args)
2269             args (cdr args)
2270             found (widget-match-inline current vals)))
2271     (if found
2272         current
2273       nil)))
2274
2275 (defun widget-checklist-value-get (widget)
2276   ;; The values of all selected items.
2277   (let ((children (widget-get widget :children))
2278         child result)
2279     (while children
2280       (setq child (car children)
2281             children (cdr children))
2282       (if (widget-value (widget-get child :button))
2283           (setq result (append result (widget-apply child :value-inline)))))
2284     result))
2285
2286 (defun widget-checklist-validate (widget)
2287   ;; Ticked chilren must be valid.
2288   (let ((children (widget-get widget :children))
2289         child button found)
2290     (while (and children (not found))
2291       (setq child (car children)
2292             children (cdr children)
2293             button (widget-get child :button)
2294             found (and (widget-value button)
2295                        (widget-apply child :validate))))
2296     found))
2297
2298 ;;; The `option' Widget
2299
2300 (define-widget 'option 'checklist
2301   "An widget with an optional item."
2302   :inline t)
2303
2304 ;;; The `choice-item' Widget.
2305
2306 (define-widget 'choice-item 'item
2307   "Button items that delegate action events to their parents."
2308   :action 'widget-parent-action
2309   :format "%[%t%] \n")
2310
2311 ;;; The `radio-button' Widget.
2312
2313 (define-widget 'radio-button 'toggle
2314   "A radio button for use in the `radio' widget."
2315   :notify 'widget-radio-button-notify
2316   :format "%[%v%]"
2317   :button-suffix ""
2318   :button-prefix ""
2319   :on "(*)"
2320   :on-glyph "radio1"
2321   :off "( )"
2322   :off-glyph "radio0")
2323
2324 (defun widget-radio-button-notify (widget child &optional event)
2325   ;; Tell daddy.
2326   (widget-apply (widget-get widget :parent) :action widget event))
2327
2328 ;;; The `radio-button-choice' Widget.
2329
2330 (define-widget 'radio-button-choice 'default
2331   "Select one of multiple options."
2332   :convert-widget 'widget-types-convert-widget
2333   :offset 4
2334   :format "%v"
2335   :entry-format "%b %v"
2336   :menu-tag "radio"
2337   :value-create 'widget-radio-value-create
2338   :value-delete 'widget-children-value-delete
2339   :value-get 'widget-radio-value-get
2340   :value-inline 'widget-radio-value-inline
2341   :value-set 'widget-radio-value-set
2342   :error "You must push one of the buttons"
2343   :validate 'widget-radio-validate
2344   :match 'widget-choice-match
2345   :match-inline 'widget-choice-match-inline
2346   :action 'widget-radio-action)
2347
2348 (defun widget-radio-value-create (widget)
2349   ;; Insert all values
2350   (let ((args (widget-get widget :args))
2351         arg)
2352     (while args
2353       (setq arg (car args)
2354             args (cdr args))
2355       (widget-radio-add-item widget arg))))
2356
2357 (defun widget-radio-add-item (widget type)
2358   "Add to radio widget WIDGET a new radio button item of type TYPE."
2359   ;; (setq type (widget-convert type))
2360   (and (eq (preceding-char) ?\n)
2361        (widget-get widget :indent)
2362        (insert-char ?  (widget-get widget :indent)))
2363   (widget-specify-insert
2364    (let* ((value (widget-get widget :value))
2365           (children (widget-get widget :children))
2366           (buttons (widget-get widget :buttons))
2367           (button-args (or (widget-get type :sibling-args)
2368                            (widget-get widget :button-args)))
2369           (from (point))
2370           (chosen (and (null (widget-get widget :choice))
2371                        (widget-apply type :match value)))
2372           child button)
2373      (insert (widget-get widget :entry-format))
2374      (goto-char from)
2375      ;; Parse % escapes in format.
2376      (while (re-search-forward "%\\([bv%]\\)" nil t)
2377        (let ((escape (aref (match-string 1) 0)))
2378          (replace-match "" t t)
2379          (cond ((eq escape ?%)
2380                 (insert "%"))
2381                ((eq escape ?b)
2382                 (setq button (apply 'widget-create-child-and-convert
2383                                     widget 'radio-button
2384                                     :value (not (null chosen))
2385                                     button-args)))
2386                ((eq escape ?v)
2387                 (setq child (if chosen
2388                                 (widget-create-child-value
2389                                  widget type value)
2390                               (widget-create-child widget type)))
2391                 (unless chosen
2392                   (widget-apply child :deactivate)))
2393                (t
2394                 (error "Unknown escape `%c'" escape)))))
2395      ;; Update properties.
2396      (when chosen
2397        (widget-put widget :choice type))
2398      (when button
2399        (widget-put child :button button)
2400        (widget-put widget :buttons (nconc buttons (list button))))
2401      (when child
2402        (widget-put widget :children (nconc children (list child))))
2403      child)))
2404
2405 (defun widget-radio-value-get (widget)
2406   ;; Get value of the child widget.
2407   (let ((chosen (widget-radio-chosen widget)))
2408     (and chosen (widget-value chosen))))
2409
2410 (defun widget-radio-chosen (widget)
2411   "Return the widget representing the chosen radio button."
2412   (let ((children (widget-get widget :children))
2413         current found)
2414     (while children
2415       (setq current (car children)
2416             children (cdr children))
2417       (let* ((button (widget-get current :button))
2418              (value (widget-apply button :value-get)))
2419         (when value
2420           (setq found current
2421                 children nil))))
2422     found))
2423
2424 (defun widget-radio-value-inline (widget)
2425   ;; Get value of the child widget.
2426   (let ((children (widget-get widget :children))
2427         current found)
2428     (while children
2429       (setq current (car children)
2430             children (cdr children))
2431       (let* ((button (widget-get current :button))
2432              (value (widget-apply button :value-get)))
2433         (when value
2434           (setq found (widget-apply current :value-inline)
2435                 children nil))))
2436     found))
2437
2438 (defun widget-radio-value-set (widget value)
2439   ;; We can't just delete and recreate a radio widget, since children
2440   ;; can be added after the original creation and won't be recreated
2441   ;; by `:create'.
2442   (let ((children (widget-get widget :children))
2443         current found)
2444     (while children
2445       (setq current (car children)
2446             children (cdr children))
2447       (let* ((button (widget-get current :button))
2448              (match (and (not found)
2449                          (widget-apply current :match value))))
2450         (widget-value-set button match)
2451         (if match
2452             (progn
2453               (widget-value-set current value)
2454               (widget-apply current :activate))
2455           (widget-apply current :deactivate))
2456         (setq found (or found match))))))
2457
2458 (defun widget-radio-validate (widget)
2459   ;; Valid if we have made a valid choice.
2460   (let ((children (widget-get widget :children))
2461         current found button)
2462     (while (and children (not found))
2463       (setq current (car children)
2464             children (cdr children)
2465             button (widget-get current :button)
2466             found (widget-apply button :value-get)))
2467     (if found
2468         (widget-apply current :validate)
2469       widget)))
2470
2471 (defun widget-radio-action (widget child event)
2472   ;; Check if a radio button was pressed.
2473   (let ((children (widget-get widget :children))
2474         (buttons (widget-get widget :buttons))
2475         current)
2476     (when (memq child buttons)
2477       (while children
2478         (setq current (car children)
2479               children (cdr children))
2480         (let* ((button (widget-get current :button)))
2481           (cond ((eq child button)
2482                  (widget-value-set button t)
2483                  (widget-apply current :activate))
2484                 ((widget-value button)
2485                  (widget-value-set button nil)
2486                  (widget-apply current :deactivate)))))))
2487   ;; Pass notification to parent.
2488   (widget-apply widget :notify child event))
2489
2490 ;;; The `insert-button' Widget.
2491
2492 (define-widget 'insert-button 'push-button
2493   "An insert button for the `editable-list' widget."
2494   :tag "INS"
2495   :help-echo "Insert a new item into the list at this position."
2496   :action 'widget-insert-button-action)
2497
2498 (defun widget-insert-button-action (widget &optional event)
2499   ;; Ask the parent to insert a new item.
2500   (widget-apply (widget-get widget :parent)
2501                 :insert-before (widget-get widget :widget)))
2502
2503 ;;; The `delete-button' Widget.
2504
2505 (define-widget 'delete-button 'push-button
2506   "A delete button for the `editable-list' widget."
2507   :tag "DEL"
2508   :help-echo "Delete this item from the list."
2509   :action 'widget-delete-button-action)
2510
2511 (defun widget-delete-button-action (widget &optional event)
2512   ;; Ask the parent to insert a new item.
2513   (widget-apply (widget-get widget :parent)
2514                 :delete-at (widget-get widget :widget)))
2515
2516 ;;; The `editable-list' Widget.
2517
2518 (defcustom widget-editable-list-gui nil
2519   "If non nil, use GUI push-buttons in editable list when available."
2520   :type 'boolean
2521   :group 'widgets)
2522
2523 (define-widget 'editable-list 'default
2524   "A variable list of widgets of the same type."
2525   :convert-widget 'widget-types-convert-widget
2526   :offset 12
2527   :format "%v%i\n"
2528   :format-handler 'widget-editable-list-format-handler
2529   :entry-format "%i %d %v"
2530   :menu-tag "editable-list"
2531   :value-create 'widget-editable-list-value-create
2532   :value-delete 'widget-children-value-delete
2533   :value-get 'widget-editable-list-value-get
2534   :validate 'widget-children-validate
2535   :match 'widget-editable-list-match
2536   :match-inline 'widget-editable-list-match-inline
2537   :insert-before 'widget-editable-list-insert-before
2538   :delete-at 'widget-editable-list-delete-at)
2539
2540 (defun widget-editable-list-format-handler (widget escape)
2541   ;; We recognize the insert button.
2542   (let ((widget-push-button-gui widget-editable-list-gui))
2543     (cond ((eq escape ?i)
2544            (and (widget-get widget :indent)
2545                 (insert-char ?  (widget-get widget :indent)))
2546            (apply 'widget-create-child-and-convert
2547                   widget 'insert-button
2548                   (widget-get widget :append-button-args)))
2549           (t
2550            (widget-default-format-handler widget escape)))))
2551
2552 (defun widget-editable-list-value-create (widget)
2553   ;; Insert all values
2554   (let* ((value (widget-get widget :value))
2555          (type (nth 0 (widget-get widget :args)))
2556          (inlinep (widget-get type :inline))
2557          children)
2558     (widget-put widget :value-pos (copy-marker (point)))
2559     (set-marker-insertion-type (widget-get widget :value-pos) t)
2560     (while value
2561       (let ((answer (widget-match-inline type value)))
2562         (if answer
2563             (setq children (cons (widget-editable-list-entry-create
2564                                   widget
2565                                   (if inlinep
2566                                       (car answer)
2567                                     (car (car answer)))
2568                                   t)
2569                                  children)
2570                   value (cdr answer))
2571           (setq value nil))))
2572     (widget-put widget :children (nreverse children))))
2573
2574 (defun widget-editable-list-value-get (widget)
2575   ;; Get value of the child widget.
2576   (apply 'append (mapcar (lambda (child) (widget-apply child :value-inline))
2577                          (widget-get widget :children))))
2578
2579 (defun widget-editable-list-match (widget value)
2580   ;; Value must be a list and all the members must match the type.
2581   (and (listp value)
2582        (null (cdr (widget-editable-list-match-inline widget value)))))
2583
2584 (defun widget-editable-list-match-inline (widget value)
2585   (let ((type (nth 0 (widget-get widget :args)))
2586         (ok t)
2587         found)
2588     (while (and value ok)
2589       (let ((answer (widget-match-inline type value)))
2590         (if answer
2591             (setq found (append found (car answer))
2592                   value (cdr answer))
2593           (setq ok nil))))
2594     (cons found value)))
2595
2596 (defun widget-editable-list-insert-before (widget before)
2597   ;; Insert a new child in the list of children.
2598   (save-excursion
2599     (let ((children (widget-get widget :children))
2600           (inhibit-read-only t)
2601           before-change-functions
2602           after-change-functions)
2603       (cond (before
2604              (goto-char (widget-get before :entry-from)))
2605             (t
2606              (goto-char (widget-get widget :value-pos))))
2607       (let ((child (widget-editable-list-entry-create
2608                     widget nil nil)))
2609         (when (< (widget-get child :entry-from) (widget-get widget :from))
2610           (set-marker (widget-get widget :from)
2611                       (widget-get child :entry-from)))
2612         (widget-specify-text (widget-get child :entry-from)
2613                              (widget-get child :entry-to))
2614         (if (eq (car children) before)
2615             (widget-put widget :children (cons child children))
2616           (while (not (eq (car (cdr children)) before))
2617             (setq children (cdr children)))
2618           (setcdr children (cons child (cdr children)))))))
2619   (widget-setup)
2620   (widget-apply widget :notify widget))
2621
2622 (defun widget-editable-list-delete-at (widget child)
2623   ;; Delete child from list of children.
2624   (save-excursion
2625     (let ((buttons (copy-sequence (widget-get widget :buttons)))
2626           button
2627           (inhibit-read-only t)
2628           before-change-functions
2629           after-change-functions)
2630       (while buttons
2631         (setq button (car buttons)
2632               buttons (cdr buttons))
2633         (when (eq (widget-get button :widget) child)
2634           (widget-put widget
2635                       :buttons (delq button (widget-get widget :buttons)))
2636           (widget-delete button))))
2637     (let ((entry-from (widget-get child :entry-from))
2638           (entry-to (widget-get child :entry-to))
2639           (inhibit-read-only t)
2640           before-change-functions
2641           after-change-functions)
2642       (widget-delete child)
2643       (delete-region entry-from entry-to)
2644       (set-marker entry-from nil)
2645       (set-marker entry-to nil))
2646     (widget-put widget :children (delq child (widget-get widget :children))))
2647   (widget-setup)
2648   (widget-apply widget :notify widget))
2649
2650 (defun widget-editable-list-entry-create (widget value conv)
2651   ;; Create a new entry to the list.
2652   (let ((type (nth 0 (widget-get widget :args)))
2653         (widget-push-button-gui widget-editable-list-gui)
2654         child delete insert)
2655     (widget-specify-insert
2656      (save-excursion
2657        (and (widget-get widget :indent)
2658             (insert-char ?  (widget-get widget :indent)))
2659        (insert (widget-get widget :entry-format)))
2660      ;; Parse % escapes in format.
2661      (while (re-search-forward "%\\(.\\)" nil t)
2662        (let ((escape (aref (match-string 1) 0)))
2663          (replace-match "" t t)
2664          (cond ((eq escape ?%)
2665                 (insert "%"))
2666                ((eq escape ?i)
2667                 (setq insert (apply 'widget-create-child-and-convert
2668                                     widget 'insert-button
2669                                     (widget-get widget :insert-button-args))))
2670                ((eq escape ?d)
2671                 (setq delete (apply 'widget-create-child-and-convert
2672                                     widget 'delete-button
2673                                     (widget-get widget :delete-button-args))))
2674                ((eq escape ?v)
2675                 (if conv
2676                     (setq child (widget-create-child-value
2677                                  widget type value))
2678                   (setq child (widget-create-child widget type))))
2679                (t
2680                 (error "Unknown escape `%c'" escape)))))
2681      (widget-put widget
2682                  :buttons (cons delete
2683                                 (cons insert
2684                                       (widget-get widget :buttons))))
2685      (let ((entry-from (copy-marker (point-min)))
2686            (entry-to (copy-marker (point-max))))
2687        (widget-specify-text entry-from entry-to)
2688        (set-marker-insertion-type entry-from t)
2689        (set-marker-insertion-type entry-to nil)
2690        (widget-put child :entry-from entry-from)
2691        (widget-put child :entry-to entry-to)))
2692     (widget-put insert :widget child)
2693     (widget-put delete :widget child)
2694     child))
2695
2696 ;;; The `group' Widget.
2697
2698 (define-widget 'group 'default
2699   "A widget which group other widgets inside."
2700   :convert-widget 'widget-types-convert-widget
2701   :format "%v"
2702   :value-create 'widget-group-value-create
2703   :value-delete 'widget-children-value-delete
2704   :value-get 'widget-editable-list-value-get
2705   :validate 'widget-children-validate
2706   :match 'widget-group-match
2707   :match-inline 'widget-group-match-inline)
2708
2709 (defun widget-group-value-create (widget)
2710   ;; Create each component.
2711   (let ((args (widget-get widget :args))
2712         (value (widget-get widget :value))
2713         arg answer children)
2714     (while args
2715       (setq arg (car args)
2716             args (cdr args)
2717             answer (widget-match-inline arg value)
2718             value (cdr answer))
2719       (and (eq (preceding-char) ?\n)
2720            (widget-get widget :indent)
2721            (insert-char ?  (widget-get widget :indent)))
2722       (push (cond ((null answer)
2723                    (widget-create-child widget arg))
2724                   ((widget-get arg :inline)
2725                    (widget-create-child-value widget arg  (car answer)))
2726                   (t
2727                    (widget-create-child-value widget arg  (car (car answer)))))
2728             children))
2729     (widget-put widget :children (nreverse children))))
2730
2731 (defun widget-group-match (widget values)
2732   ;; Match if the components match.
2733   (and (listp values)
2734        (let ((match (widget-group-match-inline widget values)))
2735          (and match (null (cdr match))))))
2736
2737 (defun widget-group-match-inline (widget vals)
2738   ;; Match if the components match.
2739   (let ((args (widget-get widget :args))
2740         argument answer found)
2741     (while args
2742       (setq argument (car args)
2743             args (cdr args)
2744             answer (widget-match-inline argument vals))
2745       (if answer
2746           (setq vals (cdr answer)
2747                 found (append found (car answer)))
2748         (setq vals nil
2749               args nil)))
2750     (if answer
2751         (cons found vals)
2752       nil)))
2753
2754 ;;; The `visibility' Widget.
2755
2756 (define-widget 'visibility 'item
2757   "An indicator and manipulator for hidden items."
2758   :format "%[%v%]"
2759   :button-prefix ""
2760   :button-suffix ""
2761   :on "Hide"
2762   :off "Show"
2763   :value-create 'widget-visibility-value-create
2764   :action 'widget-toggle-action
2765   :match (lambda (widget value) t))
2766
2767 (defun widget-visibility-value-create (widget)
2768   ;; Insert text representing the `on' and `off' states.
2769   (let ((on (widget-get widget :on))
2770         (off (widget-get widget :off)))
2771     (if on
2772         (setq on (concat widget-push-button-prefix
2773                          on
2774                          widget-push-button-suffix))
2775       (setq on ""))
2776     (if off
2777         (setq off (concat widget-push-button-prefix
2778                           off
2779                           widget-push-button-suffix))
2780       (setq off ""))
2781     (if (widget-value widget)
2782         (widget-glyph-insert widget on "down" "down-pushed")
2783       (widget-glyph-insert widget off "right" "right-pushed"))))
2784
2785 ;;; The `documentation-link' Widget.
2786 ;;
2787 ;; This is a helper widget for `documentation-string'.
2788
2789 (define-widget 'documentation-link 'link
2790   "Link type used in documentation strings."
2791   :tab-order -1
2792   :help-echo 'widget-documentation-link-echo-help
2793   :action 'widget-documentation-link-action)
2794
2795 (defun widget-documentation-link-echo-help (widget)
2796   "Tell what this link will describe."
2797   (concat "Describe the `" (widget-get widget :value) "' symbol."))
2798
2799 (defun widget-documentation-link-action (widget &optional event)
2800   "Display documentation for WIDGET's value.  Ignore optional argument EVENT."
2801   (let* ((string (widget-get widget :value))
2802          (symbol (intern string)))
2803     (if (and (fboundp symbol) (boundp symbol))
2804         ;; If there are two doc strings, give the user a way to pick one.
2805         (apropos (concat "\\`" (regexp-quote string) "\\'"))
2806       (if (fboundp symbol)
2807           (describe-function symbol)
2808         (describe-variable symbol)))))
2809
2810 (defcustom widget-documentation-links t
2811   "Add hyperlinks to documentation strings when non-nil."
2812   :type 'boolean
2813   :group 'widget-documentation)
2814
2815 (defcustom widget-documentation-link-regexp "`\\([^\n`' ]+\\)'"
2816   "Regexp for matching potential links in documentation strings.
2817 The first group should be the link itself."
2818   :type 'regexp
2819   :group 'widget-documentation)
2820
2821 (defcustom widget-documentation-link-p 'intern-soft
2822   "Predicate used to test if a string is useful as a link.
2823 The value should be a function.  The function will be called one
2824 argument, a string, and should return non-nil if there should be a
2825 link for that string."
2826   :type 'function
2827   :options '(widget-documentation-link-p)
2828   :group 'widget-documentation)
2829
2830 (defcustom widget-documentation-link-type 'documentation-link
2831   "Widget type used for links in documentation strings."
2832   :type 'symbol
2833   :group 'widget-documentation)
2834
2835 (defun widget-documentation-link-add (widget from to)
2836   (widget-specify-doc widget from to)
2837   (when widget-documentation-links
2838     (let ((regexp widget-documentation-link-regexp)
2839           (predicate widget-documentation-link-p)
2840           (type widget-documentation-link-type)
2841           (buttons (widget-get widget :buttons)))
2842       (save-excursion
2843         (goto-char from)
2844         (while (re-search-forward regexp to t)
2845           (let ((name (match-string 1))
2846                 (begin (match-beginning 1))
2847                 (end (match-end 1)))
2848             (when (funcall predicate name)
2849               (push (widget-convert-button type begin end :value name)
2850                     buttons)))))
2851       (widget-put widget :buttons buttons)))
2852   (let ((indent (widget-get widget :indent)))
2853     (when (and indent (not (zerop indent)))
2854       (save-excursion
2855         (save-restriction
2856           (narrow-to-region from to)
2857           (goto-char (point-min))
2858           (while (search-forward "\n" nil t)
2859             (insert-char ?\  indent)))))))
2860
2861 ;;; The `documentation-string' Widget.
2862
2863 (define-widget 'documentation-string 'item
2864   "A documentation string."
2865   :format "%v"
2866   :action 'widget-documentation-string-action
2867   :value-delete 'widget-children-value-delete
2868   :value-create 'widget-documentation-string-value-create)
2869
2870 (defun widget-documentation-string-value-create (widget)
2871   ;; Insert documentation string.
2872   (let ((doc (widget-value widget))
2873         (indent (widget-get widget :indent))
2874         (shown (widget-get (widget-get widget :parent) :documentation-shown))
2875         (start (point)))
2876     (if (string-match "\n" doc)
2877         (let ((before (substring doc 0 (match-beginning 0)))
2878               (after (substring doc (match-beginning 0)))
2879               buttons)
2880           (insert before " ")
2881           (widget-documentation-link-add widget start (point))
2882           (push (widget-create-child-and-convert
2883                  widget 'visibility
2884                  :help-echo "Show or hide rest of the documentation."
2885                  :off "More"
2886                  :action 'widget-parent-action
2887                  shown)
2888                 buttons)
2889           (when shown
2890             (setq start (point))
2891             (when (and indent (not (zerop indent)))
2892               (insert-char ?\  indent))
2893             (insert after)
2894             (widget-documentation-link-add widget start (point)))
2895           (widget-put widget :buttons buttons))
2896       (insert doc)
2897       (widget-documentation-link-add widget start (point))))
2898   (insert "\n"))
2899
2900 (defun widget-documentation-string-action (widget &rest ignore)
2901   ;; Toggle documentation.
2902   (let ((parent (widget-get widget :parent)))
2903     (widget-put parent :documentation-shown
2904                 (not (widget-get parent :documentation-shown))))
2905   ;; Redraw.
2906   (widget-value-set widget (widget-value widget)))
2907
2908 ;;; The Sexp Widgets.
2909
2910 (define-widget 'const 'item
2911   "An immutable sexp."
2912   :prompt-value 'widget-const-prompt-value
2913   :format "%t\n%d")
2914
2915 (defun widget-const-prompt-value (widget prompt value unbound)
2916   ;; Return the value of the const.
2917   (widget-value widget))
2918
2919 (define-widget 'function-item 'const
2920   "An immutable function name."
2921   :format "%v\n%h"
2922   :documentation-property (lambda (symbol)
2923                             (condition-case nil
2924                                 (documentation symbol t)
2925                               (error nil))))
2926
2927 (define-widget 'variable-item 'const
2928   "An immutable variable name."
2929   :format "%v\n%h"
2930   :documentation-property 'variable-documentation)
2931
2932 (defvar widget-string-prompt-value-history nil
2933   "History of input to `widget-string-prompt-value'.")
2934
2935 (define-widget 'string 'editable-field
2936   "A string"
2937   :tag "String"
2938   :format "%{%t%}: %v"
2939   :complete-function 'ispell-complete-word
2940   :prompt-history 'widget-string-prompt-value-history)
2941
2942 (define-widget 'regexp 'string
2943   "A regular expression."
2944   :match 'widget-regexp-match
2945   :validate 'widget-regexp-validate
2946   :value-face 'widget-single-line-field-face
2947   :tag "Regexp")
2948
2949 (defun widget-regexp-match (widget value)
2950   ;; Match valid regexps.
2951   (and (stringp value)
2952        (condition-case nil
2953            (prog1 t
2954              (string-match value ""))
2955          (error nil))))
2956
2957 (defun widget-regexp-validate (widget)
2958   "Check that the value of WIDGET is a valid regexp."
2959   (let ((val (widget-value widget)))
2960     (condition-case data
2961         (prog1 nil
2962           (string-match val ""))
2963       (error (widget-put widget :error (error-message-string data))
2964              widget))))
2965
2966 (define-widget 'file 'string
2967   "A file widget.
2968 It will read a file name from the minibuffer when invoked."
2969   :complete-function 'widget-file-complete
2970   :prompt-value 'widget-file-prompt-value
2971   :format "%{%t%}: %v"
2972   :value-face 'widget-single-line-field-face
2973   :tag "File")
2974
2975 (defun widget-file-complete ()
2976   "Perform completion on file name preceding point."
2977   (interactive)
2978   (let* ((end (point))
2979          (beg (save-excursion
2980                 (skip-chars-backward "^ ")
2981                 (point)))
2982          (pattern (buffer-substring beg end))
2983          (name-part (file-name-nondirectory pattern))
2984          (directory (file-name-directory pattern))
2985          (completion (file-name-completion name-part directory)))
2986     (cond ((eq completion t))
2987           ((null completion)
2988            (message "Can't find completion for \"%s\"" pattern)
2989            (ding))
2990           ((not (string= name-part completion))
2991            (delete-region beg end)
2992            (insert (expand-file-name completion directory)))
2993           (t
2994            (message "Making completion list...")
2995            (let ((list (file-name-all-completions name-part directory)))
2996              (setq list (sort list 'string<))
2997              (with-output-to-temp-buffer "*Completions*"
2998                (display-completion-list list)))
2999            (message "Making completion list...%s" "done")))))
3000
3001 (defun widget-file-prompt-value (widget prompt value unbound)
3002   ;; Read file from minibuffer.
3003   (abbreviate-file-name
3004    (if unbound
3005        (read-file-name prompt)
3006      (let ((prompt2 (format "%s (default %s) " prompt value))
3007            (dir (file-name-directory value))
3008            (file (file-name-nondirectory value))
3009            (must-match (widget-get widget :must-match)))
3010        (read-file-name prompt2 dir nil must-match file)))))
3011
3012 ;;;(defun widget-file-action (widget &optional event)
3013 ;;;  ;; Read a file name from the minibuffer.
3014 ;;;  (let* ((value (widget-value widget))
3015 ;;;      (dir (file-name-directory value))
3016 ;;;      (file (file-name-nondirectory value))
3017 ;;;      (menu-tag (widget-apply widget :menu-tag-get))
3018 ;;;      (must-match (widget-get widget :must-match))
3019 ;;;      (answer (read-file-name (concat menu-tag ": (default `" value "') ")
3020 ;;;                              dir nil must-match file)))
3021 ;;;    (widget-value-set widget (abbreviate-file-name answer))
3022 ;;;    (widget-setup)
3023 ;;;    (widget-apply widget :notify widget event)))
3024
3025 (define-widget 'directory 'file
3026   "A directory widget.
3027 It will read a directory name from the minibuffer when invoked."
3028   :tag "Directory")
3029
3030 (defvar widget-symbol-prompt-value-history nil
3031   "History of input to `widget-symbol-prompt-value'.")
3032
3033 (define-widget 'symbol 'editable-field
3034   "A lisp symbol."
3035   :value nil
3036   :tag "Symbol"
3037   :format "%{%t%}: %v"
3038   :match (lambda (widget value) (symbolp value))
3039   :complete-function 'lisp-complete-symbol
3040   :prompt-internal 'widget-symbol-prompt-internal
3041   :prompt-match 'symbolp
3042   :prompt-history 'widget-symbol-prompt-value-history
3043   :value-to-internal (lambda (widget value)
3044                        (if (symbolp value)
3045                            (symbol-name value)
3046                          value))
3047   :value-to-external (lambda (widget value)
3048                        (if (stringp value)
3049                            (intern value)
3050                          value)))
3051
3052 (defun widget-symbol-prompt-internal (widget prompt initial history)
3053   ;; Read file from minibuffer.
3054   (let ((answer (completing-read prompt obarray
3055                                  (widget-get widget :prompt-match)
3056                                  nil initial history)))
3057     (if (and (stringp answer)
3058              (not (zerop (length answer))))
3059         answer
3060       (error "No value"))))
3061
3062 (defvar widget-function-prompt-value-history nil
3063   "History of input to `widget-function-prompt-value'.")
3064
3065 (define-widget 'function 'sexp
3066   "A lisp function."
3067   :complete-function 'lisp-complete-symbol
3068   :prompt-value 'widget-field-prompt-value
3069   :prompt-internal 'widget-symbol-prompt-internal
3070   :prompt-match 'fboundp
3071   :prompt-history 'widget-function-prompt-value-history
3072   :action 'widget-field-action
3073   :tag "Function")
3074
3075 (defvar widget-variable-prompt-value-history nil
3076   "History of input to `widget-variable-prompt-value'.")
3077
3078 (define-widget 'variable 'symbol
3079   ;; Should complete on variables.
3080   "A lisp variable."
3081   :prompt-match 'boundp
3082   :prompt-history 'widget-variable-prompt-value-history
3083   :tag "Variable")
3084
3085 (when (featurep 'mule)
3086   (defvar widget-coding-system-prompt-value-history nil
3087     "History of input to `widget-coding-system-prompt-value'.")
3088
3089   (define-widget 'coding-system 'symbol
3090     "A MULE coding-system."
3091     :format "%{%t%}: %v"
3092     :tag "Coding system"
3093     :prompt-history 'widget-coding-system-prompt-value-history
3094     :prompt-value 'widget-coding-system-prompt-value
3095     :action 'widget-coding-system-action)
3096
3097   (defun widget-coding-system-prompt-value (widget prompt value unbound)
3098     ;; Read coding-system from minibuffer.
3099     (intern
3100      (completing-read (format "%s (default %s) " prompt value)
3101                       (mapcar (function
3102                                (lambda (sym)
3103                                  (list (symbol-name sym))
3104                                  ))
3105                               (coding-system-list)))))
3106
3107   (defun widget-coding-system-action (widget &optional event)
3108     ;; Read a file name from the minibuffer.
3109     (let ((answer
3110            (widget-coding-system-prompt-value
3111             widget
3112             (widget-apply widget :menu-tag-get)
3113             (widget-value widget)
3114             t)))
3115       (widget-value-set widget answer)
3116       (widget-apply widget :notify widget event)
3117       (widget-setup)))
3118   )
3119
3120 (define-widget 'sexp 'editable-field
3121   "An arbitrary lisp expression."
3122   :tag "Lisp expression"
3123   :format "%{%t%}: %v"
3124   :value nil
3125   :validate 'widget-sexp-validate
3126   :match (lambda (widget value) t)
3127   :value-to-internal 'widget-sexp-value-to-internal
3128   :value-to-external (lambda (widget value) (read value))
3129   :prompt-history 'widget-sexp-prompt-value-history
3130   :prompt-value 'widget-sexp-prompt-value)
3131
3132 (defun widget-sexp-value-to-internal (widget value)
3133   ;; Use pp for printer representation.
3134   (let ((pp (if (symbolp value)
3135                 (prin1-to-string value)
3136               (pp-to-string value))))
3137     (while (string-match "\n\\'" pp)
3138       (setq pp (substring pp 0 -1)))
3139     (if (or (string-match "\n\\'" pp)
3140             (> (length pp) 40))
3141         (concat "\n" pp)
3142       pp)))
3143
3144 (defun widget-sexp-validate (widget)
3145   ;; Valid if we can read the string and there is no junk left after it.
3146   (save-excursion
3147     (let ((buffer (set-buffer (get-buffer-create " *Widget Scratch*"))))
3148       (erase-buffer)
3149       (insert (widget-apply widget :value-get))
3150       (goto-char (point-min))
3151       (condition-case data
3152           (let ((value (read buffer)))
3153             (if (eobp)
3154                 (if (widget-apply widget :match value)
3155                     nil
3156                   (widget-put widget :error (widget-get widget :type-error))
3157                   widget)
3158               (widget-put widget
3159                           :error (format "Junk at end of expression: %s"
3160                                          (buffer-substring (point)
3161                                                            (point-max))))
3162               widget))
3163         (error (widget-put widget :error (error-message-string data))
3164                widget)))))
3165
3166 (defvar widget-sexp-prompt-value-history nil
3167   "History of input to `widget-sexp-prompt-value'.")
3168
3169 (defun widget-sexp-prompt-value (widget prompt value unbound)
3170   ;; Read an arbitrary sexp.
3171   (let ((found (read-string prompt
3172                             (if unbound nil (cons (prin1-to-string value) 0))
3173                             (widget-get widget :prompt-history))))
3174     (save-excursion
3175       (let ((buffer (set-buffer (get-buffer-create " *Widget Scratch*"))))
3176         (erase-buffer)
3177         (insert found)
3178         (goto-char (point-min))
3179         (let ((answer (read buffer)))
3180           (unless (eobp)
3181             (error "Junk at end of expression: %s"
3182                    (buffer-substring (point) (point-max))))
3183           answer)))))
3184
3185 (define-widget 'restricted-sexp 'sexp
3186   "A Lisp expression restricted to values that match.
3187 To use this type, you must define :match or :match-alternatives."
3188   :type-error "The specified value is not valid"
3189   :match 'widget-restricted-sexp-match
3190   :value-to-internal (lambda (widget value)
3191                        (if (widget-apply widget :match value)
3192                            (prin1-to-string value)
3193                          value)))
3194
3195 (defun widget-restricted-sexp-match (widget value)
3196   (let ((alternatives (widget-get widget :match-alternatives))
3197         matched)
3198     (while (and alternatives (not matched))
3199       (if (cond ((functionp (car alternatives))
3200                  (funcall (car alternatives) value))
3201                 ((and (consp (car alternatives))
3202                       (eq (car (car alternatives)) 'quote))
3203                  (eq value (nth 1 (car alternatives)))))
3204           (setq matched t))
3205       (setq alternatives (cdr alternatives)))
3206     matched))
3207
3208 (define-widget 'integer 'restricted-sexp
3209   "An integer."
3210   :tag "Integer"
3211   :value 0
3212   :type-error "This field should contain an integer"
3213   :match-alternatives '(integerp))
3214
3215 (define-widget 'number 'restricted-sexp
3216   "A floating point number."
3217   :tag "Number"
3218   :value 0.0
3219   :type-error "This field should contain a number"
3220   :match-alternatives '(numberp))
3221
3222 (define-widget 'character 'editable-field
3223   "A character."
3224   :tag "Character"
3225   :value 0
3226   :size 1
3227   :format "%{%t%}: %v\n"
3228   :valid-regexp "\\`.\\'"
3229   :error "This field should contain a single character"
3230   :value-to-internal (lambda (widget value)
3231                        (if (stringp value)
3232                            value
3233                          (char-to-string value)))
3234   :value-to-external (lambda (widget value)
3235                        (if (stringp value)
3236                            (aref value 0)
3237                          value))
3238   :match (lambda (widget value)
3239            (if (fboundp 'characterp)
3240                (characterp value)
3241              (integerp value))))
3242
3243 (define-widget 'list 'group
3244   "A lisp list."
3245   :tag "List"
3246   :format "%{%t%}:\n%v")
3247
3248 (define-widget 'vector 'group
3249   "A lisp vector."
3250   :tag "Vector"
3251   :format "%{%t%}:\n%v"
3252   :match 'widget-vector-match
3253   :value-to-internal (lambda (widget value) (append value nil))
3254   :value-to-external (lambda (widget value) (apply 'vector value)))
3255
3256 (defun widget-vector-match (widget value)
3257   (and (vectorp value)
3258        (widget-group-match widget
3259                            (widget-apply widget :value-to-internal value))))
3260
3261 (define-widget 'cons 'group
3262   "A cons-cell."
3263   :tag "Cons-cell"
3264   :format "%{%t%}:\n%v"
3265   :match 'widget-cons-match
3266   :value-to-internal (lambda (widget value)
3267                        (list (car value) (cdr value)))
3268   :value-to-external (lambda (widget value)
3269                        (cons (nth 0 value) (nth 1 value))))
3270
3271 (defun widget-cons-match (widget value)
3272   (and (consp value)
3273        (widget-group-match widget
3274                            (widget-apply widget :value-to-internal value))))
3275
3276 (define-widget 'choice 'menu-choice
3277   "A union of several sexp types."
3278   :tag "Choice"
3279   :format "%{%t%}: %[Value Menu%] %v"
3280   :button-prefix 'widget-push-button-prefix
3281   :button-suffix 'widget-push-button-suffix
3282   :prompt-value 'widget-choice-prompt-value)
3283
3284 (defun widget-choice-prompt-value (widget prompt value unbound)
3285   "Make a choice."
3286   (let ((args (widget-get widget :args))
3287         (completion-ignore-case (widget-get widget :case-fold))
3288         current choices old)
3289     ;; Find the first arg that match VALUE.
3290     (let ((look args))
3291       (while look
3292         (if (widget-apply (car look) :match value)
3293             (setq old (car look)
3294                   look nil)
3295           (setq look (cdr look)))))
3296     ;; Find new choice.
3297     (setq current
3298           (cond ((= (length args) 0)
3299                  nil)
3300                 ((= (length args) 1)
3301                  (nth 0 args))
3302                 ((and (= (length args) 2)
3303                       (memq old args))
3304                  (if (eq old (nth 0 args))
3305                      (nth 1 args)
3306                    (nth 0 args)))
3307                 (t
3308                  (while args
3309                    (setq current (car args)
3310                          args (cdr args))
3311                    (setq choices
3312                          (cons (cons (widget-apply current :menu-tag-get)
3313                                      current)
3314                                choices)))
3315                  (let ((val (completing-read prompt choices nil t)))
3316                    (if (stringp val)
3317                        (let ((try (try-completion val choices)))
3318                          (when (stringp try)
3319                            (setq val try))
3320                          (cdr (assoc val choices)))
3321                      nil)))))
3322     (if current
3323         (widget-prompt-value current prompt nil t)
3324       value)))
3325
3326 (define-widget 'radio 'radio-button-choice
3327   "A union of several sexp types."
3328   :tag "Choice"
3329   :format "%{%t%}:\n%v"
3330   :prompt-value 'widget-choice-prompt-value)
3331
3332 (define-widget 'repeat 'editable-list
3333   "A variable length homogeneous list."
3334   :tag "Repeat"
3335   :format "%{%t%}:\n%v%i\n")
3336
3337 (define-widget 'set 'checklist
3338   "A list of members from a fixed set."
3339   :tag "Set"
3340   :format "%{%t%}:\n%v")
3341
3342 (define-widget 'boolean 'toggle
3343   "To be nil or non-nil, that is the question."
3344   :tag "Boolean"
3345   :prompt-value 'widget-boolean-prompt-value
3346   :button-prefix 'widget-push-button-prefix
3347   :button-suffix 'widget-push-button-suffix
3348   :format "%{%t%}: %[Toggle%]  %v\n"
3349   :on "on (non-nil)"
3350   :off "off (nil)")
3351
3352 (defun widget-boolean-prompt-value (widget prompt value unbound)
3353   ;; Toggle a boolean.
3354   (y-or-n-p prompt))
3355
3356 ;;; The `color' Widget.
3357
3358 (define-widget 'color 'editable-field
3359   "Choose a color name (with sample)."
3360   :format "%t: %v (%{sample%})\n"
3361   :size 10
3362   :tag "Color"
3363   :value "black"
3364   :complete 'widget-color-complete
3365   :sample-face-get 'widget-color-sample-face-get
3366   :notify 'widget-color-notify
3367   :action 'widget-color-action)
3368
3369 (defun widget-color-complete (widget)
3370   "Complete the color in WIDGET."
3371   (let* ((prefix (buffer-substring-no-properties (widget-field-start widget)
3372                                                  (point)))
3373          (list (widget-color-choice-list))
3374          (completion (try-completion prefix list)))
3375     (cond ((eq completion t)
3376            (message "Exact match."))
3377           ((null completion)
3378            (error "Can't find completion for \"%s\"" prefix))
3379           ((not (string-equal prefix completion))
3380            (insert-and-inherit (substring completion (length prefix))))
3381           (t
3382            (message "Making completion list...")
3383            (let ((list (all-completions prefix list nil)))
3384              (with-output-to-temp-buffer "*Completions*"
3385                (display-completion-list list)))
3386            (message "Making completion list...done")))))
3387
3388 (defun widget-color-sample-face-get (widget)
3389   (let ((symbol (intern (concat "fg:" (widget-value widget)))))
3390     (if (string-match "XEmacs" emacs-version)
3391         (prog1 symbol
3392           (or (find-face symbol)
3393               (set-face-foreground (make-face symbol) (widget-value widget))))
3394       (condition-case nil
3395           (facemenu-get-face symbol)
3396         (error 'default)))))
3397
3398 (defvar widget-color-choice-list nil)
3399 ;; Variable holding the possible colors.
3400
3401 (defun widget-color-choice-list ()
3402   (unless widget-color-choice-list
3403     (setq widget-color-choice-list
3404           (if (fboundp 'read-color-completion-table)
3405               (read-color-completion-table)
3406             (mapcar '(lambda (color) (list color))
3407                     (x-defined-colors)))))
3408   widget-color-choice-list)
3409
3410 (defvar widget-color-history nil
3411   "History of entered colors")
3412
3413 (defun widget-color-action (widget &optional event)
3414   ;; Prompt for a color.
3415   (let* ((tag (widget-apply widget :menu-tag-get))
3416          (prompt (concat tag ": "))
3417          (answer (cond ((string-match "XEmacs" emacs-version)
3418                         (read-color prompt))
3419                        ((fboundp 'x-defined-colors)
3420                         (completing-read (concat tag ": ")
3421                                          (widget-color-choice-list)
3422                                          nil nil nil 'widget-color-history))
3423                        (t
3424                         (read-string prompt (widget-value widget))))))
3425     (unless (zerop (length answer))
3426       (widget-value-set widget answer)
3427       (widget-setup)
3428       (widget-apply widget :notify widget event))))
3429
3430 (defun widget-color-notify (widget child &optional event)
3431   "Update the sample, and notofy the parent."
3432   (overlay-put (widget-get widget :sample-overlay)
3433                'face (widget-apply widget :sample-face-get))
3434   (widget-default-notify widget child event))
3435
3436 ;;; The Help Echo
3437
3438 (defun widget-echo-help-mouse ()
3439   "Display the help message for the widget under the mouse.
3440 Enable with (run-with-idle-timer 1 t 'widget-echo-help-mouse)"
3441   (let* ((pos (mouse-position))
3442          (frame (car pos))
3443          (x (car (cdr pos)))
3444          (y (cdr (cdr pos)))
3445          (win (window-at x y frame))
3446          (where (coordinates-in-window-p (cons x y) win)))
3447     (when (consp where)
3448       (save-window-excursion
3449         (progn ; save-excursion
3450           (select-window win)
3451           (let* ((result (compute-motion (window-start win)
3452                                          '(0 . 0)
3453                                          (window-end win)
3454                                          where
3455                                          (window-width win)
3456                                          (cons (window-hscroll) 0)
3457                                          win)))
3458             (when (and (eq (nth 1 result) x)
3459                        (eq (nth 2 result) y))
3460               (widget-echo-help (nth 0 result))))))))
3461   (unless track-mouse
3462     (setq track-mouse t)
3463     (add-hook 'post-command-hook 'widget-stop-mouse-tracking)))
3464
3465 (defun widget-stop-mouse-tracking (&rest args)
3466   "Stop the mouse tracking done while idle."
3467   (remove-hook 'post-command-hook 'widget-stop-mouse-tracking)
3468   (setq track-mouse nil))
3469
3470 (defun widget-at (pos)
3471   "The button or field at POS."
3472   (or (get-char-property pos 'button)
3473       (get-char-property pos 'field)))
3474
3475 (defun widget-echo-help (pos)
3476   "Display the help echo for widget at POS."
3477   (let* ((widget (widget-at pos))
3478          (help-echo (and widget (widget-get widget :help-echo))))
3479     (cond ((stringp help-echo)
3480            (message "%s" help-echo))
3481           ((and (symbolp help-echo) (fboundp help-echo)
3482                 (stringp (setq help-echo (funcall help-echo widget))))
3483            (message "%s" help-echo)))))
3484
3485 ;;; The End:
3486
3487 (provide 'wid-edit)
3488
3489 ;; wid-edit.el ends here