chrome/android/BUILD.gn

   1 # Copyright 2014 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/android/config.gni")
   6 import("//build/config/android/rules.gni")
   7 import("//build/module_args/v8.gni")
   8 import("//chrome/version.gni")
   9 import("//testing/test.gni")
  10 import("//third_party/icu/config.gni")
  11 import("//third_party/protobuf/proto_library.gni")
  12 import("channel.gni")
  13
  14 manifest_package = "org.chromium.chrome"
  15 if (enable_configuration_policy) {
  16   configuration_policy = 1
  17 } else {
  18   configuration_policy = 0
  19 }
  20
  21 jinja_variables = [
  22   "channel=$android_channel",
  23   "manifest_package=$manifest_package",
  24   "configuration_policy=$configuration_policy",
  25 ]
  26
  27 # GYP: //chrome/chrome.gyp:chrome_java (resources part)
  28 android_resources("chrome_java_resources") {
  29   resource_dirs = [ "java/res" ]
  30   deps = [
  31     ":chrome_strings_grd",
  32     "//content/public/android:content_java_resources",
  33     "//chrome/app:java_strings_grd",
  34     "//third_party/android_data_chart:android_data_chart_java_resources",
  35     "//third_party/android_media:android_media_resources",
  36     "//third_party/android_tools:android_support_v7_appcompat_resources",
  37   ]
  38   custom_package = "org.chromium.chrome"
  39 }
  40
  41 # GYP: //chrome/chrome.gyp:chrome_strings_grd
  42 java_strings_grd("chrome_strings_grd") {
  43   grd_file = "java/strings/android_chrome_strings.grd"
  44   outputs = [
  45     "values-am/android_chrome_strings.xml",
  46     "values-ar/android_chrome_strings.xml",
  47     "values-bg/android_chrome_strings.xml",
  48     "values-ca/android_chrome_strings.xml",
  49     "values-cs/android_chrome_strings.xml",
  50     "values-da/android_chrome_strings.xml",
  51     "values-de/android_chrome_strings.xml",
  52     "values-el/android_chrome_strings.xml",
  53     "values/android_chrome_strings.xml",
  54     "values-en-rGB/android_chrome_strings.xml",
  55     "values-es/android_chrome_strings.xml",
  56     "values-es-rUS/android_chrome_strings.xml",
  57     "values-fa/android_chrome_strings.xml",
  58     "values-fi/android_chrome_strings.xml",
  59     "values-tl/android_chrome_strings.xml",
  60     "values-fr/android_chrome_strings.xml",
  61     "values-hi/android_chrome_strings.xml",
  62     "values-hr/android_chrome_strings.xml",
  63     "values-hu/android_chrome_strings.xml",
  64     "values-in/android_chrome_strings.xml",
  65     "values-it/android_chrome_strings.xml",
  66     "values-iw/android_chrome_strings.xml",
  67     "values-ja/android_chrome_strings.xml",
  68     "values-ko/android_chrome_strings.xml",
  69     "values-lt/android_chrome_strings.xml",
  70     "values-lv/android_chrome_strings.xml",
  71     "values-nl/android_chrome_strings.xml",
  72     "values-nb/android_chrome_strings.xml",
  73     "values-pl/android_chrome_strings.xml",
  74     "values-pt-rBR/android_chrome_strings.xml",
  75     "values-pt-rPT/android_chrome_strings.xml",
  76     "values-ro/android_chrome_strings.xml",
  77     "values-ru/android_chrome_strings.xml",
  78     "values-sk/android_chrome_strings.xml",
  79     "values-sl/android_chrome_strings.xml",
  80     "values-sr/android_chrome_strings.xml",
  81     "values-sv/android_chrome_strings.xml",
  82     "values-sw/android_chrome_strings.xml",
  83     "values-th/android_chrome_strings.xml",
  84     "values-tr/android_chrome_strings.xml",
  85     "values-uk/android_chrome_strings.xml",
  86     "values-vi/android_chrome_strings.xml",
  87     "values-zh-rCN/android_chrome_strings.xml",
  88     "values-zh-rTW/android_chrome_strings.xml",
  89   ]
  90 }
  91
  92 # GYP: //chrome/chrome.gyp:chrome_java
  93 android_library("chrome_java") {
  94   deps = [
  95     ":chrome_java_resources",
  96     ":document_tab_model_info_proto_java",
  97     "//base:base_java",
  98     "//net/android:net_java",
  99     "//components/bookmarks/common/android:bookmarks_java",
 100     "//components/dom_distiller/android:dom_distiller_core_java",
 101     "//components/gcm_driver/android:gcm_driver_java",
 102     "//components/invalidation:java",
 103     "//components/navigation_interception/android:navigation_interception_java",
 104     "//components/service_tab_launcher:service_tab_launcher_java",
 105     "//components/precache/android:precache_java",
 106     "//components/variations/android:variations_java",
 107     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
 108     "//content/public/android:content_java",
 109     "//printing:printing_java",
 110     "//sync/android:sync_java",
 111     "//third_party/android_data_chart:android_data_chart_java",
 112     "//third_party/android_media:android_media_java",
 113     "//third_party/android_protobuf:protobuf_nano_javalib",
 114     "//third_party/android_tools:android_gcm_java",
 115     "//third_party/android_swipe_refresh:android_swipe_refresh_java",
 116     "//third_party/android_tools:android_support_v13_java",
 117     "//third_party/android_tools:android_support_v7_appcompat_java",
 118     "//third_party/android_tools:android_support_v7_mediarouter_java",
 119     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 120     "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
 121     "//third_party/jsr-305:jsr_305_javalib",
 122     "//media/base/android:media_java",
 123     "//media/midi:midi_java",
 124     "//ui/android:ui_java",
 125     "//ui/android:ui_java_resources",
 126     google_play_services_library,
 127   ]
 128
 129   srcjar_deps = [
 130     ":chrome_android_java_enums_srcjar",
 131     ":chrome_version_srcjar",
 132     ":resource_id_javagen",
 133     "//chrome:page_info_connection_type_javagen",
 134     "//chrome:content_setting_javagen",
 135     "//chrome:content_settings_type_javagen",
 136     "//components/enhanced_bookmarks:enhanced_bookmarks_java_enums_srcjar",
 137   ]
 138
 139   DEPRECATED_java_in_dir = "java/src"
 140 }
 141
 142 # GYP: //chrome/chrome_browser.gypi:activity_type_ids_java
 143 # GYP: //chrome/chrome_browser.gypi:profile_account_management_metrics_java
 144 # GYP: //chrome/chrome_browser.gypi:profile_sync_service_model_type_selection_java
 145 # GYP: //chrome/chrome_browser.gypi:connection_security_helper_security_levels_java
 146 # GYP: //chrome/chrome_browser.gypi:tab_load_status_java
 147 java_cpp_enum("chrome_android_java_enums_srcjar") {
 148   sources = [
 149     "//chrome/browser/android/activity_type_ids.h",
 150     "//chrome/browser/android/tab_android.h",
 151     "//chrome/browser/profiles/profile_metrics.h",
 152     "//chrome/browser/ssl/connection_security_helper.h",
 153     "//chrome/browser/sync/profile_sync_service_android.cc",
 154   ]
 155   outputs = [
 156     "org/chromium/chrome/browser/ActivityTypeIds.java",
 157     "org/chromium/chrome/browser/TabLoadStatus.java",
 158     "org/chromium/chrome/browser/profiles/ProfileAccountManagementMetrics.java",
 159     "org/chromium/chrome/browser/ssl/ConnectionSecurityHelperSecurityLevel.java",
 160     "org/chromium/chrome/browser/sync/ModelTypeSelection.java",
 161   ]
 162 }
 163
 164 # GYP: //chrome/chrome_browser.gypi:document_tab_model_info_proto_java
 165 proto_java_library("document_tab_model_info_proto_java") {
 166   proto_path = "java/src/org/chromium/chrome/browser/tabmodel/document"
 167   sources = [
 168     "$proto_path/document_tab_model_info.proto",
 169   ]
 170 }
 171
 172 # GYP: //chrome/chrome_browser.gypi:resource_id_java
 173 java_cpp_template("resource_id_javagen") {
 174   sources = [
 175     "java/ResourceId.template",
 176   ]
 177   package_name = "org/chromium/chrome/browser"
 178   inputs = [
 179     "../browser/android/resource_id.h",
 180   ]
 181 }
 182
 183 # GYP: //chrome/chrome_shell.gypi:libchromeshell_base
 184 group("chrome_shell_base") {
 185   deps = [
 186     "//chrome/browser/ui",
 187     "//chrome:chrome_android_core",
 188     "//base",
 189     "//base/allocator",
 190     "//content/public/app:both",
 191     "//skia",
 192   ]
 193   # TODO(GYP):
 194   #[ 'order_profiling!=0', {
 195   #'dependencies': [ '../tools/cygprofile/cygprofile.gyp:cygprofile', ],
 196   #}],
 197 }
 198
 199 # GYP: //chrome/chrome_shell.gypi:libchromeshell
 200 shared_library("chrome_shell") {
 201   testonly = true
 202   sources = [
 203     "shell/chrome_main_delegate_chrome_shell_android.cc",
 204     "shell/chrome_main_delegate_chrome_shell_android.h",
 205     "shell/chrome_shell_entry_point.cc",
 206   ]
 207   deps = [
 208     ":chrome_shell_base",
 209   ]
 210 }
 211
 212 # GYP: //chrome/chrome_shell.gypi:libchromesyncshell
 213 shared_library("chrome_sync_shell") {
 214   testonly = true
 215   sources = [
 216     #"shell/chrome_shell_entry_point.cc",
 217     #"sync_shell/chrome_main_delegate_chrome_sync_shell_android.cc",
 218     #"sync_shell/chrome_main_delegate_chrome_sync_shell_android.h",
 219   ]
 220   deps = [
 221     "//sync:test_support_sync_fake_server_android",
 222   ]
 223   data_deps = [ ":chrome_shell_base" ]
 224 }
 225
 226 # GYP: N/A
 227 android_resources("chrome_shell_resources") {
 228   deps = [
 229     ":chrome_java_resources",
 230   ]
 231   testonly = true
 232   resource_dirs = [ "shell/res" ]
 233   custom_package = "org.chromium.chrome.shell"
 234 }
 235
 236 # GYP: N/A
 237 android_library("chrome_shell_java") {
 238   testonly = true
 239   deps = [
 240     ":chrome_shell_resources",
 241     ":chrome_java",
 242     "//base:base_java",
 243     "//content/public/android:content_java",
 244     "//components/dom_distiller/android:dom_distiller_content_java",
 245     "//components/dom_distiller/android:dom_distiller_core_java",
 246     "//components/service_tab_launcher:service_tab_launcher_java",
 247     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
 248     "//printing:printing_java",
 249     "//net/android:net_java",
 250     "//sync/android:sync_java",
 251     "//third_party/android_tools:android_support_v13_java",
 252     "//third_party/android_tools:android_support_v7_appcompat_java",
 253     "//ui/android:ui_java",
 254   ]
 255   DEPRECATED_java_in_dir = "shell/java/src"
 256 }
 257
 258 chrome_shell_assets_dir = "$root_build_dir/chrome_shell/assets"
 259
 260 # GYP: N/A
 261 copy_ex("chrome_shell_assets") {
 262   clear_dir = true
 263   dest = chrome_shell_assets_dir
 264   sources = [
 265     "$root_build_dir/chrome_100_percent.pak",
 266     "$root_build_dir/locales/am.pak",
 267     "$root_build_dir/locales/ar.pak",
 268     "$root_build_dir/locales/bg.pak",
 269     "$root_build_dir/locales/ca.pak",
 270     "$root_build_dir/locales/cs.pak",
 271     "$root_build_dir/locales/da.pak",
 272     "$root_build_dir/locales/de.pak",
 273     "$root_build_dir/locales/el.pak",
 274     "$root_build_dir/locales/en-GB.pak",
 275     "$root_build_dir/locales/en-US.pak",
 276     "$root_build_dir/locales/es-419.pak",
 277     "$root_build_dir/locales/es.pak",
 278     "$root_build_dir/locales/fa.pak",
 279     "$root_build_dir/locales/fi.pak",
 280     "$root_build_dir/locales/fil.pak",
 281     "$root_build_dir/locales/fr.pak",
 282     "$root_build_dir/locales/he.pak",
 283     "$root_build_dir/locales/hi.pak",
 284     "$root_build_dir/locales/hr.pak",
 285     "$root_build_dir/locales/hu.pak",
 286     "$root_build_dir/locales/id.pak",
 287     "$root_build_dir/locales/it.pak",
 288     "$root_build_dir/locales/ja.pak",
 289     "$root_build_dir/locales/ko.pak",
 290     "$root_build_dir/locales/lt.pak",
 291     "$root_build_dir/locales/lv.pak",
 292     "$root_build_dir/locales/nb.pak",
 293     "$root_build_dir/locales/nl.pak",
 294     "$root_build_dir/locales/pl.pak",
 295     "$root_build_dir/locales/pt-BR.pak",
 296     "$root_build_dir/locales/pt-PT.pak",
 297     "$root_build_dir/locales/ro.pak",
 298     "$root_build_dir/locales/ru.pak",
 299     "$root_build_dir/locales/sk.pak",
 300     "$root_build_dir/locales/sl.pak",
 301     "$root_build_dir/locales/sr.pak",
 302     "$root_build_dir/locales/sv.pak",
 303     "$root_build_dir/locales/sw.pak",
 304     "$root_build_dir/locales/th.pak",
 305     "$root_build_dir/locales/tr.pak",
 306     "$root_build_dir/locales/uk.pak",
 307     "$root_build_dir/locales/vi.pak",
 308     "$root_build_dir/locales/zh-CN.pak",
 309     "$root_build_dir/locales/zh-TW.pak",
 310     "$root_build_dir/resources.pak",
 311   ]
 312   deps = [
 313     "//chrome:packed_resources",
 314     "//chrome:packed_extra_resources",
 315   ]
 316
 317   if (icu_use_data_file) {
 318     sources += [ "$root_build_dir/icudtl.dat" ]
 319     deps += [ "//third_party/icu:icudata" ]
 320   }
 321   if (v8_use_external_startup_data) {
 322     sources += [
 323       "$root_build_dir/natives_blob.bin",
 324       "$root_build_dir/snapshot_blob.bin",
 325     ]
 326     deps += [ "//v8" ]
 327   }
 328 }
 329
 330 chrome_shell_manifest =
 331     "$target_gen_dir/chrome_shell_manifest/AndroidManifest.xml"
 332
 333 # GYP: //chrome/chrome_shell.gypi:chrome_shell_manifest
 334 jinja_template("chrome_shell_manifest") {
 335   testonly = true
 336   input = "shell/java/AndroidManifest.xml.jinja2"
 337   output = chrome_shell_manifest
 338 }
 339
 340 # TODO(cjhopman): This should actually be done as a build step instead of at gn
 341 # time.
 342 _version_py_path = "//build/util/version.py"
 343 _chrome_version_path = "//chrome/VERSION"
 344 _version_full = exec_script(_version_py_path,
 345                             [
 346                               "-f",
 347                               rebase_path(_chrome_version_path, root_build_dir),
 348                               "-t \"@MAJOR@.@MINOR@.@BUILD@.@PATCH@\"",
 349                             ],
 350                             "value",
 351                             [ _chrome_version_path ])
 352
 353 # GYP: //chrome/chrome_shell.gypi:chrome_shell_apk
 354 android_apk("chrome_shell_apk") {
 355   testonly = true
 356   deps = [
 357     ":chrome_shell",
 358     ":chrome_shell_assets",
 359     ":chrome_shell_java",
 360     ":chrome_shell_manifest",
 361     ":chrome_shell_resources",
 362     "//base:base_java",
 363   ]
 364   apk_name = "ChromeShell"
 365   android_manifest = chrome_shell_manifest
 366   native_libs = [ "libchrome_shell.so" ]
 367   native_lib_version_name = _version_full
 368   asset_location = chrome_shell_assets_dir
 369
 370   #TODO(GYP):
 371   #'variables': {
 372   #'conditions': [
 373   #['component != "shared_library" and target_arch != "arm64" and target_arch != "x64" and profiling_full_stack_frames != 1', {
 374   ## Only enable the chromium linker on regular builds, since the
 375   ## component build crashes on Android 4.4. See b/11379966
 376   #'use_chromium_linker': '1',
 377   #}],
 378   #],
 379   #},
 380 }
 381
 382 chrome_sync_shell_manifest =
 383     "$target_gen_dir/chrome_sync_shell_manifest/AndroidManifest.xml"
 384
 385 # GYP: //chrome/chrome_shell.gypi:chrome_sync_shell_manifest
 386 jinja_template("chrome_sync_shell_manifest") {
 387   testonly = true
 388   input = "sync_shell/java/AndroidManifest.xml.jinja2"
 389   output = chrome_sync_shell_manifest
 390 }
 391
 392 # GYP: //chrome/chrome_shell.gypi:chrome_sync_shell_apk
 393 android_apk("chrome_sync_shell_apk") {
 394   testonly = true
 395   deps = [
 396     ":chrome_shell_resources",
 397     ":chrome_shell_java",
 398     ":chrome_shell_assets",
 399     ":chrome_sync_shell",
 400     ":chrome_sync_shell_manifest",
 401     "//base:base_java",
 402   ]
 403   apk_name = "ChromeSyncShell"
 404   android_manifest = chrome_sync_shell_manifest
 405   native_libs = [ "libchrome_sync_shell.so" ]
 406   asset_location = chrome_shell_assets_dir
 407 }
 408
 409 # GYP: part of //chrome/chrome_tests.gypi:chrome_shell_test_apk
 410 android_library("chrome_javatests") {
 411   testonly = true
 412   DEPRECATED_java_in_dir = "javatests_shell/src"
 413   deps = [
 414     ":chrome_java",
 415     ":chrome_java_resources",
 416     ":chrome_shell_java",
 417     ":chrome_shell_resources",
 418     ":chrome_shell_test_java",
 419     "//base:base_java",
 420     "//base:base_java_test_support",
 421     "//chrome/test/android:chrome_java_test_support",
 422     "//components/bookmarks/common/android:bookmarks_java",
 423     "//components/dom_distiller/android:dom_distiller_core_java",
 424     "//components/invalidation:java",
 425     "//components/invalidation:javatests",
 426     "//components/navigation_interception/android:navigation_interception_java",
 427     "//components/precache/android:precache_java",
 428     "//components/precache/android:precache_javatests",
 429     "//content/public/android:content_java",
 430     "//content/public/test/android:content_java_test_support",
 431     "//net/android:net_java_test_support",
 432     "//printing:printing_java",
 433     "//sync/android:sync_java",
 434     "//sync/android:sync_javatests",
 435     "//sync:sync_java_test_support",
 436     "//third_party/android_protobuf:protobuf_nano_javalib",
 437     "//third_party/android_tools:android_support_v13_java",
 438     "//third_party/android_tools:android_support_v7_appcompat_java",
 439     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 440     "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
 441     "//third_party/jsr-305:jsr_305_javalib",
 442     "//ui/android:ui_java",
 443   ]
 444 }
 445
 446 android_library("chrome_shell_test_java") {
 447   testonly = true
 448   deps = [
 449     ":chrome_java",
 450     ":chrome_shell_java",
 451     "//base:base_java",
 452     "//base:base_java_test_support",
 453     "//chrome/test/android:chrome_java_test_support",
 454     "//content/public/android:content_java",
 455     "//content/public/test/android:content_java_test_support",
 456     "//third_party/android_tools:android_support_v13_java",
 457     "//third_party/android_tools:android_support_v7_appcompat_java",
 458     "//ui/android:ui_java",
 459   ]
 460   DEPRECATED_java_in_dir = "shell/javatests/src"
 461 }
 462
 463 # GYP: //chrome/chrome_tests.gypi:chrome_shell_test_apk
 464 instrumentation_test_apk("chrome_shell_test_apk") {
 465   apk_under_test = ":chrome_shell_apk"
 466   deps = [
 467     ":chrome_javatests",
 468     ":chrome_shell_test_java",
 469     "//sync/android:sync_javatests",
 470     "//ui/android:ui_javatests",
 471   ]
 472   apk_name = "ChromeShellTest"
 473   android_manifest = "shell/javatests/AndroidManifest.xml"
 474   isolate_file = "../chrome_shell_test_apk.isolate"
 475 }
 476
 477 # GYP: //chrome/chrome_tests.gypi:chrome_junit_tests
 478 junit_binary("chrome_junit_tests") {
 479   java_files = [
 480     "junit/src/org/chromium/chrome/browser/externalauth/ExternalAuthUtilsTest.java",
 481     "junit/src/org/chromium/chrome/browser/omaha/ResponseParserTest.java",
 482     "junit/src/org/chromium/chrome/browser/media/remote/AbstractMediaRouteControllerTest.java",
 483     "junit/src/org/chromium/chrome/browser/media/remote/MediaUrlResolverTest.java",
 484     "junit/src/org/chromium/chrome/browser/media/remote/RemoteVideoInfoTest.java",
 485     "junit/src/org/chromium/chrome/browser/media/remote/TransportControlTest.java",
 486   ]
 487   deps = [
 488     ":chrome_java",
 489     "//base:base_java",
 490     "//base:base_java_test_support",
 491     "//third_party/junit:hamcrest",
 492     "//third_party/android_tools:android_support_v7_mediarouter_java",
 493   ]
 494 }
 495
 496 # GYP: //chrome/chrome_tests.gypi:chrome_sync_shell_test_apk
 497 if (false) {
 498   # TODO(GYP): We need sync/sync_tests.gypi:test_support_sync_proto_java to be ported.
 499   # crbug.com/475612
 500   instrumentation_test_apk("chrome_sync_shell_test_apk") {
 501     apk_under_test = ":chrome_sync_shell_apk"
 502     deps = [
 503       ":chrome_java",
 504       ":chrome_shell_java",
 505       ":chrome_shell_test_java",
 506       "//base:base_java",
 507       "//base:base_java_test_support",
 508       "//chrome/test/android:chrome_java_test_support",
 509       "//components/invalidation:java",
 510       "//content/public/android:content_java",
 511       "//content/public/test/android:content_java_test_support",
 512       "//sync/android:sync_java",
 513       "//sync:sync_java_test_support",
 514       "//third_party/android_tools:android_support_v13_java",
 515       "//third_party/android_tools:android_support_v7_appcompat_java",
 516       "//ui/android:ui_java",
 517     ]
 518     apk_name = "ChromeSyncShellTest"
 519     DEPRECATED_java_in_dir = "sync_shell/javatests/src"
 520     android_manifest = "sync_shell/javatests/AndroidManifest.xml"
 521   }
 522 }
 523
 524 # GYP: //chrome/chrome_tests.gypi:chrome_shell_uiautomator_tests_java
 525 android_library("uiautomator_tests_java") {
 526   testonly = true
 527   DEPRECATED_java_in_dir = "uiautomator_tests/src"
 528   deps = [
 529     "//base:base_java_test_support",
 530     "//third_party/android_tools:uiautomator_java",
 531   ]
 532 }
 533
 534 # GYP: //chrome/chrome_tests.gypi:chrome_shell_uiautomator_tests
 535 uiautomator_test("uiautomator_tests") {
 536   testonly = true
 537   deps = [
 538     ":uiautomator_tests_java",
 539   ]
 540 }
 541
 542 # GYP: //chrome/chrome_android.gypi:chrome_version_java
 543 chrome_version_java_dir = "$root_gen_dir/templates/chrome_version_java"
 544 chrome_version_java_file = "$chrome_version_java_dir/org/chromium/chrome/browser/ChromeVersionConstants.java"
 545 process_version("chrome_version_java") {
 546   template_file = "java/ChromeVersionConstants.java.version"
 547   output = chrome_version_java_file
 548   extra_args = [
 549     "-e",
 550     "CHANNEL=str.upper('$android_channel')",
 551   ]
 552 }
 553
 554 zip("chrome_version_srcjar") {
 555   inputs = [
 556     chrome_version_java_file,
 557   ]
 558   output = "$target_gen_dir/$target_name.srcjar"
 559   base_dir = chrome_version_java_dir
 560   deps = [
 561     ":chrome_version_java",
 562   ]
 563 }
 564
 565 #GYP: //chrome/android/chrome_apk.gyp:custom_tabs_service_aidl
 566 android_aidl("custom_tabs_service_aidl") {
 567   import_include = "java_staging/src/org/chromium/chrome/browser/customtabs"
 568   interface_file =
 569       "java_staging/src/org/chromium/chrome/browser/customtabs/common.aidl"
 570   sources = [
 571     "java_staging/src/org/chromium/chrome/browser/customtabs/IBrowserConnectionCallback.aidl",
 572     "java_staging/src/org/chromium/chrome/browser/customtabs/IBrowserConnectionService.aidl",
 573   ]
 574 }
 575
 576 # GYP: //chrome/android/chrome_apk.gyp:chrome_staging_java
 577 android_library("chrome_staging_java") {
 578   DEPRECATED_java_in_dir = "java_staging/src"
 579
 580   deps = [
 581     ":chrome_staging_java_resources",
 582     "//base:base_java",
 583     "//net/android:net_java",
 584     "//chrome/android:chrome_java",
 585     "//chrome/android:chrome_java_resources",
 586     "//chrome/android:document_tab_model_info_proto_java",
 587     "//components/bookmarks/common/android:bookmarks_java",
 588     "//components/dom_distiller/android:dom_distiller_content_java",
 589     "//components/dom_distiller/android:dom_distiller_core_java",
 590     "//components/invalidation:java",
 591     "//components/navigation_interception/android:navigation_interception_java",
 592     "//components/service_tab_launcher:service_tab_launcher_java",
 593     "//components/variations/android:variations_java",
 594     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
 595     "//content/public/android:content_java",
 596     "//media/base/android:media_java",
 597     "//printing:printing_java",
 598     "//sync/android:sync_java",
 599     "//third_party/android_protobuf:protobuf_nano_javalib",
 600     "//third_party/android_tools:android_gcm_java",
 601     "//third_party/android_tools:android_support_v13_java",
 602     "//third_party/android_tools:android_support_v7_appcompat_java",
 603     "//third_party/android_tools:android_support_v7_mediarouter_java",
 604     "//third_party/android_tools:android_support_v7_mediarouter_resources",
 605     "//third_party/android_tools:android_support_v7_recyclerview_java",
 606     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 607     "//third_party/cacheinvalidation:cacheinvalidation_proto_java",
 608     "//third_party/jsr-305:jsr_305_javalib",
 609     "//ui/android:ui_java",
 610     "//ui/android:ui_java_resources",
 611     google_play_services_library,
 612   ]
 613   srcjar_deps = [ ":custom_tabs_service_aidl" ]
 614 }
 615
 616 #GYP: //chrome/android/chrome_apk.gyp:chrome_staging_java
 617 android_resources("chrome_staging_java_resources") {
 618   resource_dirs = [
 619     "java_staging/res",
 620     "java_staging/res_default",
 621   ]
 622   custom_package = "com.google.android.apps.chrome"
 623   deps = [
 624     ":chrome_template_resources",
 625     "//chrome/android:chrome_java_resources",
 626     "//components/policy:app_restrictions_resources",
 627     "//third_party/android_tools:android_support_v7_appcompat_resources",
 628     "//third_party/android_tools:android_support_v7_mediarouter_resources",
 629   ]
 630   if (!enable_configuration_policy) {
 631     deps -= [ "//components/policy:app_restrictions_resources" ]
 632   }
 633 }
 634
 635 # GYP: //chrome/android/chrome_apk.gyp:chrome_template_resources
 636 jinja_template_resources("chrome_template_resources") {
 637   resources = [
 638     "java_staging/res_template/xml/searchable.xml",
 639     "java_staging/res_template/xml/syncadapter.xml",
 640   ]
 641   res_dir = "java_staging/res_template"
 642   variables = jinja_variables
 643 }
 644
 645 # GYP: //chrome/android/chrome_apk.gyp:chrome_staging_test_java
 646 android_library("chrome_staging_test_java") {
 647   testonly = true
 648   DEPRECATED_java_in_dir = "javatests/src"
 649
 650   deps = [
 651     "//chrome/android:chrome_staging_java",
 652     "//chrome/android:chrome_staging_java_resources",
 653     "//chrome/test/android:chrome_staging_test_support_java",
 654     "//base:base_java",
 655     "//base:base_java_test_support",
 656     "//chrome/android:chrome_java",
 657     "//chrome/android:chrome_java_resources",
 658     "//chrome/test/android:chrome_java_test_support",
 659     "//components/bookmarks/common/android:bookmarks_java",
 660     "//components/dom_distiller/android:dom_distiller_core_java",
 661     "//components/web_contents_delegate_android:web_contents_delegate_android_java",
 662     "//content/public/android:content_java",
 663     "//content/public/test/android:content_java_test_support",
 664     "//net/android:net_java",
 665     "//net/android:net_java_test_support",
 666     "//sync/android:sync_java",
 667     "//sync:sync_java_test_support",
 668     "//third_party/android_tools:android_support_v7_appcompat_java",
 669     "//third_party/android_tools:android_support_v7_recyclerview_java",
 670     "//third_party/android_tools:android_support_v13_java",
 671     "//third_party/cacheinvalidation:cacheinvalidation_javalib",
 672     "//third_party/jsr-305:jsr_305_javalib",
 673     "//ui/android:ui_java",
 674   ]
 675 }
 676
 677 # GYP: //chrome/android/chrome_apk.gyp:staging_jni_headers
 678 generate_jni("staging_jni_headers") {
 679   jni_package = "staging/android"
 680   gypi_values = exec_script("//build/gypi_to_gn.py",
 681                             [
 682                               rebase_path("chrome_apk.gyp"),
 683                               "--replace=<(chrome_java_dir)=java_staging",
 684                             ],
 685                             "scope",
 686                             [ "chrome_apk.gyp" ])
 687   sources = gypi_values.chrome_staging_jni_files
 688 }
 689
 690 # GYP: //chrome/android/chrome_apk.gyp:libchrome_staging
 691 static_library("chrome_staging") {
 692   deps = [
 693     ":staging_jni_headers",
 694     "//chrome/browser",
 695     "//chrome:strings",
 696     "//components/enhanced_bookmarks",
 697     "//components/metrics/proto",
 698     "//third_party/leveldatabase",
 699   ]
 700
 701   gypi_values = exec_script(
 702           "//build/gypi_to_gn.py",
 703           [
 704             rebase_path("chrome_apk.gyp"),
 705             "--replace=<(chrome_native_sources_dir)=../browser/android/",
 706           ],
 707           "scope",
 708           [ "chrome_apk.gyp" ])
 709   sources = gypi_values.chrome_staging_native_sources
 710
 711   if (safe_browsing_mode != 0) {
 712     sources += [
 713       "../browser/android/spdy_proxy_resource_throttle.cc",
 714       "../browser/android/spdy_proxy_resource_throttle.h",
 715     ]
 716   }
 717
 718   libs = [
 719     "android",
 720     "jnigraphics",
 721   ]
 722
 723   defines = []
 724 }
 725
 726 chrome_public_apk_assets_dir = "$root_build_dir/chrome_public_apk_assets"
 727
 728 chrome_android_paks_gypi =
 729     exec_script("//build/gypi_to_gn.py",
 730                 [ rebase_path("//chrome/chrome_android_paks.gypi") ],
 731                 "scope",
 732                 [ "//chrome/chrome_android_paks.gypi" ])
 733
 734 copy_ex("chrome_public_apk_assets") {
 735   clear_dir = true
 736   dest = chrome_public_apk_assets_dir
 737   gypi_sources = chrome_android_paks_gypi.chrome_android_pak_input_resources
 738   cleaned_sources = rebase_path(gypi_sources, "<(PRODUCT_DIR)")
 739   sources = rebase_path(cleaned_sources, ".", root_out_dir)
 740   if (icu_use_data_file) {
 741     sources += [ "$root_build_dir/icudtl.dat" ]
 742   }
 743   deps = [
 744     "//chrome:packed_extra_resources",
 745     "//chrome:packed_resources",
 746     "//third_party/icu:icudata",
 747   ]
 748
 749   if (v8_use_external_startup_data) {
 750     sources += [
 751       "$root_build_dir/natives_blob.bin",
 752       "$root_build_dir/snapshot_blob.bin",
 753     ]
 754     deps += [ "//v8" ]
 755   }
 756
 757   sources += [ "$root_build_dir/resources.pak" ]
 758 }
 759
 760 # GYP: //chrome/android/chrome_apk.gyp:chrome_apk_manifest
 761 jinja_template("chrome_public_apk_manifest") {
 762   input = "java_staging/AndroidManifest.xml"
 763   output = "$root_gen_dir/chrome_public_apk_manifest/AndroidManifest.xml"
 764   variables = jinja_variables + [ "min_sdk_version=16" ]
 765 }
 766
 767 # GYP: //chrome/android/chrome_apk.gyp:libchrome_public
 768 shared_library("chrome_public") {
 769   deps = [
 770     "//chrome/android:chrome_staging",
 771     "//chrome:chrome_android_core",
 772   ]
 773   gypi_values = exec_script(
 774           "//build/gypi_to_gn.py",
 775           [
 776             rebase_path("chrome_apk.gyp"),
 777             "--replace=<(chrome_native_sources_dir)=../browser/android/",
 778           ],
 779           "scope",
 780           [ "chrome_apk.gyp" ])
 781   sources = gypi_values.chrome_public_app_native_sources
 782
 783   # TODO(GYP):
 784   #'target_conditions': [
 785   #['component != "shared_library"', {
 786   #'product_extension': '<(version_libchrome_short).so',
 787   #}],
 788   #],
 789 }
 790
 791 android_apk("chrome_public_apk") {
 792   version_name = "Developer Build"
 793   version_code = "1"
 794   android_manifest = get_target_outputs(":chrome_public_apk_manifest")
 795   android_manifest = android_manifest[1]
 796   apk_name = "ChromePublic"
 797   native_libs = [ "$root_build_dir/lib.stripped/libchrome_public.so" ]
 798   native_lib_version_name = _version_full
 799   asset_location = chrome_public_apk_assets_dir
 800
 801   deps = [
 802     ":chrome_staging_java",
 803     ":chrome_staging_java_resources",
 804     ":chrome_public",
 805     ":chrome_public_apk_assets",
 806     ":chrome_public_apk_manifest",
 807     "//base:base_java",
 808     "//third_party/android_tools:google_play_services_default_resources",
 809   ]
 810 }
 811
 812 chrome_public_test_apk_manifest =
 813     "$root_gen_dir/chrome_public_test_apk_manifest/AndroidManifest.xml"
 814
 815 # GYP: //chrome/android/chrome_apk.gyp:chrome_public_test_apk_manifest
 816 jinja_template("chrome_public_test_apk_manifest") {
 817   input = "javatests/AndroidManifest.xml"
 818   output = chrome_public_test_apk_manifest
 819   variables = jinja_variables
 820 }
 821
 822 # GYP: //chrome/android/chrome_apk.gyp:chrome_public_test_apk
 823 instrumentation_test_apk("chrome_public_test_apk") {
 824   # TODO(GYP,cjhopman): Does this need version code/name?
 825   apk_name = "ChromePublicTest"
 826   apk_under_test = ":chrome_public_apk"
 827   android_manifest = chrome_public_test_apk_manifest
 828   deps = [
 829     ":chrome_public_test_apk_manifest",
 830     "//chrome/test/android:chrome_staging_test_support_java",
 831     "//chrome/android:chrome_staging_test_java",
 832   ]
 833   isolate_file = "../chrome_public_test_apk.isolate"
 834 }