configure.in

   1 dnl  Autoconf script for GNU Emacs
   2 dnl To rebuild the `configure' script from this, execute the command
   3 dnl     autoconf
   4 dnl in the directory containing this script.
   5 dnl If you changed any AC_DEFINES, also run autoheader.
   6 dnl
   7 dnl Copyright (C) 1994-1996, 1999-2012 Free Software Foundation, Inc.
   8 dnl
   9 dnl  This file is part of GNU Emacs.
  10 dnl
  11 dnl  GNU Emacs is free software: you can redistribute it and/or modify
  12 dnl  it under the terms of the GNU General Public License as published by
  13 dnl  the Free Software Foundation, either version 3 of the License, or
  14 dnl  (at your option) any later version.
  15 dnl
  16 dnl  GNU Emacs is distributed in the hope that it will be useful,
  17 dnl  but WITHOUT ANY WARRANTY; without even the implied warranty of
  18 dnl  MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  19 dnl  GNU General Public License for more details.
  20 dnl
  21 dnl  You should have received a copy of the GNU General Public License
  22 dnl  along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  23
  24 AC_PREREQ(2.65)
  25 AC_INIT(emacs, 24.1.50)
  26 AC_CONFIG_HEADER(src/config.h:src/config.in)
  27 AC_CONFIG_SRCDIR(src/lisp.h)
  28 AC_CONFIG_AUX_DIR(build-aux)
  29 AM_INIT_AUTOMAKE
  30
  31 dnl Support for --program-prefix, --program-suffix and
  32 dnl --program-transform-name options
  33 AC_ARG_PROGRAM
  34
  35 dnl It is important that variables on the RHS not be expanded here,
  36 dnl hence the single quotes.  This is per the GNU coding standards, see
  37 dnl (autoconf) Installation Directory Variables
  38 dnl See also epaths.h below.
  39 lispdir='${datadir}/emacs/${version}/lisp'
  40 leimdir='${datadir}/emacs/${version}/leim'
  41 locallisppath='${datadir}/emacs/${version}/site-lisp:'\
  42 '${datadir}/emacs/site-lisp'
  43 lisppath='${locallisppath}:${lispdir}:${datadir}/emacs/${version}/leim'
  44 etcdir='${datadir}/emacs/${version}/etc'
  45 archlibdir='${libexecdir}/emacs/${version}/${configuration}'
  46 docdir='${datadir}/emacs/${version}/etc'
  47 gamedir='${localstatedir}/games/emacs'
  48
  49 dnl OPTION_DEFAULT_OFF(NAME, HELP-STRING)
  50 dnl Create a new --with option that defaults to being disabled.
  51 dnl NAME is the base name of the option.  The shell variable with_NAME
  52 dnl   will be set to either the user's value (if the option is
  53 dnl   specified; 'yes' for a plain --with-NAME) or to 'no' (if the
  54 dnl   option is not specified).  Note that the shell variable name is
  55 dnl   constructed as autoconf does, by replacing non-alphanumeric
  56 dnl   characters with "_".
  57 dnl HELP-STRING is the help text for the option.
  58 AC_DEFUN([OPTION_DEFAULT_OFF], [dnl
  59   AC_ARG_WITH([$1],[AS_HELP_STRING([--with-$1],[$2])],[],[dnl
  60     m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=no])dnl
  61 ])dnl
  62
  63 dnl OPTION_DEFAULT_ON(NAME, HELP-STRING)
  64 dnl Create a new --with option that defaults to being enabled.  NAME
  65 dnl   is the base name of the option.  The shell variable with_NAME
  66 dnl   will be set either to 'no' (for a plain --without-NAME) or to
  67 dnl   'yes' (if the option is not specified).  Note that the shell
  68 dnl   variable name is constructed as autoconf does, by replacing
  69 dnl   non-alphanumeric characters with "_".
  70 dnl HELP-STRING is the help text for the option.
  71 AC_DEFUN([OPTION_DEFAULT_ON], [dnl
  72   AC_ARG_WITH([$1],[AS_HELP_STRING([--without-$1],[$2])],[],[dnl
  73    m4_bpatsubst([with_$1], [[^0-9a-z]], [_])=yes])dnl
  74 ])dnl
  75
  76 OPTION_DEFAULT_ON([pop],[don't support POP mail retrieval with movemail])
  77 if test "$with_pop" = yes; then
  78    AC_DEFINE(MAIL_USE_POP)
  79 fi
  80 AH_TEMPLATE(MAIL_USE_POP, [Define to support POP mail retrieval.])dnl
  81
  82 OPTION_DEFAULT_OFF([kerberos],[support Kerberos-authenticated POP])
  83 if test "$with_kerberos" != no; then
  84    AC_DEFINE(KERBEROS)
  85 fi
  86 AH_TEMPLATE(KERBEROS,
  87             [Define to support Kerberos-authenticated POP mail retrieval.])dnl
  88
  89 OPTION_DEFAULT_OFF([kerberos5],[support Kerberos version 5 authenticated POP])
  90 if test "${with_kerberos5}" != no; then
  91   if test "${with_kerberos}" = no; then
  92     with_kerberos=yes
  93     AC_DEFINE(KERBEROS)
  94   fi
  95   AC_DEFINE(KERBEROS5, 1, [Define to use Kerberos 5 instead of Kerberos 4.])
  96 fi
  97
  98 OPTION_DEFAULT_OFF([hesiod],[support Hesiod to get the POP server host])
  99 dnl FIXME hesiod support may not be present, so it seems like an error
 100 dnl to define, or at least use, this unconditionally.
 101 if test "$with_hesiod" != no; then
 102   AC_DEFINE(HESIOD, 1, [Define to support using a Hesiod database to find the POP server.])
 103 fi
 104
 105 OPTION_DEFAULT_OFF([mmdf],[support MMDF mailboxes])
 106 if test "$with_mmdf" != no; then
 107    AC_DEFINE(MAIL_USE_MMDF, 1, [Define to support MMDF mailboxes in movemail.])
 108 fi
 109
 110 OPTION_DEFAULT_OFF([mail-unlink],[unlink, rather than empty, mail spool after reading])
 111 if test "$with_mail_unlink" != no; then
 112    AC_DEFINE(MAIL_UNLINK_SPOOL, 1, [Define to unlink, rather than empty, mail spool after reading.])
 113 fi
 114
 115 AC_ARG_WITH([mailhost],[AS_HELP_STRING([--with-mailhost=HOSTNAME],
 116     [string giving default POP mail host])],
 117     AC_DEFINE_UNQUOTED(MAILHOST, ["$withval"], [String giving fallback POP mail host.]))
 118
 119 OPTION_DEFAULT_ON([sound],[don't compile with sound support])
 120
 121 OPTION_DEFAULT_ON([sync-input],[process async input synchronously])
 122 if test "$with_sync_input" = yes; then
 123    AC_DEFINE(SYNC_INPUT, 1, [Process async input synchronously.])
 124 fi
 125
 126 dnl FIXME currently it is not the last.
 127 dnl This should be the last --with option, because --with-x is
 128 dnl added later on when we find the path of X, and it's best to
 129 dnl keep them together visually.
 130 AC_ARG_WITH([x-toolkit],[AS_HELP_STRING([--with-x-toolkit=KIT],
 131  [use an X toolkit (KIT one of: yes or gtk, gtk3, lucid or athena, motif, no)])],
 132 [         case "${withval}" in
 133             y | ye | yes )      val=gtk ;;
 134             n | no )            val=no  ;;
 135             l | lu | luc | luci | lucid )       val=lucid ;;
 136             a | at | ath | athe | athen | athena )      val=athena ;;
 137             m | mo | mot | moti | motif )       val=motif ;;
 138             g | gt | gtk  )     val=gtk ;;
 139             gtk3  )     val=gtk3 ;;
 140             * )
 141 AC_MSG_ERROR([`--with-x-toolkit=$withval' is invalid;
 142 this option's value should be `yes', `no', `lucid', `athena', `motif', `gtk' or
 143 `gtk3'.  `yes' and `gtk' are synonyms. `athena' and `lucid' are synonyms.])
 144             ;;
 145           esac
 146           with_x_toolkit=$val
 147 ])
 148
 149 OPTION_DEFAULT_OFF([wide-int], [prefer wide Emacs integers (typically 62-bit)])
 150 if test "$with_wide_int" = yes; then
 151   AC_DEFINE([WIDE_EMACS_INT], 1, [Use long long for EMACS_INT if available.])
 152 fi
 153
 154 dnl _ON results in a '--without' option in the --help output, so
 155 dnl the help text should refer to "don't compile", etc.
 156 OPTION_DEFAULT_ON([xpm],[don't compile with XPM image support])
 157 OPTION_DEFAULT_ON([jpeg],[don't compile with JPEG image support])
 158 OPTION_DEFAULT_ON([tiff],[don't compile with TIFF image support])
 159 OPTION_DEFAULT_ON([gif],[don't compile with GIF image support])
 160 OPTION_DEFAULT_ON([png],[don't compile with PNG image support])
 161 OPTION_DEFAULT_ON([rsvg],[don't compile with SVG image support])
 162 OPTION_DEFAULT_ON([xml2],[don't compile with XML parsing support])
 163 OPTION_DEFAULT_ON([imagemagick],[don't compile with ImageMagick image support])
 164
 165 OPTION_DEFAULT_ON([xft],[don't use XFT for anti aliased fonts])
 166 OPTION_DEFAULT_ON([libotf],[don't use libotf for OpenType font support])
 167 OPTION_DEFAULT_ON([m17n-flt],[don't use m17n-flt for text shaping])
 168
 169 OPTION_DEFAULT_ON([toolkit-scroll-bars],[don't use Motif or Xaw3d scroll bars])
 170 OPTION_DEFAULT_ON([xaw3d],[don't use Xaw3d])
 171 OPTION_DEFAULT_ON([xim],[don't use X11 XIM])
 172 OPTION_DEFAULT_OFF([ns],[use NeXTstep (Cocoa or GNUstep) windowing system])
 173
 174 OPTION_DEFAULT_ON([gpm],[don't use -lgpm for mouse support on a GNU/Linux console])
 175 OPTION_DEFAULT_ON([dbus],[don't compile with D-Bus support])
 176 OPTION_DEFAULT_ON([gconf],[don't compile with GConf support])
 177 OPTION_DEFAULT_ON([gsettings],[don't compile with GSettings support])
 178 OPTION_DEFAULT_ON([selinux],[don't compile with SELinux support])
 179 OPTION_DEFAULT_ON([gnutls],[don't use -lgnutls for SSL/TLS support])
 180
 181 ## For the times when you want to build Emacs but don't have
 182 ## a suitable makeinfo, and can live without the manuals.
 183 dnl http://lists.gnu.org/archive/html/emacs-devel/2008-04/msg01844.html
 184 OPTION_DEFAULT_ON([makeinfo],[don't require makeinfo for building manuals])
 185
 186 ## Makefile.in needs the cache file name.
 187 AC_SUBST(cache_file)
 188
 189 ## This is an option because I do not know if all info/man support
 190 ## compressed files, nor how to test if they do so.
 191 OPTION_DEFAULT_ON([compress-info],[don't compress the installed Info pages])
 192 if test $with_compress_info = yes; then
 193    GZIP_INFO=yes
 194 else
 195    GZIP_INFO=
 196 fi
 197 AC_SUBST(GZIP_INFO)
 198
 199 AC_ARG_WITH([pkg-config-prog],dnl
 200 [AS_HELP_STRING([--with-pkg-config-prog=PATH],
 201                   [path to pkg-config for finding GTK and librsvg])])
 202 if test "X${with_pkg_config_prog}" != X; then
 203    if test "${with_pkg_config_prog}" != yes; then
 204       PKG_CONFIG="${with_pkg_config_prog}"
 205    fi
 206 fi
 207
 208 CRT_DIR=
 209 AC_ARG_WITH([crt-dir],dnl
 210 [AS_HELP_STRING([--with-crt-dir=DIR],[directory containing crtn.o etc.
 211 The default is /usr/lib, or /usr/lib64 on some platforms.])])
 212 CRT_DIR="${with_crt_dir}"
 213
 214 AC_ARG_WITH(gameuser,dnl
 215 [AS_HELP_STRING([--with-gameuser=USER],[user for shared game score files])])
 216 test "X${with_gameuser}" != X && test "${with_gameuser}" != yes \
 217   && gameuser="${with_gameuser}"
 218 test "X$gameuser" = X && gameuser=games
 219
 220 AC_ARG_WITH([gnustep-conf],dnl
 221 [AS_HELP_STRING([--with-gnustep-conf=PATH],[path to GNUstep.conf; default $GNUSTEP_CONFIG_FILE, or /etc/GNUstep/GNUstep.conf])])
 222 test "X${with_gnustep_conf}" != X && test "${with_gnustep_conf}" != yes && \
 223   GNUSTEP_CONFIG_FILE="${with_gnustep_conf}"
 224 test "X$GNUSTEP_CONFIG_FILE" = "X" && \
 225      GNUSTEP_CONFIG_FILE=/etc/GNUstep/GNUstep.conf
 226
 227 AC_ARG_ENABLE(ns-self-contained,
 228 [AS_HELP_STRING([--disable-ns-self-contained],
 229                 [disable self contained build under NeXTstep])],
 230    EN_NS_SELF_CONTAINED=$enableval,
 231    EN_NS_SELF_CONTAINED=yes)
 232
 233 AC_ARG_ENABLE(asserts,
 234 [AS_HELP_STRING([--enable-asserts], [compile code with asserts enabled])],
 235       USE_XASSERTS=$enableval,
 236       USE_XASSERTS=no)
 237
 238 AC_ARG_ENABLE(locallisppath,
 239 [AS_HELP_STRING([--enable-locallisppath=PATH],
 240                 [directories Emacs should search for lisp files specific
 241                  to this site])],
 242 if test "${enableval}" = "no"; then
 243   locallisppath=
 244 elif test "${enableval}" != "yes"; then
 245   locallisppath=${enableval}
 246 fi)
 247
 248 AC_ARG_ENABLE(checking,
 249 [AS_HELP_STRING([--enable-checking@<:@=LIST@:>@],
 250                 [enable expensive run-time checks.  With LIST,
 251                  enable only specific categories of checks.
 252                  Categories are: all,yes,no.
 253                  Flags are: stringbytes, stringoverrun, stringfreelist,
 254                  xmallocoverrun, conslist])],
 255 [ac_checking_flags="${enableval}"],[])
 256 IFS="${IFS=     }"; ac_save_IFS="$IFS"; IFS="$IFS,"
 257 for check in $ac_checking_flags
 258 do
 259         case $check in
 260         # these set all the flags to specific states
 261         yes)            ac_enable_checking=1 ;;
 262         no)             ac_enable_checking= ;
 263                         ac_gc_check_stringbytes= ;
 264                         ac_gc_check_string_overrun= ;
 265                         ac_gc_check_string_free_list= ;
 266                         ac_xmalloc_overrun= ;
 267                         ac_gc_check_cons_list= ;;
 268         all)            ac_enable_checking=1 ;
 269                         ac_gc_check_stringbytes=1 ;
 270                         ac_gc_check_string_overrun=1 ;
 271                         ac_gc_check_string_free_list=1 ;
 272                         ac_xmalloc_overrun=1 ;
 273                         ac_gc_check_cons_list=1 ;;
 274         # these enable particular checks
 275         stringbytes)    ac_gc_check_stringbytes=1 ;;
 276         stringoverrun)  ac_gc_check_string_overrun=1 ;;
 277         stringfreelist) ac_gc_check_string_free_list=1 ;;
 278         xmallocoverrun) ac_xmalloc_overrun=1 ;;
 279         conslist)       ac_gc_check_cons_list=1 ;;
 280         *)      AC_MSG_ERROR(unknown check category $check) ;;
 281         esac
 282 done
 283 IFS="$ac_save_IFS"
 284
 285 if test x$ac_enable_checking != x ; then
 286   AC_DEFINE(ENABLE_CHECKING, 1,
 287 [Enable expensive run-time checking of data types?])
 288 fi
 289 if test x$ac_gc_check_stringbytes != x ; then
 290   AC_DEFINE(GC_CHECK_STRING_BYTES, 1,
 291 [Define this temporarily to hunt a bug.  If defined, the size of
 292    strings is redundantly recorded in sdata structures so that it can
 293    be compared to the sizes recorded in Lisp strings.])
 294 fi
 295 if test x$ac_gc_check_string_overrun != x ; then
 296   AC_DEFINE(GC_CHECK_STRING_OVERRUN, 1,
 297 [Define this to check for short string overrun.])
 298 fi
 299 if test x$ac_gc_check_string_free_list != x ; then
 300   AC_DEFINE(GC_CHECK_STRING_FREE_LIST, 1,
 301 [Define this to check the string free list.])
 302 fi
 303 if test x$ac_xmalloc_overrun != x ; then
 304   AC_DEFINE(XMALLOC_OVERRUN_CHECK, 1,
 305 [Define this to check for malloc buffer overrun.])
 306 fi
 307 if test x$ac_gc_check_cons_list != x ; then
 308   AC_DEFINE(GC_CHECK_CONS_LIST, 1,
 309 [Define this to check for errors in cons list.])
 310 fi
 311
 312 AC_ARG_ENABLE(check-lisp-object-type,
 313 [AS_HELP_STRING([--enable-check-lisp-object-type],
 314                 [enable compile time checks for the Lisp_Object data type.
 315                 This is useful for development for catching certain types of bugs.])],
 316 if test "${enableval}" != "no"; then
 317    AC_DEFINE(CHECK_LISP_OBJECT_TYPE, 1,
 318    [Define this to enable compile time checks for the Lisp_Object data type.])
 319 fi)
 320
 321
 322 AC_ARG_ENABLE(profiling,
 323 [AS_HELP_STRING([--enable-profiling],
 324                 [build emacs with profiling support.
 325                  This might not work on all platforms])],
 326 [ac_enable_profiling="${enableval}"],[])
 327 if test x$ac_enable_profiling != x ; then
 328    PROFILING_CFLAGS="-DPROFILING=1 -pg"
 329 else
 330    PROFILING_CFLAGS=
 331 fi
 332 AC_SUBST(PROFILING_CFLAGS)
 333
 334 AC_ARG_ENABLE(autodepend,
 335 [AS_HELP_STRING([--enable-autodepend],
 336                 [automatically generate dependencies to .h-files.
 337                  Requires GNU Make and Gcc. Enabled if GNU Make and Gcc is
 338                  found])],
 339 [ac_enable_autodepend="${enableval}"],[ac_enable_autodepend=yes])
 340
 341 #### Make srcdir absolute, if it isn't already.  It's important to
 342 #### avoid running the path through pwd unnecessarily, since pwd can
 343 #### give you automounter prefixes, which can go away.  We do all this
 344 #### so Emacs can find its files when run uninstalled.
 345 ## Make sure CDPATH doesn't affect cd (in case PWD is relative).
 346 unset CDPATH
 347 case "${srcdir}" in
 348   /* ) ;;
 349   . )
 350     ## We may be able to use the $PWD environment variable to make this
 351     ## absolute.  But sometimes PWD is inaccurate.
 352     ## Note: we used to use ${PWD} at the end instead of `pwd`,
 353     ## but that tested only for a well-formed and valid PWD,
 354     ## it did not object when PWD was well-formed and valid but just wrong.
 355     if test ".${PWD}" != "." && test ".`(cd ${PWD} ; sh -c pwd)`" = ".`pwd`"  ;
 356     then
 357       srcdir="$PWD"
 358     else
 359       srcdir="`(cd ${srcdir}; pwd)`"
 360     fi
 361   ;;
 362   *  ) srcdir="`(cd ${srcdir}; pwd)`" ;;
 363 esac
 364
 365 #### Given the configuration name, set opsysfile to the
 366 #### name of s/*.h file we should use.
 367
 368 ### Canonicalize the configuration name.
 369
 370 AC_CANONICAL_HOST
 371 canonical=$host
 372 configuration=${host_alias-${build_alias-$host}}
 373
 374 dnl This used to use changequote, but, apart from `changequote is evil'
 375 dnl per the autoconf manual, we can speed up autoconf somewhat by quoting
 376 dnl the great gob of text.  Thus it's not processed for possible expansion.
 377 dnl Just make sure the brackets remain balanced.
 378 dnl
 379 dnl Since Emacs can't find matching pairs of quotes, boundaries are
 380 dnl indicated by comments.
 381 dnl quotation begins
 382 [
 383
 384 ### If you add support for a new configuration, add code to this
 385 ### switch statement to recognize your configuration name and select
 386 ### the appropriate operating system file.
 387
 388 ### You would hope that you could choose an s/*.h
 389 ### file based on the operating system portion.  However, it turns out
 390 ### that each s/*.h file is pretty manufacturer-specific.
 391 ### So we basically have to have a special case for each
 392 ### configuration name.
 393 ###
 394 ### As far as handling version numbers on operating systems is
 395 ### concerned, make sure things will fail in a fixable way.  If
 396 ### /etc/MACHINES doesn't say anything about version numbers, be
 397 ### prepared to handle anything reasonably.  If version numbers
 398 ### matter, be sure /etc/MACHINES says something about it.
 399
 400 opsys='' unported=no
 401 case "${canonical}" in
 402
 403   ## GNU/Linux and similar ports
 404   *-*-linux* )
 405     opsys=gnu-linux
 406   ;;
 407
 408   ## FreeBSD ports
 409   *-*-freebsd* )
 410     opsys=freebsd
 411   ;;
 412
 413   ## FreeBSD kernel + glibc based userland
 414   *-*-kfreebsd*gnu* )
 415     opsys=gnu-kfreebsd
 416   ;;
 417
 418   ## NetBSD ports
 419   *-*-netbsd* )
 420     opsys=netbsd
 421   ;;
 422
 423   ## OpenBSD ports
 424   *-*-openbsd* )
 425     opsys=openbsd
 426   ;;
 427
 428   ## Apple Darwin / Mac OS X
 429   *-apple-darwin* )
 430     case "${canonical}" in
 431       i[3456]86-* )  ;;
 432       powerpc-* )    ;;
 433       x86_64-* )     ;;
 434       * )            unported=yes ;;
 435     esac
 436     opsys=darwin
 437     ## Use fink packages if available.
 438     ## FIXME find a better way to do this: http://debbugs.gnu.org/11507
 439 ##    if test -d /sw/include && test -d /sw/lib; then
 440 ##      GCC_TEST_OPTIONS="-I/sw/include -L/sw/lib"
 441 ##      NON_GCC_TEST_OPTIONS=${GCC_TEST_OPTIONS}
 442 ##    fi
 443   ;;
 444
 445   ## HP 9000 series 700 and 800, running HP/UX
 446   hppa*-hp-hpux10.2* )
 447     opsys=hpux10-20
 448   ;;
 449   hppa*-hp-hpux1[1-9]* )
 450     opsys=hpux11
 451     CFLAGS="-D_INCLUDE__STDC_A1_SOURCE $CFLAGS"
 452   ;;
 453
 454   ## IBM machines
 455   rs6000-ibm-aix4.[23]* )
 456     opsys=aix4-2
 457   ;;
 458   powerpc-ibm-aix4.[23]*  )
 459     opsys=aix4-2
 460   ;;
 461   rs6000-ibm-aix[56]* )
 462     opsys=aix4-2
 463   ;;
 464   powerpc-ibm-aix[56]*  )
 465     opsys=aix4-2
 466   ;;
 467
 468   ## Silicon Graphics machines
 469   ## Iris 4D
 470   mips-sgi-irix6.5 )
 471     opsys=irix6-5
 472     # Without defining _LANGUAGE_C, things get masked out in the headers
 473     # so that, for instance, grepping for `free' in stdlib.h fails and
 474     # AC_HEADER_STD_C fails.   (MIPSPro 7.2.1.2m compilers, Irix 6.5.3m).
 475     NON_GCC_TEST_OPTIONS="-D_LANGUAGE_C"
 476   ;;
 477
 478   ## Suns
 479   *-sun-solaris* \
 480     | i[3456]86-*-solaris2* | i[3456]86-*-sunos5* \
 481     | x86_64-*-solaris2*    | x86_64-*-sunos5*)
 482     case "${canonical}" in
 483       i[3456]86-*-* )   ;;
 484       amd64-*-*|x86_64-*-*) ;;
 485       sparc* )          ;;
 486       * )               unported=yes ;;
 487     esac
 488     case "${canonical}" in
 489       *-sunos5.6* | *-solaris2.6* )
 490                 opsys=sol2-6
 491                 RANLIB="ar -ts"
 492                 ;;
 493       *-sunos5.[7-9]* | *-solaris2.[7-9]* )
 494                 opsys=sol2-6
 495                 emacs_check_sunpro_c=yes
 496                 ;;
 497       *-sunos5* | *-solaris* )
 498                 opsys=sol2-10
 499                 emacs_check_sunpro_c=yes
 500                 ;;
 501     esac
 502     ## Watch out for a compiler that we know will not work.
 503     case "${canonical}" in
 504      *-solaris* | *-sunos5* )
 505                 if [ "x$CC" = x/usr/ucb/cc ]; then
 506                   ## /usr/ucb/cc doesn't work;
 507                   ## we should find some other compiler that does work.
 508                   unset CC
 509                 fi
 510                 ;;
 511       *) ;;
 512     esac
 513   ;;
 514
 515   ## Intel 386 machines where we don't care about the manufacturer.
 516   i[3456]86-*-* )
 517     case "${canonical}" in
 518       *-cygwin )                opsys=cygwin ;;
 519       *-darwin* )               opsys=darwin ;;
 520       *-sysv4.2uw* )            opsys=unixware ;;
 521       *-sysv5uw* )              opsys=unixware ;;
 522       *-sysv5OpenUNIX* )        opsys=unixware ;;
 523       ## Otherwise, we'll fall through to the generic opsys code at the bottom.
 524     esac
 525   ;;
 526
 527   * )
 528     unported=yes
 529   ;;
 530 esac
 531
 532 ### If the code above didn't choose an operating system, just choose
 533 ### an operating system based on the configuration name.  You really
 534 ### only want to use this when you have no idea what the right
 535 ### operating system is; if you know what operating systems a machine
 536 ### runs, it's cleaner to make it explicit in the case statement
 537 ### above.
 538 if test x"${opsys}" = x; then
 539   case "${canonical}" in
 540     *-gnu* )                            opsys=gnu ;;
 541     * )
 542       unported=yes
 543     ;;
 544   esac
 545 fi
 546
 547 ]
 548 dnl quotation ends
 549
 550 if test $unported = yes; then
 551   AC_MSG_ERROR([Emacs hasn't been ported to `${canonical}' systems.
 552 Check `etc/MACHINES' for recognized configuration names.])
 553 fi
 554
 555 opsysfile="s/${opsys}.h"
 556
 557
 558 #### Choose a compiler.
 559
 560 dnl Sets GCC=yes if using gcc.
 561 AC_PROG_CC
 562 AM_PROG_CC_C_O
 563
 564 if test x$GCC = xyes; then
 565   test "x$GCC_TEST_OPTIONS" != x && CC="$CC $GCC_TEST_OPTIONS"
 566 else
 567   test "x$NON_GCC_TEST_OPTIONS" != x && CC="$CC $NON_GCC_TEST_OPTIONS"
 568 fi
 569
 570 # Initialize gnulib right after choosing the compiler.
 571 gl_EARLY
 572
 573 AC_ARG_ENABLE([gcc-warnings],
 574   [AS_HELP_STRING([--enable-gcc-warnings],
 575                   [turn on lots of GCC warnings (for developers)])],
 576   [case $enableval in
 577      yes|no) ;;
 578      *)      AC_MSG_ERROR([bad value $enableval for gcc-warnings option]) ;;
 579    esac
 580    gl_gcc_warnings=$enableval],
 581   [gl_gcc_warnings=no]
 582 )
 583
 584 # gl_GCC_VERSION_IFELSE([major], [minor], [run-if-found], [run-if-not-found])
 585 # ------------------------------------------------
 586 # If $CPP is gcc-MAJOR.MINOR or newer, then run RUN-IF-FOUND.
 587 # Otherwise, run RUN-IF-NOT-FOUND.
 588 AC_DEFUN([gl_GCC_VERSION_IFELSE],
 589   [AC_PREPROC_IFELSE(
 590     [AC_LANG_PROGRAM(
 591       [[
 592 #if ($1) < __GNUC__ || (($1) == __GNUC__ && ($2) <= __GNUC_MINOR__)
 593 /* ok */
 594 #else
 595 # error "your version of gcc is older than $1.$2"
 596 #endif
 597       ]]),
 598     ], [$3], [$4])
 599   ]
 600 )
 601
 602 # When compiling with GCC, prefer -isystem to -I when including system
 603 # include files, to avoid generating useless diagnostics for the files.
 604 if test "$gl_gcc_warnings" != yes; then
 605   isystem='-I'
 606 else
 607   isystem='-isystem '
 608
 609   # This, $nw, is the list of warnings we disable.
 610   nw=
 611
 612   case $with_x_toolkit in
 613     lucid | athena | motif)
 614        # Old toolkits mishandle 'const'.
 615        nw="$nw -Wwrite-strings"
 616        ;;
 617     *)
 618        gl_WARN_ADD([-Werror], [WERROR_CFLAGS])
 619        ;;
 620   esac
 621   AC_SUBST([WERROR_CFLAGS])
 622
 623   nw="$nw -Waggregate-return"       # anachronistic
 624   nw="$nw -Wlong-long"              # C90 is anachronistic
 625   nw="$nw -Wc++-compat"             # We don't care about C++ compilers
 626   nw="$nw -Wundef"                  # Warns on '#if GNULIB_FOO' etc in gnulib
 627   nw="$nw -Wtraditional"            # Warns on #elif which we use often
 628   nw="$nw -Wcast-qual"              # Too many warnings for now
 629   nw="$nw -Wconversion"             # Too many warnings for now
 630   nw="$nw -Wsystem-headers"         # Don't let system headers trigger warnings
 631   nw="$nw -Wsign-conversion"        # Too many warnings for now
 632   nw="$nw -Woverlength-strings"     # Not a problem these days
 633   nw="$nw -Wtraditional-conversion" # Too many warnings for now
 634   nw="$nw -Wpadded"                 # Our structs are not padded
 635   nw="$nw -Wredundant-decls"        # We regularly (re)declare getenv etc.
 636   nw="$nw -Wlogical-op"             # any use of fwrite provokes this
 637   nw="$nw -Wformat-nonliteral"      # Emacs does this a lot
 638   nw="$nw -Wvla"                    # warnings in gettext.h
 639   nw="$nw -Wnested-externs"         # use of XARGMATCH/verify_function__
 640   nw="$nw -Wswitch-enum"            # Too many warnings for now
 641   nw="$nw -Wswitch-default"         # Too many warnings for now
 642   nw="$nw -Wfloat-equal"            # e.g., ftoastr.c
 643   nw="$nw -Winline"                 # e.g., dispnew.c's inlining of row_equal_p
 644
 645   # Emacs doesn't care about shadowing; see
 646   # <http://lists.gnu.org/archive/html/emacs-diffs/2011-11/msg00265.html>.
 647   nw="$nw -Wshadow"
 648
 649   # The following lines should be removable at some point.
 650   nw="$nw -Wstack-protector"
 651   nw="$nw -Wstrict-overflow"
 652   nw="$nw -Wsuggest-attribute=const"
 653   nw="$nw -Wsuggest-attribute=pure"
 654
 655   gl_MANYWARN_ALL_GCC([ws])
 656   gl_MANYWARN_COMPLEMENT([ws], [$ws], [$nw])
 657   for w in $ws; do
 658     gl_WARN_ADD([$w])
 659   done
 660   gl_WARN_ADD([-Wno-missing-field-initializers]) # We need this one
 661   gl_WARN_ADD([-Wno-sign-compare])     # Too many warnings for now
 662   gl_WARN_ADD([-Wno-type-limits])      # Too many warnings for now
 663   gl_WARN_ADD([-Wno-switch])           # Too many warnings for now
 664   gl_WARN_ADD([-Wno-unused-parameter]) # Too many warnings for now
 665   gl_WARN_ADD([-Wno-format-nonliteral])
 666
 667   # In spite of excluding -Wlogical-op above, it is enabled, as of
 668   # gcc 4.5.0 20090517.
 669   gl_WARN_ADD([-Wno-logical-op])
 670
 671   gl_WARN_ADD([-fdiagnostics-show-option])
 672   gl_WARN_ADD([-funit-at-a-time])
 673
 674   AC_DEFINE([lint], [1], [Define to 1 if the compiler is checking for lint.])
 675   AC_DEFINE([_FORTIFY_SOURCE], [2],
 676     [enable compile-time and run-time bounds-checking, and some warnings])
 677   AC_DEFINE([GNULIB_PORTCHECK], [1], [enable some gnulib portability checks])
 678
 679   # We use a slightly smaller set of warning options for lib/.
 680   # Remove the following and save the result in GNULIB_WARN_CFLAGS.
 681   nw=
 682   nw="$nw -Wunused-macros"
 683
 684   gl_MANYWARN_COMPLEMENT([GNULIB_WARN_CFLAGS], [$WARN_CFLAGS], [$nw])
 685   AC_SUBST([GNULIB_WARN_CFLAGS])
 686 fi
 687
 688
 689
 690 dnl Some other nice autoconf tests.
 691 dnl These are commented out, since gl_EARLY and/or Autoconf already does them.
 692 dnl AC_PROG_INSTALL
 693 dnl AC_PROG_MKDIR_P
 694 dnl if test "x$RANLIB" = x; then
 695 dnl   AC_PROG_RANLIB
 696 dnl fi
 697
 698 AC_PATH_PROG(INSTALL_INFO, install-info, :,
 699   $PATH$PATH_SEPARATOR/usr/sbin$PATH_SEPARATOR/sbin)
 700 dnl Don't use GZIP, which is used by gzip for additional parameters.
 701 AC_PATH_PROG(GZIP_PROG, gzip)
 702
 703 if test $opsys = gnu-linux; then
 704   AC_PATH_PROG(PAXCTL, paxctl,,
 705     [$PATH$PATH_SEPARATOR/sbin$PATH_SEPARATOR/usr/sbin])
 706 fi
 707
 708 ## Need makeinfo >= 4.7 (?) to build the manuals.
 709 AC_PATH_PROG(MAKEINFO, makeinfo, no)
 710 dnl By this stage, configure has already checked for egrep and set EGREP,
 711 dnl or exited with an error if no egrep was found.
 712 if test "$MAKEINFO" != "no" && \
 713   test x"`$MAKEINFO --version 2> /dev/null | $EGREP 'texinfo[[^0-9]]*([[1-4]][[0-9]]+|[[5-9]]|4\.[[7-9]]|4\.[[1-6]][[0-9]]+)'`" = x; then
 714    MAKEINFO=no
 715 fi
 716
 717 ## Makeinfo is unusual.  For a released Emacs, the manuals are
 718 ## pre-built, and not deleted by the normal clean rules.  makeinfo is
 719 ## therefore in the category of "special tools" not normally required, which
 720 ## configure does not have to check for (eg autoconf itself).
 721 ## In a Bazaar checkout on the other hand, the manuals are not included.
 722 ## So makeinfo is a requirement to build from Bazaar, and configure
 723 ## should test for it as it does for any other build requirement.
 724 ## We use the presence of $srcdir/info/emacs to distinguish a release,
 725 ## with pre-built manuals, from a Bazaar checkout.
 726 HAVE_MAKEINFO=yes
 727
 728 if test "$MAKEINFO" = "no"; then
 729   MAKEINFO=makeinfo
 730   if test "x${with_makeinfo}" = "xno"; then
 731     HAVE_MAKEINFO=no
 732   elif test ! -e $srcdir/info/emacs; then
 733     AC_MSG_ERROR( [You do not seem to have makeinfo >= 4.7, and your
 734 source tree does not seem to have pre-built manuals in the `info' directory.
 735 Either install a suitable version of makeinfo, or re-run configure
 736 with the `--without-makeinfo' option to build without the manuals.] )
 737   fi
 738 fi
 739 AC_SUBST(HAVE_MAKEINFO)
 740
 741 dnl Just so that there is only a single place we need to edit.
 742 INFO_EXT=.info
 743 INFO_OPTS=--no-split
 744 AC_SUBST(INFO_EXT)
 745 AC_SUBST(INFO_OPTS)
 746
 747 dnl Add our options to ac_link now, after it is set up.
 748
 749 if test x$GCC = xyes; then
 750   test "x$GCC_LINK_TEST_OPTIONS" != x && \
 751     ac_link="$ac_link $GCC_LINK_TEST_OPTIONS"
 752 else
 753   test "x$NON_GCC_LINK_TEST_OPTIONS" != x && \
 754     ac_link="$ac_link $NON_GCC_LINK_TEST_OPTIONS"
 755 fi
 756
 757 dnl We need -znocombreloc if we're using a relatively recent GNU ld.
 758 dnl If we can link with the flag, it shouldn't do any harm anyhow.
 759 dnl (Don't use `-z nocombreloc' as -z takes no arg on Irix.)
 760 dnl Treat GCC specially since it just gives a non-fatal `unrecognized option'
 761 dnl if not built to support GNU ld.
 762
 763 late_LDFLAGS=$LDFLAGS
 764 if test x$GCC = xyes; then
 765   LDFLAGS="$LDFLAGS -Wl,-znocombreloc"
 766 else
 767   LDFLAGS="$LDFLAGS -znocombreloc"
 768 fi
 769
 770 AC_MSG_CHECKING([for -znocombreloc])
 771 AC_LINK_IFELSE([AC_LANG_PROGRAM([], [])],
 772   [AC_MSG_RESULT(yes)],
 773   LDFLAGS=$late_LDFLAGS
 774   [AC_MSG_RESULT(no)])
 775
 776
 777 dnl The function dump-emacs will not be defined and temacs will do
 778 dnl (load "loadup") automatically unless told otherwise.
 779 test "x$CANNOT_DUMP" = "x" && CANNOT_DUMP=no
 780 case "$opsys" in
 781   your-opsys-here) CANNOT_DUMP=yes ;;
 782 esac
 783
 784 test "$CANNOT_DUMP" = "yes" && \
 785   AC_DEFINE(CANNOT_DUMP, 1, [Define if Emacs cannot be dumped on your system.])
 786
 787 AC_SUBST(CANNOT_DUMP)
 788
 789
 790 UNEXEC_OBJ=unexelf.o
 791 case "$opsys" in
 792   # MSDOS uses unexcoff.o
 793   # MSWindows uses unexw32.o
 794   aix4-2)
 795    UNEXEC_OBJ=unexaix.o
 796    ;;
 797   cygwin)
 798    UNEXEC_OBJ=unexcw.o
 799    ;;
 800   darwin)
 801    UNEXEC_OBJ=unexmacosx.o
 802    ;;
 803   hpux10-20 | hpux11)
 804    UNEXEC_OBJ=unexhp9k800.o
 805    ;;
 806   sol2-10)
 807    # Use the Solaris dldump() function, called from unexsol.c, to dump
 808    # emacs, instead of the generic ELF dump code found in unexelf.c.
 809    # The resulting binary has a complete symbol table, and is better
 810    # for debugging and other observability tools (debuggers, pstack, etc).
 811    #
 812    # If you encounter a problem using dldump(), please consider sending
 813    # a message to the OpenSolaris tools-linking mailing list:
 814    #      http://mail.opensolaris.org/mailman/listinfo/tools-linking
 815    #
 816    # It is likely that dldump() works with older Solaris too, but this has
 817    # not been tested, so for now this change is for Solaris 10 or newer.
 818    UNEXEC_OBJ=unexsol.o
 819    ;;
 820 esac
 821
 822 LD_SWITCH_SYSTEM=
 823 case "$opsys" in
 824   freebsd)
 825    ## Let `ld' find image libs and similar things in /usr/local/lib.
 826    ## The system compiler, GCC, has apparently been modified to not
 827    ## look there, contrary to what a stock GCC would do.
 828 ### It's not our place to do this.  See bug#10313#17.
 829 ###   LD_SWITCH_SYSTEM=-L/usr/local/lib
 830       :
 831    ;;
 832
 833   gnu-linux)
 834    ## cpp test was "ifdef __mips__", but presumably this is equivalent...
 835    case $host_cpu in mips*) LD_SWITCH_SYSTEM="-G 0";; esac
 836    ;;
 837
 838   netbsd)
 839 ### It's not our place to do this.  See bug#10313#17.
 840 ###   LD_SWITCH_SYSTEM="-Wl,-rpath,/usr/pkg/lib -L/usr/pkg/lib -Wl,-rpath,/usr/local/lib -L/usr/local/lib"
 841       :
 842    ;;
 843
 844   openbsd)
 845    ## Han Boetes <han@mijncomputer.nl> says this is necessary,
 846    ## otherwise Emacs dumps core on elf systems.
 847    LD_SWITCH_SYSTEM="-Z"
 848    ;;
 849 esac
 850 AC_SUBST(LD_SWITCH_SYSTEM)
 851
 852 ac_link="$ac_link $LD_SWITCH_SYSTEM"
 853
 854 ## This setting of LD_SWITCH_SYSTEM references LD_SWITCH_X_SITE_RPATH,
 855 ## which has not been defined yet.  When this was handled with cpp,
 856 ## it was expanded to null when configure sourced the s/*.h file.
 857 ## Thus LD_SWITCH_SYSTEM had different values in configure and the Makefiles.
 858 ## FIXME it would be cleaner to put this in LD_SWITCH_SYSTEM_TEMACS
 859 ## (or somesuch), but because it is supposed to go at the _front_
 860 ## of LD_SWITCH_SYSTEM, we cannot do that in exactly the same way.
 861 ## Compare with the gnu-linux case below, which added to the end
 862 ## of LD_SWITCH_SYSTEM, and so can instead go at the front of
 863 ## LD_SWITCH_SYSTEM_TEMACS.
 864 case "$opsys" in
 865   netbsd|openbsd)
 866    LD_SWITCH_SYSTEM="\$(LD_SWITCH_X_SITE_RPATH) $LD_SWITCH_SYSTEM" ;;
 867 esac
 868
 869
 870 C_SWITCH_MACHINE=
 871 case $canonical in
 872  alpha*)
 873   AC_CHECK_DECL([__ELF__])
 874   if test "$ac_cv_have_decl___ELF__" = "yes"; then
 875     ## With ELF, make sure that all common symbols get allocated to in the
 876     ## data section.  Otherwise, the dump of temacs may miss variables in
 877     ## the shared library that have been initialized.  For example, with
 878     ## GNU libc, __malloc_initialized would normally be resolved to the
 879     ## shared library's .bss section, which is fatal.
 880     if test "x$GCC" = "xyes"; then
 881       C_SWITCH_MACHINE="-fno-common"
 882     else
 883       AC_MSG_ERROR([What gives?  Fix me if DEC Unix supports ELF now.])
 884     fi
 885   else
 886     UNEXEC_OBJ=unexalpha.o
 887   fi
 888   ;;
 889 esac
 890 AC_SUBST(C_SWITCH_MACHINE)
 891
 892 AC_SUBST(UNEXEC_OBJ)
 893
 894 C_SWITCH_SYSTEM=
 895 ## Some programs in src produce warnings saying certain subprograms
 896 ## are too complex and need a MAXMEM value greater than 2000 for
 897 ## additional optimization.  --nils@exp-math.uni-essen.de
 898 test "$opsys" = "aix4.2" && test "x$GCC" != "xyes" && \
 899   C_SWITCH_SYSTEM="-ma -qmaxmem=4000"
 900 ## gnu-linux might need -D_BSD_SOURCE on old libc5 systems.
 901 ## It is redundant in glibc2, since we define _GNU_SOURCE.
 902 AC_SUBST(C_SWITCH_SYSTEM)
 903
 904
 905 LIBS_SYSTEM=
 906 case "$opsys" in
 907   ## IBM's X11R5 uses -lIM and -liconv in AIX 3.2.2.
 908   aix4-2) LIBS_SYSTEM="-lrts -lIM -liconv" ;;
 909
 910   freebsd) LIBS_SYSTEM="-lutil" ;;
 911
 912   hpux*) LIBS_SYSTEM="-l:libdld.sl" ;;
 913
 914   sol2*) LIBS_SYSTEM="-lsocket -lnsl" ;;
 915
 916   ## Motif needs -lgen.
 917   unixware) LIBS_SYSTEM="-lsocket -lnsl -lelf -lgen" ;;
 918 esac
 919 AC_SUBST(LIBS_SYSTEM)
 920
 921
 922 ### Make sure subsequent tests use flags consistent with the build flags.
 923
 924 if test x"${OVERRIDE_CPPFLAGS}" != x; then
 925   CPPFLAGS="${OVERRIDE_CPPFLAGS}"
 926 else
 927   CPPFLAGS="$C_SWITCH_SYSTEM $C_SWITCH_MACHINE $CPPFLAGS"
 928 fi
 929
 930 # Suppress obsolescent Autoconf test for size_t; Emacs assumes C89 or better.
 931 AC_DEFUN([AC_TYPE_SIZE_T])
 932 # Likewise for obsolescent test for uid_t, gid_t; Emacs assumes them.
 933 AC_DEFUN([AC_TYPE_UID_T])
 934
 935
 936 LIB_MATH=-lm
 937 LIB_STANDARD=
 938 START_FILES=
 939 dnl Current possibilities handled by sed (aix4-2 -> aix,
 940 dnl gnu-linux -> gnu/linux, etc.):
 941 dnl gnu, gnu/linux, gnu/kfreebsd, aix, cygwin, darwin, hpux, irix.
 942 dnl And special cases: berkeley-unix, usg-unix-v, ms-dos, windows-nt.
 943 SYSTEM_TYPE=`echo $opsys | sed -e 's/[[0-9]].*//' -e 's|-|/|'`
 944
 945 dnl NB do not use CRT_DIR unquoted here, since it might not be set yet.
 946 case $opsys in
 947   cygwin )
 948     LIB_MATH=
 949     START_FILES='pre-crt0.o'
 950     ;;
 951   darwin )
 952     ## Adding -lm confuses the dynamic linker, so omit it.
 953     LIB_MATH=
 954     START_FILES='pre-crt0.o'
 955     ;;
 956   freebsd )
 957     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
 958     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
 959     SYSTEM_TYPE=berkeley-unix
 960     ;;
 961   gnu-linux | gnu-kfreebsd )
 962     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtn.o'
 963     START_FILES='pre-crt0.o $(CRT_DIR)/crt1.o $(CRT_DIR)/crti.o'
 964     ;;
 965   hpux10-20 | hpux11 )
 966     LIB_STANDARD=-lc
 967     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o'
 968     ;;
 969   dnl NB this may be adjusted below.
 970   netbsd | openbsd )
 971     LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o'
 972     START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crtbegin.o'
 973     SYSTEM_TYPE=berkeley-unix
 974     ;;
 975
 976   sol2* | unixware )
 977     SYSTEM_TYPE=usg-unix-v
 978     ;;
 979
 980 esac
 981
 982 AC_SUBST(LIB_MATH)
 983 AC_SUBST(START_FILES)
 984 AC_DEFINE_UNQUOTED(SYSTEM_TYPE, "$SYSTEM_TYPE",
 985   [The type of system you are compiling for; sets `system-type'.])
 986
 987 dnl Not all platforms use crtn.o files.  Check if the current one does.
 988 crt_files=
 989
 990 for file in x $LIB_STANDARD $START_FILES; do
 991   case "$file" in
 992     *CRT_DIR*) crt_files="$crt_files `echo $file | sed -e 's|.*/||'`" ;;
 993   esac
 994 done
 995
 996 if test "x$crt_files" != x; then
 997
 998   ## If user specified a crt-dir, use that unconditionally.
 999   crt_gcc=no
1000
1001   if test "X$CRT_DIR" = "X"; then
1002
1003     CRT_DIR=/usr/lib            # default
1004
1005     case "$canonical" in
1006       x86_64-*-linux-gnu* | s390x-*-linux-gnu*)
1007       ## On x86-64 and s390x GNU/Linux distributions, the standard library
1008       ## can be in a variety of places.  We only try /usr/lib64 and /usr/lib.
1009       ## For anything else (eg /usr/lib32), it is up the user to specify
1010       ## the location (bug#5655).
1011       ## Test for crtn.o, not just the directory, because sometimes the
1012       ## directory exists but does not have the relevant files (bug#1287).
1013       ## FIXME better to test for binary compatibility somehow.
1014       test -e /usr/lib64/crtn.o && CRT_DIR=/usr/lib64
1015       ;;
1016
1017       powerpc64-*-linux-gnu* | sparc64-*-linux-gnu*) CRT_DIR=/usr/lib64 ;;
1018     esac
1019
1020     case "$opsys" in
1021       hpux10-20) CRT_DIR=/lib ;;
1022     esac
1023
1024     test "x${GCC}" = xyes && crt_gcc=yes
1025
1026   fi                            # CRT_DIR = ""
1027
1028   crt_missing=
1029
1030   for file in $crt_files; do
1031
1032     ## If we're using gcc, try to determine it automatically by asking
1033     ## gcc.  [If this doesn't work, CRT_DIR will remain at the
1034     ## system-dependent default from above.]
1035     if test $crt_gcc = yes && test ! -e $CRT_DIR/$file; then
1036
1037        crt_file=`$CC --print-file-name=$file 2>/dev/null`
1038        case "$crt_file" in
1039          */*)
1040            CRT_DIR=`AS_DIRNAME(["$crt_file"])`
1041            ;;
1042        esac
1043     fi
1044
1045     dnl We expect all the files to be in a single directory, so after the
1046     dnl first there is no point asking gcc.
1047     crt_gcc=no
1048
1049     test -e $CRT_DIR/$file || crt_missing="$crt_missing $file"
1050   done                          # $crt_files
1051
1052   test "x$crt_missing" = x || \
1053     AC_MSG_ERROR([Required file(s) not found:$crt_missing
1054 Try using the --with-crt-dir option.])
1055
1056 fi                              # crt_files != ""
1057
1058 AC_SUBST(CRT_DIR)
1059
1060 case $opsys in
1061   netbsd | openbsd )
1062     if test -f $CRT_DIR/crti.o; then
1063
1064         test -f $CRT_DIR/crtn.o || \
1065           AC_MSG_ERROR([Required file not found: crtn.o])
1066
1067         LIB_STANDARD='-lgcc -lc -lgcc $(CRT_DIR)/crtend.o $(CRT_DIR)/crtn.o'
1068         START_FILES='pre-crt0.o $(CRT_DIR)/crt0.o $(CRT_DIR)/crti.o $(CRT_DIR)/crtbegin.o'
1069     fi
1070     ;;
1071 esac
1072
1073
1074 # Configure gnulib before invoking PKG_CHECK_MODULES, as the latter might
1075 # for example add -lrt to RSVG_LIBS, which would then cause gnulib to
1076 # incorrectly conclude that -lrt is not needed to link clock_gettime.
1077 gl_ASSERT_NO_GNULIB_POSIXCHECK
1078 gl_ASSERT_NO_GNULIB_TESTS
1079 gl_INIT
1080
1081 AC_PATH_PROG(PKG_CONFIG, pkg-config, no)
1082
1083 dnl This function definition taken from Gnome 2.0
1084 dnl PKG_CHECK_MODULES(GSTUFF, gtk+-2.0 >= 1.3 glib = 1.3.4, action-if, action-not)
1085 dnl defines GSTUFF_LIBS, GSTUFF_CFLAGS, see pkg-config man page
1086 dnl also defines GSTUFF_PKG_ERRORS on error
1087 AC_DEFUN([PKG_CHECK_MODULES], [
1088   succeeded=no
1089
1090   if test "$PKG_CONFIG" = "no" ; then
1091      ifelse([$4], , [AC_MSG_ERROR([
1092       *** The pkg-config script could not be found. Make sure it is in your path, or give the full path to pkg-config with the PKG_CONFIG environment variable or --with-pkg-config-prog.  Or see http://www.freedesktop.org/software/pkgconfig to get pkg-config.])], [$4])
1093   else
1094      PKG_CONFIG_MIN_VERSION=0.9.0
1095      if $PKG_CONFIG --atleast-pkgconfig-version $PKG_CONFIG_MIN_VERSION; then
1096         AC_MSG_CHECKING(for $2)
1097
1098         if $PKG_CONFIG --exists "$2" 2>&AS_MESSAGE_LOG_FD &&
1099            $1_CFLAGS=`$PKG_CONFIG --cflags "$2" 2>&AS_MESSAGE_LOG_FD` &&
1100            $1_LIBS=`$PKG_CONFIG --libs "$2" 2>&AS_MESSAGE_LOG_FD`; then
1101             edit_cflags="
1102               s,///*,/,g
1103               s/^/ /
1104               s/ -I/ $isystem/g
1105               s/^ //
1106             "
1107             $1_CFLAGS=`AS_ECHO(["$$1_CFLAGS"]) | sed -e "$edit_cflags"`
1108             $1_LIBS=`AS_ECHO(["$$1_LIBS"]) | sed -e 's,///*,/,g'`
1109             AC_MSG_RESULT([yes CFLAGS='$$1_CFLAGS' LIBS='$$1_LIBS'])
1110             succeeded=yes
1111         else
1112             AC_MSG_RESULT(no)
1113             $1_CFLAGS=""
1114             $1_LIBS=""
1115             ## If we have a custom action on failure, don't print errors, but
1116             ## do set a variable so people can do so.
1117             $1_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
1118             ifelse([$4], ,echo $$1_PKG_ERRORS,)
1119         fi
1120
1121         AC_SUBST($1_CFLAGS)
1122         AC_SUBST($1_LIBS)
1123      else
1124         echo "*** Your version of pkg-config is too old. You need version $PKG_CONFIG_MIN_VERSION or newer."
1125         echo "*** See http://www.freedesktop.org/software/pkgconfig"
1126      fi
1127   fi
1128
1129   if test $succeeded = yes; then
1130      ifelse([$3], , :, [$3])
1131   else
1132      ifelse([$4], , [AC_MSG_ERROR([Library requirements ($2) not met; consider adjusting the PKG_CONFIG_PATH environment variable if your libraries are in a nonstandard prefix so pkg-config can find them.])], [$4])
1133   fi
1134 ])
1135
1136
1137 if test "${with_sound}" != "no"; then
1138   # Sound support for GNU/Linux and the free BSDs.
1139   AC_CHECK_HEADERS(machine/soundcard.h sys/soundcard.h soundcard.h,
1140     have_sound_header=yes)
1141   # Emulation library used on NetBSD.
1142   AC_CHECK_LIB(ossaudio, _oss_ioctl, LIBSOUND=-lossaudio, LIBSOUND=)
1143   AC_SUBST(LIBSOUND)
1144
1145   ALSA_REQUIRED=1.0.0
1146   ALSA_MODULES="alsa >= $ALSA_REQUIRED"
1147   PKG_CHECK_MODULES(ALSA, $ALSA_MODULES, HAVE_ALSA=yes, HAVE_ALSA=no)
1148   if test $HAVE_ALSA = yes; then
1149     SAVE_CFLAGS="$CFLAGS"
1150     SAVE_LIBS="$LIBS"
1151     CFLAGS="$ALSA_CFLAGS $CFLAGS"
1152     LIBS="$ALSA_LIBS $LIBS"
1153     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <asoundlib.h>]], [[snd_lib_error_set_handler (0);]])],
1154                     emacs_alsa_normal=yes,
1155                     emacs_alsa_normal=no)
1156     if test "$emacs_alsa_normal" != yes; then
1157       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <alsa/asoundlib.h>]],
1158                      [[snd_lib_error_set_handler (0);]])],
1159                      emacs_alsa_subdir=yes,
1160                      emacs_alsa_subdir=no)
1161       if test "$emacs_alsa_subdir" != yes; then
1162         AC_MSG_ERROR([pkg-config found alsa, but it does not compile.  See config.log for error messages.])
1163       fi
1164       ALSA_CFLAGS="$ALSA_CFLAGS -DALSA_SUBDIR_INCLUDE"
1165     fi
1166
1167     CFLAGS="$SAVE_CFLAGS"
1168     LIBS="$SAVE_LIBS"
1169     LIBSOUND="$LIBSOUND $ALSA_LIBS"
1170     CFLAGS_SOUND="$CFLAGS_SOUND $ALSA_CFLAGS"
1171     AC_DEFINE(HAVE_ALSA, 1, [Define to 1 if ALSA is available.])
1172   fi
1173
1174   dnl Define HAVE_SOUND if we have sound support.  We know it works and
1175   dnl compiles only on the specified platforms.  For others, it
1176   dnl probably doesn't make sense to try.
1177   if test x$have_sound_header = xyes || test $HAVE_ALSA = yes; then
1178      case "$opsys" in
1179        dnl defined __FreeBSD__ || defined __NetBSD__ || defined __linux__
1180        gnu-linux|freebsd|netbsd)
1181          AC_DEFINE(HAVE_SOUND, 1, [Define to 1 if you have sound support.])
1182          ;;
1183      esac
1184   fi
1185
1186   AC_SUBST(CFLAGS_SOUND)
1187 fi
1188
1189 dnl checks for header files
1190 AC_CHECK_HEADERS_ONCE(
1191   linux/version.h sys/systeminfo.h
1192   stdio_ext.h fcntl.h coff.h pty.h
1193   sys/vlimit.h sys/resource.h
1194   sys/utsname.h pwd.h utmp.h dirent.h util.h)
1195
1196 AC_MSG_CHECKING(if personality LINUX32 can be set)
1197 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/personality.h>]], [[personality (PER_LINUX32)]])],
1198                emacs_cv_personality_linux32=yes,
1199                emacs_cv_personality_linux32=no)
1200 AC_MSG_RESULT($emacs_cv_personality_linux32)
1201
1202 if test $emacs_cv_personality_linux32 = yes; then
1203   AC_DEFINE(HAVE_PERSONALITY_LINUX32, 1,
1204             [Define to 1 if personality LINUX32 can be set.])
1205 fi
1206
1207 dnl On Solaris 8 there's a compilation warning for term.h because
1208 dnl it doesn't define `bool'.
1209 AC_CHECK_HEADERS(term.h, , , -)
1210 AC_HEADER_TIME
1211 AC_CHECK_DECLS([sys_siglist])
1212 if test $ac_cv_have_decl_sys_siglist != yes; then
1213   # For Tru64, at least:
1214   AC_CHECK_DECLS([__sys_siglist])
1215   if test $ac_cv_have_decl___sys_siglist = yes; then
1216     AC_DEFINE(sys_siglist, __sys_siglist,
1217               [Define to any substitute for sys_siglist.])
1218   fi
1219 fi
1220 AC_HEADER_SYS_WAIT
1221
1222 dnl Check for speed_t typedef.
1223 AC_CACHE_CHECK(for speed_t, emacs_cv_speed_t,
1224   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <termios.h>]], [[speed_t x = 1;]])],
1225     emacs_cv_speed_t=yes, emacs_cv_speed_t=no)])
1226 if test $emacs_cv_speed_t = yes; then
1227   AC_DEFINE(HAVE_SPEED_T, 1,
1228            [Define to 1 if `speed_t' is declared by <termios.h>.])
1229 fi
1230
1231 AC_CACHE_CHECK(for struct exception, emacs_cv_struct_exception,
1232 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]],
1233 [[static struct exception x; x.arg1 = x.arg2 = x.retval; x.name = ""; x.type = 1;]])],
1234   emacs_cv_struct_exception=yes, emacs_cv_struct_exception=no))
1235 HAVE_EXCEPTION=$emacs_cv_struct_exception
1236 if test $emacs_cv_struct_exception != yes; then
1237   AC_DEFINE(NO_MATHERR, 1, [Define to 1 if you don't have struct exception in math.h.])
1238 fi
1239
1240 AC_CHECK_HEADERS_ONCE(sys/socket.h)
1241 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
1242 #if HAVE_SYS_SOCKET_H
1243 #include <sys/socket.h>
1244 #endif])
1245 AC_CHECK_HEADERS(ifaddrs.h, , , [AC_INCLUDES_DEFAULT
1246 #if HAVE_SYS_SOCKET_H
1247 #include <sys/socket.h>
1248 #endif])
1249 AC_CHECK_HEADERS(net/if_dl.h, , , [AC_INCLUDES_DEFAULT
1250 #if HAVE_SYS_SOCKET_H
1251 #include <sys/socket.h>
1252 #endif])
1253
1254 dnl checks for structure members
1255 AC_CHECK_MEMBERS([struct ifreq.ifr_flags, struct ifreq.ifr_hwaddr,
1256                   struct ifreq.ifr_netmask, struct ifreq.ifr_broadaddr,
1257                   struct ifreq.ifr_addr,
1258                   struct ifreq.ifr_addr.sa_len], , ,
1259                  [AC_INCLUDES_DEFAULT
1260 #if HAVE_SYS_SOCKET_H
1261 #include <sys/socket.h>
1262 #endif
1263 #if HAVE_NET_IF_H
1264 #include <net/if.h>
1265 #endif])
1266
1267 dnl Check for endianness.
1268 dnl AC_C_BIGENDIAN is done by gnulib.
1269
1270 AC_CACHE_CHECK([for  __attribute__ ((__aligned__ (expr)))],
1271   [emacs_cv_attribute_aligned],
1272   [AC_COMPILE_IFELSE(
1273      [AC_LANG_PROGRAM(
1274         [[char __attribute__ ((__aligned__ (1 << 3))) c;]],
1275         [[]])],
1276      [emacs_cv_attribute_aligned=yes],
1277      [emacs_cv_attribute_aligned=no])])
1278 if test $emacs_cv_attribute_aligned = yes; then
1279   AC_DEFINE([HAVE_ATTRIBUTE_ALIGNED], 1,
1280     [Define to 1 if GCC-style __attribute__ ((__aligned__ (expr))) works.])
1281 fi
1282
1283 dnl check for Make feature
1284 dnl AC_PROG_MAKE_SET is done by Automake.
1285
1286 DEPFLAGS=
1287 MKDEPDIR=":"
1288 deps_frag=deps.mk
1289 dnl check for GNU Make if we have GCC and autodepend is on.
1290 if test "$GCC" = yes && test "$ac_enable_autodepend" = yes; then
1291    AC_MSG_CHECKING([whether we are using GNU Make])
1292    HAVE_GNU_MAKE=no
1293    testval=`${MAKE-make} --version 2>/dev/null | grep 'GNU Make'`
1294    if test "x$testval" != x; then
1295       HAVE_GNU_MAKE=yes
1296    else
1297       ac_enable_autodepend=no
1298    fi
1299    AC_MSG_RESULT([$HAVE_GNU_MAKE])
1300    if test $HAVE_GNU_MAKE = yes; then
1301       AC_MSG_CHECKING([whether gcc understands -MMD -MF])
1302       SAVE_CFLAGS="$CFLAGS"
1303       CFLAGS="$CFLAGS -MMD -MF deps.d -MP"
1304       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[]])], , ac_enable_autodepend=no)
1305       CFLAGS="$SAVE_CFLAGS"
1306       test -f deps.d || ac_enable_autodepend=no
1307       rm -rf deps.d
1308       AC_MSG_RESULT([$ac_enable_autodepend])
1309    fi
1310    if test $ac_enable_autodepend = yes; then
1311       DEPFLAGS='-MMD -MF ${DEPDIR}/$*.d -MP'
1312       ## MKDIR_P is documented (see AC_PROG_MKDIR_P) to be parallel-safe.
1313       MKDEPDIR='${MKDIR_P} ${DEPDIR}'
1314       deps_frag=autodeps.mk
1315    fi
1316 fi
1317 deps_frag=$srcdir/src/$deps_frag
1318 AC_SUBST(MKDEPDIR)
1319 AC_SUBST(DEPFLAGS)
1320 AC_SUBST_FILE(deps_frag)
1321
1322
1323 lisp_frag=$srcdir/src/lisp.mk
1324 AC_SUBST_FILE(lisp_frag)
1325
1326
1327 dnl checks for operating system services
1328 AC_SYS_LONG_FILE_NAMES
1329
1330 #### Choose a window system.
1331
1332 AC_PATH_X
1333 if test "$no_x" = yes; then
1334   window_system=none
1335 else
1336   window_system=x11
1337 fi
1338
1339 LD_SWITCH_X_SITE_RPATH=
1340 if test "${x_libraries}" != NONE; then
1341   if test -n "${x_libraries}"; then
1342     LD_SWITCH_X_SITE=-L`echo ${x_libraries} | sed -e "s/:/ -L/g"`
1343     LD_SWITCH_X_SITE_RPATH=-Wl,-rpath,`echo ${x_libraries} | sed -e "s/:/ -Wl,-rpath,/g"`
1344   fi
1345   x_default_search_path=""
1346   x_search_path=${x_libraries}
1347   if test -z "${x_search_path}"; then
1348     x_search_path=/usr/lib
1349   fi
1350   for x_library in `echo ${x_search_path}: | \
1351                     sed -e "s/:/ /g" -e p -e "s:/lib[[^ /]]* :/share :g"`; do
1352     x_search_path="\
1353 ${x_library}/X11/%L/%T/%N%C%S:\
1354 ${x_library}/X11/%l/%T/%N%C%S:\
1355 ${x_library}/X11/%T/%N%C%S:\
1356 ${x_library}/X11/%L/%T/%N%S:\
1357 ${x_library}/X11/%l/%T/%N%S:\
1358 ${x_library}/X11/%T/%N%S"
1359     if test x"${x_default_search_path}" = x; then
1360       x_default_search_path=${x_search_path}
1361     else
1362       x_default_search_path="${x_search_path}:${x_default_search_path}"
1363     fi
1364   done
1365 fi
1366 AC_SUBST(LD_SWITCH_X_SITE_RPATH)
1367
1368 if test "${x_includes}" != NONE && test -n "${x_includes}"; then
1369   C_SWITCH_X_SITE="$isystem"`echo ${x_includes} | sed -e "s/:/ $isystem/g"`
1370 fi
1371
1372 if test x"${x_includes}" = x; then
1373   bitmapdir=/usr/include/X11/bitmaps
1374 else
1375   # accumulate include directories that have X11 bitmap subdirectories
1376   bmd_acc="dummyval"
1377   for bmd in `echo ${x_includes} | sed -e "s/:/ /g"`; do
1378     if test -d "${bmd}/X11/bitmaps"; then
1379       bmd_acc="${bmd_acc}:${bmd}/X11/bitmaps"
1380     fi
1381     if test -d "${bmd}/bitmaps"; then
1382       bmd_acc="${bmd_acc}:${bmd}/bitmaps"
1383     fi
1384   done
1385   if test ${bmd_acc} != "dummyval"; then
1386     bitmapdir=`echo ${bmd_acc} | sed -e "s/^dummyval://"`
1387   fi
1388 fi
1389
1390 HAVE_NS=no
1391 NS_IMPL_COCOA=no
1392 NS_IMPL_GNUSTEP=no
1393 tmp_CPPFLAGS="$CPPFLAGS"
1394 tmp_CFLAGS="$CFLAGS"
1395 CPPFLAGS="$CPPFLAGS -x objective-c"
1396 CFLAGS="$CFLAGS -x objective-c"
1397 TEMACS_LDFLAGS2="\${LDFLAGS}"
1398 GNU_OBJC_CFLAGS=
1399 if test "${with_ns}" != no; then
1400   if test "${opsys}" = darwin; then
1401      NS_IMPL_COCOA=yes
1402      ns_appdir=`pwd`/nextstep/Emacs.app
1403      ns_appbindir=${ns_appdir}/Contents/MacOS
1404      ns_appresdir=${ns_appdir}/Contents/Resources
1405      ns_appsrc=${srcdir}/nextstep/Cocoa/Emacs.base
1406   elif test -f $GNUSTEP_CONFIG_FILE; then
1407      NS_IMPL_GNUSTEP=yes
1408      ns_appdir=`pwd`/nextstep/Emacs.app
1409      ns_appbindir=${ns_appdir}
1410      ns_appresdir=${ns_appdir}/Resources
1411      ns_appsrc=${srcdir}/nextstep/GNUstep/Emacs.base
1412      dnl FIXME sourcing this several times in subshells seems inefficient.
1413      GNUSTEP_SYSTEM_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_HEADERS)"
1414      GNUSTEP_SYSTEM_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_SYSTEM_LIBRARIES)"
1415      dnl I seemed to need these as well with GNUstep-startup 0.25.
1416      GNUSTEP_LOCAL_HEADERS="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_HEADERS)"
1417      GNUSTEP_LOCAL_LIBRARIES="$(. $GNUSTEP_CONFIG_FILE; echo $GNUSTEP_LOCAL_LIBRARIES)"
1418      test "x${GNUSTEP_LOCAL_HEADERS}" != "x" && \
1419        GNUSTEP_LOCAL_HEADERS="-I${GNUSTEP_LOCAL_HEADERS}"
1420      test "x${GNUSTEP_LOCAL_LIBRARIES}" != "x" && \
1421        GNUSTEP_LOCAL_LIBRARIES="-L${GNUSTEP_LOCAL_LIBRARIES}"
1422      CPPFLAGS="$CPPFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1423      CFLAGS="$CFLAGS -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
1424      LDFLAGS="$LDFLAGS -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES}"
1425      LIB_STANDARD=
1426      START_FILES=
1427      TEMACS_LDFLAGS2=
1428      dnl GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS to 0 or 1.
1429      dnl If they had chosen to either define it or not, we could have
1430      dnl just used AC_CHECK_DECL here.
1431      AC_CACHE_CHECK(if GNUstep defines BASE_NATIVE_OBJC_EXCEPTIONS,
1432        emacs_cv_objc_exceptions,
1433 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GNUstepBase/GSConfig.h>]],
1434 [[#if defined BASE_NATIVE_OBJC_EXCEPTIONS && BASE_NATIVE_OBJC_EXCEPTIONS > 0
1435 1;
1436 #else
1437 fail;
1438 #endif]])], emacs_cv_objc_exceptions=yes, emacs_cv_objc_exceptions=no ) )
1439      if test $emacs_cv_objc_exceptions = yes; then
1440        dnl _NATIVE_OBJC_EXCEPTIONS is used by the GNUstep headers.
1441        AC_DEFINE(_NATIVE_OBJC_EXCEPTIONS, 1,
1442          [Define if GNUstep uses ObjC exceptions.])
1443        GNU_OBJC_CFLAGS="-fobjc-exceptions"
1444      fi
1445   fi
1446
1447   dnl This is only used while we test the NS headers, it gets reset below.
1448   CFLAGS="$CFLAGS $GNU_OBJC_CFLAGS"
1449
1450   AC_CHECK_HEADER([AppKit/AppKit.h], [HAVE_NS=yes],
1451                   [AC_MSG_ERROR([`--with-ns' was specified, but the include
1452   files are missing or cannot be compiled.])])
1453   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([#include <Foundation/NSObjCRuntime.h>],
1454                                      [NSInteger i;])],
1455                     ns_have_nsinteger=yes,
1456                     ns_have_nsinteger=no)
1457   if test $ns_have_nsinteger = yes; then
1458     AC_DEFINE(NS_HAVE_NSINTEGER, 1, [Define to 1 if `NSInteger' is defined.])
1459   fi
1460 fi
1461 AC_SUBST(TEMACS_LDFLAGS2)
1462
1463 INSTALL_ARCH_INDEP_EXTRA=install-etc
1464 ns_self_contained=no
1465 ns_frag=/dev/null
1466 NS_OBJ=
1467 NS_OBJC_OBJ=
1468 if test "${HAVE_NS}" = yes; then
1469   if test "$with_toolkit_scroll_bars" = "no"; then
1470     AC_MSG_ERROR([Non-toolkit scroll bars are not implemented for Nextstep.])
1471   fi
1472
1473   window_system=nextstep
1474   with_xft=no
1475   # set up packaging dirs
1476   if test "${EN_NS_SELF_CONTAINED}" = yes; then
1477      ns_self_contained=yes
1478      prefix=${ns_appresdir}
1479      exec_prefix=${ns_appbindir}
1480      dnl This one isn't really used, only archlibdir is.
1481      libexecdir="\${ns_appbindir}/libexec"
1482      archlibdir="\${ns_appbindir}/libexec"
1483      docdir="\${ns_appresdir}/etc"
1484      etcdir="\${ns_appresdir}/etc"
1485      dnl FIXME maybe set datarootdir instead.
1486      dnl That would also get applications, icons, man.
1487      infodir="\${ns_appresdir}/info"
1488      mandir="\${ns_appresdir}/man"
1489      lispdir="\${ns_appresdir}/lisp"
1490      leimdir="\${ns_appresdir}/leim"
1491      INSTALL_ARCH_INDEP_EXTRA=
1492   fi
1493   ns_frag=$srcdir/src/ns.mk
1494   NS_OBJ="fontset.o fringe.o image.o"
1495   NS_OBJC_OBJ="nsterm.o nsfns.o nsmenu.o nsselect.o nsimage.o nsfont.o"
1496 fi
1497 CFLAGS="$tmp_CFLAGS"
1498 CPPFLAGS="$tmp_CPPFLAGS"
1499 AC_SUBST(INSTALL_ARCH_INDEP_EXTRA)
1500 AC_SUBST(ns_self_contained)
1501 AC_SUBST(NS_OBJ)
1502 AC_SUBST(NS_OBJC_OBJ)
1503 AC_SUBST(LIB_STANDARD)
1504 AC_SUBST_FILE(ns_frag)
1505
1506 case "${window_system}" in
1507   x11 )
1508     HAVE_X_WINDOWS=yes
1509     HAVE_X11=yes
1510     case "${with_x_toolkit}" in
1511       athena | lucid ) USE_X_TOOLKIT=LUCID ;;
1512       motif ) USE_X_TOOLKIT=MOTIF ;;
1513       gtk ) with_gtk=yes
1514 dnl Don't set this for GTK.  A lot of tests below assumes Xt when
1515 dnl USE_X_TOOLKIT is set.
1516             USE_X_TOOLKIT=none ;;
1517       gtk3 ) with_gtk3=yes
1518              USE_X_TOOLKIT=none ;;
1519       no ) USE_X_TOOLKIT=none ;;
1520 dnl If user did not say whether to use a toolkit, make this decision later:
1521 dnl use the toolkit if we have gtk, or X11R5 or newer.
1522       * ) USE_X_TOOLKIT=maybe ;;
1523     esac
1524   ;;
1525   nextstep | none )
1526     HAVE_X_WINDOWS=no
1527     HAVE_X11=no
1528     USE_X_TOOLKIT=none
1529   ;;
1530 esac
1531
1532 if test "$window_system" = none && test "X$with_x" != "Xno"; then
1533    AC_CHECK_PROG(HAVE_XSERVER, X, true, false)
1534    if test "$HAVE_XSERVER" = true ||
1535       test -n "$DISPLAY" ||
1536       test "`echo /usr/lib/libX11.*`" != "/usr/lib/libX11.*"; then
1537         AC_MSG_ERROR([You seem to be running X, but no X development libraries
1538 were found.  You should install the relevant development files for X
1539 and for the toolkit you want, such as Gtk+, Lesstif or Motif.  Also make
1540 sure you have development files for image handling, i.e.
1541 tiff, gif, jpeg, png and xpm.
1542 If you are sure you want Emacs compiled without X window support, pass
1543   --without-x
1544 to configure.])
1545    fi
1546 fi
1547
1548 ### If we're using X11, we should use the X menu package.
1549 HAVE_MENUS=no
1550 case ${HAVE_X11} in
1551   yes ) HAVE_MENUS=yes ;;
1552 esac
1553
1554 # Does the opsystem file prohibit the use of the GNU malloc?
1555 # Assume not, until told otherwise.
1556 GNU_MALLOC=yes
1557
1558 AC_CACHE_CHECK(
1559   [whether malloc is Doug Lea style],
1560   [emacs_cv_var_doug_lea_malloc],
1561   [AC_LINK_IFELSE(
1562      [AC_LANG_PROGRAM(
1563         [[#include <malloc.h>
1564           static void hook (void) {}]],
1565         [[malloc_set_state (malloc_get_state ());
1566           __after_morecore_hook = hook;
1567           __malloc_initialize_hook = hook;]])],
1568      [emacs_cv_var_doug_lea_malloc=yes],
1569      [emacs_cv_var_doug_lea_malloc=no])])
1570 doug_lea_malloc=$emacs_cv_var_doug_lea_malloc
1571
1572
1573 dnl See comments in aix4-2.h about maybe using system malloc there.
1574 system_malloc=no
1575 case "$opsys" in
1576   ## darwin ld insists on the use of malloc routines in the System framework.
1577   darwin|sol2-10) system_malloc=yes ;;
1578 esac
1579
1580 if test "${system_malloc}" = "yes"; then
1581   AC_DEFINE(SYSTEM_MALLOC, 1, [Define to use system malloc.])
1582   GNU_MALLOC=no
1583   GNU_MALLOC_reason="
1584     (The GNU allocators don't work with this system configuration.)"
1585   GMALLOC_OBJ=
1586   VMLIMIT_OBJ=
1587 else
1588   test "$doug_lea_malloc" != "yes" && GMALLOC_OBJ=gmalloc.o
1589   VMLIMIT_OBJ=vm-limit.o
1590 fi
1591 AC_SUBST(GMALLOC_OBJ)
1592 AC_SUBST(VMLIMIT_OBJ)
1593
1594 if test "$doug_lea_malloc" = "yes" ; then
1595   if test "$GNU_MALLOC" = yes ; then
1596     GNU_MALLOC_reason="
1597       (Using Doug Lea's new malloc from the GNU C Library.)"
1598   fi
1599   AC_DEFINE(DOUG_LEA_MALLOC, 1,
1600             [Define to 1 if you are using the GNU C Library.])
1601
1602   ## Use mmap directly for allocating larger buffers.
1603   ## FIXME this comes from src/s/{gnu,gnu-linux}.h:
1604   ## #ifdef DOUG_LEA_MALLOC; #undef REL_ALLOC; #endif
1605   ## Does the AC_FUNC_MMAP test below make this check unnecessary?
1606   case "$opsys" in
1607     gnu*) REL_ALLOC=no ;;
1608   esac
1609 fi
1610
1611 if test x"${REL_ALLOC}" = x; then
1612   REL_ALLOC=${GNU_MALLOC}
1613 fi
1614
1615 use_mmap_for_buffers=no
1616 case "$opsys" in
1617   cygwin|freebsd|irix6-5) use_mmap_for_buffers=yes ;;
1618 esac
1619
1620 AC_FUNC_MMAP
1621 if test $use_mmap_for_buffers = yes; then
1622   AC_DEFINE(USE_MMAP_FOR_BUFFERS, 1, [Define to use mmap to allocate buffer text.])
1623   REL_ALLOC=no
1624 fi
1625
1626 LIBS="$LIBS_SYSTEM $LIBS"
1627
1628 dnl If found, this defines HAVE_LIBDNET, which m/pmax.h checks,
1629 dnl and also adds -ldnet to LIBS, which Autoconf uses for checks.
1630 AC_CHECK_LIB(dnet, dnet_ntoa)
1631 dnl This causes -lresolv to get used in subsequent tests,
1632 dnl which causes failures on some systems such as HPUX 9.
1633 dnl AC_CHECK_LIB(resolv, gethostbyname)
1634
1635 dnl FIXME replace main with a function we actually want from this library.
1636 AC_CHECK_LIB(Xbsd, main, LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -lXbsd")
1637
1638 dnl Check if pthreads is available.
1639 LIB_PTHREAD=
1640 AC_CHECK_HEADERS_ONCE(pthread.h)
1641 if test "$ac_cv_header_pthread_h"; then
1642   dnl gmalloc.c uses pthread_atfork, which is not available on older-style
1643   dnl hosts such as MirBSD 10, so test for pthread_atfork instead of merely
1644   dnl testing for pthread_self if Emacs uses gmalloc.c.
1645   if test "$GMALLOC_OBJ" = gmalloc.o; then
1646     emacs_pthread_function=pthread_atfork
1647   else
1648     emacs_pthread_function=pthread_self
1649   fi
1650   AC_CHECK_LIB(pthread, $emacs_pthread_function, HAVE_PTHREAD=yes)
1651 fi
1652 if test "$HAVE_PTHREAD" = yes; then
1653   case "${canonical}" in
1654     *-hpux*) ;;
1655     *) LIB_PTHREAD="-lpthread"
1656        LIBS="$LIB_PTHREAD $LIBS" ;;
1657   esac
1658   AC_DEFINE(HAVE_PTHREAD, 1, [Define to 1 if you have pthread (-lpthread).])
1659 fi
1660 AC_SUBST([LIB_PTHREAD])
1661
1662 AC_CHECK_LIB(pthreads, cma_open)
1663
1664 ## Note: when using cpp in s/aix4.2.h, this definition depended on
1665 ## HAVE_LIBPTHREADS.  That was not defined earlier in configure when
1666 ## the system file was sourced.  Hence the value of LIBS_SYSTEM
1667 ## added to LIBS in configure would never contain the pthreads part,
1668 ## but the value used in Makefiles might.  FIXME?
1669 ##
1670 ## -lpthreads seems to be necessary for Xlib in X11R6, and should
1671 ## be harmless on older versions of X where it happens to exist.
1672 test "$opsys" = "aix4-2" && \
1673   test $ac_cv_lib_pthreads_cma_open = yes && \
1674   LIBS_SYSTEM="$LIBS_SYSTEM -lpthreads"
1675
1676 dnl Check for need for bigtoc support on IBM AIX
1677
1678 case ${host_os} in
1679 aix*)
1680   AC_CACHE_CHECK([for -bbigtoc option], [gdb_cv_bigtoc], [
1681     case $GCC in
1682     yes) gdb_cv_bigtoc=-Wl,-bbigtoc ;;
1683     *) gdb_cv_bigtoc=-bbigtoc ;;
1684     esac
1685
1686     LDFLAGS=$LDFLAGS\ $gdb_cv_bigtoc
1687     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[int i;]])], [], [gdb_cv_bigtoc=])
1688   ])
1689   ;;
1690 esac
1691
1692 # Change CFLAGS and CPPFLAGS temporarily so that C_SWITCH_X_SITE gets
1693 # used for the tests that follow.  We set them back to REAL_CFLAGS and
1694 # REAL_CPPFLAGS later on.
1695
1696 REAL_CFLAGS="$CFLAGS"
1697 REAL_CPPFLAGS="$CPPFLAGS"
1698
1699 if test "${HAVE_X11}" = "yes"; then
1700   DEFS="$C_SWITCH_X_SITE $DEFS"
1701   LDFLAGS="$LDFLAGS $LD_SWITCH_X_SITE"
1702   LIBS="-lX11 $LIBS"
1703   CFLAGS="$C_SWITCH_X_SITE $CFLAGS"
1704   CPPFLAGS="$C_SWITCH_X_SITE $CPPFLAGS"
1705
1706   # On Solaris, arrange for LD_RUN_PATH to point to the X libraries for tests.
1707   # This is handled by LD_SWITCH_X_SITE_RPATH during the real build,
1708   # but it's more convenient here to set LD_RUN_PATH since this
1709   # also works on hosts that don't understand LD_SWITCH_X_SITE_RPATH.
1710   if test "${x_libraries}" != NONE && test -n "${x_libraries}"; then
1711     LD_RUN_PATH=$x_libraries${LD_RUN_PATH+:}$LD_RUN_PATH
1712     export LD_RUN_PATH
1713   fi
1714
1715   if test "${opsys}" = "gnu-linux"; then
1716     AC_MSG_CHECKING(whether X on GNU/Linux needs -b to link)
1717     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1718      [[XOpenDisplay ("foo");]])],
1719      [xgnu_linux_first_failure=no],
1720      [xgnu_linux_first_failure=yes])
1721     if test "${xgnu_linux_first_failure}" = "yes"; then
1722       OLD_LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE"
1723       OLD_C_SWITCH_X_SITE="$C_SWITCH_X_SITE"
1724       OLD_CPPFLAGS="$CPPFLAGS"
1725       OLD_LIBS="$LIBS"
1726       LD_SWITCH_X_SITE="$LD_SWITCH_X_SITE -b i486-linuxaout"
1727       C_SWITCH_X_SITE="$C_SWITCH_X_SITE -b i486-linuxaout"
1728       CPPFLAGS="$CPPFLAGS -b i486-linuxaout"
1729       LIBS="$LIBS -b i486-linuxaout"
1730       AC_LINK_IFELSE([AC_LANG_PROGRAM([[]],
1731        [[XOpenDisplay ("foo");]])],
1732        [xgnu_linux_second_failure=no],
1733        [xgnu_linux_second_failure=yes])
1734       if test "${xgnu_linux_second_failure}" = "yes"; then
1735         # If we get the same failure with -b, there is no use adding -b.
1736         # So take it out.  This plays safe.
1737         LD_SWITCH_X_SITE="$OLD_LD_SWITCH_X_SITE"
1738         C_SWITCH_X_SITE="$OLD_C_SWITCH_X_SITE"
1739         CPPFLAGS="$OLD_CPPFLAGS"
1740         LIBS="$OLD_LIBS"
1741         AC_MSG_RESULT(no)
1742       else
1743         AC_MSG_RESULT(yes)
1744       fi
1745     else
1746       AC_MSG_RESULT(no)
1747     fi
1748   fi
1749
1750   # Reportedly, some broken Solaris systems have XKBlib.h but are missing
1751   # header files included from there.
1752   AC_MSG_CHECKING(for Xkb)
1753   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1754 #include <X11/XKBlib.h>]],
1755         [[XkbDescPtr kb = XkbGetKeyboard (0, XkbAllComponentsMask, XkbUseCoreKbd);]])],
1756         emacs_xkb=yes, emacs_xkb=no)
1757   AC_MSG_RESULT($emacs_xkb)
1758   if test $emacs_xkb = yes; then
1759     AC_DEFINE(HAVE_XKBGETKEYBOARD, 1, [Define to 1 if you have the XkbGetKeyboard function.])
1760   fi
1761
1762   AC_CHECK_FUNCS(XrmSetDatabase XScreenResourceString \
1763 XScreenNumberOfScreen)
1764 fi
1765
1766 if test "${window_system}" = "x11"; then
1767   AC_MSG_CHECKING(X11 version 6)
1768   AC_CACHE_VAL(emacs_cv_x11_version_6,
1769   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>]],
1770 [[#if XlibSpecificationRelease < 6
1771 fail;
1772 #endif
1773 ]])], emacs_cv_x11_version_6=yes, emacs_cv_x11_version_6=no)])
1774   if test $emacs_cv_x11_version_6 = yes; then
1775     AC_MSG_RESULT(6 or newer)
1776     AC_DEFINE(HAVE_X11R6, 1,
1777               [Define to 1 if you have the X11R6 or newer version of Xlib.])
1778     AC_DEFINE(HAVE_X_I18N, 1, [Define if you have usable i18n support.])
1779     ## inoue@ainet.or.jp says Solaris has a bug related to X11R6-style
1780     ## XIM support.
1781     case "$opsys" in
1782       sol2-*) : ;;
1783       *) AC_DEFINE(HAVE_X11R6_XIM, 1,
1784            [Define if you have usable X11R6-style XIM support.])
1785          ;;
1786     esac
1787   else
1788     AC_MSG_RESULT(before 6)
1789   fi
1790 fi
1791
1792
1793 ### Use -lrsvg-2 if available, unless `--with-rsvg=no' is specified.
1794 HAVE_RSVG=no
1795 if test "${HAVE_X11}" = "yes" || test "${HAVE_NS}" = "yes"; then
1796   if test "${with_rsvg}" != "no"; then
1797     RSVG_REQUIRED=2.11.0
1798     RSVG_MODULE="librsvg-2.0 >= $RSVG_REQUIRED"
1799
1800     PKG_CHECK_MODULES(RSVG, $RSVG_MODULE, HAVE_RSVG=yes, :)
1801     AC_SUBST(RSVG_CFLAGS)
1802     AC_SUBST(RSVG_LIBS)
1803
1804     if test $HAVE_RSVG = yes; then
1805       AC_DEFINE(HAVE_RSVG, 1, [Define to 1 if using librsvg.])
1806       CFLAGS="$CFLAGS $RSVG_CFLAGS"
1807       LIBS="$RSVG_LIBS $LIBS"
1808     fi
1809   fi
1810 fi
1811
1812 HAVE_IMAGEMAGICK=no
1813 if test "${HAVE_X11}" = "yes"; then
1814   if test "${with_imagemagick}" != "no"; then
1815     ## 6.2.8 is the earliest version known to work, but earlier versions
1816     ## might work - let us know if you find one.
1817     ## 6.0.7 does not work.  See bug#7955.
1818     IMAGEMAGICK_MODULE="Wand >= 6.2.8"
1819     PKG_CHECK_MODULES(IMAGEMAGICK, $IMAGEMAGICK_MODULE, HAVE_IMAGEMAGICK=yes, :)
1820     AC_SUBST(IMAGEMAGICK_CFLAGS)
1821     AC_SUBST(IMAGEMAGICK_LIBS)
1822
1823     if test $HAVE_IMAGEMAGICK = yes; then
1824       AC_DEFINE(HAVE_IMAGEMAGICK, 1, [Define to 1 if using imagemagick.])
1825       CFLAGS="$CFLAGS $IMAGEMAGICK_CFLAGS"
1826       LIBS="$IMAGEMAGICK_LIBS $LIBS"
1827       AC_CHECK_FUNCS(MagickExportImagePixels MagickMergeImageLayers)
1828     fi
1829   fi
1830 fi
1831
1832
1833 HAVE_GTK=no
1834 GTK_OBJ=
1835 if test "${with_gtk3}" = "yes"; then
1836   GLIB_REQUIRED=2.28
1837   GTK_REQUIRED=3.0
1838   GTK_MODULES="gtk+-3.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1839
1840   dnl Checks for libraries.
1841   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1842   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1843      AC_MSG_ERROR($GTK_PKG_ERRORS)
1844   fi
1845   AC_DEFINE(HAVE_GTK3, 1, [Define to 1 if using GTK 3 or later.])
1846   GTK_OBJ=emacsgtkfixed.o
1847 fi
1848
1849 if test "$pkg_check_gtk" != "yes"; then
1850   HAVE_GTK=no
1851 if test "${with_gtk}" = "yes" || test "$USE_X_TOOLKIT" = "maybe"; then
1852   GLIB_REQUIRED=2.10
1853   GTK_REQUIRED=2.10
1854   GTK_MODULES="gtk+-2.0 >= $GTK_REQUIRED glib-2.0 >= $GLIB_REQUIRED"
1855
1856   dnl Checks for libraries.
1857   PKG_CHECK_MODULES(GTK, $GTK_MODULES, pkg_check_gtk=yes, pkg_check_gtk=no)
1858   if test "$pkg_check_gtk" = "no" && test "$USE_X_TOOLKIT" != "maybe"; then
1859      AC_MSG_ERROR($GTK_PKG_ERRORS)
1860   fi
1861 fi
1862 fi
1863
1864 if test x"$pkg_check_gtk" = xyes; then
1865
1866   AC_SUBST(GTK_CFLAGS)
1867   AC_SUBST(GTK_LIBS)
1868   C_SWITCH_X_SITE="$C_SWITCH_X_SITE $GTK_CFLAGS"
1869   CFLAGS="$CFLAGS $GTK_CFLAGS"
1870   LIBS="$GTK_LIBS $LIBS"
1871   dnl Try to compile a simple GTK program.
1872   GTK_COMPILES=no
1873   AC_CHECK_FUNCS(gtk_main, GTK_COMPILES=yes)
1874   if test "${GTK_COMPILES}" != "yes"; then
1875     if test "$USE_X_TOOLKIT" != "maybe"; then
1876       AC_MSG_ERROR([Gtk+ wanted, but it does not compile, see config.log.  Maybe some x11-devel files missing?]);
1877     fi
1878   else
1879     HAVE_GTK=yes
1880     AC_DEFINE(USE_GTK, 1, [Define to 1 if using GTK.])
1881     GTK_OBJ="gtkutil.o $GTK_OBJ"
1882     USE_X_TOOLKIT=none
1883     if $PKG_CONFIG --atleast-version=2.10 gtk+-2.0; then
1884       :
1885     else
1886       AC_MSG_WARN([[Your version of Gtk+ will have problems with
1887        closing open displays.  This is no problem if you just use
1888        one display, but if you use more than one and close one of them
1889        Emacs may crash.]])
1890       sleep 3
1891     fi
1892   fi
1893
1894 fi
1895 AC_SUBST(GTK_OBJ)
1896
1897
1898 if test "${HAVE_GTK}" = "yes"; then
1899
1900   dnl  GTK scrollbars resemble toolkit scrollbars a lot, so to avoid
1901   dnl  a lot if #ifdef:s, say we have toolkit scrollbars.
1902   if test "$with_toolkit_scroll_bars" != no; then
1903     with_toolkit_scroll_bars=yes
1904   fi
1905
1906   dnl  Check if we have the old file selection dialog declared and
1907   dnl  in the link library.  In 2.x it may be in the library,
1908   dnl  but not declared if deprecated featured has been selected out.
1909   dnl  AC_CHECK_DECL checks for a macro, so check for GTK_TYPE_FILE_SELECTION.
1910   HAVE_GTK_FILE_SELECTION=no
1911   AC_CHECK_DECL(GTK_TYPE_FILE_SELECTION, HAVE_GTK_FILE_SELECTION=yes,
1912                    HAVE_GTK_FILE_SELECTION=no, [AC_INCLUDES_DEFAULT
1913 #include <gtk/gtk.h>])
1914   if test "$HAVE_GTK_FILE_SELECTION" = yes; then
1915     AC_CHECK_FUNCS(gtk_file_selection_new)
1916   fi
1917
1918
1919   dnl Check for functions introduced in 2.14 and later.
1920   AC_CHECK_FUNCS(gtk_widget_get_window gtk_widget_set_has_window \
1921                  gtk_dialog_get_action_area gtk_widget_get_sensitive \
1922                  gtk_widget_get_mapped gtk_adjustment_get_page_size \
1923                  gtk_orientable_set_orientation \
1924                  gtk_window_set_has_resize_grip)
1925 fi
1926
1927 dnl D-Bus has been tested under GNU/Linux only.  Must be adapted for
1928 dnl other platforms.
1929 HAVE_DBUS=no
1930 DBUS_OBJ=
1931 if test "${with_dbus}" = "yes"; then
1932    PKG_CHECK_MODULES(DBUS, dbus-1 >= 1.0, HAVE_DBUS=yes, HAVE_DBUS=no)
1933    if test "$HAVE_DBUS" = yes; then
1934      LIBS="$LIBS $DBUS_LIBS"
1935      AC_DEFINE(HAVE_DBUS, 1, [Define to 1 if using D-Bus.])
1936      dnl dbus_watch_get_unix_fd has been introduced in D-Bus 1.1.1.
1937      dnl dbus_type_is_valid and dbus_validate_* have been introduced in
1938      dnl D-Bus 1.5.12.
1939      AC_CHECK_FUNCS(dbus_watch_get_unix_fd \
1940                     dbus_type_is_valid \
1941                     dbus_validate_bus_name \
1942                     dbus_validate_path \
1943                     dbus_validate_interface \
1944                     dbus_validate_member)
1945      DBUS_OBJ=dbusbind.o
1946    fi
1947 fi
1948 AC_SUBST(DBUS_OBJ)
1949
1950 dnl GSettings has been tested under GNU/Linux only.
1951 HAVE_GSETTINGS=no
1952 if test "${HAVE_X11}" = "yes" && test "${with_gsettings}" = "yes"; then
1953    PKG_CHECK_MODULES(GSETTINGS, gio-2.0 >= 2.26, HAVE_GSETTINGS=yes, HAVE_GSETTINGS=no)
1954    if test "$HAVE_GSETTINGS" = "yes"; then
1955       AC_DEFINE(HAVE_GSETTINGS, 1, [Define to 1 if using GSettings.])
1956       SETTINGS_CFLAGS="$GSETTINGS_CFLAGS"
1957       SETTINGS_LIBS="$GSETTINGS_LIBS"
1958    fi
1959 fi
1960
1961 dnl GConf has been tested under GNU/Linux only.
1962 dnl The version is really arbitrary, it is about the same age as Gtk+ 2.6.
1963 HAVE_GCONF=no
1964 if test "${HAVE_X11}" = "yes" && test "${with_gconf}" = "yes"; then
1965    PKG_CHECK_MODULES(GCONF, gconf-2.0 >= 2.13, HAVE_GCONF=yes, HAVE_GCONF=no)
1966    if test "$HAVE_GCONF" = yes; then
1967       AC_DEFINE(HAVE_GCONF, 1, [Define to 1 if using GConf.])
1968       dnl Newer GConf doesn't link with g_objects, so this is not defined.
1969       SETTINGS_CFLAGS="$SETTINGS_CFLAGS $GCONF_CFLAGS"
1970       SETTINGS_LIBS="$SETTINGS_LIBS $GCONF_LIBS"
1971    fi
1972 fi
1973
1974 if test "$HAVE_GSETTINGS" = "yes" || test "$HAVE_GCONF" = "yes"; then
1975     SAVE_CFLAGS="$CFLAGS"
1976     SAVE_LIBS="$LIBS"
1977     CFLAGS="$SETTINGS_CFLAGS $CFLAGS"
1978     LIBS="$SETTINGS_LIBS $LIBS"
1979     AC_CHECK_FUNCS([g_type_init])
1980     CFLAGS="$SAVE_CFLAGS"
1981     LIBS="$SAVE_LIBS"
1982 fi
1983 AC_SUBST(SETTINGS_CFLAGS)
1984 AC_SUBST(SETTINGS_LIBS)
1985
1986
1987 dnl SELinux is available for GNU/Linux only.
1988 HAVE_LIBSELINUX=no
1989 LIBSELINUX_LIBS=
1990 if test "${with_selinux}" = "yes"; then
1991    AC_CHECK_LIB([selinux], [lgetfilecon], HAVE_LIBSELINUX=yes, HAVE_LIBSELINUX=no)
1992    if test "$HAVE_LIBSELINUX" = yes; then
1993       AC_DEFINE(HAVE_LIBSELINUX, 1, [Define to 1 if using SELinux.])
1994       LIBSELINUX_LIBS=-lselinux
1995    fi
1996 fi
1997 AC_SUBST(LIBSELINUX_LIBS)
1998
1999 HAVE_GNUTLS=no
2000 HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=no
2001 if test "${with_gnutls}" = "yes" ; then
2002   PKG_CHECK_MODULES([LIBGNUTLS], [gnutls >= 2.6.6], HAVE_GNUTLS=yes, HAVE_GNUTLS=no)
2003   if test "${HAVE_GNUTLS}" = "yes"; then
2004     AC_DEFINE(HAVE_GNUTLS, 1, [Define if using GnuTLS.])
2005   fi
2006
2007   CFLAGS="$CFLAGS $LIBGNUTLS_CFLAGS"
2008   LIBS="$LIBGNUTLS_LIBS $LIBS"
2009   AC_CHECK_FUNCS(gnutls_certificate_set_verify_function, HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY=yes)
2010
2011   if test "${HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY}" = "yes"; then
2012     AC_DEFINE(HAVE_GNUTLS_CALLBACK_CERTIFICATE_VERIFY, 1, [Define if using GnuTLS certificate verification callbacks.])
2013   fi
2014 fi
2015
2016 AC_SUBST(LIBGNUTLS_LIBS)
2017 AC_SUBST(LIBGNUTLS_CFLAGS)
2018
2019 dnl Do not put whitespace before the #include statements below.
2020 dnl Older compilers (eg sunos4 cc) choke on it.
2021 HAVE_XAW3D=no
2022 LUCID_LIBW=
2023 if test x"${USE_X_TOOLKIT}" = xmaybe || test x"${USE_X_TOOLKIT}" = xLUCID; then
2024   if test "$with_xaw3d" != no; then
2025     AC_MSG_CHECKING(for xaw3d)
2026     AC_CACHE_VAL(emacs_cv_xaw3d,
2027     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2028 #include <X11/Intrinsic.h>
2029 #include <X11/Xaw3d/Simple.h>]],
2030       [[]])],
2031       [AC_CHECK_LIB(Xaw3d, XawScrollbarSetThumb,
2032                     emacs_cv_xaw3d=yes, emacs_cv_xaw3d=no)],
2033       emacs_cv_xaw3d=no)])
2034   else
2035     emacs_cv_xaw3d=no
2036   fi
2037   if test $emacs_cv_xaw3d = yes; then
2038     AC_MSG_RESULT([yes; using Lucid toolkit])
2039     USE_X_TOOLKIT=LUCID
2040     HAVE_XAW3D=yes
2041     LUCID_LIBW=-lXaw3d
2042     AC_DEFINE(HAVE_XAW3D, 1,
2043               [Define to 1 if you have the Xaw3d library (-lXaw3d).])
2044   else
2045     AC_MSG_RESULT(no)
2046     AC_MSG_CHECKING(for libXaw)
2047     AC_CACHE_VAL(emacs_cv_xaw,
2048     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[
2049 #include <X11/Intrinsic.h>
2050 #include <X11/Xaw/Simple.h>]],
2051       [[]])],
2052       emacs_cv_xaw=yes,
2053       emacs_cv_xaw=no)])
2054     if test $emacs_cv_xaw = yes; then
2055       AC_MSG_RESULT([yes; using Lucid toolkit])
2056       USE_X_TOOLKIT=LUCID
2057       LUCID_LIBW=-lXaw
2058     elif test x"${USE_X_TOOLKIT}" = xLUCID; then
2059       AC_MSG_ERROR([Lucid toolkit requires X11/Xaw include files])
2060     else
2061       AC_MSG_ERROR([No X toolkit could be found.
2062 If you are sure you want Emacs compiled without an X toolkit, pass
2063   --with-x-toolkit=no
2064 to configure.  Otherwise, install the development libraries for the toolkit
2065 that you want to use (e.g. Gtk+) and re-run configure.])
2066     fi
2067   fi
2068 fi
2069
2070 X_TOOLKIT_TYPE=$USE_X_TOOLKIT
2071
2072 LIBXTR6=
2073 if test "${USE_X_TOOLKIT}" != "none"; then
2074   AC_MSG_CHECKING(X11 toolkit version)
2075   AC_CACHE_VAL(emacs_cv_x11_toolkit_version_6,
2076   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <X11/Intrinsic.h>]],
2077 [[#if XtSpecificationRelease < 6
2078 fail;
2079 #endif
2080 ]])], emacs_cv_x11_toolkit_version_6=yes, emacs_cv_x11_toolkit_version_6=no)])
2081   HAVE_X11XTR6=$emacs_cv_x11_toolkit_version_6
2082   if test $emacs_cv_x11_toolkit_version_6 = yes; then
2083     AC_MSG_RESULT(6 or newer)
2084     AC_DEFINE(HAVE_X11XTR6, 1,
2085               [Define to 1 if you have the X11R6 or newer version of Xt.])
2086     LIBXTR6="-lSM -lICE"
2087     case "$opsys" in
2088       ## Use libw.a along with X11R6 Xt.
2089       unixware) LIBXTR6="$LIBXTR6 -lw" ;;
2090     esac
2091   else
2092     AC_MSG_RESULT(before 6)
2093   fi
2094
2095 dnl If using toolkit, check whether libXmu.a exists.
2096 dnl tranle@intellicorp.com says libXmu.a can need XtMalloc in libXt.a to link.
2097   OLDLIBS="$LIBS"
2098   if test x$HAVE_X11XTR6 = xyes; then
2099     LIBS="-lXt -lSM -lICE $LIBS"
2100   else
2101     LIBS="-lXt $LIBS"
2102   fi
2103   AC_CHECK_LIB(Xmu, XmuConvertStandardSelection)
2104   test $ac_cv_lib_Xmu_XmuConvertStandardSelection = no && LIBS="$OLDLIBS"
2105 fi
2106 AC_SUBST(LIBXTR6)
2107
2108 dnl FIXME the logic here seems weird, but this is what cpp was doing.
2109 dnl Why not just test for libxmu in the normal way?
2110 LIBXMU=-lXmu
2111 case $opsys in
2112   ## These systems don't supply Xmu.
2113   hpux* | aix4-2 )
2114     test "X$ac_cv_lib_Xmu_XmuConvertStandardSelection" != "Xyes" && LIBXMU=
2115     ;;
2116 esac
2117 AC_SUBST(LIBXMU)
2118
2119 # On Irix 6.5, at least, we need XShapeQueryExtension from -lXext for Xaw3D.
2120 if test "${HAVE_X11}" = "yes"; then
2121   if test "${USE_X_TOOLKIT}" != "none"; then
2122     AC_CHECK_LIB(Xext, XShapeQueryExtension)
2123   fi
2124 fi
2125
2126 LIBXP=
2127 if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2128   AC_CACHE_CHECK(for Motif version 2.1, emacs_cv_motif_version_2_1,
2129   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <Xm/Xm.h>]],
2130     [[#if XmVERSION > 2 || (XmVERSION == 2 && XmREVISION >= 1)
2131 int x = 5;
2132 #else
2133 Motif version prior to 2.1.
2134 #endif]])],
2135     emacs_cv_motif_version_2_1=yes, emacs_cv_motif_version_2_1=no)])
2136   if test $emacs_cv_motif_version_2_1 = yes; then
2137     AC_CHECK_LIB(Xp, XpCreateContext, LIBXP=-lXp)
2138   else
2139     AC_CACHE_CHECK(for LessTif where some systems put it, emacs_cv_lesstif,
2140     # We put this in CFLAGS temporarily to precede other -I options
2141     # that might be in CFLAGS temporarily.
2142     # We put this in CPPFLAGS where it precedes the other -I options.
2143     OLD_CPPFLAGS=$CPPFLAGS
2144     OLD_CFLAGS=$CFLAGS
2145     CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CPPFLAGS"
2146     CFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $CFLAGS"
2147     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include </usr/X11R6/LessTif/Motif1.2/include/Xm/Xm.h>]],
2148       [[int x = 5;]])],
2149       emacs_cv_lesstif=yes, emacs_cv_lesstif=no)])
2150     if test $emacs_cv_lesstif = yes; then
2151       # Make sure this -I option remains in CPPFLAGS after it is set
2152       # back to REAL_CPPFLAGS.
2153       # There is no need to change REAL_CFLAGS, because REAL_CFLAGS does not
2154       # have those other -I options anyway.  Ultimately, having this
2155       # directory ultimately in CPPFLAGS will be enough.
2156       REAL_CPPFLAGS="-I/usr/X11R6/LessTif/Motif1.2/include $REAL_CPPFLAGS"
2157       LDFLAGS="-L/usr/X11R6/LessTif/Motif1.2/lib $LDFLAGS"
2158     else
2159       CFLAGS=$OLD_CFLAGS
2160       CPPFLAGS=$OLD_CPPFLAGS
2161     fi
2162   fi
2163   AC_CHECK_HEADER([Xm/BulletinB.h], [],
2164     [AC_MSG_ERROR([Motif toolkit requested but requirements not found.])])
2165 fi
2166
2167 dnl Use toolkit scroll bars if configured for GTK or X toolkit and either
2168 dnl using Motif or Xaw3d is available, and unless
2169 dnl --with-toolkit-scroll-bars=no was specified.
2170
2171 AH_TEMPLATE(USE_TOOLKIT_SCROLL_BARS,
2172             [Define to 1 if we should use toolkit scroll bars.])dnl
2173 USE_TOOLKIT_SCROLL_BARS=no
2174 if test "${with_toolkit_scroll_bars}" != "no"; then
2175   if test "${USE_X_TOOLKIT}" != "none"; then
2176     if test "${USE_X_TOOLKIT}" = "MOTIF"; then
2177       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2178       HAVE_XAW3D=no
2179       USE_TOOLKIT_SCROLL_BARS=yes
2180     elif test "${HAVE_XAW3D}" = "yes" || test "${USE_X_TOOLKIT}" = "LUCID"; then
2181       AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2182       USE_TOOLKIT_SCROLL_BARS=yes
2183     fi
2184   elif test "${HAVE_GTK}" = "yes"; then
2185     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2186     USE_TOOLKIT_SCROLL_BARS=yes
2187   elif test "${HAVE_NS}" = "yes"; then
2188     AC_DEFINE(USE_TOOLKIT_SCROLL_BARS)
2189     USE_TOOLKIT_SCROLL_BARS=yes
2190   fi
2191 fi
2192
2193 dnl See if XIM is available.
2194 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2195           #include <X11/Xlib.h>
2196           #include <X11/Xresource.h>]],
2197          [[XIMProc  callback;]])],
2198          [HAVE_XIM=yes
2199          AC_DEFINE(HAVE_XIM, 1, [Define to 1 if XIM is available])],
2200          HAVE_XIM=no)
2201
2202 dnl `--with-xim' now controls only the initial value of use_xim at run time.
2203
2204 if test "${with_xim}" != "no"; then
2205   AC_DEFINE(USE_XIM, 1,
2206             [Define to 1 if we should use XIM, if it is available.])
2207 fi
2208
2209
2210 if test "${HAVE_XIM}" != "no"; then
2211   late_CFLAGS=$CFLAGS
2212   if test "$GCC" = yes; then
2213     CFLAGS="$CFLAGS --pedantic-errors"
2214   fi
2215   AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2216 #include <X11/Xlib.h>
2217 #include <X11/Xresource.h>]],
2218 [[Display *display;
2219 XrmDatabase db;
2220 char *res_name;
2221 char *res_class;
2222 XIMProc  callback;
2223 XPointer *client_data;
2224 #ifndef __GNUC__
2225 /* If we're not using GCC, it's probably not XFree86, and this is
2226    probably right, but we can't use something like --pedantic-errors.  */
2227 extern Bool XRegisterIMInstantiateCallback(Display*, XrmDatabase, char*,
2228                                            char*, XIMProc, XPointer*);
2229 #endif
2230 (void)XRegisterIMInstantiateCallback(display, db, res_name, res_class, callback,
2231    client_data);]])],
2232     [emacs_cv_arg6_star=yes])
2233   AH_TEMPLATE(XRegisterIMInstantiateCallback_arg6,
2234          [Define to the type of the 6th arg of XRegisterIMInstantiateCallback,
2235 either XPointer or XPointer*.])dnl
2236   if test "$emacs_cv_arg6_star" = yes; then
2237     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer*])
2238   else
2239     AC_DEFINE(XRegisterIMInstantiateCallback_arg6, [XPointer])
2240   fi
2241   CFLAGS=$late_CFLAGS
2242 fi
2243
2244 ### Start of font-backend (under any platform) section.
2245 # (nothing here yet -- this is a placeholder)
2246 ### End of font-backend (under any platform) section.
2247
2248 ### Start of font-backend (under X11) section.
2249 if test "${HAVE_X11}" = "yes"; then
2250    PKG_CHECK_MODULES(FONTCONFIG, fontconfig >= 2.2.0, HAVE_FC=yes, HAVE_FC=no)
2251
2252    ## Use -lXft if available, unless `--with-xft=no'.
2253    HAVE_XFT=maybe
2254     if test "${HAVE_FC}" = "no" || test "x${with_x}" = "xno"; then
2255       with_xft="no";
2256     fi
2257     if test "x${with_xft}" != "xno"; then
2258
2259       PKG_CHECK_MODULES(XFT, xft >= 0.13.0, , HAVE_XFT=no)
2260       ## Because xftfont.c uses XRenderQueryExtension, we also
2261       ## need to link to -lXrender.
2262       HAVE_XRENDER=no
2263       AC_CHECK_LIB(Xrender, XRenderQueryExtension, HAVE_XRENDER=yes)
2264       if test "$HAVE_XFT" != no && test "$HAVE_XRENDER" != no; then
2265         OLD_CPPFLAGS="$CPPFLAGS"
2266         OLD_CFLAGS="$CFLAGS"
2267         OLD_LIBS="$LIBS"
2268         CPPFLAGS="$CPPFLAGS $XFT_CFLAGS"
2269         CFLAGS="$CFLAGS $XFT_CFLAGS"
2270         XFT_LIBS="-lXrender $XFT_LIBS"
2271         LIBS="$XFT_LIBS $LIBS"
2272         AC_CHECK_HEADER(X11/Xft/Xft.h,
2273           AC_CHECK_LIB(Xft, XftFontOpen, HAVE_XFT=yes, , $XFT_LIBS))
2274
2275         if test "${HAVE_XFT}" = "yes"; then
2276           AC_DEFINE(HAVE_XFT, 1, [Define to 1 if you have the Xft library.])
2277             AC_SUBST(XFT_LIBS)
2278           C_SWITCH_X_SITE="$C_SWITCH_X_SITE $XFT_CFLAGS"
2279         else
2280           CPPFLAGS="$OLD_CPPFLAGS"
2281           CFLAGS="$OLD_CFLAGS"
2282           LIBS="$OLD_LIBS"
2283         fi                        # "${HAVE_XFT}" = "yes"
2284       fi                          # "$HAVE_XFT" != no
2285     fi                            # "x${with_xft}" != "xno"
2286
2287     ## We used to allow building with FreeType and without Xft.
2288     ## However, the ftx font backend driver is not in good shape.
2289     if test "$HAVE_XFT" != "yes"; then
2290        dnl For the "Does Emacs use" message at the end.
2291        HAVE_XFT=no
2292        HAVE_FREETYPE=no
2293     else
2294        dnl Strict linkers fail with
2295        dnl ftfont.o: undefined reference to symbol 'FT_New_Face'
2296        dnl if -lfreetype is not specified.
2297        dnl The following is needed to set FREETYPE_LIBS.
2298        PKG_CHECK_MODULES(FREETYPE, freetype2, HAVE_FREETYPE=yes,
2299                          HAVE_FREETYPE=no)
2300
2301        test "$HAVE_FREETYPE" = "no" && AC_MSG_ERROR(libxft requires libfreetype)
2302     fi
2303
2304     HAVE_LIBOTF=no
2305     if test "${HAVE_FREETYPE}" = "yes"; then
2306       AC_DEFINE(HAVE_FREETYPE, 1,
2307                 [Define to 1 if using the freetype and fontconfig libraries.])
2308       if test "${with_libotf}" != "no"; then
2309         PKG_CHECK_MODULES(LIBOTF, libotf, HAVE_LIBOTF=yes,
2310                           HAVE_LIBOTF=no)
2311         if test "$HAVE_LIBOTF" = "yes"; then
2312           AC_DEFINE(HAVE_LIBOTF, 1, [Define to 1 if using libotf.])
2313           AC_CHECK_LIB(otf, OTF_get_variation_glyphs,
2314                        HAVE_OTF_GET_VARIATION_GLYPHS=yes,
2315                        HAVE_OTF_GET_VARIATION_GLYPHS=no)
2316           if test "${HAVE_OTF_GET_VARIATION_GLYPHS}" = "yes"; then
2317             AC_DEFINE(HAVE_OTF_GET_VARIATION_GLYPHS, 1,
2318                       [Define to 1 if libotf has OTF_get_variation_glyphs.])
2319           fi
2320         fi
2321       fi
2322     dnl FIXME should there be an error if HAVE_FREETYPE != yes?
2323     dnl Does the new font backend require it, or can it work without it?
2324     fi
2325
2326     HAVE_M17N_FLT=no
2327     if test "${HAVE_LIBOTF}" = yes; then
2328       if test "${with_m17n_flt}" != "no"; then
2329         PKG_CHECK_MODULES(M17N_FLT, m17n-flt, HAVE_M17N_FLT=yes, HAVE_M17N_FLT=no)
2330         if test "$HAVE_M17N_FLT" = "yes"; then
2331           AC_DEFINE(HAVE_M17N_FLT, 1, [Define to 1 if using libm17n-flt.])
2332         fi
2333       fi
2334     fi
2335 else
2336     HAVE_XFT=no
2337     HAVE_FREETYPE=no
2338     HAVE_LIBOTF=no
2339     HAVE_M17N_FLT=no
2340 fi
2341
2342 ### End of font-backend (under X11) section.
2343
2344 AC_SUBST(FREETYPE_CFLAGS)
2345 AC_SUBST(FREETYPE_LIBS)
2346 AC_SUBST(FONTCONFIG_CFLAGS)
2347 AC_SUBST(FONTCONFIG_LIBS)
2348 AC_SUBST(LIBOTF_CFLAGS)
2349 AC_SUBST(LIBOTF_LIBS)
2350 AC_SUBST(M17N_FLT_CFLAGS)
2351 AC_SUBST(M17N_FLT_LIBS)
2352
2353 ### Use -lXpm if available, unless `--with-xpm=no'.
2354 HAVE_XPM=no
2355 LIBXPM=
2356 if test "${HAVE_X11}" = "yes"; then
2357   if test "${with_xpm}" != "no"; then
2358     AC_CHECK_HEADER(X11/xpm.h,
2359       [AC_CHECK_LIB(Xpm, XpmReadFileToPixmap, HAVE_XPM=yes, , -lX11)])
2360     if test "${HAVE_XPM}" = "yes"; then
2361       AC_MSG_CHECKING(for XpmReturnAllocPixels preprocessor define)
2362       AC_EGREP_CPP(no_return_alloc_pixels,
2363       [#include "X11/xpm.h"
2364 #ifndef XpmReturnAllocPixels
2365 no_return_alloc_pixels
2366 #endif
2367       ], HAVE_XPM=no, HAVE_XPM=yes)
2368
2369       if test "${HAVE_XPM}" = "yes"; then
2370         AC_MSG_RESULT(yes)
2371       else
2372         AC_MSG_RESULT(no)
2373       fi
2374     fi
2375   fi
2376
2377   if test "${HAVE_XPM}" = "yes"; then
2378     AC_DEFINE(HAVE_XPM, 1, [Define to 1 if you have the Xpm library (-lXpm).])
2379     LIBXPM=-lXpm
2380   fi
2381 fi
2382 AC_SUBST(LIBXPM)
2383
2384 ### Use -ljpeg if available, unless `--with-jpeg=no'.
2385 HAVE_JPEG=no
2386 LIBJPEG=
2387 if test "${HAVE_X11}" = "yes"; then
2388   if test "${with_jpeg}" != "no"; then
2389     dnl Checking for jpeglib.h can lose because of a redefinition of
2390     dnl  HAVE_STDLIB_H.
2391     AC_CHECK_HEADER(jerror.h,
2392       [AC_CHECK_LIB(jpeg, jpeg_destroy_compress, HAVE_JPEG=yes)])
2393   fi
2394
2395   AH_TEMPLATE(HAVE_JPEG, [Define to 1 if you have the jpeg library (-ljpeg).])dnl
2396   if test "${HAVE_JPEG}" = "yes"; then
2397     AC_DEFINE(HAVE_JPEG)
2398     AC_EGREP_CPP([version= *(6[2-9]|[7-9][0-9])],
2399         [#include <jpeglib.h>
2400          version=JPEG_LIB_VERSION
2401 ],
2402         [AC_DEFINE(HAVE_JPEG)],
2403         [AC_MSG_WARN([libjpeg found, but not version 6b or later])
2404         HAVE_JPEG=no])
2405   fi
2406   if test "${HAVE_JPEG}" = "yes"; then
2407     LIBJPEG=-ljpeg
2408   fi
2409 fi
2410 AC_SUBST(LIBJPEG)
2411
2412 ### Use -lpng if available, unless `--with-png=no'.
2413 HAVE_PNG=no
2414 LIBPNG=
2415 if test "${HAVE_X11}" = "yes"; then
2416   if test "${with_png}" != "no"; then
2417     # Debian unstable as of July 2003 has multiple libpngs, and puts png.h
2418     # in /usr/include/libpng.
2419     AC_CHECK_HEADERS(png.h libpng/png.h)
2420     if test "$ac_cv_header_png_h" = yes || test "$ac_cv_header_libpng_png_h" = yes ; then
2421       AC_CHECK_LIB(png, png_get_channels, HAVE_PNG=yes, , -lz -lm)
2422     fi
2423   fi
2424
2425   if test "${HAVE_PNG}" = "yes"; then
2426     AC_DEFINE(HAVE_PNG, 1, [Define to 1 if you have the png library (-lpng).])
2427     LIBPNG="-lpng -lz -lm"
2428   fi
2429 fi
2430 AC_SUBST(LIBPNG)
2431
2432 ### Use -ltiff if available, unless `--with-tiff=no'.
2433 HAVE_TIFF=no
2434 LIBTIFF=
2435 if test "${HAVE_X11}" = "yes"; then
2436   if test "${with_tiff}" != "no"; then
2437     AC_CHECK_HEADER(tiffio.h,
2438       [tifflibs="-lz -lm"
2439       # At least one tiff package requires the jpeg library.
2440       if test "${HAVE_JPEG}" = yes; then tifflibs="-ljpeg $tifflibs"; fi
2441       AC_CHECK_LIB(tiff, TIFFGetVersion, HAVE_TIFF=yes, , $tifflibs)])
2442   fi
2443
2444   if test "${HAVE_TIFF}" = "yes"; then
2445     AC_DEFINE(HAVE_TIFF, 1, [Define to 1 if you have the tiff library (-ltiff).])
2446     dnl FIXME -lz -lm, as per libpng?
2447     LIBTIFF=-ltiff
2448   fi
2449 fi
2450 AC_SUBST(LIBTIFF)
2451
2452 ### Use -lgif or -lungif if available, unless `--with-gif=no'.
2453 HAVE_GIF=no
2454 LIBGIF=
2455 if test "${HAVE_X11}" = "yes" && test "${with_gif}" != "no"; then
2456   AC_CHECK_HEADER(gif_lib.h,
2457 # EGifPutExtensionLast only exists from version libungif-4.1.0b1.
2458 # Earlier versions can crash Emacs.
2459     [AC_CHECK_LIB(gif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=maybe)])
2460
2461   if test "$HAVE_GIF" = yes; then
2462     LIBGIF=-lgif
2463   elif test "$HAVE_GIF" = maybe; then
2464 # If gif_lib.h but no libgif, try libungif.
2465     AC_CHECK_LIB(ungif, EGifPutExtensionLast, HAVE_GIF=yes, HAVE_GIF=no)
2466     test "$HAVE_GIF" = yes && LIBGIF=-lungif
2467   fi
2468
2469   if test "${HAVE_GIF}" = "yes"; then
2470     AC_DEFINE(HAVE_GIF, 1, [Define to 1 if you have a gif (or ungif) library.])
2471   fi
2472 fi
2473 AC_SUBST(LIBGIF)
2474
2475 dnl Check for required libraries.
2476 if test "${HAVE_X11}" = "yes"; then
2477   MISSING=""
2478   WITH_NO=""
2479   test "${with_xpm}" != "no" && test "${HAVE_XPM}" != "yes" &&
2480     MISSING="libXpm" && WITH_NO="--with-xpm=no"
2481   test "${with_jpeg}" != "no" && test "${HAVE_JPEG}" != "yes" &&
2482     MISSING="$MISSING libjpeg" && WITH_NO="$WITH_NO --with-jpeg=no"
2483   test "${with_png}" != "no" && test "${HAVE_PNG}" != "yes" &&
2484     MISSING="$MISSING libpng" && WITH_NO="$WITH_NO --with-png=no"
2485   test "${with_gif}" != "no" && test "${HAVE_GIF}" != "yes" &&
2486     MISSING="$MISSING libgif/libungif" && WITH_NO="$WITH_NO --with-gif=no"
2487   test "${with_tiff}" != "no" && test "${HAVE_TIFF}" != "yes" &&
2488     MISSING="$MISSING libtiff" && WITH_NO="$WITH_NO --with-tiff=no"
2489
2490   if test "X${MISSING}" != X; then
2491     AC_MSG_ERROR([The following required libraries were not found:
2492     $MISSING
2493 Maybe some development libraries/packages are missing?
2494 If you don't want to link with them give
2495     $WITH_NO
2496 as options to configure])
2497   fi
2498 fi
2499
2500 ### Use -lgpm if available, unless `--with-gpm=no'.
2501 HAVE_GPM=no
2502 LIBGPM=
2503 if test "${with_gpm}" != "no"; then
2504   AC_CHECK_HEADER(gpm.h,
2505     [AC_CHECK_LIB(gpm, Gpm_Open, HAVE_GPM=yes)])
2506
2507   if test "${HAVE_GPM}" = "yes"; then
2508     AC_DEFINE(HAVE_GPM, 1, [Define to 1 if you have the gpm library (-lgpm).])
2509     LIBGPM=-lgpm
2510   fi
2511 fi
2512 AC_SUBST(LIBGPM)
2513
2514 dnl Check for malloc/malloc.h on darwin
2515 AC_CHECK_HEADERS_ONCE(malloc/malloc.h)
2516
2517 GNUSTEP_CFLAGS=
2518 ### Use NeXTstep API to implement GUI.
2519 if test "${HAVE_NS}" = "yes"; then
2520   AC_DEFINE(HAVE_NS, 1, [Define to 1 if you are using the NeXTstep API, either GNUstep or Cocoa on Mac OS X.])
2521   if test "${NS_IMPL_COCOA}" = "yes"; then
2522     AC_DEFINE(NS_IMPL_COCOA, 1, [Define to 1 if you are using NS windowing under MacOS X.])
2523   fi
2524   if test "${NS_IMPL_GNUSTEP}" = "yes"; then
2525     AC_DEFINE(NS_IMPL_GNUSTEP, 1, [Define to 1 if you are using NS windowing under GNUstep.])
2526     # See also .m.o rule in Makefile.in */
2527     # FIXME: are all these flags really needed?  Document here why.  */
2528     GNUSTEP_CFLAGS="-D_REENTRANT -fPIC -fno-strict-aliasing -I${GNUSTEP_SYSTEM_HEADERS} ${GNUSTEP_LOCAL_HEADERS}"
2529     ## Extra CFLAGS applied to src/*.m files.
2530     GNU_OBJC_CFLAGS="$GNU_OBJC_CFLAGS -fgnu-runtime -Wno-import -fconstant-string-class=NSConstantString -DGNUSTEP_BASE_LIBRARY=1 -DGNU_GUI_LIBRARY=1 -DGNU_RUNTIME=1 -DGSWARN -DGSDIAGNOSE"
2531   fi
2532   # We also have mouse menus.
2533   HAVE_MENUS=yes
2534   OTHER_FILES=ns-app
2535 fi
2536
2537
2538 ### Use session management (-lSM -lICE) if available
2539 HAVE_X_SM=no
2540 LIBXSM=
2541 if test "${HAVE_X11}" = "yes"; then
2542   AC_CHECK_HEADER(X11/SM/SMlib.h,
2543     [AC_CHECK_LIB(SM, SmcOpenConnection, HAVE_X_SM=yes, , -lICE)])
2544
2545   if test "${HAVE_X_SM}" = "yes"; then
2546     AC_DEFINE(HAVE_X_SM, 1, [Define to 1 if you have the SM library (-lSM).])
2547     LIBXSM="-lSM -lICE"
2548     case "$LIBS" in
2549       *-lSM*) ;;
2550       *)      LIBS="$LIBXSM $LIBS" ;;
2551     esac
2552   fi
2553 fi
2554 AC_SUBST(LIBXSM)
2555
2556 ### Use libxml (-lxml2) if available
2557 HAVE_LIBXML2=no
2558 if test "${with_xml2}" != "no"; then
2559   ### I'm not sure what the version number should be, so I just guessed.
2560   PKG_CHECK_MODULES(LIBXML2, libxml-2.0 > 2.6.17, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2561   if test "${HAVE_LIBXML2}" = "yes"; then
2562     LIBS="$LIBXML2_LIBS $LIBS"
2563     AC_CHECK_LIB(xml2, htmlReadMemory, HAVE_LIBXML2=yes, HAVE_LIBXML2=no)
2564     if test "${HAVE_LIBXML2}" = "yes"; then
2565       AC_DEFINE(HAVE_LIBXML2, 1, [Define to 1 if you have the libxml library (-lxml2).])
2566     else
2567       LIBXML2_LIBS=""
2568       LIBXML2_CFLAGS=""
2569     fi
2570   fi
2571 fi
2572 AC_SUBST(LIBXML2_LIBS)
2573 AC_SUBST(LIBXML2_CFLAGS)
2574
2575 # If netdb.h doesn't declare h_errno, we must declare it by hand.
2576 AC_CACHE_CHECK(whether netdb declares h_errno,
2577                emacs_cv_netdb_declares_h_errno,
2578 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],
2579   [[return h_errno;]])],
2580   emacs_cv_netdb_declares_h_errno=yes, emacs_cv_netdb_declares_h_errno=no)])
2581 if test $emacs_cv_netdb_declares_h_errno = yes; then
2582   AC_DEFINE(HAVE_H_ERRNO, 1, [Define to 1 if netdb.h declares h_errno.])
2583 fi
2584
2585 # fmod, logb, and frexp are found in -lm on most systems.
2586 # On HPUX 9.01, -lm does not contain logb, so check for sqrt.
2587 AC_CHECK_LIB(m, sqrt)
2588
2589 # Check for mail-locking functions in a "mail" library.  Probably this should
2590 # have the same check as for liblockfile below.
2591 AC_CHECK_LIB(mail, maillock, have_mail=yes, have_mail=no)
2592 if test $have_mail = yes; then
2593   LIBS_MAIL=-lmail
2594   LIBS="$LIBS_MAIL $LIBS"
2595   AC_DEFINE(HAVE_LIBMAIL, 1, [Define to 1 if you have the `mail' library (-lmail).])
2596 else
2597   LIBS_MAIL=
2598 fi
2599 dnl Debian, at least:
2600 AC_CHECK_LIB(lockfile, maillock, have_lockfile=yes, have_lockfile=no)
2601 if test $have_lockfile = yes; then
2602    LIBS_MAIL=-llockfile
2603    LIBS="$LIBS_MAIL $LIBS"
2604    AC_DEFINE(HAVE_LIBLOCKFILE, 1, [Define to 1 if you have the `lockfile' library (-llockfile).])
2605 else
2606 # If we have the shared liblockfile, assume we must use it for mail
2607 # locking (e.g. Debian).  If we couldn't link against liblockfile
2608 # (no liblockfile.a installed), ensure that we don't need to.
2609   dnl This works for files generally, not just executables.
2610   dnl Should we look elsewhere for it?  Maybe examine /etc/ld.so.conf?
2611   AC_CHECK_PROG(liblockfile, liblockfile.so, yes, no,
2612                 /usr/lib:/lib:/usr/local/lib:$LD_LIBRARY_PATH)
2613   if test $ac_cv_prog_liblockfile = yes; then
2614     AC_MSG_ERROR([Shared liblockfile found but can't link against it.
2615 This probably means that movemail could lose mail.
2616 There may be a `development' package to install containing liblockfile.])
2617   fi
2618 fi
2619 AC_CHECK_HEADERS_ONCE(maillock.h)
2620 AC_SUBST(LIBS_MAIL)
2621
2622 ## Define MAIL_USE_FLOCK (or LOCKF) if the mailer uses flock (or lockf) to
2623 ## interlock access to the mail spool.  The alternative is a lock file named
2624 ## /usr/spool/mail/$USER.lock.
2625 mail_lock=no
2626 case "$opsys" in
2627   aix4-2) mail_lock="lockf" ;;
2628
2629   gnu|freebsd|netbsd|openbsd|darwin|irix6-5) mail_lock="flock" ;;
2630
2631   ## On GNU/Linux systems, both methods are used by various mail programs.
2632   ## I assume most people are using newer mailers that have heard of flock.
2633   ## Change this if you need to.
2634   ## Debian contains a patch which says: ``On Debian/GNU/Linux systems,
2635   ## configure gets the right answers, and that means *NOT* using flock.
2636   ## Using flock is guaranteed to be the wrong thing. See Debian Policy
2637   ## for details.'' and then uses `#ifdef DEBIAN'.  Unfortunately the
2638   ## Debian maintainer hasn't provided a clean fix for Emacs.
2639   ## movemail.c will use `maillock' when MAILDIR, HAVE_LIBMAIL and
2640   ## HAVE_MAILLOCK_H are defined, so the following appears to be the
2641   ## correct logic.  -- fx
2642   ## We must check for HAVE_LIBLOCKFILE too, as movemail does.
2643   ## liblockfile is a Free Software replacement for libmail, used on
2644   ## Debian systems and elsewhere. -rfr.
2645   gnu-*)
2646     mail_lock="flock"
2647     if test $have_mail = yes || test $have_lockfile = yes; then
2648       test $ac_cv_header_maillock_h = yes && mail_lock=no
2649     fi
2650     ;;
2651 esac
2652
2653 BLESSMAIL_TARGET=
2654 case "$mail_lock" in
2655   flock) AC_DEFINE(MAIL_USE_FLOCK, 1, [Define if the mailer uses flock to interlock the mail spool.]) ;;
2656
2657   lockf) AC_DEFINE(MAIL_USE_LOCKF, 1, [Define if the mailer uses lockf to interlock the mail spool.]) ;;
2658
2659   *) BLESSMAIL_TARGET="need-blessmail" ;;
2660 esac
2661 AC_SUBST(BLESSMAIL_TARGET)
2662
2663
2664 AC_CHECK_FUNCS(gethostname \
2665 rename closedir mkdir rmdir getrusage get_current_dir_name \
2666 random lrand48 logb frexp fmod rint cbrt setsid \
2667 strerror fpathconf select euidaccess getpagesize setlocale \
2668 utimes getrlimit setrlimit setpgid getcwd getwd shutdown getaddrinfo \
2669 __fpending strsignal setitimer \
2670 sendto recvfrom getsockname getpeername getifaddrs freeifaddrs \
2671 gai_strerror mkstemp getline getdelim fsync sync \
2672 difftime posix_memalign \
2673 getpwent endpwent getgrent endgrent \
2674 touchlock \
2675 strcasecmp strncasecmp \
2676 cfmakeraw cfsetspeed copysign __executable_start)
2677
2678 dnl Cannot use AC_CHECK_FUNCS
2679 AC_CACHE_CHECK([for __builtin_unwind_init],
2680                emacs_cv_func___builtin_unwind_init,
2681 [AC_LINK_IFELSE([AC_LANG_PROGRAM([], [__builtin_unwind_init ();])],
2682                 emacs_cv_func___builtin_unwind_init=yes,
2683                 emacs_cv_func___builtin_unwind_init=no)])
2684 if test $emacs_cv_func___builtin_unwind_init = yes; then
2685   AC_DEFINE(HAVE___BUILTIN_UNWIND_INIT, 1,
2686             [Define to 1 if you have the `__builtin_unwind_init' function.])
2687 fi
2688
2689 AC_CHECK_HEADERS_ONCE(sys/un.h)
2690
2691 AC_FUNC_FSEEKO
2692
2693 AC_FUNC_GETPGRP
2694
2695 # UNIX98 PTYs.
2696 AC_CHECK_FUNCS(grantpt)
2697
2698 # PTY-related GNU extensions.
2699 AC_CHECK_FUNCS(getpt)
2700
2701 # Check this now, so that we will NOT find the above functions in ncurses.
2702 # That is because we have not set up to link ncurses in lib-src.
2703 # It's better to believe a function is not available
2704 # than to expect to find it in ncurses.
2705 # Also we need tputs and friends to be able to build at all.
2706 AC_MSG_CHECKING([for library containing tputs])
2707 # Run a test program that contains a call to tputs, a call that is
2708 # never executed.  This tests whether a pre-'main' dynamic linker
2709 # works with the library.  It's too much trouble to actually call
2710 # tputs in the test program, due to portability hassles.  When
2711 # cross-compiling, assume the test program will run if it links.
2712 AC_DEFUN([tputs_link_source], [
2713   AC_LANG_SOURCE(
2714      [[extern void tputs (const char *, int, int (*)(int));
2715        int main (int argc, char **argv)
2716        {
2717           if (argc == 10000)
2718             tputs (argv[0], 0, 0);
2719           return 0;
2720        }]])
2721 ])
2722 # Maybe curses should be tried earlier?
2723 # See http://debbugs.gnu.org/cgi/bugreport.cgi?bug=9736#35
2724 for tputs_library in '' tinfo ncurses terminfo termcap curses; do
2725   OLIBS=$LIBS
2726   if test -z "$tputs_library"; then
2727     LIBS_TERMCAP=
2728     msg='none required'
2729   else
2730     LIBS_TERMCAP=-l$tputs_library
2731     msg=$LIBS_TERMCAP
2732     LIBS="$LIBS_TERMCAP $LIBS"
2733   fi
2734   AC_RUN_IFELSE([tputs_link_source], [], [msg=no],
2735     [AC_LINK_IFELSE([tputs_link_source], [], [msg=no])])
2736   LIBS=$OLIBS
2737   if test "X$msg" != Xno; then
2738     break
2739   fi
2740 done
2741 AC_MSG_RESULT([$msg])
2742 if test "X$msg" = Xno; then
2743   AC_MSG_ERROR([The required function `tputs' was not found in any library.
2744 The following libraries were tried (in order):
2745   libtinfo, libncurses, libterminfo, libtermcap, libcurses
2746 Please try installing whichever of these libraries is most appropriate
2747 for your system, together with its header files.
2748 For example, a libncurses-dev(el) or similar package.])
2749 fi
2750
2751 ## Use termcap instead of terminfo?
2752 ## Only true for: freebsd < 40000, ms-w32, msdos, netbsd < 599002500.
2753 TERMINFO=yes
2754 ## FIXME?  In the cases below where we unconditionally set
2755 ## LIBS_TERMCAP="-lncurses", this overrides LIBS_TERMCAP = -ltinfo,
2756 ## if that was found above to have tputs.
2757 ## Should we use the gnu* logic everywhere?
2758 case "$opsys" in
2759   ## darwin: Prevents crashes when running Emacs in Terminal.app under 10.2.
2760   ##  The ncurses library has been moved out of the System framework in
2761   ##  Mac OS X 10.2.  So if configure detects it, set the command-line
2762   ##  option to use it.
2763   darwin) LIBS_TERMCAP="-lncurses" ;;
2764
2765   gnu*) test -z "$LIBS_TERMCAP" && LIBS_TERMCAP="-lncurses" ;;
2766
2767   freebsd)
2768     AC_MSG_CHECKING([whether FreeBSD is new enough to use terminfo])
2769     AC_CACHE_VAL(emacs_cv_freebsd_terminfo,
2770     [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <osreldate.h>]],
2771 [[#if __FreeBSD_version < 400000
2772 fail;
2773 #endif
2774 ]])], emacs_cv_freebsd_terminfo=yes, emacs_cv_freebsd_terminfo=no)])
2775
2776     AC_MSG_RESULT($emacs_cv_freebsd_terminfo)
2777
2778     if test $emacs_cv_freebsd_terminfo = yes; then
2779       LIBS_TERMCAP="-lncurses"
2780     else
2781       TERMINFO=no
2782       LIBS_TERMCAP="-ltermcap"
2783     fi
2784     ;;
2785
2786   netbsd)
2787     if test "x$LIBS_TERMCAP" != "x-lterminfo"; then
2788       TERMINFO=no
2789       LIBS_TERMCAP="-ltermcap"
2790     fi
2791     ;;
2792
2793   openbsd) LIBS_TERMCAP="-lncurses" ;;
2794
2795   ## hpux: Make sure we get select from libc rather than from libcurses
2796   ##  because libcurses on HPUX 10.10 has a broken version of select.
2797   ##  We used to use -lc -lcurses, but this may be cleaner.
2798   ## FIXME?  But TERMINFO = yes on hpux (it used to be explicitly
2799   # set that way, now it uses the default).  Isn't this a contradiction?
2800   hpux*) LIBS_TERMCAP="-ltermcap" ;;
2801
2802 esac
2803
2804 TERMCAP_OBJ=tparam.o
2805 if test $TERMINFO = yes; then
2806   AC_DEFINE(TERMINFO, 1, [Define to 1 if you use terminfo instead of termcap.])
2807   TERMCAP_OBJ=terminfo.o
2808 fi
2809 AC_SUBST(LIBS_TERMCAP)
2810 AC_SUBST(TERMCAP_OBJ)
2811
2812
2813 # Do we have res_init, for detecting changes in /etc/resolv.conf?
2814 resolv=no
2815 AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2816 #include <arpa/nameser.h>
2817 #include <resolv.h>]],
2818     [[return res_init();]])],
2819     have_res_init=yes, have_res_init=no)
2820 if test "$have_res_init" = no; then
2821   OLIBS="$LIBS"
2822   LIBS="$LIBS -lresolv"
2823   AC_MSG_CHECKING(for res_init with -lresolv)
2824   AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netinet/in.h>
2825 #include <arpa/nameser.h>
2826 #include <resolv.h>]],
2827     [[return res_init();]])],
2828     have_res_init=yes, have_res_init=no)
2829   AC_MSG_RESULT($have_res_init)
2830   if test "$have_res_init" = yes ; then
2831     resolv=yes
2832   fi
2833   LIBS="$OLIBS"
2834 fi
2835
2836 if test "$have_res_init" = yes; then
2837   AC_DEFINE(HAVE_RES_INIT, 1, [Define to 1 if res_init is available.])
2838 fi
2839
2840 # Do we need the Hesiod library to provide the support routines?
2841 LIBHESIOD=
2842 if test "$with_hesiod" != no ; then
2843   # Don't set $LIBS here -- see comments above.  FIXME which comments?
2844   AC_CHECK_FUNC(res_send, , [AC_CHECK_FUNC(__res_send, ,
2845      [AC_CHECK_LIB(resolv, res_send, resolv=yes,
2846                   [AC_CHECK_LIB(resolv, __res_send, resolv=yes)])])])
2847   if test "$resolv" = yes ; then
2848     RESOLVLIB=-lresolv
2849   else
2850     RESOLVLIB=
2851   fi
2852   AC_CHECK_FUNC(hes_getmailhost, , [AC_CHECK_LIB(hesiod, hes_getmailhost,
2853         hesiod=yes, :, $RESOLVLIB)])
2854
2855   if test x"$hesiod" = xyes; then
2856     AC_DEFINE(HAVE_LIBHESIOD, 1,
2857               [Define to 1 if you have the hesiod library (-lhesiod).])
2858     LIBHESIOD=-lhesiod
2859   fi
2860 fi
2861 AC_SUBST(LIBHESIOD)
2862
2863 # Do we need libresolv (due to res_init or Hesiod)?
2864 if test "$resolv" = yes ; then
2865   AC_DEFINE(HAVE_LIBRESOLV, 1,
2866             [Define to 1 if you have the resolv library (-lresolv).])
2867   LIBRESOLV=-lresolv
2868 else
2869   LIBRESOLV=
2870 fi
2871 AC_SUBST(LIBRESOLV)
2872
2873 # These tell us which Kerberos-related libraries to use.
2874 COM_ERRLIB=
2875 CRYPTOLIB=
2876 KRB5LIB=
2877 DESLIB=
2878 KRB4LIB=
2879
2880 if test "${with_kerberos}" != no; then
2881   AC_CHECK_LIB(com_err, com_err, have_com_err=yes, have_com_err=no)
2882   if test $have_com_err = yes; then
2883     COM_ERRLIB=-lcom_err
2884     LIBS="$COM_ERRLIB $LIBS"
2885     AC_DEFINE(HAVE_LIBCOM_ERR, 1, [Define to 1 if you have the `com_err' library (-lcom_err).])
2886   fi
2887   AC_CHECK_LIB(crypto, mit_des_cbc_encrypt, have_crypto=yes, have_crypto=no)
2888   if test $have_crypto = yes; then
2889     CRYPTOLIB=-lcrypto
2890     LIBS="$CRYPTOLIB $LIBS"
2891     AC_DEFINE(HAVE_LIBCRYPTO, 1, [Define to 1 if you have the `crypto' library (-lcrypto).])
2892   fi
2893   AC_CHECK_LIB(k5crypto, mit_des_cbc_encrypt, have_k5crypto=yes, have_k5crypto=no)
2894   if test $have_k5crypto = yes; then
2895     CRYPTOLIB=-lk5crypto
2896     LIBS="$CRYPTOLIB $LIBS"
2897     AC_DEFINE(HAVE_LIBK5CRYPTO, 1, [Define to 1 if you have the `k5crypto' library (-lk5crypto).])
2898   fi
2899   AC_CHECK_LIB(krb5, krb5_init_context, have_krb5=yes, have_krb5=no)
2900   if test $have_krb5=yes; then
2901     KRB5LIB=-lkrb5
2902     LIBS="$KRB5LIB $LIBS"
2903     AC_DEFINE(HAVE_LIBKRB5, 1, [Define to 1 if you have the `krb5' library (-lkrb5).])
2904   fi
2905   dnl FIXME Simplify.  Does not match 22 logic, thanks to default_off?
2906   if test "${with_kerberos5}" = no; then
2907     AC_CHECK_LIB(des425, des_cbc_encrypt, have_des425=yes, have_des425=no )
2908     if test $have_des425 = yes; then
2909       DESLIB=-ldes425
2910       LIBS="$DESLIB $LIBS"
2911       AC_DEFINE(HAVE_LIBDES425, 1, [Define to 1 if you have the `des425' library (-ldes425).])
2912     else
2913       AC_CHECK_LIB(des, des_cbc_encrypt, have_des=yes, have_des=no)
2914       if test $have_des = yes; then
2915         DESLIB=-ldes
2916         LIBS="$DESLIB $LIBS"
2917         AC_DEFINE(HAVE_LIBDES, 1, [Define to 1 if you have the `des' library (-ldes).])
2918       fi
2919     fi
2920     AC_CHECK_LIB(krb4, krb_get_cred, have_krb4=yes, have_krb4=no)
2921     if test $have_krb4 = yes; then
2922       KRB4LIB=-lkrb4
2923       LIBS="$KRB4LIB $LIBS"
2924       AC_DEFINE(HAVE_LIBKRB4, 1, [Define to 1 if you have the `krb4' library (-lkrb4).])
2925     else
2926       AC_CHECK_LIB(krb, krb_get_cred, have_krb=yes, have_krb=no)
2927       if test $have_krb = yes; then
2928         KRB4LIB=-lkrb
2929         LIBS="$KRB4LIB $LIBS"
2930         AC_DEFINE(HAVE_LIBKRB, 1, [Define to 1 if you have the `krb' library (-lkrb).])
2931       fi
2932     fi
2933   fi
2934
2935   if test "${with_kerberos5}" != no; then
2936     AC_CHECK_HEADERS(krb5.h,
2937       [AC_CHECK_MEMBERS([krb5_error.text, krb5_error.e_text],,,
2938                         [#include <krb5.h>])])
2939   else
2940     AC_CHECK_HEADERS(des.h,,
2941                      [AC_CHECK_HEADERS(kerberosIV/des.h,,
2942                                        [AC_CHECK_HEADERS(kerberos/des.h)])])
2943     AC_CHECK_HEADERS(krb.h,,
2944                      [AC_CHECK_HEADERS(kerberosIV/krb.h,,
2945                                        [AC_CHECK_HEADERS(kerberos/krb.h)])])
2946   fi
2947   AC_CHECK_HEADERS(com_err.h)
2948 fi
2949
2950 AC_SUBST(COM_ERRLIB)
2951 AC_SUBST(CRYPTOLIB)
2952 AC_SUBST(KRB5LIB)
2953 AC_SUBST(DESLIB)
2954 AC_SUBST(KRB4LIB)
2955
2956 AC_CHECK_FUNCS(tzset)
2957 AC_MSG_CHECKING(whether localtime caches TZ)
2958 AC_CACHE_VAL(emacs_cv_localtime_cache,
2959 [if test x$ac_cv_func_tzset = xyes; then
2960 AC_RUN_IFELSE([AC_LANG_SOURCE([[#include <time.h>
2961 char TZ_GMT0[] = "TZ=GMT0";
2962 char TZ_PST8[] = "TZ=PST8";
2963 main()
2964 {
2965   time_t now = time ((time_t *) 0);
2966   int hour_GMT0, hour_unset;
2967   if (putenv (TZ_GMT0) != 0)
2968     exit (1);
2969   hour_GMT0 = localtime (&now)->tm_hour;
2970   unsetenv("TZ");
2971   hour_unset = localtime (&now)->tm_hour;
2972   if (putenv (TZ_PST8) != 0)
2973     exit (1);
2974   if (localtime (&now)->tm_hour == hour_GMT0)
2975     exit (1);
2976   unsetenv("TZ");
2977   if (localtime (&now)->tm_hour != hour_unset)
2978     exit (1);
2979   exit (0);
2980 }]])], emacs_cv_localtime_cache=no, emacs_cv_localtime_cache=yes,
2981 [# If we have tzset, assume the worst when cross-compiling.
2982 emacs_cv_localtime_cache=yes])
2983 else
2984         # If we lack tzset, report that localtime does not cache TZ,
2985         # since we can't invalidate the cache if we don't have tzset.
2986         emacs_cv_localtime_cache=no
2987 fi])dnl
2988 AC_MSG_RESULT($emacs_cv_localtime_cache)
2989 if test $emacs_cv_localtime_cache = yes; then
2990   AC_DEFINE(LOCALTIME_CACHE, 1,
2991             [Define to 1 if localtime caches TZ.])
2992 fi
2993
2994 ok_so_far=yes
2995 AC_CHECK_FUNC(socket, , ok_so_far=no)
2996 if test $ok_so_far = yes; then
2997   AC_CHECK_HEADER(netinet/in.h, , ok_so_far=no)
2998 fi
2999 if test $ok_so_far = yes; then
3000   AC_CHECK_HEADER(arpa/inet.h, , ok_so_far=no)
3001 fi
3002 if test $ok_so_far = yes; then
3003 dnl Fixme: Not used.  Should this be HAVE_SOCKETS?
3004   AC_DEFINE(HAVE_INET_SOCKETS, 1,
3005             [Define to 1 if you have inet sockets.])
3006 fi
3007
3008 if test -f /usr/lpp/X11/bin/smt.exp; then
3009   AC_DEFINE(HAVE_AIX_SMT_EXP, 1,
3010             [Define to 1 if the file /usr/lpp/X11/bin/smt.exp exists.])
3011 fi
3012
3013 AC_MSG_CHECKING(whether system supports dynamic ptys)
3014 if test -d /dev/pts && ls -d /dev/ptmx > /dev/null 2>&1 ; then
3015   AC_MSG_RESULT(yes)
3016   AC_DEFINE(HAVE_DEV_PTMX, 1, [Define to 1 if dynamic ptys are supported.])
3017 else
3018   AC_MSG_RESULT(no)
3019 fi
3020
3021 AC_FUNC_FORK
3022
3023 AC_CHECK_FUNCS(snprintf)
3024
3025 dnl Adapted from Haible's version.
3026 AC_CACHE_CHECK([for nl_langinfo and CODESET], emacs_cv_langinfo_codeset,
3027   [AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <langinfo.h>]],
3028     [[char* cs = nl_langinfo(CODESET);]])],
3029     emacs_cv_langinfo_codeset=yes,
3030     emacs_cv_langinfo_codeset=no)
3031   ])
3032 if test $emacs_cv_langinfo_codeset = yes; then
3033   AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
3034     [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
3035 fi
3036
3037 AC_TYPE_MBSTATE_T
3038
3039 AC_CACHE_CHECK([for C restricted array declarations], emacs_cv_c_restrict_arr,
3040   [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[void fred (int x[__restrict]);]], [[]])],
3041                   emacs_cv_c_restrict_arr=yes, emacs_cv_c_restrict_arr=no)])
3042 if test "$emacs_cv_c_restrict_arr" = yes; then
3043   AC_DEFINE(__restrict_arr, __restrict,
3044     [Define to compiler's equivalent of C99 restrict keyword in array
3045      declarations.  Define as empty for no equivalent.])
3046 fi
3047
3048 dnl Fixme: AC_SYS_POSIX_TERMIOS should probably be used, but it's not clear
3049 dnl how the tty code is related to POSIX and/or other versions of termios.
3050 dnl The following looks like a useful start.
3051 dnl
3052 dnl AC_SYS_POSIX_TERMIOS
3053 dnl if test $ac_cv_sys_posix_termios = yes; then
3054 dnl    AC_DEFINE(HAVE_TERMIOS, 1, [Define to 1 if you have POSIX-style functions
3055 dnl                                and macros for terminal control.])
3056 dnl    AC_DEFINE(HAVE_TCATTR, 1, [Define to 1 if you have tcgetattr and tcsetattr.])
3057 dnl fi
3058
3059 case $opsys in
3060   darwin | gnu | hpux* | *bsd )
3061     AC_DEFINE(NO_TERMIO, 1, [Define if termio.h should not be included.])
3062   ;;
3063 esac
3064
3065 dnl SIGIO exists, but the feature doesn't work in the way Emacs needs.
3066 dnl See eg <http://article.gmane.org/gmane.os.openbsd.ports/46831>.
3067 case $opsys in
3068   hpux* | irix6-5 | openbsd | sol2* | unixware )
3069     AC_DEFINE(BROKEN_SIGIO, 1, [Define if SIGIO should not be used.])
3070   ;;
3071 esac
3072
3073 case $opsys in
3074   gnu-* | sol2-10 )
3075     dnl FIXME Can't we test if this exists (eg /proc/$$)?
3076     AC_DEFINE(HAVE_PROCFS, 1, [Define if you have the /proc filesystem.])
3077   ;;
3078 esac
3079
3080 case $opsys in
3081    gnu-kfreebsd) opsysfile="s/gnu-linux.h" ;;
3082
3083    hpux11)
3084      dnl SA_RESTART resets the timeout of `select', so don't use it.
3085      AC_DEFINE(BROKEN_SA_RESTART, 1, [Define if SA_RESTART should not
3086        be used.])
3087      dnl It works to open the pty's tty in the parent (Emacs), then
3088      dnl close and reopen it in the child.
3089      AC_DEFINE(USG_SUBTTY_WORKS, 1, [Define for USG systems where it
3090        works to open a pty's tty in the parent process, then close and
3091        reopen it in the child.])
3092
3093      opsysfile="s/hpux10-20.h"
3094    ;;
3095
3096    openbsd) opsysfile="s/netbsd.h" ;;
3097
3098    sol2-10)
3099      AC_DEFINE(_STRUCTURED_PROC, 1, [Needed for system_process_attributes
3100        on Solaris.])
3101      opsysfile="s/sol2-6.h"
3102    ;;
3103 esac
3104
3105 # Set up the CFLAGS for real compilation, so we can substitute it.
3106 CFLAGS="$REAL_CFLAGS"
3107 CPPFLAGS="$REAL_CPPFLAGS"
3108
3109 ## Hack to detect a buggy GCC version.
3110 if test "x$GCC" = xyes \
3111    && test x"`$CC --version 2> /dev/null | grep 'gcc.* 4.5.0'`" != x \
3112    && test x"`echo $CFLAGS | grep '\-O@<:@23@:>@'`" != x \
3113    && test x"`echo $CFLAGS | grep '\-fno-optimize-sibling-calls'`" = x; then
3114    AC_MSG_ERROR([GCC 4.5.0 has problems compiling Emacs; see etc/PROBLEMS'.])
3115 fi
3116
3117 version=$PACKAGE_VERSION
3118
3119 ### Specify what sort of things we'll be editing into Makefile and config.h.
3120 ### Use configuration here uncanonicalized to avoid exceeding size limits.
3121 AC_SUBST(version)
3122 AC_SUBST(configuration)
3123 ## Unused?
3124 AC_SUBST(canonical)
3125 AC_SUBST(srcdir)
3126 AC_SUBST(prefix)
3127 AC_SUBST(exec_prefix)
3128 AC_SUBST(bindir)
3129 AC_SUBST(datadir)
3130 AC_SUBST(sharedstatedir)
3131 AC_SUBST(libexecdir)
3132 AC_SUBST(mandir)
3133 AC_SUBST(infodir)
3134 AC_SUBST(lispdir)
3135 AC_SUBST(leimdir)
3136 AC_SUBST(locallisppath)
3137 AC_SUBST(lisppath)
3138 AC_SUBST(x_default_search_path)
3139 AC_SUBST(etcdir)
3140 AC_SUBST(archlibdir)
3141 AC_SUBST(docdir)
3142 AC_SUBST(bitmapdir)
3143 AC_SUBST(gamedir)
3144 AC_SUBST(gameuser)
3145 ## FIXME? Nothing uses @LD_SWITCH_X_SITE@.
3146 ## src/Makefile.in did add LD_SWITCH_X_SITE (as a cpp define) to the
3147 ## end of LIBX_BASE, but nothing ever set it.
3148 AC_SUBST(LD_SWITCH_X_SITE)
3149 AC_SUBST(C_SWITCH_X_SITE)
3150 AC_SUBST(GNUSTEP_CFLAGS)
3151 AC_SUBST(CFLAGS)
3152 ## Used in lwlib/Makefile.in.
3153 AC_SUBST(X_TOOLKIT_TYPE)
3154 if test -n "${opsysfile}"; then
3155   S_FILE="\$(srcdir)/${opsysfile}"
3156 else
3157   S_FILE=
3158 fi
3159 AC_SUBST(S_FILE)
3160 AC_SUBST(ns_appdir)
3161 AC_SUBST(ns_appbindir)
3162 AC_SUBST(ns_appresdir)
3163 AC_SUBST(ns_appsrc)
3164 AC_SUBST(GNU_OBJC_CFLAGS)
3165 AC_SUBST(OTHER_FILES)
3166
3167 AC_DEFINE_UNQUOTED(EMACS_CONFIGURATION,  "${canonical}",
3168                    [Define to the canonical Emacs configuration name.])
3169 AC_DEFINE_UNQUOTED(EMACS_CONFIG_OPTIONS, "${ac_configure_args}",
3170                    [Define to the options passed to configure.])
3171 if test -n "$opsysfile"; then
3172   AC_DEFINE_UNQUOTED(config_opsysfile, "${opsysfile}",
3173                      [Define to the used os dependent file.])
3174 fi
3175
3176 XMENU_OBJ=
3177 XOBJ=
3178 FONT_OBJ=
3179 if test "${HAVE_X_WINDOWS}" = "yes" ; then
3180   AC_DEFINE(HAVE_X_WINDOWS, 1,
3181             [Define to 1 if you want to use the X window system.])
3182   XMENU_OBJ=xmenu.o
3183   XOBJ="xterm.o xfns.o xselect.o xrdb.o fontset.o xsmfns.o fringe.o image.o xsettings.o xgselect.o"
3184   FONT_OBJ=xfont.o
3185   if test "$HAVE_XFT" = "yes"; then
3186     FONT_OBJ="$FONT_OBJ ftfont.o xftfont.o ftxfont.o"
3187   elif test "$HAVE_FREETYPE" = "yes"; then
3188     FONT_OBJ="$FONT_OBJ ftfont.o ftxfont.o"
3189   fi
3190   AC_SUBST(FONT_OBJ)
3191 fi
3192 AC_SUBST(XMENU_OBJ)
3193 AC_SUBST(XOBJ)
3194 AC_SUBST(FONT_OBJ)
3195
3196 WIDGET_OBJ=
3197 MOTIF_LIBW=
3198 if test "${USE_X_TOOLKIT}" != "none" ; then
3199   WIDGET_OBJ=widget.o
3200   AC_DEFINE(USE_X_TOOLKIT, 1, [Define to 1 if using an X toolkit.])
3201   if test "${USE_X_TOOLKIT}" = "LUCID"; then
3202     AC_DEFINE(USE_LUCID, 1, [Define to 1 if using the Lucid X toolkit.])
3203   elif test "${USE_X_TOOLKIT}" = "MOTIF"; then
3204     AC_DEFINE(USE_MOTIF, 1, [Define to 1 if using the Motif X toolkit.])
3205     MOTIF_LIBW=-lXm
3206     case "$opsys" in
3207       gnu-linux)
3208         ## Paul Abrahams <abrahams at equinox.shaysnet.com> says this is needed.
3209         MOTIF_LIBW="$MOTIF_LIBW -lXpm"
3210         ;;
3211
3212       unixware)
3213         ## Richard Anthony Ryan <ryanr at ellingtn.ftc.nrcs.usda.gov>
3214         ## says -lXimp is needed in UNIX_SV ... 4.2 1.1.2.
3215         MOTIF_LIBW="MOTIF_LIBW -lXimp"
3216         ;;
3217
3218       aix4-2)
3219         ## olson@mcs.anl.gov says -li18n is needed by -lXm.
3220         MOTIF_LIBW="$MOTIF_LIBW -li18n"
3221         ;;
3222     esac
3223     MOTIF_LIBW="$MOTIF_LIBW $LIBXP"
3224   fi
3225 fi
3226 AC_SUBST(WIDGET_OBJ)
3227
3228 TOOLKIT_LIBW=
3229 case "$USE_X_TOOLKIT" in
3230   MOTIF) TOOLKIT_LIBW="$MOTIF_LIBW" ;;
3231   LUCID) TOOLKIT_LIBW="$LUCID_LIBW" ;;
3232   none) test "x$HAVE_GTK" = "xyes" && TOOLKIT_LIBW="$GTK_LIBS" ;;
3233 esac
3234 AC_SUBST(TOOLKIT_LIBW)
3235
3236 if test "$USE_X_TOOLKIT" = "none"; then
3237   LIBXT_OTHER="\$(LIBXSM)"
3238   OLDXMENU_TARGET="really-oldXMenu"
3239 else
3240   LIBXT_OTHER="\$(LIBXMU) -lXt \$(LIBXTR6) -lXext"
3241   OLDXMENU_TARGET="really-lwlib"
3242 fi
3243 AC_SUBST(LIBXT_OTHER)
3244
3245 ## The X Menu stuff is present in the X10 distribution, but missing
3246 ## from X11.  If we have X10, just use the installed library;
3247 ## otherwise, use our own copy.
3248 if test "${HAVE_X11}" = "yes" ; then
3249   AC_DEFINE(HAVE_X11, 1,
3250             [Define to 1 if you want to use version 11 of X windows.
3251              Otherwise, Emacs expects to use version 10.])
3252
3253   if test "$USE_X_TOOLKIT" = "none"; then
3254     OLDXMENU="\${oldXMenudir}/libXMenu11.a"
3255   else
3256     OLDXMENU="\${lwlibdir}/liblw.a"
3257   fi
3258   LIBXMENU="\$(OLDXMENU)"
3259   LIBX_OTHER="\$(LIBXT) \$(LIBX_EXTRA)"
3260   OLDXMENU_DEPS="\${OLDXMENU} ../src/\${OLDXMENU}"
3261 else
3262   ## For a syntactically valid Makefile; not actually used for anything.
3263   ## See comments in src/Makefile.in.
3264   OLDXMENU=nothing
3265   ## FIXME This case (!HAVE_X11 && HAVE_X_WINDOWS) is no longer possible(?).
3266   if test "${HAVE_X_WINDOWS}" = "yes"; then
3267     LIBXMENU="-lXMenu"
3268   else
3269     LIBXMENU=
3270   fi
3271   LIBX_OTHER=
3272   OLDXMENU_DEPS=
3273 fi
3274
3275 if test "$HAVE_GTK" = "yes" || test "$HAVE_MENUS" != "yes"; then
3276   OLDXMENU_TARGET=
3277   OLDXMENU=nothing
3278   LIBXMENU=
3279   OLDXMENU_DEPS=
3280 fi
3281
3282 AC_SUBST(OLDXMENU_TARGET)
3283 AC_SUBST(OLDXMENU)
3284 AC_SUBST(LIBXMENU)
3285 AC_SUBST(LIBX_OTHER)
3286 AC_SUBST(OLDXMENU_DEPS)
3287
3288 if test "${HAVE_MENUS}" = "yes" ; then
3289   AC_DEFINE(HAVE_MENUS, 1,
3290             [Define to 1 if you have mouse menus.
3291              (This is automatic if you use X, but the option to specify it remains.)
3292              It is also defined with other window systems that support xmenu.c.])
3293 fi
3294
3295 if test "${GNU_MALLOC}" = "yes" ; then
3296   AC_DEFINE(GNU_MALLOC, 1,
3297             [Define to 1 if you want to use the GNU memory allocator.])
3298 fi
3299
3300 RALLOC_OBJ=
3301 if test "${REL_ALLOC}" = "yes" ; then
3302   AC_DEFINE(REL_ALLOC, 1,
3303             [Define REL_ALLOC if you want to use the relocating allocator for
3304              buffer space.])
3305
3306   test "$system_malloc" != "yes" && RALLOC_OBJ=ralloc.o
3307 fi
3308 AC_SUBST(RALLOC_OBJ)
3309
3310 if test "$opsys" = "cygwin"; then
3311   CYGWIN_OBJ="sheap.o"
3312   ## Cygwin differs because of its unexec().
3313   PRE_ALLOC_OBJ=
3314   POST_ALLOC_OBJ=lastfile.o
3315 else
3316   CYGWIN_OBJ=
3317   PRE_ALLOC_OBJ=lastfile.o
3318   POST_ALLOC_OBJ=
3319 fi
3320 AC_SUBST(CYGWIN_OBJ)
3321 AC_SUBST(PRE_ALLOC_OBJ)
3322 AC_SUBST(POST_ALLOC_OBJ)
3323
3324 case "$opsys" in
3325   aix4-2) LD_SWITCH_SYSTEM_TEMACS="-Wl,-bnodelcsect" ;;
3326
3327   darwin)
3328    ## The -headerpad option tells ld (see man page) to leave room at the
3329    ## end of the header for adding load commands.  Needed for dumping.
3330    ## 0x690 is the total size of 30 segment load commands (at 56
3331    ## each); under Cocoa 31 commands are required.
3332    if test "$HAVE_NS" = "yes"; then
3333      libs_nsgui="-framework AppKit"
3334      headerpad_extra=6C8
3335    else
3336      libs_nsgui=
3337      headerpad_extra=690
3338    fi
3339    LD_SWITCH_SYSTEM_TEMACS="-fno-pie -prebind $libs_nsgui -Xlinker -headerpad -Xlinker $headerpad_extra"
3340
3341    ## This is here because src/Makefile.in did some extra fiddling around
3342    ## with LD_SWITCH_SYSTEM.  The cpp logic was:
3343    ##   #ifndef LD_SWITCH_SYSTEM
3344    ##   #if !defined (__GNUC__) && ((defined (BSD_SYSTEM) && !defined (COFF)))
3345    ## Since all the *bsds define LD_SWITCH_SYSTEM, this simplifies to:
3346    ## not using gcc, darwin.
3347    ## Because this was done in src/Makefile.in, the resulting part of
3348    ## LD_SWITCH_SYSTEM was not used in configure (ie, in ac_link).
3349    ## It therefore seems cleaner to put this in LD_SWITCH_SYSTEM_TEMACS,
3350    ## rather than LD_SWITCH_SYSTEM.
3351    test "x$LD_SWITCH_SYSTEM" = "x" && test "x$GCC" != "xyes" && \
3352      LD_SWITCH_SYSTEM_TEMACS="-X $LD_SWITCH_SYSTEM_TEMACS"
3353    ;;
3354
3355   ## LD_SWITCH_X_SITE_RPATH is a -rpath option saying where to
3356   ## find X at run-time.
3357   ## When handled by cpp, this was in LD_SWITCH_SYSTEM.  However, at the
3358   ## point where configure sourced the s/*.h file, LD_SWITCH_X_SITE_RPATH
3359   ## had not yet been defined and was expanded to null.  Hence LD_SWITCH_SYSTEM
3360   ## had different values in configure (in ac_link) and src/Makefile.in.
3361   ## It seems clearer therefore to put this piece in LD_SWITCH_SYSTEM_TEMACS.
3362   gnu*) LD_SWITCH_SYSTEM_TEMACS="\$(LD_SWITCH_X_SITE_RPATH)" ;;
3363
3364   *) LD_SWITCH_SYSTEM_TEMACS= ;;
3365 esac
3366
3367 if test "$NS_IMPL_GNUSTEP" = "yes"; then
3368   LD_SWITCH_SYSTEM_TEMACS="${LD_SWITCH_SYSTEM_TEMACS} -L${GNUSTEP_SYSTEM_LIBRARIES} ${GNUSTEP_LOCAL_LIBRARIES} -lgnustep-gui -lgnustep-base -lobjc -lpthread"
3369 fi
3370
3371 AC_SUBST(LD_SWITCH_SYSTEM_TEMACS)
3372
3373
3374 LD_FIRSTFLAG=
3375 ORDINARY_LINK=
3376 case "$opsys" in
3377   ## gnu: GNU needs its own crt0.
3378   aix4-2|cygwin|darwin|gnu|hpux*|irix6-5|sol2*|unixware) ORDINARY_LINK=yes ;;
3379
3380   ## On post 1.3 releases of NetBSD, gcc -nostdlib also clears the
3381   ## library search parth, i.e. it won't search /usr/lib for libc and
3382   ## friends.  Using -nostartfiles instead avoids this problem, and
3383   ## will also work on earlier NetBSD releases.
3384   netbsd|openbsd) LD_FIRSTFLAG="-nostartfiles" ;;
3385
3386   ## powerpc*: NAKAJI Hiroyuki <nakaji@tutrp.tut.ac.jp> says
3387   ##   MkLinux/LinuxPPC needs this.
3388   ## s390x-* only supports opsys = gnu-linux so it can be added here.
3389   gnu-*)
3390     case "$canonical" in
3391       powerpc*|s390x-*) LD_FIRSTFLAG="-nostdlib" ;;
3392     esac
3393     ;;
3394 esac
3395
3396
3397 if test "x$ORDINARY_LINK" = "xyes"; then
3398
3399   LD_FIRSTFLAG=""
3400   AC_DEFINE(ORDINARY_LINK, 1, [Define if the C compiler is the linker.])
3401
3402 ## The system files defining neither ORDINARY_LINK nor LD_FIRSTFLAG are:
3403 ## freebsd, gnu-* not on powerpc*|s390x*.
3404 elif test "x$GCC" = "xyes" && test "x$LD_FIRSTFLAG" = "x"; then
3405
3406   ## Versions of GCC >= 2.0 put their library, libgcc.a, in obscure
3407   ## places that are difficult to figure out at make time.  Fortunately,
3408   ## these same versions allow you to pass arbitrary flags on to the
3409   ## linker, so there is no reason not to use it as a linker.
3410   ##
3411   ## Well, it is not quite perfect.  The "-nostdlib" keeps GCC from
3412   ## searching for libraries in its internal directories, so we have to
3413   ## ask GCC explicitly where to find libgcc.a (LIB_GCC below).
3414   LD_FIRSTFLAG="-nostdlib"
3415 fi
3416
3417 ## FIXME? What setting of EDIT_LDFLAGS should this have?
3418 test "$NS_IMPL_GNUSTEP" = "yes" && LD_FIRSTFLAG="-rdynamic"
3419
3420 AC_SUBST(LD_FIRSTFLAG)
3421
3422
3423 ## FIXME? The logic here is not precisely the same as that above.
3424 ## There is no check here for a pre-defined LD_FIRSTFLAG.
3425 ## Should we only be setting LIB_GCC if LD ~ -nostdlib?
3426 LIB_GCC=
3427 if test "x$GCC" = "xyes" && test "x$ORDINARY_LINK" != "xyes"; then
3428
3429   case "$opsys" in
3430     freebsd|netbsd|openbsd) LIB_GCC= ;;
3431
3432     gnu-*)
3433       ## armin76@gentoo.org reported that the lgcc_s flag is necessary to
3434       ## build on ARM EABI under GNU/Linux.  (Bug#5518)
3435       case $host_cpu in
3436       arm*)
3437         LIB_GCC="-lgcc_s"
3438         ;;
3439       *)
3440         ## FIXME? s/gnu-linux.h used to define LIB_GCC as below, then
3441         ## immediately undefine it again and redefine it to empty.
3442         ## Was the C_SWITCH_X_SITE part really necessary?
3443 ##      LIB_GCC=`$CC $C_SWITCH_X_SITE -print-libgcc-file-name`
3444         LIB_GCC=
3445         ;;
3446       esac
3447       ;;
3448
3449     ## Ask GCC where to find libgcc.a.
3450     *) LIB_GCC=`$CC -print-libgcc-file-name 2> /dev/null` ;;
3451   esac
3452 fi                              dnl if $GCC
3453 AC_SUBST(LIB_GCC)
3454
3455
3456 ## If we're using X11/GNUstep, define some consequences.
3457 if test "$HAVE_X_WINDOWS" = "yes" || test "$HAVE_NS" = "yes"; then
3458   AC_DEFINE(HAVE_WINDOW_SYSTEM, 1, [Define if you have a window system.])
3459   AC_DEFINE(HAVE_MOUSE, 1, [Define if you have mouse support.])
3460 fi
3461
3462
3463 AH_TOP([/* GNU Emacs site configuration template file.
3464
3465 Copyright (C) 1988, 1993-1994, 1999-2002, 2004-2012
3466   Free Software Foundation, Inc.
3467
3468 This file is part of GNU Emacs.
3469
3470 GNU Emacs is free software: you can redistribute it and/or modify
3471 it under the terms of the GNU General Public License as published by
3472 the Free Software Foundation, either version 3 of the License, or
3473 (at your option) any later version.
3474
3475 GNU Emacs is distributed in the hope that it will be useful,
3476 but WITHOUT ANY WARRANTY; without even the implied warranty of
3477 MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
3478 GNU General Public License for more details.
3479
3480 You should have received a copy of the GNU General Public License
3481 along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.  */
3482
3483
3484 /* No code in Emacs #includes config.h twice, but some bits of code
3485    intended to work with other packages as well (like gmalloc.c)
3486    think they can include it as many times as they like.  */
3487 #ifndef EMACS_CONFIG_H
3488 #define EMACS_CONFIG_H
3489 ])dnl
3490
3491 AH_BOTTOM([
3492 /* On AIX 3 this must be included before any other include file.  */
3493 #include <alloca.h>
3494 #if ! HAVE_ALLOCA
3495 # error "alloca not available on this machine"
3496 #endif
3497
3498 /* Define AMPERSAND_FULL_NAME if you use the convention
3499    that & in the full name stands for the login id.  */
3500 /* Turned on June 1996 supposing nobody will mind it.  */
3501 #define AMPERSAND_FULL_NAME
3502
3503 /* `subprocesses' should be defined if you want to
3504    have code for asynchronous subprocesses
3505    (as used in M-x compile and M-x shell).
3506    Only MSDOS does not support this (it overrides
3507    this in its config_opsysfile below).  */
3508
3509 #define subprocesses
3510
3511 /* Include the os dependent file.  */
3512 #ifdef config_opsysfile
3513 # include config_opsysfile
3514 #endif
3515
3516 /* GNUstep needs a bit more pure memory.  Of the existing knobs,
3517    SYSTEM_PURESIZE_EXTRA seems like the least likely to cause problems.
3518   (There is probably a better place to do this, but right now the
3519    Cocoa side does this in s/darwin.h and we cannot parallel this
3520    exactly since GNUstep is multi-OS.  */
3521 #if defined HAVE_NS && defined NS_IMPL_GNUSTEP
3522 #  define SYSTEM_PURESIZE_EXTRA 30000
3523 #endif
3524
3525 #ifdef emacs /* Don't do this for lib-src.  */
3526 /* Tell regex.c to use a type compatible with Emacs.  */
3527 #define RE_TRANSLATE_TYPE Lisp_Object
3528 #define RE_TRANSLATE(TBL, C) CHAR_TABLE_TRANSLATE (TBL, C)
3529 #ifdef make_number
3530 /* If make_number is a macro, use it.  */
3531 #define RE_TRANSLATE_P(TBL) (!EQ (TBL, make_number (0)))
3532 #else
3533 /* If make_number is a function, avoid it.  */
3534 #define RE_TRANSLATE_P(TBL) (!(INTEGERP (TBL) && XINT (TBL) == 0))
3535 #endif
3536 #endif
3537
3538 #include <string.h>
3539 #include <stdlib.h>
3540
3541 #if __GNUC__ >= 3  /* On GCC 3.0 we might get a warning.  */
3542 #define NO_INLINE __attribute__((noinline))
3543 #else
3544 #define NO_INLINE
3545 #endif
3546
3547 #if (__GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 1))
3548 #define EXTERNALLY_VISIBLE __attribute__((externally_visible))
3549 #else
3550 #define EXTERNALLY_VISIBLE
3551 #endif
3552
3553 #if __GNUC__ > 2 || (__GNUC__ == 2 && __GNUC_MINOR__ >= 7)
3554 # define ATTRIBUTE_FORMAT(spec) __attribute__ ((__format__ spec))
3555 #else
3556 # define ATTRIBUTE_FORMAT(spec) /* empty */
3557 #endif
3558
3559 #if __GNUC__ > 4 || (__GNUC__ == 4 && __GNUC_MINOR__ >= 4)
3560 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3561    ATTRIBUTE_FORMAT ((__gnu_printf__, formatstring_parameter, first_argument))
3562 #else
3563 # define ATTRIBUTE_FORMAT_PRINTF(formatstring_parameter, first_argument) \
3564    ATTRIBUTE_FORMAT ((__printf__, formatstring_parameter, first_argument))
3565 #endif
3566
3567 /* Some versions of GNU/Linux define noinline in their headers.  */
3568 #ifdef noinline
3569 #undef noinline
3570 #endif
3571
3572 /* These won't be used automatically yet.  We also need to know, at least,
3573    that the stack is continuous.  */
3574 #ifdef __GNUC__
3575 #  ifndef GC_SETJMP_WORKS
3576   /* GC_SETJMP_WORKS is nearly always appropriate for GCC.  */
3577 #    define GC_SETJMP_WORKS 1
3578 #  endif
3579 #endif
3580
3581 #endif /* EMACS_CONFIG_H */
3582
3583 /*
3584 Local Variables:
3585 mode: c
3586 End:
3587 */
3588 ])dnl
3589
3590 #### Report on what we decided to do.
3591 #### Report GTK as a toolkit, even if it doesn't use Xt.
3592 #### It makes printing result more understandable as using GTK sets
3593 #### toolkit_scroll_bars to yes by default.
3594 if test "${HAVE_GTK}" = "yes"; then
3595   USE_X_TOOLKIT=GTK
3596 fi
3597
3598 echo "
3599 Configured for \`${canonical}'.
3600
3601   Where should the build process find the source code?    ${srcdir}
3602   What operating system file should Emacs use?            ${opsysfile-none}
3603   What compiler should emacs be built with?               ${CC} ${CFLAGS}
3604   Should Emacs use the GNU version of malloc?             ${GNU_MALLOC}${GNU_MALLOC_reason}
3605   Should Emacs use a relocating allocator for buffers?    ${REL_ALLOC}
3606   Should Emacs use mmap(2) for buffer allocation?         $use_mmap_for_buffers
3607   What window system should Emacs use?                    ${window_system}
3608   What toolkit should Emacs use?                          ${USE_X_TOOLKIT}"
3609
3610 if test -n "${x_includes}"; then
3611 echo "  Where do we find X Windows header files?                ${x_includes}"
3612 else
3613 echo "  Where do we find X Windows header files?                Standard dirs"
3614 fi
3615 if test -n "${x_libraries}"; then
3616 echo "  Where do we find X Windows libraries?                   ${x_libraries}"
3617 else
3618 echo "  Where do we find X Windows libraries?                   Standard dirs"
3619 fi
3620
3621 echo "  Does Emacs use -lXaw3d?                                 ${HAVE_XAW3D}"
3622 echo "  Does Emacs use -lXpm?                                   ${HAVE_XPM}"
3623 echo "  Does Emacs use -ljpeg?                                  ${HAVE_JPEG}"
3624 echo "  Does Emacs use -ltiff?                                  ${HAVE_TIFF}"
3625 echo "  Does Emacs use a gif library?                           ${HAVE_GIF} $LIBGIF"
3626 echo "  Does Emacs use -lpng?                                   ${HAVE_PNG}"
3627 echo "  Does Emacs use -lrsvg-2?                                ${HAVE_RSVG}"
3628 echo "  Does Emacs use imagemagick?                             ${HAVE_IMAGEMAGICK}"
3629
3630 echo "  Does Emacs use -lgpm?                                   ${HAVE_GPM}"
3631 echo "  Does Emacs use -ldbus?                                  ${HAVE_DBUS}"
3632 echo "  Does Emacs use -lgconf?                                 ${HAVE_GCONF}"
3633 echo "  Does Emacs use GSettings?                               ${HAVE_GSETTINGS}"
3634 echo "  Does Emacs use -lselinux?                               ${HAVE_LIBSELINUX}"
3635 echo "  Does Emacs use -lgnutls?                                ${HAVE_GNUTLS}"
3636 echo "  Does Emacs use -lxml2?                                  ${HAVE_LIBXML2}"
3637
3638 echo "  Does Emacs use -lfreetype?                              ${HAVE_FREETYPE}"
3639 echo "  Does Emacs use -lm17n-flt?                              ${HAVE_M17N_FLT}"
3640 echo "  Does Emacs use -lotf?                                   ${HAVE_LIBOTF}"
3641 echo "  Does Emacs use -lxft?                                   ${HAVE_XFT}"
3642
3643 echo "  Does Emacs use toolkit scroll bars?                     ${USE_TOOLKIT_SCROLL_BARS}"
3644 echo
3645
3646 if test -n "${EMACSDATA}"; then
3647    echo "  Environment variable EMACSDATA set to:                  $EMACSDATA"
3648 fi
3649 if test -n "${EMACSDOC}"; then
3650    echo "  Environment variable EMACSDOC set to:                   $EMACSDOC"
3651 fi
3652
3653 if test $USE_XASSERTS = yes; then
3654    echo "  Compiling with asserts turned on."
3655    CPPFLAGS="$CPPFLAGS -DXASSERTS=1"
3656 fi
3657
3658 echo
3659
3660 if test "$HAVE_NS" = "yes"; then
3661    echo
3662    echo "You must run \"${MAKE-make} install\" in order to test the built application.
3663 The installed application will go to nextstep/Emacs.app and can be
3664 run or moved from there."
3665    if test "$EN_NS_SELF_CONTAINED" = "yes"; then
3666       echo "The application will be fully self-contained."
3667     else
3668       echo "The lisp resources for the application will be installed under ${prefix}.
3669 You may need to run \"${MAKE-make} install\" with sudo.  The application will fail
3670 to run if these resources are not installed."
3671    fi
3672    echo
3673 fi
3674
3675 if test "${opsys}" = "cygwin"; then
3676   case `uname -r` in
3677     1.5.*) AC_MSG_WARN([[building Emacs on Cygwin 1.5 is not supported.]])
3678            echo
3679            ;;
3680   esac
3681 fi
3682
3683 # Remove any trailing slashes in these variables.
3684 [test "${prefix}" != NONE &&
3685   prefix=`echo "${prefix}" | sed 's,\([^/]\)/*$,\1,'`
3686 test "${exec_prefix}" != NONE &&
3687   exec_prefix=`echo "${exec_prefix}" | sed 's,\([^/]\)/*$,\1,'`]
3688
3689 dnl Obviously there is duplication here wrt $SUBDIR_MAKEFILES.
3690 dnl You _can_ use that variable in AC_CONFIG_FILES, so long as any directory
3691 dnl using automake (ie lib/) is explicitly listed and not "hidden" in a variable
3692 dnl (else you get "no `Makefile.am' found for any configure output").
3693 dnl This will work, but you get a config.status that is not quite right
3694 dnl (see http://lists.gnu.org/archive/html/bug-autoconf/2008-08/msg00028.html).
3695 dnl That doesn't have any obvious consequences for Emacs, but on the whole
3696 dnl it seems better to just live with the duplication.
3697 SUBDIR_MAKEFILES="lib/Makefile lib-src/Makefile oldXMenu/Makefile doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile leim/Makefile"
3698
3699 AC_CONFIG_FILES([Makefile lib/Makefile lib-src/Makefile oldXMenu/Makefile \
3700        doc/emacs/Makefile doc/misc/Makefile doc/lispintro/Makefile \
3701        doc/lispref/Makefile src/Makefile lwlib/Makefile lisp/Makefile \
3702        leim/Makefile])
3703
3704 dnl test/ is not present in release tarfiles.
3705 opt_makefile=test/automated/Makefile
3706
3707 if test -f $srcdir/${opt_makefile}.in; then
3708   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3709   dnl Again, it's best not to use a variable.  Though you can add
3710   dnl ", [], [opt_makefile='$opt_makefile']" and it should work.
3711   AC_CONFIG_FILES([test/automated/Makefile])
3712 fi
3713
3714
3715 dnl admin/ may or may not be present.
3716 opt_makefile=admin/unidata/Makefile
3717
3718 if test -f $srcdir/${opt_makefile}.in; then
3719   SUBDIR_MAKEFILES="$SUBDIR_MAKEFILES $opt_makefile"
3720   AC_CONFIG_FILES([admin/unidata/Makefile])
3721 fi
3722
3723
3724 SUBDIR_MAKEFILES_IN=`echo " ${SUBDIR_MAKEFILES}" | sed -e 's| | $(srcdir)/|g' -e 's|Makefile|Makefile.in|g'`
3725
3726 AC_SUBST(SUBDIR_MAKEFILES_IN)
3727
3728 dnl Make the necessary directories, if they don't exist.
3729 AC_CONFIG_COMMANDS([mkdirs], [
3730 for dir in etc lisp ; do
3731   test -d ${dir} || mkdir ${dir}
3732 done
3733 ])
3734
3735 dnl You might wonder (I did) why epaths.h is generated by running make,
3736 dnl rather than just letting configure generate it from epaths.in.
3737 dnl One reason is that the various paths are not fully expanded (see above);
3738 dnl eg gamedir=${prefix}/var/games/emacs.
3739 dnl Secondly, the GNU Coding standards require that one should be able
3740 dnl to run `make prefix=/some/where/else' and override the values set
3741 dnl by configure.  This also explains the `move-if-change' test and
3742 dnl the use of force in the `epaths-force' rule in Makefile.in.
3743 AC_CONFIG_COMMANDS([epaths], [
3744 echo creating src/epaths.h
3745 ${MAKE-make} epaths-force
3746 ], [GCC="$GCC" CPPFLAGS="$CPPFLAGS"])
3747
3748 AC_CONFIG_COMMANDS([gdbinit], [
3749 if test ! -f src/.gdbinit && test -f $srcdir/src/.gdbinit; then
3750   echo creating src/.gdbinit
3751   echo source $srcdir/src/.gdbinit > src/.gdbinit
3752 fi
3753 ])
3754
3755 AC_OUTPUT
3756
3757 dnl configure.in ends here