CMakeLists.txt

   1 cmake_minimum_required(VERSION 3.0)
   2 project(alure)
   3
   4 IF(COMMAND CMAKE_POLICY)
   5     CMAKE_POLICY(SET CMP0003 NEW)
   6     CMAKE_POLICY(SET CMP0005 NEW)
   7     IF(POLICY CMP0042)
   8         CMAKE_POLICY(SET CMP0042 NEW)
   9     ENDIF(POLICY CMP0042)
  10 ENDIF(COMMAND CMAKE_POLICY)
  11
  12 set(CMAKE_MODULE_PATH "${alure_SOURCE_DIR}/cmake")
  13
  14 include(CheckCXXCompilerFlag)
  15 include(CheckCXXSourceCompiles)
  16
  17 find_package(OpenAL REQUIRED)
  18
  19 option(ALURE_STATIC_GCCRT "Static-link libgcc and libstdc++ runtimes" OFF)
  20
  21 set(CXX_FLAGS )
  22 check_cxx_compiler_flag(-std=c++11 HAVE_STD_CXX11)
  23 if(HAVE_STD_CXX11)
  24     set(CXX_FLAGS -std=c++11 ${CXX_FLAGS})
  25 endif()
  26
  27 check_cxx_compiler_flag(-Wall HAVE_WALL_SWITCH)
  28 if(HAVE_WALL_SWITCH)
  29     set(CXX_FLAGS ${CXX_FLAGS} -Wall)
  30 endif()
  31 check_cxx_compiler_flag(-Wextra HAVE_WEXTRA_SWITCH)
  32 if(HAVE_WEXTRA_SWITCH)
  33     set(CXX_FLAGS ${CXX_FLAGS} -Wextra)
  34 endif()
  35
  36 check_cxx_compiler_flag(-fno-rtti HAVE_NO_RTTI_SWITCH)
  37 if(HAVE_NO_RTTI_SWITCH)
  38     set(CXX_FLAGS ${CXX_FLAGS} -fno-rtti)
  39 else()
  40     check_cxx_compiler_flag(/GR- HAVE_GRX_SWITCH)
  41     if(HAVE_GRX_SWITCH)
  42         set(CXX_FLAGS ${CXX_FLAGS} /GR-)
  43     endif()
  44 endif()
  45
  46 unset(EXPORT_DECL)
  47 set(VISIBILITY_FLAGS )
  48 if(WIN32)
  49     set(EXPORT_DECL "__declspec(dllexport)")
  50 else()
  51     set(OLD_REQUIRED_FLAGS "${CMAKE_REQUIRED_FLAGS}")
  52     # Yes GCC, really don't accept visibility modes you don't support
  53     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS} -Wattributes -Werror")
  54
  55     check_cxx_source_compiles("int foo() __attribute__((visibility(\"default\")));
  56                                 int main() {return 0;}" HAVE_GCC_DEFAULT_VISIBILITY)
  57     if(HAVE_GCC_DEFAULT_VISIBILITY)
  58         set(EXPORT_DECL "__attribute__((visibility(\"default\")))")
  59     endif()
  60
  61     if(HAVE_GCC_DEFAULT_VISIBILITY)
  62         check_cxx_compiler_flag(-fvisibility=hidden HAVE_VISIBILITY_HIDDEN_SWITCH)
  63         if(HAVE_VISIBILITY_HIDDEN_SWITCH)
  64             set(VISIBILITY_FLAGS ${VISIBILITY_FLAGS} -fvisibility=hidden)
  65         endif()
  66     endif()
  67
  68     set(CMAKE_REQUIRED_FLAGS "${OLD_REQUIRED_FLAGS}")
  69 endif()
  70
  71
  72 set(LINKER_OPTS )
  73 if(ALURE_STATIC_GCCRT)
  74     set(OLD_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES})
  75     set(CMAKE_REQUIRED_LIBRARIES ${CMAKE_REQUIRED_LIBRARIES} -static-libgcc -static-libstdc++)
  76     check_cxx_source_compiles(
  77 "#include <vector>
  78 int main()
  79 {
  80     std::vector<int> test;
  81     return test.size();
  82 }"
  83         HAVE_STATIC_GCCRT_SWITCHES
  84     )
  85     if(HAVE_STATIC_GCCRT_SWITCHES)
  86         set(LINKER_OPTS ${LINKER_OPTS} -static-libgcc -static-libstdc++)
  87     endif()
  88     set(CMAKE_REQUIRED_LIBRARIES ${OLD_REQUIRED_LIBRARIES})
  89     unset(OLD_REQUIRED_LIBRARIES)
  90 endif()
  91
  92
  93 set(alure_srcs src/devicemanager.cpp
  94                src/device.cpp
  95                src/context.cpp
  96                src/buffer.cpp
  97                src/source.cpp
  98                src/sourcegroup.cpp
  99                src/auxeffectslot.cpp
 100                src/effect.cpp
 101 )
 102 set(alure_libs ${OPENAL_LIBRARY})
 103 set(decoder_incls )
 104
 105 unset(HAVE_WAVE)
 106 unset(HAVE_VORBISFILE)
 107 unset(HAVE_LIBFLAC)
 108 unset(HAVE_OPUSFILE)
 109 unset(HAVE_LIBSNDFILE)
 110 unset(HAVE_MPG123)
 111
 112 option(ALURE_ENABLE_WAVE    "Enables the built-in wave file decoder"     ON)
 113 option(ALURE_ENABLE_VORBIS  "Enables the built-in libvorbisfile decoder" ON)
 114 option(ALURE_ENABLE_FLAC    "Enables the built-in FLAC decoder"          ON)
 115 option(ALURE_ENABLE_OPUS    "Enables the built-in libopusfile decoder"   ON)
 116 option(ALURE_ENABLE_SNDFILE "Enables the built-in libsndfile decoder"    ON)
 117 option(ALURE_ENABLE_MPG123  "Enables the built-in libmpg123 decoder"     ON)
 118
 119 if(ALURE_ENABLE_WAVE)
 120     set(alure_srcs ${alure_srcs} src/decoders/wave.cpp)
 121     set(HAVE_WAVE 1)
 122 endif()
 123
 124 find_package(Ogg)
 125 if(OGG_FOUND)
 126     set(decoder_incls ${decoder_incls} ${OGG_INCLUDE_DIRS})
 127     find_package(Vorbis)
 128     if(VORBIS_FOUND AND ALURE_ENABLE_VORBIS)
 129         set(decoder_incls ${decoder_incls} ${VORBIS_INCLUDE_DIRS})
 130         set(alure_libs ${alure_libs} ${VORBIS_LIBRARIES})
 131         set(alure_srcs ${alure_srcs} src/decoders/vorbisfile.cpp)
 132         set(HAVE_VORBISFILE 1)
 133     endif()
 134
 135     find_package(FLAC)
 136     if(FLAC_FOUND AND ALURE_ENABLE_FLAC)
 137         set(decoder_incls ${decoder_incls} ${FLAC_INCLUDE_DIRS})
 138         set(alure_libs ${alure_libs} ${FLAC_LIBRARIES})
 139         set(alure_srcs ${alure_srcs} src/decoders/flac.cpp)
 140         set(HAVE_LIBFLAC 1)
 141     endif()
 142
 143     find_package(Opus)
 144     if(OPUS_FOUND AND ALURE_ENABLE_OPUS)
 145         set(decoder_incls ${decoder_incls} ${OPUS_INCLUDE_DIRS})
 146         set(alure_libs ${alure_libs} ${OPUS_LIBRARIES})
 147         set(alure_srcs ${alure_srcs} src/decoders/opusfile.cpp)
 148         set(HAVE_OPUSFILE 1)
 149     endif()
 150     set(alure_libs ${alure_libs} ${OGG_LIBRARIES})
 151 endif()
 152
 153 find_package(SndFile)
 154 if(SNDFILE_FOUND AND ALURE_ENABLE_SNDFILE)
 155     set(decoder_incls ${decoder_incls} ${SNDFILE_INCLUDE_DIRS})
 156     set(alure_libs ${alure_libs} ${SNDFILE_LIBRARIES})
 157     set(alure_srcs ${alure_srcs} src/decoders/sndfile.cpp)
 158     set(HAVE_LIBSNDFILE 1)
 159 endif()
 160
 161 find_package(MPG123)
 162 if(MPG123_FOUND AND ALURE_ENABLE_MPG123)
 163     set(decoder_incls ${decoder_incls} ${MPG123_INCLUDE_DIRS})
 164     set(alure_libs ${alure_libs} ${MPG123_LIBRARIES})
 165     set(alure_srcs ${alure_srcs} src/decoders/mpg123.cpp)
 166     set(HAVE_MPG123 1)
 167 endif()
 168
 169
 170 CONFIGURE_FILE(
 171     "${alure_SOURCE_DIR}/config.h.in"
 172     "${alure_BINARY_DIR}/config.h")
 173
 174
 175 add_library(alure2 SHARED ${alure_srcs})
 176 if(EXPORT_DECL)
 177     target_compile_definitions(alure2 PRIVATE ALURE_API=${EXPORT_DECL})
 178 endif()
 179 target_include_directories(alure2
 180     PUBLIC ${alure_SOURCE_DIR}/include/AL ${OPENAL_INCLUDE_DIR}
 181     PRIVATE ${alure_SOURCE_DIR}/include ${alure_SOURCE_DIR}/src ${alure_BINARY_DIR}
 182             ${decoder_incls}
 183 )
 184 target_compile_options(alure2 PRIVATE ${CXX_FLAGS} ${VISIBILITY_FLAGS})
 185 target_link_libraries(alure2 PUBLIC ${alure_libs} PRIVATE ${LINKER_OPTS})
 186
 187 add_library(alure2_s STATIC ${alure_srcs})
 188 target_compile_definitions(alure2_s PUBLIC ALURE_STATIC_LIB)
 189 target_include_directories(alure2_s
 190     PUBLIC ${alure_SOURCE_DIR}/include/AL ${OPENAL_INCLUDE_DIR}
 191     PRIVATE ${alure_SOURCE_DIR}/include ${alure_SOURCE_DIR}/src ${alure_BINARY_DIR}
 192             ${decoder_incls}
 193 )
 194 target_compile_options(alure2_s PRIVATE ${CXX_FLAGS} ${VISIBILITY_FLAGS})
 195 target_link_libraries(alure2_s PUBLIC ${alure_libs})
 196
 197 if(NOT DEFINED LIB_SUFFIX)
 198     set(LIB_SUFFIX "")
 199 endif()
 200
 201 install(TARGETS alure2 alure2_s
 202         RUNTIME DESTINATION bin
 203         LIBRARY DESTINATION "lib${LIB_SUFFIX}"
 204         ARCHIVE DESTINATION "lib${LIB_SUFFIX}"
 205 )
 206
 207
 208 option(ALURE_BUILD_EXAMPLES "Build example programs" ON)
 209 if(ALURE_BUILD_EXAMPLES)
 210     add_executable(alure-enum examples/alure-enum.cpp)
 211     target_compile_options(alure-enum PRIVATE ${CXX_FLAGS})
 212     target_link_libraries(alure-enum PRIVATE alure2 ${LINKER_OPTS})
 213
 214     add_executable(alure-play examples/alure-play.cpp)
 215     target_compile_options(alure-play PRIVATE ${CXX_FLAGS})
 216     target_link_libraries(alure-play PRIVATE alure2 ${LINKER_OPTS})
 217
 218     add_executable(alure-stream examples/alure-stream.cpp)
 219     target_compile_options(alure-stream PRIVATE ${CXX_FLAGS})
 220     target_link_libraries(alure-stream PRIVATE alure2 ${LINKER_OPTS})
 221
 222     add_executable(alure-reverb examples/alure-reverb.cpp)
 223     target_compile_options(alure-reverb PRIVATE ${CXX_FLAGS})
 224     target_link_libraries(alure-reverb PRIVATE alure2 ${LINKER_OPTS})
 225
 226     add_executable(alure-hrtf examples/alure-hrtf.cpp)
 227     target_compile_options(alure-hrtf PRIVATE ${CXX_FLAGS})
 228     target_link_libraries(alure-hrtf PRIVATE alure2 ${LINKER_OPTS})
 229
 230     find_package(PhysFS)
 231     if(PHYSFS_FOUND)
 232         add_executable(alure-physfs examples/alure-physfs.cpp)
 233         target_include_directories(alure-physfs PRIVATE ${PHYSFS_INCLUDE_DIR})
 234         target_compile_options(alure-physfs PRIVATE ${CXX_FLAGS})
 235         target_link_libraries(alure-physfs PRIVATE alure2 ${PHYSFS_LIBRARY} ${LINKER_OPTS})
 236     endif()
 237
 238     find_package(DUMB)
 239     if(DUMB_FOUND)
 240         add_executable(alure-dumb examples/alure-dumb.cpp)
 241         target_include_directories(alure-dumb PRIVATE ${DUMB_INCLUDE_DIRS})
 242         target_compile_options(alure-dumb PRIVATE ${CXX_FLAGS})
 243         target_link_libraries(alure-dumb PRIVATE alure2 ${DUMB_LIBRARIES} ${LINKER_OPTS})
 244     endif()
 245 endif()