CMakeLists.txt

   1 #***********************************************************************
   2 #*                   GNU Lesser General Public License
   3 #*
   4 #* This file is part of the GFDL Flexible Modeling System (FMS).
   5 #*
   6 #* FMS is free software: you can redistribute it and/or modify it under
   7 #* the terms of the GNU Lesser General Public License as published by
   8 #* the Free Software Foundation, either version 3 of the License, or (at
   9 #* your option) any later version.
  10 #*
  11 #* FMS is distributed in the hope that it will be useful, but WITHOUT
  12 #* ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
  13 #* FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  14 #* for more details.
  15 #*
  16 #* You should have received a copy of the GNU Lesser General Public
  17 #* License along with FMS.  If not, see <http://www.gnu.org/licenses/>.
  18 #***********************************************************************
  19
  20 # Copyright (c) GFDL, @underwoo
  21
  22 cmake_minimum_required(VERSION 3.12 FATAL_ERROR)
  23
  24 # add build type for debug, overrides default flags (set with $FCFLAGS, $CFLAGS)
  25 set(CMAKE_Fortran_FLAGS_DEBUG)
  26
  27 # Define the CMake project
  28 project(FMS
  29   VERSION 2023.04.0
  30   DESCRIPTION  "GFDL FMS Library"
  31   HOMEPAGE_URL "https://www.gfdl.noaa.gov/fms"
  32   LANGUAGES C Fortran)
  33
  34 include(GNUInstallDirs)
  35
  36 if(NOT CMAKE_BUILD_TYPE MATCHES "^(Debug|Release|RelWithDebInfo|MinSizeRel)$")
  37   message(STATUS "Setting build type to 'Release' as none was specified.")
  38   set(CMAKE_BUILD_TYPE
  39       "Release"
  40       CACHE STRING "Choose the type of build." FORCE)
  41   set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS "Debug" "Release" "MinSizeRel" "RelWithDebInfo")
  42 endif()
  43
  44 if(NOT CMAKE_C_COMPILER_ID MATCHES "^(Intel|GNU|Clang|IntelLLVM)$")
  45   message(
  46     WARNING "Compiler not officially supported: ${CMAKE_C_COMPILER_ID}")
  47 endif()
  48
  49 if(NOT CMAKE_Fortran_COMPILER_ID MATCHES "^(Intel|GNU|IntelLLVM)$")
  50   message(
  51     WARNING "Compiler not officially supported: ${CMAKE_Fortran_COMPILER_ID}")
  52 endif()
  53
  54 # Append directory that contains CMake Modules for building FMS
  55 list(APPEND CMAKE_MODULE_PATH ${CMAKE_CURRENT_SOURCE_DIR}/cmake)
  56
  57 # Build options
  58 option(OPENMP "Build FMS with OpenMP support"        OFF)
  59 option(32BIT  "Build 32-bit (r4) FMS library"         ON)
  60 option(64BIT  "Build 64-bit (r8) FMS library"        OFF)
  61 option(FPIC   "Build with position independent code" OFF)
  62
  63 # Options for compiler definitions
  64 option(INTERNAL_FILE_NML     "Enable compiler definition -DINTERNAL_FILE_NML"      ON)
  65 option(ENABLE_QUAD_PRECISION "Enable compiler definition -DENABLE_QUAD_PRECISION"  ON)
  66 option(GFS_PHYS              "Enable compiler definition -DGFS_PHYS"              OFF)
  67 option(LARGEFILE             "Enable compiler definition -Duse_LARGEFILE"         OFF)
  68 option(WITH_YAML             "Enable compiler definition -Duse_yaml"              OFF)
  69 option(USE_DEPRECATED_IO     "Enable compiler definition -Duse_deprecated_io (compile with fms_io/mpp_io)"   OFF)
  70
  71 if(32BIT)
  72   list(APPEND kinds "r4")
  73 endif()
  74 if(64BIT)
  75   list(APPEND kinds "r8")
  76 endif()
  77 if(NOT kinds)
  78   message(STATUS "Single Precision 32BIT: ${32BIT}")
  79   message(STATUS "Double Precision 64BIT: ${64BIT}")
  80   message(FATAL_ERROR "Either 32BIT or 64BIT should be ON")
  81 endif()
  82
  83 # Find dependencies
  84 find_package(MPI REQUIRED COMPONENTS C Fortran)
  85 find_package(NetCDF REQUIRED COMPONENTS C Fortran)
  86
  87 # Check for the OpenMP library and set the required compile flags
  88 if (OPENMP)
  89   find_package(OpenMP REQUIRED COMPONENTS C Fortran)
  90 endif()
  91
  92 if (WITH_YAML)
  93   find_package(libyaml REQUIRED)
  94   include_directories(${LIBYAML_INCLUDE_DIR})
  95 endif ()
  96
  97 # Enables position independent code (i.e., -fPIC)
  98 if (FPIC)
  99   set(CMAKE_POSITION_INDEPENDENT_CODE ON)
 100 endif ()
 101
 102 # Collect FMS Fortran source files
 103 list(APPEND fms_fortran_src_files
 104   affinity/fms_affinity.F90
 105   amip_interp/amip_interp.F90
 106   astronomy/astronomy.F90
 107   axis_utils/axis_utils.F90
 108   axis_utils/axis_utils2.F90
 109   block_control/block_control.F90
 110   column_diagnostics/column_diagnostics.F90
 111   constants/constants.F90
 112   constants/fmsconstants.F90
 113   constants4/constantsr4.F90
 114   constants4/fmsconstantsr4.F90
 115   coupler/atmos_ocean_fluxes.F90
 116   coupler/coupler_types.F90
 117   coupler/ensemble_manager.F90
 118   data_override/get_grid_version.F90
 119   data_override/data_override.F90
 120   diag_integral/diag_integral.F90
 121   diag_manager/diag_axis.F90
 122   diag_manager/diag_data.F90
 123   diag_manager/diag_grid.F90
 124   diag_manager/diag_manager.F90
 125   diag_manager/diag_output.F90
 126   diag_manager/diag_table.F90
 127   diag_manager/diag_util.F90
 128   diag_manager/fms_diag_time_reduction.F90
 129   diag_manager/fms_diag_outfield.F90
 130   diag_manager/fms_diag_elem_weight_procs.F90
 131   diag_manager/fms_diag_fieldbuff_update.F90
 132   diag_manager/fms_diag_bbox.F90
 133   diag_manager/fms_diag_time_utils.F90
 134   diag_manager/fms_diag_object.F90
 135   diag_manager/fms_diag_yaml.F90
 136   diag_manager/fms_diag_file_object.F90
 137   diag_manager/fms_diag_field_object.F90
 138   diag_manager/fms_diag_axis_object.F90
 139   diag_manager/fms_diag_dlinked_list.F90
 140   diag_manager/fms_diag_object_container.F90
 141   diag_manager/fms_diag_buffer.F90
 142   drifters/cloud_interpolator.F90
 143   drifters/drifters.F90
 144   drifters/drifters_comm.F90
 145   drifters/drifters_core.F90
 146   drifters/drifters_input.F90
 147   drifters/drifters_io.F90
 148   drifters/quicksort.F90
 149   exchange/stock_constants.F90
 150   exchange/xgrid.F90
 151   field_manager/field_manager.F90
 152   field_manager/fm_util.F90
 153   field_manager/fm_yaml.F90
 154   fms/fms_io.F90
 155   fms/fms.F90
 156   fms2_io/blackboxio.F90
 157   fms2_io/fms_io_utils.F90
 158   fms2_io/fms_netcdf_domain_io.F90
 159   fms2_io/fms_netcdf_unstructured_domain_io.F90
 160   fms2_io/fms2_io.F90
 161   fms2_io/netcdf_io.F90
 162   horiz_interp/horiz_interp_bicubic.F90
 163   horiz_interp/horiz_interp_bilinear.F90
 164   horiz_interp/horiz_interp_conserve.F90
 165   horiz_interp/horiz_interp_spherical.F90
 166   horiz_interp/horiz_interp_type.F90
 167   horiz_interp/horiz_interp.F90
 168   interpolator/interpolator.F90
 169   memutils/memutils.F90
 170   monin_obukhov/monin_obukhov_inter.F90
 171   monin_obukhov/monin_obukhov.F90
 172   mosaic/gradient.F90
 173   mosaic/grid.F90
 174   mosaic/mosaic.F90
 175   mosaic2/grid2.F90
 176   mosaic2/mosaic2.F90
 177   mpp/mpp.F90
 178   mpp/mpp_data.F90
 179   mpp/mpp_domains.F90
 180   mpp/mpp_efp.F90
 181   mpp/mpp_io.F90
 182   mpp/mpp_memutils.F90
 183   mpp/mpp_parameter.F90
 184   mpp/mpp_utilities.F90
 185   parser/yaml_parser.F90
 186   parser/fms_yaml_output.F90
 187   platform/platform.F90
 188   random_numbers/mersennetwister.F90
 189   random_numbers/random_numbers.F90
 190   sat_vapor_pres/sat_vapor_pres_k.F90
 191   sat_vapor_pres/sat_vapor_pres.F90
 192   string_utils/fms_string_utils.F90
 193   time_interp/time_interp_external.F90
 194   time_interp/time_interp_external2.F90
 195   time_interp/time_interp.F90
 196   time_manager/get_cal_time.F90
 197   time_manager/time_manager.F90
 198   topography/gaussian_topog.F90
 199   topography/topography.F90
 200   tracer_manager/tracer_manager.F90
 201   tridiagonal/tridiagonal.F90
 202   libFMS.F90
 203 )
 204
 205 # Collect FMS C source files
 206 list(APPEND fms_c_src_files
 207   affinity/affinity.c
 208   fms/fms_stacksize.c
 209   mosaic/create_xgrid.c
 210   mosaic/gradient_c2l.c
 211   mosaic/interp.c
 212   mosaic/mosaic_util.c
 213   mosaic/read_mosaic.c
 214   mpp/mpp_memuse.c
 215   parser/yaml_parser_binding.c
 216   parser/yaml_output_functions.c
 217   string_utils/fms_string_utils_binding.c
 218 )
 219
 220 # Collect FMS header files
 221 list(APPEND fms_header_files
 222   include/file_version.h
 223   include/fms_platform.h
 224 )
 225
 226 # Standard FMS compiler definitions
 227 list(APPEND fms_defs
 228   use_libMPI
 229   use_netCDF)
 230
 231 # check gettid
 232 include(CheckFunctionExists)
 233 check_function_exists(gettid HAVE_GETTID)
 234 if(HAVE_GETTID)
 235   list(APPEND fms_defs HAVE_GETTID)
 236 endif()
 237
 238 # Additional (optional) compiler definitions
 239 if(NOT CONSTANTS)
 240     set(CONSTANTS GFDL)
 241 endif()
 242 if(CONSTANTS STREQUAL "GFS")
 243   list(APPEND fms_defs GFS_CONSTANTS)
 244 elseif(CONSTANTS STREQUAL "GEOS")
 245   list(APPEND fms_defs GEOS_CONSTANTS)
 246 elseif(CONSTANTS STREQUAL "GFDL")
 247   list(APPEND fms_defs GFDL_CONSTANTS)
 248 else()
 249   message(FATAL_ERROR "CONSTANTS=${CONSTANTS} option not supported")
 250 endif()
 251
 252 if(GFS_PHYS)
 253   list(APPEND fms_defs GFS_PHYS)
 254 endif()
 255
 256 if(WITH_YAML)
 257   list(APPEND fms_defs use_yaml)
 258 endif()
 259
 260 if(USE_DEPRECATED_IO)
 261   list(APPEND fms_defs use_deprecated_io)
 262 endif()
 263
 264 if(INTERNAL_FILE_NML)
 265   list(APPEND fms_defs INTERNAL_FILE_NML)
 266 endif()
 267
 268 if(ENABLE_QUAD_PRECISION)
 269   list(APPEND fms_defs ENABLE_QUAD_PRECISION)
 270 endif()
 271
 272 if(LARGEFILE)
 273   list(APPEND fms_defs use_LARGEFILE)
 274 endif()
 275
 276 # Precision-based compiler definitions
 277 if(32BIT)
 278   list(APPEND r4_defs OVERLOAD_R4 OVERLOAD_R8)
 279 endif()
 280
 281 # Add platform specific compiler definitions
 282 if(APPLE)
 283   list(APPEND fms_defs __APPLE__)
 284 endif()
 285
 286 # Obtain compiler-specific flags
 287 include(fms_compiler_flags)
 288
 289 foreach(kind ${kinds})
 290
 291   set(libTgt fms_${kind})
 292   set(includeDir "include_${kind}")
 293   set(moduleDir "${CMAKE_CURRENT_BINARY_DIR}/${includeDir}")
 294
 295   # C
 296   add_library(${libTgt}_c OBJECT ${fms_c_src_files})
 297
 298   target_include_directories(${libTgt}_c PRIVATE include)
 299   target_compile_definitions(${libTgt}_c PRIVATE "${fms_defs}")
 300
 301   target_link_libraries(${libTgt}_c PRIVATE NetCDF::NetCDF_C
 302                                             MPI::MPI_C)
 303
 304   if(OpenMP_C_FOUND)
 305     target_link_libraries(${libTgt}_c PRIVATE OpenMP::OpenMP_C)
 306   endif()
 307
 308   # Fortran
 309   add_library(${libTgt}_f OBJECT ${fms_fortran_src_files})
 310
 311   target_include_directories(${libTgt}_f PRIVATE include
 312                                                  fms
 313                                                  fms/include
 314                                                  fms2_io/include
 315                                                  string_utils/include
 316                                                  mpp/include
 317                                                  column_diagnostics/include
 318                                                  monin_obukhov/include
 319                                                  sat_vapor_pres/include
 320                                                  horiz_interp/include
 321                                                  diag_integral/include
 322                                                  random_numbers/include
 323                                                  diag_manager/include
 324                                                  constants4
 325                                                  topography/include
 326                                                  axis_utils/include
 327                                                  mosaic2/include
 328                                                  constants
 329                                                  astronomy/include
 330                                                  field_manager/include
 331                                                  time_interp/include
 332                                                  tracer_manager/include
 333                                                  tridiagonal/include
 334                                                  interpolator/include
 335                                                  coupler/include
 336                                                  data_override/include
 337                                                  amip_interp/include)
 338
 339   target_compile_definitions(${libTgt}_f PRIVATE "${fms_defs}")
 340   target_compile_definitions(${libTgt}_f PRIVATE "${${kind}_defs}")
 341
 342   string(TOLOWER ${CMAKE_BUILD_TYPE} build_type)
 343   if (NOT build_type STREQUAL debug)
 344     set_target_properties(${libTgt}_f PROPERTIES COMPILE_FLAGS
 345                                                "${${kind}_flags}")
 346   endif()
 347   set_target_properties(${libTgt}_f PROPERTIES Fortran_MODULE_DIRECTORY
 348                                                ${moduleDir})
 349
 350   target_link_libraries(${libTgt}_f PRIVATE NetCDF::NetCDF_Fortran
 351                                             MPI::MPI_Fortran)
 352
 353   if(OpenMP_Fortran_FOUND)
 354     target_link_libraries(${libTgt}_f PRIVATE OpenMP::OpenMP_Fortran)
 355   endif()
 356
 357   # Check if gnu 10 or higher
 358   # this should only be needed with mpich, but wasn't able to find a good way to find the MPI flavor consistently
 359   if ( CMAKE_Fortran_COMPILER_VERSION MATCHES "1[0-9]\.[0-9]*\.[0-9]*" AND CMAKE_Fortran_COMPILER_ID MATCHES "GNU")
 360     include(CheckFortranCompilerFlag)
 361     check_fortran_compiler_flag("-fallow-argument-mismatch" _arg_mismatch_flag)
 362     if(_arg_mismatch_flag)
 363       message(STATUS "Adding -fallow-argument-mismatch flag to compile with GCC >=10 and MPICH")
 364       target_compile_options(${libTgt}_f PRIVATE "-fallow-argument-mismatch;-w")
 365     endif()
 366   endif()
 367
 368   # FMS (C + Fortran)
 369   add_library(${libTgt} STATIC $<TARGET_OBJECTS:${libTgt}_c>
 370                                $<TARGET_OBJECTS:${libTgt}_f>)
 371
 372   target_include_directories(${libTgt} PUBLIC
 373     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
 374     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/fms>
 375     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/fms/include>
 376     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/fms2_io/include>
 377     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/column_diagnostics/include>
 378     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/astronomy/include>
 379     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/monin_obukhov/include>
 380     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/sat_vapor_pres/include>
 381     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/field_manager/include>
 382     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/horiz_interp/include>
 383     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mosaic2/include>
 384     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/string_utils/include>
 385     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mpp/include>
 386     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/diag_manager/include>
 387     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/topography/include>
 388     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/random_numbers/include>
 389     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/diag_integral/include>
 390     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/diag_manager/include>
 391     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/tracer_manager/include>
 392     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/interpolator/include>
 393     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/coupler/include>
 394     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/mosaic2/include>
 395     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/data_override/include>
 396     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/tridiagonal/include>
 397     $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/amip_interp/include>)
 398
 399   target_include_directories(${libTgt} INTERFACE
 400     $<BUILD_INTERFACE:${moduleDir}>
 401     $<INSTALL_INTERFACE:${includeDir}>)
 402
 403   target_compile_definitions(${libTgt} PRIVATE "${fms_defs}")
 404   target_compile_definitions(${libTgt} PRIVATE "${${kind}_defs}")
 405
 406   target_link_libraries(${libTgt} PUBLIC NetCDF::NetCDF_Fortran
 407                                          MPI::MPI_Fortran)
 408
 409   if(OpenMP_Fortran_FOUND)
 410     target_link_libraries(${libTgt} PRIVATE OpenMP::OpenMP_C OpenMP::OpenMP_Fortran)
 411   endif()
 412
 413   add_library(FMS::${libTgt} ALIAS ${libTgt})
 414
 415   list(APPEND LIB_TARGETS ${libTgt})
 416   install(DIRECTORY ${moduleDir}    DESTINATION ${CMAKE_INSTALL_PREFIX})
 417   install(FILES ${fms_header_files} DESTINATION ${CMAKE_INSTALL_PREFIX}/${includeDir})
 418
 419 endforeach()
 420
 421 install(
 422   TARGETS ${LIB_TARGETS}
 423   EXPORT FMSExports
 424   RUNTIME DESTINATION bin
 425   LIBRARY DESTINATION lib
 426   ARCHIVE DESTINATION lib)
 427
 428 ### Package config
 429 include(CMakePackageConfigHelpers)
 430 set(CONFIG_INSTALL_DESTINATION lib/cmake/fms)
 431
 432 export(EXPORT FMSExports
 433   NAMESPACE FMS::
 434   FILE fms-targets.cmake)
 435
 436 configure_package_config_file(
 437   ${CMAKE_CURRENT_SOURCE_DIR}/cmake/FMSConfig.cmake.in ${CMAKE_CURRENT_BINARY_DIR}/fms-config.cmake
 438   INSTALL_DESTINATION ${CONFIG_INSTALL_DESTINATION})
 439 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/fms-config.cmake
 440   DESTINATION ${CONFIG_INSTALL_DESTINATION})
 441
 442 write_basic_package_version_file(
 443   ${CMAKE_CURRENT_BINARY_DIR}/fms-config-version.cmake
 444   VERSION ${PROJECT_VERSION}
 445   COMPATIBILITY AnyNewerVersion)
 446 install(FILES ${CMAKE_CURRENT_BINARY_DIR}/fms-config-version.cmake
 447   DESTINATION ${CONFIG_INSTALL_DESTINATION})
 448
 449 install(EXPORT FMSExports
 450   NAMESPACE FMS::
 451   FILE fms-targets.cmake
 452   DESTINATION ${CONFIG_INSTALL_DESTINATION})