configure.ac

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(src/WindowMaker.h)
  15
  16
  17
  18 AM_INIT_AUTOMAKE(WindowMaker, 0.81.0)
  19
  20 AC_PROG_LIBTOOL
  21
  22 # by Marcelo Magallon <mmagallo@efis.ucr.ac.cr>
  23 # Turn around -rpath problem with libtool 1.0c
  24 # This define should be improbable enough to not conflict with anything
  25 case ${host} in
  26   *-pc-linux-gnu)
  27     AC_MSG_RESULT([Fixing libtool for -rpath problems.])
  28     sed < libtool > libtool-2 \
  29     's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
  30     mv libtool-2 libtool
  31     chmod 755 libtool
  32   ;;
  33 esac
  34
  35
  36 AM_CONFIG_HEADER(src/config.h)
  37
  38
  39 dnl Checks for host/os name
  40 dnl =======================
  41 dnl AC_CANONICAL_HOST -- already done by AC_PROG_LIBTOOL
  42
  43
  44 dnl Checks for programs.
  45 dnl ===================
  46 AC_ISC_POSIX
  47 AC_PROG_CC
  48 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  49 #AC_PROG_RANLIB
  50 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  51 AC_PROG_LN_S
  52 AC_PROG_GCC_TRADITIONAL
  53
  54
  55 dnl the prefix
  56 dnl ==========
  57 dnl
  58 dnl move this earlier in the script... anyone know why this is handled
  59 dnl in such a bizarre way?
  60
  61 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  62 dnl Let make expand exec_prefix.
  63 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  64
  65
  66 _bindir=`eval echo $bindir`
  67 _bindir=`eval echo $_bindir`
  68
  69 _libdir=`eval echo $libdir`
  70 _libdir=`eval echo $_libdir`
  71 lib_search_path="-L$_libdir"
  72
  73 inc_search_path=`eval echo $includedir`
  74 inc_search_path="-I`eval echo $inc_search_path`"
  75
  76
  77 dnl
  78 dnl Check for RedHat bugs
  79 dnl =====================
  80
  81 dnl WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
  82
  83
  84 dnl
  85 dnl Specify paths to look for libraries and headers
  86 dnl ===============================================
  87 AC_ARG_WITH(libs-from,
  88 [  --with-libs-from       pass compiler flags to look for libraries],
  89         [lib_search_path="$withval $lib_search_path"])
  90
  91 AC_ARG_WITH(incs-from,
  92 [  --with-incs-from       pass compiler flags to look for header files],
  93         [inc_search_path="$withval $inc_search_path"])
  94
  95
  96
  97 dnl Checks for library functions.
  98 dnl ============================
  99 dnl not used anywhere
 100 dnl AC_FUNC_MEMCMP
 101 AC_FUNC_VPRINTF
 102 AC_FUNC_ALLOCA
 103 AC_CHECK_FUNCS(gethostname select poll strerror strcasecmp strncasecmp setsid atexit mallinfo mkstemp snprintf vsnprintf asprintf vasprintf)
 104
 105
 106 dnl ripped from samba
 107 dnl
 108 AC_CACHE_CHECK([for C99 vsnprintf],_cv_HAVE_C99_VSNPRINTF,[
 109 AC_TRY_RUN([
 110 #include <sys/types.h>
 111 #include <stdarg.h>
 112 void foo(const char *format, ...) {
 113        va_list ap;
 114        int len;
 115        char buf[5];
 116
 117        va_start(ap, format);
 118        len = vsnprintf(0, 0, format, ap);
 119        va_end(ap);
 120        if (len != 5) exit(1);
 121
 122        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 123
 124        exit(0);
 125 }
 126 main() { foo("hello"); }
 127 ],
 128 _cv_HAVE_C99_VSNPRINTF=yes,_cv_HAVE_C99_VSNPRINTF=no,_cv_HAVE_C99_VSNPRINTF=cross)])
 129 if test x"$_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 130     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [define if you have vsnprintf with C99 semantics (set by configure)])
 131 fi
 132
 133 dnl Loading of dynamic libraries at runtime
 134 dnl =======================================
 135 DLLIBS=""
 136
 137 AC_CHECK_FUNC(dlopen, [HAVEDL="yes"],
 138         AC_CHECK_LIB(dl, dlopen, [DLLIBS="-ldl" HAVEDL="yes"],
 139                          DLLIBS="" ))
 140
 141 if test "x$HAVEDL" = xyes; then
 142     AC_CHECK_HEADERS(dlfcn.h)
 143 fi
 144
 145
 146
 147 dnl Check CPP
 148 dnl =========
 149 if test "x$CPP_PATH" = x; then
 150     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 151                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 152 fi
 153
 154 dnl
 155 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 156 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 157 dnl standard locations
 158 dnl
 159 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 160     if test "$GCC" = "yes"; then
 161         CPP_PATH="gcc -E -x c"
 162     else
 163         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 164             CPP_PATH="$CPP_PATH -B"
 165         else
 166             echo "cpp, the C preprocessor was not found in your system."
 167             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 168             exit
 169         fi
 170     fi
 171 fi
 172 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH", [define to the path to cpp])
 173
 174
 175
 176 dnl Checks for header files.
 177 dnl =======================
 178 AC_HEADER_SYS_WAIT
 179 AC_HEADER_TIME
 180 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h libintl.h sys/select.h poll.h malloc.h ctype.h string.h strings.h)
 181
 182
 183
 184 dnl Checks for typedefs, structures, and compiler characteristics.
 185 dnl ==============================================================
 186 AC_DECL_SYS_SIGLIST
 187 AC_C_CONST
 188 #AC_TYPE_SIZE_T
 189 #AC_TYPE_PID_T
 190 AC_TYPE_SIGNAL
 191
 192
 193
 194 dnl Compiler/architecture specific optimizations
 195 dnl ============================================
 196
 197
 198 dnl GCC/as with MMX support
 199 dnl -----------------------
 200
 201 # until we fix it, leave it disabled
 202 asm_support=no
 203 mmx_support=no
 204 if test "$ac_cv_prog_gcc" = yes; then
 205     x86=0
 206     changequote(,)dnl
 207     case "$host_cpu" in
 208        i[3456]86) x86=1
 209        ;;
 210     esac
 211     changequote([,])dnl
 212
 213     if test "$host_os" != "linux" -a "$host_os" != "linux-gnu" ; then
 214        x86=0
 215     fi
 216
 217     if test $x86 = 1; then
 218        AC_DEFINE(ASM_X86, 1, [define if processor is x86 (normally detected by configure)])
 219        asm_support=yes
 220
 221        AC_CACHE_CHECK(whether gcc supports MMX(tm) inline asm,
 222                       ac_cv_c_inline_mmx,
 223                       [AC_TRY_LINK(,[asm ("movq %mm0, %mm1");],
 224                       ac_cv_c_inline_mmx=yes,
 225                       ac_cv_c_inline_mmx=no)])
 226
 227        if test "x$ac_cv_c_inline_mmx" = xyes; then
 228           AC_DEFINE(ASM_X86_MMX, 1, [define if processor is x86 with MMX(tm) support (normally autodetected by configure)])
 229           mmx_support=yes
 230        fi
 231     fi
 232 fi
 233
 234
 235
 236 dnl gettext
 237 dnl =======
 238
 239
 240 dnl AM_GNU_GETTEXT
 241
 242
 243
 244 INTLIBS=""
 245
 246 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 247         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 248                          INTLIBS="" ))
 249
 250 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 251
 252 if test "$XGETTEXT" != ""; then
 253     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 254         echo "xgettext isn't GNU version"
 255         XGETTEXT=""
 256     fi
 257 fi
 258
 259 if test "$LINGUAS" != ""; then
 260     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 261         AC_DEFINE(I18N, 1, [Internationalization (I18N) support (set by configure)])
 262         PO=""
 263 #       if test "$LINGUAS" = ""; then
 264 #           ling=` (cd src/po; /bin/ls *.po) `
 265 #           for l in $ling; do
 266 #               lcode=`basename $l .po`
 267 #               LINGUAS="$LINGUAS $lcode"
 268 #           done
 269 #       fi
 270         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 271     else
 272         LINGUAS=""
 273         PO=""
 274         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 275     fi
 276 else
 277         INTLIBS=""
 278         MOFILES=""
 279         WPMOFILES=""
 280         PO=""
 281 fi
 282
 283
 284 dnl The Tower of Babel
 285 dnl ==================
 286
 287 dnl List of supported locales
 288 dnl -------------------------
 289 supported_locales="bg cs da de el es et fi fr gl hr hu it ja ko ms nl no pl pt ro ru sk sv tr zh_CN zh_TW.Big5"
 290 supported_wprefs_locales="bg cs de es et fi fr hr hu it ja ko pt ru sk zh_CN zh_TW.Big5"
 291 supported_wings_locales="cs de sk"
 292
 293 for lang in $LINGUAS; do
 294         ok=0
 295         for l in $supported_locales; do
 296                 if test "$l" = "$lang"; then
 297                         ok=1
 298                         break
 299                 fi
 300         done
 301         if test "$ok" = 1; then
 302                 MOFILES="$MOFILES $lang.mo"
 303         else
 304                 echo "Locale $lang is not supported."
 305         fi
 306         ok=0
 307         for l in $supported_wprefs_locales; do
 308                 if test "$l" = "$lang"; then
 309                         ok=1
 310                         break
 311                 fi
 312         done
 313         if test "$ok" = 1; then
 314                 WPMOFILES="$WPMOFILES $lang.mo"
 315         fi
 316         ok=0
 317         for l in $supported_wings_locales; do
 318                 if test "$l" = "$lang"; then
 319                         ok=1
 320                         break
 321                 fi
 322         done
 323         if test "$ok" = 1; then
 324                 WINGSMOFILES="$WINGSMOFILES $lang.mo"
 325         fi
 326 done
 327
 328
 329 dnl Kanji Characters support
 330 dnl ========================
 331
 332 case $host_os in
 333         freebsd*)
 334                 AC_CHECK_LIB(xpg4, setlocale, [LIBS="$LIBS -lxpg4"]);;
 335         *)
 336         ;;
 337 esac
 338
 339
 340
 341 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 342 dnl ===========================================
 343 AC_ARG_WITH(nlsdir,
 344         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 345
 346
 347 if test "x$NLSDIR" = "x"; then
 348         if test "x$with_nlsdir" != "x"; then
 349                 NLSDIR=$with_nlsdir
 350         else
 351                 NLSDIR='$(prefix)/lib/locale'
 352         fi
 353 fi
 354
 355
 356
 357 AC_SUBST(DLLIBS)
 358 AC_SUBST(INTLIBS)
 359 AC_SUBST(NLSDIR)
 360 AC_SUBST(MOFILES)
 361 AC_SUBST(WPMOFILES)
 362 AC_SUBST(WINGSMOFILES)
 363 AC_SUBST(supported_locales)
 364
 365
 366
 367 dnl Support for various hint things
 368 dnl ===============================
 369
 370
 371 AC_ARG_ENABLE(gnome,
 372   [  --enable-gnome       enable stuff needed for GNOME ],
 373   [if test x$enableval = xyes; then
 374     AC_DEFINE(GNOME_STUFF, 1, [define if you want GNOME stuff support])
 375     gnome_on=yes
 376   fi])
 377
 378
 379 AC_ARG_ENABLE(kde,
 380   [  --enable-kde                 enable support for KDE window manager (kwm) hints ],
 381   [if test x$enableval = xyes; then
 382     AC_DEFINE(KWM_HINTS, 1, [define if you want KDE hint support])
 383     kde_on=yes
 384   fi])
 385
 386
 387 AC_ARG_ENABLE(openlook,
 388   [  --enable-openlook    enable support for OPEN LOOK(tm) (olwm) hints ],
 389   [if test x$enableval = xyes; then
 390     AC_DEFINE(OLWM_HINTS, 1, [define if you want OPEN LOOK(tm) hint support])
 391     openlook_on=yes
 392   fi])
 393
 394
 395 dnl
 396 dnl Disable some stuff that are duplicated in kde
 397 dnl ---------------------------------------------
 398 AC_ARG_ENABLE(lite,
 399   [  --enable-lite                disable some stuff (dont use it) ],
 400   [if test x$enableval = xyes; then
 401         LITE=yes
 402         AC_DEFINE(LITE, 1, [define if you want the 'lite' version])
 403         AC_SUBST(LITE)
 404   fi])
 405
 406
 407
 408 dnl
 409 dnl Networking stuff
 410 dnl
 411
 412 NETLIBS=""
 413
 414 AC_CHECK_FUNC(connect,,
 415         AC_CHECK_LIB(socket, connect, NETLIBS="$NETLIBS -lsocket"))
 416
 417 AC_CHECK_FUNC(gethostbyname,,
 418         AC_CHECK_LIB(nsl, gethostbyname, NETLIBS="$NETLIBS -lnsl"))
 419
 420 AC_CHECK_FUNC(inet_aton, AC_DEFINE(HAVE_INET_ATON, 1, [define if you have then inet_aton function (set by configure)]),
 421      for lib in resolv socket inet bsd; do
 422         AC_CHECK_LIB($lib, inet_aton, [AC_DEFINE(HAVE_INET_ATON)
 423                      NETLIBS="$NETLIBS -l$lib"; break],, $NETLIBS)
 424      done)
 425
 426 AC_SUBST(NETLIBS)
 427
 428
 429 dnl ===========================================
 430 dnl             Stuff that uses X
 431 dnl ===========================================
 432
 433 AC_PATH_XTRA
 434
 435 if test $no_x; then
 436     AC_MSG_ERROR([The path for the X11 files not found!
 437 Make sure you have X and it's headers and libraries (the -devel packages
 438 in Linux) installed.])
 439 fi
 440
 441 X_LIBRARY_PATH=$x_libraries
 442
 443 XCFLAGS="$X_CFLAGS"
 444
 445 XLFLAGS="$X_LIBS"
 446
 447 XLIBS="-lX11 $X_EXTRA_LIBS"
 448
 449
 450 lib_search_path="$lib_search_path $XLFLAGS"
 451 inc_search_path="$inc_search_path $XCFLAGS"
 452
 453
 454 AC_SUBST(X_LIBRARY_PATH)
 455
 456
 457
 458 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 459 dnl by MANOME Tomonori
 460 dnl ===========================================
 461 use_locale=yes
 462 AC_ARG_ENABLE(locale,
 463 [  --disable-locale       disable use of X locale support],
 464                 use_locale=no)
 465
 466 if test "$use_locale" = yes; then
 467         AC_CHECK_LIB(X11, _Xsetlocale,
 468                 AC_DEFINE(X_LOCALE, 1, [define if you want support for X window's X_LOCALE (set by configure)]),,
 469                 $XLFLAGS $XLIBS)
 470 fi
 471
 472
 473 dnl Check whether XInternAtoms() exist
 474 dnl ==================================
 475 AC_CHECK_LIB(X11, XInternAtoms,
 476              AC_DEFINE(HAVE_XINTERNATOMS, 1, [define if your X server has XInternAtoms() (set by configure)]),,
 477              $XLFLAGS $XLIBS)
 478
 479 dnl Check whether XConvertCase() exist
 480 dnl ==================================
 481 AC_CHECK_LIB(X11, XConvertCase,
 482              AC_DEFINE(HAVE_XCONVERTCASE, 1, [define if your X server has XConvertCase() (set by configure)]),,
 483              $XLFLAGS $XLIBS)
 484
 485
 486 dnl XKB keyboard language status
 487 dnl ============================
 488 AC_ARG_ENABLE(modelock,
 489 [  --enable-modelock      XKB keyboard language status support],
 490                 AC_DEFINE(XKB_MODELOCK, 1, [whether XKB language MODELOCK should be enabled]))
 491
 492
 493
 494 dnl Shape support
 495 dnl =============
 496 shape=yes
 497 AC_ARG_ENABLE(shape,
 498 [  --disable-shape        disable shaped window extension support],
 499                 shape=$enableval, shape=yes)
 500
 501 added_xext=no
 502
 503 if test "$shape" = yes; then
 504         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 505                 added_xext=yes
 506                 AC_DEFINE(SHAPE, 1, [define if you want support for shaped windows (set by configure)])],
 507                 shape=no, $XLFLAGS $XLIBS)
 508 fi
 509
 510
 511 dnl XINERAMA support
 512 dnl ================
 513 xinerama=no
 514 #AC_ARG_ENABLE(xinerama,
 515 #[  --disable-xinerama    disable XInerama extension support],
 516 #               xinerama=$enableval, xinerama=yes)
 517
 518 if test "$xinerama" = yes; then
 519         AC_CHECK_LIB(Xinerama, XineramaQueryScreens, [XLIBS="-lXinerama $XLIBS"
 520                 AC_DEFINE(XINERAMA, 1, [define if you want support for the XINERAMA extension (set by configure)])],
 521                 xinerama=no, $XLFLAGS $XLIBS)
 522 fi
 523
 524
 525
 526 dnl MIT-SHM support
 527 dnl ===============
 528 shm=yes
 529 AC_ARG_ENABLE(shm,
 530 [  --disable-shm           disable usage of MIT-SHM extension],
 531                 shm=$enableval, shm=yes)
 532
 533 if test "$shm" = yes; then
 534         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 535
 536         if test "$ok" = yes; then
 537         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 538         fi
 539
 540         if test "$ok" = yes; then
 541                 if test "$added_xext" = no; then
 542                         XLIBS="-lXext $XLIBS"
 543                 fi
 544                 AC_DEFINE(XSHM, 1, [define if X's shared memory extension is available (set by configure)])
 545         fi
 546 fi
 547
 548
 549 dnl R6 Style Session Management Support
 550 dnl ===================================
 551
 552 #
 553 #
 554 #AC_DEFINE(R6SM)
 555 #AC_SUBST(XSMPLIBS)
 556 #
 557
 558
 559 dnl ==============================================
 560 dnl         Graphic Format Libraries
 561 dnl ==============================================
 562
 563
 564
 565
 566
 567 dnl XPM Support
 568 dnl ===========
 569 xpm=yes
 570 AC_ARG_ENABLE(xpm,
 571 [  --disable-xpm                  disable use of XPM pixmaps through libXpm],
 572         xpm=$enableval, xpm=yes)
 573
 574 if test "$xpm" = yes; then
 575     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 576
 577     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 578         WM_CHECK_HEADER(X11/xpm.h)
 579         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 580                 GFXLIBS="$GFXLIBS -lXpm"
 581                 supported_gfx="XPM"
 582                 AC_DEFINE(USE_XPM, 1, [define if XPM libraries are available (set by configure)])
 583         else
 584                 supported_gfx="builtin-XPM"
 585         fi
 586     fi
 587 fi
 588
 589 # for wmlib
 590 AC_SUBST(XCFLAGS)
 591 # for test
 592 AC_SUBST(XLFLAGS)
 593 AC_SUBST(XLIBS)
 594
 595 AC_SUBST(X_EXTRA_LIBS)
 596
 597 dnl ===============================================
 598 dnl             End of stuff that uses X
 599 dnl ===============================================
 600
 601
 602
 603 dnl PNG Support
 604 dnl ===========
 605 png=yes
 606 AC_ARG_ENABLE(png,
 607 [  --disable-png                  disable PNG support through libpng],
 608         png=$enableval, png=yes, png=no)
 609
 610
 611 if test "$png" = yes ; then
 612     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 613
 614     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 615         WM_CHECK_HEADER(png.h)
 616         if test "x$ac_cv_header_png_h" = xyes; then
 617             GFXLIBS="$GFXLIBS -lpng -lz"
 618             supported_gfx="$supported_gfx PNG"
 619             AC_DEFINE(USE_PNG, 1, [define if PNG libraries are available (set by configure)])
 620         fi
 621     fi
 622 fi
 623
 624
 625 dnl JPEG Support
 626 dnl ============
 627 jpeg=yes
 628 ljpeg=""
 629 AC_ARG_ENABLE(jpeg,
 630 [  --disable-jpeg         disable JPEG support through libjpeg],
 631         jpeg=$enableval, jpeg=yes, jpeg=no)
 632
 633 if test "$jpeg" = yes; then
 634     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 635
 636     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 637
 638         ljpeg="-ljpeg"
 639
 640         WM_CHECK_HEADER(jpeglib.h)
 641         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 642             GFXLIBS="$GFXLIBS -ljpeg"
 643             supported_gfx="$supported_gfx JPEG"
 644             AC_DEFINE(USE_JPEG, 1, [define if JPEG libraries are available (set by configure)])
 645         fi
 646     fi
 647 fi
 648
 649
 650 dnl GIF Support
 651 dnl ============
 652 gif=yes
 653 AC_ARG_ENABLE(gif,
 654 [  --disable-gif           disable GIF support through libgif or libungif],
 655         gif=$enableval, gif=yes, gif=no)
 656
 657 if test "$gif" = yes; then
 658     my_libname=""
 659     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 660     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 661         my_libname=-lungif
 662     fi
 663 dnl
 664 dnl libungif is the same thing as libgif for all practical purposes.
 665 dnl
 666     if test "x$my_libname" = x; then
 667         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 668         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 669             my_libname=-lgif
 670         fi
 671     fi
 672
 673     if test "$my_libname" != x; then
 674         WM_CHECK_HEADER(gif_lib.h)
 675         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 676             GFXLIBS="$GFXLIBS $my_libname"
 677             supported_gfx="$supported_gfx GIF"
 678             AC_DEFINE(USE_GIF, 1, [define if GIF libraries are available (set by configure)])
 679         fi
 680     fi
 681 fi
 682
 683
 684
 685 dnl TIFF Support
 686 dnl ============
 687 AC_ARG_ENABLE(tiff,
 688 [  --disable-tiff         disable use of TIFF images through libtiff],
 689         tif=$enableval, tif=yes, tif=no)
 690
 691 #
 692 # TIFF can optionally have JPEG and/or zlib support. Must find out
 693 # when they are supported so that correct library flags are passed during
 694 # detection and linkage
 695 #
 696 #
 697 # By default use xpm icons if tiff is not found.
 698 ICONEXT="xpm"
 699 #
 700
 701 if test "$tif" = yes; then
 702     my_libname=""
 703     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 704     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 705         my_libname="-ltiff"
 706     fi
 707 dnl
 708 dnl Retry with zlib
 709 dnl
 710     unset ac_cv_lib_tiff_TIFFGetVersion
 711     if test "x$my_libname" = x; then
 712         WM_CHECK_LIB(tiff, TIFFGetVersion, [$ljpeg -lz -lm])
 713         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 714             my_libname="-ltiff -lz"
 715         fi
 716     fi
 717
 718     if test "x$my_libname" = x; then
 719         WM_CHECK_LIB(tiff34, TIFFGetVersion, [$ljpeg -lm])
 720         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 721             my_libname="-ltiff34"
 722         fi
 723     fi
 724
 725
 726     if test "x$my_libname" != x; then
 727         WM_CHECK_HEADER(tiffio.h)
 728         if test "x$ac_cv_header_tiffio_h" = xyes; then
 729             GFXLIBS="$my_libname $GFXLIBS"
 730             ICONEXT="tiff"
 731             supported_gfx="$supported_gfx TIFF"
 732             AC_DEFINE(USE_TIFF, 1, [define if TIFF libraries are available (set by configure)])
 733         fi
 734     fi
 735 fi
 736
 737 LIBRARY_SEARCH_PATH="$lib_search_path"
 738 HEADER_SEARCH_PATH="$inc_search_path"
 739
 740 AC_SUBST(LIBRARY_SEARCH_PATH)
 741 AC_SUBST(HEADER_SEARCH_PATH)
 742
 743
 744 AC_SUBST(GFXLIBS)
 745 AC_SUBST(ICONEXT)
 746
 747
 748 dnl ==============================================
 749 dnl         End of Graphic Format Libraries
 750 dnl ==============================================
 751
 752
 753 dnl
 754 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 755 AC_CHECK_HEADERS(stdlib.h)
 756
 757 # AC_PREFIX_PROGRAM(wmaker)
 758
 759 dnl Support for PIXMAPDIR option
 760 dnl ============================
 761 AC_ARG_WITH(pixmapdir,
 762 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 763
 764 if test "x$with_pixmapdir" != "x"; then
 765         pixmapdir=$with_pixmapdir
 766 else
 767         pixmapdir=`eval echo ${datadir}/pixmaps`
 768 fi
 769
 770 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir", [define an extra path for pixmaps (set by configure)])
 771
 772 pkgdatadir=`eval echo $datadir`
 773 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker", [where shared data is stored (defined by configure)])
 774
 775 _sysconfdir=`eval echo $sysconfdir`
 776 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir", [where the configuration is stored (defined by configure)])
 777
 778
 779 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 780 dnl ==============================================
 781
 782 appspath=""
 783
 784 AC_ARG_WITH(appspath,
 785 [  --with-appspath=PATH    specify the directory for GNUstep applications], appspath=$withval )
 786
 787 if test "x$appspath" = "x"; then
 788     gnustepdir='$(prefix)/GNUstep'
 789
 790     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 791         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 792         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 793     fi
 794
 795     with_appspath=$gnustepdir/Apps
 796 fi
 797
 798 wprefsdir=$with_appspath/WPrefs.app
 799
 800 AC_SUBST(wprefsdir)
 801
 802
 803 dnl Enable User Defined Menu thing
 804 dnl ==================================
 805 AC_ARG_ENABLE(usermenu,
 806 [  --enable-usermenu       user defined menus for applications
 807 ],
 808 if test "$enableval" = yes; then
 809         AC_DEFINE(USER_MENU, 1, [define if you want user defined menus for applications])
 810 fi
 811 )
 812
 813
 814 dnl
 815 dnl Nicolai:  Program tests for Documentation Section
 816 dnl =================================================
 817 dnl DOCTYPES=""
 818 dnl AC_CHECK_PROG(MAKEINFO, makeinfo, makeinfo, ,$PATH)
 819 dnl if test "x$MAKEINFO" != "x" ; then
 820 dnl       DOCTYPES="$DOCTYPES info_doc"
 821 dnl fi
 822 dnl AC_CHECK_PROG(TEX, tex, tex, ,$PATH)
 823 dnl if test "x$TEX" != "x" ; then
 824 dnl       DOCTYPES="$DOCTYPES dvi_doc"
 825 dnl fi
 826 dnl AC_CHECK_PROG(DVIPS, dvips, dvips, ,$PATH)
 827 dnl if test "x$DVIPS" != "x" ; then
 828 dnl       DOCTYPES="$DOCTYPES ps_doc"
 829 dnl fi
 830 dnl AC_CHECK_PROG(PERL, perl, perl, ,$PATH)
 831 dnl if test "x$PERL" != "x" ; then
 832 dnl       DOCTYPES="$DOCTYPES html_doc"
 833 dnl fi
 834 dnl AC_PATH_PROG(PERL_PATH, perl, perl, ,$PATH)
 835 dnl AC_CHECK_PROG(TEXI2HTML, texi2html, texi2html, ,$PATH)
 836
 837 dnl AC_SUBST(DOCTYPES)
 838
 839 AC_OUTPUT(Makefile po/Makefile util/Makefile test/Makefile \
 840         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 841         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 842         WINGs/Extras/Makefile WINGs/po/Makefile \
 843         wmlib/Makefile wrlib/Makefile src/Makefile src/wconfig.h \
 844         doc/Makefile doc/sk/Makefile \
 845         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 846         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 847         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 848         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 849         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 850         WPrefs.app/po/Makefile \
 851         contrib/Makefile contrib/WindowMaker.spec )
 852 #       plugins/Makefile plugins/libwmfun/Makefile)
 853
 854
 855
 856 dnl
 857 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 858 dnl ===================================================================
 859 dnl
 860
 861 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 862 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 863 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 864
 865 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 866 dnl parsed by m4
 867
 868 cat <<EOF >get-wraster-flags
 869 #!/bin/sh
 870
 871 WCFLAGS="$inc_search_path"
 872 WLFLAGS="$lib_search_path"
 873 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 874
 875 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 876
 877 if test \$# -eq 0; then
 878       echo "\${usage}" 1>&2
 879       exit 1
 880 fi
 881
 882 while test \$# -gt 0; do
 883   case \$1 in
 884     --cflags)
 885         echo \$WCFLAGS
 886         ;;
 887     --ldflags|--lflags)
 888         echo \$WLFLAGS
 889         ;;
 890     --libs)
 891         echo \$WLIBS
 892         ;;
 893     *)
 894         echo "\${usage}" 1>&2
 895         exit 1
 896         ;;
 897   esac
 898   shift
 899 done
 900
 901
 902 EOF
 903
 904 cat <<EOF >get-wings-flags
 905 #!/bin/sh
 906
 907 WCFLAGS="$inc_search_path"
 908 WLFLAGS="$lib_search_path"
 909 WLIBS="-lWINGs -lwraster $GFXLIBS $XLIBS -lm $NETLIBS $INTLIBS"
 910
 911 usage="Usage: get-wings-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 912
 913 if test \$# -eq 0; then
 914       echo "\${usage}" 1>&2
 915       exit 1
 916 fi
 917
 918 while test \$# -gt 0; do
 919   case \$1 in
 920     --cflags)
 921         echo \$WCFLAGS
 922         ;;
 923     --ldflags|--lflags)
 924         echo \$WLFLAGS
 925         ;;
 926     --libs)
 927         echo \$WLIBS
 928         ;;
 929     *)
 930         echo "\${usage}" 1>&2
 931         exit 1
 932         ;;
 933   esac
 934   shift
 935 done
 936
 937
 938 EOF
 939
 940 cat <<EOF >get-wutil-flags
 941 #!/bin/sh
 942
 943 WCFLAGS="-I`eval echo ${includedir}`"
 944 WLFLAGS="-L${_libdir}"
 945 WLIBS="-lWUtil $NETLIBS $INTLIBS"
 946
 947 usage="Usage: get-wutil-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 948
 949 if test \$# -eq 0; then
 950       echo "\${usage}" 1>&2
 951       exit 1
 952 fi
 953
 954 while test \$# -gt 0; do
 955   case \$1 in
 956     --cflags)
 957         echo \$WCFLAGS
 958         ;;
 959     --ldflags|--lflags)
 960         echo \$WLFLAGS
 961         ;;
 962     --libs)
 963         echo \$WLIBS
 964         ;;
 965     *)
 966         echo "\${usage}" 1>&2
 967         exit 1
 968         ;;
 969   esac
 970   shift
 971 done
 972
 973
 974 EOF
 975
 976 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
 977 sed 's/#lp#/[/g' get-wings-flags | sed 's/#rp#/]/g' > WINGs/get-wings-flags
 978 sed 's/#lp#/[/g' get-wutil-flags | sed 's/#rp#/]/g' > WINGs/get-wutil-flags
 979
 980 chmod 755 wrlib/get-wraster-flags WINGs/get-wings-flags WINGs/get-wutil-flags
 981
 982 rm -f get-wraster-flags get-wings-flags get-wutil-flags
 983
 984
 985 dnl
 986 dnl Spit out the configuration
 987 dnl ==========================
 988
 989 supported_gfx="$supported_gfx builtin-PPM"
 990
 991 if test "x$MOFILES" = "x"; then
 992         mof=none
 993 else
 994         mof=$MOFILES
 995 fi
 996
 997
 998 echo
 999 echo "Window Maker was configured as follows:"
1000 echo
1001 echo "Installation path prefix: $prefix"
1002 echo "Installation path prefix for binaries: $_bindir"
1003 echo "Installation path for WPrefs.app: $wprefsdir" | sed -e 's|\$(prefix)|'"$prefix|"
1004 echo "Graphic format libraries: $supported_gfx"
1005 echo "Use assembly routines for wrlib: $asm_support"
1006 echo "Use inline MMX(tm) x86 assembly: $mmx_support"
1007 dnl echo "Sound support: yes"
1008 echo "Translated message files to install: $mof"
1009 if test "x$MOFILES" != "x"; then
1010         echo "Installation path of translated messages: $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
1011 fi
1012
1013 dnl WM_PRINT_REDCRAP_BUG_STATUS
1014
1015 if test "x$ac_cv_header_jpeglib_h" != xyes; then
1016 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1017 echo
1018 echo "JPEG support will not be included because the JPEG library is"
1019 echo "not installed correctly or was not found. Background images"
1020 echo "from themes will not display as they usually are JPEG files."
1021 echo
1022 echo "To fix, download and install the jpeg library and/or make sure you"
1023 echo "installed all jpeg related packages, SPECIALLY the development packages"
1024 echo "like jpeg-devel (if you use some prepackaged version of libjpeg)."
1025 echo
1026 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1027 fi
1028
1029
1030 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
1031 dnl ================================================
1032 dnl Local Variables:
1033 dnl compile-command: "autoconf"
1034 dnl End:
1035