configure.ac

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(src/WindowMaker.h)
  15
  16
  17
  18 AM_INIT_AUTOMAKE(WindowMaker, 0.94.0-crm)
  19
  20 AC_PROG_LIBTOOL
  21
  22 AM_CONFIG_HEADER(src/config.h)
  23
  24
  25 dnl Checks for host/os name
  26 dnl =======================
  27 dnl AC_CANONICAL_HOST -- already done by AC_PROG_LIBTOOL
  28
  29
  30 dnl Checks for programs.
  31 dnl ===================
  32 AC_ISC_POSIX
  33 AC_PROG_CC
  34 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  35 #AC_PROG_RANLIB
  36 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  37 AC_PROG_LN_S
  38 AC_PROG_GCC_TRADITIONAL
  39
  40
  41 dnl the prefix
  42 dnl ==========
  43 dnl
  44 dnl move this earlier in the script... anyone know why this is handled
  45 dnl in such a bizarre way?
  46
  47 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  48 dnl Let make expand exec_prefix.
  49 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  50
  51
  52 _bindir=`eval echo $bindir`
  53 _bindir=`eval echo $_bindir`
  54
  55 _libdir=`eval echo $libdir`
  56 _libdir=`eval echo $_libdir`
  57 lib_search_path="-L$_libdir"
  58
  59 inc_search_path=`eval echo $includedir`
  60 inc_search_path="-I`eval echo $inc_search_path`"
  61
  62
  63 dnl
  64 dnl Check for RedHat bugs
  65 dnl =====================
  66
  67 dnl WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
  68
  69
  70 dnl
  71 dnl Specify paths to look for libraries and headers
  72 dnl ===============================================
  73 AC_ARG_WITH(libs-from,
  74 [  --with-libs-from        pass compiler flags to look for libraries],
  75         [lib_search_path="$withval $lib_search_path"])
  76
  77 AC_ARG_WITH(incs-from,
  78 [  --with-incs-from        pass compiler flags to look for header files],
  79         [inc_search_path="$withval $inc_search_path"])
  80
  81
  82
  83 dnl Checks for library functions.
  84 dnl ============================
  85 dnl not used anywhere
  86 dnl AC_FUNC_MEMCMP
  87 AC_FUNC_VPRINTF
  88 AC_CHECK_FUNCS(gethostname select poll strerror strcasecmp strncasecmp \
  89                setsid atexit mallinfo mkstemp snprintf vsnprintf asprintf \
  90                vasprintf)
  91
  92 dnl ripped from samba
  93 dnl
  94 AC_CACHE_CHECK([for C99 vsnprintf],_cv_HAVE_C99_VSNPRINTF,[
  95 AC_TRY_RUN([
  96 #include <sys/types.h>
  97 #include <stdarg.h>
  98 void foo(const char *format, ...) {
  99        va_list ap;
 100        int len;
 101        char buf[5];
 102
 103        va_start(ap, format);
 104        len = vsnprintf(0, 0, format, ap);
 105        va_end(ap);
 106        if (len != 5) exit(1);
 107
 108        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 109
 110        exit(0);
 111 }
 112 main() { foo("hello"); }
 113 ],
 114 _cv_HAVE_C99_VSNPRINTF=yes,_cv_HAVE_C99_VSNPRINTF=no,_cv_HAVE_C99_VSNPRINTF=cross)])
 115 if test x"$_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 116     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [define if you have vsnprintf with C99 semantics (set by configure)])
 117 fi
 118
 119 dnl Check for inotify
 120 dnl =================
 121 AC_CHECK_HEADERS(sys/inotify.h, AC_DEFINE(HAVE_INOTIFY, 1, Check for inotify))
 122
 123 dnl Check CPP
 124 dnl =========
 125 if test "x$CPP_PATH" = x; then
 126     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 127                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 128 fi
 129
 130 dnl
 131 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 132 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 133 dnl standard locations
 134 dnl
 135 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 136     if test "$GCC" = "yes"; then
 137         CPP_PATH="gcc -E -x c"
 138     else
 139         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 140             CPP_PATH="$CPP_PATH -B"
 141         else
 142             echo "cpp, the C preprocessor was not found in your system."
 143             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 144             exit
 145         fi
 146     fi
 147 fi
 148 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH", [define to the path to cpp])
 149
 150
 151
 152 dnl Checks for header files.
 153 dnl =======================
 154 AC_HEADER_SYS_WAIT
 155 AC_HEADER_TIME
 156 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h \
 157                  libintl.h sys/select.h poll.h malloc.h ctype.h string.h \
 158                  strings.h)
 159
 160
 161
 162 dnl Checks for typedefs, structures, and compiler characteristics.
 163 dnl ==============================================================
 164 AC_DECL_SYS_SIGLIST
 165 AC_C_CONST
 166 #AC_TYPE_SIZE_T
 167 #AC_TYPE_PID_T
 168 AC_TYPE_SIGNAL
 169
 170
 171
 172 dnl Compiler/architecture specific optimizations
 173 dnl ============================================
 174
 175
 176 dnl GCC/as with MMX support
 177 dnl -----------------------
 178
 179 # until we fix it, leave it disabled
 180 asm_support=no
 181 mmx_support=no
 182
 183 check_for_mmx_support=yes
 184 AC_ARG_ENABLE(mmx,
 185    [  --disable-mmx          disable compilation of MMX inline assembly ],
 186    [if test x$enableval != xyes; then
 187     check_for_mmx_support=no
 188     fi])
 189
 190 if test "$ac_cv_prog_gcc" = yes -a "$check_for_mmx_support" = yes; then
 191 case $host_cpu in
 192 *i?86*)
 193
 194     # gcc-3.3 or newer complains about some of our stuff without this
 195     NOSTRICTALIASING="-fno-strict-aliasing"
 196
 197     AC_CACHE_CHECK(whether gcc supports x86 inline asm,
 198                    ac_cv_c_inline_asm,
 199                    [AC_TRY_LINK(,[{int x; asm volatile("movl %%eax, %%ebx\n\t pushal\n\t popal"::
 200                           "m" (x),"m" (x),"m" (x),"m" (x),"m" (x),"m" (x),
 201                           "m" (x),"m" (x),"m" (x),"m" (x),"m" (x),"m" (x));}],
 202                    ac_cv_c_inline_asm=yes,
 203                    ac_cv_c_inline_asm=no)])
 204
 205     if test "x$ac_cv_c_inline_asm" = xyes; then
 206        AC_DEFINE(ASM_X86, 1, [define if processor is x86 (normally detected by configure)])
 207        asm_support=yes
 208
 209        AC_CACHE_CHECK(whether gcc supports MMX(tm) inline asm,
 210                       ac_cv_c_inline_mmx,
 211                       [AC_TRY_LINK(,[asm ("movq %mm0, %mm1");],
 212                       ac_cv_c_inline_mmx=yes,
 213                       ac_cv_c_inline_mmx=no)])
 214
 215        if test "x$ac_cv_c_inline_mmx" = xyes; then
 216           AC_DEFINE(ASM_X86_MMX, 1, [define if processor is x86 with MMX(tm) support (normally autodetected by configure)])
 217           mmx_support=yes
 218        fi
 219     fi
 220     ;;
 221 esac
 222 fi
 223 AC_SUBST(NOSTRICTALIASING)
 224
 225
 226 dnl pkg-config
 227 dnl ----------
 228 dnl AC_ARG_VAR(PKGCONFIG, [pkg-config command])
 229 AC_CHECK_PROG(PKGCONFIG, pkg-config, pkg-config)
 230
 231
 232 dnl gettext
 233 dnl -------
 234
 235
 236 dnl AM_GNU_GETTEXT
 237
 238
 239
 240 INTLIBS=""
 241
 242 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 243         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 244                          INTLIBS="" ))
 245
 246 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 247
 248 if test "$XGETTEXT" != ""; then
 249     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 250         echo "xgettext isn't GNU version"
 251         XGETTEXT=""
 252     fi
 253 fi
 254
 255 if test "$LINGUAS" != ""; then
 256     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 257         AC_DEFINE(I18N, 1, [Internationalization (I18N) support (set by configure)])
 258         PO=""
 259         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 260     else
 261         LINGUAS=""
 262         PO=""
 263         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 264     fi
 265 else
 266         INTLIBS=""
 267         MOFILES=""
 268         WPMOFILES=""
 269         UTILMOFILES=""
 270         PO=""
 271 fi
 272
 273
 274 dnl The Tower of Babel
 275 dnl ==================
 276
 277 dnl List of supported locales
 278 dnl -------------------------
 279 supported_locales="be bg bs ca cs da de el es et fi fr gl hr hu hy it ja ko ms nl no pl pt ro ru sk sv tr zh_CN zh_TW"
 280 supported_wprefs_locales="bg ca cs de es et fi fr hr hu it ja ko pt ru sk zh_CN zh_TW"
 281 supported_wings_locales="bg ca cs de fr sk"
 282 supported_util_locales="de"
 283
 284 for lang in $LINGUAS; do
 285         ok=0
 286         for l in $supported_locales; do
 287                 if test "$l" = "$lang"; then
 288                         ok=1
 289                         break
 290                 fi
 291         done
 292         if test "$ok" = 1; then
 293                 MOFILES="$MOFILES $lang.mo"
 294         else
 295                 echo "Locale $lang is not supported."
 296         fi
 297         ok=0
 298         for l in $supported_wprefs_locales; do
 299                 if test "$l" = "$lang"; then
 300                         ok=1
 301                         break
 302                 fi
 303         done
 304         if test "$ok" = 1; then
 305                 WPMOFILES="$WPMOFILES $lang.mo"
 306         fi
 307         ok=0
 308         for l in $supported_util_locales; do
 309                 if test "$l" = "$lang"; then
 310                         ok=1
 311                         break
 312                 fi
 313         done
 314         if test "$ok" = 1; then
 315                 UTILMOFILES="$UTILMOFILES $lang.mo"
 316         fi
 317         ok=0
 318         for l in $supported_wings_locales; do
 319                 if test "$l" = "$lang"; then
 320                         ok=1
 321                         break
 322                 fi
 323         done
 324         if test "$ok" = 1; then
 325                 WINGSMOFILES="$WINGSMOFILES $lang.mo"
 326         fi
 327 done
 328
 329
 330 dnl Kanji Characters support
 331 dnl ========================
 332
 333 case $host_os in
 334         freebsd*)
 335                 AC_CHECK_LIB(xpg4, setlocale, [LIBS="$LIBS -lxpg4"]);;
 336         *)
 337         ;;
 338 esac
 339
 340
 341
 342 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 343 dnl ===========================================
 344 AC_ARG_WITH(nlsdir,
 345         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 346
 347
 348 if test "x$NLSDIR" = "x"; then
 349         if test "x$with_nlsdir" != "x"; then
 350                 NLSDIR=$with_nlsdir
 351         else
 352                 NLSDIR='$(prefix)/lib/locale'
 353         fi
 354 fi
 355
 356
 357
 358 AC_SUBST(INTLIBS)
 359 AC_SUBST(NLSDIR)
 360 AC_SUBST(MOFILES)
 361 AC_SUBST(WPMOFILES)
 362 AC_SUBST(UTILMOFILES)
 363 AC_SUBST(WINGSMOFILES)
 364 AC_SUBST(supported_locales)
 365
 366
 367
 368 dnl Support for various hint things
 369 dnl ===============================
 370
 371 dnl
 372 dnl Beautify compilation messages
 373 dnl ---------------------------------------------
 374 AC_ARG_ENABLE(verbose-compile, AS_HELP_STRING([--disable-verbose-compile],
 375                                [Streamline compilation messages (default off)]),
 376   [
 377         QUIET='@echo "     CC" $@;'
 378         QUIET_AR='@echo "     AR" $@;'
 379         LIBTOOL_ARG="--silent"
 380         MAKEFLAGS="-s"
 381         AC_SUBST(QUIET)
 382         AC_SUBST(QUIET_AR)
 383         AC_SUBST(LIBTOOL_ARG)
 384         AC_SUBST(MAKEFLAGS)
 385 ])
 386
 387
 388
 389 dnl
 390 dnl Networking stuff
 391 dnl
 392
 393 NETLIBS=""
 394
 395 AC_CHECK_FUNC(connect,,
 396         AC_CHECK_LIB(socket, connect, NETLIBS="$NETLIBS -lsocket"))
 397
 398 AC_CHECK_FUNC(gethostbyname,,
 399         AC_CHECK_LIB(nsl, gethostbyname, NETLIBS="$NETLIBS -lnsl"))
 400
 401 AC_CHECK_FUNC(inet_aton, AC_DEFINE(HAVE_INET_ATON, 1, [define if you have then inet_aton function (set by configure)]),
 402      for lib in resolv socket inet bsd; do
 403         AC_CHECK_LIB($lib, inet_aton, [AC_DEFINE(HAVE_INET_ATON)
 404                      NETLIBS="$NETLIBS -l$lib"; break],, $NETLIBS)
 405      done)
 406
 407 AC_SUBST(NETLIBS)
 408
 409
 410 dnl ===========================================
 411 dnl             Stuff that uses X
 412 dnl ===========================================
 413
 414 AC_PATH_XTRA
 415
 416 if test $no_x; then
 417     AC_MSG_ERROR([The path for the X11 files not found!
 418 Make sure you have X and it's headers and libraries (the -devel packages
 419 in Linux) installed.])
 420 fi
 421
 422 X_LIBRARY_PATH=$x_libraries
 423
 424 XCFLAGS="$X_CFLAGS"
 425
 426 XLFLAGS="$X_LIBS"
 427
 428 XLIBS="-lX11 -lXmu $X_EXTRA_LIBS"
 429
 430
 431 lib_search_path="$lib_search_path $XLFLAGS"
 432 inc_search_path="$inc_search_path $XCFLAGS"
 433
 434
 435 AC_SUBST(X_LIBRARY_PATH)
 436
 437
 438
 439 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 440 dnl by MANOME Tomonori
 441 dnl ===========================================
 442 use_locale=yes
 443 AC_ARG_ENABLE(locale,
 444 [  --disable-locale        disable use of X locale support],
 445                 use_locale=no)
 446
 447 if test "$use_locale" = yes; then
 448         AC_CHECK_LIB(X11, _Xsetlocale,
 449                 AC_DEFINE(X_LOCALE, 1, [define if you want support for X window's X_LOCALE (set by configure)]),,
 450                 $XLFLAGS $XLIBS)
 451 fi
 452
 453
 454 dnl Check whether XInternAtoms() exist
 455 dnl ==================================
 456 AC_CHECK_LIB(X11, XInternAtoms,
 457              AC_DEFINE(HAVE_XINTERNATOMS, 1, [define if your X server has XInternAtoms() (set by configure)]),,
 458              $XLFLAGS $XLIBS)
 459
 460 dnl Check whether XConvertCase() exist
 461 dnl ==================================
 462 AC_CHECK_LIB(X11, XConvertCase,
 463              AC_DEFINE(HAVE_XCONVERTCASE, 1, [define if your X server has XConvertCase() (set by configure)]),,
 464              $XLFLAGS $XLIBS)
 465
 466
 467 dnl XKB keyboard language status
 468 dnl ============================
 469 AC_ARG_ENABLE(modelock,
 470 [  --enable-modelock       XKB keyboard language status support],
 471                 AC_DEFINE(XKB_MODELOCK, 1, [whether XKB language MODELOCK should be enabled]))
 472
 473
 474
 475 dnl Shape support
 476 dnl =============
 477 shape=yes
 478 AC_ARG_ENABLE(shape,
 479 [  --disable-shape         disable shaped window extension support],
 480                 shape=$enableval, shape=yes)
 481
 482 added_xext=no
 483
 484 if test "$shape" = yes; then
 485         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 486                 added_xext=yes
 487                 AC_DEFINE(SHAPE, 1, [define if you want support for shaped windows (set by configure)])],
 488                 shape=no, $XLFLAGS $XLIBS)
 489 fi
 490
 491
 492 dnl Xft2 antialiased font support
 493 dnl =============================
 494
 495 xft=yes
 496 XFTLIBS=""
 497
 498 if test "x$PKGCONFIG" != x -a "`$PKGCONFIG xft; echo $?`" = 0; then
 499         XFTCONFIG="$PKGCONFIG xft"
 500         pkgconfig_xft=yes
 501 else
 502         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 503 fi
 504
 505 AC_MSG_CHECKING([for the Xft2 library])
 506
 507 if test "x$XFTCONFIG" != x; then
 508         XFTLIBS=`$XFTCONFIG --libs`
 509         XFTFLAGS=`$XFTCONFIG --cflags`
 510         AC_MSG_RESULT([found])
 511 else
 512         AC_MSG_RESULT([not found])
 513         echo
 514         echo "ERROR!!! libXft2 is not installed or could not be found."
 515         echo "         Xft2 is a requirement for building Window Maker."
 516         echo "         Please install it (along with fontconfig) before continuing."
 517         echo
 518         exit 1
 519 fi
 520
 521 minXFT="2.1.0"
 522 goodxft="no"
 523
 524 dnl
 525 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 526 dnl
 527 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 528
 529 if test "$goodxft" = no; then
 530         echo
 531         echo "ERROR!!! libXft on this system is an old version."
 532         echo "         Please consider upgrading to at least version ${minXFT}."
 533         echo
 534         exit 1
 535 fi
 536
 537 AC_SUBST(XFTFLAGS)
 538 AC_SUBST(XFTLIBS)
 539
 540
 541 dnl XINERAMA support
 542 dnl ================
 543 xinerama=no
 544 AC_ARG_ENABLE(xinerama,
 545 [  --enable-xinerama       enable Xinerama extension support],
 546                 xinerama=$enableval, xinerama=no)
 547
 548 if test "$xinerama" = yes; then
 549         AC_CHECK_LIB(Xinerama, XineramaQueryScreens,
 550                 [XLIBS="-lXinerama $XLIBS"
 551                 xfxine=yes],
 552                 xfxine=no, $XLFLAGS $XLIBS)
 553
 554         AC_CHECK_LIB(Xext, XineramaGetInfo,
 555                 [sunxine=yes
 556                 ], sunxine=no, $XLFLAGS $XLIBS)
 557
 558         if test "$xfxine" = yes; then
 559                 xine=1
 560         fi
 561
 562         if test "$sunxine" = yes; then
 563             xine=1
 564             AC_DEFINE(SOLARIS_XINERAMA, 1,
 565                 [define if you want support for the XINERAMA extension and are in Solaris (set by configure)])
 566         fi
 567
 568         if test "$xine" = 1; then
 569             AC_DEFINE(XINERAMA, 1,
 570                 [define if you want support for the XINERAMA extension (set by configure)])
 571         fi
 572 fi
 573
 574
 575
 576 dnl MIT-SHM support
 577 dnl ===============
 578 shm=yes
 579 AC_ARG_ENABLE(shm,
 580 [  --disable-shm           disable usage of MIT-SHM extension],
 581                 shm=$enableval, shm=yes)
 582
 583 if test "$shm" = yes; then
 584         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 585
 586         if test "$ok" = yes; then
 587         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 588         fi
 589
 590         if test "$ok" = yes; then
 591                 if test "$added_xext" = no; then
 592                         XLIBS="-lXext $XLIBS"
 593                 fi
 594                 AC_DEFINE(XSHM, 1, [define if X's shared memory extension is available (set by configure)])
 595         fi
 596 fi
 597
 598
 599 dnl R6 Style Session Management Support
 600 dnl ===================================
 601
 602 #
 603 #
 604 #AC_DEFINE(R6SM)
 605 #AC_SUBST(XSMPLIBS)
 606 #
 607
 608
 609 dnl ==============================================
 610 dnl         Graphic Format Libraries
 611 dnl ==============================================
 612
 613
 614
 615
 616
 617 dnl XPM Support
 618 dnl ===========
 619 xpm=yes
 620 AC_ARG_ENABLE(xpm,
 621 [  --disable-xpm           disable use of XPM pixmaps through libXpm],
 622         xpm=$enableval, xpm=yes)
 623
 624 if test "$xpm" = yes; then
 625     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 626
 627     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 628         WM_CHECK_HEADER(X11/xpm.h)
 629         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 630                 GFXLIBS="$GFXLIBS -lXpm"
 631                 supported_gfx="XPM"
 632                 AC_DEFINE(USE_XPM, 1, [define if XPM libraries are available (set by configure)])
 633         else
 634                 supported_gfx="builtin-XPM"
 635         fi
 636     fi
 637 fi
 638
 639 # for wmlib
 640 AC_SUBST(XCFLAGS)
 641 # for test
 642 AC_SUBST(XLFLAGS)
 643 AC_SUBST(XLIBS)
 644
 645 AC_SUBST(X_EXTRA_LIBS)
 646
 647 dnl ===============================================
 648 dnl             End of stuff that uses X
 649 dnl ===============================================
 650
 651
 652
 653 dnl PNG Support
 654 dnl ===========
 655 png=yes
 656 AC_ARG_ENABLE(png,
 657 [  --disable-png           disable PNG support through libpng],
 658         png=$enableval, png=yes, png=no)
 659
 660
 661 if test "$png" = yes ; then
 662     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 663
 664     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 665         WM_CHECK_HEADER(png.h)
 666         if test "x$ac_cv_header_png_h" = xyes; then
 667             GFXLIBS="$GFXLIBS -lpng -lz"
 668             supported_gfx="$supported_gfx PNG"
 669             AC_DEFINE(USE_PNG, 1, [define if PNG libraries are available (set by configure)])
 670         fi
 671     fi
 672 fi
 673
 674
 675 dnl JPEG Support
 676 dnl ============
 677 jpeg=yes
 678 ljpeg=""
 679 AC_ARG_ENABLE(jpeg,
 680 [  --disable-jpeg          disable JPEG support through libjpeg],
 681         jpeg=$enableval, jpeg=yes, jpeg=no)
 682
 683 if test "$jpeg" = yes; then
 684     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 685
 686     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 687
 688         ljpeg="-ljpeg"
 689
 690         WM_CHECK_HEADER(jpeglib.h)
 691         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 692             GFXLIBS="$GFXLIBS -ljpeg"
 693             supported_gfx="$supported_gfx JPEG"
 694             AC_DEFINE(USE_JPEG, 1, [define if JPEG libraries are available (set by configure)])
 695         fi
 696     fi
 697 fi
 698
 699
 700 dnl GIF Support
 701 dnl ============
 702 gif=yes
 703 AC_ARG_ENABLE(gif,
 704 [  --disable-gif           disable GIF support through libgif or libungif],
 705         gif=$enableval, gif=yes, gif=no)
 706
 707 if test "$gif" = yes; then
 708     my_libname=""
 709     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 710     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 711         my_libname=-lungif
 712     fi
 713 dnl
 714 dnl libungif is the same thing as libgif for all practical purposes.
 715 dnl
 716     if test "x$my_libname" = x; then
 717         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 718         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 719             my_libname=-lgif
 720         fi
 721     fi
 722
 723     if test "$my_libname" != x; then
 724         WM_CHECK_HEADER(gif_lib.h)
 725         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 726             GFXLIBS="$GFXLIBS $my_libname"
 727             supported_gfx="$supported_gfx GIF"
 728             AC_DEFINE(USE_GIF, 1, [define if GIF libraries are available (set by configure)])
 729         fi
 730     fi
 731 fi
 732
 733
 734
 735 dnl TIFF Support
 736 dnl ============
 737 AC_ARG_ENABLE(tiff,
 738 [  --disable-tiff          disable use of TIFF images through libtiff],
 739         tif=$enableval, tif=yes, tif=no)
 740
 741 #
 742 # TIFF can optionally have JPEG and/or zlib support. Must find out
 743 # when they are supported so that correct library flags are passed during
 744 # detection and linkage
 745 #
 746 #
 747 # By default use xpm icons if tiff is not found.
 748 ICONEXT="xpm"
 749 #
 750
 751 if test "$tif" = yes; then
 752     my_libname=""
 753     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 754     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 755         my_libname="-ltiff"
 756     fi
 757 dnl
 758 dnl Retry with zlib
 759 dnl
 760     unset ac_cv_lib_tiff_TIFFGetVersion
 761     if test "x$my_libname" = x; then
 762         WM_CHECK_LIB(tiff, TIFFGetVersion, [$ljpeg -lz -lm])
 763         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 764             my_libname="-ltiff -lz"
 765         fi
 766     fi
 767
 768     if test "x$my_libname" = x; then
 769         WM_CHECK_LIB(tiff34, TIFFGetVersion, [$ljpeg -lm])
 770         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 771             my_libname="-ltiff34"
 772         fi
 773     fi
 774
 775
 776     if test "x$my_libname" != x; then
 777         WM_CHECK_HEADER(tiffio.h)
 778         if test "x$ac_cv_header_tiffio_h" = xyes; then
 779             GFXLIBS="$my_libname $GFXLIBS"
 780             ICONEXT="tiff"
 781             supported_gfx="$supported_gfx TIFF"
 782             AC_DEFINE(USE_TIFF, 1, [define if TIFF libraries are available (set by configure)])
 783         fi
 784     fi
 785 fi
 786
 787 LIBRARY_SEARCH_PATH="$lib_search_path"
 788 HEADER_SEARCH_PATH="$inc_search_path"
 789
 790 AC_SUBST(LIBRARY_SEARCH_PATH)
 791 AC_SUBST(HEADER_SEARCH_PATH)
 792
 793
 794 AC_SUBST(GFXLIBS)
 795 AC_SUBST(ICONEXT)
 796
 797
 798 dnl ==============================================
 799 dnl         End of Graphic Format Libraries
 800 dnl ==============================================
 801
 802
 803 dnl
 804 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 805 AC_CHECK_HEADERS(stdlib.h)
 806
 807 # AC_PREFIX_PROGRAM(wmaker)
 808
 809 dnl Support for PIXMAPDIR option
 810 dnl ============================
 811 AC_ARG_WITH(pixmapdir,
 812 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 813
 814 if test "x$with_pixmapdir" != "x"; then
 815         pixmapdir=$with_pixmapdir
 816 else
 817         pixmapdir=`eval echo ${datadir}/pixmaps`
 818 fi
 819
 820 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir", [define an extra path for pixmaps (set by configure)])
 821
 822 pkgdatadir=`eval echo $datadir`
 823 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker", [where shared data is stored (defined by configure)])
 824
 825 _sysconfdir=`eval echo $sysconfdir`
 826 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir", [where the configuration is stored (defined by configure)])
 827
 828
 829 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 830 dnl ==============================================
 831
 832 AC_ARG_WITH(appspath,
 833 [  --with-gnustepdir=PATH  specify the directory for GNUstep applications])
 834
 835 if test "x`echo $with_gnustepdir | grep ^/`" != "x"; then
 836     appspath=$with_gnustepdir
 837 fi
 838
 839 if test "x$appspath$GNUSTEP_LOCAL_ROOT" = "x"; then
 840     wprefs_base_dir=${prefix}
 841     wprefs_datadir="${datadir}/WPrefs"
 842     wprefs_bindir="${bindir}"
 843 else
 844     gnustepdir=$appspath
 845
 846     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 847         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 848         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 849     fi
 850
 851     wprefs_base_dir=$gnustepdir/Applications
 852     wprefs_datadir=$wprefs_base_dir/WPrefs.app
 853     wprefs_bindir=$wprefs_base_dir/WPrefs.app
 854 fi
 855
 856 AC_SUBST(wprefs_datadir)
 857 AC_SUBST(wprefs_bindir)
 858
 859
 860 dnl Enable User Defined Menu thing
 861 dnl ==================================
 862 AC_ARG_ENABLE(usermenu,
 863 [  --enable-usermenu       user defined menus for applications
 864 ],
 865 if test "$enableval" = yes; then
 866         AC_DEFINE(USER_MENU, 1, [define if you want user defined menus for applications])
 867 fi
 868 )
 869
 870
 871 AC_OUTPUT(Makefile po/Makefile util/Makefile util/po/Makefile test/Makefile \
 872         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 873         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 874         WINGs/Extras/Makefile WINGs/po/Makefile \
 875         wmlib/Makefile wrlib/Makefile wrlib/tests/Makefile \
 876         src/Makefile src/wconfig.h \
 877         doc/Makefile doc/sk/Makefile \
 878         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 879         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 880         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 881         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 882         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 883         WPrefs.app/po/Makefile \
 884         contrib/Makefile contrib/WindowMaker.spec )
 885
 886
 887
 888 dnl
 889 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 890 dnl ===================================================================
 891 dnl
 892
 893 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 894 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 895 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 896
 897 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 898 dnl parsed by m4
 899
 900 cat <<EOF >get-wraster-flags
 901 #!/bin/sh
 902
 903 WCFLAGS="$inc_search_path"
 904 WLFLAGS="$lib_search_path"
 905 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 906
 907 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 908
 909 if test \$# -eq 0; then
 910       echo "\${usage}" 1>&2
 911       exit 1
 912 fi
 913
 914 while test \$# -gt 0; do
 915   case \$1 in
 916     --cflags)
 917         echo \$WCFLAGS
 918         ;;
 919     --ldflags|--lflags)
 920         echo \$WLFLAGS
 921         ;;
 922     --libs)
 923         echo \$WLIBS
 924         ;;
 925     *)
 926         echo "\${usage}" 1>&2
 927         exit 1
 928         ;;
 929   esac
 930   shift
 931 done
 932
 933
 934 EOF
 935
 936 cat <<EOF > wrlib/wrlib.pc
 937 Name: wrlib
 938 Description: Image manipulation and conversion library
 939 Version: $VERSION
 940 Libs: $lib_search_path -lwraster $GFXLIBS $XLIBS -lm
 941 Cflags: $inc_search_path
 942 EOF
 943
 944 cat <<EOF >get-wings-flags
 945 #!/bin/sh
 946
 947 WCFLAGS="$inc_search_path"
 948 WLFLAGS="$lib_search_path"
 949 WLIBS="-lWINGs -lWUtil -lwraster $GFXLIBS $XFTLIBS $XLIBS -lm $NETLIBS $INTLIBS"
 950
 951 usage="Usage: get-wings-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 952
 953 if test \$# -eq 0; then
 954       echo "\${usage}" 1>&2
 955       exit 1
 956 fi
 957
 958 while test \$# -gt 0; do
 959   case \$1 in
 960     --cflags)
 961         echo \$WCFLAGS
 962         ;;
 963     --ldflags|--lflags)
 964         echo \$WLFLAGS
 965         ;;
 966     --libs)
 967         echo \$WLIBS
 968         ;;
 969     *)
 970         echo "\${usage}" 1>&2
 971         exit 1
 972         ;;
 973   esac
 974   shift
 975 done
 976
 977
 978 EOF
 979
 980 cat <<EOF > WINGs/WINGs.pc
 981 Name: WINGs
 982 Description: Small widget set with the NeXTStep(TM) look and feel
 983 Version: $VERSION
 984 Requires: wrlib
 985 Libs: $lib_search_path -lWINGs $XFTLIBS $XLIBS -lm $NETLIBS $INTLIBS
 986 Cflags: $inc_search_path
 987 EOF
 988
 989 cat <<EOF >get-wutil-flags
 990 #!/bin/sh
 991
 992 WCFLAGS="-I`eval echo ${includedir}`"
 993 WLFLAGS="-L${_libdir}"
 994 WLIBS="-lWUtil $NETLIBS $INTLIBS"
 995
 996 usage="Usage: get-wutil-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 997
 998 if test \$# -eq 0; then
 999       echo "\${usage}" 1>&2
1000       exit 1
1001 fi
1002
1003 while test \$# -gt 0; do
1004   case \$1 in
1005     --cflags)
1006         echo \$WCFLAGS
1007         ;;
1008     --ldflags|--lflags)
1009         echo \$WLFLAGS
1010         ;;
1011     --libs)
1012         echo \$WLIBS
1013         ;;
1014     *)
1015         echo "\${usage}" 1>&2
1016         exit 1
1017         ;;
1018   esac
1019   shift
1020 done
1021
1022
1023 EOF
1024
1025 cat <<EOF > wmlib/wmlib.pc
1026 Name: wmlib
1027 Description: FIXME: What do I write here?
1028 Version: $VERSION
1029 Requires: wrlib
1030 Libs: $lib_search_path -lWUtil $NETLIBS $INTLIBS
1031 Cflags: $inc_search_path
1032 EOF
1033
1034 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
1035 sed 's/#lp#/[/g' get-wings-flags | sed 's/#rp#/]/g' > WINGs/get-wings-flags
1036 sed 's/#lp#/[/g' get-wutil-flags | sed 's/#rp#/]/g' > WINGs/get-wutil-flags
1037
1038 chmod 755 wrlib/get-wraster-flags WINGs/get-wings-flags WINGs/get-wutil-flags
1039
1040 rm -f get-wraster-flags get-wings-flags get-wutil-flags
1041
1042
1043 dnl
1044 dnl Spit out the configuration
1045 dnl ==========================
1046
1047 supported_gfx="$supported_gfx builtin-PPM"
1048
1049 if test "x$MOFILES" = "x"; then
1050         mof=None
1051 else
1052         mof=`echo $MOFILES`
1053 fi
1054
1055 if test "x$MOFILES" = "x"; then
1056         languages=None
1057 else
1058         languages=`echo $MOFILES | sed 's/.mo//g'`
1059 fi
1060
1061 echo
1062 echo "Window Maker was configured as follows:"
1063 echo
1064 echo "Installation path prefix            : $prefix"
1065 echo "Installation path for binaries      : $_bindir"
1066 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
1067 echo "Supported graphic format libraries  : $supported_gfx"
1068 echo "Use assembly routines for wrlib     : $asm_support"
1069 echo "Use inline MMX(tm) x86 assembly     : $mmx_support"
1070 echo "Antialiased text support in WINGs   : $xft"
1071 echo "Xinerama extension support          : $xinerama"
1072 echo "Translated message files to install : $mof"
1073 dnl echo "Supported languages beside English  : $languages"
1074 if test "x$MOFILES" != "x"; then
1075         echo "Installation path for translations  : $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
1076 fi
1077 echo
1078
1079 dnl WM_PRINT_REDCRAP_BUG_STATUS
1080
1081 if test "x$ac_cv_header_jpeglib_h" != xyes; then
1082 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1083 echo
1084 echo "JPEG support will not be included because the JPEG library is"
1085 echo "not installed correctly or was not found. Background images"
1086 echo "from themes will not display as they usually are JPEG files."
1087 echo
1088 echo "To fix, download and install the jpeg library and/or make sure you"
1089 echo "installed all jpeg related packages, SPECIALLY the development packages"
1090 echo "like jpeg-devel (if you use some prepackaged version of libjpeg)."
1091 echo
1092 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1093 fi
1094
1095
1096 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
1097 dnl ================================================
1098 dnl Local Variables:
1099 dnl compile-command: "autoconf"
1100 dnl End:
1101