content/renderer/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 import("//content/renderer/renderer.gni")
   8 import("//media/media_options.gni")
   9
  10 source_set("renderer") {
  11   # Only the public target should depend on this. All other targets (even
  12   # internal content ones) should depend on the public one.
  13   visibility = [ "//content/public/renderer:renderer_sources" ]
  14
  15   sources = rebase_path(content_renderer_gypi_values.private_renderer_sources,
  16                         ".",
  17                         "//content")
  18
  19   configs += [
  20     "//content:content_implementation",
  21     "//build/config/compiler:no_size_t_to_int_warning",
  22   ]
  23
  24   deps = [
  25     # TODO(GYP) bug 376846 remove this. This should be inherited from //net but
  26     # those don't cross component boundaries.
  27     "//crypto:platform",
  28     "//base/allocator",
  29     "//cc",
  30     "//cc/blink",
  31     "//content:resources",
  32     "//content/common:mojo_bindings",
  33     "//content/public/child:child_sources",
  34     "//content/public/common:common_sources",
  35     "//content/public/common:mojo_bindings",
  36     "//device/battery:mojo_bindings",
  37     "//device/vibration:mojo_bindings",
  38     "//gin",
  39     "//gpu",
  40     "//gpu/command_buffer/client:gles2_interface",
  41     "//jingle:jingle_glue",
  42     "//media",
  43     "//media/blink",
  44     "//mojo/environment:chromium",
  45     "//net",
  46     "//skia",
  47     "//storage/common",
  48     "//third_party/icu",
  49     "//third_party/libjingle",
  50     "//third_party/mojo/src/mojo/edk/js",
  51     "//third_party/mojo/src/mojo/public/js",
  52     "//third_party/mojo/src/mojo/public/interfaces/application",
  53     "//third_party/npapi",
  54     "//third_party/WebKit/public:blink",
  55     "//third_party/widevine/cdm:version_h",
  56     "//ui/accessibility",
  57     "//ui/base",
  58     "//ui/events:events_base",
  59     "//ui/events:dom4_keycode_converter",
  60     "//ui/gl",
  61     "//ui/native_theme",
  62     "//ui/surface",
  63     "//v8",
  64     "//webkit/common/gpu",
  65   ]
  66
  67   if (is_mac) {
  68     sources -= [
  69       "webscrollbarbehavior_impl_gtkoraura.cc",
  70       "webscrollbarbehavior_impl_gtkoraura.h",
  71     ]
  72     sources += [
  73       "external_popup_menu.cc",
  74       "external_popup_menu.h",
  75     ]
  76   }
  77
  78   if (is_android) {
  79     sources -= [ "media/audio_decoder.cc" ]
  80     sources += [
  81       "external_popup_menu.cc",
  82       "external_popup_menu.h",
  83     ]
  84
  85     # Add back the Linux file which Android shares.
  86     set_sources_assignment_filter([])
  87     sources += [ "render_view_linux.cc" ]
  88
  89     deps += [
  90       "//third_party/android_tools:cpu_features",
  91       "//third_party/libphonenumber",
  92     ]
  93   } else {
  94     sources -= [
  95       "java/gin_java_bridge_dispatcher.cc",
  96       "java/gin_java_bridge_dispatcher.h",
  97       "java/gin_java_bridge_object.cc",
  98       "java/gin_java_bridge_object.h",
  99       "java/gin_java_bridge_value_converter.cc",
 100       "java/gin_java_bridge_value_converter.h",
 101     ]
 102   }
 103
 104   # TODO(jrg): remove the OS=="android" section?
 105   # http://crbug.com/113172
 106   # Understand better how media_stream_ is tied into Chromium.
 107   if (!enable_webrtc && is_android) {
 108     sources -= [
 109       "media/media_stream_audio_level_calculator.cc",
 110       "media/media_stream_audio_level_calculator.h",
 111       "media/media_stream_audio_renderer.cc",
 112       "media/media_stream_audio_renderer.h",
 113       "media/media_stream_center.h",
 114       "media/media_stream_constraints_util.cc",
 115       "media/media_stream_constraints_util.h",
 116       "media/media_stream_dispatcher.h",
 117       "media/media_stream_dispatcher_eventhandler.h",
 118       "media/media_stream_track.cc",
 119       "media/media_stream_track.h",
 120     ]
 121   }
 122
 123   if (enable_webrtc) {
 124     sources += rebase_path(
 125             content_renderer_gypi_values.private_renderer_webrtc_sources,
 126             ".",
 127             "//content")
 128     deps += [
 129       "//crypto",
 130       "//third_party/libyuv",
 131       "//third_party/webrtc/modules/audio_device",
 132       "//third_party/webrtc/modules/audio_processing",
 133       "//third_party/libjingle:libjingle_webrtc",
 134       "//third_party/libjingle:libpeerconnection",
 135     ]
 136   } else {
 137     sources += [
 138       "media/webrtc_logging.h",
 139       "media/webrtc_logging_noop.cc",
 140     ]
 141   }
 142
 143   if (enable_plugins) {
 144     sources += rebase_path(
 145             content_renderer_gypi_values.private_renderer_plugin_sources,
 146             ".",
 147             "//content")
 148     deps += [
 149       "//ppapi/host",
 150       "//ppapi/proxy",
 151       "//ppapi/shared_impl",
 152       "//third_party/libyuv",
 153     ]
 154   } else {
 155     # These files are in the WebRTC list, but also require plugins.
 156     if (enable_webrtc) {
 157       sources -= [
 158         "media/webrtc/video_destination_handler.cc",
 159         "media/webrtc/video_destination_handler.h",
 160       ]
 161     }
 162   }
 163
 164   if (enable_plugins && enable_webrtc) {
 165     sources += rebase_path(
 166             content_renderer_gypi_values.private_renderer_plugin_webrtc_sources,
 167             ".",
 168             "//content")
 169   }
 170
 171   if (!enable_pepper_cdms) {
 172     sources -= [
 173       "media/crypto/pepper_cdm_wrapper.h",
 174       "media/crypto/pepper_cdm_wrapper_impl.cc",
 175       "media/crypto/pepper_cdm_wrapper_impl.h",
 176       "media/crypto/ppapi_decryptor.cc",
 177       "media/crypto/ppapi_decryptor.h",
 178     ]
 179   }
 180
 181   if (enable_print_preview) {
 182     deps += [ "//printing" ]
 183   }
 184
 185   if (enable_browser_cdms) {
 186     sources += [
 187       "media/crypto/proxy_media_keys.cc",
 188       "media/crypto/proxy_media_keys.h",
 189       "media/crypto/renderer_cdm_manager.cc",
 190       "media/crypto/renderer_cdm_manager.h",
 191     ]
 192   }
 193
 194   if (enable_media_mojo_renderer) {
 195     sources += [
 196       "media/media_renderer_service_provider.cc",
 197       "media/media_renderer_service_provider.h",
 198     ]
 199     deps += [ "//media/mojo/services:renderer_proxy" ]
 200   }
 201 }