m4/wm_xext_check.m4

   1 # wm_xext_check.m4 - Macros to check for X extensions support libraries
   2 #
   3 # Copyright (c) 2013 Christophe CURIS
   4 #
   5 # This program is free software; you can redistribute it and/or modify
   6 # it under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 2 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # This program is distributed in the hope that it will be useful,
  11 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with this program; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 # WM_XEXT_CHECK_XSHAPE
  20 # --------------------
  21 #
  22 # Check for the X Shaped Window extension
  23 # The check depends on variable 'enable_xshape' being either:
  24 #   yes  - detect, fail if not found
  25 #   no   - do not detect, disable support
  26 #   auto - detect, disable if not found
  27 #
  28 # When found, append appropriate stuff in XLIBS, and append info to
  29 # the variable 'supported_xext'
  30 # When not found, append info to variable 'unsupported'
  31 AC_DEFUN_ONCE([WM_XEXT_CHECK_XSHAPE],
  32 [WM_LIB_CHECK([XShape], [-lXext], [XShapeSelectInput], [$XLIBS],
  33     [wm_save_CFLAGS="$CFLAGS"
  34      AS_IF([wm_fn_lib_try_compile "X11/extensions/shape.h" "Window win;" "XShapeSelectInput(NULL, win, 0)" ""],
  35         [],
  36         [AC_MSG_ERROR([found $CACHEVAR but cannot compile using XShape header])])
  37      CFLAGS="$wm_save_CFLAGS"],
  38     [supported_xext], [XLIBS], [enable_shape], [-])dnl
  39 ]) dnl AC_DEFUN
  40
  41
  42 # WM_XEXT_CHECK_XSHM
  43 # ------------------
  44 #
  45 # Check for the MIT-SHM extension for Shared Memory support
  46 # The check depends on variable 'enable_shm' being either:
  47 #   yes  - detect, fail if not found
  48 #   no   - do not detect, disable support
  49 #   auto - detect, disable if not found
  50 #
  51 # When found, append appropriate stuff in XLIBS, and append info to
  52 # the variable 'supported_xext'
  53 # When not found, append info to variable 'unsupported'
  54 AC_DEFUN_ONCE([WM_XEXT_CHECK_XSHM],
  55 [WM_LIB_CHECK([XShm], [-lXext], [XShmAttach], [$XLIBS],
  56     [wm_save_CFLAGS="$CFLAGS"
  57      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([dnl
  58 @%:@include <X11/Xlib.h>
  59 @%:@include <X11/extensions/XShm.h>
  60 ], [dnl
  61   XShmSegmentInfo si;
  62
  63   XShmAttach(NULL, &si);])],
  64         [],
  65         [AC_MSG_ERROR([found $CACHEVAR but cannot compile using XShm header])])
  66      AC_COMPILE_IFELSE([AC_LANG_PROGRAM([dnl
  67 @%:@include <sys/ipc.h>
  68 @%:@include <sys/shm.h>
  69 ], [dnl
  70   shmget(IPC_PRIVATE, 1024, IPC_CREAT);])],
  71         [],
  72         [AC_MSG_ERROR([found $CACHEVAR but cannot compile using ipc/shm headers])])
  73      CFLAGS="$wm_save_CFLAGS"],
  74     [supported_xext], [XLIBS], [enable_shm], [-])dnl
  75 ]) dnl AC_DEFUN
  76
  77
  78 # WM_XEXT_CHECK_XINERAMA
  79 # ----------------------
  80 #
  81 # Check for the Xinerama extension for multiscreen-as-one support
  82 # The check depends on variable 'enable_xinerama' being either:
  83 #   yes  - detect, fail if not found
  84 #   no   - do not detect, disable support
  85 #   auto - detect, disable if not found
  86 #
  87 # When found, append appropriate stuff in LIBXINERAMA, and append info to
  88 # the variable 'supported_xext'
  89 # When not found, append info to variable 'unsupported'
  90 AC_DEFUN_ONCE([WM_XEXT_CHECK_XINERAMA],
  91 [LIBXINERAMA=""
  92 AS_IF([test "x$enable_xinerama" = "xno"],
  93     [unsupported="$unsupported Xinerama"],
  94     [AC_CACHE_CHECK([for Xinerama support library], [wm_cv_xext_xinerama],
  95         [wm_cv_xext_xinerama=no
  96          dnl
  97          dnl We check that the library is available
  98          wm_save_LIBS="$LIBS"
  99          for wm_arg in dnl
 100 dnl           Lib flag   % Function name        % info
 101              "-lXinerama % XineramaQueryScreens" dnl
 102              "-lXext     % XineramaGetInfo      % solaris" ; do
 103            AS_IF([wm_fn_lib_try_link "`echo "$wm_arg" | dnl
 104 sed -e 's,^[[^%]]*% *,,' | sed -e 's, *%.*$,,' `" dnl
 105 "$XLFLAGS $XLIBS `echo "$wm_arg" | sed -e 's, *%.*$,,' `"],
 106              [wm_cv_xext_xinerama="`echo "$wm_arg" | sed -e 's, *%[[^%]]*, ,' `"
 107               break])
 108          done
 109          LIBS="$wm_save_LIBS"
 110          AS_IF([test "x$enable_xinerama$wm_cv_xext_xinerama" = "xyesno"],
 111             [AC_MSG_ERROR([explicit Xinerama support requested but no library found])])
 112          dnl
 113          dnl A library was found, check if header is available and compile
 114          wm_save_CFLAGS="$CFLAGS"
 115          AS_CASE([`echo "$wm_cv_xext_xinerama" | sed -e 's,^[[^%]]*,,' `],
 116              [*solaris*], [wm_header="X11/extensions/xinerama.h" ; wm_fct="XineramaGetInfo(NULL, 0, NULL, NULL, &intval)"],
 117              [wm_header="X11/extensions/Xinerama.h" ; wm_fct="XineramaQueryScreens(NULL, &intval)"])
 118          AS_IF([wm_fn_lib_try_compile "$wm_header" "int intval;" "$wm_fct" ""],
 119              [],
 120              [AC_MSG_ERROR([found $wm_cv_xext_xinerama but cannot compile with the header])])
 121          AS_UNSET([wm_header])
 122          AS_UNSET([wm_fct])
 123          CFLAGS="$wm_save_CFLAGS"])
 124      AS_IF([test "x$wm_cv_xext_xinerama" = "xno"],
 125         [unsupported="$unsupported Xinerama"
 126          enable_xinerama="no"],
 127         [LIBXINERAMA="`echo "$wm_cv_xext_xinerama" | sed -e 's, *%.*$,,' `"
 128          AC_DEFINE([USE_XINERAMA], [1],
 129              [defined when usable Xinerama library with header was found])
 130          AS_CASE([`echo "$wm_cv_xext_xinerama" | sed -e 's,^[[^%]]*,,' `],
 131              [*solaris*], [AC_DEFINE([SOLARIS_XINERAMA], [1],
 132                  [defined when the Solaris Xinerama extension was detected])])
 133          supported_xext="$supported_xext Xinerama"])
 134     ])
 135 AC_SUBST(LIBXINERAMA)dnl
 136 ])
 137
 138
 139 # WM_XEXT_CHECK_XRANDR
 140 # --------------------
 141 #
 142 # Check for the X RandR (Resize-and-Rotate) extension
 143 # The check depends on variable 'enable_xrandr' being either:
 144 #   yes  - detect, fail if not found
 145 #   no   - do not detect, disable support
 146 #   auto - detect, disable if not found
 147 #
 148 # When found, append appropriate stuff in LIBXRANDR, and append info to
 149 # the variable 'supported_xext'
 150 # When not found, append info to variable 'unsupported'
 151 AC_DEFUN_ONCE([WM_XEXT_CHECK_XRANDR],
 152 [WM_LIB_CHECK([XRandR], [-lXrandr], [XRRQueryExtension], [$XLIBS],
 153     [wm_save_CFLAGS="$CFLAGS"
 154      AS_IF([wm_fn_lib_try_compile "X11/extensions/Xrandr.h" "Display *dpy;" "XRRQueryExtension(dpy, NULL, NULL)" ""],
 155         [],
 156         [AC_MSG_ERROR([found $CACHEVAR but cannot compile using XRandR header])])
 157      CFLAGS="$wm_save_CFLAGS"],
 158     [supported_xext], [LIBXRANDR], [], [-])dnl
 159 AC_SUBST([LIBXRANDR])dnl
 160 ]) dnl AC_DEFUN