ui/gfx/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/ui.gni")
   6 import("//testing/test.gni")
   7
   8 if (is_android) {
   9   import("//build/config/android/config.gni")
  10   import("//build/config/android/rules.gni")
  11 }
  12
  13 # Several targets want to include this header file, and some of them are
  14 # child dependencies of "gfx". Therefore, we separate it out here so multiple
  15 # targets can all have a dependency for header checking purposes without
  16 # creating circular dependencies.
  17 source_set("gfx_export") {
  18   sources = [
  19     "gfx_export.h",
  20   ]
  21 }
  22
  23 component("gfx") {
  24   sources = [
  25     "android/device_display_info.cc",
  26     "android/device_display_info.h",
  27     "android/gfx_jni_registrar.cc",
  28     "android/gfx_jni_registrar.h",
  29     "android/java_bitmap.cc",
  30     "android/java_bitmap.h",
  31     "android/shared_device_display_info.cc",
  32     "android/shared_device_display_info.h",
  33     "android/view_configuration.cc",
  34     "android/view_configuration.h",
  35     "animation/animation.cc",
  36     "animation/animation.h",
  37     "animation/animation_container.cc",
  38     "animation/animation_container.h",
  39     "animation/animation_container_element.h",
  40     "animation/animation_container_observer.h",
  41     "animation/animation_delegate.h",
  42     "animation/linear_animation.cc",
  43     "animation/linear_animation.h",
  44     "animation/multi_animation.cc",
  45     "animation/multi_animation.h",
  46     "animation/slide_animation.cc",
  47     "animation/slide_animation.h",
  48     "animation/throb_animation.cc",
  49     "animation/throb_animation.h",
  50     "animation/tween.cc",
  51     "animation/tween.h",
  52     "blit.cc",
  53     "blit.h",
  54     "break_list.h",
  55     "canvas.cc",
  56     "canvas.h",
  57     "canvas_notimplemented.cc",
  58     "canvas_paint_mac.h",
  59     "canvas_paint_mac.mm",
  60     "canvas_paint_win.cc",
  61     "canvas_paint_win.h",
  62     "canvas_skia.cc",
  63     "canvas_skia_paint.h",
  64     "codec/jpeg_codec.cc",
  65     "codec/jpeg_codec.h",
  66     "codec/png_codec.cc",
  67     "codec/png_codec.h",
  68     "color_analysis.cc",
  69     "color_analysis.h",
  70     "color_profile.cc",
  71     "color_profile.h",
  72     "color_profile_mac.mm",
  73     "color_profile_win.cc",
  74     "color_utils.cc",
  75     "color_utils.h",
  76     "display.cc",
  77     "display.h",
  78     "display_change_notifier.cc",
  79     "display_change_notifier.h",
  80     "display_observer.cc",
  81     "display_observer.h",
  82     "favicon_size.cc",
  83     "favicon_size.h",
  84     "font.cc",
  85     "font.h",
  86     "font_fallback.h",
  87     "font_fallback_linux.cc",
  88     "font_fallback_mac.cc",
  89     "font_fallback_win.cc",
  90     "font_fallback_win.h",
  91     "font_list.cc",
  92     "font_list.h",
  93     "font_list_impl.cc",
  94     "font_list_impl.h",
  95     "font_render_params.cc",
  96     "font_render_params.h",
  97     "font_render_params_android.cc",
  98     "font_render_params_linux.cc",
  99     "font_render_params_mac.cc",
 100     "font_render_params_win.cc",
 101     "frame_time.h",
 102     "gdi_util.cc",
 103     "gdi_util.h",
 104     "gfx_paths.cc",
 105     "gfx_paths.h",
 106     "gpu_memory_buffer.cc",
 107     "gpu_memory_buffer.h",
 108     "icon_util.cc",
 109     "icon_util.h",
 110     "image/canvas_image_source.cc",
 111     "image/canvas_image_source.h",
 112     "image/image.cc",
 113     "image/image.h",
 114     "image/image_family.cc",
 115     "image/image_family.h",
 116     "image/image_ios.mm",
 117     "image/image_mac.mm",
 118     "image/image_png_rep.cc",
 119     "image/image_png_rep.h",
 120     "image/image_skia.cc",
 121     "image/image_skia.h",
 122     "image/image_skia_operations.cc",
 123     "image/image_skia_operations.h",
 124     "image/image_skia_rep.cc",
 125     "image/image_skia_rep.h",
 126     "image/image_skia_source.h",
 127     "image/image_skia_util_ios.h",
 128     "image/image_skia_util_ios.mm",
 129     "image/image_skia_util_mac.h",
 130     "image/image_skia_util_mac.mm",
 131     "image/image_util.cc",
 132     "image/image_util.h",
 133     "image/image_util_ios.mm",
 134     "interpolated_transform.cc",
 135     "interpolated_transform.h",
 136     "linux_font_delegate.cc",
 137     "linux_font_delegate.h",
 138     "mac/coordinate_conversion.h",
 139     "mac/coordinate_conversion.mm",
 140     "mac/scoped_ns_disable_screen_updates.h",
 141     "native_widget_types.h",
 142     "nine_image_painter.cc",
 143     "nine_image_painter.h",
 144     "path.cc",
 145     "path.h",
 146     "path_aura.cc",
 147     "path_win.cc",
 148     "path_win.h",
 149     "path_x11.cc",
 150     "path_x11.h",
 151     "platform_font.h",
 152     "platform_font_android.cc",
 153     "platform_font_ios.h",
 154     "platform_font_ios.mm",
 155     "platform_font_mac.h",
 156     "platform_font_mac.mm",
 157     "platform_font_win.cc",
 158     "platform_font_win.h",
 159     "range/range.cc",
 160     "range/range.h",
 161     "range/range_mac.mm",
 162     "range/range_win.cc",
 163     "scoped_canvas.h",
 164     "scoped_cg_context_save_gstate_mac.h",
 165     "scoped_ns_graphics_context_save_gstate_mac.h",
 166     "scoped_ns_graphics_context_save_gstate_mac.mm",
 167     "scoped_ui_graphics_push_context_ios.h",
 168     "scoped_ui_graphics_push_context_ios.mm",
 169     "screen.cc",
 170     "screen.h",
 171     "screen_android.cc",
 172     "screen_aura.cc",
 173     "screen_ios.mm",
 174     "screen_mac.mm",
 175     "screen_win.cc",
 176     "screen_win.h",
 177     "scrollbar_size.cc",
 178     "scrollbar_size.h",
 179     "selection_model.cc",
 180     "selection_model.h",
 181     "sequential_id_generator.cc",
 182     "sequential_id_generator.h",
 183     "shadow_value.cc",
 184     "shadow_value.h",
 185     "skbitmap_operations.cc",
 186     "skbitmap_operations.h",
 187     "skia_util.cc",
 188     "skia_util.h",
 189     "switches.cc",
 190     "switches.h",
 191     "sys_color_change_listener.cc",
 192     "sys_color_change_listener.h",
 193     "text_constants.h",
 194     "text_elider.cc",
 195     "text_elider.h",
 196     "text_utils.cc",
 197     "text_utils.h",
 198     "text_utils_android.cc",
 199     "text_utils_ios.mm",
 200     "transform.cc",
 201     "transform.h",
 202     "transform_util.cc",
 203     "transform_util.h",
 204     "ui_gfx_exports.cc",
 205     "utf16_indexing.cc",
 206     "utf16_indexing.h",
 207     "vsync_provider.h",
 208     "win/direct_write.cc",
 209     "win/direct_write.h",
 210     "win/dpi.cc",
 211     "win/dpi.h",
 212     "win/hwnd_util.cc",
 213     "win/hwnd_util.h",
 214     "win/scoped_set_map_mode.h",
 215     "win/singleton_hwnd.cc",
 216     "win/singleton_hwnd.h",
 217     "win/window_impl.cc",
 218     "win/window_impl.h",
 219   ]
 220
 221   defines = [ "GFX_IMPLEMENTATION" ]
 222
 223   deps = [
 224     ":gfx_export",
 225     "//base:i18n",
 226     "//base:base_static",
 227     "//base/third_party/dynamic_annotations",
 228     "//skia",
 229     "//third_party/harfbuzz-ng",
 230     "//third_party/libpng",
 231     "//third_party/zlib",
 232     "//ui/gfx/geometry",
 233   ]
 234   public_deps = [
 235     "//base",
 236     "//skia",
 237     "//third_party/icu",
 238   ]
 239
 240   # Text rendering conditions (complicated so separated out).
 241   if (is_android || is_ios) {
 242     # We don't support RenderText on these platforms.
 243   } else {
 244     # These text rendering files are supported everywhere text rendering is.
 245     sources += [
 246       "render_text.cc",
 247       "render_text.h",
 248       "render_text_harfbuzz.cc",
 249       "render_text_harfbuzz.h",
 250       "text_utils_skia.cc",
 251     ]
 252
 253     # These are the "native" rendering routines, only one should apply.
 254     if (is_win) {
 255       sources += [ "render_text_win.cc" ]
 256     } else if (is_mac) {
 257       sources += [ "render_text_mac.cc" ]
 258     } else if (use_pango) {
 259       sources += [ "render_text_pango.cc" ]
 260     } else if (use_ozone) {
 261       sources += [ "render_text_ozone.cc" ]
 262     }
 263   }
 264
 265   # iOS.
 266   if (is_ios) {
 267     sources -= [
 268       "codec/jpeg_codec.cc",
 269       "codec/jpeg_codec.h",
 270     ]
 271   } else {
 272     deps += [ "//third_party:jpeg" ]
 273   }
 274
 275   # Android.
 276   if (is_android) {
 277     sources -= [
 278       "animation/throb_animation.cc",
 279       "canvas_skia.cc",
 280       "selection_model.cc",
 281     ]
 282
 283     if (use_aura) {
 284       sources -= [ "screen_android.cc" ]
 285     } else {
 286       sources -= [ "path.cc" ]
 287     }
 288
 289     # TODO(GYP) re-enable when base_java exists.
 290     #if (!is_android_webview_build) {
 291     #  deps += [ "//base:base_java" ]
 292     #}
 293
 294     if (!is_debug) {
 295       configs -= [ "//build/config/compiler:optimize" ]
 296       configs += [ "//build/config/compiler:optimize_max" ]
 297     }
 298
 299     deps += [ ":gfx_jni_headers" ]
 300     libs = [
 301       "android",
 302       "jnigraphics",
 303     ]
 304   } else {
 305     sources -= [ "canvas_notimplemented.cc" ]
 306   }
 307
 308   # Windows.
 309   if (is_win) {
 310     cflags = [
 311       "/wd4267",  # TODO(jschuh): C4267: http://crbug.com/167187 size_t -> int.
 312       "/wd4324",  # Structure was padded due to __declspec(align()), which is
 313                   # uninteresting.
 314     ]
 315   } else {
 316     sources -= [
 317       "gdi_util.cc",
 318       "gdi_util.h",
 319       "icon_util.cc",
 320       "icon_util.h",
 321     ]
 322   }
 323
 324   # Linux.
 325   if (is_linux) {
 326     configs += [ "//build/config/linux:fontconfig" ]
 327   }
 328
 329   # Ozone stuff.
 330   if (use_ozone) {
 331     sources += [ "platform_font_ozone.cc" ]
 332   }
 333
 334   if (!use_aura) {
 335     sources -= [
 336       "nine_image_painter.cc",
 337       "nine_image_painter.h",
 338       "path_aura.cc",
 339       "screen_aura.cc",
 340     ]
 341   }
 342
 343   if (use_x11) {
 344     deps += [ "//ui/gfx/x" ]
 345     configs += [ "//build/config/linux:x11" ]
 346   } else {
 347     sources -= [ "path_x11.cc" ]
 348   }
 349
 350   if (use_pango) {
 351     sources += [
 352       "pango_util.cc",
 353       "pango_util.h",
 354       "platform_font_pango.cc",
 355       "platform_font_pango.h",
 356     ]
 357     configs += [ "//build/config/linux:pangocairo" ]
 358   }
 359   if (use_pango && use_ozone) {
 360     sources -= [ "platform_font_ozone.cc" ]
 361   }
 362 }
 363
 364 # Looking for gfx_geometry? It's //ui/gfx/geometry:geometry
 365
 366 source_set("test_support") {
 367   testonly = true
 368   sources = [
 369     "image/image_unittest_util.cc",
 370     "image/image_unittest_util.h",
 371     "image/image_unittest_util_ios.mm",
 372     "image/image_unittest_util_mac.mm",
 373     "test/fontconfig_util_linux.cc",
 374     "test/fontconfig_util_linux.h",
 375     "test/gfx_util.cc",
 376     "test/gfx_util.h",
 377     "test/ui_cocoa_test_helper.h",
 378     "test/ui_cocoa_test_helper.mm",
 379   ]
 380
 381   public_deps = [
 382     ":gfx",
 383   ]
 384
 385   deps = [
 386     "//base",
 387     "//base/test:test_support",
 388     "//skia",
 389     "//testing/gtest",
 390     "//ui/gfx/geometry",
 391   ]
 392
 393   if (is_ios) {
 394     # The cocoa files don't apply to iOS.
 395     sources -= [
 396       "test/ui_cocoa_test_helper.h",
 397       "test/ui_cocoa_test_helper.mm",
 398     ]
 399   }
 400   if (is_linux) {
 401     configs += [ "//build/config/linux:fontconfig" ]
 402   }
 403 }
 404
 405 test("gfx_unittests") {
 406   sources = [
 407     "font_unittest.cc",
 408     "image/image_family_unittest.cc",
 409     "image/image_ios_unittest.mm",
 410     "image/image_skia_unittest.cc",
 411     "image/image_unittest.cc",
 412     "screen_unittest.cc",
 413     "test/run_all_unittests.cc",
 414     "text_elider_unittest.cc",
 415     "text_utils_unittest.cc",
 416   ]
 417
 418   if (!is_ios) {
 419     sources += [
 420       "animation/animation_container_unittest.cc",
 421       "animation/animation_unittest.cc",
 422       "animation/multi_animation_unittest.cc",
 423       "animation/slide_animation_unittest.cc",
 424       "animation/tween_unittest.cc",
 425       "blit_unittest.cc",
 426       "break_list_unittest.cc",
 427       "canvas_unittest.cc",
 428       "canvas_unittest_mac.mm",
 429       "codec/jpeg_codec_unittest.cc",
 430       "codec/png_codec_unittest.cc",
 431       "color_analysis_unittest.cc",
 432       "color_profile_mac_unittest.mm",
 433       "color_utils_unittest.cc",
 434       "display_change_notifier_unittest.cc",
 435       "display_unittest.cc",
 436       "font_list_unittest.cc",
 437       "geometry/box_unittest.cc",
 438       "geometry/cubic_bezier_unittest.cc",
 439       "geometry/insets_unittest.cc",
 440       "geometry/matrix3_unittest.cc",
 441       "geometry/point_unittest.cc",
 442       "geometry/point3_unittest.cc",
 443       "geometry/quad_unittest.cc",
 444       "geometry/r_tree_unittest.cc",
 445       "geometry/rect_unittest.cc",
 446       "geometry/safe_integer_conversions_unittest.cc",
 447       "geometry/scroll_offset_unittest.cc",
 448       "geometry/size_unittest.cc",
 449       "geometry/vector2d_unittest.cc",
 450       "geometry/vector3d_unittest.cc",
 451       "image/image_mac_unittest.mm",
 452       "image/image_util_unittest.cc",
 453       "mac/coordinate_conversion_unittest.mm",
 454       "platform_font_mac_unittest.mm",
 455       "range/range_mac_unittest.mm",
 456       "range/range_unittest.cc",
 457       "range/range_win_unittest.cc",
 458       "render_text_unittest.cc",
 459       "sequential_id_generator_unittest.cc",
 460       "shadow_value_unittest.cc",
 461       "skbitmap_operations_unittest.cc",
 462       "skrect_conversion_unittest.cc",
 463       "transform_util_unittest.cc",
 464       "utf16_indexing_unittest.cc",
 465     ]
 466   }
 467
 468   deps = [
 469     ":gfx",
 470     ":test_support",
 471     "//base",
 472     "//base/test:test_support",
 473     "//skia",
 474     "//third_party/icu:icuuc",
 475     "//third_party/libpng",
 476     "//third_party/zlib",
 477     "//testing/gtest",
 478     "//ui/base",
 479     "//ui/gfx/geometry",
 480     "//ui/resources:ui_test_pak",
 481   ]
 482
 483   if (use_pango) {
 484     sources += [
 485       "font_render_params_linux_unittest.cc",
 486       "platform_font_pango_unittest.cc",
 487     ]
 488     configs += [
 489       "//build/config/linux:pangocairo",
 490       "//build/config/linux:pangoft2",
 491     ]
 492   }
 493
 494   if (!is_mac && !is_ios) {
 495     sources += [
 496       "transform_unittest.cc",
 497       "interpolated_transform_unittest.cc",
 498     ]
 499   }
 500
 501   if (use_ozone && !use_pango) {
 502     sources -= [
 503       "canvas_unittest.cc",
 504       "font_list_unittest.cc",
 505       "font_unittest.cc",
 506       "render_text_unittest.cc",
 507       "text_elider_unittest.cc",
 508     ]
 509   }
 510
 511   if (is_android) {
 512     sources -= [
 513       # Do not run display_change_notifier_unittest.cc on Android because it
 514       # does not compile display_observer.cc
 515       "display_change_notifier_unittest.cc",
 516     ]
 517
 518     deps += [
 519       #'../../testing/android/native_test.gyp:native_test_native_code', TODO(GYP)
 520     ]
 521   }
 522
 523   if (is_android || is_ios) {
 524     sources -= [ "render_text_unittest.cc" ]
 525   }
 526
 527   if (use_aura) {
 528     sources -= [ "screen_unittest.cc" ]
 529   }
 530
 531   if (is_win) {
 532     sources += [
 533       "color_profile_win_unittest.cc",
 534       "font_fallback_win_unittest.cc",
 535       "icon_util_unittest.cc",
 536       "icon_util_unittests.rc",
 537       "path_win_unittest.cc",
 538       "platform_font_win_unittest.cc",
 539     ]
 540
 541     ldflags = [
 542       "/DELAYLOAD:d2d1.dll",
 543       "/DELAYLOAD:d3d10_1.dll",
 544     ]
 545
 546     libs = [
 547       "d2d1.lib",
 548       "d3d10_1.lib",
 549       "imm32.lib",
 550       "oleacc.lib",
 551     ]
 552
 553     # TODO(jschuh): crbug.com/167187 fix size_t to int truncations.
 554     cflags = [ "/wd4267" ]
 555   }
 556 }
 557
 558 if (is_android) {
 559   generate_jni("gfx_jni_headers") {
 560     sources = [
 561       "../android/java/src/org/chromium/ui/gfx/BitmapHelper.java",
 562       "../android/java/src/org/chromium/ui/gfx/DeviceDisplayInfo.java",
 563       "../android/java/src/org/chromium/ui/gfx/ViewConfigurationHelper.java",
 564     ]
 565     jni_package = "gfx"
 566   }
 567 }