configure.ac

   1 dnl
   2 dnl Window Maker autoconf input.
   3 dnl
   4 dnl Process with:
   5 dnl               aclocal
   6 dnl               autoheader
   7 dnl               autoconf
   8 dnl               libtoolize --force --automake
   9 dnl               automake -a --gnu --include-deps
  10 dnl
  11 dnl
  12
  13
  14 AC_INIT(src/WindowMaker.h)
  15
  16
  17
  18 AM_INIT_AUTOMAKE(WindowMaker, 0.94.0-crm)
  19
  20 AC_PROG_LIBTOOL
  21
  22 AM_CONFIG_HEADER(src/config.h)
  23
  24
  25 dnl Checks for host/os name
  26 dnl =======================
  27 dnl AC_CANONICAL_HOST -- already done by AC_PROG_LIBTOOL
  28
  29
  30 dnl Checks for programs.
  31 dnl ===================
  32 AC_ISC_POSIX
  33 AC_PROG_CC
  34 dnl AC_PROG_MAKE_SET -- already done by AM_INIT_AUTOMAKE
  35 #AC_PROG_RANLIB
  36 dnl AC_PROG_INSTALL -- already done by AM_INIT_AUTOMAKE
  37 AC_PROG_LN_S
  38 AC_PROG_GCC_TRADITIONAL
  39
  40 dnl Platform-specific Makefile setup
  41 dnl ================================
  42
  43 case "${host}" in
  44         *-*-linux*)
  45                 WM_OSDEP="linux"
  46         ;;
  47         *-*-freebsd*)
  48                 WM_OSDEP="bsd"
  49                 CFLAGS="$CFLAGS -DFREEBSD"
  50         ;;
  51         *-*-netbsd*)
  52                 WM_OSDEP="bsd"
  53                 CFLAGS="$CFLAGS -DNETBSD"
  54         ;;
  55         *-*-openbsd*)
  56                 WM_OSDEP="bsd"
  57         CFLAGS="$CFLAGS -DOPENBSD"
  58         ;;
  59         *-*-dragonfly*)
  60                 WM_OSDEP="bsd"
  61                 CFLAGS="$CFLAGS -DDRAGONFLYBSD"
  62         ;;
  63         *-apple-darwin*)
  64                 WM_OSDEP="darwin"
  65         ;;
  66         *-*-solaris*)
  67                 WM_OSDEP="stub"         # solaris.c when done
  68         ;;
  69         *)
  70                 WM_OSDEP="stub"
  71         ;;
  72 esac
  73 AC_SUBST(WM_OSDEP)
  74
  75
  76 dnl the prefix
  77 dnl ==========
  78 dnl
  79 dnl move this earlier in the script... anyone know why this is handled
  80 dnl in such a bizarre way?
  81
  82 test "x$prefix" = xNONE && prefix=$ac_default_prefix
  83 dnl Let make expand exec_prefix.
  84 test "x$exec_prefix" = xNONE && exec_prefix='${prefix}'
  85
  86
  87 _bindir=`eval echo $bindir`
  88 _bindir=`eval echo $_bindir`
  89
  90 _libdir=`eval echo $libdir`
  91 _libdir=`eval echo $_libdir`
  92 lib_search_path="-L$_libdir"
  93
  94 inc_search_path=`eval echo $includedir`
  95 inc_search_path="-I`eval echo $inc_search_path`"
  96
  97
  98 dnl
  99 dnl Check for RedHat bugs
 100 dnl =====================
 101
 102 dnl WM_CHECK_REDCRAP_BUGS($prefix,$_bindir,$_libdir)
 103
 104
 105 dnl
 106 dnl Specify paths to look for libraries and headers
 107 dnl ===============================================
 108 AC_ARG_WITH(libs-from,
 109 [  --with-libs-from        pass compiler flags to look for libraries],
 110         [lib_search_path="$withval $lib_search_path"])
 111
 112 AC_ARG_WITH(incs-from,
 113 [  --with-incs-from        pass compiler flags to look for header files],
 114         [inc_search_path="$withval $inc_search_path"])
 115
 116
 117
 118 dnl Checks for library functions.
 119 dnl ============================
 120 dnl not used anywhere
 121 dnl AC_FUNC_MEMCMP
 122 AC_FUNC_VPRINTF
 123 AC_CHECK_FUNCS(gethostname select poll strerror strcasecmp strncasecmp \
 124                setsid atexit mallinfo mkstemp snprintf vsnprintf asprintf \
 125                vasprintf)
 126
 127 dnl ripped from samba
 128 dnl
 129 AC_CACHE_CHECK([for C99 vsnprintf],_cv_HAVE_C99_VSNPRINTF,[
 130 AC_TRY_RUN([
 131 #include <sys/types.h>
 132 #include <stdarg.h>
 133 void foo(const char *format, ...) {
 134        va_list ap;
 135        int len;
 136        char buf[5];
 137
 138        va_start(ap, format);
 139        len = vsnprintf(0, 0, format, ap);
 140        va_end(ap);
 141        if (len != 5) exit(1);
 142
 143        if (snprintf(buf, 3, "hello") != 5 || strcmp(buf, "he") != 0) exit(1);
 144
 145        exit(0);
 146 }
 147 main() { foo("hello"); }
 148 ],
 149 _cv_HAVE_C99_VSNPRINTF=yes,_cv_HAVE_C99_VSNPRINTF=no,_cv_HAVE_C99_VSNPRINTF=cross)])
 150 if test x"$_cv_HAVE_C99_VSNPRINTF" = x"yes"; then
 151     AC_DEFINE(HAVE_C99_VSNPRINTF, 1, [define if you have vsnprintf with C99 semantics (set by configure)])
 152 fi
 153
 154 dnl Check for inotify
 155 dnl =================
 156 AC_CHECK_HEADERS(sys/inotify.h, AC_DEFINE(HAVE_INOTIFY, 1, Check for inotify))
 157
 158 dnl Check CPP
 159 dnl =========
 160 if test "x$CPP_PATH" = x; then
 161     AC_PATH_PROG(CPP_PATH, cpp, notfound,
 162                 $PATH:/lib:/usr/bin:/bin:/usr/lib:/usr/ccs/lib)
 163 fi
 164
 165 dnl
 166 dnl Tell stupid Solaris cpp that the files it will process have C++ like syntax
 167 dnl RedHat 5.x is broken too, so it won't make a symlink from cpp to the
 168 dnl standard locations
 169 dnl
 170 if test "$CPP_PATH" = "/usr/ccs/lib/cpp" -o "$CPP_PATH" = "notfound" ; then
 171     if test "$GCC" = "yes"; then
 172         CPP_PATH="gcc -E -x c"
 173     else
 174         if test "$CPP_PATH" = "/usr/ccs/lib/cpp"; then
 175             CPP_PATH="$CPP_PATH -B"
 176         else
 177             echo "cpp, the C preprocessor was not found in your system."
 178             echo "Create a symbolic link from it to /lib/cpp and rerun configure"
 179             exit
 180         fi
 181     fi
 182 fi
 183 AC_DEFINE_UNQUOTED(CPP_PATH, "$CPP_PATH", [define to the path to cpp])
 184
 185
 186
 187 dnl Checks for header files.
 188 dnl =======================
 189 AC_HEADER_SYS_WAIT
 190 AC_HEADER_TIME
 191 AC_CHECK_HEADERS(fcntl.h limits.h sys/ioctl.h sys/time.h sys/types.h \
 192                  libintl.h sys/select.h poll.h malloc.h ctype.h string.h \
 193                  strings.h)
 194
 195
 196
 197 dnl Checks for typedefs, structures, and compiler characteristics.
 198 dnl ==============================================================
 199 AC_DECL_SYS_SIGLIST
 200 AC_C_CONST
 201 #AC_TYPE_SIZE_T
 202 #AC_TYPE_PID_T
 203 AC_TYPE_SIGNAL
 204
 205
 206
 207 dnl Compiler/architecture specific optimizations
 208 dnl ============================================
 209
 210
 211 dnl GCC/as with MMX support
 212 dnl -----------------------
 213
 214 # until we fix it, leave it disabled
 215 asm_support=no
 216 mmx_support=no
 217
 218 check_for_mmx_support=yes
 219 AC_ARG_ENABLE(mmx,
 220    [  --disable-mmx          disable compilation of MMX inline assembly ],
 221    [if test x$enableval != xyes; then
 222     check_for_mmx_support=no
 223     fi])
 224
 225 if test "$ac_cv_prog_gcc" = yes -a "$check_for_mmx_support" = yes; then
 226 case $host_cpu in
 227 *i?86*)
 228
 229     # gcc-3.3 or newer complains about some of our stuff without this
 230     NOSTRICTALIASING="-fno-strict-aliasing"
 231
 232     AC_CACHE_CHECK(whether gcc supports x86 inline asm,
 233                    ac_cv_c_inline_asm,
 234                    [AC_TRY_LINK(,[{int x; asm volatile("movl %%eax, %%ebx\n\t pushal\n\t popal"::
 235                           "m" (x),"m" (x),"m" (x),"m" (x),"m" (x),"m" (x),
 236                           "m" (x),"m" (x),"m" (x),"m" (x),"m" (x),"m" (x));}],
 237                    ac_cv_c_inline_asm=yes,
 238                    ac_cv_c_inline_asm=no)])
 239
 240     if test "x$ac_cv_c_inline_asm" = xyes; then
 241        AC_DEFINE(ASM_X86, 1, [define if processor is x86 (normally detected by configure)])
 242        asm_support=yes
 243
 244        AC_CACHE_CHECK(whether gcc supports MMX(tm) inline asm,
 245                       ac_cv_c_inline_mmx,
 246                       [AC_TRY_LINK(,[asm ("movq %mm0, %mm1");],
 247                       ac_cv_c_inline_mmx=yes,
 248                       ac_cv_c_inline_mmx=no)])
 249
 250        if test "x$ac_cv_c_inline_mmx" = xyes; then
 251           AC_DEFINE(ASM_X86_MMX, 1, [define if processor is x86 with MMX(tm) support (normally autodetected by configure)])
 252           mmx_support=yes
 253        fi
 254     fi
 255     ;;
 256 esac
 257 fi
 258 AC_SUBST(NOSTRICTALIASING)
 259
 260
 261 dnl pkg-config
 262 dnl ----------
 263 dnl AC_ARG_VAR(PKGCONFIG, [pkg-config command])
 264 AC_CHECK_PROG(PKGCONFIG, pkg-config, pkg-config)
 265
 266
 267 dnl gettext
 268 dnl -------
 269
 270
 271 dnl AM_GNU_GETTEXT
 272
 273
 274
 275 INTLIBS=""
 276
 277 AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 278         AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 279                          INTLIBS="" ))
 280
 281 AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 282
 283 if test "$XGETTEXT" != ""; then
 284     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 285         echo "xgettext isn't GNU version"
 286         XGETTEXT=""
 287     fi
 288 fi
 289
 290 if test "$LINGUAS" != ""; then
 291     if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 292         AC_DEFINE(I18N, 1, [Internationalization (I18N) support (set by configure)])
 293         PO=""
 294         echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 295     else
 296         LINGUAS=""
 297         PO=""
 298         echo "xgettext and libintl.a don't both exist; will not build i18n support"
 299     fi
 300 else
 301         INTLIBS=""
 302         MOFILES=""
 303         WPMOFILES=""
 304         UTILMOFILES=""
 305         PO=""
 306 fi
 307
 308
 309 dnl The Tower of Babel
 310 dnl ==================
 311
 312 dnl List of supported locales
 313 dnl -------------------------
 314 supported_locales="be bg bs ca cs da de el es et fi fr gl hr hu hy it ja ko ms nl no pl pt ro ru sk sv tr zh_CN zh_TW"
 315 supported_wprefs_locales="bg ca cs de es et fi fr hr hu it ja ko pt ru sk zh_CN zh_TW"
 316 supported_wings_locales="bg ca cs de fr sk"
 317 supported_util_locales="de"
 318
 319 for lang in $LINGUAS; do
 320         ok=0
 321         for l in $supported_locales; do
 322                 if test "$l" = "$lang"; then
 323                         ok=1
 324                         break
 325                 fi
 326         done
 327         if test "$ok" = 1; then
 328                 MOFILES="$MOFILES $lang.mo"
 329         else
 330                 echo "Locale $lang is not supported."
 331         fi
 332         ok=0
 333         for l in $supported_wprefs_locales; do
 334                 if test "$l" = "$lang"; then
 335                         ok=1
 336                         break
 337                 fi
 338         done
 339         if test "$ok" = 1; then
 340                 WPMOFILES="$WPMOFILES $lang.mo"
 341         fi
 342         ok=0
 343         for l in $supported_util_locales; do
 344                 if test "$l" = "$lang"; then
 345                         ok=1
 346                         break
 347                 fi
 348         done
 349         if test "$ok" = 1; then
 350                 UTILMOFILES="$UTILMOFILES $lang.mo"
 351         fi
 352         ok=0
 353         for l in $supported_wings_locales; do
 354                 if test "$l" = "$lang"; then
 355                         ok=1
 356                         break
 357                 fi
 358         done
 359         if test "$ok" = 1; then
 360                 WINGSMOFILES="$WINGSMOFILES $lang.mo"
 361         fi
 362 done
 363
 364
 365 dnl Added by Oliver - Support for NLSDIR option,   Hi Oliver!
 366 dnl ===========================================
 367 AC_ARG_WITH(nlsdir,
 368         [  --with-nlsdir=PATH      specify where the locale stuff should go ])
 369
 370
 371 if test "x$NLSDIR" = "x"; then
 372         if test "x$with_nlsdir" != "x"; then
 373                 NLSDIR=$with_nlsdir
 374         else
 375                 NLSDIR='$(prefix)/lib/locale'
 376         fi
 377 fi
 378
 379
 380
 381 AC_SUBST(INTLIBS)
 382 AC_SUBST(NLSDIR)
 383 AC_SUBST(MOFILES)
 384 AC_SUBST(WPMOFILES)
 385 AC_SUBST(UTILMOFILES)
 386 AC_SUBST(WINGSMOFILES)
 387 AC_SUBST(supported_locales)
 388
 389
 390
 391 dnl Support for various hint things
 392 dnl ===============================
 393
 394 dnl
 395 dnl Beautify compilation messages
 396 dnl ---------------------------------------------
 397 AC_ARG_ENABLE(verbose-compile, AS_HELP_STRING([--disable-verbose-compile],
 398                                [Streamline compilation messages (default off)]),
 399   [
 400         QUIET='@echo "     CC" $@;'
 401         QUIET_AR='@echo "     AR" $@;'
 402         LIBTOOL_ARG="--silent"
 403         MAKEFLAGS="-s"
 404         AC_SUBST(QUIET)
 405         AC_SUBST(QUIET_AR)
 406         AC_SUBST(LIBTOOL_ARG)
 407         AC_SUBST(MAKEFLAGS)
 408 ])
 409
 410
 411 dnl ===========================================
 412 dnl             Stuff that uses X
 413 dnl ===========================================
 414
 415 AC_PATH_XTRA
 416
 417 if test $no_x; then
 418     AC_MSG_ERROR([The path for the X11 files not found!
 419 Make sure you have X and it's headers and libraries (the -devel packages
 420 in Linux) installed.])
 421 fi
 422
 423 X_LIBRARY_PATH=$x_libraries
 424
 425 XCFLAGS="$X_CFLAGS"
 426
 427 XLFLAGS="$X_LIBS"
 428
 429 XLIBS="-lX11 -lXmu $X_EXTRA_LIBS"
 430
 431
 432 lib_search_path="$lib_search_path $XLFLAGS"
 433 inc_search_path="$inc_search_path $XCFLAGS"
 434
 435
 436 AC_SUBST(X_LIBRARY_PATH)
 437
 438
 439
 440 dnl Decide which locale function to use, setlocale() or _Xsetlocale()
 441 dnl by MANOME Tomonori
 442 dnl ===========================================
 443 use_locale=yes
 444 AC_ARG_ENABLE(locale,
 445 [  --disable-locale        disable use of X locale support],
 446                 use_locale=no)
 447
 448 if test "$use_locale" = yes; then
 449         AC_CHECK_LIB(X11, _Xsetlocale,
 450                 AC_DEFINE(X_LOCALE, 1, [define if you want support for X window's X_LOCALE (set by configure)]),,
 451                 $XLFLAGS $XLIBS)
 452 fi
 453
 454
 455 dnl Check whether XInternAtoms() exist
 456 dnl ==================================
 457 AC_CHECK_LIB(X11, XInternAtoms,
 458              AC_DEFINE(HAVE_XINTERNATOMS, 1, [define if your X server has XInternAtoms() (set by configure)]),,
 459              $XLFLAGS $XLIBS)
 460
 461 dnl Check whether XConvertCase() exist
 462 dnl ==================================
 463 AC_CHECK_LIB(X11, XConvertCase,
 464              AC_DEFINE(HAVE_XCONVERTCASE, 1, [define if your X server has XConvertCase() (set by configure)]),,
 465              $XLFLAGS $XLIBS)
 466
 467
 468 dnl XKB keyboard language status
 469 dnl ============================
 470 AC_ARG_ENABLE(modelock,
 471 [  --enable-modelock       XKB keyboard language status support],
 472                 AC_DEFINE(XKB_MODELOCK, 1, [whether XKB language MODELOCK should be enabled]))
 473
 474
 475
 476 dnl Shape support
 477 dnl =============
 478 shape=yes
 479 AC_ARG_ENABLE(shape,
 480 [  --disable-shape         disable shaped window extension support],
 481                 shape=$enableval, shape=yes)
 482
 483 added_xext=no
 484
 485 if test "$shape" = yes; then
 486         AC_CHECK_LIB(Xext, XShapeSelectInput, [XLIBS="-lXext $XLIBS"
 487                 added_xext=yes
 488                 AC_DEFINE(SHAPE, 1, [define if you want support for shaped windows (set by configure)])],
 489                 shape=no, $XLFLAGS $XLIBS)
 490 fi
 491
 492
 493 dnl Xft2 antialiased font support
 494 dnl =============================
 495
 496 xft=yes
 497 XFTLIBS=""
 498
 499 if test "x$PKGCONFIG" != x -a "`$PKGCONFIG xft; echo $?`" = 0; then
 500         XFTCONFIG="$PKGCONFIG xft"
 501         pkgconfig_xft=yes
 502 else
 503         AC_CHECK_PROG(XFTCONFIG, xft-config, xft-config)
 504 fi
 505
 506 AC_MSG_CHECKING([for the Xft2 library])
 507
 508 if test "x$XFTCONFIG" != x; then
 509         XFTLIBS=`$XFTCONFIG --libs`
 510         XFTFLAGS=`$XFTCONFIG --cflags`
 511         AC_MSG_RESULT([found])
 512 else
 513         AC_MSG_RESULT([not found])
 514         echo
 515         echo "ERROR!!! libXft2 is not installed or could not be found."
 516         echo "         Xft2 is a requirement for building Window Maker."
 517         echo "         Please install it (along with fontconfig) before continuing."
 518         echo
 519         exit 1
 520 fi
 521
 522 minXFT="2.1.0"
 523 goodxft="no"
 524
 525 dnl
 526 dnl The macro below will use $XFTFLAGS (defined above) to find Xft.h
 527 dnl
 528 WM_CHECK_XFT_VERSION($minXFT, goodxft=yes, goodxft=no)
 529
 530 if test "$goodxft" = no; then
 531         echo
 532         echo "ERROR!!! libXft on this system is an old version."
 533         echo "         Please consider upgrading to at least version ${minXFT}."
 534         echo
 535         exit 1
 536 fi
 537
 538 AC_SUBST(XFTFLAGS)
 539 AC_SUBST(XFTLIBS)
 540
 541
 542 dnl XINERAMA support
 543 dnl ================
 544 xinerama=no
 545 AC_ARG_ENABLE(xinerama,
 546 [  --enable-xinerama       enable Xinerama extension support],
 547                 xinerama=$enableval, xinerama=no)
 548
 549 if test "$xinerama" = yes; then
 550         AC_CHECK_LIB(Xinerama, XineramaQueryScreens,
 551                 [XLIBS="-lXinerama $XLIBS"
 552                 xfxine=yes],
 553                 xfxine=no, $XLFLAGS $XLIBS)
 554
 555         AC_CHECK_LIB(Xext, XineramaGetInfo,
 556                 [sunxine=yes
 557                 ], sunxine=no, $XLFLAGS $XLIBS)
 558
 559         if test "$xfxine" = yes; then
 560                 xine=1
 561         fi
 562
 563         if test "$sunxine" = yes; then
 564             xine=1
 565             AC_DEFINE(SOLARIS_XINERAMA, 1,
 566                 [define if you want support for the XINERAMA extension and are in Solaris (set by configure)])
 567         fi
 568
 569         if test "$xine" = 1; then
 570             AC_DEFINE(XINERAMA, 1,
 571                 [define if you want support for the XINERAMA extension (set by configure)])
 572         fi
 573 fi
 574
 575
 576
 577 dnl MIT-SHM support
 578 dnl ===============
 579 shm=yes
 580 AC_ARG_ENABLE(shm,
 581 [  --disable-shm           disable usage of MIT-SHM extension],
 582                 shm=$enableval, shm=yes)
 583
 584 if test "$shm" = yes; then
 585         AC_CHECK_LIB(Xext, XShmAttach, ok=yes, ok=no, $XLFLAGS $XLIBS)
 586
 587         if test "$ok" = yes; then
 588         AC_CHECK_FUNC(shmget, ok=yes, ok=no)
 589         fi
 590
 591         if test "$ok" = yes; then
 592                 if test "$added_xext" = no; then
 593                         XLIBS="-lXext $XLIBS"
 594                 fi
 595                 AC_DEFINE(XSHM, 1, [define if X's shared memory extension is available (set by configure)])
 596         fi
 597 fi
 598
 599
 600 dnl R6 Style Session Management Support
 601 dnl ===================================
 602
 603 #
 604 #
 605 #AC_DEFINE(R6SM)
 606 #AC_SUBST(XSMPLIBS)
 607 #
 608
 609
 610 dnl ==============================================
 611 dnl         Graphic Format Libraries
 612 dnl ==============================================
 613
 614
 615
 616
 617
 618 dnl XPM Support
 619 dnl ===========
 620 xpm=yes
 621 AC_ARG_ENABLE(xpm,
 622 [  --disable-xpm           disable use of XPM pixmaps through libXpm],
 623         xpm=$enableval, xpm=yes)
 624
 625 if test "$xpm" = yes; then
 626     WM_CHECK_LIB(Xpm, XpmCreatePixmapFromData, [$XLFLAGS $XLIBS])
 627
 628     if test "x$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = xyes; then
 629         WM_CHECK_HEADER(X11/xpm.h)
 630         if test "x$ac_cv_header_X11_xpm_h" = xyes; then
 631                 GFXLIBS="$GFXLIBS -lXpm"
 632                 supported_gfx="XPM"
 633                 AC_DEFINE(USE_XPM, 1, [define if XPM libraries are available (set by configure)])
 634         else
 635                 supported_gfx="builtin-XPM"
 636         fi
 637     fi
 638 fi
 639
 640 AC_SUBST(XLFLAGS)
 641 AC_SUBST(XLIBS)
 642 AC_SUBST(X_EXTRA_LIBS)
 643
 644 dnl ===============================================
 645 dnl             End of stuff that uses X
 646 dnl ===============================================
 647
 648
 649
 650 dnl PNG Support
 651 dnl ===========
 652 png=yes
 653 AC_ARG_ENABLE(png,
 654 [  --disable-png           disable PNG support through libpng],
 655         png=$enableval, png=yes, png=no)
 656
 657
 658 if test "$png" = yes ; then
 659     WM_CHECK_LIB(png, png_get_valid, [-lz -lm])
 660
 661     if test "x$ac_cv_lib_png_png_get_valid" = xyes; then
 662         WM_CHECK_HEADER(png.h)
 663         if test "x$ac_cv_header_png_h" = xyes; then
 664             GFXLIBS="$GFXLIBS -lpng -lz"
 665             supported_gfx="$supported_gfx PNG"
 666             AC_DEFINE(USE_PNG, 1, [define if PNG libraries are available (set by configure)])
 667         fi
 668     fi
 669 fi
 670
 671
 672 dnl JPEG Support
 673 dnl ============
 674 jpeg=yes
 675 ljpeg=""
 676 AC_ARG_ENABLE(jpeg,
 677 [  --disable-jpeg          disable JPEG support through libjpeg],
 678         jpeg=$enableval, jpeg=yes, jpeg=no)
 679
 680 if test "$jpeg" = yes; then
 681     WM_CHECK_LIB(jpeg, jpeg_destroy_compress)
 682
 683     if test "x$ac_cv_lib_jpeg_jpeg_destroy_compress" = xyes; then
 684
 685         ljpeg="-ljpeg"
 686
 687         WM_CHECK_HEADER(jpeglib.h)
 688         if test "x$ac_cv_header_jpeglib_h" = xyes; then
 689             GFXLIBS="$GFXLIBS -ljpeg"
 690             supported_gfx="$supported_gfx JPEG"
 691             AC_DEFINE(USE_JPEG, 1, [define if JPEG libraries are available (set by configure)])
 692         fi
 693     fi
 694 fi
 695
 696
 697 dnl GIF Support
 698 dnl ============
 699 gif=yes
 700 AC_ARG_ENABLE(gif,
 701 [  --disable-gif           disable GIF support through libgif or libungif],
 702         gif=$enableval, gif=yes, gif=no)
 703
 704 if test "$gif" = yes; then
 705     my_libname=""
 706     WM_CHECK_LIB(ungif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 707     if test "x$ac_cv_lib_ungif_DGifOpenFileName" = xyes; then
 708         my_libname=-lungif
 709     fi
 710 dnl
 711 dnl libungif is the same thing as libgif for all practical purposes.
 712 dnl
 713     if test "x$my_libname" = x; then
 714         WM_CHECK_LIB(gif, DGifOpenFileName, [$XLFLAGS $XLIBS])
 715         if test "x$ac_cv_lib_gif_DGifOpenFileName" = xyes; then
 716             my_libname=-lgif
 717         fi
 718     fi
 719
 720     if test "$my_libname" != x; then
 721         WM_CHECK_HEADER(gif_lib.h)
 722         if test "x$ac_cv_header_gif_lib_h" = xyes; then
 723             GFXLIBS="$GFXLIBS $my_libname"
 724             supported_gfx="$supported_gfx GIF"
 725             AC_DEFINE(USE_GIF, 1, [define if GIF libraries are available (set by configure)])
 726         fi
 727     fi
 728 fi
 729
 730
 731
 732 dnl TIFF Support
 733 dnl ============
 734 AC_ARG_ENABLE(tiff,
 735 [  --disable-tiff          disable use of TIFF images through libtiff],
 736         tif=$enableval, tif=yes, tif=no)
 737
 738 #
 739 # TIFF can optionally have JPEG and/or zlib support. Must find out
 740 # when they are supported so that correct library flags are passed during
 741 # detection and linkage
 742 #
 743 #
 744 # By default use xpm icons if tiff is not found.
 745 ICONEXT="xpm"
 746 #
 747
 748 if test "$tif" = yes; then
 749     my_libname=""
 750     WM_CHECK_LIB(tiff, TIFFGetVersion, [-lm])
 751     if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 752         my_libname="-ltiff"
 753     fi
 754 dnl
 755 dnl Retry with zlib
 756 dnl
 757     unset ac_cv_lib_tiff_TIFFGetVersion
 758     if test "x$my_libname" = x; then
 759         WM_CHECK_LIB(tiff, TIFFGetVersion, [$ljpeg -lz -lm])
 760         if test "x$ac_cv_lib_tiff_TIFFGetVersion" = xyes; then
 761             my_libname="-ltiff -lz"
 762         fi
 763     fi
 764
 765     if test "x$my_libname" = x; then
 766         WM_CHECK_LIB(tiff34, TIFFGetVersion, [$ljpeg -lm])
 767         if test "x$ac_cv_lib_tiff34_TIFFGetVersion" = xyes; then
 768             my_libname="-ltiff34"
 769         fi
 770     fi
 771
 772
 773     if test "x$my_libname" != x; then
 774         WM_CHECK_HEADER(tiffio.h)
 775         if test "x$ac_cv_header_tiffio_h" = xyes; then
 776             GFXLIBS="$my_libname $GFXLIBS"
 777             ICONEXT="tiff"
 778             supported_gfx="$supported_gfx TIFF"
 779             AC_DEFINE(USE_TIFF, 1, [define if TIFF libraries are available (set by configure)])
 780         fi
 781     fi
 782 fi
 783
 784 LIBRARY_SEARCH_PATH="$lib_search_path"
 785 HEADER_SEARCH_PATH="$inc_search_path"
 786
 787 AC_SUBST(LIBRARY_SEARCH_PATH)
 788 AC_SUBST(HEADER_SEARCH_PATH)
 789
 790
 791 AC_SUBST(GFXLIBS)
 792 AC_SUBST(ICONEXT)
 793
 794
 795 dnl ==============================================
 796 dnl         End of Graphic Format Libraries
 797 dnl ==============================================
 798
 799
 800 dnl
 801 dnl stdlib.h is checked here, because of conflict in jpeglib.h
 802 AC_CHECK_HEADERS(stdlib.h)
 803
 804 # AC_PREFIX_PROGRAM(wmaker)
 805
 806 dnl Support for PIXMAPDIR option
 807 dnl ============================
 808 AC_ARG_WITH(pixmapdir,
 809 [  --with-pixmapdir=PATH   specify where pixmaps are located [DATADIR/pixmaps]])
 810
 811 if test "x$with_pixmapdir" != "x"; then
 812         pixmapdir=$with_pixmapdir
 813 else
 814         pixmapdir=`eval echo ${datadir}/pixmaps`
 815 fi
 816
 817 AC_DEFINE_UNQUOTED(PIXMAPDIR, "$pixmapdir", [define an extra path for pixmaps (set by configure)])
 818
 819 pkgdatadir=`eval echo $datadir`
 820 AC_DEFINE_UNQUOTED(PKGDATADIR, "$pkgdatadir/WindowMaker", [where shared data is stored (defined by configure)])
 821
 822 _sysconfdir=`eval echo $sysconfdir`
 823 AC_DEFINE_UNQUOTED(SYSCONFDIR, "$_sysconfdir", [where the configuration is stored (defined by configure)])
 824
 825
 826 dnl Support for GNUSTEP_LOCAL_ROOT, for WPrefs.app
 827 dnl ==============================================
 828
 829 AC_ARG_WITH(appspath,
 830 [  --with-gnustepdir=PATH  specify the directory for GNUstep applications])
 831
 832 if test "x`echo $with_gnustepdir | grep ^/`" != "x"; then
 833     appspath=$with_gnustepdir
 834 fi
 835
 836 if test "x$appspath$GNUSTEP_LOCAL_ROOT" = "x"; then
 837     wprefs_base_dir=${prefix}
 838     wprefs_datadir="${datadir}/WPrefs"
 839     wprefs_bindir="${bindir}"
 840 else
 841     gnustepdir=$appspath
 842
 843     if test "x$GNUSTEP_LOCAL_ROOT" != "x" ; then
 844         gnustepdir=`echo "$GNUSTEP_LOCAL_ROOT" | sed -e "s|^${prefix}|prefix|"`
 845         gnustepdir=`echo $gnustepdir | sed -e 's|^prefix|${prefix}|'`
 846     fi
 847
 848     wprefs_base_dir=$gnustepdir/Applications
 849     wprefs_datadir=$wprefs_base_dir/WPrefs.app
 850     wprefs_bindir=$wprefs_base_dir/WPrefs.app
 851 fi
 852
 853 AC_SUBST(wprefs_datadir)
 854 AC_SUBST(wprefs_bindir)
 855
 856
 857 dnl Enable User Defined Menu thing
 858 dnl ==================================
 859 AC_ARG_ENABLE(usermenu,
 860 [  --enable-usermenu       user defined menus for applications
 861 ],
 862 if test "$enableval" = yes; then
 863         AC_DEFINE(USER_MENU, 1, [define if you want user defined menus for applications])
 864 fi
 865 )
 866
 867
 868 AC_OUTPUT(Makefile po/Makefile util/Makefile util/po/Makefile \
 869         WINGs/Makefile WINGs/WINGs/Makefile WINGs/Documentation/Makefile \
 870         WINGs/Examples/Makefile WINGs/Resources/Makefile WINGs/Tests/Makefile \
 871         WINGs/Extras/Makefile WINGs/po/Makefile \
 872         wrlib/Makefile wrlib/tests/Makefile \
 873         src/Makefile src/wconfig.h \
 874         doc/Makefile doc/sk/Makefile \
 875         WindowMaker/Makefile WindowMaker/Backgrounds/Makefile \
 876         WindowMaker/Defaults/Makefile WindowMaker/IconSets/Makefile \
 877         WindowMaker/Icons/Makefile WindowMaker/Pixmaps/Makefile \
 878         WindowMaker/Styles/Makefile WindowMaker/Themes/Makefile \
 879         WPrefs.app/Makefile WPrefs.app/tiff/Makefile WPrefs.app/xpm/Makefile \
 880         WPrefs.app/po/Makefile \
 881         contrib/Makefile contrib/WindowMaker.spec )
 882
 883
 884
 885 dnl
 886 dnl Output some helpful data for compiling wraster and WINGs/WUtil apps
 887 dnl ===================================================================
 888 dnl
 889
 890 dnl echo "WFLAGS=\"$LIBPL_INC_PATH -I$prefix/include\"" > WINGs-flags
 891 dnl echo "WLIBS=\"-L$exec_prefix/lib -lWINGs -lwraster $LIBPL_LIBS $GFXLIBS -lm\""\
 892 dnl     | sed -e 's|\$(prefix)|'"$prefix|" >> WINGs-flags
 893
 894 dnl The #lp# and #rp# stuff below is a hack because [ and ] get lost when
 895 dnl parsed by m4
 896
 897 cat <<EOF >get-wraster-flags
 898 #!/bin/sh
 899
 900 WCFLAGS="$inc_search_path"
 901 WLFLAGS="$lib_search_path"
 902 WLIBS="-lwraster $GFXLIBS $XLIBS -lm"
 903
 904 usage="Usage: get-wraster-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 905
 906 if test \$# -eq 0; then
 907       echo "\${usage}" 1>&2
 908       exit 1
 909 fi
 910
 911 while test \$# -gt 0; do
 912   case \$1 in
 913     --cflags)
 914         echo \$WCFLAGS
 915         ;;
 916     --ldflags|--lflags)
 917         echo \$WLFLAGS
 918         ;;
 919     --libs)
 920         echo \$WLIBS
 921         ;;
 922     *)
 923         echo "\${usage}" 1>&2
 924         exit 1
 925         ;;
 926   esac
 927   shift
 928 done
 929
 930
 931 EOF
 932
 933 cat <<EOF > wrlib/wrlib.pc
 934 Name: wrlib
 935 Description: Image manipulation and conversion library
 936 Version: $VERSION
 937 Libs: $lib_search_path -lwraster $GFXLIBS $XLIBS -lm
 938 Cflags: $inc_search_path
 939 EOF
 940
 941 cat <<EOF >get-wings-flags
 942 #!/bin/sh
 943
 944 WCFLAGS="$inc_search_path"
 945 WLFLAGS="$lib_search_path"
 946 WLIBS="-lWINGs -lWUtil -lwraster $GFXLIBS $XFTLIBS $XLIBS -lm $INTLIBS"
 947
 948 usage="Usage: get-wings-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 949
 950 if test \$# -eq 0; then
 951       echo "\${usage}" 1>&2
 952       exit 1
 953 fi
 954
 955 while test \$# -gt 0; do
 956   case \$1 in
 957     --cflags)
 958         echo \$WCFLAGS
 959         ;;
 960     --ldflags|--lflags)
 961         echo \$WLFLAGS
 962         ;;
 963     --libs)
 964         echo \$WLIBS
 965         ;;
 966     *)
 967         echo "\${usage}" 1>&2
 968         exit 1
 969         ;;
 970   esac
 971   shift
 972 done
 973
 974
 975 EOF
 976
 977 cat <<EOF > WINGs/WINGs.pc
 978 Name: WINGs
 979 Description: Small widget set with the NeXTStep(TM) look and feel
 980 Version: $VERSION
 981 Requires: wrlib
 982 Libs: $lib_search_path -lWINGs $XFTLIBS $XLIBS -lm $INTLIBS
 983 Cflags: $inc_search_path
 984 EOF
 985
 986 cat <<EOF >get-wutil-flags
 987 #!/bin/sh
 988
 989 WCFLAGS="-I`eval echo ${includedir}`"
 990 WLFLAGS="-L${_libdir}"
 991 WLIBS="-lWUtil $INTLIBS"
 992
 993 usage="Usage: get-wutil-flags #lp#--cflags#rp# #lp#--ldflags#rp# #lp#--libs#rp#"
 994
 995 if test \$# -eq 0; then
 996       echo "\${usage}" 1>&2
 997       exit 1
 998 fi
 999
1000 while test \$# -gt 0; do
1001   case \$1 in
1002     --cflags)
1003         echo \$WCFLAGS
1004         ;;
1005     --ldflags|--lflags)
1006         echo \$WLFLAGS
1007         ;;
1008     --libs)
1009         echo \$WLIBS
1010         ;;
1011     *)
1012         echo "\${usage}" 1>&2
1013         exit 1
1014         ;;
1015   esac
1016   shift
1017 done
1018
1019
1020 EOF
1021
1022 sed 's/#lp#/[/g' get-wraster-flags | sed 's/#rp#/]/g' > wrlib/get-wraster-flags
1023 sed 's/#lp#/[/g' get-wings-flags | sed 's/#rp#/]/g' > WINGs/get-wings-flags
1024 sed 's/#lp#/[/g' get-wutil-flags | sed 's/#rp#/]/g' > WINGs/get-wutil-flags
1025
1026 chmod 755 wrlib/get-wraster-flags WINGs/get-wings-flags WINGs/get-wutil-flags
1027
1028 rm -f get-wraster-flags get-wings-flags get-wutil-flags
1029
1030
1031 dnl
1032 dnl Spit out the configuration
1033 dnl ==========================
1034
1035 supported_gfx="$supported_gfx builtin-PPM"
1036
1037 if test "x$MOFILES" = "x"; then
1038         mof=None
1039 else
1040         mof=`echo $MOFILES`
1041 fi
1042
1043 if test "x$MOFILES" = "x"; then
1044         languages=None
1045 else
1046         languages=`echo $MOFILES | sed 's/.mo//g'`
1047 fi
1048
1049 echo
1050 echo "Window Maker was configured as follows:"
1051 echo
1052 echo "Installation path prefix            : $prefix"
1053 echo "Installation path for binaries      : $_bindir"
1054 echo "Installation path for WPrefs.app    : $wprefs_base_dir" | sed -e 's|\${prefix}|'"$prefix|"
1055 echo "Supported graphic format libraries  : $supported_gfx"
1056 echo "Use assembly routines for wrlib     : $asm_support"
1057 echo "Use inline MMX(tm) x86 assembly     : $mmx_support"
1058 echo "Antialiased text support in WINGs   : $xft"
1059 echo "Xinerama extension support          : $xinerama"
1060 echo "Translated message files to install : $mof"
1061 dnl echo "Supported languages beside English  : $languages"
1062 if test "x$MOFILES" != "x"; then
1063         echo "Installation path for translations  : $NLSDIR" | sed -e 's|\$(prefix)|'"$prefix|"
1064 fi
1065 echo
1066
1067 dnl WM_PRINT_REDCRAP_BUG_STATUS
1068
1069 if test "x$ac_cv_header_jpeglib_h" != xyes; then
1070 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1071 echo
1072 echo "JPEG support will not be included because the JPEG library is"
1073 echo "not installed correctly or was not found. Background images"
1074 echo "from themes will not display as they usually are JPEG files."
1075 echo
1076 echo "To fix, download and install the jpeg library and/or make sure you"
1077 echo "installed all jpeg related packages, SPECIALLY the development packages"
1078 echo "like jpeg-devel (if you use some prepackaged version of libjpeg)."
1079 echo
1080 echo "WARNING   WARNING   WARNING   WARNING   WARNING   WARNING   WARNING"
1081 fi
1082
1083
1084 dnl This is for Emacs.  I'm lazy, I know... (nicolai)
1085 dnl ================================================
1086 dnl Local Variables:
1087 dnl compile-command: "autoconf"
1088 dnl End:
1089