lisp/vc-git.el

   1 ;;; vc-git.el --- VC backend for the git version control system
   2
   3 ;; Copyright (C) 2006, 2007, 2008 Free Software Foundation, Inc.
   4
   5 ;; Author: Alexandre Julliard <julliard@winehq.org>
   6 ;; Keywords: tools
   7
   8 ;; This file is part of GNU Emacs.
   9
  10 ;; GNU Emacs is free software: you can redistribute it and/or modify
  11 ;; it under the terms of the GNU General Public License as published by
  12 ;; the Free Software Foundation, either version 3 of the License, or
  13 ;; (at your option) any later version.
  14
  15 ;; GNU Emacs is distributed in the hope that it will be useful,
  16 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  17 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  18 ;; GNU General Public License for more details.
  19
  20 ;; You should have received a copy of the GNU General Public License
  21 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  22
  23 ;;; Commentary:
  24
  25 ;; This file contains a VC backend for the git version control
  26 ;; system.
  27 ;;
  28
  29 ;;; Installation:
  30
  31 ;; To install: put this file on the load-path and add Git to the list
  32 ;; of supported backends in `vc-handled-backends'; the following line,
  33 ;; placed in your ~/.emacs, will accomplish this:
  34 ;;
  35 ;;     (add-to-list 'vc-handled-backends 'Git)
  36
  37 ;;; Todo:
  38 ;;  - check if more functions could use vc-git-command instead
  39 ;;     of start-process.
  40 ;;  - changelog generation
  41
  42 ;; Implement the rest of the vc interface. See the comment at the
  43 ;; beginning of vc.el. The current status is:
  44 ;; ("??" means: "figure out what to do about it")
  45 ;;
  46 ;; FUNCTION NAME                        STATUS
  47 ;; BACKEND PROPERTIES
  48 ;; * revision-granularity                      OK
  49 ;; STATE-QUERYING FUNCTIONS
  50 ;; * registered (file)                     OK
  51 ;; * state (file)                                  OK
  52 ;; - state-heuristic (file)                        NOT NEEDED
  53 ;; * working-revision (file)               OK
  54 ;; - latest-on-branch-p (file)             NOT NEEDED
  55 ;; * checkout-model (files)                OK
  56 ;; - workfile-unchanged-p (file)                   OK
  57 ;; - mode-line-string (file)                       OK
  58 ;; STATE-CHANGING FUNCTIONS
  59 ;; * create-repo ()                        OK
  60 ;; * register (files &optional rev comment)    OK
  61 ;; - init-revision (file)                          NOT NEEDED
  62 ;; - responsible-p (file)                          OK
  63 ;; - could-register (file)                         NOT NEEDED, DEFAULT IS GOOD
  64 ;; - receive-file (file rev)                       NOT NEEDED
  65 ;; - unregister (file)                     OK
  66 ;; * checkin (files rev comment)                   OK
  67 ;; * find-revision (file rev buffer)               OK
  68 ;; * checkout (file &optional editable rev)        OK
  69 ;; * revert (file &optional contents-done)         OK
  70 ;; - rollback (files)                      COULD BE SUPPORTED
  71 ;; - merge (file rev1 rev2)                   It would be possible to merge
  72 ;;                                          changes into a single file, but when
  73 ;;                                          committing they wouldn't
  74 ;;                                          be identified as a merge
  75 ;;                                          by git, so it's probably
  76 ;;                                          not a good idea.
  77 ;; - merge-news (file)                     see `merge'
  78 ;; - steal-lock (file &optional revision)          NOT NEEDED
  79 ;; HISTORY FUNCTIONS
  80 ;; * print-log (files &optional buffer)            OK
  81 ;; - log-view-mode ()                              OK
  82 ;; - show-log-entry (revision)                     OK
  83 ;; - comment-history (file)                        ??
  84 ;; - update-changelog (files)                      COULD BE SUPPORTED
  85 ;; * diff (file &optional rev1 rev2 buffer)                OK
  86 ;; - revision-completion-table (files)             OK
  87 ;; - annotate-command (file buf &optional rev)     OK
  88 ;; - annotate-time ()                              OK
  89 ;; - annotate-current-time ()                      NOT NEEDED
  90 ;; - annotate-extract-revision-at-line ()                  OK
  91 ;; TAG SYSTEM
  92 ;; - create-tag (dir name branchp)         OK
  93 ;; - retrieve-tag (dir name update)        OK, needs to update buffers
  94 ;; MISCELLANEOUS
  95 ;; - make-version-backups-p (file)         NOT NEEDED
  96 ;; - repository-hostname (dirname)         NOT NEEDED
  97 ;; - previous-revision (file rev)                  OK
  98 ;; - next-revision (file rev)              OK
  99 ;; - check-headers ()                      COULD BE SUPPORTED
 100 ;; - clear-headers ()                      NOT NEEDED
 101 ;; - delete-file (file)                    OK
 102 ;; - rename-file (old new)                 OK
 103 ;; - find-file-hook ()                     NOT NEEDED
 104 ;; - find-file-not-found-hook ()                NOT NEEDED
 105
 106 (eval-when-compile
 107   (require 'cl)
 108   (require 'vc)
 109   (require 'vc-dir)
 110   (require 'grep))
 111
 112 (defvar git-commits-coding-system 'utf-8
 113   "Default coding system for git commits.")
 114
 115 ;;; BACKEND PROPERTIES
 116
 117 (defun vc-git-revision-granularity () 'repository)
 118 (defun vc-git-checkout-model (files) 'implicit)
 119
 120 ;;; STATE-QUERYING FUNCTIONS
 121
 122 ;;;###autoload (defun vc-git-registered (file)
 123 ;;;###autoload   "Return non-nil if FILE is registered with git."
 124 ;;;###autoload   (if (vc-find-root file ".git")       ; short cut
 125 ;;;###autoload       (progn
 126 ;;;###autoload         (load "vc-git")
 127 ;;;###autoload         (vc-git-registered file))))
 128
 129 (defun vc-git-registered (file)
 130   "Check whether FILE is registered with git."
 131   (when (vc-git-root file)
 132     (with-temp-buffer
 133       (let* ((dir (file-name-directory file))
 134              (name (file-relative-name file dir))
 135              (str (ignore-errors
 136                     (when dir (cd dir))
 137                     (vc-git--out-ok "ls-files" "-c" "-z" "--" name)
 138                     ;; if result is empty, use ls-tree to check for deleted file
 139                     (when (eq (point-min) (point-max))
 140                       (vc-git--out-ok "ls-tree" "--name-only" "-z" "HEAD" "--" name))
 141                     (buffer-string))))
 142         (and str
 143              (> (length str) (length name))
 144              (string= (substring str 0 (1+ (length name)))
 145                       (concat name "\0")))))))
 146
 147 (defun vc-git--state-code (code)
 148   "Convert from a string to a added/deleted/modified state."
 149   (case (string-to-char code)
 150     (?M 'edited)
 151     (?A 'added)
 152     (?D 'removed)
 153     (?U 'edited)     ;; FIXME
 154     (?T 'edited)))   ;; FIXME
 155
 156 (defun vc-git-state (file)
 157   "Git-specific version of `vc-state'."
 158   ;; FIXME: This can't set 'ignored yet
 159   (if (not (vc-git-registered file))
 160       'unregistered
 161     (vc-git--call nil "add" "--refresh" "--" (file-relative-name file))
 162     (let ((diff (vc-git--run-command-string file "diff-index" "-z" "HEAD" "--")))
 163       (if (and diff (string-match ":[0-7]\\{6\\} [0-7]\\{6\\} [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\([ADMUT]\\)\0[^\0]+\0"
 164                                   diff))
 165           (vc-git--state-code (match-string 1 diff))
 166         (if (vc-git--empty-db-p) 'added 'up-to-date)))))
 167
 168 (defun vc-git-working-revision (file)
 169   "Git-specific version of `vc-working-revision'."
 170   (let ((str (with-output-to-string
 171                (with-current-buffer standard-output
 172                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 173     (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 174         (match-string 2 str)
 175       str)))
 176
 177 (defun vc-git-workfile-unchanged-p (file)
 178   (eq 'up-to-date (vc-git-state file)))
 179
 180 (defun vc-git-mode-line-string (file)
 181   "Return string for placement into the modeline for FILE."
 182   (let* ((branch (vc-git-working-revision file))
 183          (def-ml (vc-default-mode-line-string 'Git file))
 184          (help-echo (get-text-property 0 'help-echo def-ml)))
 185     (if (zerop (length branch))
 186         (propertize
 187          (concat def-ml "!")
 188          'help-echo (concat help-echo "\nNo current branch (detached HEAD)"))
 189       (propertize def-ml
 190                   'help-echo (concat help-echo "\nCurrent branch: " branch)))))
 191
 192 (defstruct (vc-git-extra-fileinfo
 193             (:copier nil)
 194             (:constructor vc-git-create-extra-fileinfo (old-perm new-perm &optional rename-state orig-name))
 195             (:conc-name vc-git-extra-fileinfo->))
 196   old-perm new-perm   ;; permission flags
 197   rename-state        ;; rename or copy state
 198   orig-name)          ;; original name for renames or copies
 199
 200 (defun vc-git-escape-file-name (name)
 201   "Escape a file name if necessary."
 202   (if (string-match "[\n\t\"\\]" name)
 203       (concat "\""
 204               (mapconcat (lambda (c)
 205                    (case c
 206                      (?\n "\\n")
 207                      (?\t "\\t")
 208                      (?\\ "\\\\")
 209                      (?\" "\\\"")
 210                      (t (char-to-string c))))
 211                  name "")
 212               "\"")
 213     name))
 214
 215 (defun vc-git-file-type-as-string (old-perm new-perm)
 216   "Return a string describing the file type based on its permissions."
 217   (let* ((old-type (lsh (or old-perm 0) -9))
 218          (new-type (lsh (or new-perm 0) -9))
 219          (str (case new-type
 220                 (?\100  ;; file
 221                  (case old-type
 222                    (?\100 nil)
 223                    (?\120 "   (type change symlink -> file)")
 224                    (?\160 "   (type change subproject -> file)")))
 225                  (?\120  ;; symlink
 226                   (case old-type
 227                     (?\100 "   (type change file -> symlink)")
 228                     (?\160 "   (type change subproject -> symlink)")
 229                     (t "   (symlink)")))
 230                   (?\160  ;; subproject
 231                    (case old-type
 232                      (?\100 "   (type change file -> subproject)")
 233                      (?\120 "   (type change symlink -> subproject)")
 234                      (t "   (subproject)")))
 235                   (?\110 nil)  ;; directory (internal, not a real git state)
 236                   (?\000  ;; deleted or unknown
 237                    (case old-type
 238                      (?\120 "   (symlink)")
 239                      (?\160 "   (subproject)")))
 240                   (t (format "   (unknown type %o)" new-type)))))
 241     (cond (str (propertize str 'face 'font-lock-comment-face))
 242           ((eq new-type ?\110) "/")
 243           (t ""))))
 244
 245 (defun vc-git-rename-as-string (state extra)
 246   "Return a string describing the copy or rename associated with INFO, or an empty string if none."
 247   (let ((rename-state (when extra
 248                         (vc-git-extra-fileinfo->rename-state extra))))
 249     (if rename-state
 250         (propertize
 251          (concat "   ("
 252                  (if (eq rename-state 'copy) "copied from "
 253                    (if (eq state 'added) "renamed from "
 254                      "renamed to "))
 255                  (vc-git-escape-file-name (vc-git-extra-fileinfo->orig-name extra))
 256                  ")") 'face 'font-lock-comment-face)
 257       "")))
 258
 259 (defun vc-git-permissions-as-string (old-perm new-perm)
 260   "Format a permission change as string."
 261   (propertize
 262    (if (or (not old-perm)
 263            (not new-perm)
 264            (eq 0 (logand ?\111 (logxor old-perm new-perm))))
 265        "  "
 266      (if (eq 0 (logand ?\111 old-perm)) "+x" "-x"))
 267   'face 'font-lock-type-face))
 268
 269 (defun vc-git-status-printer (info)
 270   "Pretty-printer for the vc-dir-fileinfo structure."
 271   (let* ((state (if (vc-dir-fileinfo->directory info)
 272                     'DIRECTORY
 273                   (vc-dir-fileinfo->state info)))
 274          (extra (vc-dir-fileinfo->extra info))
 275          (old-perm (when extra (vc-git-extra-fileinfo->old-perm extra)))
 276          (new-perm (when extra (vc-git-extra-fileinfo->new-perm extra))))
 277     (insert
 278      "  "
 279      (propertize (format "%c" (if (vc-dir-fileinfo->marked info) ?* ? ))
 280                  'face 'font-lock-type-face)
 281      "  "
 282      (propertize
 283       (format "%-12s" state)
 284       'face (cond ((eq state 'up-to-date) 'font-lock-builtin-face)
 285                   ((eq state 'missing) 'font-lock-warning-face)
 286                   (t 'font-lock-variable-name-face))
 287       'mouse-face 'highlight)
 288      "  " (vc-git-permissions-as-string old-perm new-perm)
 289      "     "
 290      (propertize (vc-git-escape-file-name (vc-dir-fileinfo->name info))
 291                  'face 'font-lock-function-name-face
 292                  'mouse-face 'highlight)
 293      (vc-git-file-type-as-string old-perm new-perm)
 294      (vc-git-rename-as-string state extra))))
 295
 296 (defun vc-git-after-dir-status-stage (stage files update-function)
 297   "Process sentinel for the various dir-status stages."
 298   (let (remaining next-stage result)
 299     (goto-char (point-min))
 300     (case stage
 301       ('update-index
 302        (setq next-stage (if (vc-git--empty-db-p) 'ls-files-added
 303                           (if files 'ls-files-up-to-date 'diff-index))))
 304       ('ls-files-added
 305        (setq next-stage 'ls-files-unknown)
 306        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 307          (let ((new-perm (string-to-number (match-string 1) 8))
 308                (name (match-string 2)))
 309            (push (list name 'added (vc-git-create-extra-fileinfo 0 new-perm)) result))))
 310       ('ls-files-up-to-date
 311        (setq next-stage 'diff-index)
 312        (while (re-search-forward "\\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} 0\t\\([^\0]+\\)\0" nil t)
 313          (let ((perm (string-to-number (match-string 1) 8))
 314                (name (match-string 2)))
 315            (push (list name 'up-to-date (vc-git-create-extra-fileinfo perm perm)) result))))
 316       ('ls-files-unknown
 317        (when files (setq next-stage 'ls-files-ignored))
 318        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 319          (push (list (match-string 1) 'unregistered (vc-git-create-extra-fileinfo 0 0)) result)))
 320       ('ls-files-ignored
 321        (while (re-search-forward "\\([^\0]*?\\)\0" nil t 1)
 322          (push (list (match-string 1) 'ignored (vc-git-create-extra-fileinfo 0 0)) result)))
 323       ('diff-index
 324        (setq next-stage 'ls-files-unknown)
 325        (while (re-search-forward
 326                ":\\([0-7]\\{6\\}\\) \\([0-7]\\{6\\}\\) [0-9a-f]\\{40\\} [0-9a-f]\\{40\\} \\(\\([ADMUT]\\)\0\\([^\0]+\\)\\|\\([CR]\\)[0-9]*\0\\([^\0]+\\)\0\\([^\0]+\\)\\)\0"
 327                nil t 1)
 328          (let ((old-perm (string-to-number (match-string 1) 8))
 329                (new-perm (string-to-number (match-string 2) 8))
 330                (state (or (match-string 4) (match-string 6)))
 331                (name (or (match-string 5) (match-string 7)))
 332                (new-name (match-string 8)))
 333            (if new-name  ; copy or rename
 334                (if (eq ?C (string-to-char state))
 335                    (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'copy name)) result)
 336                  (push (list name 'removed (vc-git-create-extra-fileinfo 0 0 'rename new-name)) result)
 337                  (push (list new-name 'added (vc-git-create-extra-fileinfo old-perm new-perm 'rename name)) result))
 338              (push (list name (vc-git--state-code state) (vc-git-create-extra-fileinfo old-perm new-perm)) result))))))
 339     (when result
 340       (setq result (nreverse result))
 341       (when files
 342         (dolist (entry result) (setq files (delete (car entry) files)))
 343         (unless files (setq next-stage nil))))
 344     (when (or result (not next-stage)) (funcall update-function result next-stage))
 345     (when next-stage (vc-git-dir-status-goto-stage next-stage files update-function))))
 346
 347 (defun vc-git-dir-status-goto-stage (stage files update-function)
 348   (erase-buffer)
 349   (case stage
 350     ('update-index
 351      (if files
 352          (vc-git-command (current-buffer) 'async files "add" "--refresh" "--")
 353        (vc-git-command (current-buffer) 'async nil "update-index" "--refresh")))
 354     ('ls-files-added
 355      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 356     ('ls-files-up-to-date
 357      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-c" "-s" "--"))
 358     ('ls-files-unknown
 359      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o"
 360                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 361     ('ls-files-ignored
 362      (vc-git-command (current-buffer) 'async files "ls-files" "-z" "-o" "-i"
 363                      "--directory" "--no-empty-directory" "--exclude-standard" "--"))
 364     ('diff-index
 365      (vc-git-command (current-buffer) 'async files "diff-index" "-z" "-M" "HEAD" "--")))
 366   (vc-exec-after
 367    `(vc-git-after-dir-status-stage (quote ,stage) (quote ,files) (quote ,update-function))))
 368
 369 (defun vc-git-dir-status (dir update-function)
 370   "Return a list of (FILE STATE EXTRA) entries for DIR."
 371   ;; Further things that would have to be fixed later:
 372   ;; - how to handle unregistered directories
 373   ;; - how to support vc-dir on a subdir of the project tree
 374   (vc-git-dir-status-goto-stage 'update-index nil update-function))
 375
 376 (defun vc-git-dir-status-files (dir files default-state update-function)
 377   "Return a list of (FILE STATE EXTRA) entries for FILES in DIR."
 378   (vc-git-dir-status-goto-stage 'update-index files update-function))
 379
 380 (defun vc-git-status-extra-headers (dir)
 381   (let ((str (with-output-to-string
 382                (with-current-buffer standard-output
 383                  (vc-git--out-ok "symbolic-ref" "HEAD")))))
 384     (concat
 385      (propertize "Branch     : " 'face 'font-lock-type-face)
 386      (propertize
 387       (if (string-match "^\\(refs/heads/\\)?\\(.+\\)$" str)
 388           (match-string 2 str)
 389         "not (detached HEAD)")
 390        'face 'font-lock-variable-name-face))))
 391
 392 ;;; STATE-CHANGING FUNCTIONS
 393
 394 (defun vc-git-create-repo ()
 395   "Create a new Git repository."
 396   (vc-git-command nil 0 nil "init"))
 397
 398 (defun vc-git-register (files &optional rev comment)
 399   "Register FILE into the git version-control system."
 400   (vc-git-command nil 0 files "update-index" "--add" "--"))
 401
 402 (defalias 'vc-git-responsible-p 'vc-git-root)
 403
 404 (defun vc-git-unregister (file)
 405   (vc-git-command nil 0 file "rm" "-f" "--cached" "--"))
 406
 407
 408 (defun vc-git-checkin (files rev comment)
 409   (let ((coding-system-for-write git-commits-coding-system))
 410     (vc-git-command nil 0 files "commit" "-m" comment "--only" "--")))
 411
 412 (defun vc-git-find-revision (file rev buffer)
 413   (let ((coding-system-for-read 'binary)
 414         (coding-system-for-write 'binary)
 415         (fullname (substring
 416                    (vc-git--run-command-string
 417                     file "ls-files" "-z" "--full-name" "--")
 418                    0 -1)))
 419     (vc-git-command
 420      buffer 0
 421      (concat (if rev rev "HEAD") ":" fullname) "cat-file" "blob")))
 422
 423 (defun vc-git-checkout (file &optional editable rev)
 424   (vc-git-command nil 0 file "checkout" (or rev "HEAD")))
 425
 426 (defun vc-git-revert (file &optional contents-done)
 427   "Revert FILE to the version stored in the git repository."
 428   (if contents-done
 429       (vc-git-command nil 0 file "update-index" "--")
 430     (vc-git-command nil 0 file "checkout" "HEAD")))
 431
 432 ;;; HISTORY FUNCTIONS
 433
 434 (defun vc-git-print-log (files &optional buffer)
 435   "Get change log associated with FILES."
 436   (let ((coding-system-for-read git-commits-coding-system)
 437         ;; Support both the old print-log interface that passes a
 438         ;; single file, and the new one that passes a file list.
 439         (flist (if (listp files) files (list files))))
 440     ;; `vc-do-command' creates the buffer, but we need it before running
 441     ;; the command.
 442     (vc-setup-buffer buffer)
 443     ;; If the buffer exists from a previous invocation it might be
 444     ;; read-only.
 445     (let ((inhibit-read-only t))
 446       (with-current-buffer
 447           buffer
 448         (vc-git-command buffer 'async files
 449                         "rev-list" "--pretty" "HEAD" "--")))))
 450
 451 (defvar log-view-message-re)
 452 (defvar log-view-file-re)
 453 (defvar log-view-font-lock-keywords)
 454 (defvar log-view-per-file-logs)
 455
 456 (define-derived-mode vc-git-log-view-mode log-view-mode "Git-Log-View"
 457   (require 'add-log) ;; we need the faces add-log
 458   ;; Don't have file markers, so use impossible regexp.
 459   (set (make-local-variable 'log-view-file-re) "\\`a\\`")
 460   (set (make-local-variable 'log-view-per-file-logs) nil)
 461   (set (make-local-variable 'log-view-message-re)
 462        "^commit *\\([0-9a-z]+\\)")
 463   (set (make-local-variable 'log-view-font-lock-keywords)
 464        (append
 465         `((,log-view-message-re  (1 'change-log-acknowledgement)))
 466         ;; Handle the case:
 467         ;; user: foo@bar
 468         '(("^Author:[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 469            (1 'change-log-email))
 470           ;; Handle the case:
 471           ;; user: FirstName LastName <foo@bar>
 472           ("^Author:[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 473            (1 'change-log-name)
 474            (2 'change-log-email))
 475           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)"
 476            (1 'change-log-name))
 477           ("^ +\\(?:\\(?:[Aa]cked\\|[Ss]igned-[Oo]ff\\)-[Bb]y:\\)[ \t]+\\([^<(]+?\\)[ \t]*[(<]\\([A-Za-z0-9_.+-]+@[A-Za-z0-9_.-]+\\)[>)]"
 478            (1 'change-log-name)
 479            (2 'change-log-email))
 480           ("^Merge: \\([0-9a-z]+\\) \\([0-9a-z]+\\)"
 481            (1 'change-log-acknowledgement)
 482            (2 'change-log-acknowledgement))
 483           ("^Date:   \\(.+\\)" (1 'change-log-date))
 484           ("^summary:[ \t]+\\(.+\\)" (1 'log-view-message))))))
 485
 486 (defun vc-git-show-log-entry (revision)
 487   "Move to the log entry for REVISION.
 488 REVISION may have the form BRANCH, BRANCH~N,
 489 or BRANCH^ (where \"^\" can be repeated)."
 490   (goto-char (point-min))
 491   (search-forward "\ncommit" nil t
 492                   (cond ((string-match "~\\([0-9]\\)$" revision)
 493                          (1+ (string-to-number (match-string 1 revision))))
 494                         ((string-match "\\^+$" revision)
 495                          (1+ (length (match-string 0 revision))))
 496                         (t nil)))
 497   (beginning-of-line))
 498
 499 (defun vc-git-diff (files &optional rev1 rev2 buffer)
 500   (let ((buf (or buffer "*vc-diff*")))
 501     (if (and rev1 rev2)
 502         (vc-git-command buf 1 files "diff-tree" "--exit-code" "-p"
 503                         rev1 rev2 "--")
 504       (vc-git-command buf 1 files "diff-index" "--exit-code" "-p"
 505                       (or rev1 "HEAD") "--"))))
 506
 507 (defun vc-git-revision-table (files)
 508   ;; What about `files'?!?  --Stef
 509   (let ((table (list "HEAD")))
 510     (with-temp-buffer
 511       (vc-git-command t nil nil "for-each-ref" "--format=%(refname)")
 512       (goto-char (point-min))
 513       (while (re-search-forward "^refs/\\(heads\\|tags\\)/\\(.*\\)$" nil t)
 514         (push (match-string 2) table)))
 515     table))
 516
 517 (defun vc-git-revision-completion-table (files)
 518   (lexical-let ((files files)
 519                 table)
 520     (setq table (lazy-completion-table
 521                  table (lambda () (vc-git-revision-table files))))
 522     table))
 523
 524 (defun vc-git-annotate-command (file buf &optional rev)
 525   (let ((name (file-relative-name file)))
 526     (vc-git-command buf 0 name "blame" rev)))
 527
 528 (declare-function vc-annotate-convert-time "vc-annotate" (time))
 529
 530 (defun vc-git-annotate-time ()
 531   (and (re-search-forward "[0-9a-f]+[^()]+(.* \\([0-9]+\\)-\\([0-9]+\\)-\\([0-9]+\\) \\([0-9]+\\):\\([0-9]+\\):\\([0-9]+\\) \\([-+0-9]+\\) +[0-9]+) " nil t)
 532        (vc-annotate-convert-time
 533         (apply #'encode-time (mapcar (lambda (match)
 534                                        (string-to-number (match-string match)))
 535                                      '(6 5 4 3 2 1 7))))))
 536
 537 (defun vc-git-annotate-extract-revision-at-line ()
 538   (save-excursion
 539     (move-beginning-of-line 1)
 540     (and (looking-at "[0-9a-f^][0-9a-f]+")
 541          (buffer-substring-no-properties (match-beginning 0) (match-end 0)))))
 542
 543 ;;; TAG SYSTEM
 544
 545 (defun vc-git-create-tag (dir name branchp)
 546   (let ((default-directory dir))
 547     (and (vc-git-command nil 0 nil "update-index" "--refresh")
 548          (if branchp
 549              (vc-git-command nil 0 nil "checkout" "-b" name)
 550            (vc-git-command nil 0 nil "tag" name)))))
 551
 552 (defun vc-git-retrieve-tag (dir name update)
 553   (let ((default-directory dir))
 554     (vc-git-command nil 0 nil "checkout" name)
 555     ;; FIXME: update buffers if `update' is true
 556     ))
 557
 558
 559 ;;; MISCELLANEOUS
 560
 561 (defun vc-git-previous-revision (file rev)
 562   "Git-specific version of `vc-previous-revision'."
 563   (if file
 564       (let ((default-directory (file-name-directory (expand-file-name file)))
 565             (file (file-name-nondirectory file)))
 566         (vc-git-symbolic-commit
 567          (with-temp-buffer
 568            (and
 569             (vc-git--out-ok "rev-list" "-2" rev "--" file)
 570             (goto-char (point-max))
 571             (bolp)
 572             (zerop (forward-line -1))
 573             (not (bobp))
 574             (buffer-substring-no-properties
 575              (point)
 576              (1- (point-max)))))))
 577     (with-temp-buffer
 578       (and
 579        (vc-git--out-ok "rev-parse" (concat rev "^"))
 580        (buffer-substring-no-properties (point-min) (+ (point-min) 40))))))
 581
 582 (defun vc-git-next-revision (file rev)
 583   "Git-specific version of `vc-next-revision'."
 584   (let* ((default-directory (file-name-directory
 585                              (expand-file-name file)))
 586          (file (file-name-nondirectory file))
 587          (current-rev
 588           (with-temp-buffer
 589             (and
 590              (vc-git--out-ok "rev-list" "-1" rev "--" file)
 591              (goto-char (point-max))
 592              (bolp)
 593              (zerop (forward-line -1))
 594              (bobp)
 595              (buffer-substring-no-properties
 596               (point)
 597               (1- (point-max)))))))
 598     (and current-rev
 599          (vc-git-symbolic-commit
 600           (with-temp-buffer
 601             (and
 602              (vc-git--out-ok "rev-list" "HEAD" "--" file)
 603              (goto-char (point-min))
 604              (search-forward current-rev nil t)
 605              (zerop (forward-line -1))
 606              (buffer-substring-no-properties
 607               (point)
 608               (progn (forward-line 1) (1- (point))))))))))
 609
 610 (defun vc-git-delete-file (file)
 611   (vc-git-command nil 0 file "rm" "-f" "--"))
 612
 613 (defun vc-git-rename-file (old new)
 614   (vc-git-command nil 0 (list old new) "mv" "-f" "--"))
 615
 616 (defvar vc-git-extra-menu-map
 617   (let ((map (make-sparse-keymap)))
 618     (define-key map [git-grep]
 619       '(menu-item "Git grep..." vc-git-grep
 620                   :help "Run the `git grep' command"))
 621     map))
 622
 623 (defun vc-git-extra-menu () vc-git-extra-menu-map)
 624
 625 (defun vc-git-extra-status-menu () vc-git-extra-menu-map)
 626
 627 ;; Derived from `lgrep'.
 628 (defun vc-git-grep (regexp &optional files dir)
 629   "Run git grep, searching for REGEXP in FILES in directory DIR.
 630 The search is limited to file names matching shell pattern FILES.
 631 FILES may use abbreviations defined in `grep-files-aliases', e.g.
 632 entering `ch' is equivalent to `*.[ch]'.
 633
 634 With \\[universal-argument] prefix, you can edit the constructed shell command line
 635 before it is executed.
 636 With two \\[universal-argument] prefixes, directly edit and run `grep-command'.
 637
 638 Collect output in a buffer.  While git grep runs asynchronously, you
 639 can use \\[next-error] (M-x next-error), or \\<grep-mode-map>\\[compile-goto-error] \
 640 in the grep output buffer,
 641 to go to the lines where grep found matches.
 642
 643 This command shares argument histories with \\[rgrep] and \\[grep]."
 644   (interactive
 645    (progn
 646      (grep-compute-defaults)
 647      (cond
 648       ((equal current-prefix-arg '(16))
 649        (list (read-from-minibuffer "Run: " "git grep"
 650                                    nil nil 'grep-history)
 651              nil))
 652       (t (let* ((regexp (grep-read-regexp))
 653                 (files (grep-read-files regexp))
 654                 (dir (read-directory-name "In directory: "
 655                                           nil default-directory t)))
 656            (list regexp files dir))))))
 657   (require 'grep)
 658   (when (and (stringp regexp) (> (length regexp) 0))
 659     (let ((command regexp))
 660       (if (null files)
 661           (if (string= command "git grep")
 662               (setq command nil))
 663         (setq dir (file-name-as-directory (expand-file-name dir)))
 664         (setq command
 665               (grep-expand-template "git grep -n -e <R> -- <F>" regexp files))
 666         (when command
 667           (if (equal current-prefix-arg '(4))
 668               (setq command
 669                     (read-from-minibuffer "Confirm: "
 670                                           command nil nil 'grep-history))
 671             (add-to-history 'grep-history command))))
 672       (when command
 673         (let ((default-directory dir)
 674               (compilation-environment '("PAGER=")))
 675           ;; Setting process-setup-function makes exit-message-function work
 676           ;; even when async processes aren't supported.
 677           (compilation-start command 'grep-mode))
 678         (if (eq next-error-last-buffer (current-buffer))
 679             (setq default-directory dir))))))
 680 \f
 681 ;;; Internal commands
 682
 683 (defun vc-git-root (file)
 684   (vc-find-root file ".git"))
 685
 686 (defun vc-git-command (buffer okstatus file-or-list &rest flags)
 687   "A wrapper around `vc-do-command' for use in vc-git.el.
 688 The difference to vc-do-command is that this function always invokes `git'."
 689   (apply 'vc-do-command (or buffer "*vc*") okstatus "git" file-or-list flags))
 690
 691 (defun vc-git--empty-db-p ()
 692   "Check if the git db is empty (no commit done yet)."
 693   (not (eq 0 (vc-git--call nil "rev-parse" "--verify" "HEAD"))))
 694
 695 (defun vc-git--call (buffer command &rest args)
 696   ;; We don't need to care the arguments.  If there is a file name, it
 697   ;; is always a relative one.  This works also for remote
 698   ;; directories.
 699   (apply 'process-file "git" nil buffer nil command args))
 700
 701 (defun vc-git--out-ok (command &rest args)
 702   (zerop (apply 'vc-git--call '(t nil) command args)))
 703
 704 (defun vc-git--run-command-string (file &rest args)
 705   "Run a git command on FILE and return its output as string."
 706   (let* ((ok t)
 707          (str (with-output-to-string
 708                 (with-current-buffer standard-output
 709                   (unless (apply 'vc-git--out-ok
 710                                  (append args (list (file-relative-name
 711                                                      file))))
 712                     (setq ok nil))))))
 713     (and ok str)))
 714
 715 (defun vc-git-symbolic-commit (commit)
 716   "Translate COMMIT string into symbolic form.
 717 Returns nil if not possible."
 718   (and commit
 719        (with-temp-buffer
 720          (and
 721           (vc-git--out-ok "name-rev" "--name-only" "--tags" commit)
 722           (goto-char (point-min))
 723           (= (forward-line 2) 1)
 724           (bolp)
 725           (buffer-substring-no-properties (point-min) (1- (point-max)))))))
 726
 727 (provide 'vc-git)
 728
 729 ;; arch-tag: bd10664a-0e5b-48f5-a877-6c17b135be12
 730 ;;; vc-git.el ends here