configure.ac

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(WindowMaker, 0.95.5, , WindowMaker, http://www.windowmaker.org/)
  15 AC_CONFIG_SRCDIR(src/WindowMaker.h)
  16 AC_CONFIG_MACRO_DIR([m4])
  17 AC_CONFIG_HEADERS(config.h)
  18 AM_INIT_AUTOMAKE([1.11 silent-rules])
  19
  20 AH_BOTTOM([#include "config-paths.h"])
  21
  22 dnl libtool library versioning
  23 dnl =======================
  24 dnl
  25 dnl current
  26 dnl revision
  27 dnl age
  28 dnl
  29 dnl 1. Start with version information of ‘0:0:0’ for each libtool library.
  30 dnl 2. Update the version information only immediately before a public
  31 dnl release of your software. More frequent updates are unnecessary, and
  32 dnl only guarantee that the current interface number gets larger faster.
  33 dnl 3. If the library source code has changed at all since the last
  34 dnl update, then increment revision (‘c:r:a’ becomes ‘c:r+1:a’).
  35 dnl 4. If any interfaces have been added, removed, or changed since the
  36 dnl last update, increment current, and set revision to 0.
  37 dnl 5. If any interfaces have been added since the last public release,
  38 dnl then increment age.
  39 dnl 6. If any interfaces have been removed or changed since the last
  40 dnl public release, then set age to 0.
  41 dnl
  42 dnl libwraster
  43 WRASTER_CURRENT=4
  44 WRASTER_REVISION=1
  45 WRASTER_AGE=1
  46 WRASTER_VERSION=$WRASTER_CURRENT:$WRASTER_REVISION:$WRASTER_AGE
  47 AC_SUBST(WRASTER_VERSION)
  48 dnl
  49 dnl libWINGs
  50 WINGS_CURRENT=2
  51 WINGS_REVISION=1
  52 WINGS_AGE=0
  53 WINGS_VERSION=$WINGS_CURRENT:$WINGS_REVISION:$WINGS_AGE
  54 AC_SUBST(WINGS_VERSION)
  55 dnl
  56 dnl libWUtil
  57 WUTIL_CURRENT=4
  58 WUTIL_REVISION=0
  59 WUTIL_AGE=0
  60 WUTIL_VERSION=$WUTIL_CURRENT:$WUTIL_REVISION:$WUTIL_AGE
  61 AC_SUBST(WUTIL_VERSION)
  62
  63
  64 dnl Checks for host/os name
  65 dnl =======================
  66 dnl AC_CANONICAL_HOST -- already done by AC_PROG_LIBTOOL
  67
  68 dnl Checks for programs.
  69 dnl ===================
  70 AC_PROG_CC
  71 WM_PROG_CC_C11
  72 AC_PROG_LN_S
  73 AC_PROG_GCC_TRADITIONAL
  74 AC_PROG_LIBTOOL
  75
  76
  77 dnl Debugging Options
  78 dnl =================
  79 AC_ARG_ENABLE(debug,
  80     [AS_HELP_STRING([--enable-debug], [enable debugging options, @<:@default=no@:>@])],
  81     [AS_CASE(["$enableval"],
  82         [yes], [debug=yes],
  83         [no],  [debug=no],
  84         [AC_MSG_ERROR([bad value $enableval for --enable-debug])] )],
  85     [debug=no])
  86 AS_IF([test "x$debug" = "xyes"],
  87     [dnl This flag should have already been detected and added, but if user
  88      dnl provided an explicit CFLAGS it may not be the case
  89      AS_IF([echo " $CFLAGS " | grep " -g " 2>&1 > /dev/null],
  90            [@%:@ Debug symbol already activated],
  91            [AX_CFLAGS_GCC_OPTION([-g])])
  92      dnl
  93      dnl This flag generally makes debugging nightmarish, remove it if present
  94      CFLAGS="`echo "$CFLAGS" | sed -e 's/-fomit-frame-pointer *//' `"
  95      dnl
  96      dnl Enable internal debug code
  97      CPPFLAGS="$CPPFLAGS -DDEBUG"
  98 ],  [dnl
  99      dnl When debug is not enabled, the user probably does not wants to keep
 100      dnl assertions in the final program
 101      CPPFLAGS="$CPPFLAGS -DNDEBUG"
 102 ])
 103
 104
 105 AX_CFLAGS_GCC_OPTION(-Wall)
 106 AX_CFLAGS_GCC_OPTION(-Wextra -Wno-sign-compare)
 107 AS_IF([test "x$debug" = "xyes"],
 108     [dnl When debug is enabled, we try to activate more checks from
 109      dnl the compiler. They are on independant check because the
 110      dnl macro checks all the options at once, but we may have cases
 111      dnl where some options are not supported and we don't want to
 112      dnl loose all of them.
 113      dnl
 114      dnl Floating-point comparison is not a good idea
 115      AX_CFLAGS_GCC_OPTION([-Wfloat-equal])
 116      dnl
 117      dnl Try to report misuses of '&' versus '&&' and similar
 118      AX_CFLAGS_GCC_OPTION([-Wlogical-op])
 119      dnl
 120      dnl Reports declaration of global things that are done inside
 121      dnl a local environment, instead of using the appropriate
 122      dnl header
 123      AX_CFLAGS_GCC_OPTION([-Wnested-externs])
 124      dnl
 125      dnl Use of 'sizeof()' on inappropriate pointer types
 126      AX_CFLAGS_GCC_OPTION([-Wpointer-arith])
 127      dnl
 128      dnl Having more than 1 prototype for a function makes code updates
 129      dnl more difficult, so try to avoid it
 130      AX_CFLAGS_GCC_OPTION([-Wredundant-decls])
 131      dnl
 132      dnl Proper attributes helps the compiler to produce better code
 133      WM_CFLAGS_CHECK_FIRST([format attribute suggest],
 134          [-Wsuggest-attribute=format  dnl new gcc syntax
 135           -Wmissing-format-attribute  dnl old gcc syntax, clang
 136          ])
 137      WM_CFLAGS_CHECK_FIRST([no-return attribute suggest],
 138          [-Wsuggest-attribute=noreturn  dnl gcc syntax
 139           -Wmissing-noreturn            dnl clang syntax
 140          ])
 141      dnl
 142      dnl The use of trampolines cause code that can crash on some
 143      dnl secured OS, and in a more general way generate binary code
 144      dnl that may not be optimal
 145      AX_CFLAGS_GCC_OPTION([-Wtrampolines])
 146 ], [dnl
 147      dnl When debug not enabled, we try to avoid some non-necessary
 148      dnl messages from the compiler
 149      dnl
 150      dnl To support legacy X servers, we have sometime to use
 151      dnl functions marked as deprecated. We do not wish our users
 152      dnl to be worried about it
 153      AX_CFLAGS_GCC_OPTION([-Wno-deprecated])
 154      AX_CFLAGS_GCC_OPTION([-Wno-deprecated-declarations])
 155 ])
 156
 157
 158 dnl Tracking on what is detected for final status
 159 dnl =============================================
 160 unsupported=""
 161 supported_xext=""
 162 supported_gfx=""
 163
 164
 165 dnl Platform-specific Makefile setup
 166 dnl ================================
 167 AS_CASE(["$host"],
 168     [*-*-linux*|*-*-cygwin*|*-gnu*], [WM_OSDEP="linux" ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600"],
 169     [*-*-freebsd*|*-k*bsd-gnu*],     [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -D_XOPEN_SOURCE=600 -DFREEBSD"],
 170     [*-*-netbsd*],                   [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DNETBSD"],
 171     [*-*-openbsd*],                  [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DOPENBSD"],
 172     [*-*-dragonfly*],                [WM_OSDEP="bsd"   ; CPPFLAGS="$CPPFLAGS -DDRAGONFLYBSD"],
 173     [*-apple-darwin*],               [WM_OSDEP="darwin"],
 174     [*-*-solaris*],                  [WM_OSDEP="stub"],  dnl  solaris.c when done
 175     [WM_OSDEP="stub"])
 176 AM_CONDITIONAL([WM_OSDEP_LINUX],   [test "x$WM_OSDEP" = "xlinux"])
 177 AM_CONDITIONAL([WM_OSDEP_BSD],     [test "x$WM_OSDEP" = "xbsd"])
 178 AM_CONDITIONAL([WM_OSDEP_DARWIN],  [test "x$WM_OSDEP" = "xdarwin"])
 179 AM_CONDITIONAL([WM_OSDEP_GENERIC], [test "x$WM_OSDEP" = "xstub"])
 180
 181
 182 dnl the prefix
 183 dnl ==========
 184 dnl
 185 dnl move this earlier in the script... anyone know why this is handled
 186 dnl in such a bizarre way?
 187
 188 test "x$prefix" = xNONE && prefix=$ac_default_prefix
 189 dnl Let make expand exec_prefix.
 190 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
 191
 192
 193 _bindir=`eval echo $bindir`
 194 _bindir=`eval echo $_bindir`
 195
 196 lib_search_path='-L${libdir}'
 197
 198 inc_search_path='-I${includedir}'
 199
 200 dnl ===============================================
 201 dnl Specify paths to look for libraries and headers
 202 dnl ===============================================
 203 AC_ARG_WITH(libs-from, AS_HELP_STRING([--with-libs-from], [pass compiler flags to look for libraries]),
 204         [lib_search_path="$withval $lib_search_path"])
 205
 206 AC_ARG_WITH(incs-from, AS_HELP_STRING([--with-incs-from], [pass compiler flags to look for header files]),
 207         [inc_search_path="$withval $inc_search_path"])
 208
 209
 210 dnl Boehm GC
 211 dnl ========
 212 AC_ARG_ENABLE([boehm-gc],
 213     [AS_HELP_STRING([--enable-boehm-gc], [use Boehm GC instead of the default libc malloc() [default=no]])],
 214     [AS_CASE(["$enableval"],
 215         [yes], [with_boehm_gc=yes],
 216         [no],  [with_boehm_gc=no],
 217         [AC_MSG_ERROR([bad value $enableval for --enable-boehm-gc])] )],
 218     [with_boehm_gc=no])
 219 AS_IF([test "x$with_boehm_gc" = "xyes"],
 220     AC_SEARCH_LIBS([GC_malloc], [gc],
 221         [AC_DEFINE(USE_BOEHM_GC, 1, [Define if Boehm GC is to be used])],
 222         [AC_MSG_FAILURE([--enable-boehm-gc specified but test for libgc failed])]))
 223
 224
 225 dnl LCOV
 226 dnl ====
 227 AC_ARG_ENABLE([lcov],
 228     [AS_HELP_STRING([--enable-lcov[=output-directory]], [enable coverage data generation using LCOV (GCC only) [default=no]])],
 229     [],
 230     [enable_lcov=no])
 231
 232 AS_IF([test "x$enable_lcov" != "xno"],
 233     [AX_CFLAGS_GCC_OPTION(-fprofile-arcs -ftest-coverage)
 234     AS_IF([test "x$enable_lcov" = "xyes"],
 235         [lcov_output_directory="coverage-report"],
 236         [lcov_output_directory="${enable_lcov}/coverage-report"])
 237     AC_SUBST(lcov_output_directory)])
 238
 239 AM_CONDITIONAL([USE_LCOV], [test "x$enable_lcov" != "xno"])
 240
 241 dnl
 242 dnl ============================
 243 dnl Checks for library functions
 244 dnl ============================
 245 dnl not used anywhere
 246 AC_FUNC_MEMCMP
 247 AC_FUNC_VPRINTF
 248 AC_CHECK_FUNCS(gethostname select poll strcasecmp strncasecmp \
 249                setsid mallinfo mkstemp sysconf)
 250 AC_SEARCH_LIBS([strerror], [cposix])
 251
 252 dnl Check for strlcat/strlcpy
 253 dnl =========================
 254 AC_ARG_WITH([libbsd],
 255   [AS_HELP_STRING([--without-libbsd], [do not use libbsd for strlcat and strlcpy [default=check]])],
 256   [AS_IF([test "x$with_libbsd" != "xno"],
 257     [with_libbsd=bsd]
 258     [with_libbsd=]
 259   )],
 260   [with_libbsd=bsd])
 261
 262 tmp_libs=$LIBS
 263 AC_SEARCH_LIBS([strlcat],[$with_libbsd],
 264   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcat is available])],
 265   [],
 266   []
 267 )
 268 AC_SEARCH_LIBS([strlcpy],[$with_libbsd],
 269   [AC_DEFINE(HAVE_STRLCAT, 1, [Define if strlcpy is available])],
 270   [],
 271   []
 272 )
 273 LIBS=$tmp_libs
 274
 275 LIBBSD=
 276 AS_IF([test "x$ac_cv_search_strlcat" = "x-lbsd" -o "x$ac_cv_search_strlcpy" = "x-lbsd"],
 277   [LIBBSD=-lbsd
 278    AC_CHECK_HEADERS([bsd/string.h])]
 279 )
 280 AC_SUBST(LIBBSD)
 281
 282 dnl Check for OpenBSD kernel memory interface - kvm(3)
 283 dnl ==================================================
 284 AS_IF([test "x$WM_OSDEP" = "xbsd"],
 285   AC_SEARCH_LIBS([kvm_openfiles], [kvm]) )
 286
 287 dnl Check for inotify
 288 dnl =================
 289 AC_CHECK_HEADERS(sys/inotify.h, AC_DEFINE(HAVE_INOTIFY, 1, Check for inotify))
 290
 291
 292 dnl Checks for header files.
 293 dnl =======================
 294 AC_HEADER_SYS_WAIT
 295 AC_HEADER_TIME
 296 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h libintl.h poll.h malloc.h ctype.h \
 297                  string.h strings.h)
 298
 299
 300 dnl Checks for typedefs, structures, and compiler characteristics.
 301 dnl ==============================================================
 302 AC_DECL_SYS_SIGLIST
 303 AC_C_CONST
 304 AC_C_INLINE
 305 WM_C_NORETURN
 306 AC_TYPE_SIZE_T
 307 AC_TYPE_PID_T
 308 AC_TYPE_SIGNAL
 309
 310
 311 dnl pkg-config
 312 dnl ==========
 313 dnl AC_ARG_VAR(PKGCONFIG, [pkg-config command])
 314 AC_CHECK_PROG(PKGCONFIG, pkg-config, pkg-config)
 315
 316 dnl gettext
 317 dnl =======
 318
 319 dnl AM_GNU_GETTEXT
 320
 321 INTLIBS=""
 322
 323 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 324         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 325                          INTLIBS="" ))
 326
 327 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 328
 329 if test "$XGETTEXT" != ""; then
 330     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 331         echo "xgettext isn't GNU version"
 332         XGETTEXT=""
 333     fi
 334 fi
 335
 336 if test "$LINGUAS" != ""; then
 337     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 338         AC_DEFINE(I18N, 1, [Internationalization (I18N) support (set by configure)])
 339         PO=""
 340         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 341     else
 342         LINGUAS=""
 343         PO=""
 344         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 345     fi
 346 else
 347         INTLIBS=""
 348         MOFILES=""
 349         WPMOFILES=""
 350         UTILMOFILES=""
 351         PO=""
 352 fi
 353
 354
 355 dnl The Tower of Babel
 356 dnl ==================
 357
 358 dnl List of supported locales
 359 dnl =========================
 360 supported_locales="be bg bs ca cs da de el es et fi fr gl hr hu hy it ja ko ms nl no pl pt ro ru sk sv tr zh_CN zh_TW"
 361 supported_wprefs_locales="bg ca cs de es et fi fr hr hu it ja ko pt ru sk zh_CN zh_TW"
 362 supported_wings_locales="bg ca cs de fr sk"
 363 supported_util_locales="de es fr pt"
 364
 365 for lang in $LINGUAS; do
 366         ok=0
 367         for l in $supported_locales; do
 368                 if test "$l" = "$lang"; then
 369                         ok=1
 370                         break
 371                 fi
 372         done
 373         if test "$ok" = 1; then
 374                 MOFILES="$MOFILES $lang.mo"
 375         else
 376                 echo "Locale $lang is not supported."
 377         fi
 378         ok=0
 379         for l in $supported_wprefs_locales; do
 380                 if test "$l" = "$lang"; then
 381                         ok=1
 382                         break
 383                 fi
 384         done
 385         if test "$ok" = 1; then
 386                 WPMOFILES="$WPMOFILES $lang.mo"
 387         fi
 388         ok=0
 389         for l in $supported_util_locales; do
 390                 if test "$l" = "$lang"; then
 391                         ok=1
 392                         break
 393                 fi
 394         done
 395         if test "$ok" = 1; then
 396                 UTILMOFILES="$UTILMOFILES $lang.mo"
 397         fi
 398         ok=0
 399         for l in $supported_wings_locales; do
 400                 if test "$l" = "$lang"; then
 401                         ok=1
 402                         break
 403                 fi
 404         done
 405         if test "$ok" = 1; then
 406                 WINGSMOFILES="$WINGSMOFILES $lang.mo"
 407         fi
 408 done
 409
 410
 411 dnl Added by Oliver - Support for NLSDIR option
 412 dnl ===========================================
 413 AC_ARG_WITH(nlsdir, AS_HELP_STRING([--with-nlsdir=PATH], [specify where the locale stuff should go]))
 414
 415 if test "x$NLSDIR" = "x"; then
 416         if test "x$with_nlsdir" != "x"; then
 417                 NLSDIR=$with_nlsdir
 418         else
 419                 NLSDIR='$(prefix)/lib/locale'
 420         fi
 421 fi
 422
 423 menutextdomain=
 424 AC_ARG_WITH(menu-textdomain, AS_HELP_STRING([--with-menu-textdomain=DOMAIN], [specify gettext domain used for menu translations]),
 425         [if test "x$withval" != "xno"; then
 426          menutextdomain=$withval
 427          fi])
 428 AC_SUBST(menutextdomain)
 429
 430 AC_SUBST(INTLIBS)
 431 AC_SUBST(NLSDIR)
 432 AC_SUBST(MOFILES)
 433 AC_SUBST(WPMOFILES)
 434 AC_SUBST(UTILMOFILES)
 435 AC_SUBST(WINGSMOFILES)
 436 AC_SUBST(supported_locales)
 437
 438 dnl ===========================================
 439 dnl             Stuff that uses X
 440 dnl ===========================================
 441
 442 AC_PATH_XTRA
 443
 444 if test $no_x; then
 445     AC_MSG_ERROR([The path for the X11 files not found!
 446 Make sure you have X and it's headers and libraries (the -devel packages
 447 in Linux) installed.])
 448 fi
 449
 450 X_LIBRARY_PATH=$x_libraries
 451 XCFLAGS="$X_CFLAGS"
 452 XLFLAGS="$X_LIBS"
 453 XLIBS="-lX11 $X_EXTRA_LIBS"
 454 LIBXMU="-lXmu"
 455 AC_SUBST(LIBXMU)
 456
 457 lib_search_path="$lib_search_path $XLFLAGS"
 458 inc_search_path="$inc_search_path $XCFLAGS"
 459
 460 AC_SUBST(X_LIBRARY_PATH)
 461
 462 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 463 dnl by MANOME Tomonori
 464 dnl ===========================================
 465 use_locale=yes
 466 AC_ARG_ENABLE(locale, AS_HELP_STRING([--disable-locale], [disable use of X locale support]),
 467               use_locale=no)
 468
 469 if test "$use_locale" = yes; then
 470         AC_CHECK_LIB(X11, _Xsetlocale,
 471                 AC_DEFINE(X_LOCALE, 1, [define if you want support for X window's X_LOCALE (set by configure)]),,
 472                 $XLFLAGS $XLIBS)
 473 fi
 474
 475 dnl Check whether XInternAtoms() exist
 476 dnl ==================================
 477 AC_CHECK_LIB(X11, XInternAtoms,
 478              AC_DEFINE(HAVE_XINTERNATOMS, 1, [define if your X server has XInternAtoms() (set by configure)]),,
 479              $XLFLAGS $XLIBS)
 480
 481 dnl Check whether XConvertCase() exist
 482 dnl ==================================
 483 AC_CHECK_LIB(X11, XConvertCase,
 484              AC_DEFINE(HAVE_XCONVERTCASE, 1, [define if your X server has XConvertCase() (set by configure)]),,
 485              $XLFLAGS $XLIBS)
 486
 487 dnl XKB keyboard language status
 488 dnl ============================
 489 AC_ARG_ENABLE(modelock, AS_HELP_STRING([--enable-modelock], [XKB keyboard language status support]),
 490                 AC_DEFINE(XKB_MODELOCK, 1, [whether XKB language MODELOCK should be enabled]))
 491
 492 dnl XShape support
 493 dnl ==============
 494 AC_ARG_ENABLE([shape],
 495     [AS_HELP_STRING([--disable-shape], [disable shaped window extension support])],
 496     [AS_CASE(["$enableval"],
 497         [yes|no], [],
 498         [AC_MSG_ERROR([bad value $enableval for --enable-shape]) ]) ],
 499     [enable_shape=auto])
 500 WM_XEXT_CHECK_XSHAPE
 501
 502 dnl XINERAMA support
 503 dnl ================
 504 AC_ARG_ENABLE([xinerama],
 505     [AS_HELP_STRING([--enable-xinerama], [enable Xinerama extension support])],
 506     [AS_CASE(["$enableval"],
 507         [yes|no], [],
 508         [AC_MSG_ERROR([bad value $enableval for --enable-xinerama]) ]) ],
 509     [enable_xinerama=auto])
 510 WM_XEXT_CHECK_XINERAMA
 511
 512 dnl XRandR support
 513 dnl ==============
 514 xrandr=no
 515 AC_ARG_ENABLE(xrandr, AS_HELP_STRING([--enable-xrandr], [enable XRandR window extension support (NOT recommended, buggy)]),
 516                 xrandr=$enableval, xrandr=no)
 517 added_xext=no
 518
 519 LIBXRANDR=
 520 if test "$xrandr" = yes; then
 521         AC_CHECK_LIB(Xrandr, XRRQueryExtension, [LIBXRANDR=-lXrandr
 522                 added_xext=yes
 523                 AC_DEFINE(HAVE_XRANDR, 1, [define if you want support for XRandR (set by configure)])],
 524                 xrandr=no, $XLFLAGS $XLIBS)
 525 fi
 526 AC_SUBST(LIBXRANDR)
 527
 528 dnl
 529 dnl libWINGS uses math functions, check whether usage requires linking
 530 dnl against libm
 531 dnl
 532 WM_CHECK_LIBM
 533
 534 dnl
 535 dnl libWINGS uses FcPatternDel from libfontconfig
 536 dnl
 537 AC_MSG_CHECKING([for fontconfig library])
 538 FCLIBS=`$PKGCONFIG fontconfig --libs`
 539 if test "x$FCLIBS" = "x" ; then
 540         AC_MSG_RESULT([not found])
 541 else
 542         AC_MSG_RESULT([found])
 543 fi
 544 AC_SUBST(FCLIBS)
 545
 546
 547 dnl Xft2 antialiased font support
 548 dnl =============================
 549
 550 xft=yes
 551 XFTLIBS=""
 552
 553 if test "x$PKGCONFIG" != x -a "`$PKGCONFIG xft; echo $?`" = 0; then
 554         XFTCONFIG="$PKGCONFIG xft"
 555         pkgconfig_xft=yes
 556 else
 557         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 558 fi
 559
 560 AC_MSG_CHECKING([for the Xft2 library])
 561
 562 if test "x$XFTCONFIG" != x; then
 563         XFTLIBS=`$XFTCONFIG --libs`
 564         XFTFLAGS=`$XFTCONFIG --cflags`
 565         AC_MSG_RESULT([found])
 566 else
 567         AC_MSG_RESULT([not found])
 568         echo
 569         echo "ERROR!!! libXft2 is not installed or could not be found."
 570         echo "         Xft2 is a requirement for building Window Maker."
 571         echo "         Please install it (along with fontconfig) before continuing."
 572         echo
 573         exit 1
 574 fi
 575
 576 minXFT="2.1.0"
 577 goodxft="no"
 578
 579 dnl
 580 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 581 dnl
 582 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 583
 584 if test "$goodxft" = no; then
 585         echo
 586         echo "ERROR!!! libXft on this system is an old version."
 587         echo "         Please consider upgrading to at least version ${minXFT}."
 588         echo
 589         exit 1
 590 fi
 591
 592 AC_SUBST(XFTFLAGS)
 593 AC_SUBST(XFTLIBS)
 594
 595
 596 dnl MIT-SHM support
 597 dnl ===============
 598 shm=yes
 599 AC_ARG_ENABLE(shm, AS_HELP_STRING([--disable-shm], [disable usage of MIT-SHM extension]),
 600                 shm=$enableval, shm=yes)
 601
 602 if test "$shm" = yes; then
 603         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 604
 605         if test "$ok" = yes; then
 606         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 607         fi
 608
 609         if test "$ok" = yes; then
 610                 if test "$added_xext" = no; then
 611                         XLIBS="-lXext $XLIBS"
 612                 fi
 613                 AC_DEFINE(XSHM, 1, [define if X's shared memory extension is available (set by configure)])
 614         fi
 615 fi
 616
 617
 618 dnl ==============================================
 619 dnl         Graphic Format Libraries
 620 dnl ==============================================
 621
 622 dnl XPM Support
 623 dnl ===========
 624 AC_ARG_ENABLE([xpm],
 625     [AS_HELP_STRING([--disable-xpm], [disable use of XPM pixmaps through libXpm])],
 626     [AS_CASE(["$enableval"],
 627         [yes|no], [],
 628         [AC_MSG_ERROR([bad value $enableval for --enable-xpm])] )],
 629     [enable_xpm=auto])
 630 WM_IMGFMT_CHECK_XPM
 631
 632
 633 # for wmlib
 634 AC_SUBST(XCFLAGS)
 635 # for test
 636 AC_SUBST(XLFLAGS)
 637 AC_SUBST(XLIBS)
 638 AC_SUBST(X_EXTRA_LIBS)
 639
 640 dnl ===============================================
 641 dnl             End of stuff that uses X
 642 dnl ===============================================
 643
 644 dnl PNG Support
 645 dnl ===========
 646 AC_ARG_ENABLE([png],
 647     [AS_HELP_STRING([--disable-png], [disable PNG support through libpng])],
 648     [AS_CASE(["$enableval"],
 649         [yes|no], [],
 650         [AC_MSG_ERROR([bad value $enableval for --enable-png])] )],
 651     [enable_png=auto])
 652 WM_IMGFMT_CHECK_PNG
 653
 654
 655 dnl JPEG Support
 656 dnl ============
 657 AC_ARG_ENABLE([jpeg],
 658     [AS_HELP_STRING([--disable-jpeg], [disable JPEG support through libjpeg])],
 659     [AS_CASE(["$enableval"],
 660         [yes|no], [],
 661         [AC_MSG_ERROR([bad value $enableval for --enable-jpeg])] )],
 662     [enable_jpeg=auto])
 663 WM_IMGFMT_CHECK_JPEG
 664
 665
 666 dnl GIF Support
 667 dnl ============
 668 AC_ARG_ENABLE(gif,
 669     [AS_HELP_STRING([--disable-gif], [disable GIF support through libgif or libungif])],
 670     [AS_CASE(["$enableval"],
 671         [yes|no], [],
 672         [AC_MSG_ERROR([bad value $enableval for --enable-gif])] )],
 673     [enable_gif=auto])
 674 WM_IMGFMT_CHECK_GIF
 675
 676
 677 dnl TIFF Support
 678 dnl ============
 679 AC_ARG_ENABLE([tiff],
 680     [AS_HELP_STRING([--disable-tiff], [disable use of TIFF images through libtiff])],
 681     [AS_CASE(["$enableval"],
 682         [yes|no], [],
 683         [AC_MSG_ERROR([bad value $enableval for --enable-tiff])] )],
 684     [enable_tiff=auto])
 685 WM_IMGFMT_CHECK_TIFF
 686
 687
 688 dnl PPM Support
 689 dnl ===========
 690 # The PPM format is always enabled because we have built-in support for the format
 691 # We are not using any external library like libppm
 692 supported_gfx="$supported_gfx builtin-PPM"
 693
 694
 695 # Choice of the default format for icons
 696 AS_IF([test "x$enable_tiff" != "xno"],
 697     [ICONEXT="tiff"],
 698     [ICONEXT="xpm"])
 699
 700
 701 LIBRARY_SEARCH_PATH="$lib_search_path"
 702 HEADER_SEARCH_PATH="$inc_search_path"
 703
 704 AC_SUBST(LIBRARY_SEARCH_PATH)
 705 AC_SUBST(HEADER_SEARCH_PATH)
 706
 707
 708 AC_SUBST(GFXLIBS)
 709 AC_SUBST(ICONEXT)
 710 AM_CONDITIONAL([ICON_EXT_XPM],  [test "x$ICONEXT" = "xxpm"])
 711 AM_CONDITIONAL([ICON_EXT_TIFF], [test "x$ICONEXT" = "xtiff"])
 712
 713
 714 dnl ==============================================
 715 dnl         End of Graphic Format Libraries
 716 dnl ==============================================
 717
 718
 719 dnl
 720 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 721 AC_CHECK_HEADERS(stdlib.h)
 722
 723 # AC_PREFIX_PROGRAM(wmaker)
 724
 725 dnl Support for PIXMAPDIR option
 726 dnl ============================
 727 AC_ARG_WITH(pixmapdir, AS_HELP_STRING([--with-pixmapdir=PATH], [specify where pixmaps are located [DATADIR/pixmaps]]))
 728
 729 if test "x$with_pixmapdir" != "x"; then
 730         pixmapdir=$with_pixmapdir
 731 else
 732         pixmapdir='${datadir}/pixmaps'
 733 fi
 734 AC_SUBST(pixmapdir)
 735
 736
 737 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 738 dnl ==============================================
 739
 740 AC_ARG_WITH(gnustepdir, AS_HELP_STRING([--with-gnustepdir=PATH], [specify the directory for GNUstep applications]))
 741
 742 if test "x`echo $with_gnustepdir | grep ^/`" != "x"; then
 743     appspath=$with_gnustepdir
 744 fi
 745
 746 if test "x$appspath$GNUSTEP_LOCAL_ROOT" = "x"; then
 747     wprefs_base_dir=${prefix}
 748     wprefs_datadir="${datadir}/WPrefs"
 749     wprefs_bindir="${bindir}"
 750 else
 751     gnustepdir=$appspath
 752
 753     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 754         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 755         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 756     fi
 757
 758     wprefs_base_dir=$gnustepdir/Applications
 759     wprefs_datadir=$wprefs_base_dir/WPrefs.app
 760     wprefs_bindir=$wprefs_base_dir/WPrefs.app
 761 fi
 762
 763 AC_SUBST(wprefs_datadir)
 764 AC_SUBST(wprefs_bindir)
 765
 766
 767 dnl Enable User Defined Menu thing
 768 dnl ==============================
 769 AC_ARG_ENABLE(usermenu, AS_HELP_STRING([--enable-usermenu], [user defined menus for applications]),
 770 if test "$enableval" = yes; then
 771         AC_DEFINE(USER_MENU, 1, [define if you want user defined menus for applications])
 772 fi
 773 )
 774
 775 gl_LD_VERSION_SCRIPT
 776
 777 AC_OUTPUT(Makefile po/Makefile util/Makefile util/po/Makefile test/Makefile \
 778         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 779         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 780         WINGs/Extras/Makefile WINGs/po/Makefile \
 781         wmlib/Makefile wrlib/Makefile wrlib/tests/Makefile \
 782         src/Makefile src/wconfig.h \
 783         doc/Makefile doc/sk/Makefile doc/cs/Makefile \
 784         doc/ru/Makefile \
 785         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 786         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 787         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 788         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 789         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 790         WPrefs.app/po/Makefile )
 791
 792
 793 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 794 dnl ===================================================================
 795
 796 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 797 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 798 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 799
 800 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 801 dnl parsed by m4
 802
 803 AC_SUBST(lib_search_path)
 804 AC_SUBST(inc_search_path)
 805
 806 dnl
 807 dnl Spit out the configuration
 808 dnl ==========================
 809
 810 if test "x$MOFILES" = "x"; then
 811         mof=None
 812 else
 813         mof=`echo $MOFILES`
 814 fi
 815
 816 if test "x$MOFILES" = "x"; then
 817         languages=None
 818 else
 819         languages=`echo $MOFILES | sed 's/.mo//g'`
 820 fi
 821
 822 echo
 823 echo "Window Maker was configured as follows:"
 824 echo
 825 echo "Installation path prefix            : $prefix"
 826 echo "Installation path for binaries      : $_bindir"
 827 echo "Installation path for libraries     : $libdir"
 828 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
 829 echo "Supported X extensions:             :$supported_xext"
 830 echo "Supported graphic format libraries  :$supported_gfx"
 831 echo "Unsupported features                :$unsupported"
 832 echo "Antialiased text support in WINGs   : $xft"
 833 echo "XRandR extension support            : $xrandr"
 834 echo "Translated message files to install : $mof"
 835 dnl echo "Supported languages beside English  : $languages"
 836 if test "x$MOFILES" != "x"; then
 837         echo "Installation path for translations  : $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
 838 fi
 839 AS_IF([test "x$debug" = "xyes"],
 840     [AS_ECHO(["Debug enabled: CFLAGS = $CFLAGS"]) ])
 841 echo
 842
 843 dnl WM_PRINT_REDCRAP_BUG_STATUS
 844
 845 AS_IF([test "x$enable_jpeg" = xno], [dnl
 846     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])
 847     AS_ECHO([])
 848     AS_ECHO(["JPEG support will not be included because the JPEG library is"])
 849     AS_ECHO(["not installed correctly or was not found. Background images"])
 850     AS_ECHO(["from themes will not display as they usually are JPEG files."])
 851     AS_ECHO([])
 852     AS_ECHO(["To fix, download and install the jpeg library and/or make sure you"])
 853     AS_ECHO(["installed all jpeg related packages, SPECIALLY the development packages"])
 854     AS_ECHO(["like jpeg-dev (if you use some prepackaged version of libjpeg)."])
 855     AS_ECHO([])
 856     AS_ECHO(["WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"])dnl
 857 ])
 858
 859
 860 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
 861 dnl ================================================
 862 dnl Local Variables:
 863 dnl compile-command: "autoconf"
 864 dnl End:
 865