remoting/host/clipboard_mac.mm

   1 // Copyright (c) 2012 The Chromium Authors. All rights reserved.
   2 // Use of this source code is governed by a BSD-style license that can be
   3 // found in the LICENSE file.
   4
   5 #include "remoting/host/clipboard.h"
   6
   7 #import <Cocoa/Cocoa.h>
   8
   9 #include "base/basictypes.h"
  10 #include "base/logging.h"
  11 #include "base/memory/scoped_ptr.h"
  12 #include "base/strings/sys_string_conversions.h"
  13 #include "base/timer/timer.h"
  14 #include "remoting/base/constants.h"
  15 #include "remoting/base/util.h"
  16 #include "remoting/proto/event.pb.h"
  17 #include "remoting/protocol/clipboard_stub.h"
  18
  19 namespace {
  20
  21 // Clipboard polling interval in milliseconds.
  22 const int64 kClipboardPollingIntervalMs = 500;
  23
  24 } // namespace
  25
  26 namespace remoting {
  27
  28 class ClipboardMac : public Clipboard {
  29  public:
  30   ClipboardMac();
  31   ~ClipboardMac() override;
  32
  33   void Start(scoped_ptr<protocol::ClipboardStub> client_clipboard) override;
  34   void InjectClipboardEvent(const protocol::ClipboardEvent& event) override;
  35
  36  private:
  37   void CheckClipboardForChanges();
  38
  39   scoped_ptr<protocol::ClipboardStub> client_clipboard_;
  40   scoped_ptr<base::RepeatingTimer<ClipboardMac> > clipboard_polling_timer_;
  41   NSInteger current_change_count_;
  42
  43   DISALLOW_COPY_AND_ASSIGN(ClipboardMac);
  44 };
  45
  46 ClipboardMac::ClipboardMac() : current_change_count_(0) {}
  47
  48 ClipboardMac::~ClipboardMac() {}
  49
  50 void ClipboardMac::Start(scoped_ptr<protocol::ClipboardStub> client_clipboard) {
  51   client_clipboard_.reset(client_clipboard.release());
  52
  53   // Synchronize local change-count with the pasteboard's. The change-count is
  54   // used to detect clipboard changes.
  55   current_change_count_ = [[NSPasteboard generalPasteboard] changeCount];
  56
  57   // OS X doesn't provide a clipboard-changed notification. The only way to
  58   // detect clipboard changes is by polling.
  59   clipboard_polling_timer_.reset(new base::RepeatingTimer<ClipboardMac>());
  60   clipboard_polling_timer_->Start(FROM_HERE,
  61       base::TimeDelta::FromMilliseconds(kClipboardPollingIntervalMs),
  62       this, &ClipboardMac::CheckClipboardForChanges);
  63 }
  64
  65 void ClipboardMac::InjectClipboardEvent(const protocol::ClipboardEvent& event) {
  66   // Currently we only handle UTF-8 text.
  67   if (event.mime_type().compare(kMimeTypeTextUtf8) != 0)
  68     return;
  69   if (!StringIsUtf8(event.data().c_str(), event.data().length())) {
  70     LOG(ERROR) << "ClipboardEvent data is not UTF-8 encoded.";
  71     return;
  72   }
  73
  74   // Write UTF-8 text to clipboard.
  75   NSString* text = base::SysUTF8ToNSString(event.data());
  76   NSPasteboard* pasteboard = [NSPasteboard generalPasteboard];
  77   [pasteboard declareTypes:[NSArray arrayWithObject:NSStringPboardType]
  78                      owner:nil];
  79   [pasteboard setString:text forType:NSStringPboardType];
  80
  81   // Update local change-count to prevent this change from being picked up by
  82   // CheckClipboardForChanges.
  83   current_change_count_ = [[NSPasteboard generalPasteboard] changeCount];
  84 }
  85
  86 void ClipboardMac::CheckClipboardForChanges() {
  87   NSPasteboard* pasteboard = [NSPasteboard generalPasteboard];
  88   NSInteger change_count = [pasteboard changeCount];
  89   if (change_count == current_change_count_) {
  90     return;
  91   }
  92   current_change_count_ = change_count;
  93
  94   NSString* data = [pasteboard stringForType:NSStringPboardType];
  95   if (data == nil) {
  96     return;
  97   }
  98
  99   protocol::ClipboardEvent event;
 100   event.set_mime_type(kMimeTypeTextUtf8);
 101   event.set_data(base::SysNSStringToUTF8(data));
 102   client_clipboard_->InjectClipboardEvent(event);
 103 }
 104
 105 scoped_ptr<Clipboard> Clipboard::Create() {
 106   return make_scoped_ptr(new ClipboardMac());
 107 }
 108
 109 }  // namespace remoting