plugin/vcssvn.vim

   1 " vim600: set foldmethod=marker:
   2 "
   3 " SVN extension for VCSCommand.
   4 "
   5 " Maintainer:    Bob Hiestand <bob.hiestand@gmail.com>
   6 " License:
   7 " Copyright (c) Bob Hiestand
   8 "
   9 " Permission is hereby granted, free of charge, to any person obtaining a copy
  10 " of this software and associated documentation files (the "Software"), to
  11 " deal in the Software without restriction, including without limitation the
  12 " rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  13 " sell copies of the Software, and to permit persons to whom the Software is
  14 " furnished to do so, subject to the following conditions:
  15 "
  16 " The above copyright notice and this permission notice shall be included in
  17 " all copies or substantial portions of the Software.
  18 "
  19 " THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  20 " IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  21 " FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  22 " AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  23 " LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  24 " FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  25 " IN THE SOFTWARE.
  26 "
  27 " Section: Documentation {{{1
  28 "
  29 " Options documentation: {{{2
  30 "
  31 " VCSCommandSVNExec
  32 "   This variable specifies the SVN executable.  If not set, it defaults to
  33 "   'svn' executed from the user's executable path.
  34 "
  35 " VCSCommandSVNDiffExt
  36 "   This variable, if set, sets the external diff program used by Subversion.
  37 "
  38 " VCSCommandSVNDiffOpt
  39 "   This variable, if set, determines the options passed to the svn diff
  40 "   command (such as 'u', 'w', or 'b').
  41
  42 " Section: Plugin header {{{1
  43
  44 if exists('VCSCommandDisableAll')
  45         finish
  46 endif
  47
  48 if v:version < 700
  49         echohl WarningMsg|echomsg 'VCSCommand requires at least VIM 7.0'|echohl None
  50         finish
  51 endif
  52
  53 runtime plugin/vcscommand.vim
  54
  55 if !executable(VCSCommandGetOption('VCSCommandSVNExec', 'svn'))
  56         " SVN is not installed
  57         finish
  58 endif
  59
  60 let s:save_cpo=&cpo
  61 set cpo&vim
  62
  63 " Section: Variable initialization {{{1
  64
  65 let s:svnFunctions = {}
  66
  67 " Section: Utility functions {{{1
  68
  69 " Function: s:Executable() {{{2
  70 " Returns the executable used to invoke git suitable for use in a shell
  71 " command.
  72 function! s:Executable()
  73         return VCSCommandGetOption('VCSCommandSVNExec', 'svn')
  74 endfunction
  75
  76 " Function: s:DoCommand(cmd, cmdName, statusText, options) {{{2
  77 " Wrapper to VCSCommandDoCommand to add the name of the SVN executable to the
  78 " command argument.
  79 function! s:DoCommand(cmd, cmdName, statusText, options)
  80         if VCSCommandGetVCSType(expand('%')) == 'SVN'
  81                 let fullCmd = s:Executable() . ' ' . a:cmd
  82                 return VCSCommandDoCommand(fullCmd, a:cmdName, a:statusText, a:options)
  83         else
  84                 throw 'SVN VCSCommand plugin called on non-SVN item.'
  85         endif
  86 endfunction
  87
  88 " Section: VCS function implementations {{{1
  89
  90 " Function: s:svnFunctions.Identify(buffer) {{{2
  91 function! s:svnFunctions.Identify(buffer)
  92         let oldCwd = VCSCommandChangeToCurrentFileDir(resolve(bufname(a:buffer)))
  93         try
  94                 call s:VCSCommandUtility.system(s:Executable() . ' info .')
  95                 if(v:shell_error)
  96                         return 0
  97                 else
  98                         return g:VCSCOMMAND_IDENTIFY_EXACT
  99                 endif
 100         finally
 101                 call VCSCommandChdir(oldCwd)
 102         endtry
 103 endfunction
 104
 105 " Function: s:svnFunctions.Add() {{{2
 106 function! s:svnFunctions.Add(argList)
 107         return s:DoCommand(join(['add'] + a:argList, ' '), 'add', join(a:argList, ' '), {})
 108 endfunction
 109
 110 " Function: s:svnFunctions.Annotate(argList) {{{2
 111 function! s:svnFunctions.Annotate(argList)
 112         if len(a:argList) == 0
 113                 if &filetype ==? 'svnannotate'
 114                         " Perform annotation of the version indicated by the current line.
 115                         let caption = matchstr(getline('.'),'\v^\s+\zs\d+')
 116                         let options = ' -r' . caption
 117                 else
 118                         let caption = ''
 119                         let options = ''
 120                 endif
 121         elseif len(a:argList) == 1 && a:argList[0] !~ '^-'
 122                 let caption = a:argList[0]
 123                 let options = ' -r' . caption
 124         else
 125                 let caption = join(a:argList, ' ')
 126                 let options = ' ' . caption
 127         endif
 128
 129         return s:DoCommand('blame --non-interactive' . options, 'annotate', caption, {})
 130 endfunction
 131
 132 " Function: s:svnFunctions.Commit(argList) {{{2
 133 function! s:svnFunctions.Commit(argList)
 134         let resultBuffer = s:DoCommand('commit --non-interactive -F "' . a:argList[0] . '"', 'commit', '', {})
 135         if resultBuffer == 0
 136                 echomsg 'No commit needed.'
 137         endif
 138 endfunction
 139
 140 " Function: s:svnFunctions.Delete() {{{2
 141 function! s:svnFunctions.Delete(argList)
 142         return s:DoCommand(join(['delete --non-interactive'] + a:argList, ' '), 'delete', join(a:argList, ' '), {})
 143 endfunction
 144
 145 " Function: s:svnFunctions.Diff(argList) {{{2
 146 function! s:svnFunctions.Diff(argList)
 147         if len(a:argList) == 0
 148                 let revOptions = []
 149                 let caption = ''
 150         elseif len(a:argList) <= 2 && match(a:argList, '^-') == -1
 151                 let revOptions = ['-r' . join(a:argList, ':')]
 152                 let caption = '(' . a:argList[0] . ' : ' . get(a:argList, 1, 'current') . ')'
 153         else
 154                 " Pass-through
 155                 let caption = join(a:argList, ' ')
 156                 let revOptions = a:argList
 157         endif
 158
 159         let svnDiffExt = VCSCommandGetOption('VCSCommandSVNDiffExt', '')
 160         if svnDiffExt == ''
 161                 let diffExt = []
 162         else
 163                 let diffExt = ['--diff-cmd ' . svnDiffExt]
 164         endif
 165
 166         let svnDiffOpt = VCSCommandGetOption('VCSCommandSVNDiffOpt', '')
 167         if svnDiffOpt == ''
 168                 let diffOptions = []
 169         else
 170                 let diffOptions = ['-x -' . svnDiffOpt]
 171         endif
 172
 173         return s:DoCommand(join(['diff --non-interactive'] + diffExt + diffOptions + revOptions), 'diff', caption, {})
 174 endfunction
 175
 176 " Function: s:svnFunctions.GetBufferInfo() {{{2
 177 " Provides version control details for the current file.  Current version
 178 " number and current repository version number are required to be returned by
 179 " the vcscommand plugin.
 180 " Returns: List of results:  [revision, repository, branch]
 181
 182 function! s:svnFunctions.GetBufferInfo()
 183         let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 184         let fileName = bufname(originalBuffer)
 185         let statusText = s:VCSCommandUtility.system(s:Executable() . ' status --non-interactive -v -- "' . fileName . '"')
 186         if(v:shell_error)
 187                 return []
 188         endif
 189
 190         " File not under SVN control.
 191         if statusText =~ '^?'
 192                 return ['Unknown']
 193         endif
 194
 195         let [flags, revision, repository] = matchlist(statusText, '^\(.\{9}\)\s*\(\d\+\)\s\+\(\d\+\)')[1:3]
 196         if revision == ''
 197                 " Error
 198                 return ['Unknown']
 199         elseif flags =~ '^A'
 200                 return ['New', 'New']
 201         elseif flags =~ '*'
 202                 return [revision, repository, '*']
 203         else
 204                 return [revision, repository]
 205         endif
 206 endfunction
 207
 208 " Function: s:svnFunctions.Info(argList) {{{2
 209 function! s:svnFunctions.Info(argList)
 210         return s:DoCommand(join(['info --non-interactive'] + a:argList, ' '), 'info', join(a:argList, ' '), {})
 211 endfunction
 212
 213 " Function: s:svnFunctions.Lock(argList) {{{2
 214 function! s:svnFunctions.Lock(argList)
 215         return s:DoCommand(join(['lock --non-interactive'] + a:argList, ' '), 'lock', join(a:argList, ' '), {})
 216 endfunction
 217
 218 " Function: s:svnFunctions.Log(argList) {{{2
 219 function! s:svnFunctions.Log(argList)
 220         if len(a:argList) == 0
 221                 let options = []
 222                 let caption = ''
 223         elseif len(a:argList) <= 2 && match(a:argList, '^-') == -1
 224                 let options = ['-r' . join(a:argList, ':')]
 225                 let caption = options[0]
 226         else
 227                 " Pass-through
 228                 let options = a:argList
 229                 let caption = join(a:argList, ' ')
 230         endif
 231
 232         let resultBuffer = s:DoCommand(join(['log --non-interactive', '-v'] + options), 'log', caption, {})
 233         return resultBuffer
 234 endfunction
 235
 236 " Function: s:svnFunctions.Revert(argList) {{{2
 237 function! s:svnFunctions.Revert(argList)
 238         return s:DoCommand('revert', 'revert', '', {})
 239 endfunction
 240
 241 " Function: s:svnFunctions.Review(argList) {{{2
 242 function! s:svnFunctions.Review(argList)
 243         if len(a:argList) == 0
 244                 let versiontag = '(current)'
 245                 let versionOption = ''
 246         else
 247                 let versiontag = a:argList[0]
 248                 let versionOption = ' -r ' . versiontag . ' '
 249         endif
 250
 251         return s:DoCommand('cat --non-interactive' . versionOption, 'review', versiontag, {})
 252 endfunction
 253
 254 " Function: s:svnFunctions.Status(argList) {{{2
 255 function! s:svnFunctions.Status(argList)
 256         let options = ['-u', '-v']
 257         if len(a:argList) != 0
 258                 let options = a:argList
 259         endif
 260         return s:DoCommand(join(['status --non-interactive'] + options, ' '), 'status', join(options, ' '), {})
 261 endfunction
 262
 263 " Function: s:svnFunctions.Unlock(argList) {{{2
 264 function! s:svnFunctions.Unlock(argList)
 265         return s:DoCommand(join(['unlock --non-interactive'] + a:argList, ' '), 'unlock', join(a:argList, ' '), {})
 266 endfunction
 267
 268 " Function: s:svnFunctions.Update(argList) {{{2
 269 function! s:svnFunctions.Update(argList)
 270         return s:DoCommand('update --non-interactive', 'update', '', {})
 271 endfunction
 272
 273 " Annotate setting {{{2
 274 let s:svnFunctions.AnnotateSplitRegex = '\s\+\S\+\s\+\S\+ '
 275
 276 " Section: Plugin Registration {{{1
 277 let s:VCSCommandUtility = VCSCommandRegisterModule('SVN', expand('<sfile>'), s:svnFunctions, [])
 278
 279 let &cpo = s:save_cpo