net/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/crypto.gni")
   6 import("//build/config/features.gni")
   7 import("//build/config/ui.gni")
   8 import("//url/config.gni")
   9
  10 # TODO(cjhopman): //build/config/android/rules.gni also imports grit_rule.gni.
  11 # Currently, that file can't be imported multiple times.  Make this always
  12 # imported when http://crbug.com/393704 is fixed.
  13 if (!is_android) {
  14   import("//tools/grit/grit_rule.gni")
  15 }
  16
  17 if (is_android) {
  18   import("//build/config/android/config.gni")
  19   import("//build/config/android/rules.gni")
  20 } else if (is_mac) {
  21   import("//build/config/mac/mac_sdk.gni")
  22 }
  23
  24 # The list of net files is kept in net.gypi. Read it.
  25 gypi_values = exec_script(
  26     "//build/gypi_to_gn.py",
  27     [ rebase_path("net.gypi") ],
  28     "scope",
  29     [ "net.gypi" ])
  30
  31 # Disable Kerberos on ChromeOS, Android and iOS, at least for now. It needs
  32 # configuration (krb5.conf and so on).
  33 use_kerberos = !is_chromeos && !is_android && !is_ios
  34
  35 # The way the cache uses mmap() is inefficient on some Android devices. If
  36 # this flag is set, we hackily avoid using mmap() in the disk cache. We are
  37 # pretty confident that mmap-ing the index would not hurt any existing x86
  38 # android devices, but we cannot be so sure about the variety of ARM devices.
  39 # So enable it for x86 only for now.
  40 posix_avoid_mmap = is_android && cpu_arch != "x86"
  41
  42 # WebSockets and socket stream code are used everywhere except iOS.
  43 enable_websockets = !is_ios
  44 use_v8_in_net = !is_ios
  45 enable_built_in_dns = !is_ios
  46 disable_ftp_support = is_ios
  47
  48 declare_args() {
  49   # Disables support for file URLs.  File URL support requires use of icu.
  50   disable_file_support = false
  51 }
  52
  53 config("net_config") {
  54   defines = []
  55   if (posix_avoid_mmap) {
  56     defines += [ "POSIX_AVOID_MMAP" ]
  57   }
  58   if (disable_file_support) {
  59     defines += [ "DISABLE_FILE_SUPPORT" ]
  60   }
  61 }
  62
  63 # Disables Windows warning about size to int truncations.
  64 # TODO(jschuh): crbug.com/167187 fix this and delete this config.
  65 config("net_win_size_truncation") {
  66   if (is_win) {
  67     cflags = [ "/wd4267" ]
  68   }
  69 }
  70
  71 component("net") {
  72   sources =
  73     gypi_values.net_nacl_common_sources +
  74     gypi_values.net_non_nacl_sources
  75
  76   cflags = []
  77   defines = [
  78     # TODO(GYP) Note that he GYP file supports linux_link_kerberos (defaults to
  79     # 0) which implies that we run pkg_config on kerberos and link to that
  80     # rather than setting this define which will dynamically open it. That
  81     # doesn't seem to be set in the regular builds, so we're skipping this
  82     # capability here.
  83     "DLOPEN_KERBEROS",
  84     "NET_IMPLEMENTATION"
  85   ]
  86   configs += [ ":net_win_size_truncation" ]
  87   direct_dependent_configs = [ ":net_config" ]
  88   include_dirs = []
  89
  90   deps = [
  91    ":net_resources",
  92     "//base",
  93     "//base:i18n",
  94     "//base:prefs",
  95     "//base/third_party/dynamic_annotations",
  96     "//crypto",
  97     "//crypto:platform",
  98     "//net/base/registry_controlled_domains",
  99     "//sdch",
 100     "//third_party/icu",
 101     "//third_party/zlib",
 102     "//url",
 103   ]
 104   forward_dependent_configs_from = [
 105     "//crypto",
 106     "//crypto:platform"
 107   ]
 108
 109   if (use_kerberos) {
 110     defines += [ "USE_KERBEROS" ]
 111     if (is_android) {
 112       include_dirs += [ "/usr/include/kerberosV" ]
 113     }
 114   } else {
 115     sources -= [
 116       "http/http_auth_gssapi_posix.cc",
 117       "http/http_auth_gssapi_posix.h",
 118       "http/http_auth_handler_negotiate.h",
 119       "http/http_auth_handler_negotiate.cc",
 120     ]
 121   }
 122
 123   if (is_posix) {
 124     if (posix_avoid_mmap) {
 125       sources -= [ "disk_cache/blockfile/mapped_file_posix.cc" ]
 126     } else {
 127       sources -= [ "disk_cache/blockfile/mapped_file_avoid_mmap_posix.cc" ]
 128     }
 129   }
 130
 131   if (disable_file_support) {
 132     sources -= [
 133       "base/directory_lister.cc",
 134       "base/directory_lister.h",
 135       "url_request/url_request_file_dir_job.cc",
 136       "url_request/url_request_file_dir_job.h",
 137       "url_request/url_request_file_job.cc",
 138       "url_request/url_request_file_job.h",
 139       "url_request/file_protocol_handler.cc",
 140       "url_request/file_protocol_handler.h",
 141     ]
 142   }
 143
 144   if (disable_ftp_support) {
 145     sources -= [
 146       "ftp/ftp_auth_cache.cc",
 147       "ftp/ftp_auth_cache.h",
 148       "ftp/ftp_ctrl_response_buffer.cc",
 149       "ftp/ftp_ctrl_response_buffer.h",
 150       "ftp/ftp_directory_listing_parser.cc",
 151       "ftp/ftp_directory_listing_parser.h",
 152       "ftp/ftp_directory_listing_parser_ls.cc",
 153       "ftp/ftp_directory_listing_parser_ls.h",
 154       "ftp/ftp_directory_listing_parser_netware.cc",
 155       "ftp/ftp_directory_listing_parser_netware.h",
 156       "ftp/ftp_directory_listing_parser_os2.cc",
 157       "ftp/ftp_directory_listing_parser_os2.h",
 158       "ftp/ftp_directory_listing_parser_vms.cc",
 159       "ftp/ftp_directory_listing_parser_vms.h",
 160       "ftp/ftp_directory_listing_parser_windows.cc",
 161       "ftp/ftp_directory_listing_parser_windows.h",
 162       "ftp/ftp_network_layer.cc",
 163       "ftp/ftp_network_layer.h",
 164       "ftp/ftp_network_session.cc",
 165       "ftp/ftp_network_session.h",
 166       "ftp/ftp_network_transaction.cc",
 167       "ftp/ftp_network_transaction.h",
 168       "ftp/ftp_request_info.h",
 169       "ftp/ftp_response_info.cc",
 170       "ftp/ftp_response_info.h",
 171       "ftp/ftp_server_type_histograms.cc",
 172       "ftp/ftp_server_type_histograms.h",
 173       "ftp/ftp_transaction.h",
 174       "ftp/ftp_transaction_factory.h",
 175       "ftp/ftp_util.cc",
 176       "ftp/ftp_util.h",
 177       "url_request/ftp_protocol_handler.cc",
 178       "url_request/ftp_protocol_handler.h",
 179       "url_request/url_request_ftp_job.cc",
 180       "url_request/url_request_ftp_job.h",
 181     ]
 182   }
 183
 184   if (enable_built_in_dns) {
 185     defines += [ "ENABLE_BUILT_IN_DNS" ]
 186   } else {
 187     sources -= [
 188       "dns/address_sorter_posix.cc",
 189       "dns/address_sorter_posix.h",
 190       "dns/dns_client.cc",
 191     ]
 192   }
 193
 194   if (use_openssl) {
 195     sources -= [
 196       "base/nss_memio.c",
 197       "base/nss_memio.h",
 198       "cert/ct_log_verifier_nss.cc",
 199       "cert/ct_objects_extractor_nss.cc",
 200       "cert/jwk_serializer_nss.cc",
 201       "cert/scoped_nss_types.h",
 202       "cert/x509_util_nss.cc",
 203       "cert/x509_util_nss.h",
 204       "quic/crypto/aead_base_decrypter_nss.cc",
 205       "quic/crypto/aead_base_encrypter_nss.cc",
 206       "quic/crypto/aes_128_gcm_12_decrypter_nss.cc",
 207       "quic/crypto/aes_128_gcm_12_encrypter_nss.cc",
 208       "quic/crypto/chacha20_poly1305_decrypter_nss.cc",
 209       "quic/crypto/chacha20_poly1305_encrypter_nss.cc",
 210       "quic/crypto/channel_id_nss.cc",
 211       "quic/crypto/p256_key_exchange_nss.cc",
 212       "socket/nss_ssl_util.cc",
 213       "socket/nss_ssl_util.h",
 214       "socket/ssl_client_socket_nss.cc",
 215       "socket/ssl_client_socket_nss.h",
 216       "socket/ssl_server_socket_nss.cc",
 217       "socket/ssl_server_socket_nss.h",
 218     ]
 219     if (is_chromeos) {
 220       sources -= [
 221         "cert/nss_cert_database_chromeos.cc",
 222         "cert/nss_cert_database_chromeos.h",
 223         "cert/nss_profile_filter_chromeos.cc",
 224         "cert/nss_profile_filter_chromeos.h",
 225       ]
 226     }
 227     if (is_linux) {
 228       # These are always removed for non-Linux cases below.
 229       sources -= [
 230         "base/crypto_module_nss.cc",
 231         "base/keygen_handler_nss.cc",
 232         "cert/cert_database_nss.cc",
 233         "cert/nss_cert_database.cc",
 234         "cert/nss_cert_database.h",
 235         "cert/x509_certificate_nss.cc",
 236         "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 237         "third_party/mozilla_security_manager/nsKeygenHandler.h",
 238         "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 239         "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 240         "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 241         "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 242       ]
 243     }
 244     if (is_ios) {
 245       # Always removed for !ios below.
 246       sources -= [
 247         "cert/cert_verify_proc_nss.cc",
 248         "cert/cert_verify_proc_nss.h",
 249         "cert/test_root_certs_nss.cc",
 250         "ocsp/nss_ocsp.cc",
 251         "ocsp/nss_ocsp.h",
 252       ]
 253     }
 254   } else {
 255     sources -= [
 256       "base/crypto_module_openssl.cc",
 257       "base/keygen_handler_openssl.cc",
 258       "cert/ct_log_verifier_openssl.cc",
 259       "cert/ct_objects_extractor_openssl.cc",
 260       "cert/jwk_serializer_openssl.cc",
 261       "cert/x509_util_openssl.cc",
 262       "cert/x509_util_openssl.h",
 263       "quic/crypto/aead_base_decrypter_openssl.cc",
 264       "quic/crypto/aead_base_encrypter_openssl.cc",
 265       "quic/crypto/aes_128_gcm_12_decrypter_openssl.cc",
 266       "quic/crypto/aes_128_gcm_12_encrypter_openssl.cc",
 267       "quic/crypto/chacha20_poly1305_decrypter_openssl.cc",
 268       "quic/crypto/chacha20_poly1305_encrypter_openssl.cc",
 269       "quic/crypto/channel_id_openssl.cc",
 270       "quic/crypto/p256_key_exchange_openssl.cc",
 271       "quic/crypto/scoped_evp_aead_ctx.cc",
 272       "quic/crypto/scoped_evp_aead_ctx.h",
 273       "socket/openssl_ssl_util.cc",
 274       "socket/openssl_ssl_util.h",
 275       "socket/ssl_client_socket_openssl.cc",
 276       "socket/ssl_client_socket_openssl.h",
 277       "socket/ssl_server_socket_openssl.cc",
 278       "socket/ssl_server_socket_openssl.h",
 279       "socket/ssl_session_cache_openssl.cc",
 280       "socket/ssl_session_cache_openssl.h",
 281     ]
 282   }
 283
 284   if (!use_openssl_certs) {
 285     sources -= [
 286       "base/openssl_private_key_store.h",
 287       "base/openssl_private_key_store_memory.cc",
 288       "cert/cert_database_openssl.cc",
 289       "cert/cert_verify_proc_openssl.cc",
 290       "cert/cert_verify_proc_openssl.h",
 291       "cert/test_root_certs_openssl.cc",
 292       "cert/x509_certificate_openssl.cc",
 293       "ssl/openssl_client_key_store.cc",
 294       "ssl/openssl_client_key_store.h",
 295     ]
 296     if (is_android) {
 297       sources -= [
 298         "base/openssl_private_key_store_android.cc",
 299       ]
 300     }
 301   } else if (is_android) {
 302     # Android doesn't use these even when using OpenSSL.
 303     sources -= [
 304       "base/openssl_private_key_store_memory.cc",
 305       "cert/cert_database_openssl.cc",
 306       "cert/cert_verify_proc_openssl.cc",
 307       "cert/test_root_certs_openssl.cc",
 308     ]
 309   }
 310
 311   if (use_glib) {
 312     configs += [ "//build/config/linux:gconf" ]
 313     deps += [ "//build/config/linux:gio" ]
 314   }
 315
 316   if (is_linux) {
 317     configs += [ "//build/config/linux:libresolv" ]
 318   } else {
 319     sources -= [
 320       "base/crypto_module_nss.cc",
 321       "base/keygen_handler_nss.cc",
 322       "cert/cert_database_nss.cc",
 323       "cert/nss_cert_database.cc",
 324       "cert/nss_cert_database.h",
 325       "cert/x509_certificate_nss.cc",
 326       "third_party/mozilla_security_manager/nsKeygenHandler.cpp",
 327       "third_party/mozilla_security_manager/nsKeygenHandler.h",
 328       "third_party/mozilla_security_manager/nsNSSCertificateDB.cpp",
 329       "third_party/mozilla_security_manager/nsNSSCertificateDB.h",
 330       "third_party/mozilla_security_manager/nsPKCS12Blob.cpp",
 331       "third_party/mozilla_security_manager/nsPKCS12Blob.h",
 332     ]
 333
 334     if (!is_ios) {
 335       # These files are part of the partial implementation of NSS on iOS so
 336       # keep them in that case.
 337       sources -= [
 338         "cert/test_root_certs_nss.cc",
 339         "ocsp/nss_ocsp.cc",
 340         "ocsp/nss_ocsp.h",
 341       ]
 342     }
 343   }
 344
 345   if (!use_nss_certs) {
 346     sources -= [
 347       "ssl/client_cert_store_nss.cc",
 348       "ssl/client_cert_store_nss.h",
 349     ]
 350     if (!is_ios) {
 351       # These files are part of the partial implementation of NSS on iOS so
 352       # keep them in that case (even though use_nss_certs is not set).
 353       sources -= [
 354         "cert/cert_verify_proc_nss.cc",
 355         "cert/cert_verify_proc_nss.h",
 356       ]
 357     }
 358     if (is_chromeos) {
 359       # These were already removed on non-ChromeOS.
 360       sources -= [
 361         "ssl/client_cert_store_chromeos.cc",
 362         "ssl/client_cert_store_chromeos.h",
 363       ]
 364     }
 365   }
 366
 367   if (!enable_websockets) {
 368     sources -= [
 369       "socket_stream/socket_stream.cc",
 370       "socket_stream/socket_stream.h",
 371       "socket_stream/socket_stream_job.cc",
 372       "socket_stream/socket_stream_job.h",
 373       "socket_stream/socket_stream_job_manager.cc",
 374       "socket_stream/socket_stream_job_manager.h",
 375       "socket_stream/socket_stream_metrics.cc",
 376       "socket_stream/socket_stream_metrics.h",
 377       "spdy/spdy_websocket_stream.cc",
 378       "spdy/spdy_websocket_stream.h",
 379       "websockets/websocket_basic_handshake_stream.cc",
 380       "websockets/websocket_basic_handshake_stream.h",
 381       "websockets/websocket_basic_stream.cc",
 382       "websockets/websocket_basic_stream.h",
 383       "websockets/websocket_channel.cc",
 384       "websockets/websocket_channel.h",
 385       "websockets/websocket_deflate_predictor.h",
 386       "websockets/websocket_deflate_predictor_impl.cc",
 387       "websockets/websocket_deflate_predictor_impl.h",
 388       "websockets/websocket_deflate_stream.cc",
 389       "websockets/websocket_deflate_stream.h",
 390       "websockets/websocket_deflater.cc",
 391       "websockets/websocket_deflater.h",
 392       "websockets/websocket_errors.cc",
 393       "websockets/websocket_errors.h",
 394       "websockets/websocket_extension.cc",
 395       "websockets/websocket_extension.h",
 396       "websockets/websocket_extension_parser.cc",
 397       "websockets/websocket_extension_parser.h",
 398       "websockets/websocket_frame.cc",
 399       "websockets/websocket_frame.h",
 400       "websockets/websocket_frame_parser.cc",
 401       "websockets/websocket_frame_parser.h",
 402       "websockets/websocket_handshake_constants.cc",
 403       "websockets/websocket_handshake_constants.h",
 404       "websockets/websocket_handshake_handler.cc",
 405       "websockets/websocket_handshake_handler.h",
 406       "websockets/websocket_handshake_request_info.cc",
 407       "websockets/websocket_handshake_request_info.h",
 408       "websockets/websocket_handshake_response_info.cc",
 409       "websockets/websocket_handshake_response_info.h",
 410       "websockets/websocket_handshake_stream_base.h",
 411       "websockets/websocket_handshake_stream_create_helper.cc",
 412       "websockets/websocket_handshake_stream_create_helper.h",
 413       "websockets/websocket_inflater.cc",
 414       "websockets/websocket_inflater.h",
 415       "websockets/websocket_job.cc",
 416       "websockets/websocket_job.h",
 417       "websockets/websocket_mux.h",
 418       "websockets/websocket_net_log_params.cc",
 419       "websockets/websocket_net_log_params.h",
 420       "websockets/websocket_stream.cc",
 421       "websockets/websocket_stream.h",
 422       "websockets/websocket_throttle.cc",
 423       "websockets/websocket_throttle.h",
 424     ]
 425   }
 426
 427   if (!enable_mdns) {
 428     sources -= [
 429       "dns/mdns_cache.cc",
 430       "dns/mdns_cache.h",
 431       "dns/mdns_client.cc",
 432       "dns/mdns_client.h",
 433       "dns/mdns_client_impl.cc",
 434       "dns/mdns_client_impl.h",
 435       "dns/record_parsed.cc",
 436       "dns/record_parsed.h",
 437       "dns/record_rdata.cc",
 438       "dns/record_rdata.h",
 439     ]
 440   }
 441
 442   if (is_win) {
 443     sources -= [
 444       "http/http_auth_handler_ntlm_portable.cc",
 445       "socket/socket_libevent.cc",
 446       "socket/socket_libevent.h",
 447       "socket/tcp_socket_libevent.cc",
 448       "socket/tcp_socket_libevent.h",
 449       "udp/udp_socket_libevent.cc",
 450       "udp/udp_socket_libevent.h",
 451     ]
 452     deps += [
 453       "//third_party/nss:nspr",
 454       "//third_party/nss",
 455     ]
 456   } else {  # !is_win
 457     sources -= [
 458       "base/winsock_init.cc",
 459       "base/winsock_init.h",
 460       "base/winsock_util.cc",
 461       "base/winsock_util.h",
 462       "proxy/proxy_resolver_winhttp.cc",
 463       "proxy/proxy_resolver_winhttp.h",
 464     ]
 465   }
 466
 467   if (is_mac) {
 468     deps += [
 469       "//third_party/nss:nspr",
 470       "//third_party/nss",
 471     ]
 472     libs = [
 473       "Foundation.framework",
 474       "Security.framework",
 475       "SystemConfiguration.framework",
 476       "resolv",
 477     ]
 478   }
 479
 480   if (is_ios) {
 481     # Add back some sources that were otherwise filtered out. iOS additionally
 482     # doesn't set USE_NSS but needs some of the files.
 483     set_sources_assignment_filter([])
 484     sources += [
 485       "base/network_change_notifier_mac.cc",
 486       "base/network_config_watcher_mac.cc",
 487       "base/platform_mime_util_mac.mm",
 488       "cert/cert_verify_proc_nss.cc",
 489       "cert/cert_verify_proc_nss.h",
 490       "cert/test_root_certs_nss.cc",
 491       "cert/x509_util_nss.cc",
 492       "cert/x509_util_nss.h",
 493       "proxy/proxy_resolver_mac.cc",
 494       "proxy/proxy_server_mac.cc",
 495       "ocsp/nss_ocsp.cc",
 496       "ocsp/nss_ocsp.h",
 497     ]
 498     set_sources_assignment_filter(sources_assignment_filter)
 499
 500     sources -= [ "disk_cache/blockfile/file_posix.cc" ]
 501     deps += [
 502       "//third_party/nss",
 503     ]
 504     libs = [
 505       "CFNetwork.framework",
 506       "MobileCoreServices.framework",
 507       "Security.framework",
 508       "SystemConfiguration.framework",
 509       "resolv",
 510     ]
 511   }
 512
 513   if (is_android) {
 514     # Add some Linux sources that were excluded by the filter, but which
 515     # are needed.
 516     set_sources_assignment_filter([])
 517     sources += [
 518       "base/platform_mime_util_linux.cc",
 519       "base/address_tracker_linux.cc",
 520       "base/address_tracker_linux.h",
 521     ]
 522     set_sources_assignment_filter(sources_assignment_filter)
 523
 524     if (!is_android_webview_build) {
 525       deps += [ ":net_jni_headers" ]
 526     }
 527   }
 528
 529   if (use_icu_alternatives_on_android) {
 530     deps -= [
 531       "//base:i18n",
 532       "//third_party/icu",
 533     ]
 534     sources -= [
 535       "base/filename_util_icu.cc",
 536       "base/net_string_util_icu.cc",
 537       "base/net_util_icu.cc",
 538     ]
 539     sources += [
 540       "base/net_string_util_icu_alternatives_android.cc",
 541       "base/net_string_util_icu_alternatives_android.h",
 542     ]
 543   }
 544 }
 545
 546 grit("net_resources") {
 547   source = "base/net_resources.grd"
 548   outputs = [
 549     "grit/net_resources.h",
 550     "net_resources.pak",
 551     "net_resources.rc",
 552   ]
 553 }
 554
 555 static_library("http_server") {
 556   sources = [
 557     "server/http_connection.cc",
 558     "server/http_connection.h",
 559     "server/http_server.cc",
 560     "server/http_server.h",
 561     "server/http_server_request_info.cc",
 562     "server/http_server_request_info.h",
 563     "server/http_server_response_info.cc",
 564     "server/http_server_response_info.h",
 565     "server/web_socket.cc",
 566     "server/web_socket.h",
 567   ]
 568   configs += [ "//build/config/compiler:wexit_time_destructors" ]
 569   deps = [
 570     ":net",
 571     "//base",
 572   ]
 573 }
 574
 575 executable("dump_cache") {
 576   sources = [
 577     "tools/dump_cache/cache_dumper.cc",
 578     "tools/dump_cache/cache_dumper.h",
 579     "tools/dump_cache/dump_cache.cc",
 580     "tools/dump_cache/dump_files.cc",
 581     "tools/dump_cache/dump_files.h",
 582     "tools/dump_cache/simple_cache_dumper.cc",
 583     "tools/dump_cache/simple_cache_dumper.h",
 584     "tools/dump_cache/upgrade_win.cc",
 585     "tools/dump_cache/upgrade_win.h",
 586     "tools/dump_cache/url_to_filename_encoder.cc",
 587     "tools/dump_cache/url_to_filename_encoder.h",
 588     "tools/dump_cache/url_utilities.h",
 589     "tools/dump_cache/url_utilities.cc",
 590   ]
 591
 592   configs += [ ":net_win_size_truncation" ]
 593
 594   deps = [
 595     "//base",
 596     ":net",
 597     ":test_support",
 598   ]
 599 }
 600
 601 source_set("test_support") {
 602   sources = [
 603     "base/capturing_net_log.cc",
 604     "base/capturing_net_log.h",
 605     "base/load_timing_info_test_util.cc",
 606     "base/load_timing_info_test_util.h",
 607     "base/mock_file_stream.cc",
 608     "base/mock_file_stream.h",
 609     "base/test_completion_callback.cc",
 610     "base/test_completion_callback.h",
 611     "base/test_data_directory.cc",
 612     "base/test_data_directory.h",
 613     "cert/mock_cert_verifier.cc",
 614     "cert/mock_cert_verifier.h",
 615     "cookies/cookie_monster_store_test.cc",
 616     "cookies/cookie_monster_store_test.h",
 617     "cookies/cookie_store_test_callbacks.cc",
 618     "cookies/cookie_store_test_callbacks.h",
 619     "cookies/cookie_store_test_helpers.cc",
 620     "cookies/cookie_store_test_helpers.h",
 621     "disk_cache/disk_cache_test_base.cc",
 622     "disk_cache/disk_cache_test_base.h",
 623     "disk_cache/disk_cache_test_util.cc",
 624     "disk_cache/disk_cache_test_util.h",
 625     "dns/dns_test_util.cc",
 626     "dns/dns_test_util.h",
 627     "dns/mock_host_resolver.cc",
 628     "dns/mock_host_resolver.h",
 629     "dns/mock_mdns_socket_factory.cc",
 630     "dns/mock_mdns_socket_factory.h",
 631     "http/http_transaction_test_util.cc",
 632     "http/http_transaction_test_util.h",
 633     "proxy/mock_proxy_resolver.cc",
 634     "proxy/mock_proxy_resolver.h",
 635     "proxy/mock_proxy_script_fetcher.cc",
 636     "proxy/mock_proxy_script_fetcher.h",
 637     "proxy/proxy_config_service_common_unittest.cc",
 638     "proxy/proxy_config_service_common_unittest.h",
 639     "socket/socket_test_util.cc",
 640     "socket/socket_test_util.h",
 641     "test/cert_test_util.cc",
 642     "test/cert_test_util.h",
 643     "test/cert_test_util_nss.cc",
 644     "test/ct_test_util.cc",
 645     "test/ct_test_util.h",
 646     "test/embedded_test_server/embedded_test_server.cc",
 647     "test/embedded_test_server/embedded_test_server.h",
 648     "test/embedded_test_server/http_connection.cc",
 649     "test/embedded_test_server/http_connection.h",
 650     "test/embedded_test_server/http_request.cc",
 651     "test/embedded_test_server/http_request.h",
 652     "test/embedded_test_server/http_response.cc",
 653     "test/embedded_test_server/http_response.h",
 654     "test/net_test_suite.cc",
 655     "test/net_test_suite.h",
 656     "test/python_utils.cc",
 657     "test/python_utils.h",
 658     "test/spawned_test_server/base_test_server.cc",
 659     "test/spawned_test_server/base_test_server.h",
 660     "test/spawned_test_server/local_test_server_posix.cc",
 661     "test/spawned_test_server/local_test_server_win.cc",
 662     "test/spawned_test_server/local_test_server.cc",
 663     "test/spawned_test_server/local_test_server.h",
 664     "test/spawned_test_server/remote_test_server.cc",
 665     "test/spawned_test_server/remote_test_server.h",
 666     "test/spawned_test_server/spawned_test_server.h",
 667     "test/spawned_test_server/spawner_communicator.cc",
 668     "test/spawned_test_server/spawner_communicator.h",
 669     "url_request/test_url_fetcher_factory.cc",
 670     "url_request/test_url_fetcher_factory.h",
 671     "url_request/url_request_test_util.cc",
 672     "url_request/url_request_test_util.h",
 673   ]
 674
 675   configs += [ ":net_win_size_truncation" ]
 676
 677   deps = [
 678     "//base",
 679     "//base/test:test_support",
 680     "//crypto:platform",
 681     "//net",
 682     "//net/tools/tld_cleanup",
 683     "//testing/gmock",
 684     "//testing/gtest",
 685     "//url",
 686   ]
 687
 688   if (is_ios) {
 689     deps += [ "//third_party/nss" ]
 690   }
 691
 692   if (!is_android) {
 693     sources -= [
 694       "test/spawned_test_server/remote_test_server.cc",
 695       "test/spawned_test_server/remote_test_server.h",
 696       "test/spawned_test_server/spawner_communicator.cc",
 697       "test/spawned_test_server/spawner_communicator.h",
 698     ]
 699   }
 700
 701   if (use_v8_in_net) {
 702     deps += [ ":net_with_v8" ]
 703   }
 704
 705   if (!enable_mdns) {
 706     sources -= [
 707       "dns/mock_mdns_socket_factory.cc",
 708       "dns/mock_mdns_socket_factory.h",
 709     ]
 710   }
 711
 712   if (!use_nss_certs) {
 713     sources -= [
 714       "test/cert_test_util_nss.cc",
 715     ]
 716   }
 717
 718   forward_dependent_configs_from = deps
 719 }
 720
 721 source_set("balsa") {
 722   sources = [
 723     "tools/balsa/balsa_enums.h",
 724     "tools/balsa/balsa_frame.cc",
 725     "tools/balsa/balsa_frame.h",
 726     "tools/balsa/balsa_headers.cc",
 727     "tools/balsa/balsa_headers.h",
 728     "tools/balsa/balsa_headers_token_utils.cc",
 729     "tools/balsa/balsa_headers_token_utils.h",
 730     "tools/balsa/balsa_visitor_interface.h",
 731     "tools/balsa/http_message_constants.cc",
 732     "tools/balsa/http_message_constants.h",
 733     "tools/balsa/noop_balsa_visitor.h",
 734     "tools/balsa/simple_buffer.cc",
 735     "tools/balsa/simple_buffer.h",
 736     "tools/balsa/split.cc",
 737     "tools/balsa/split.h",
 738     "tools/balsa/string_piece_utils.h",
 739     "tools/quic/spdy_utils.cc",
 740     "tools/quic/spdy_utils.h",
 741   ]
 742   deps = [
 743     ":net",
 744     "//base",
 745   ]
 746 }
 747
 748 if (use_v8_in_net) {
 749   component("net_with_v8") {
 750     sources = [
 751       "proxy/proxy_resolver_v8.cc",
 752       "proxy/proxy_resolver_v8.h",
 753       "proxy/proxy_resolver_v8_tracing.cc",
 754       "proxy/proxy_resolver_v8_tracing.h",
 755       "proxy/proxy_service_v8.cc",
 756       "proxy/proxy_service_v8.h",
 757     ]
 758
 759     defines = [ "NET_IMPLEMENTATION" ]
 760     configs += [
 761       ":net_win_size_truncation",
 762       "//build/config/compiler:wexit_time_destructors",
 763     ]
 764
 765     deps = [
 766       ":net",
 767       "//base",
 768       "//gin",
 769       "//url",
 770       "//v8",
 771     ]
 772
 773     forward_dependent_configs_from = [ ":net" ]
 774   }
 775 }
 776
 777 if (!is_ios && !is_android) {
 778   executable("crash_cache") {
 779     sources = [ "tools/crash_cache/crash_cache.cc" ]
 780     configs += [ ":net_win_size_truncation" ]
 781     deps = [
 782       ":net",
 783       ":test_support",
 784       "//base",
 785     ]
 786   }
 787
 788   executable("crl_set_dump") {
 789     sources = [ "tools/crl_set_dump/crl_set_dump.cc" ]
 790     configs += [ ":net_win_size_truncation" ]
 791     deps = [
 792       ":net",
 793       "//base",
 794     ]
 795   }
 796
 797   executable("dns_fuzz_stub") {
 798     sources = [ "tools/dns_fuzz_stub/dns_fuzz_stub.cc" ]
 799     configs += [ ":net_win_size_truncation" ]
 800     deps = [
 801       ":net",
 802       "//base",
 803     ]
 804   }
 805
 806   executable("gdig") {
 807     sources = [
 808       "tools/gdig/file_net_log.cc",
 809       "tools/gdig/gdig.cc",
 810     ]
 811     deps = [
 812       ":net",
 813       "//base",
 814     ]
 815   }
 816
 817   executable("get_server_time") {
 818     sources = [ "tools/get_server_time/get_server_time.cc" ]
 819     configs += [ ":net_win_size_truncation" ]
 820     deps = [
 821       ":net",
 822       "//base",
 823       "//base:i18n",
 824       "//url",
 825     ]
 826   }
 827
 828   if (use_v8_in_net) {
 829     executable("net_watcher") {
 830       sources = [ "tools/net_watcher/net_watcher.cc" ]
 831       deps = [
 832         ":net",
 833         ":net_with_v8",
 834         "//base",
 835       ]
 836
 837       if (is_linux) {
 838         configs += [ "//build/config/linux:gconf" ]
 839         deps += [ "//build/config/linux:gio" ]
 840       }
 841     }
 842   }
 843
 844   executable("run_testserver") {
 845     sources = [ "tools/testserver/run_testserver.cc" ]
 846     deps = [
 847       ":net",  # TODO(brettw) bug 363749: this shouldn't be necessary. It's not
 848                # in the GYP build, and can be removed when the bug is fixed.
 849       ":test_support",
 850       "//base",
 851       "//base/test:test_support",
 852       "//testing/gtest",
 853     ]
 854   }
 855
 856   executable("stress_cache") {
 857     sources = [ "disk_cache/blockfile/stress_cache.cc" ]
 858     configs += [ ":net_win_size_truncation" ]
 859     deps = [
 860       ":net",
 861       ":test_support",
 862       "//base",
 863     ]
 864   }
 865
 866   executable("tld_cleanup") {
 867     sources = [ "tools/tld_cleanup/tld_cleanup.cc" ]
 868     configs += [ ":net_win_size_truncation" ]
 869     deps = [
 870       "//base",
 871       "//base:i18n",
 872       "//net/tools/tld_cleanup",
 873     ]
 874   }
 875 }
 876
 877 if (is_linux) {
 878   static_library("epoll_server") {
 879     sources = [
 880       "tools/epoll_server/epoll_server.cc",
 881       "tools/epoll_server/epoll_server.h",
 882     ]
 883     deps = [
 884       ":net",
 885       "//base",
 886     ]
 887   }
 888
 889   static_library("flip_in_mem_edsm_server_base") {
 890     sources = [
 891       "tools/dump_cache/url_to_filename_encoder.cc",
 892       "tools/dump_cache/url_to_filename_encoder.h",
 893       "tools/dump_cache/url_utilities.h",
 894       "tools/dump_cache/url_utilities.cc",
 895       "tools/flip_server/acceptor_thread.h",
 896       "tools/flip_server/acceptor_thread.cc",
 897       "tools/flip_server/create_listener.cc",
 898       "tools/flip_server/create_listener.h",
 899       "tools/flip_server/constants.h",
 900       "tools/flip_server/flip_config.cc",
 901       "tools/flip_server/flip_config.h",
 902       "tools/flip_server/http_interface.cc",
 903       "tools/flip_server/http_interface.h",
 904       "tools/flip_server/loadtime_measurement.h",
 905       "tools/flip_server/mem_cache.h",
 906       "tools/flip_server/mem_cache.cc",
 907       "tools/flip_server/output_ordering.cc",
 908       "tools/flip_server/output_ordering.h",
 909       "tools/flip_server/ring_buffer.cc",
 910       "tools/flip_server/ring_buffer.h",
 911       "tools/flip_server/sm_connection.cc",
 912       "tools/flip_server/sm_connection.h",
 913       "tools/flip_server/sm_interface.h",
 914       "tools/flip_server/spdy_ssl.cc",
 915       "tools/flip_server/spdy_ssl.h",
 916       "tools/flip_server/spdy_interface.cc",
 917       "tools/flip_server/spdy_interface.h",
 918       "tools/flip_server/spdy_util.cc",
 919       "tools/flip_server/spdy_util.h",
 920       "tools/flip_server/streamer_interface.cc",
 921       "tools/flip_server/streamer_interface.h",
 922     ]
 923     deps = [
 924       ":balsa",
 925       ":epoll_server",
 926       ":net",
 927       "//base",
 928       "//third_party/boringssl",
 929     ]
 930   }
 931
 932   executable("flip_in_mem_edsm_server_unittests") {
 933     sources = [
 934       "tools/flip_server/flip_test_utils.cc",
 935       "tools/flip_server/flip_test_utils.h",
 936       "tools/flip_server/http_interface_test.cc",
 937       "tools/flip_server/mem_cache_test.cc",
 938       "tools/flip_server/run_all_tests.cc",
 939       "tools/flip_server/spdy_interface_test.cc",
 940     ]
 941     deps = [
 942       ":flip_in_mem_edsm_server_base",
 943       ":net",
 944       ":test_support",
 945       "//testing/gtest",
 946       "//testing/gmock",
 947       "//third_party/boringssl",
 948     ]
 949   }
 950
 951   executable("flip_in_mem_edsm_server") {
 952     sources = [ "tools/flip_server/flip_in_mem_edsm_server.cc" ]
 953     deps = [
 954       ":flip_in_mem_edsm_server_base",
 955       ":net",
 956       "//base",
 957     ]
 958   }
 959
 960   source_set("quic_base") {
 961     sources = [
 962       "tools/quic/quic_client.cc",
 963       "tools/quic/quic_client.h",
 964       "tools/quic/quic_client_session.cc",
 965       "tools/quic/quic_client_session.h",
 966       "tools/quic/quic_default_packet_writer.cc",
 967       "tools/quic/quic_default_packet_writer.h",
 968       "tools/quic/quic_dispatcher.h",
 969       "tools/quic/quic_dispatcher.cc",
 970       "tools/quic/quic_epoll_clock.cc",
 971       "tools/quic/quic_epoll_clock.h",
 972       "tools/quic/quic_epoll_connection_helper.cc",
 973       "tools/quic/quic_epoll_connection_helper.h",
 974       "tools/quic/quic_in_memory_cache.cc",
 975       "tools/quic/quic_in_memory_cache.h",
 976       "tools/quic/quic_packet_writer_wrapper.cc",
 977       "tools/quic/quic_packet_writer_wrapper.h",
 978       "tools/quic/quic_server.cc",
 979       "tools/quic/quic_server.h",
 980       "tools/quic/quic_server_session.cc",
 981       "tools/quic/quic_server_session.h",
 982       "tools/quic/quic_socket_utils.cc",
 983       "tools/quic/quic_socket_utils.h",
 984       "tools/quic/quic_spdy_client_stream.cc",
 985       "tools/quic/quic_spdy_client_stream.h",
 986       "tools/quic/quic_spdy_server_stream.cc",
 987       "tools/quic/quic_spdy_server_stream.h",
 988       "tools/quic/quic_time_wait_list_manager.h",
 989       "tools/quic/quic_time_wait_list_manager.cc",
 990     ]
 991     deps = [
 992       ":balsa",
 993       ":epoll_server",
 994       ":net",
 995       "//base",
 996       "//base/third_party/dynamic_annotations",
 997       "//crypto",
 998       "//third_party/boringssl",
 999       "//url",
1000     ]
1001   }
1002
1003   executable("quic_client") {
1004     sources = [ "tools/quic/quic_client_bin.cc" ]
1005     deps = [
1006       ":quic_base",
1007       ":net",
1008       "//base",
1009       "//third_party/boringssl",
1010     ]
1011   }
1012 }
1013
1014 if (is_android) {
1015   generate_jni("net_jni_headers") {
1016     sources = [
1017       "android/java/src/org/chromium/net/AndroidCertVerifyResult.java",
1018       "android/java/src/org/chromium/net/AndroidKeyStore.java",
1019       "android/java/src/org/chromium/net/AndroidNetworkLibrary.java",
1020       "android/java/src/org/chromium/net/AndroidPrivateKey.java",
1021       "android/java/src/org/chromium/net/GURLUtils.java",
1022       "android/java/src/org/chromium/net/NetworkChangeNotifier.java",
1023       "android/java/src/org/chromium/net/ProxyChangeListener.java",
1024       "android/java/src/org/chromium/net/X509Util.java",
1025     ]
1026     jni_package = "net"
1027   }
1028 }
1029
1030 if (is_android || is_linux) {
1031   executable("disk_cache_memory_test") {
1032     sources = [ "tools/disk_cache_memory_test/disk_cache_memory_test.cc" ]
1033     deps = [
1034       ":net",
1035       "//base",
1036     ]
1037   }
1038 }
1039
1040 # TODO(GYP) make this compile on Android, we need some native test deps done.
1041 if (!is_android) {
1042
1043 source_set("quic_tools") {
1044   sources = [
1045     "quic/quic_dispatcher.cc",
1046     "quic/quic_dispatcher.h",
1047     "quic/quic_in_memory_cache.cc",
1048     "quic/quic_in_memory_cache.h",
1049     "quic/quic_per_connection_packet_writer.cc",
1050     "quic/quic_per_connection_packet_writer.h",
1051     "quic/quic_server.cc",
1052     "quic/quic_server.h",
1053     "quic/quic_server_packet_writer.cc",
1054     "quic/quic_server_packet_writer.h",
1055     "quic/quic_server_session.cc",
1056     "quic/quic_server_session.h",
1057     "quic/quic_spdy_server_stream.cc",
1058     "quic/quic_spdy_server_stream.h",
1059     "quic/quic_time_wait_list_manager.cc",
1060     "quic/quic_time_wait_list_manager.h",
1061   ]
1062   deps = [
1063     ":net",
1064     "//base",
1065     "//base/third_party/dynamic_annotations",
1066     "//url",
1067   ]
1068 }
1069
1070 test("net_unittests") {
1071   sources = gypi_values.net_test_sources
1072
1073   configs += [ ":net_win_size_truncation" ]
1074   defines = []
1075
1076   deps = [
1077     ":http_server",
1078     ":net",
1079     ":quic_tools",
1080     ":test_support",
1081     "//base",
1082     "//base:i18n",
1083     "//base:prefs_test_support",
1084     "//base/allocator",
1085     "//base/third_party/dynamic_annotations",
1086     "//crypto",
1087     "//crypto:platform",
1088     "//net/base/registry_controlled_domains",
1089     "//testing/gmock",
1090     "//testing/gtest",
1091     "//third_party/zlib",
1092     "//url",
1093   ]
1094
1095   if (is_linux) {
1096     sources += gypi_values.net_linux_test_sources
1097     deps += [
1098       ":balsa",
1099       ":epoll_server",
1100       ":flip_in_mem_edsm_server_base",
1101       ":quic_base",
1102     ]
1103   }
1104
1105   if (is_chromeos) {
1106     sources -= [
1107       "proxy/proxy_config_service_linux_unittest.cc",
1108     ]
1109   }
1110
1111   if (is_android) {
1112     sources -= [
1113       # See bug http://crbug.com/344533.
1114       "disk_cache/blockfile/index_table_v3_unittest.cc",
1115       # No res_ninit() et al on Android, so this doesn't make a lot of
1116       # sense.
1117       "dns/dns_config_service_posix_unittest.cc",
1118     ]
1119     deps += [
1120       ":net_javatests",  # FIXME(brettw)
1121       ":net_test_jni_headers",
1122     ]
1123   }
1124
1125   if (!use_nss_certs) {
1126     sources -= [
1127       "ssl/client_cert_store_nss_unittest.cc",
1128     ]
1129     if (is_chromeos) {  # Already removed for all non-ChromeOS builds.
1130       sources -= [
1131         "ssl/client_cert_store_chromeos_unittest.cc",
1132       ]
1133     }
1134   }
1135
1136   if (use_openssl) {
1137     # When building for OpenSSL, we need to exclude NSS specific tests
1138     # or functionality not supported by OpenSSL yet.
1139     # TODO(bulach): Add equivalent tests when the underlying
1140     #               functionality is ported to OpenSSL.
1141     sources -= [
1142       "cert/ct_objects_extractor_unittest.cc",
1143       "cert/multi_log_ct_verifier_unittest.cc",
1144       "cert/nss_cert_database_unittest.cc",
1145       "cert/nss_cert_database_chromeos_unittest.cc",
1146       "cert/nss_profile_filter_chromeos_unittest.cc",
1147       "cert/x509_util_nss_unittest.cc",
1148       "quic/test_tools/crypto_test_utils_nss.cc",
1149     ]
1150   } else {
1151     sources -= [
1152       "cert/x509_util_openssl_unittest.cc",
1153       "quic/test_tools/crypto_test_utils_openssl.cc",
1154       "socket/ssl_client_socket_openssl_unittest.cc",
1155       "socket/ssl_session_cache_openssl_unittest.cc",
1156     ]
1157     if (!is_desktop_linux && !is_chromeos) {
1158       sources -= [ "cert/nss_cert_database_unittest.cc" ]
1159     }
1160   }
1161
1162   if (use_kerberos) {
1163     defines += [ "USE_KERBEROS" ]
1164   } else {
1165     sources -= [
1166       "http/http_auth_gssapi_posix_unittest.cc",
1167       "http/http_auth_handler_negotiate_unittest.cc",
1168       "http/mock_gssapi_library_posix.cc",
1169       "http/mock_gssapi_library_posix.h",
1170     ]
1171   }
1172
1173   if (use_openssl || (!is_desktop_linux && !is_chromeos && !is_ios)) {
1174     # Only include this test when on Posix and using NSS for
1175     # cert verification or on iOS (which also uses NSS for certs).
1176     sources -= [ "ocsp/nss_ocsp_unittest.cc" ]
1177   }
1178
1179   if (!use_openssl_certs) {
1180     sources -= [ "ssl/openssl_client_key_store_unittest.cc" ]
1181   }
1182
1183   if (!enable_websockets) {
1184     sources -= [
1185       "socket_stream/socket_stream_metrics_unittest.cc",
1186       "socket_stream/socket_stream_unittest.cc",
1187       "spdy/spdy_websocket_stream_unittest.cc",
1188       "websockets/websocket_basic_stream_test.cc",
1189       "websockets/websocket_channel_test.cc",
1190       "websockets/websocket_deflate_predictor_impl_test.cc",
1191       "websockets/websocket_deflate_stream_test.cc",
1192       "websockets/websocket_deflater_test.cc",
1193       "websockets/websocket_errors_test.cc",
1194       "websockets/websocket_extension_parser_test.cc",
1195       "websockets/websocket_frame_parser_test.cc",
1196       "websockets/websocket_frame_test.cc",
1197       "websockets/websocket_handshake_handler_spdy_test.cc",
1198       "websockets/websocket_handshake_handler_test.cc",
1199       "websockets/websocket_handshake_stream_create_helper_test.cc",
1200       "websockets/websocket_inflater_test.cc",
1201       "websockets/websocket_job_test.cc",
1202       "websockets/websocket_net_log_params_test.cc",
1203       "websockets/websocket_stream_test.cc",
1204       "websockets/websocket_test_util.cc",
1205       "websockets/websocket_test_util.h",
1206       "websockets/websocket_throttle_test.cc",
1207     ]
1208   }
1209
1210   if (disable_file_support) {
1211     sources -= [
1212       "base/directory_lister_unittest.cc",
1213       "url_request/url_request_file_job_unittest.cc",
1214     ]
1215   }
1216
1217   if (disable_ftp_support) {
1218     sources -= [
1219       "ftp/ftp_auth_cache_unittest.cc",
1220       "ftp/ftp_ctrl_response_buffer_unittest.cc",
1221       "ftp/ftp_directory_listing_parser_ls_unittest.cc",
1222       "ftp/ftp_directory_listing_parser_netware_unittest.cc",
1223       "ftp/ftp_directory_listing_parser_os2_unittest.cc",
1224       "ftp/ftp_directory_listing_parser_unittest.cc",
1225       "ftp/ftp_directory_listing_parser_unittest.h",
1226       "ftp/ftp_directory_listing_parser_vms_unittest.cc",
1227       "ftp/ftp_directory_listing_parser_windows_unittest.cc",
1228       "ftp/ftp_network_transaction_unittest.cc",
1229       "ftp/ftp_util_unittest.cc",
1230       "url_request/url_request_ftp_job_unittest.cc",
1231     ]
1232   }
1233
1234   if (!enable_built_in_dns) {
1235     sources -= [
1236       "dns/address_sorter_posix_unittest.cc",
1237       "dns/address_sorter_unittest.cc",
1238     ]
1239   }
1240
1241   # Always need use_v8_in_net to be 1 to run on Android, so just remove
1242   # net_unittest's dependency on v8 when using icu alternatives instead of
1243   # setting use_v8_in_net to 0.
1244   if (use_v8_in_net && !use_icu_alternatives_on_android) {
1245     deps += [ ":net_with_v8" ]
1246   } else {
1247     sources -= [
1248       "proxy/proxy_resolver_v8_unittest.cc",
1249       "proxy/proxy_resolver_v8_tracing_unittest.cc",
1250     ]
1251   }
1252
1253   if (!enable_mdns) {
1254     sources -= [
1255       "dns/mdns_cache_unittest.cc",
1256       "dns/mdns_client_unittest.cc",
1257       "dns/record_parsed_unittest.cc",
1258       "dns/record_rdata_unittest.cc",
1259     ]
1260   }
1261
1262   if (is_ios) {
1263     # TODO(GYP)
1264     #  'actions': [
1265     #    {
1266     #      'action_name': 'copy_test_data',
1267     #      'variables': {
1268     #        'test_data_files': [
1269     #          'data/ssl/certificates/',
1270     #          'data/test.html',
1271     #          'data/url_request_unittest/',
1272     #        ],
1273     #        'test_data_prefix': 'net',
1274     #      },
1275     #      'includes': [ '../build/copy_test_data_ios.gypi' ],
1276     #    },
1277     #  ],
1278     sources -= [
1279       # TODO(droger): The following tests are disabled because the
1280       # implementation is missing or incomplete.
1281       # KeygenHandler::GenKeyAndSignChallenge() is not ported to iOS.
1282       "base/keygen_handler_unittest.cc",
1283       "disk_cache/backend_unittest.cc",
1284       "disk_cache/blockfile/block_files_unittest.cc",
1285       # Need to read input data files.
1286       "filter/gzip_filter_unittest.cc",
1287       "socket/ssl_server_socket_unittest.cc",
1288       "spdy/fuzzing/hpack_fuzz_util_test.cc",
1289       # Need TestServer.
1290       "proxy/proxy_script_fetcher_impl_unittest.cc",
1291       "socket/ssl_client_socket_unittest.cc",
1292       "url_request/url_fetcher_impl_unittest.cc",
1293       "url_request/url_request_context_builder_unittest.cc",
1294       # Needs GetAppOutput().
1295       "test/python_utils_unittest.cc",
1296
1297       # The following tests are disabled because they don't apply to
1298       # iOS.
1299       # OS is not "linux" or "freebsd" or "openbsd".
1300       "socket/unix_domain_client_socket_posix_unittest.cc",
1301       "socket/unix_domain_listen_socket_posix_unittest.cc",
1302       "socket/unix_domain_server_socket_posix_unittest.cc",
1303
1304       # See bug http://crbug.com/344533.
1305       "disk_cache/blockfile/index_table_v3_unittest.cc",
1306     ]
1307   }
1308
1309   if (is_android) {
1310     sources -= [
1311       "dns/dns_config_service_posix_unittest.cc",
1312     ]
1313     # TODO(GYP)
1314     # # TODO(mmenke):  This depends on test_support_base, which depends on
1315     # #                icu.  Figure out a way to remove that dependency.
1316     # 'dependencies': [
1317     #   '../testing/android/native_test.gyp:native_test_native_code',
1318     # ]
1319
1320     set_sources_assignment_filter([])
1321     sources += [ "base/address_tracker_linux_unittest.cc" ]
1322     set_sources_assignment_filter(sources_assignment_filter)
1323   }
1324
1325   if (use_icu_alternatives_on_android) {
1326     sources -= [
1327       "base/filename_util_unittest.cc",
1328       "base/net_util_icu_unittest.cc",
1329     ]
1330     deps -= [ "//base:i18n" ]
1331   }
1332 }
1333
1334 executable("quic_server") {
1335   sources = [ "quic/quic_server_bin.cc" ]
1336   deps = [
1337     ":quic_tools",
1338     ":net",
1339     "//base",
1340     "//third_party/boringssl",
1341   ]
1342 }
1343
1344 }  # !is_android