configure.in.in

   1
   2 ###############################################################################
   3 # BEGIN PKG-CONFIG CHECK
   4 ###############################################################################
   5
   6 AC_ARG_VAR(PKGCONFIGFOUND, [Path to pkg-config])
   7 AC_CHECK_PROG(PKGCONFIGFOUND, pkg-config,[yes])
   8
   9 ###############################################################################
  10 # END PKG-CONFIG CHECK
  11 ###############################################################################
  12
  13
  14
  15 ###############################################################################
  16 # BEGIN TAGLIB CHECK
  17 ###############################################################################
  18
  19 TAGLIB_REQ_VERSION="1.4.0";
  20 AC_DEFUN([VERSION_TO_NUMBER], [`$1 | awk 'BEGIN { FS = "."; } { printf "%d",  ([$]1* 1000 + [$]2) * 1000 + [$]3;}'`])
  21
  22 AC_PATH_PROG(TAGLIB_CONFIG, taglib-config, no)
  23
  24 if test "x$TAGLIB_CONFIG" = "xno" ; then
  25     amarok_error_notaglib=yes
  26     DO_NOT_COMPILE="$DO_NOT_COMPILE amarok"
  27     no_amarok=yes
  28 else
  29     AC_DEFINE(HAVE_TAGLIB, 1, [have TagLib])
  30     taglib_includes=[`$TAGLIB_CONFIG --cflags`]
  31     taglib_libs=[`$TAGLIB_CONFIG --libs`]
  32     taglib_version=[`$TAGLIB_CONFIG --version`]
  33
  34     if test VERSION_TO_NUMBER(echo $taglib_version) -lt VERSION_TO_NUMBER(echo $TAGLIB_REQ_VERSION); then
  35         amarok_error_taglibold=yes
  36         DO_NOT_COMPILE="$DO_NOT_COMPILE amarok"
  37         no_amarok=yes
  38     fi
  39 fi
  40
  41 AC_SUBST(taglib_includes)
  42 AC_SUBST(taglib_libs)
  43
  44 ###############################################################################
  45 # END TAGLIB CHECK
  46 ###############################################################################
  47
  48
  49
  50 ###############################################################################
  51 # BEGIN GSTREAMER-0.10 CHECK
  52 ###############################################################################
  53
  54 #AC_ARG_WITH(gstreamer10,
  55 #    AC_HELP_STRING([--with-gstreamer10],[build Amarok with GStreamer 0.10-engine]),
  56 #    [build_gstreamer10=$withval],
  57 #    [build_gstreamer10=no]
  58 #)
  59 #
  60 #if test "$build_gstreamer10" != "no"; then
  61 #    if test "$PKGCONFIGFOUND" = "yes" ; then
  62 #        # check for GStreamer
  63 #        dnl Now we're ready to ask for gstreamer libs and cflags
  64 #        dnl And we can also ask for the right version of gstreamer
  65 #        have_gst10=no
  66 #
  67 #        GST10_MAJORMINOR=0.10
  68 #        GST10_REQ=0.10.0
  69 #
  70 #        PKG_CHECK_MODULES(GST10, gstreamer-$GST10_MAJORMINOR >= $GST10_REQ gstreamer-base-$GST10_MAJORMINOR,
  71 #            have_gst10=yes,have_gst10=no)
  72 #
  73 #        dnl Give error if we don't have gstreamer
  74 #        if test "x$have_gst10" = "xno"; then
  75 #            LIB_GST10=""
  76 #            CFLAGS_GST10=""
  77 #        else
  78 #            LIB_GST10=$GST10_LIBS
  79 #            CFLAGS_GST10=$GST10_CFLAGS
  80 #            AC_SUBST(LIB_GST10)
  81 #            AC_SUBST(CFLAGS_GST10)
  82 #            AC_SUBST(GST10_MAJORMINOR)
  83 #            AC_DEFINE(HAVE_GSTREAMER10, 1, [have GStreamer10])
  84 #        fi
  85 #    fi
  86 #fi
  87 #
  88 #AM_CONDITIONAL(with_gst10, [test x$have_gst10 = xyes])
  89
  90 ###############################################################################
  91 # END GSTREAMER-0.10 CHECK
  92 ###############################################################################
  93
  94
  95
  96 ###############################################################################
  97 # BEGIN XINE CHECK
  98 ###############################################################################
  99
 100 AC_ARG_WITH(xine,
 101     AC_HELP_STRING([--without-xine],[build Amarok without xine-engine]),
 102     [build_xine=$withval],
 103     [build_xine=yes]
 104 )
 105
 106 if test "$build_xine" != "no"; then
 107
 108     AC_CHECK_PROG(XINE_CONFIG, xine-config, yes)
 109
 110     if test x$XINE_CONFIG = xyes ; then
 111         AC_DEFINE(HAVE_XINE, 1, [have Xine])
 112         CFLAGS_XINE=[`xine-config --cflags`]
 113         LIBS_XINE=[`xine-config --libs`]
 114
 115         xine_version=`xine-config --version`
 116         xine_version=VERSION_TO_NUMBER(echo $xine_version)
 117         xine_version_min="1.0.2"
 118         xine_version_min=VERSION_TO_NUMBER(echo $xine_version_min)
 119
 120         xine_include=`xine-config --cflags | sed -e 's|.*-I/|/|;s/ .*//'`
 121         xine_rc_version=`sed -ne '/^#define XINE_VERSION/s/.*-rc\([0-9]\+\).*/\1/p' $xine_include/xine.h`
 122         : ${xine_rc_version:=4} # if this is no rc version, it fulfills the requirements
 123
 124         AC_MSG_CHECKING([for xine-lib version >= 1.0.2])
 125
 126         if test $xine_version -eq $xine_version_min \
 127              -a $xine_rc_version -gt 3 \
 128              -o $xine_version -gt $xine_version_min; then
 129
 130             echo "yes"
 131
 132         else
 133             echo "no"
 134
 135             amarok_warning_xineold=yes
 136             build_xine=no
 137         fi
 138     else
 139         build_xine=no
 140     fi
 141 fi
 142
 143 AM_CONDITIONAL(with_xine, test x$build_xine = xyes)
 144 AC_SUBST(CFLAGS_XINE)
 145 AC_SUBST(LIBS_XINE)
 146
 147 ###############################################################################
 148 # END XINE CHECK
 149 ###############################################################################
 150
 151
 152
 153 ###############################################################################
 154 # BEGIN AKODE CHECK
 155 ###############################################################################
 156
 157 #AC_ARG_WITH(akode,
 158 #    AC_HELP_STRING([--without-akode],[build Amarok without akode-engine]),
 159 #    [build_akode=$withval],
 160 #    [build_akode=yes]
 161 #)
 162 #
 163 #if test "$build_akode" != "no"; then
 164 #
 165 #    AC_CHECK_PROG(AKODE_CONFIG, akode-config, yes)
 166 #
 167 #    if test x$AKODE_CONFIG = xyes ; then
 168 #        AC_DEFINE(HAVE_AKODE, 1, [have aKode])
 169 #        CFLAGS_AKODE=[`akode-config --cflags`]
 170 #        LIBS_AKODE=[`akode-config --libs`]
 171 #
 172 #        akode_version=`akode-config --version`
 173 #        akode_version=VERSION_TO_NUMBER(echo $akode_version)
 174 #        akode_version_min="2.0.0"
 175 #        akode_version_min=VERSION_TO_NUMBER(echo $akode_version_min)
 176 #
 177 #        AC_MSG_CHECKING([for akode-lib version >= 2.0])
 178 #
 179 #        if test $akode_version -eq $akode_version_min \
 180 #             -o $akode_version -gt $akode_version_min; then
 181 #
 182 #            echo "yes"
 183 #
 184 #        else
 185 #            echo "no"
 186 #
 187 #            build_akode=no
 188 #        fi
 189 #    else
 190 #        build_akode=no
 191 #    fi
 192 #fi
 193 #
 194 #AM_CONDITIONAL(with_akode, test x$build_akode = xyes)
 195 #AC_SUBST(CFLAGS_AKODE)
 196 #AC_SUBST(LIBS_AKODE)
 197
 198 ###############################################################################
 199 # END AKODE CHECK
 200 ###############################################################################
 201
 202
 203
 204 ###############################################################################
 205 # BEGIN NMM CHECK
 206 ###############################################################################
 207
 208 AC_ARG_WITH(nmm,
 209     AC_HELP_STRING([--with-nmm],[build Amarok with NMM-engine]),
 210     [build_nmm=$withval],
 211     [build_nmm=no]
 212 )
 213
 214 AC_ARG_WITH(nmm-dir,
 215     AC_HELP_STRING([--with-nmm-dir],[path to the NMM [default=/usr/local]]),
 216     [nmm_dir="$withval"],
 217     [nmm_dir=/usr/local]
 218 )
 219
 220 if test "$build_nmm" != "no"; then
 221
 222     CFLAGS_NMM="-I$nmm_dir/include"
 223     LDFLAGS_NMM="-L$nmm_dir/lib"
 224     AC_DEFINE(HAVE_NMM, 1, [have NMM])
 225 fi
 226
 227 AM_CONDITIONAL(with_nmm, test x$build_nmm = xyes)
 228 AC_SUBST(CFLAGS_NMM)
 229 AC_SUBST(LDFLAGS_NMM)
 230
 231 ###############################################################################
 232 # END NMM CHECK
 233 ###############################################################################
 234
 235
 236
 237 ###############################################################################
 238 # BEGIN MAS CHECK
 239 ###############################################################################
 240
 241 #AC_ARG_WITH(mas,
 242 #    AC_HELP_STRING([--with-mas],[build Amarok with MAS-engine]),
 243 #    [build_mas=$withval],
 244 #    [build_mas=no]
 245 #)
 246 #
 247 #
 248 #if test "$build_mas" != "no"; then
 249 #
 250 #    AC_PATH_PROG(MAS_CONFIG, mas-config, no)
 251 #
 252 #    if test $MAS_CONFIG = "no"
 253 #    then
 254 #        amarok_warning_mas_notfound=yes
 255 #    echo "amarok_warning_mas_notfound: $amarok_warning_mas_notfound"
 256 #        build_mas=no
 257 #    else
 258 #        AC_DEFINE(HAVE_MAS, 1, [have MAS])
 259 #
 260 #        CFLAGS_MAS=[`$MAS_CONFIG --cflags`]
 261 #        LIBS_MAS=[`$MAS_CONFIG --libs`]
 262 #
 263 #        build_mas=yes
 264 #    fi
 265 #fi
 266 #
 267 #AM_CONDITIONAL(with_mas, test x$build_mas = xyes)
 268 #AC_SUBST(CFLAGS_MAS)
 269 #AC_SUBST(LIBS_MAS)
 270
 271 ###############################################################################
 272 # END MAS CHECK
 273 ###############################################################################
 274
 275
 276
 277 ###############################################################################
 278 # BEGIN HELIX CHECK
 279 ###############################################################################
 280
 281 AC_ARG_WITH(helix,
 282     AC_HELP_STRING([--with-helix],[build Amarok with Helix-engine]),
 283     [build_helix=$withval],
 284     [build_helix=no]
 285 )
 286
 287 if test "$build_helix" != "no"; then
 288     AC_MSG_CHECKING([for RealPlayer or HelixPlayer])
 289
 290     if test "$build_helix" = "yes"; then
 291         HXPLAY=`type -p hxplay`
 292     RPLAY=`type -p realplay`
 293     if test "$RPLAY" != "" -a -x "$RPLAY"; then
 294         HELIX_LINK=`readlink -f $RPLAY`
 295         HELIX_LINK=`dirname $HELIX_LINK`
 296         HELIX_LIBS=`unset CDPATH; cd $HELIX_LINK && pwd`
 297         if test -e "$HELIX_LIBS/common/clntcore.so"; then
 298         AC_MSG_RESULT([found RealPlayer in $HELIX_LIBS])
 299         build_helix=$HELIX_LIBS
 300         fi
 301     elif test "$HXPLAY" != "" -a -x "$HXPLAY"; then
 302         HELIX_LINK=`readlink -f $HXPLAY`
 303         HELIX_LINK=`dirname $HELIX_LINK`
 304         HELIX_LIBS=`unset CDPATH; cd $HELIX_LINK && pwd`
 305         if test -e "$HELIX_LIBS/common/clntcore.so"; then
 306         AC_MSG_RESULT([found HelixPlayer in $HELIX_LIBS])
 307         build_helix=$HELIX_LIBS
 308         fi
 309     fi
 310     else
 311         if test -n "$build_helix" -a -d "$build_helix"; then
 312           HELIX_LIBS=`unset CDPATH; cd $build_helix && pwd`
 313         else
 314           HELIX_LIBS="$build_helix"
 315         fi
 316     build_helix=$HELIX_LIBS
 317         AC_MSG_RESULT([using $HELIX_LIBS])
 318     fi
 319
 320     AC_DEFINE(HAVE_HELIX, 1, [have HELIX])
 321     if test "$build_helix" = "yes"; then
 322         HELIX_LIBS="/usr/local/RealPlayer"
 323         AC_MSG_RESULT(["not found, using default dir"])
 324     fi
 325     AC_DEFINE_UNQUOTED(HELIX_LIBS, "${HELIX_LIBS}", [location of helix libs])
 326     if test "$PKGCONFIGFOUND" = "yes" ; then
 327     PKG_CHECK_MODULES([ALSALIB], alsa, have_alsa=yes,have_alsa=no)
 328     if test "$have_alsa" = "yes" ; then
 329         AC_DEFINE(USE_HELIX_ALSA, 1, [support ALSA in the helix-engine])
 330     fi
 331     fi
 332 fi
 333
 334 AM_CONDITIONAL(with_helix, test x$build_helix != xno)
 335
 336 ###############################################################################
 337 # END HELIX CHECK
 338 ###############################################################################
 339
 340 ###############################################################################
 341 # BEGIN yauap CHECK
 342 ###############################################################################
 343
 344 AC_ARG_WITH(yauap,
 345     AC_HELP_STRING([--with-yauap],[build Amarok with yauap-engine]),
 346     [build_yauap=$withval],
 347     [build_yauap=no]
 348 )
 349
 350 if test "$build_yauap" != "no"; then
 351     if test "$PKGCONFIGFOUND" = "yes" ; then
 352         # check for dbus-glib
 353         have_yauap=no
 354
 355         PKG_CHECK_MODULES(DBUSGLIB, dbus-glib-1,
 356             have_yauap=yes,have_yauap=no)
 357
 358
 359         dnl Give error if we don't have gstreamer
 360         if test "x$have_yauap" = "xno"; then
 361             LIB_YAUAP=""
 362             CFLAGS_YAUAP=""
 363         else
 364             PKG_CHECK_MODULES(GOBJECT, gobject-2.0,
 365                 have_yauap=yes,have_yauap=no)
 366             LIB_YAUAP="$DBUSGLIB_LIBS -ldbus-qt-1 $GOBJECT_LIBS"
 367             CFLAGS_YAUAP="$DBUSGLIB_CFLAGS $GOBJECT_CFLAGS"
 368             AC_SUBST(LIB_YAUAP)
 369             AC_SUBST(CFLAGS_YAUAP)
 370             AC_DEFINE(HAVE_YAUAP, 1, [have yauap])
 371         fi
 372     fi
 373 fi
 374
 375 AM_CONDITIONAL(with_yauap, [test x$have_yauap = xyes])
 376
 377 ###############################################################################
 378 # END yauap CHECK
 379 ###############################################################################
 380
 381
 382
 383 ###############################################################################
 384 # BEGIN stdint.h CHECK
 385 ###############################################################################
 386
 387 AC_CHECK_HEADER(stdint.h)
 388
 389 ###############################################################################
 390 # END stdint.h CHECK
 391 ###############################################################################
 392
 393
 394 ###############################################################################
 395 # BEGIN fabsf CHECK
 396 ###############################################################################
 397
 398 AC_CHECK_DECLS([fabsf],,,[#include <math.h>])
 399 if test "$ac_cv_have_decl_fabsf" = "yes"; then
 400     AC_COMPILE_IFELSE(
 401         [AC_LANG_PROGRAM(
 402             [[#include <math.h>]],
 403             [[return (int)fabsf(1.f);]])],
 404         [AC_DEFINE(HAVE_FABSF, 1, [have fabsf])])
 405 fi
 406
 407 ###############################################################################
 408 # END fabsf CHECK
 409 ###############################################################################
 410
 411
 412
 413
 414
 415 ###############################################################################
 416 # BEGIN INOTIFY CHECK
 417 ###############################################################################
 418
 419 AC_CHECK_HEADERS(linux/inotify.h)
 420
 421 if test x"$ac_cv_header_linux_inotify_h" = x"yes"; then
 422     AC_DEFINE(HAVE_INOTIFY, 1, [have inotify])
 423 fi
 424
 425 ###############################################################################
 426 # END INOTIFY CHECK
 427 ###############################################################################
 428
 429
 430
 431 ###############################################################################
 432 # BEGIN QT OPENGL CHECK
 433 ###############################################################################
 434
 435 AC_ARG_WITH(opengl,
 436     AC_HELP_STRING([--without-opengl],[build Amarok without OpenGL support]),
 437     [build_opengl=$withval],
 438     [build_opengl=yes]
 439 )
 440
 441 if test "$build_opengl" != "no"; then
 442     AC_MSG_CHECKING(for Qt with OpenGL support)
 443     AC_CACHE_VAL(ac_cv_kde_qt_has_opengl,
 444     [
 445     AC_LANG_SAVE
 446     AC_LANG_CPLUSPLUS
 447
 448     save_CXXFLAGS="$CXXFLAGS"
 449     save_LIBS="$LIBS"
 450     save_LDFLAGS="$LDFLAGS"
 451
 452     CXXFLAGS="$CXXFLAGS -I$qt_incdir $all_includes"
 453     LDFLAGS="$LDFLAGS -L$qt_libdir $all_libraries $USER_LDFLAGS $KDE_MT_LDFLAGS"
 454     LIBS="$LIBS $LIBQT $KDE_MT_LIBS"
 455
 456     AC_TRY_LINK([
 457     #include <qgl.h>
 458     ],
 459     [
 460     (void)new QGLWidget((QWidget*)0, "qgl");
 461     ],
 462     ac_cv_kde_qt_has_opengl=yes,
 463     ac_cv_kde_qt_has_opengl=no)
 464
 465     CXXFLAGS="$save_CXXFLAGS"
 466     LIBS="$save_LIBS"
 467     LDFLAGS="$save_LDFLAGS"
 468     AC_LANG_RESTORE
 469     ])
 470     AC_MSG_RESULT($ac_cv_kde_qt_has_opengl)
 471
 472     if test x$ac_cv_kde_qt_has_opengl = xyes; then
 473     AC_DEFINE(HAVE_QGLWIDGET, 1, [have Qt with OpenGL support])
 474     gl_libs="-lGL"
 475     else
 476     gl_libs=""
 477     fi
 478
 479     AC_SUBST(gl_libs)
 480 fi
 481
 482 ###############################################################################
 483 # END QT OPENGL CHECK
 484 ###############################################################################
 485
 486
 487
 488 ###############################################################################
 489 # BEGIN SQLITE CHECK
 490 ###############################################################################
 491
 492 LIB_SQLITE=""
 493
 494 AC_ARG_WITH(included-sqlite,
 495     AC_HELP_STRING([--without-included-sqlite],[build Amarok using system sqlite library]),
 496     [included_sqlite=$withval],
 497     [included_sqlite=yes]
 498 )
 499
 500 if test x$included_sqlite = xno; then
 501     if test x$PKGCONFIGFOUND = xyes; then
 502         PKG_CHECK_MODULES(SQLITE, sqlite3 >= 3.0, have_sqlite=yes,have_sqlite=no)
 503
 504         if test x$have_sqlite = xyes; then
 505             ## AC_DEFINE(HAVE_SQLITE, 1, [have SQLite database library])
 506             LIB_SQLITE=`pkg-config --libs sqlite3`
 507         else
 508             # We don't support not having sqlite anymore
 509             DO_NOT_COMPILE="$DO_NOT_COMPILE amarok"
 510             no_amarok=yes
 511         fi
 512     fi
 513 fi
 514
 515 AC_SUBST(LIB_SQLITE)
 516 AM_CONDITIONAL(with_included_sqlite, [test x$included_sqlite = xyes])
 517
 518
 519 # Determine pointer size for sqlite
 520
 521 KDE_CHECK_TYPES
 522 AC_DEFINE(SQLITE_PTR_SZ, SIZEOF_CHAR_P, [Determine pointer size for SQLite])
 523
 524 ###############################################################################
 525 # END SQLITE CHECK
 526 ###############################################################################
 527
 528
 529
 530 ###############################################################################
 531 # BEGIN MYSQL CHECK
 532 ###############################################################################
 533
 534 AC_ARG_ENABLE(mysql,
 535     AC_HELP_STRING([--enable-mysql],[build Amarok with MySQL support]),
 536     [enable_mysql=$enableval],
 537     [enable_mysql=no]
 538 )
 539
 540 if test "$enable_mysql" = "yes"; then
 541
 542     AC_CHECK_PROG(MYSQL_CONFIG, mysql_config, yes)
 543
 544     if test x$MYSQL_CONFIG = xyes; then
 545         AC_DEFINE(USE_MYSQL, 1, [MySql database support enabled])
 546
 547         mysql_includes=`mysql_config --cflags`
 548         mysql_libs=`mysql_config --libs`
 549     else
 550         amarok_warning_mysql_notfound=yes
 551         enable_mysql=no
 552     fi
 553
 554 fi
 555
 556 AM_CONDITIONAL(enable_mysql, test x$enable_mysql = xyes)
 557 AC_SUBST(mysql_includes)
 558 AC_SUBST(mysql_libs)
 559
 560 ###############################################################################
 561 # END MYSQL CHECK
 562 ###############################################################################
 563
 564
 565
 566 ###############################################################################
 567 # BEGIN POSTGRESQL CHECK
 568 ###############################################################################
 569
 570 AC_ARG_ENABLE(postgresql,
 571     AC_HELP_STRING([--enable-postgresql],[build Amarok with PostgreSQL support]),
 572     [enable_postgresql=$enableval],
 573     [enable_postgresql=no]
 574 )
 575
 576 if test "$enable_postgresql" = "yes"; then
 577
 578     AC_CHECK_PROG(POSTGRESQL_CONFIG, pg_config, yes)
 579
 580     if test x$POSTGRESQL_CONFIG = xyes; then
 581         AC_DEFINE(USE_POSTGRESQL, 1, [Postgresql database support enabled])
 582
 583         postgresql_includes=-I`pg_config --includedir`
 584         postgresql_libs="-L`pg_config --libdir` -lpq"
 585     else
 586         amarok_warning_postgresql_notfound=yes
 587         enable_postgresql=no
 588     fi
 589
 590 fi
 591
 592 AM_CONDITIONAL(enable_postgresql, test x$enable_postgresql = xyes)
 593 AC_SUBST(postgresql_includes)
 594 AC_SUBST(postgresql_libs)
 595
 596 ###############################################################################
 597 # END POSTGRESQL CHECK
 598 ###############################################################################
 599
 600
 601
 602 ###############################################################################
 603 # BEGIN LIBVISUAL CHECK
 604 ###############################################################################
 605
 606 AC_ARG_WITH(libvisual,
 607     AC_HELP_STRING([--without-libvisual],[build Amarok without libvisual support]),
 608     [with_libvisual=$withval],
 609     [with_libvisual=yes]
 610 )
 611
 612 if test "$with_libvisual" = "yes"; then
 613     ## libvisual plugin depends on sdl
 614     AC_CHECK_PROG(SDL_CONFIG, sdl-config, yes)
 615
 616     if test x$SDL_CONFIG = xyes; then
 617         sdl_cflags=`sdl-config --cflags`
 618         sdl_libs=`sdl-config --libs`
 619     fi
 620
 621     AC_SUBST(sdl_cflags)
 622     AC_SUBST(sdl_libs)
 623
 624     if test x$PKGCONFIGFOUND = xyes -a x$SDL_CONFIG = xyes; then
 625
 626         PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0, [build_libvisual="yes"], [build_libvisual="no"])
 627
 628         AC_SUBST(LIBVISUAL_LIBS)
 629         AC_SUBST(LIBVISUAL_CFLAGS)
 630
 631         if test x$build_libvisual = xyes; then
 632             AC_DEFINE(HAVE_LIBVISUAL, 1, [have LIBVISUAL])
 633         fi
 634     fi
 635 fi
 636
 637 AM_CONDITIONAL(with_libvisual, test x$build_libvisual = xyes)
 638
 639 ###############################################################################
 640 # END LIBVISUAL CHECK
 641 ###############################################################################
 642
 643
 644
 645 ###############################################################################
 646 # BEGIN TUNEPIMP CHECK
 647 ###############################################################################
 648
 649 AC_ARG_WITH(musicbrainz,
 650     AC_HELP_STRING([--without-musicbrainz],[build Amarok without MusicBrainz support]),
 651     [with_musicbrainz=$withval],
 652     [with_musicbrainz=yes]
 653 )
 654
 655 if test "$with_musicbrainz" = "yes"; then
 656     AC_CHECK_HEADER(tunepimp-0.5/tp_c.h, [build_musicbrainz="yes"],
 657       [AC_CHECK_HEADER(tunepimp/tp_c.h, [build_musicbrainz="yes"],
 658         [build_musicbrainz="no"])])
 659 fi
 660
 661 if test "$build_musicbrainz" = "yes"; then
 662     AC_CHECK_LIB(tunepimp, tr_GetPUID,
 663       AC_DEFINE(HAVE_TUNEPIMP, 5, [have MusicBrainz 0.5.x]),
 664         AC_CHECK_LIB(tunepimp, tp_SetFileNameEncoding,
 665         AC_DEFINE(HAVE_TUNEPIMP, 4, [have MusicBrainz 0.4.x]),
 666         AC_DEFINE(HAVE_TUNEPIMP, 1, [have MusicBrainz])))
 667     LIB_TUNEPIMP="-ltunepimp"
 668     have_tunepimp=yes
 669 else
 670     AC_DEFINE(HAVE_TUNEPIMP, 0, [have TunePimp])
 671     LIB_TUNEPIMP=""
 672     have_tunepimp=no
 673 fi
 674
 675 AC_SUBST(LIB_TUNEPIMP)
 676
 677 ###############################################################################
 678 # END TUNEPIMP CHECK
 679 ###############################################################################
 680
 681
 682
 683 ###############################################################################
 684 # BEGIN AMAZON CHECK
 685 ###############################################################################
 686
 687 AC_ARG_ENABLE(amazon,
 688     AC_HELP_STRING([--disable-amazon],[disable Amazon cover download support [default=enable]]),
 689     [enable_amazon=$enableval],
 690     [enable_amazon=yes]
 691 )
 692
 693 if test "$enable_amazon" != "no"; then
 694     AC_DEFINE(AMAZON_SUPPORT, 1, [Amazon cover download support enabled])
 695 fi
 696
 697 ###############################################################################
 698 # END AMAZON CHECK
 699 ###############################################################################
 700
 701
 702
 703 ###############################################################################
 704 # BEGIN SCHED_SETAFFINITY BUGGY GLIBC CHECK
 705 ###############################################################################
 706
 707 AC_MSG_CHECKING([if sched_setaffinity should be enabled])
 708
 709 AC_LANG_SAVE
 710 AC_LANG_CPLUSPLUS
 711
 712 amarok_glibcsched_works=no
 713
 714 AC_TRY_COMPILE([
 715     #include <sched.h>
 716 ],
 717 [
 718     cpu_set_t mask;
 719     CPU_ZERO( &mask );
 720     CPU_SET( 0, &mask );
 721     sched_setaffinity( 0, sizeof(mask), &mask );
 722 ],
 723     amarok_sched_3params=yes,
 724     amarok_sched_3params=no
 725 )
 726
 727 if test "x$amarok_sched_3params" = "xyes"; then
 728     AC_DEFINE(SCHEDAFFINITY_SUPPORT, 1, [sched_setaffinity works correctly])
 729     AC_DEFINE(SCHEDAFFINITY_3PARAMS, 1, [sched_setaffinity takes three params])
 730     amarok_glibcsched_works=yes
 731 fi
 732
 733 if test "x$amarok_sched_3params" = "xno"; then
 734     AC_TRY_COMPILE([
 735     #include <sched.h>
 736     ],
 737     [
 738         cpu_set_t mask;
 739         CPU_ZERO( &mask );
 740         CPU_SET( 0, &mask );
 741         sched_setaffinity( 0, &mask );
 742     ],
 743         amarok_sched_2params=yes,
 744         amarok_sched_2params=no
 745     )
 746     if test "x$amarok_sched_2params" = "xyes"; then
 747         AC_DEFINE(SCHEDAFFINITY_SUPPORT, 1, [sched_setaffinity works correctly])
 748         amarok_glibcsched_works=yes
 749     fi
 750 fi
 751
 752 AC_LANG_RESTORE
 753
 754 AC_MSG_RESULT($amarok_glibcsched_works)
 755
 756 ###############################################################################
 757 # END SCHED_SETAFFINITY BUGGY GLIBC CHECK
 758 ###############################################################################
 759
 760
 761
 762 ###############################################################################
 763 # BEGIN KDEBASE CHECK
 764 ###############################################################################
 765
 766 KDE_CHECK_HEADER(konqsidebarplugin.h, have_konqsidebar=yes, have_konqsidebar=no)
 767 KDE_CHECK_LIB(konqsidebarplugin, _init, have_konqsidebar=$have_konqsidebar, have_konqsidebar=no)
 768
 769 AM_CONDITIONAL(with_konqsidebar, [test x$have_konqsidebar = xyes])
 770
 771 ###############################################################################
 772 # END KDEBASE CHECK
 773 ###############################################################################
 774
 775
 776
 777 ###############################################################################
 778 # BEGIN NJB CHECK
 779 ###############################################################################
 780 ### mediabrowser.cpp can use libnjb if available
 781
 782 AC_ARG_WITH(libnjb,
 783     AC_HELP_STRING([--with-libnjb],[build Amarok with Nomad Jukebox support from libnjb]),
 784     [build_libnjb=$withval],
 785     [build_libnjb=yes]
 786 )
 787
 788 if test "$build_libnjb" != "no"; then
 789     if test "$PKGCONFIGFOUND" = "yes" ; then
 790
 791         # check for libnjb
 792         have_libnjb=no
 793
 794         PKG_CHECK_MODULES(LIBNJB, libnjb, have_libnjb=yes,have_libnjb=no)
 795         if test "x$have_libnjb" != "xno"; then
 796             AC_DEFINE(HAVE_LIBNJB, 1, [have libnjb])
 797         fi
 798     fi
 799 fi
 800
 801 AM_CONDITIONAL(with_libnjb, [test x$have_libnjb = xyes])
 802
 803 ###############################################################################
 804 # END NJB CHECK
 805 ###############################################################################
 806
 807
 808
 809 ###############################################################################
 810 # BEGIN MTP CHECK
 811 ###############################################################################
 812 ### mediabrowser.cpp can use libmtp if available
 813
 814 AC_ARG_WITH(libmtp,
 815     AC_HELP_STRING([--with-libmtp],[build Amarok with support for MTP devices]),
 816     [build_libmtp=$withval],
 817     [build_libmtp=yes]
 818 )
 819 if test "$build_libmtp" != "no"; then
 820     if test "$PKGCONFIGFOUND" = "yes" ; then
 821         PKG_CHECK_MODULES(LIBMTP, libmtp >= 0.1.1,
 822         [
 823             have_libmtp=yes
 824         ],
 825         [
 826             have_libmtp=no
 827         ])
 828     fi
 829
 830     if test "x$have_libmtp" != "xno"; then
 831         AC_DEFINE(HAVE_LIBMTP, 1, [have libmtp])
 832     fi
 833 fi
 834
 835 AM_CONDITIONAL(with_libmtp, [test x$have_libmtp = xyes])
 836
 837 ###############################################################################
 838 # END MTP CHECK
 839 ###############################################################################
 840
 841 ###############################################################################
 842 # BEGIN RIO KARMA CHECK
 843 ###############################################################################
 844 ### mediabrowser.cpp can use libkarma if available
 845
 846 AC_ARG_WITH(libkarma,
 847     AC_HELP_STRING([--with-libkarma],[build Amarok with Rio Karma support]),
 848     [build_libkarma=$withval],
 849     [build_libkarma=yes]
 850 )
 851
 852 if test "$build_libkarma" != "no"; then
 853     AC_CHECK_HEADERS([libkarma/lkarma.h], [have_libkarma=yes], [], [])
 854     AC_CHECK_HEADERS([usb.h], [have_usb=yes], [], [])
 855
 856     if test "$have_libkarma" = "yes"; then
 857         AC_DEFINE(HAVE_LIBKARMA, 1, [have libkarma])
 858     else
 859         AC_MSG_RESULT($have_libkarma)
 860         have_libkarma=no
 861     fi
 862 fi
 863
 864 AM_CONDITIONAL(with_libkarma, [test x$have_libkarma = xyes])
 865
 866 ###############################################################################
 867 # END RIO KARMA CHECK
 868 ###############################################################################
 869
 870 ###############################################################################
 871 # BEGIN IFP CHECK
 872 ###############################################################################
 873 ### mediabrowser.cpp can use libifp if available
 874
 875 AC_ARG_WITH(ifp,
 876     AC_HELP_STRING([--with-ifp],[build Amarok with ifp support]),
 877     [build_ifp=$withval],
 878     [build_ifp=yes]
 879 )
 880
 881 if test "$build_ifp" != "no"; then
 882
 883     AC_CHECK_HEADERS([ifp.h], [have_ifp=yes], [], [])
 884     AC_CHECK_HEADERS([usb.h], [have_usb=yes], [], [])
 885
 886     if test "$have_ifp" = "yes"; then
 887         AC_DEFINE(HAVE_IFP, 1, [have ifp])
 888         IFP_LIBS="-lifp -lusb"
 889     else
 890         AC_MSG_RESULT($have_ifp)
 891         have_ifp=no
 892     fi
 893
 894 fi
 895
 896 AC_SUBST(IFP_INCLUDES)
 897 AC_SUBST(IFP_LIBS)
 898
 899 AM_CONDITIONAL(with_ifp, [test x$have_ifp = xyes])
 900
 901 ###############################################################################
 902 # END IFP CHECK
 903 ###############################################################################
 904
 905
 906
 907 ###############################################################################
 908 # BEGIN LIBGPOD CHECK
 909 ###############################################################################
 910
 911 AC_ARG_WITH(libgpod,
 912     AC_HELP_STRING([--with-libgpod],[build Amarok with iPod support from libgpod]),
 913     [build_libgpod=$withval],
 914     [build_libgpod=yes]
 915 )
 916
 917 if test "$build_libgpod" != "no"; then
 918     if test "$PKGCONFIGFOUND" = "yes" ; then
 919
 920         # check for libgpod
 921         have_libgpod=no
 922
 923         PKG_CHECK_MODULES(LIBGPOD, libgpod-1.0, have_libgpod=yes,have_libgpod=no)
 924
 925         if test "x$have_libgpod" = "xyes"; then
 926             ac_cppflags_save=$CPPFLAGS
 927             ac_cflags_save=$CFLAGS
 928             ac_libs_save=$LIBS
 929             CPPFLAGS="$CPPFLAGS $LIBGPOD_INCLUDES"
 930             CFLAGS="$CFLAGS $LIBGPOD_CFLAGS"
 931             LIBS="$LIBS $LIBGPOD_LIBS"
 932
 933             AC_CHECK_FUNCS(itdb_track_set_thumbnails, , have_libgpod_042=no)
 934             AC_CHECK_FUNCS(itdb_get_mountpoint, , have_libgpod_042=no)
 935             AC_CHECK_FUNCS(itdb_device_get_ipod_info, , have_libgpod_042=no)
 936
 937             AC_CHECK_MEMBER(struct _Itdb_Track.movie_flag,
 938                   [AC_DEFINE(HAVE_ITDB_MOVIE_FLAG, 1, [have libgpod movie flag])],
 939                   have_libgpod_042=no,
 940                   [#include <gpod/itdb.h>])
 941
 942             AC_CHECK_MEMBER(struct _Itdb_Track.skip_when_shuffling,
 943                   [AC_DEFINE(HAVE_ITDB_SKIP_SHUFFLE_FLAG, 1, [have libgpod skip when shuffling flag])],
 944                   have_libgpod_042=no,
 945                   [#include <gpod/itdb.h>])
 946
 947             AC_CHECK_MEMBER(struct _Itdb_Track.mark_unplayed,
 948                   [AC_DEFINE(HAVE_ITDB_MARK_UNPLAYED, 1, [have libgpod mark played flag])],
 949                   have_libgpod_042=no,
 950                   [#include <gpod/itdb.h>])
 951
 952             AC_CHECK_MEMBER(struct _Itdb_Track.mediatype,
 953                   [AC_DEFINE(HAVE_ITDB_MEDIATYPE, 1, [have libgpod mediatype flag])],
 954                   have_libgpod_042=no,
 955                   [#include <gpod/itdb.h>])
 956
 957             CPPFLAGS=$ac_cppflags_save
 958             CFLAGS=$ac_cflags_save
 959             LIBS=$ac_libs_save
 960         fi
 961
 962         if test "x$have_libgpod_042" = "xno"; then
 963             have_libgpod=no
 964             AC_MSG_RESULT(Your libgpod version is too old: at least 0.4.2 is required)
 965         fi
 966
 967         if test "x$have_libgpod" != "xno"; then
 968             AC_DEFINE(HAVE_LIBGPOD, 1, [have libgpod])
 969         fi
 970     fi
 971 fi
 972
 973 AM_CONDITIONAL(with_libgpod, [test x$have_libgpod = xyes])
 974
 975 ###############################################################################
 976 # END LIBGPOD CHECK
 977 ###############################################################################
 978
 979
 980
 981 ###############################################################################
 982 # BEGIN statvfs(2) CHECK
 983 ###############################################################################
 984
 985 AC_CHECK_FUNCS(statvfs)
 986
 987 ###############################################################################
 988 # END statvfs(2) CHECK
 989 ###############################################################################
 990
 991
 992
 993 ###############################################################################
 994 # BEGIN MP4V2 CHECK
 995 ###############################################################################
 996 # m4a/aac tag reading and writing needs libmp4v2 from faad2 or better mpeg4ip
 997
 998 AC_ARG_WITH(mp4v2,
 999     AC_HELP_STRING([--with-mp4v2],[build Amarok with M4A/AAC tag support from mp4v2/faad2]),
1000     [have_mp4v2=$withval],
1001     [have_mp4v2=no]
1002 )
1003
1004 AC_ARG_WITH(mp4v2-dir,
1005     AC_HELP_STRING([--with-mp4v2-dir],[path to mp4v2  [default=/usr]]),
1006     [mp4v2_dir="$withval"],
1007     [mp4v2_dir=/usr]
1008 )
1009
1010 if test "$have_mp4v2" != "no"; then
1011     AC_LANG_SAVE
1012     AC_LANG_CPLUSPLUS
1013     ac_cxxflags_save=$CXXFLAGS
1014     CXXFLAGS="$CXXFLAGS -I$mp4v2_dir/include"
1015     ac_ldflags_save=$LDFLAGS
1016     LDFLAGS="$LDFLAGS -L$mp4v2_dir/lib"
1017
1018     # not even everyone using faad2 has <systems.h>
1019     if ! test -f config.h; then
1020         echo "#include \"confdefs.h\"" > config.h
1021     fi
1022     ac_cppflags_save=$CPPFLAGS
1023     CPPFLAGS="$CPPFLAGS -I."
1024     AC_CHECK_HEADERS(systems.h)
1025     AC_CHECK_HEADERS([mp4.h], [have_mp4_h=yes], [],
1026         [#ifdef HAVE_SYSTEMS_H
1027          # include <systems.h>
1028          #endif
1029         ])
1030
1031     AC_CHECK_LIB( mp4v2, MP4Read, have_mp4v2=yes, have_mp4v2=no )
1032
1033     if test "$have_mp4v2" = "yes" -a "$have_mp4_h" = "yes"; then
1034         AC_DEFINE(HAVE_MP4V2, 1, [have mp4v2])
1035         MP4V2_INCLUDES="-I$mp4v2_dir/include"
1036         MP4V2_LIBS="-L$mp4v2_dir/lib -lmp4v2"
1037     else
1038         have_mp4v2=no
1039     fi
1040
1041     CPPFLAGS=$ac_cppflags_save
1042     CXXFLAGS=$ac_cxxflags_save
1043     LDFLAGS=$ac_ldflags_save
1044     AC_LANG_RESTORE
1045 fi
1046
1047 AC_SUBST(MP4V2_INCLUDES)
1048 AC_SUBST(MP4V2_LIBS)
1049
1050 AM_CONDITIONAL(with_mp4v2, [test x$have_mp4v2 != xno ])
1051
1052 ###############################################################################
1053 # END MP4V2 CHECK
1054 ###############################################################################
1055
1056
1057
1058 ###############################################################################
1059 # BEGIN DAAP KDE 3.4 CHECK
1060 ###############################################################################
1061
1062 daapsave_CXXFLAGS="$CXXFLAGS"
1063 CXXFLAGS="$CXXFLAGS $all_includes"
1064 AC_LANG_SAVE
1065 AC_LANG_CPLUSPLUS
1066
1067 AC_MSG_CHECKING([if KDE is at least 3.4 for DAAP support])
1068 AC_COMPILE_IFELSE([
1069 #include <kdeversion.h>
1070 #if ! ( KDE_IS_VERSION( 3, 4, 0 ) )
1071 #error KDE 3.4
1072 #endif
1073 ],
1074     have_kde34="yes"
1075     DNSSD_LIBS=$LIB_KDNSSD
1076 #    echo "yes"
1077 ,
1078     have_kde34="no"
1079     DNSSD_LIBS=""
1080 #    echo "no"
1081 )
1082 CXXFLAGS="$daapsave_CXXFLAGS"
1083 AC_LANG_RESTORE
1084 AC_SUBST(DNSSD_LIBS)
1085 AM_CONDITIONAL(atleast_kde34, [test x$have_kde34 != xno ])
1086 AC_MSG_RESULT($have_kde34)
1087
1088 ###############################################################################
1089 # END DAAP KDE 3.4 CHECK
1090 ###############################################################################
1091
1092
1093
1094 ###############################################################################
1095 # BEGIN OPTIONAL DAAP SUPPORT
1096 ###############################################################################
1097
1098 AC_ARG_WITH(daap,
1099     AC_HELP_STRING([--without-daap],[build Amarok without support for DAAP]),
1100     [have_daap=$withval],
1101     [have_daap=yes]
1102 )
1103
1104 AM_CONDITIONAL(with_daap, [test x$have_daap = xyes])
1105
1106 ###############################################################################
1107 # END OPTIONAL DAAP SUPPORT
1108 ###############################################################################
1109
1110
1111
1112 ###############################################################################
1113 # BEGIN DAAP TYPE CHECKS
1114 ###############################################################################
1115
1116 AC_CHECK_TYPES([uint8_t, u_int8_t, uint16_t, u_int16_t, uint32_t, u_int32_t, uint64_t, u_int64_t])
1117
1118 ###############################################################################
1119 # END DAAP TYPE CHECKS
1120 ###############################################################################
1121
1122
1123
1124 ###############################################################################
1125 # BEGIN DAAP MONGREL RUBY VARIABLE
1126 ###############################################################################
1127
1128 AC_PATH_PROG(RUBY, ruby, no)
1129
1130 ruby_includes=[`$RUBY -rrbconfig -e 'puts Config.expand( Config::MAKEFILE_CONFIG["archdir"] )'`]
1131 ruby_ldflags=[`$RUBY -rrbconfig -e 'puts Config.expand( Config::MAKEFILE_CONFIG["LIBRUBYARG_SHARED"] )'`]
1132
1133 AC_SUBST(ruby_includes)
1134 AC_SUBST(ruby_ldflags)
1135 OLDCFLAGS="$CFLAGS"
1136 CFLAGS="-I$ruby_includes -Wall"
1137 OLDCPPFLAGS="$CPPFLAGS"
1138 CPPFLAGS="-I$ruby_includes" #no I don't know why CPPFLAGS is used
1139 AC_CHECK_HEADERS([ruby.h], [have_ruby_h=yes], [have_ruby_h=no]) #used in ruby check below
1140 CFLAGS="$OLDCFLAGS"
1141 CPPFLAGS="$OLDCPPFLAGS"
1142
1143 ###############################################################################
1144 # END DAAP MONGREL RUBY VARIABLE
1145 ###############################################################################
1146
1147
1148
1149 ###############################################################################
1150 # BEGIN RUBY CHECK
1151 ###############################################################################
1152 ## TODO: Check version number >= 1.8
1153
1154 if test "x$RUBY" = "xno" -o "x$have_ruby_h" = "xno"; then
1155     amarok_error_noruby=yes
1156     DO_NOT_COMPILE="$DO_NOT_COMPILE amarok"
1157     no_amarok=yes
1158 fi
1159
1160 ###############################################################################
1161 # END RUBY CHECK
1162 ###############################################################################
1163
1164
1165 ###############################################################################
1166 # BEGIN DO_NOT_COMPILE CHECK
1167 ###############################################################################
1168
1169 if test x$build_xine = xno -a x$build_helix = xno; then
1170
1171     DO_NOT_COMPILE="$DO_NOT_COMPILE amarok"
1172     no_engine=yes
1173
1174 fi
1175
1176 ###############################################################################
1177 # END DO_NOT_COMPILE CHECK
1178 ###############################################################################
1179