skia/BUILD.gn

   1 # Copyright (c) 2013 The Chromium Authors. All rights reserved.
   2 # Use of this source code is governed by a BSD-style license that can be
   3 # found in the LICENSE file.
   4
   5 import("//build/config/features.gni")
   6 import("//build/config/ui.gni")
   7 if (cpu_arch == "arm") {
   8   import("//build/config/arm.gni")
   9 }
  10
  11 skia_support_gpu = !is_ios
  12 skia_support_pdf = !is_ios && enable_printing != 0
  13
  14 # The list of Skia defines that are to be set for chromium.
  15 gypi_skia_defines = exec_script(
  16     "//build/gypi_to_gn.py",
  17     [ rebase_path("//third_party/skia/gyp/skia_for_chromium_defines.gypi"),
  18       "--replace=<(skia_include_path)=//third_party/skia/include",
  19       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  20     "scope",
  21     [ "//third_party/skia/gyp/skia_for_chromium_defines.gypi" ])
  22
  23 # The list of Skia core sources that are to be set for chromium.
  24 gypi_skia_core = exec_script(
  25     "//build/gypi_to_gn.py",
  26     [ rebase_path("//third_party/skia/gyp/core.gypi"),
  27       "--replace=<(skia_include_path)=//third_party/skia/include",
  28       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  29     "scope",
  30     [ "//third_party/skia/gyp/core.gypi" ])
  31
  32 # The list of Skia gpu sources that are to be set for chromium.
  33 gypi_skia_gpu = exec_script(
  34     "//build/gypi_to_gn.py",
  35     [ rebase_path("//third_party/skia/gyp/gpu.gypi"),
  36       "--replace=<(skia_include_path)=//third_party/skia/include",
  37       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  38     "scope",
  39     [ "//third_party/skia/gyp/gpu.gypi" ])
  40
  41 # The list of Skia pdf sources that are to be set for chromium.
  42 gypi_skia_pdf = exec_script(
  43     "//build/gypi_to_gn.py",
  44     [ rebase_path("//third_party/skia/gyp/pdf.gypi"),
  45       "--replace=<(skia_include_path)=//third_party/skia/include",
  46       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  47     "scope",
  48     [ "//third_party/skia/gyp/pdf.gypi" ])
  49
  50 # The list of Skia effects that are to be set for chromium.
  51 gypi_skia_effects = exec_script(
  52     "//build/gypi_to_gn.py",
  53     [ rebase_path("//third_party/skia/gyp/effects.gypi"),
  54       "--replace=<(skia_include_path)=//third_party/skia/include",
  55       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  56     "scope",
  57     [ "//third_party/skia/gyp/effects.gypi" ])
  58
  59 # The list of Skia utilss that are to be set for chromium.
  60 gypi_skia_utils = exec_script(
  61     "//build/gypi_to_gn.py",
  62     [ rebase_path("//third_party/skia/gyp/utils.gypi"),
  63       "--replace=<(skia_include_path)=//third_party/skia/include",
  64       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  65     "scope",
  66     [ "//third_party/skia/gyp/utils.gypi" ])
  67
  68 # The list of Skia files is kept in skia_gn_files.gypi. Read it.
  69 gypi_values = exec_script(
  70     "//build/gypi_to_gn.py",
  71     [ rebase_path("skia_gn_files.gypi"),
  72       "--replace=<(skia_include_path)=//third_party/skia/include",
  73       "--replace=<(skia_src_path)=//third_party/skia/src" ],
  74     "scope",
  75     [ "skia_gn_files.gypi" ])
  76
  77 # External-facing config for dependent code.
  78 config("skia_config") {
  79   include_dirs = [
  80     "config",
  81     "ext",
  82     "//third_party/skia/include/config",
  83     "//third_party/skia/include/core",
  84     "//third_party/skia/include/effects",
  85     "//third_party/skia/include/images",
  86     "//third_party/skia/include/lazy",
  87     "//third_party/skia/include/pathops",
  88     "//third_party/skia/include/pdf",
  89     "//third_party/skia/include/pipe",
  90     "//third_party/skia/include/ports",
  91     "//third_party/skia/include/utils",
  92     "//third_party/skia/src/core",
  93     "//third_party/skia/src/image",
  94     "//third_party/skia/src/opts",
  95     "//third_party/skia/src/ports",
  96     "//third_party/skia/src/sfnt",
  97     "//third_party/skia/src/utils",
  98     "//third_party/skia/src/lazy",
  99   ]
 100
 101   defines = gypi_skia_defines.skia_for_chromium_defines
 102
 103   defines += [
 104     "SK_ENABLE_INST_COUNT=0",
 105     "GR_GL_CUSTOM_SETUP_HEADER=\"GrGLConfig_chrome.h\"",
 106     "SK_ENABLE_LEGACY_API_ALIASING=1",
 107     "SK_ATTR_DEPRECATED=SK_NOTHING_ARG1",
 108     "GR_GL_IGNORE_ES3_MSAA=0",
 109     "SK_WILL_NEVER_DRAW_PERSPECTIVE_TEXT",
 110     "SK_SUPPORT_LEGACY_GETTOTALCLIP",
 111   ]
 112
 113   if (component_mode == "shared_library") {
 114     defines += [ "SKIA_DLL" ]
 115   }
 116
 117   if (skia_support_gpu) {
 118     include_dirs += [
 119       "//third_party/skia/include/gpu",
 120       "//third_party/skia/src/gpu",
 121     ]
 122     defines += [ "SK_SUPPORT_GPU=1" ]
 123   } else {
 124     defines += [ "SK_SUPPORT_GPU=0" ]
 125   }
 126
 127   # For POSIX platforms, prefer the Mutex implementation provided by Skia
 128   # since it does not generate static initializers.
 129   if (is_posix) {
 130     defines += [ "SK_USE_POSIX_THREADS" ]
 131   }
 132
 133   if (is_android) {
 134     defines += [
 135       "SK_BUILD_FOR_ANDROID",
 136       "USE_CHROMIUM_SKIA",
 137     ]
 138   }
 139
 140   if (is_mac) {
 141     defines += [ "SK_BUILD_FOR_MAC" ]
 142   }
 143 }
 144
 145 # Internal-facing config for Skia library code.
 146 config("skia_library_config") {
 147   # These include directories are only included for Skia code and are not
 148   # exported to dependents. It's not clear if this is on purpose, but this
 149   # matches the GYP build.
 150   include_dirs = []
 151   if (is_mac || is_ios) {
 152     include_dirs += [ "//third_party/skia/include/utils/mac" ]
 153   }
 154   if (is_mac) {
 155     include_dirs += [ "//third_party/skia/include/utils/ios" ]
 156   }
 157
 158   defines = [
 159     #skia_export_defines ???) TODO
 160
 161     # skia uses static initializers to initialize the serialization logic
 162     # of its "pictures" library. This is currently not used in chrome; if
 163     # it ever gets used the processes that use it need to call
 164     # SkGraphics::Init().
 165     "SK_ALLOW_STATIC_GLOBAL_INITIALIZERS=0",
 166
 167     # Forcing the unoptimized path for the offset image filter in skia until
 168     # all filters used in Blink support the optimized path properly
 169     "SK_DISABLE_OFFSETIMAGEFILTER_OPTIMIZATION",
 170
 171     "IGNORE_ROT_AA_RECT_OPT",
 172
 173     "SK_IGNORE_BLURRED_RRECT_OPT",
 174
 175     "SK_IGNORE_QUAD_RR_CORNERS_OPT",
 176
 177     # this flag forces Skia not to use typographic metrics with GDI.
 178     "SK_GDI_ALWAYS_USE_TEXTMETRICS_FOR_FONT_METRICS",
 179
 180     "SK_USE_DISCARDABLE_SCALEDIMAGECACHE",
 181   ]
 182
 183   # Settings for text blitting, chosen to approximate the system browser.
 184   if (is_linux) {
 185     defines += [
 186       "SK_GAMMA_EXPONENT=1.2",
 187       "SK_GAMMA_CONTRAST=0.2",
 188       "SK_HIGH_QUALITY_IS_LANCZOS",
 189     ]
 190   } else if (is_android) {
 191     defines += [
 192       "SK_GAMMA_APPLY_TO_A8",
 193       "SK_GAMMA_EXPONENT=1.4",
 194       "SK_GAMMA_CONTRAST=0.0",
 195     ]
 196   } else if (is_win) {
 197     defines += [
 198       "SK_GAMMA_SRGB",
 199       "SK_GAMMA_CONTRAST=0.5",
 200       "SK_HIGH_QUALITY_IS_LANCZOS",
 201     ]
 202   } else if (is_mac) {
 203     defines += [
 204       "SK_GAMMA_SRGB",
 205       "SK_GAMMA_CONTRAST=0.0",
 206       "SK_HIGH_QUALITY_IS_LANCZOS",
 207     ]
 208   }
 209
 210   if (is_android) {
 211     defines += [
 212       # Android devices are typically more memory constrained, so default to a
 213       # smaller glyph cache (it may be overriden at runtime when the renderer
 214       # starts up, depending on the actual device memory).
 215       "SK_DEFAULT_FONT_CACHE_LIMIT=1048576"  # 1024 * 1024
 216     ]
 217   } else {
 218     defines += [ "SK_DEFAULT_FONT_CACHE_LIMIT=20971520" ]  # 20 * 1024 * 1024
 219   }
 220
 221   if (is_win) {
 222     include_dirs = [
 223       "//third_party/skia/include/utils/win",
 224       "//third_party/skia/src/utils/win",
 225     ]
 226
 227     defines += [ "SK_FONTHOST_USES_FONTMGR" ]
 228
 229     cflags = [
 230       # TODO(brettw) comment what these are.
 231       "/wd4244",
 232       "/wd4267",
 233       "/wd4341",
 234       "/wd4345",
 235       "/wd4390",
 236       "/wd4554",
 237       "/wd4748",
 238       "/wd4800",
 239     ]
 240   }
 241 }
 242
 243 component("skia") {
 244   sources = [
 245     # Chrome sources.
 246     "ext/analysis_canvas.cc",
 247     "ext/analysis_canvas.h",
 248     "ext/benchmarking_canvas.cc",
 249     "ext/benchmarking_canvas.h",
 250     "ext/bitmap_platform_device.h",
 251     "ext/bitmap_platform_device_cairo.cc",
 252     "ext/bitmap_platform_device_cairo.h",
 253     "ext/bitmap_platform_device_mac.cc",
 254     "ext/bitmap_platform_device_mac.h",
 255     #"ext/bitmap_platform_device_skia.cc",
 256     #"ext/bitmap_platform_device_skia.h",
 257     "ext/bitmap_platform_device_win.cc",
 258     "ext/bitmap_platform_device_win.h",
 259     "ext/convolver.cc",
 260     "ext/convolver.h",
 261     "ext/event_tracer_impl.cc",
 262     "ext/event_tracer_impl.h",
 263     "ext/fontmgr_default_win.cc",
 264     "ext/fontmgr_default_win.h",
 265     "ext/google_logging.cc",
 266     "ext/image_operations.cc",
 267     "ext/image_operations.h",
 268     "ext/lazy_pixel_ref.cc",
 269     "ext/lazy_pixel_ref.h",
 270     "ext/SkThread_chrome.cc",
 271     "ext/opacity_draw_filter.cc",
 272     "ext/opacity_draw_filter.h",
 273     "ext/paint_simplifier.cc",
 274     "ext/paint_simplifier.h",
 275     "ext/pixel_ref_utils.cc",
 276     "ext/pixel_ref_utils.h",
 277     "ext/platform_canvas.cc",
 278     "ext/platform_canvas.h",
 279     "ext/platform_device.cc",
 280     "ext/platform_device.h",
 281     "ext/platform_device_linux.cc",
 282     "ext/platform_device_mac.cc",
 283     "ext/platform_device_win.cc",
 284     "ext/recursive_gaussian_convolution.cc",
 285     "ext/recursive_gaussian_convolution.h",
 286     "ext/refptr.h",
 287     "ext/SkDiscardableMemory_chrome.h",
 288     "ext/SkDiscardableMemory_chrome.cc",
 289     "ext/SkMemory_new_handler.cpp",
 290     "ext/skia_trace_shim.h",
 291     "ext/skia_utils_base.cc",
 292     "ext/skia_utils_base.h",
 293     "ext/skia_utils_ios.mm",
 294     "ext/skia_utils_ios.h",
 295     "ext/skia_utils_mac.mm",
 296     "ext/skia_utils_mac.h",
 297     "ext/skia_utils_win.cc",
 298     "ext/skia_utils_win.h",
 299     "ext/vector_canvas.h",
 300     "ext/vector_platform_device_emf_win.cc",
 301     "ext/vector_platform_device_emf_win.h",
 302     "ext/vector_platform_device_skia.cc",
 303     "ext/vector_platform_device_skia.h",
 304   ]
 305
 306   # The skia gypi values are relative to the skia_dir, so we need to rebase.
 307   sources += gypi_skia_core.sources
 308   sources += gypi_skia_effects.sources
 309   sources += gypi_skia_utils.sources
 310   sources += gypi_skia_pdf.sources
 311   sources += gypi_values.skia_library_sources
 312
 313   if (cpu_arch == "arm") {
 314     sources += [
 315       "//third_party/skia/src/core/SkUtilsArm.cpp",
 316       "//third_party/skia/src/core/SkUtilsArm.h",
 317     ]
 318   }
 319
 320   # GPU
 321   if (skia_support_gpu) {
 322     sources += gypi_skia_gpu.skgpu_sources
 323     sources += gypi_skia_gpu.skgpu_null_gl_sources
 324   }
 325
 326   # Remove unused util files include in utils.gypi
 327   sources -= [
 328   "//third_party/skia/include/utils/SkCondVar.h",
 329   "//third_party/skia/include/utils/SkRunnable.h",
 330   "//third_party/skia/include/utils/SkThreadPool.h",
 331   "//third_party/skia/src/utils/SkCondVar.cpp",
 332
 333   "//third_party/skia/include/utils/SkBoundaryPatch.h",
 334   "//third_party/skia/include/utils/SkFrontBufferedStream.h",
 335   "//third_party/skia/include/utils/SkCamera.h",
 336   "//third_party/skia/include/utils/SkCanvasStateUtils.h",
 337   "//third_party/skia/include/utils/SkCubicInterval.h",
 338   "//third_party/skia/include/utils/SkCullPoints.h",
 339   "//third_party/skia/include/utils/SkDebugUtils.h",
 340   "//third_party/skia/include/utils/SkDumpCanvas.h",
 341   "//third_party/skia/include/utils/SkEventTracer.h",
 342   "//third_party/skia/include/utils/SkInterpolator.h",
 343   "//third_party/skia/include/utils/SkLayer.h",
 344   "//third_party/skia/include/utils/SkMeshUtils.h",
 345   "//third_party/skia/include/utils/SkNinePatch.h",
 346   "//third_party/skia/include/utils/SkParse.h",
 347   "//third_party/skia/include/utils/SkParsePaint.h",
 348   "//third_party/skia/include/utils/SkParsePath.h",
 349   "//third_party/skia/include/utils/SkRandom.h",
 350   "//third_party/skia/include/utils/SkWGL.h",
 351
 352   "//third_party/skia/src/utils/SkBitmapHasher.cpp",
 353   "//third_party/skia/src/utils/SkBitmapHasher.h",
 354   "//third_party/skia/src/utils/SkBoundaryPatch.cpp",
 355   "//third_party/skia/src/utils/SkFrontBufferedStream.cpp",
 356   "//third_party/skia/src/utils/SkCamera.cpp",
 357   "//third_party/skia/src/utils/SkCanvasStack.h",
 358   "//third_party/skia/src/utils/SkCubicInterval.cpp",
 359   "//third_party/skia/src/utils/SkCullPoints.cpp",
 360   "//third_party/skia/src/utils/SkDumpCanvas.cpp",
 361   "//third_party/skia/src/utils/SkFloatUtils.h",
 362   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.cpp",
 363   "//third_party/skia/src/utils/SkGatherPixelRefsAndRects.h",
 364   "//third_party/skia/src/utils/SkInterpolator.cpp",
 365   "//third_party/skia/src/utils/SkLayer.cpp",
 366   "//third_party/skia/src/utils/SkMD5.cpp",
 367   "//third_party/skia/src/utils/SkMD5.h",
 368   "//third_party/skia/src/utils/SkMeshUtils.cpp",
 369   "//third_party/skia/src/utils/SkNinePatch.cpp",
 370   "//third_party/skia/src/utils/SkOSFile.cpp",
 371   "//third_party/skia/src/utils/SkParse.cpp",
 372   "//third_party/skia/src/utils/SkParseColor.cpp",
 373   "//third_party/skia/src/utils/SkParsePath.cpp",
 374   "//third_party/skia/src/utils/SkPathUtils.cpp",
 375   "//third_party/skia/src/utils/SkSHA1.cpp",
 376   "//third_party/skia/src/utils/SkSHA1.h",
 377   "//third_party/skia/src/utils/SkThreadUtils.h",
 378   "//third_party/skia/src/utils/SkThreadUtils_pthread.cpp",
 379   "//third_party/skia/src/utils/SkThreadUtils_pthread.h",
 380   "//third_party/skia/src/utils/SkThreadUtils_pthread_linux.cpp",
 381   "//third_party/skia/src/utils/SkThreadUtils_pthread_mach.cpp",
 382   "//third_party/skia/src/utils/SkThreadUtils_pthread_other.cpp",
 383   "//third_party/skia/src/utils/SkThreadUtils_win.cpp",
 384   "//third_party/skia/src/utils/SkTFitsIn.h",
 385   "//third_party/skia/src/utils/SkTLogic.h",
 386
 387   #testing
 388   "//third_party/skia/src/fonts/SkGScalerContext.cpp",
 389   "//third_party/skia/src/fonts/SkGScalerContext.h",
 390   ]
 391
 392   # need separate win section to handle chromes auto gn filter (build/config/BUILDCONFIG.gn)
 393   if (is_win) {
 394     sources -= [
 395       "//third_party/skia/src/utils/SkThreadUtils_win.h",
 396
 397       #windows
 398       "//third_party/skia/include/utils/win/SkAutoCoInitialize.h",
 399       "//third_party/skia/include/utils/win/SkHRESULT.h",
 400       "//third_party/skia/include/utils/win/SkIStream.h",
 401       "//third_party/skia/include/utils/win/SkTScopedComPtr.h",
 402       "//third_party/skia/src/utils/win/SkAutoCoInitialize.cpp",
 403       "//third_party/skia/src/utils/win/SkIStream.cpp",
 404       "//third_party/skia/src/utils/win/SkWGL_win.cpp",
 405     ]
 406   }
 407
 408   # Fixup Chrome sources.
 409   if (is_posix) {
 410     sources -= [ "ext/SkThread_chrome.cc" ]
 411   }
 412   if (is_ios) {
 413     sources -= [ "ext/vector_platform_device_skia.cc" ]
 414   }
 415   if (is_win) {
 416     sources -= [ "ext/SkThread_chrome.cc" ]
 417   }
 418   if (is_android && enable_printing == 0) {
 419     sources -= [
 420       "ext/skia_utils_base.cc",
 421       "ext/vector_platform_device_skia.cc"
 422     ]
 423   }
 424
 425   # Fixup skia library sources.
 426   if (is_win) {
 427     sources -= [
 428       "//third_party/skia/src/ports/SkOSFile_posix.cpp",
 429       "//third_party/skia/src/ports/SkTime_Unix.cpp",
 430       "//third_party/skia/src/ports/SkTLS_pthread.cpp",
 431     ]
 432   } else {
 433     sources -= [
 434       "//third_party/skia/src/ports/SkFontHost_win.cpp",
 435       "//third_party/skia/src/ports/SkFontMgr_win_dw.cpp",
 436       "//third_party/skia/src/ports/SkOSFile_win.cpp",
 437       "//third_party/skia/src/ports/SkRemotableFontMgr_win_dw.cpp",
 438       "//third_party/skia/src/ports/SkScalerContext_win_dw.cpp",
 439       "//third_party/skia/src/ports/SkScalerContext_win_dw.h",
 440       "//third_party/skia/src/ports/SkTLS_win.cpp",
 441       "//third_party/skia/src/ports/SkTypeface_win_dw.cpp",
 442       "//third_party/skia/src/ports/SkTypeface_win_dw.h",
 443     ]
 444   }
 445   if (!is_android) {
 446     sources -= [
 447       "//third_party/skia/src/ports/SkFontConfigInterface_android.cpp",
 448       "//third_party/skia/src/ports/SkFontConfigParser_android.cpp",
 449     ]
 450   }
 451   if (!is_mac) {
 452     sources -= [
 453       "//third_party/skia/src/ports/SkFontHost_mac.cpp",
 454     ]
 455   }
 456
 457   if (!is_linux) {
 458     sources -= [
 459       "//third_party/skia/src/fonts/SkFontMgr_fontconfig.cpp",
 460       "//third_party/skia/src/ports/SkFontConfigInterface_direct.cpp",
 461     ]
 462   }
 463
 464   if (!is_linux && !is_android) {
 465     sources -= [
 466       "//third_party/skia/src/ports/SkFontHost_fontconfig.cpp",
 467       "//third_party/skia/src/ports/SkFontHost_FreeType_common.cpp",
 468       "//third_party/skia/src/ports/SkFontHost_FreeType.cpp",
 469     ]
 470   }
 471
 472   if (!use_cairo) {
 473     sources -= [
 474       "ext/bitmap_platform_device_cairo.cc",
 475       "ext/bitmap_platform_device_cairo.h",
 476     ]
 477   }
 478
 479   if (is_clang) {
 480     # Skia won't compile with some of the more strict clang warnings.
 481     # e.g. it does:
 482     #  SkASSERT(!"sk_out_of_memory");
 483     configs -= [ "//build/config/clang:extra_warnings" ]
 484   }
 485
 486   configs -= [ "//build/config/compiler:chromium_code" ]
 487   configs += [
 488     ":skia_library_config",
 489     "//build/config/compiler:no_chromium_code"
 490   ]
 491   direct_dependent_configs = [ ":skia_config" ]
 492
 493   deps = [
 494     ":skia_opts",
 495     "//base",
 496     "//base/third_party/dynamic_annotations",
 497     "//third_party/zlib",
 498   ]
 499
 500   if (component_mode == "shared_library") {
 501     defines = [ "SKIA_IMPLEMENTATION=1" ]
 502   }
 503
 504   if (is_win) {
 505     configs -= [
 506       # Some files define WIN32_LEAN_AND_MEAN and we want to avoid a duplicate
 507       # definition warning.
 508       "//build/config/win:lean_and_mean",
 509     ]
 510   }
 511
 512   if (is_linux) {
 513     configs += [
 514       "//build/config/linux:fontconfig",
 515       "//build/config/linux:freetype2",
 516       "//build/config/linux:pangocairo",
 517     ]
 518     deps += [
 519       "//third_party/icu:icuuc",
 520     ]
 521   }
 522
 523   if (is_android) {
 524     set_sources_assignment_filter([])
 525     sources += [
 526       "ext/platform_device_linux.cc",
 527     ]
 528     set_sources_assignment_filter(sources_assignment_filter)
 529     deps += [
 530       "//third_party/expat",
 531       "//third_party/freetype",
 532       "//third_party/android_tools:cpu_features",
 533     ]
 534   }
 535
 536   if (skia_support_pdf) {
 537     deps += [ "//third_party/sfntly" ]
 538   }
 539 }
 540
 541 # Separated out so it can be compiled with different flags for SSE.
 542 source_set("skia_opts") {
 543   cflags = []
 544   defines = []
 545
 546   if (cpu_arch == "x86" || cpu_arch == "x64") {
 547     sources = [
 548       "//third_party/skia/src/opts/SkTextureCompression_opts_none.cpp",
 549
 550       # SSE 2
 551       "//third_party/skia/src/opts/opts_check_x86.cpp",
 552       "//third_party/skia/src/opts/SkBitmapFilter_opts_SSE2.cpp",
 553       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSE2.cpp",
 554       "//third_party/skia/src/opts/SkBlitRect_opts_SSE2.cpp",
 555       "//third_party/skia/src/opts/SkBlitRow_opts_SSE2.cpp",
 556       "//third_party/skia/src/opts/SkBlurImage_opts_SSE2.cpp",
 557       "//third_party/skia/src/opts/SkMorphology_opts_SSE2.cpp",
 558       "//third_party/skia/src/opts/SkUtils_opts_SSE2.cpp",
 559       "//third_party/skia/src/opts/SkXfermode_opts_SSE2.cpp",
 560
 561       # SSSE 3
 562       "//third_party/skia/src/opts/SkBitmapProcState_opts_SSSE3.cpp",
 563
 564       # SSE 4
 565       "//third_party/skia/src/opts/SkBlurImage_opts_SSE4.cpp",
 566
 567       # Chrome-specific.
 568       "ext/convolver_SSE2.cc",
 569
 570       # These are header files used by this target from the skia one above.
 571       "ext/convolver.h",
 572       "//third_party/skia/include/core/SkTypes.h",
 573     ]
 574
 575     # SSE 4
 576     if (cpu_arch == "x86") {
 577       sources += [ "//third_party/skia/src/opts/SkBlitRow_opts_SSE4_asm.S" ]
 578     } else {  # x64
 579       sources += [ "//third_party/skia/src/opts/SkBlitRow_opts_SSE4_x64_asm.S" ]
 580     }
 581
 582     if (is_linux || is_mac) {
 583       cflags += [ "-msse4.1" ]
 584     }
 585   } else if (cpu_arch == "arm") {
 586     sources = [
 587       "//third_party/skia/src/opts/SkBitmapProcState_opts_arm.cpp",
 588     ]
 589
 590     # The assembly uses the frame pointer register (r7 in Thumb/r11 in
 591     # ARM), the compiler doesn't like that.
 592     cflags += [ "-fomit-frame-pointer" ]
 593
 594     if (arm_version >= 7) {
 595       if (arm_use_neon || arm_optionally_use_neon) {
 596         sources += [
 597           "//third_party/skia/src/opts/SkBitmapProcState_arm_neon.cpp",
 598           "//third_party/skia/src/opts/SkBitmapProcState_matrixProcs_neon.cpp",
 599           "//third_party/skia/src/opts/SkBitmapProcState_matrix_clamp_neon.h",
 600           "//third_party/skia/src/opts/SkBitmapProcState_matrix_repeat_neon.h",
 601           "//third_party/skia/src/opts/SkBlitMask_opts_arm_neon.cpp",
 602           "//third_party/skia/src/opts/SkBlitRow_opts_arm_neon.cpp",
 603           "//third_party/skia/src/opts/SkBlurImage_opts_neon.cpp",
 604           "//third_party/skia/src/opts/SkMorphology_opts_neon.cpp",
 605           "//third_party/skia/src/opts/SkTextureCompression_opts_neon.cpp",
 606           "//third_party/skia/src/opts/SkXfermode_opts_arm_neon.cpp",
 607           "//third_party/skia/src/opts/memset16_neon.S",
 608           "//third_party/skia/src/opts/memset32_neon.S",
 609         ]
 610
 611         cflags += [
 612           # The neon assembly contains conditional instructions which aren't
 613           # enclosed in an IT block. The assembler complains without this
 614           # option. See #86592.
 615           "-Wa,-mimplicit-it=always",
 616         ]
 617
 618         # Root build config sets -mfpu=$arm_fpu, which we expect to be neon
 619         # when running this.
 620         assert(arm_fpu == "neon")
 621
 622         #ldflags = [
 623         #  "-march=armv7-a",
 624         #  "-Wl,--fix-cortex-a8",
 625         #]
 626       }
 627
 628       if (arm_use_neon) {
 629         defines += [ "__ARM_HAVE_NEON" ]
 630       }
 631       if (arm_optionally_use_neon) {
 632         defines += [ "__ARM_HAVE_OPTIONAL_NEON_SUPPORT" ]
 633       }
 634     }
 635
 636     # Non-Neon ARM code.
 637     if (arm_version < 7 || !arm_use_neon) {
 638       sources += [ "//third_party/skia/src/opts/memset.arm.S" ]
 639     }
 640
 641     if (arm_version < 6) {
 642       sources += [
 643         "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 644         "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 645         "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 646         "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 647         "//third_party/skia/src/opts/SkTextureCompression_opts_none.cpp",
 648         "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 649         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 650       ]
 651     } else {
 652       # arm version >= 6.
 653       sources += [
 654         "//third_party/skia/src/opts/SkBlitMask_opts_arm.cpp",
 655         "//third_party/skia/src/opts/SkBlitRow_opts_arm.cpp",
 656         "//third_party/skia/src/opts/SkBlitRow_opts_arm.h",
 657         "//third_party/skia/src/opts/SkBlurImage_opts_arm.cpp",
 658         "//third_party/skia/src/opts/SkMorphology_opts_arm.cpp",
 659         "//third_party/skia/src/opts/SkTextureCompression_opts_arm.cpp",
 660         "//third_party/skia/src/opts/SkUtils_opts_arm.cpp",
 661         "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 662       ]
 663     }
 664
 665   } else if (cpu_arch == "mipsel") {
 666     cflags += [ "-fomit-frame-pointer" ]
 667     sources = [
 668       "//third_party/skia/src/opts/SkBitmapProcState_opts_none.cpp",
 669       "//third_party/skia/src/opts/SkBlitMask_opts_none.cpp",
 670       "//third_party/skia/src/opts/SkBlitRow_opts_none.cpp",
 671       "//third_party/skia/src/opts/SkBlurImage_opts_none.cpp",
 672       "//third_party/skia/src/opts/SkMorphology_opts_none.cpp",
 673       "//third_party/skia/src/opts/SkTextureCompression_opts_none.cpp",
 674       "//third_party/skia/src/opts/SkUtils_opts_none.cpp",
 675       "//third_party/skia/src/opts/SkXfermode_opts_none.cpp",
 676     ]
 677   } else {
 678     assert(false, "Need to port cpu specific stuff from skia_library_opts.gyp")
 679   }
 680
 681   configs -= [ "//build/config/compiler:chromium_code" ]
 682   configs += [
 683     ":skia_config",
 684     "//build/config/compiler:no_chromium_code"
 685   ]
 686
 687   deps = [
 688     "//base",
 689   ]
 690
 691   visibility = ":skia"
 692 }