webalizer/PKGBUILD

   1 # Maintainer: megadriver <megadriver at gmx dot com>
   2 # Contributor: Jamie Nguyen <jamie AT tomoyolinux.co.uk>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4
   5 pkgname=webalizer
   6 _geodbver=20111101
   7 pkgver=2.23.05.${_geodbver}
   8 _pkgver=2.23-05
   9 pkgrel=1
  10 pkgdesc="A web server log file analysis program producing HTML reports"
  11 arch=('i686' 'x86_64')
  12 url="http://www.webalizer.com/"
  13 license=('GPL')
  14 depends=('db' 'gd' 'geoip')
  15 install=webalizer.install
  16 source=("ftp://ftp.mrunix.net/pub/webalizer/webalizer-${_pkgver}-src.tgz"
  17         "ftp://ftp.mrunix.net/pub/webalizer/geodb/webalizer-geodb-${_geodbver}.tgz"
  18         "ftp://ftp.mrunix.net/pub/webalizer/webalizer-flags.tgz")
  19 md5sums=('304338cf3b1e9389123380d5f7d88d58'
  20          '1a00df39f7c1f25ed0f8962e5bbd5874'
  21          '2605387b6076b8bdc0ec41b8655095c1')
  22
  23 build() {
  24   cd "${srcdir}/webalizer-${_pkgver}"
  25
  26   ./configure \
  27     --prefix=/usr \
  28     --sysconfdir=/etc \
  29     --datarootdir=/usr/share \
  30     --enable-bz2 \
  31     --enable-geoip
  32   make
  33 }
  34
  35 package() {
  36   cd "${srcdir}/webalizer-${_pkgver}"
  37
  38   # install webalizer
  39   make DESTDIR="${pkgdir}" install
  40
  41   # install geolocation database (GeoDB)
  42   install -m755 -d "${pkgdir}/usr/share/GeoDB"
  43   install -m644 "${srcdir}/GeoDB.dat" "${pkgdir}/usr/share/GeoDB/GeoDB.dat"
  44
  45   # install flags
  46   cd "${srcdir}/flags"
  47   install -m755 -d "${pkgdir}/usr/share/webalizer/flags"
  48   for i in *.png; do
  49     install -m644 ${i} "${pkgdir}/usr/share/webalizer/flags/${i}"
  50   done
  51 }