gnucash-devel/PKGBUILD

   1 # Maintainer: Ng Oon-Ee <ngoonee.talk@gmail.com>
   2 # Contributor: Carl Flippin <carlf@photocarl.org>
   3
   4 pkgname=gnucash-devel
   5 _pkgname=gnucash
   6 pkgver=2.4.8
   7 pkgrel=1
   8 pkgdesc="A personal and small-business financial-accounting application"
   9 arch=('i686' 'x86_64')
  10 url="http://www.gnucash.org"
  11 license=("GPL")
  12 depends=('gtkhtml' 'slib' 'goffice' 'libgnomeui' 'libdbi-drivers' 'aqbanking' 'desktop-file-utils')
  13 makedepends=('intltool')
  14 optdepends=('evince: for print preview'
  15             'gnucash-docs: (AUR) for user documentation'
  16             'perl-finance-quote: for stock information lookups'
  17             'perl-date-manip: for stock information lookups')
  18 options=('!libtool' '!makeflags')
  19 provides=("gnucash=$pkgver")
  20 conflicts=('gnucash')
  21 install=${pkgname}.install
  22 source=(http://downloads.sourceforge.net/sourceforge/${_pkgname}/${_pkgname}-${pkgver}.tar.gz)
  23 sha1sums=('9b65c6c53846fbc8065f63d8b1487fdf0c3a40cc')
  24
  25 build() {
  26   cd "${srcdir}/${_pkgname}-${pkgver}"
  27   ./configure --prefix=/usr --mandir=/usr/share/man \
  28     --sysconfdir=/etc --libexecdir=/usr/lib --enable-ofx --enable-aqbanking
  29   make
  30 }
  31
  32 package() {
  33   cd "${srcdir}/${_pkgname}-${pkgver}"
  34   make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
  35
  36   install -dm755 "${pkgdir}/usr/share/gconf/schemas"
  37   gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain gnucash "${pkgdir}"/etc/gconf/schemas/*.schemas
  38   rm -f "${pkgdir}"/etc/gconf/schemas/*.schemas
  39 }