configure.in

   1
   2 dnl /**-------------------------------------------------------------------**
   3 dnl  **                              CLooG                                **
   4 dnl  **-------------------------------------------------------------------**
   5 dnl  **                           configure.in                            **
   6 dnl  **-------------------------------------------------------------------**
   7 dnl  **                   First version: august 7th 2002                  **
   8 dnl  **-------------------------------------------------------------------**/
   9 dnl
  10 dnl Input file for autoconf to build a configuration shellscript.
  11 dnl To build the configure script from the CLooG's top-level directory, use
  12 dnl autoconf -l autoconf autoconf/configure.in > configure
  13 dnl if it doesn't work (invalid option -l) try -I instead
  14 dnl autoconf -I autoconf autoconf/configure.in > configure
  15
  16 dnl /**************************************************************************
  17 dnl *               CLooG : the Chunky Loop Generator (experimental)          *
  18 dnl ***************************************************************************
  19 dnl *                                                                         *
  20 dnl * Copyright (C) 2001 Cedric Bastoul                                       *
  21 dnl *                                                                         *
  22 dnl * This library is free software; you can redistribute it and/or           *
  23 dnl * modify it under the terms of the GNU Lesser General Public              *
  24 dnl * License as published by the Free Software Foundation; either            *
  25 dnl * version 2.1 of the License, or (at your option) any later version.      *
  26 dnl *                                                                         *
  27 dnl * This library is distributed in the hope that it will be useful,         *
  28 dnl * but WITHOUT ANY WARRANTY; without even the implied warranty of          *
  29 dnl * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU       *
  30 dnl * Lesser General Public License for more details.                         *
  31 dnl *                                                                         *
  32 dnl * You should have received a copy of the GNU Lesser General Public        *
  33 dnl * License along with this library; if not, write to the Free Software     *
  34 dnl * Foundation, Inc., 51 Franklin Street, Fifth Floor,                      *
  35 dnl * Boston, MA  02110-1301  USA                                             *
  36 dnl *                                                                         *
  37 dnl * CLooG, the Chunky Loop Generator                                        *
  38 dnl * Written by Cedric Bastoul, Cedric.Bastoul@inria.fr                      *
  39 dnl *                                                                         *
  40 dnl ***************************************************************************/
  41
  42 AC_PREREQ(2.13)
  43 AC_INIT(source/cloog.c)
  44 AC_CONFIG_AUX_DIR(autoconf)
  45 AC_CONFIG_MACRO_DIR([m4])
  46
  47 VERSION_MAJOR=0
  48 VERSION_MINOR=16
  49 VERSION_REVISION=2
  50 AC_SUBST(versioninfo)
  51 versioninfo=1:2:0
  52
  53 AM_INIT_AUTOMAKE(cloog, "${VERSION_MAJOR}.${VERSION_MINOR}.${VERSION_REVISION}")
  54
  55 dnl /**************************************************************************
  56 dnl  *                              Checking                                  *
  57 dnl  **************************************************************************/
  58
  59 dnl Checks for programs.
  60 AC_PROG_CC
  61 AC_PROG_LN_S
  62 AC_PROG_MAKE_SET
  63 AC_CHECK_PROG(CD, cd)
  64 dnl Configure needs an empty install.sh file with this, i HATE that...
  65 AC_PROG_INSTALL
  66 AC_PROG_LIBTOOL
  67 AC_CHECK_PROG(TEXI2DVI, texi2dvi, texi2dvi, [])
  68 AM_CONDITIONAL(HAVE_TEXI2DVI, test -n "$TEXI2DVI")
  69
  70 AX_CC_MAXOPT
  71 AC_SUBST(CFLAGS_WARN)
  72 AX_CFLAGS_WARN_ALL(CFLAGS_WARN)
  73
  74 dnl Checks for typedefs, structures, and compiler characteristics.
  75 AC_C_CONST
  76 AC_TYPE_SIZE_T
  77
  78
  79
  80 dnl Checks for header files.
  81 AC_HEADER_STDC
  82
  83
  84 dnl Checks for library functions.
  85 AC_CHECK_FUNCS(strtol)
  86
  87
  88 dnl /**************************************************************************
  89 dnl  *                             Option setting                             *
  90 dnl  **************************************************************************/
  91
  92 AC_CHECK_HEADERS([sys/resource.h],
  93         [AC_DEFINE([CLOOG_RUSAGE], [], [Print time required to generate code])])
  94
  95 AX_SUBMODULE(isl,no|system|build|bundled,bundled)
  96 BITS="gmp"
  97
  98 dnl /**************************************************************************
  99 dnl  *                            Where is GMP?                               *
 100 dnl  **************************************************************************/
 101
 102 AX_SUBMODULE(gmp,system,system)
 103
 104 need_get_memory_functions=false
 105 case "$with_gmp" in
 106 system)
 107     if test "x$with_gmp_prefix" != "x"; then
 108         CPPFLAGS="-I$with_gmp_prefix/include $CPPFLAGS"
 109     fi
 110
 111     if test "$with_gmp_exec_prefix" != "yes" ; then
 112         LDFLAGS="-L$with_gmp_exec_prefix/lib $LDFLAGS"
 113     fi
 114
 115     AC_CHECK_HEADER(gmp.h,
 116                     [],
 117                     [AC_MSG_ERROR(Can't find gmp headers.)])
 118     AC_CHECK_LIB(gmp,
 119                  __gmpz_init,
 120                  [LIBS="$LIBS -lgmp"],
 121                  [AC_MSG_ERROR(Can't find gmp library.)])
 122     AC_CHECK_DECLS(mp_get_memory_functions,[],[
 123             need_get_memory_functions=true
 124     ],[#include <gmp.h>])
 125     ;;
 126 esac
 127 AM_CONDITIONAL(NEED_GET_MEMORY_FUNCTIONS,
 128                 test x$need_get_memory_functions = xtrue)
 129
 130 dnl /**************************************************************************
 131 dnl  *                          Where is isl?                                 *
 132 dnl  **************************************************************************/
 133
 134 AC_SUBST(ISL_CPPFLAGS)
 135 AC_SUBST(ISL_LDFLAGS)
 136 AC_SUBST(ISL_LIBS)
 137 case "$with_isl" in
 138 bundled)
 139         ISL_CPPFLAGS="-I$srcdir/isl/include -Iisl/include"
 140         ;;
 141 build)
 142         ISL_CPPFLAGS="-I$isl_srcdir/include -I$with_isl_builddir/include"
 143         ISL_LIBS="$with_isl_builddir/libisl.la"
 144         ;;
 145 system)
 146         if test "x$with_isl_prefix" != "x"; then
 147                 ISL_CPPFLAGS="-I$with_isl_prefix/include"
 148         fi
 149         if test "x$with_isl_exec_prefix" != "x"; then
 150                 ISL_LDFLAGS="-L$with_isl_exec_prefix/lib"
 151         fi
 152         ISL_LIBS="-lisl"
 153 esac
 154 AM_CONDITIONAL(BUNDLED_ISL, test $with_isl = bundled)
 155 AM_CONDITIONAL(NO_ISL, test $with_isl = no)
 156
 157
 158 AC_DEFINE([CLOOG_INT_GMP], 1, [Use arbitrary precision integers])
 159
 160 AC_SUBST(GIT_INDEX)
 161 if test -f $srcdir/.git/HEAD; then
 162         GIT_INDEX="\$(top_srcdir)/.git/index"
 163 fi
 164
 165
 166 dnl /**************************************************************************
 167 dnl  *                            Substitutions                               *
 168 dnl  **************************************************************************/
 169
 170
 171 dnl Substitutions to do in Makefile.in.
 172 AC_SUBST(CC)
 173 AC_SUBST(LN_S)
 174
 175 AC_SUBST(prefix)
 176 AC_SUBST(exec_prefix)
 177 AC_SUBST(INSTALL)
 178
 179 AC_SUBST(BITS)
 180
 181 AC_SUBST(VERSION_MAJOR)
 182 AC_SUBST(VERSION_MINOR)
 183 AC_SUBST(VERSION_REVISION)
 184
 185 PACKAGE_NAME="cloog-isl"
 186 PACKAGE_CFLAGS="-DCLOOG_INT_GMP=1"
 187 AX_CREATE_PKGCONFIG_INFO
 188
 189 AC_CONFIG_FILES(Makefile test/Makefile)
 190 AC_CONFIG_FILES(autoconf/Doxyfile)
 191 AC_CONFIG_FILES(doc/Makefile)
 192 AC_CONFIG_FILES(source/version.c)
 193 AC_CONFIG_FILES(include/cloog/version.h)
 194 AC_CONFIG_FILES([genversion.sh], [chmod +x genversion.sh])
 195 AC_CONFIG_COMMANDS([version.h],
 196         [echo '#define CLOOG_HEAD "'`./genversion.sh`'"' > version.h])
 197 AC_CONFIG_COMMANDS([doc/gitversion.texi],
 198         [echo '@set VERSION '`./genversion.sh`'' > doc/gitversion.texi])
 199 if test $with_isl = bundled; then
 200         AC_CONFIG_SUBDIRS(isl)
 201 fi
 202 AC_CONFIG_COMMANDS_POST([
 203         ac_configure_args="$ac_configure_args $cloog_configure_args"
 204 ])
 205 AC_OUTPUT
 206
 207
 208 echo "             /*-----------------------------------------------*"
 209 echo "              *           CLooG configuration is OK           *"
 210 echo "              *-----------------------------------------------*/"
 211 echo "It appears that your system is OK to start CLooG compilation. You need"
 212 echo "now to type \"make\". After compilation, you should check CLooG by typing"
 213 echo "\"make check\". If no problem occur, you can type \"make uninstall\" if"
 214 echo "you are upgrading an old version. Lastly type \"make install\" to install"
 215 echo "CLooG on your system (log as root if necessary)."