pouetchess/PKGBUILD

   1 # Maintainer: David Watzke <david@watzke.cz>
   2 # PKGBUILD based on a Gentoo ebuild
   3 # patches are from Gentoo and the .desktop file is based on that from Debian
   4
   5 pkgname=pouetchess
   6 _realname=pouetChess
   7 pkgver=0.2.0
   8 pkgrel=2
   9 pkgdesc="a small 3D chess game with pretty graphics"
  10 url="http://pouetchess.sourceforge.net/"
  11 arch=('i686' 'x86_64')
  12 license=('GPL')
  13 depends=('sdl_image')
  14 makedepends=('scons')
  15 source=("http://downloads.sourceforge.net/project/${pkgname}/${pkgname}/${pkgver%.*}/${pkgname}_src_${pkgver}.tar.gz"
  16         "${_realname}.desktop"
  17         "${pkgname}-${pkgver}-gcc43.patch"
  18         "${pkgname}-${pkgver}-nvidia_glext.patch"
  19         "${pkgname}-${pkgver}-segfaults.patch")
  20 md5sums=('c0454aca11ead9be724d769c521120b1'
  21         '8e9c89f1287300966944476adb51b03b'
  22         '81134f46083e4e9a7f8b5b10509ae0a1'
  23         '65d18a3d457e64f6168ed2975cfa4b00'
  24         'fa5c2687e2eb55fa7728071e10975605')
  25
  26 build() {
  27         cd "${startdir}/src/${pkgname}_src_${pkgver}"
  28
  29         patch -Np0 -i "${srcdir}/${pkgname}-${pkgver}-nvidia_glext.patch"
  30         patch -Np0 -i "${srcdir}/${pkgname}-${pkgver}-segfaults.patch"
  31         patch -Np0 -i "${srcdir}/${pkgname}-${pkgver}-gcc43.patch"
  32
  33         # fix for libsdl >= 1.2.10 detection
  34         sed -i -e \
  35                 "s:sdlver.split('.') >= \['1','2','8'\]:sdlver.split('.') >= [1,2,8]:" \
  36                 pouetChess.py
  37
  38         scons configure prefix="/usr" strip=true optimize=false \
  39                 datadir="/usr/share/${_realname}"
  40         scons
  41 }
  42
  43 package() {
  44         cd "${startdir}/src/${pkgname}_src_${pkgver}"
  45
  46         install -D -m755 "bin/${_realname}" \
  47                 "${pkgdir}/usr/bin/${_realname}"
  48
  49         install -d -m755 "${pkgdir}/usr/share/${_realname}"
  50         cp -a data/* "${pkgdir}/usr/share/${_realname}/"
  51
  52         install -D -m644 "data/icons/${_realname}.png" \
  53                 "${pkgdir}/usr/share/pixmaps/${_realname}.png"
  54
  55         install -D -m644 "${srcdir}/${_realname}.desktop" \
  56                 "${pkgdir}/usr/share/applications/${_realname}.desktop"
  57 }