| blob | 863fe66e269b49a81a9e4dbefddf614ef56a93b1 |
1 " vim600: set foldmethod=marker:
2 "
3 " Vim plugin to assist in working with files under control of various Version
4 " Control Systems, such as CVS, SVN, SVK, and git.
5 "
6 " Maintainer: Bob Hiestand <bob.hiestand@gmail.com>
7 " License:
8 " Copyright (c) Bob Hiestand
9 "
10 " Permission is hereby granted, free of charge, to any person obtaining a copy
11 " of this software and associated documentation files (the "Software"), to
12 " deal in the Software without restriction, including without limitation the
13 " rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
14 " sell copies of the Software, and to permit persons to whom the Software is
15 " furnished to do so, subject to the following conditions:
16 "
17 " The above copyright notice and this permission notice shall be included in
18 " all copies or substantial portions of the Software.
19 "
20 " THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
21 " IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
22 " FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
23 " AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
24 " LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
25 " FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
26 " IN THE SOFTWARE.
27 "
28 " Section: Documentation {{{1
29 "
30 " Provides functions to invoke various source control commands on the current
31 " file (either the current buffer, or, in the case of an directory buffer, the
32 " directory and all subdirectories associated with the current buffer). The
33 " output of the commands is captured in a new scratch window.
34 "
35 " This plugin needs additional extension plugins, each specific to a source
36 " control system, to function. Several options include the name of the
37 " version control system in the option name. Such options use the placeholder
38 " text '{VCSType}', which would be replaced in actual usage with 'CVS' or
39 " 'SVN', for instance.
40 "
41 " Command documentation {{{2
42 "
43 " VCSAdd Adds the current file to source control.
44 "
45 " VCSAnnotate[!] Displays the current file with each line annotated with the
46 " version in which it was most recently changed. If an
47 " argument is given, the argument is used as a revision
48 " number to display. If not given an argument, it uses the
49 " most recent version of the file on the current branch.
50 " Additionally, if the current buffer is a VCSAnnotate buffer
51 " already, the version number on the current line is used.
52 "
53 " If '!' is used, the view of the annotated buffer is split
54 " so that the annotation is in a separate window from the
55 " content, and each is highlighted separately.
56 "
57 " VCSBlame Alias for 'VCSAnnotate'.
58 "
59 " VCSCommit[!] Commits changes to the current file to source control.
60 "
61 " If called with arguments, the arguments are the log message.
62 "
63 " If '!' is used, an empty log message is committed.
64 "
65 " If called with no arguments, this is a two-step command.
66 " The first step opens a buffer to accept a log message.
67 " When that buffer is written, it is automatically closed and
68 " the file is committed using the information from that log
69 " message. The commit can be abandoned if the log message
70 " buffer is deleted or wiped before being written.
71 "
72 " VCSDelete Deletes the current file and removes it from source control.
73 "
74 " VCSDiff With no arguments, this displays the differences between
75 " the current file and its parent version under source
76 " control in a new scratch buffer.
77 "
78 " With one argument, the diff is performed on the
79 " current file against the specified revision.
80 "
81 " With two arguments, the diff is performed between the
82 " specified revisions of the current file.
83 "
84 " This command uses the 'VCSCommand{VCSType}DiffOpt' variable
85 " to specify diff options. If that variable does not exist,
86 " a plugin-specific default is used. If you wish to have no
87 " options, then set it to the empty string.
88 "
89 " VCSGotoOriginal Jumps to the source buffer if the current buffer is a VCS
90 " scratch buffer. If VCSGotoOriginal[!] is used, remove all
91 " VCS scratch buffers associated with the original file.
92 "
93 " VCSInfo Displays extended information about the current file in a
94 " new scratch buffer.
95 "
96 " VCSLock Locks the current file in order to prevent other users from
97 " concurrently modifying it. The exact semantics of this
98 " command depend on the underlying VCS.
99 "
100 " VCSLog Displays the version history of the current file in a new
101 " scratch buffer.
102 "
103 " VCSRemove Alias for 'VCSDelete'.
104 "
105 " VCSRevert Replaces the modified version of the current file with the
106 " most recent version from the repository.
107 "
108 " VCSReview Displays a particular version of the current file in a new
109 " scratch buffer. If no argument is given, the most recent
110 " version of the file on the current branch is retrieved.
111 "
112 " VCSStatus Displays versioning information about the current file in a
113 " new scratch buffer.
114 "
115 " VCSUnlock Unlocks the current file in order to allow other users from
116 " concurrently modifying it. The exact semantics of this
117 " command depend on the underlying VCS.
118 "
119 " VCSUpdate Updates the current file with any relevant changes from the
120 " repository.
121 "
122 " VCSVimDiff Uses vimdiff to display differences between versions of the
123 " current file.
124 "
125 " If no revision is specified, the most recent version of the
126 " file on the current branch is used. With one argument,
127 " that argument is used as the revision as above. With two
128 " arguments, the differences between the two revisions is
129 " displayed using vimdiff.
130 "
131 " With either zero or one argument, the original buffer is
132 " used to perform the vimdiff. When the scratch buffer is
133 " closed, the original buffer will be returned to normal
134 " mode.
135 "
136 " Once vimdiff mode is started using the above methods,
137 " additional vimdiff buffers may be added by passing a single
138 " version argument to the command. There may be up to 4
139 " vimdiff buffers total.
140 "
141 " Using the 2-argument form of the command resets the vimdiff
142 " to only those 2 versions. Additionally, invoking the
143 " command on a different file will close the previous vimdiff
144 " buffers.
145 "
146 " Mapping documentation: {{{2
147 "
148 " By default, a mapping is defined for each command. User-provided mappings
149 " can be used instead by mapping to <Plug>CommandName, for instance:
150 "
151 " nmap ,ca <Plug>VCSAdd
152 "
153 " The default mappings are as follow:
154 "
155 " <Leader>ca VCSAdd
156 " <Leader>cn VCSAnnotate
157 " <Leader>cN VCSAnnotate!
158 " <Leader>cc VCSCommit
159 " <Leader>cD VCSDelete
160 " <Leader>cd VCSDiff
161 " <Leader>cg VCSGotoOriginal
162 " <Leader>cG VCSGotoOriginal!
163 " <Leader>ci VCSInfo
164 " <Leader>cl VCSLog
165 " <Leader>cL VCSLock
166 " <Leader>cr VCSReview
167 " <Leader>cs VCSStatus
168 " <Leader>cu VCSUpdate
169 " <Leader>cU VCSUnlock
170 " <Leader>cv VCSVimDiff
171 "
172 " Options documentation: {{{2
173 "
174 " Several variables are checked by the script to determine behavior as follow:
175 "
176 " VCSCommandCommitOnWrite
177 " This variable, if set to a non-zero value, causes the pending commit to
178 " take place immediately as soon as the log message buffer is written. If
179 " set to zero, only the VCSCommit mapping will cause the pending commit to
180 " occur. If not set, it defaults to 1.
181 "
182 " VCSCommandDeleteOnHide
183 " This variable, if set to a non-zero value, causes the temporary VCS result
184 " buffers to automatically delete themselves when hidden.
185 "
186 " VCSCommand{VCSType}DiffOpt
187 " This variable, if set, determines the options passed to the diff command
188 " of the underlying VCS. Each VCS plugin defines a default value.
189 "
190 " VCSCommandDiffSplit
191 " This variable overrides the VCSCommandSplit variable, but only for buffers
192 " created with VCSVimDiff.
193 "
194 " VCSCommandDisableAll
195 " This variable, if set, prevents the plugin or any extensions from loading
196 " at all. This is useful when a single runtime distribution is used on
197 " multiple systems with varying versions.
198 "
199 " VCSCommandDisableMappings
200 " This variable, if set to a non-zero value, prevents the default command
201 " mappings from being set.
202 "
203 " VCSCommandDisableExtensionMappings
204 " This variable, if set to a non-zero value, prevents the default command
205 " mappings from being set for commands specific to an individual VCS.
206 "
207 " VCSCommandDisableMenu
208 " This variable, if set to a non-zero value, prevents the default command
209 " menu from being set.
210 "
211 " VCSCommandEdit
212 " This variable controls whether to split the current window to display a
213 " scratch buffer ('split'), or to display it in the current buffer ('edit').
214 " If not set, it defaults to 'split'.
215 "
216 " VCSCommandEnableBufferSetup
217 " This variable, if set to a non-zero value, activates VCS buffer management
218 " mode. This mode means that the buffer variable 'VCSRevision' is set if
219 " the file is VCS-controlled. This is useful for displaying version
220 " information in the status bar. Additional options may be set by
221 " individual VCS plugins.
222 "
223 " VCSCommandMappings
224 " This variable, if set, overrides the default mappings used for shortcuts.
225 " It should be a List of 2-element Lists, each containing a shortcut and
226 " function name pair.
227 "
228 " VCSCommandMapPrefix
229 " This variable, if set, overrides the default mapping prefix ('<Leader>c').
230 " This allows customization of the mapping space used by the vcscommand
231 " shortcuts.
232 "
233 " VCSCommandMenuPriority
234 " This variable, if set, overrides the default menu priority '' (empty)
235 "
236 " VCSCommandMenuRoot
237 " This variable, if set, overrides the default menu root 'Plugin.VCS'
238 "
239 " VCSCommandResultBufferNameExtension
240 " This variable, if set to a non-blank value, is appended to the name of the
241 " VCS command output buffers. For example, '.vcs'. Using this option may
242 " help avoid problems caused by autocommands dependent on file extension.
243 "
244 " VCSCommandResultBufferNameFunction
245 " This variable, if set, specifies a custom function for naming VCS command
246 " output buffers. This function will be passed the following arguments:
247 "
248 " command - name of the VCS command being executed (such as 'Log' or
249 " 'Diff').
250 "
251 " originalBuffer - buffer number of the source file.
252 "
253 " vcsType - type of VCS controlling this file (such as 'CVS' or 'SVN').
254 "
255 " statusText - extra text associated with the VCS action (such as version
256 " numbers).
257 "
258 " VCSCommandSplit
259 " This variable controls the orientation of the various window splits that
260 " may occur (such as with VCSVimDiff, when using a VCS command on a VCS
261 " command buffer, or when the 'VCSCommandEdit' variable is set to 'split'.
262 " If set to 'horizontal', the resulting windows will be on stacked on top of
263 " one another. If set to 'vertical', the resulting windows will be
264 " side-by-side. If not set, it defaults to 'horizontal' for all but
265 " VCSVimDiff windows.
266 "
267 " VCSCommandVCSTypeOverride
268 " This variable allows the VCS type detection to be overridden on a
269 " path-by-path basis. The value of this variable is expected to be a List
270 " of Lists. Each high-level List item is a List containing two elements.
271 " The first element is a regular expression that will be matched against the
272 " full file name of a given buffer. If it matches, the second element will
273 " be used as the VCS type.
274 "
275 " VCSCommandVCSTypePreference
276 " This variable allows the VCS type detection to be weighted towards a
277 " specific VCS, in case more than one potential VCS is detected as useable.
278 " The format of the variable is either a list or a space-separated string
279 " containing the ordered-by-preference abbreviations of the preferred VCS
280 " types.
281 "
282 " Event documentation {{{2
283 " For additional customization, VCSCommand.vim uses User event autocommand
284 " hooks. Each event is in the VCSCommand group, and different patterns
285 " match the various hooks.
286 "
287 " For instance, the following could be added to the vimrc to provide a 'q'
288 " mapping to quit a VCS scratch buffer:
289 "
290 " augroup VCSCommand
291 " au VCSCommand User VCSBufferCreated silent! nmap <unique> <buffer> q :bwipeout<cr>
292 " augroup END
293 "
294 " The following hooks are available:
295 "
296 " VCSBufferCreated This event is fired just after a VCS command
297 " output buffer is created. It is executed
298 " within the context of the new buffer.
299 "
300 " VCSBufferSetup This event is fired just after VCS buffer setup
301 " occurs, if enabled.
302 "
303 " VCSPluginInit This event is fired when the VCSCommand plugin
304 " first loads.
305 "
306 " VCSPluginFinish This event is fired just after the VCSCommand
307 " plugin loads.
308 "
309 " VCSVimDiffFinish This event is fired just after the VCSVimDiff
310 " command executes to allow customization of,
311 " for instance, window placement and focus.
312 "
313 " Section: Plugin header {{{1
315 " loaded_VCSCommand is set to 1 when the initialization begins, and 2 when it
316 " completes. This allows various actions to only be taken by functions after
317 " system initialization.
319 if exists('VCSCommandDisableAll')
320 finish
321 endif
323 if exists('loaded_VCSCommand')
324 finish
325 endif
326 let loaded_VCSCommand = 1
328 if v:version < 700
329 echohl WarningMsg|echomsg 'VCSCommand requires at least VIM 7.0'|echohl None
330 finish
331 endif
333 let s:save_cpo=&cpo
334 set cpo&vim
336 " Section: Event group setup {{{1
338 augroup VCSCommand
339 augroup END
341 augroup VCSCommandCommit
342 augroup END
344 " Section: Plugin initialization {{{1
345 silent do VCSCommand User VCSPluginInit
347 " Section: Constants declaration {{{1
349 let g:VCSCOMMAND_IDENTIFY_EXACT = 1
350 let g:VCSCOMMAND_IDENTIFY_INEXACT = -1
352 " Section: Script variable initialization {{{1
354 " Hidden functions for use by extensions
355 let s:VCSCommandUtility = {}
357 " plugin-specific information: {vcs -> [script, {command -> function}, {key -> mapping}]}
358 let s:plugins = {}
360 " Stack of dictionaries representing nested options
361 let s:executionContext = []
363 " state flag used to vary behavior of certain automated actions
364 let s:isEditFileRunning = 0
366 " Section: Utility functions {{{1
368 " Function: s:ReportError(mapping) {{{2
369 " Displays the given error in a consistent faction. This is intended to be
370 " invoked from a catch statement.
372 function! s:ReportError(error)
373 echohl WarningMsg|echomsg 'VCSCommand: ' . a:error|echohl None
374 endfunction
376 " Function: s:VCSCommandUtility.system(...) {{{2
377 " Replacement for system() function. This version protects the quoting in the
378 " command line on Windows systems.
380 function! s:VCSCommandUtility.system(...)
381 if (has("win32") || has("win64")) && &sxq !~ '"'
382 let save_sxq = &sxq
383 set sxq=\"
384 endif
385 try
386 if exists('*iconv') && has('multi_byte')
387 return iconv(call('system', a:000), &tenc, &enc)
388 endif
389 return call('system', a:000)
390 finally
391 if exists("save_sxq")
392 let &sxq = save_sxq
393 endif
394 endtry
395 endfunction
397 " Function: s:VCSCommandUtility.addMenuItem(shortcut, command) {{{2
398 " Adds the given menu item.
400 function! s:VCSCommandUtility.addMenuItem(shortcut, command)
401 if s:menuEnabled
402 exe 'amenu <silent> '.s:menuPriority.' '.s:menuRoot.'.'.a:shortcut.' '.a:command
403 endif
404 endfunction
406 " Function: s:VCSCommandUtility.pushContext(context) {{{2
407 " Adds a dictionary containing current options to the stack.
409 function! s:VCSCommandUtility.pushContext(context)
410 call insert(s:executionContext, a:context)
411 endfunction
413 " Function: s:VCSCommandUtility.popContext() {{{2
414 " Removes a dictionary containing current options from the stack.
416 function! s:VCSCommandUtility.popContext()
417 call remove(s:executionContext, 0)
418 endfunction
420 " Function: s:ClearMenu() {{{2
421 " Removes all VCSCommand menu items
422 function! s:ClearMenu()
423 if s:menuEnabled
424 execute 'aunmenu' s:menuRoot
425 endif
426 endfunction
428 " Function: s:CreateMapping(shortcut, expansion, display) {{{2
429 " Creates the given mapping by prepending the contents of
430 " 'VCSCommandMapPrefix' (by default '<Leader>c') to the given shortcut and
431 " mapping it to the given plugin function. If a mapping exists for the
432 " specified shortcut + prefix, emit an error but continue. If a mapping
433 " exists for the specified function, do nothing.
435 function! s:CreateMapping(shortcut, expansion, display)
436 let lhs = VCSCommandGetOption('VCSCommandMapPrefix', '<Leader>c') . a:shortcut
437 if !hasmapto(a:expansion)
438 try
439 execute 'nmap <silent> <unique>' lhs a:expansion
440 catch /^Vim(.*):E227:/
441 if(&verbose != 0)
442 echohl WarningMsg|echomsg 'VCSCommand: mapping ''' . lhs . ''' already exists, refusing to overwrite. The mapping for ' . a:display . ' will not be available.'|echohl None
443 endif
444 endtry
445 endif
446 endfunction
448 " Function: s:ExecuteExtensionMapping(mapping) {{{2
449 " Invokes the appropriate extension mapping depending on the type of the
450 " current buffer.
452 function! s:ExecuteExtensionMapping(mapping)
453 let buffer = bufnr('%')
454 let vcsType = VCSCommandGetVCSType(buffer)
455 if !has_key(s:plugins, vcsType)
456 throw 'Unknown VCS type: ' . vcsType
457 endif
458 if !has_key(s:plugins[vcsType][2], a:mapping)
459 throw 'This extended mapping is not defined for ' . vcsType
460 endif
461 silent execute 'normal!' ':' . s:plugins[vcsType][2][a:mapping] . "\<CR>"
462 endfunction
464 " Function: s:ExecuteVCSCommand(command, argList) {{{2
465 " Calls the indicated plugin-specific VCS command on the current buffer.
466 " Returns: buffer number of resulting output scratch buffer, or -1 if an error
467 " occurs.
469 function! s:ExecuteVCSCommand(command, argList)
470 try
471 let buffer = bufnr('%')
473 let vcsType = VCSCommandGetVCSType(buffer)
474 if !has_key(s:plugins, vcsType)
475 throw 'Unknown VCS type: ' . vcsType
476 endif
478 let originalBuffer = VCSCommandGetOriginalBuffer(buffer)
479 let bufferName = bufname(originalBuffer)
481 " It is already known that the directory is under VCS control. No further
482 " checks are needed. Otherwise, perform some basic sanity checks to avoid
483 " VCS-specific error messages from confusing things.
484 if !isdirectory(bufferName)
485 if !filereadable(bufferName)
486 throw 'No such file ' . bufferName
487 endif
488 endif
490 let functionMap = s:plugins[vcsType][1]
491 if !has_key(functionMap, a:command)
492 throw 'Command ''' . a:command . ''' not implemented for ' . vcsType
493 endif
494 return functionMap[a:command](a:argList)
495 catch
496 call s:ReportError(v:exception)
497 return -1
498 endtry
499 endfunction
501 " Function: s:GenerateResultBufferName(command, originalBuffer, vcsType, statusText) {{{2
502 " Default method of generating the name for VCS result buffers. This can be
503 " overridden with the VCSResultBufferNameFunction variable.
505 function! s:GenerateResultBufferName(command, originalBuffer, vcsType, statusText)
506 let fileName = bufname(a:originalBuffer)
507 let bufferName = a:vcsType . ' ' . a:command
508 if strlen(a:statusText) > 0
509 let bufferName .= ' ' . a:statusText
510 endif
511 let bufferName .= ' ' . fileName
512 let counter = 0
513 let versionedBufferName = bufferName
514 while bufexists(versionedBufferName)
515 let counter += 1
516 let versionedBufferName = bufferName . ' (' . counter . ')'
517 endwhile
518 return versionedBufferName
519 endfunction
521 " Function: s:GenerateResultBufferNameWithExtension(command, originalBuffer, vcsType, statusText) {{{2
522 " Method of generating the name for VCS result buffers that uses the original
523 " file name with the VCS type and command appended as extensions.
525 function! s:GenerateResultBufferNameWithExtension(command, originalBuffer, vcsType, statusText)
526 let fileName = bufname(a:originalBuffer)
527 let bufferName = a:vcsType . ' ' . a:command
528 if strlen(a:statusText) > 0
529 let bufferName .= ' ' . a:statusText
530 endif
531 let bufferName .= ' ' . fileName . VCSCommandGetOption('VCSCommandResultBufferNameExtension', '.vcs')
532 let counter = 0
533 let versionedBufferName = bufferName
534 while bufexists(versionedBufferName)
535 let counter += 1
536 let versionedBufferName = '(' . counter . ') ' . bufferName
537 endwhile
538 return versionedBufferName
539 endfunction
541 " Function: s:EditFile(command, originalBuffer, statusText) {{{2
542 " Creates a new buffer of the given name and associates it with the given
543 " original buffer.
545 function! s:EditFile(command, originalBuffer, statusText)
546 let vcsType = getbufvar(a:originalBuffer, 'VCSCommandVCSType')
548 " Protect against useless buffer set-up
549 let s:isEditFileRunning += 1
550 try
551 let editCommand = VCSCommandGetOption('VCSCommandEdit', 'split')
552 if editCommand == 'split'
553 if VCSCommandGetOption('VCSCommandSplit', 'horizontal') == 'horizontal'
554 rightbelow split
555 else
556 vert rightbelow split
557 endif
558 endif
560 enew
562 call s:SetupScratchBuffer(a:command, vcsType, a:originalBuffer, a:statusText)
564 finally
565 let s:isEditFileRunning -= 1
566 endtry
567 endfunction
569 " Function: s:IdentifyVCSType() {{{2
570 " This function implements the non-cached identification strategy for
571 " VcsCommandGetVCSType().
572 "
573 " Returns: VCS type name identified for the given buffer; an exception is
574 " thrown in case no type can be identified.
576 function! s:IdentifyVCSType(buffer)
577 if exists("g:VCSCommandVCSTypeOverride")
578 let fullpath = fnamemodify(bufname(a:buffer), ':p')
579 for [path, vcsType] in g:VCSCommandVCSTypeOverride
580 if match(fullpath, path) > -1
581 return vcsType
582 endif
583 endfor
584 endif
585 let matches = []
586 let exactMatch = ''
587 let exactMatchCount = 0
588 for vcsType in keys(s:plugins)
589 let identified = s:plugins[vcsType][1].Identify(a:buffer)
590 if identified
591 if identified == g:VCSCOMMAND_IDENTIFY_EXACT
592 let exactMatch = vcsType
593 let exactMatchCount += 1
594 endif
595 call add(matches, [vcsType, identified])
596 endif
597 endfor
598 if len(matches) == 1
599 return matches[0][0]
600 elseif len(matches) == 0
601 throw 'No suitable plugin'
602 else
603 let preferences = VCSCommandGetOption("VCSCommandVCSTypePreference", [])
604 if len(preferences) > 0
605 if type(preferences) == 1
606 let listPreferences = split(preferences, '\W\+')
607 unlet preferences
608 let preferences = listPreferences
609 endif
610 for preferred in preferences
611 for [vcsType, identified] in matches
612 if vcsType ==? preferred
613 return vcsType
614 endif
615 endfor
616 endfor
617 endif
619 if exactMatchCount == 1
620 return exactMatch
621 endif
623 throw 'can''t identify VCS type for current buffer due to too many matching VCS: ' . join(map(matches, 'v:val[0]'))
624 endif
625 endfunction
627 " Function: s:SetupScratchBuffer(command, vcsType, originalBuffer, statusText) {{{2
628 " Creates convenience buffer variables and the name of a vcscommand result
629 " buffer.
631 function! s:SetupScratchBuffer(command, vcsType, originalBuffer, statusText)
632 let nameExtension = VCSCommandGetOption('VCSCommandResultBufferNameExtension', '')
633 if nameExtension == ''
634 let nameFunction = VCSCommandGetOption('VCSCommandResultBufferNameFunction', 's:GenerateResultBufferName')
635 else
636 let nameFunction = VCSCommandGetOption('VCSCommandResultBufferNameFunction', 's:GenerateResultBufferNameWithExtension')
637 endif
639 let name = call(nameFunction, [a:command, a:originalBuffer, a:vcsType, a:statusText])
641 let b:VCSCommandCommand = a:command
642 let b:VCSCommandOriginalBuffer = a:originalBuffer
643 let b:VCSCommandSourceFile = bufname(a:originalBuffer)
644 let b:VCSCommandVCSType = a:vcsType
645 if a:statusText != ''
646 let b:VCSCommandStatusText = a:statusText
647 endif
649 setlocal buftype=nofile
650 setlocal noswapfile
651 let &filetype = tolower(a:vcsType . a:command)
653 if VCSCommandGetOption('VCSCommandDeleteOnHide', 0)
654 setlocal bufhidden=delete
655 endif
656 silent noautocmd file `=name`
657 endfunction
659 " Function: s:SetupBuffer() {{{2
660 " Attempts to set the b:VCSCommandBufferInfo variable
662 function! s:SetupBuffer()
663 if (exists('b:VCSCommandBufferSetup') && b:VCSCommandBufferSetup)
664 " This buffer is already set up.
665 return
666 endif
668 if !isdirectory(@%) && (strlen(&buftype) > 0 || !filereadable(@%))
669 " No special status for special buffers other than directory buffers.
670 return
671 endif
673 if !VCSCommandGetOption('VCSCommandEnableBufferSetup', 0) || s:isEditFileRunning > 0
674 unlet! b:VCSCommandBufferSetup
675 return
676 endif
678 try
679 let vcsType = VCSCommandGetVCSType(bufnr('%'))
680 let b:VCSCommandBufferInfo = s:plugins[vcsType][1].GetBufferInfo()
681 silent do VCSCommand User VCSBufferSetup
682 catch /No suitable plugin/
683 " This is not a VCS-controlled file.
684 let b:VCSCommandBufferInfo = []
685 endtry
687 let b:VCSCommandBufferSetup = 1
688 endfunction
690 " Function: s:MarkOrigBufferForSetup(buffer) {{{2
691 " Resets the buffer setup state of the original buffer for a given VCS scratch
692 " buffer.
693 " Returns: The VCS buffer number in a passthrough mode.
695 function! s:MarkOrigBufferForSetup(buffer)
696 checktime
697 if a:buffer > 0
698 let origBuffer = VCSCommandGetOriginalBuffer(a:buffer)
699 " This should never not work, but I'm paranoid
700 if origBuffer != a:buffer
701 call setbufvar(origBuffer, 'VCSCommandBufferSetup', 0)
702 endif
703 endif
704 return a:buffer
705 endfunction
707 " Function: s:WipeoutCommandBuffers() {{{2
708 " Clears all current VCS output buffers of the specified type for a given source.
710 function! s:WipeoutCommandBuffers(originalBuffer, VCSCommand)
711 let buffer = 1
712 while buffer <= bufnr('$')
713 if getbufvar(buffer, 'VCSCommandOriginalBuffer') == a:originalBuffer
714 if getbufvar(buffer, 'VCSCommandCommand') == a:VCSCommand
715 execute 'bw' buffer
716 endif
717 endif
718 let buffer = buffer + 1
719 endwhile
720 endfunction
722 " Function: s:VimDiffRestore(vimDiffBuff) {{{2
723 " Checks whether the given buffer is one whose deletion should trigger
724 " restoration of an original buffer after it was diffed. If so, it executes
725 " the appropriate setting command stored with that original buffer.
727 function! s:VimDiffRestore(vimDiffBuff)
728 let s:isEditFileRunning += 1
729 try
730 if exists('t:vcsCommandVimDiffSourceBuffer')
731 if a:vimDiffBuff == t:vcsCommandVimDiffSourceBuffer
732 " Original file is being removed.
733 unlet! t:vcsCommandVimDiffSourceBuffer
734 unlet! t:vcsCommandVimDiffRestoreCmd
735 unlet! t:vcsCommandVimDiffScratchList
736 else
737 let index = index(t:vcsCommandVimDiffScratchList, a:vimDiffBuff)
738 if index >= 0
739 call remove(t:vcsCommandVimDiffScratchList, index)
740 if len(t:vcsCommandVimDiffScratchList) == 0
741 if exists('t:vcsCommandVimDiffRestoreCmd')
742 " All scratch buffers are gone, reset the original.
743 " Only restore if the source buffer is still in Diff mode
745 let sourceWinNR = bufwinnr(t:vcsCommandVimDiffSourceBuffer)
746 if sourceWinNR != -1
747 " The buffer is visible in at least one window
748 let currentWinNR = winnr()
749 while winbufnr(sourceWinNR) != -1
750 if winbufnr(sourceWinNR) == t:vcsCommandVimDiffSourceBuffer
751 execute sourceWinNR . 'wincmd w'
752 if getwinvar(0, '&diff')
753 execute t:vcsCommandVimDiffRestoreCmd
754 endif
755 endif
756 let sourceWinNR = sourceWinNR + 1
757 endwhile
758 execute currentWinNR . 'wincmd w'
759 else
760 " The buffer is hidden. It must be visible in order to set the
761 " diff option.
762 let currentBufNR = bufnr('')
763 execute 'hide buffer' t:vcsCommandVimDiffSourceBuffer
764 if getwinvar(0, '&diff')
765 execute t:vcsCommandVimDiffRestoreCmd
766 endif
767 execute 'hide buffer' currentBufNR
768 endif
770 unlet t:vcsCommandVimDiffRestoreCmd
771 endif
772 " All buffers are gone.
773 unlet t:vcsCommandVimDiffSourceBuffer
774 unlet t:vcsCommandVimDiffScratchList
775 endif
776 endif
777 endif
778 endif
779 finally
780 let s:isEditFileRunning -= 1
781 endtry
782 endfunction
784 " Section: Generic VCS command functions {{{1
786 " Function: s:VCSAnnotate(...) {{{2
787 function! s:VCSAnnotate(bang, ...)
788 try
789 let line = line('.')
790 let currentBuffer = bufnr('%')
791 let originalBuffer = VCSCommandGetOriginalBuffer(currentBuffer)
793 let annotateBuffer = s:ExecuteVCSCommand('Annotate', a:000)
794 if annotateBuffer == -1
795 return -1
796 endif
797 if a:bang == '!' && VCSCommandGetOption('VCSCommandDisableSplitAnnotate', 0) == 0
798 let vcsType = VCSCommandGetVCSType(annotateBuffer)
799 let functionMap = s:plugins[vcsType][1]
800 let splitRegex = ''
801 if has_key(s:plugins[vcsType][1], 'AnnotateSplitRegex')
802 let splitRegex = s:plugins[vcsType][1]['AnnotateSplitRegex']
803 endif
804 let splitRegex = VCSCommandGetOption('VCSCommand' . vcsType . 'AnnotateSplitRegex', splitRegex)
805 if splitRegex == ''
806 return annotateBuffer
807 endif
808 let originalFileType = getbufvar(originalBuffer, '&ft')
809 let annotateFileType = getbufvar(annotateBuffer, '&ft')
810 execute "normal! 0zR\<c-v>G/" . splitRegex . "/e\<cr>d"
811 call setbufvar('%', '&filetype', getbufvar(originalBuffer, '&filetype'))
812 set scrollbind
813 leftabove vert new
814 normal! 0P
815 execute "normal!" . (col('$') + (&number ? &numberwidth : 0)). "\<c-w>|"
816 call s:SetupScratchBuffer('annotate', vcsType, originalBuffer, 'header')
817 wincmd l
818 endif
820 if currentBuffer == originalBuffer
821 " Starting from the original source buffer, so the
822 " current line is relevant.
823 if a:0 == 0
824 " No argument list means that we're annotating
825 " the current version, so jumping to the same
826 " line is the expected action.
827 execute "normal!" line . 'G'
828 if has('folding')
829 " The execution of the buffer created autocommand
830 " re-folds the buffer. Display the current line
831 " unfolded.
832 normal! zv
833 endif
834 endif
835 endif
837 return annotateBuffer
838 catch
839 call s:ReportError(v:exception)
840 return -1
841 endtry
842 endfunction
844 " Function: s:VCSCommit() {{{2
845 function! s:VCSCommit(bang, message)
846 try
847 let vcsType = VCSCommandGetVCSType(bufnr('%'))
848 if !has_key(s:plugins, vcsType)
849 throw 'Unknown VCS type: ' . vcsType
850 endif
852 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
854 " Handle the commit message being specified. If a message is supplied, it
855 " is used; if bang is supplied, an empty message is used; otherwise, the
856 " user is provided a buffer from which to edit the commit message.
858 if strlen(a:message) > 0 || a:bang == '!'
859 return s:VCSFinishCommit([a:message], originalBuffer)
860 endif
862 call s:EditFile('commitlog', originalBuffer, '')
863 setlocal ft=vcscommit
865 " Create a commit mapping.
867 nnoremap <silent> <buffer> <Plug>VCSCommit :call <SID>VCSFinishCommitWithBuffer()<CR>
869 silent 0put ='VCS: ----------------------------------------------------------------------'
870 silent put ='VCS: Please enter log message. Lines beginning with ''VCS:'' are removed automatically.'
871 silent put ='VCS: To finish the commit, Type <leader>cc (or your own <Plug>VCSCommit mapping)'
873 if VCSCommandGetOption('VCSCommandCommitOnWrite', 1) == 1
874 setlocal buftype=acwrite
875 au VCSCommandCommit BufWriteCmd <buffer> call s:VCSFinishCommitWithBuffer()
876 silent put ='VCS: or write this buffer'
877 endif
879 silent put ='VCS: ----------------------------------------------------------------------'
880 $
881 setlocal nomodified
882 silent do VCSCommand User VCSBufferCreated
883 catch
884 call s:ReportError(v:exception)
885 return -1
886 endtry
887 endfunction
889 " Function: s:VCSFinishCommitWithBuffer() {{{2
890 " Wrapper for s:VCSFinishCommit which is called only from a commit log buffer
891 " which removes all lines starting with 'VCS:'.
893 function! s:VCSFinishCommitWithBuffer()
894 setlocal nomodified
895 let currentBuffer = bufnr('%')
896 let logMessageList = getbufline('%', 1, '$')
897 call filter(logMessageList, 'v:val !~ ''^\s*VCS:''')
898 let resultBuffer = s:VCSFinishCommit(logMessageList, b:VCSCommandOriginalBuffer)
899 if resultBuffer >= 0
900 execute 'bw' currentBuffer
901 endif
902 return resultBuffer
903 endfunction
905 " Function: s:VCSFinishCommit(logMessageList, originalBuffer) {{{2
906 function! s:VCSFinishCommit(logMessageList, originalBuffer)
907 let messageFileName = tempname()
908 call writefile(a:logMessageList, messageFileName)
909 try
910 let resultBuffer = s:ExecuteVCSCommand('Commit', [messageFileName])
911 if resultBuffer < 0
912 return resultBuffer
913 endif
914 return s:MarkOrigBufferForSetup(resultBuffer)
915 finally
916 call delete(messageFileName)
917 endtry
918 endfunction
920 " Function: s:VCSGotoOriginal(bang) {{{2
921 function! s:VCSGotoOriginal(bang)
922 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
923 if originalBuffer > 0
924 let origWinNR = bufwinnr(originalBuffer)
925 if origWinNR == -1
926 execute 'buffer' originalBuffer
927 else
928 execute origWinNR . 'wincmd w'
929 endif
930 if a:bang == '!'
931 let buffnr = 1
932 let buffmaxnr = bufnr('$')
933 while buffnr <= buffmaxnr
934 if getbufvar(buffnr, 'VCSCommandOriginalBuffer') == originalBuffer
935 execute 'bw' buffnr
936 endif
937 let buffnr = buffnr + 1
938 endwhile
939 endif
940 endif
941 endfunction
943 function! s:VCSDiff(...) "{{{2
944 let resultBuffer = s:ExecuteVCSCommand('Diff', a:000)
945 if resultBuffer > 0
946 let &filetype = 'diff'
947 elseif resultBuffer == 0
948 echomsg 'No differences found'
949 endif
950 return resultBuffer
951 endfunction
953 function! s:VCSReview(...) "{{{2
954 let resultBuffer = s:ExecuteVCSCommand('Review', a:000)
955 if resultBuffer > 0
956 let &filetype = getbufvar(b:VCSCommandOriginalBuffer, '&filetype')
957 endif
958 return resultBuffer
959 endfunction
961 " Function: s:VCSVimDiff(...) {{{2
962 function! s:VCSVimDiff(...)
963 try
964 let vcsType = VCSCommandGetVCSType(bufnr('%'))
965 if !has_key(s:plugins, vcsType)
966 throw 'Unknown VCS type: ' . vcsType
967 endif
968 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
969 let s:isEditFileRunning = s:isEditFileRunning + 1
970 try
971 " If there's already a VimDiff'ed window, restore it.
972 " There may only be one VCSVimDiff original window at a time.
974 if exists('t:vcsCommandVimDiffSourceBuffer') && t:vcsCommandVimDiffSourceBuffer != originalBuffer
975 " Clear the existing vimdiff setup by removing the result buffers.
976 call s:WipeoutCommandBuffers(t:vcsCommandVimDiffSourceBuffer, 'vimdiff')
977 endif
979 let orientation = &diffopt =~ 'horizontal' ? 'horizontal' : 'vertical'
980 let orientation = VCSCommandGetOption('VCSCommandSplit', orientation)
981 let orientation = VCSCommandGetOption('VCSCommandDiffSplit', orientation)
983 " Split and diff
984 if(a:0 == 2)
985 " Reset the vimdiff system, as 2 explicit versions were provided.
986 if exists('t:vcsCommandVimDiffSourceBuffer')
987 call s:WipeoutCommandBuffers(t:vcsCommandVimDiffSourceBuffer, 'vimdiff')
988 endif
989 let resultBuffer = s:VCSReview(a:1)
990 if resultBuffer < 0
991 echomsg 'Can''t open revision ' . a:1
992 return resultBuffer
993 endif
994 let b:VCSCommandCommand = 'vimdiff'
995 diffthis
996 let t:vcsCommandVimDiffScratchList = [resultBuffer]
997 " If no split method is defined, cheat, and set it to vertical.
998 call s:VCSCommandUtility.pushContext({'VCSCommandSplit': orientation})
999 try
1000 let resultBuffer = s:VCSReview(a:2)
1001 finally
1002 call s:VCSCommandUtility.popContext()
1003 endtry
1004 if resultBuffer < 0
1005 echomsg 'Can''t open revision ' . a:1
1006 return resultBuffer
1007 endif
1008 let b:VCSCommandCommand = 'vimdiff'
1009 diffthis
1010 let t:vcsCommandVimDiffScratchList += [resultBuffer]
1011 else
1012 " Add new buffer. Force splitting behavior, otherwise why use vimdiff?
1013 call s:VCSCommandUtility.pushContext({'VCSCommandEdit': 'split', 'VCSCommandSplit': orientation})
1014 try
1015 if(a:0 == 0)
1016 let resultBuffer = s:VCSReview()
1017 else
1018 let resultBuffer = s:VCSReview(a:1)
1019 endif
1020 finally
1021 call s:VCSCommandUtility.popContext()
1022 endtry
1023 if resultBuffer < 0
1024 echomsg 'Can''t open current revision'
1025 return resultBuffer
1026 endif
1027 let b:VCSCommandCommand = 'vimdiff'
1028 diffthis
1030 if !exists('t:vcsCommandVimDiffSourceBuffer')
1031 " New instance of vimdiff.
1032 let t:vcsCommandVimDiffScratchList = [resultBuffer]
1034 " This could have been invoked on a VCS result buffer, not the
1035 " original buffer.
1036 wincmd W
1037 execute 'buffer' originalBuffer
1038 " Store info for later original buffer restore
1039 let t:vcsCommandVimDiffRestoreCmd =
1040 \ 'call setbufvar('.originalBuffer.', ''&diff'', '.getbufvar(originalBuffer, '&diff').')'
1041 \ . '|call setbufvar('.originalBuffer.', ''&foldcolumn'', '.getbufvar(originalBuffer, '&foldcolumn').')'
1042 \ . '|call setbufvar('.originalBuffer.', ''&foldenable'', '.getbufvar(originalBuffer, '&foldenable').')'
1043 \ . '|call setbufvar('.originalBuffer.', ''&foldmethod'', '''.getbufvar(originalBuffer, '&foldmethod').''')'
1044 \ . '|call setbufvar('.originalBuffer.', ''&foldlevel'', '''.getbufvar(originalBuffer, '&foldlevel').''')'
1045 \ . '|call setbufvar('.originalBuffer.', ''&scrollbind'', '.getbufvar(originalBuffer, '&scrollbind').')'
1046 \ . '|call setbufvar('.originalBuffer.', ''&cursorbind'', '.getbufvar(originalBuffer, '&cursorbind').')'
1047 \ . '|call setbufvar('.originalBuffer.', ''&wrap'', '.getbufvar(originalBuffer, '&wrap').')'
1048 \ . '|if &foldmethod==''manual''|execute ''normal! zE''|endif'
1049 diffthis
1050 wincmd w
1051 else
1052 " Adding a window to an existing vimdiff
1053 let t:vcsCommandVimDiffScratchList += [resultBuffer]
1054 endif
1055 endif
1057 let t:vcsCommandVimDiffSourceBuffer = originalBuffer
1059 " Avoid executing the modeline in the current buffer after the autocommand.
1061 let currentBuffer = bufnr('%')
1062 let saveModeline = getbufvar(currentBuffer, '&modeline')
1063 try
1064 call setbufvar(currentBuffer, '&modeline', 0)
1065 silent do VCSCommand User VCSVimDiffFinish
1066 finally
1067 call setbufvar(currentBuffer, '&modeline', saveModeline)
1068 endtry
1069 return resultBuffer
1070 finally
1071 let s:isEditFileRunning = s:isEditFileRunning - 1
1072 endtry
1073 catch
1074 call s:ReportError(v:exception)
1075 return -1
1076 endtry
1077 endfunction
1079 " Section: Public functions {{{1
1081 " Function: VCSCommandGetVCSType() {{{2
1082 " This function sets the b:VCSCommandVCSType variable in the given buffer to the
1083 " appropriate source control system name and returns the same name.
1084 "
1085 " Returns: VCS type name identified for the given buffer. An exception is
1086 " thrown if no type can be identified.
1087 "
1088 " Rules for determining type:
1089 " 1. use previously-cached value
1090 " 2. use value from 'VCSCommandVCSTypeOverride'
1091 " 3. use single match
1092 " 4. use first matching value from 'VCSCommandTypePreference'
1093 " 5. use single exact match
1094 " 6. error if multiple matching types
1095 " 7. error if no matching types
1097 function! VCSCommandGetVCSType(buffer)
1098 let vcsType = VCSCommandGetOption('VCSCommandVCSTypeExplicitOverride', '')
1099 if len(vcsType) == 0
1100 let vcsType = getbufvar(a:buffer, 'VCSCommandVCSType')
1101 if strlen(vcsType) == 0
1102 let vcsType = s:IdentifyVCSType(a:buffer)
1103 call setbufvar(a:buffer, 'VCSCommandVCSType', vcsType)
1104 endif
1105 endif
1106 return vcsType
1107 endfunction
1109 " Function: VCSCommandChdir(directory) {{{2
1110 " Changes the current directory, respecting :lcd changes.
1112 function! VCSCommandChdir(directory)
1113 let command = 'cd'
1114 if exists("*haslocaldir") && haslocaldir()
1115 let command = 'lcd'
1116 endif
1117 if exists("*fnameescape")
1118 execute command fnameescape(a:directory)
1119 else
1120 execute command escape(a:directory, ' ')
1121 endif
1122 endfunction
1124 " Function: VCSCommandChangeToCurrentFileDir() {{{2
1125 " Go to the directory in which the given file is located.
1127 function! VCSCommandChangeToCurrentFileDir(fileName)
1128 let oldCwd = getcwd()
1129 let newCwd = fnamemodify(resolve(a:fileName), ':p:h')
1130 if strlen(newCwd) > 0
1131 call VCSCommandChdir(newCwd)
1132 endif
1133 return oldCwd
1134 endfunction
1136 " Function: VCSCommandGetOriginalBuffer(vcsBuffer) {{{2
1137 " Attempts to locate the original file to which VCS operations were applied
1138 " for a given buffer.
1140 function! VCSCommandGetOriginalBuffer(vcsBuffer)
1141 let origBuffer = getbufvar(a:vcsBuffer, 'VCSCommandOriginalBuffer')
1142 if origBuffer
1143 if bufexists(origBuffer)
1144 return origBuffer
1145 else
1146 " Original buffer no longer exists.
1147 throw 'Original buffer for this VCS buffer no longer exists.'
1148 endif
1149 else
1150 " No original buffer
1151 return a:vcsBuffer
1152 endif
1153 endfunction
1155 " Function: VCSCommandRegisterModule(name, file, commandMap) {{{2
1156 " Allows VCS modules to register themselves.
1158 function! VCSCommandRegisterModule(name, path, commandMap, mappingMap)
1159 let s:plugins[a:name] = [a:path, a:commandMap, a:mappingMap]
1160 if !empty(a:mappingMap)
1161 \ && !exists("g:no_plugin_maps")
1162 \ && !VCSCommandGetOption('VCSCommandDisableMappings', 0)
1163 \ && !VCSCommandGetOption('VCSCommandDisableExtensionMappings', 0)
1164 for shortcut in keys(a:mappingMap)
1165 let expansion = ":call <SID>ExecuteExtensionMapping('" . shortcut . "')<CR>"
1166 call s:CreateMapping(shortcut, expansion, a:name . " extension mapping " . shortcut)
1167 endfor
1168 endif
1169 return s:VCSCommandUtility
1170 endfunction
1172 " Function: VCSCommandDoCommand(cmd, cmdName, statusText, [options]) {{{2
1173 " General skeleton for VCS function execution. The given command is executed
1174 " after appending the current buffer name (or substituting it for
1175 " <VCSCOMMANDFILE>, if such a token is present). The output is captured in a
1176 " new buffer.
1177 "
1178 " The optional 'options' Dictionary may contain the following options:
1179 " allowNonZeroExit: if non-zero, if the underlying VCS command has a
1180 " non-zero exit status, the command is still considered
1181 " successfuly. This defaults to zero.
1182 " Returns: name of the new command buffer containing the command results
1184 function! VCSCommandDoCommand(cmd, cmdName, statusText, options)
1185 let allowNonZeroExit = 0
1186 if has_key(a:options, 'allowNonZeroExit')
1187 let allowNonZeroExit = a:options.allowNonZeroExit
1188 endif
1190 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
1191 if originalBuffer == -1
1192 throw 'Original buffer no longer exists, aborting.'
1193 endif
1195 let path = resolve(bufname(originalBuffer))
1197 " Work with netrw or other systems where a directory listing is displayed in
1198 " a buffer.
1200 if isdirectory(path)
1201 let fileName = '.'
1202 else
1203 let fileName = fnamemodify(path, ':t')
1204 endif
1206 if match(a:cmd, '<VCSCOMMANDFILE>') > 0
1207 let fullCmd = substitute(a:cmd, '<VCSCOMMANDFILE>', fileName, 'g')
1208 else
1209 let fullCmd = a:cmd . ' -- ' . shellescape(fileName)
1210 endif
1212 " Change to the directory of the current buffer. This is done for CVS, but
1213 " is left in for other systems as it does not affect them negatively.
1215 let oldCwd = VCSCommandChangeToCurrentFileDir(path)
1216 try
1217 let output = s:VCSCommandUtility.system(fullCmd)
1218 finally
1219 call VCSCommandChdir(oldCwd)
1220 endtry
1222 " HACK: if line endings in the repository have been corrupted, the output
1223 " of the command will be confused.
1224 let output = substitute(output, "\r", '', 'g')
1226 if v:shell_error && !allowNonZeroExit
1227 if strlen(output) == 0
1228 throw 'Version control command failed'
1229 else
1230 let output = substitute(output, '\n', ' ', 'g')
1231 throw 'Version control command failed: ' . output
1232 endif
1233 endif
1235 if strlen(output) == 0
1236 " Handle case of no output. In this case, it is important to check the
1237 " file status, especially since cvs edit/unedit may change the attributes
1238 " of the file with no visible output.
1240 checktime
1241 return 0
1242 endif
1244 call s:EditFile(a:cmdName, originalBuffer, a:statusText)
1246 silent 0put=output
1248 " The last command left a blank line at the end of the buffer. If the
1249 " last line is folded (a side effect of the 'put') then the attempt to
1250 " remove the blank line will kill the last fold.
1251 "
1252 " This could be fixed by explicitly detecting whether the last line is
1253 " within a fold, but I prefer to simply unfold the result buffer altogether.
1255 if has('folding')
1256 normal! zR
1257 endif
1259 $d
1260 1
1262 " Define the environment and execute user-defined hooks.
1264 silent do VCSCommand User VCSBufferCreated
1265 return bufnr('%')
1266 endfunction
1268 " Function: VCSCommandGetOption(name, default) {{{2
1269 " Grab a user-specified option to override the default provided. Options are
1270 " searched in the window, buffer, then global spaces.
1272 function! VCSCommandGetOption(name, default)
1273 for context in s:executionContext
1274 if has_key(context, a:name)
1275 return context[a:name]
1276 endif
1277 endfor
1278 if exists('w:' . a:name)
1279 return w:{a:name}
1280 elseif exists('b:' . a:name)
1281 return b:{a:name}
1282 elseif exists('g:' . a:name)
1283 return g:{a:name}
1284 else
1285 return a:default
1286 endif
1287 endfunction
1289 " Function: VCSCommandDisableBufferSetup() {{{2
1290 " Global function for deactivating the buffer autovariables.
1292 function! VCSCommandDisableBufferSetup()
1293 let g:VCSCommandEnableBufferSetup = 0
1294 silent! augroup! VCSCommandPlugin
1295 endfunction
1297 " Function: VCSCommandEnableBufferSetup() {{{2
1298 " Global function for activating the buffer autovariables.
1300 function! VCSCommandEnableBufferSetup()
1301 let g:VCSCommandEnableBufferSetup = 1
1302 augroup VCSCommandPlugin
1303 au!
1304 au BufEnter * call s:SetupBuffer()
1305 augroup END
1307 " Only auto-load if the plugin is fully loaded. This gives other plugins a
1308 " chance to run.
1309 if g:loaded_VCSCommand == 2
1310 call s:SetupBuffer()
1311 endif
1312 endfunction
1314 " Function: VCSCommandGetStatusLine() {{{2
1315 " Default (sample) status line entry for VCS-controlled files. This is only
1316 " useful if VCS-managed buffer mode is on (see the VCSCommandEnableBufferSetup
1317 " variable for how to do this).
1319 function! VCSCommandGetStatusLine()
1320 if exists('b:VCSCommandCommand')
1321 " This is a result buffer. Return nothing because the buffer name
1322 " contains information already.
1323 return ''
1324 endif
1326 if exists('b:VCSCommandVCSType')
1327 \ && exists('g:VCSCommandEnableBufferSetup')
1328 \ && g:VCSCommandEnableBufferSetup
1329 \ && exists('b:VCSCommandBufferInfo')
1330 return '[' . join(extend([b:VCSCommandVCSType], b:VCSCommandBufferInfo), ' ') . ']'
1331 else
1332 return ''
1333 endif
1334 endfunction
1336 function! VCSCommandSetVCSType(type)
1337 if exists('b:VCSCommandBufferSetup')
1338 unlet b:VCSCommandBufferSetup
1339 endif
1340 let b:VCSCommandVCSType = a:type
1341 call s:SetupBuffer()
1342 endfunction
1344 " Section: Command definitions {{{1
1345 " Section: Primary commands {{{2
1346 com! -nargs=* VCSAdd call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Add', [<f-args>]))
1347 com! -nargs=* -bang VCSAnnotate call s:VCSAnnotate(<q-bang>, <f-args>)
1348 com! -nargs=* -bang VCSBlame call s:VCSAnnotate(<q-bang>, <f-args>)
1349 com! -nargs=? -bang VCSCommit call s:VCSCommit(<q-bang>, <q-args>)
1350 com! -nargs=* VCSDelete call s:ExecuteVCSCommand('Delete', [<f-args>])
1351 com! -nargs=* VCSDiff call s:VCSDiff(<f-args>)
1352 com! -nargs=0 -bang VCSGotoOriginal call s:VCSGotoOriginal(<q-bang>)
1353 com! -nargs=* VCSInfo call s:ExecuteVCSCommand('Info', [<f-args>])
1354 com! -nargs=* VCSLock call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Lock', [<f-args>]))
1355 com! -nargs=* VCSLog call s:ExecuteVCSCommand('Log', [<f-args>])
1356 com! -nargs=* VCSRemove call s:ExecuteVCSCommand('Delete', [<f-args>])
1357 com! -nargs=0 VCSRevert call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Revert', []))
1358 com! -nargs=? VCSReview call s:VCSReview(<f-args>)
1359 com! -nargs=* VCSStatus call s:ExecuteVCSCommand('Status', [<f-args>])
1360 com! -nargs=* VCSUnlock call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Unlock', [<f-args>]))
1361 com! -nargs=0 VCSUpdate call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Update', []))
1362 com! -nargs=* VCSVimDiff call s:VCSVimDiff(<f-args>)
1364 " Section: VCS buffer management commands {{{2
1365 com! VCSCommandDisableBufferSetup call VCSCommandDisableBufferSetup()
1366 com! VCSCommandEnableBufferSetup call VCSCommandEnableBufferSetup()
1368 " Allow reloading VCSCommand.vim
1369 com! VCSReload let savedPlugins = s:plugins|let s:plugins = {}|call s:ClearMenu()|unlet! g:loaded_VCSCommand|runtime plugin/vcscommand.vim|for plugin in values(savedPlugins)|execute 'source' plugin[0]|endfor|unlet savedPlugins
1371 " Section: Plugin command mappings {{{1
1372 if !exists("no_plugin_maps")
1373 nnoremap <silent> <Plug>VCSAdd :VCSAdd<CR>
1374 nnoremap <silent> <Plug>VCSAnnotate :VCSAnnotate<CR>
1375 nnoremap <silent> <Plug>VCSCommit :VCSCommit<CR>
1376 nnoremap <silent> <Plug>VCSDelete :VCSDelete<CR>
1377 nnoremap <silent> <Plug>VCSDiff :VCSDiff<CR>
1378 nnoremap <silent> <Plug>VCSGotoOriginal :VCSGotoOriginal<CR>
1379 nnoremap <silent> <Plug>VCSClearAndGotoOriginal :VCSGotoOriginal!<CR>
1380 nnoremap <silent> <Plug>VCSInfo :VCSInfo<CR>
1381 nnoremap <silent> <Plug>VCSLock :VCSLock<CR>
1382 nnoremap <silent> <Plug>VCSLog :VCSLog<CR>
1383 nnoremap <silent> <Plug>VCSRevert :VCSRevert<CR>
1384 nnoremap <silent> <Plug>VCSReview :VCSReview<CR>
1385 nnoremap <silent> <Plug>VCSSplitAnnotate :VCSAnnotate!<CR>
1386 nnoremap <silent> <Plug>VCSStatus :VCSStatus<CR>
1387 nnoremap <silent> <Plug>VCSUnlock :VCSUnlock<CR>
1388 nnoremap <silent> <Plug>VCSUpdate :VCSUpdate<CR>
1389 nnoremap <silent> <Plug>VCSVimDiff :VCSVimDiff<CR>
1390 endif
1392 " Section: Default mappings {{{1
1394 let s:defaultMappings = [
1395 \['a', 'VCSAdd'],
1396 \['c', 'VCSCommit'],
1397 \['D', 'VCSDelete'],
1398 \['d', 'VCSDiff'],
1399 \['G', 'VCSClearAndGotoOriginal'],
1400 \['g', 'VCSGotoOriginal'],
1401 \['i', 'VCSInfo'],
1402 \['L', 'VCSLock'],
1403 \['l', 'VCSLog'],
1404 \['N', 'VCSSplitAnnotate'],
1405 \['n', 'VCSAnnotate'],
1406 \['q', 'VCSRevert'],
1407 \['r', 'VCSReview'],
1408 \['s', 'VCSStatus'],
1409 \['U', 'VCSUnlock'],
1410 \['u', 'VCSUpdate'],
1411 \['v', 'VCSVimDiff'],
1412 \]
1414 if !exists("g:no_plugin_maps") && !VCSCommandGetOption('VCSCommandDisableMappings', 0)
1415 for [s:shortcut, s:vcsFunction] in VCSCommandGetOption('VCSCommandMappings', s:defaultMappings)
1416 call s:CreateMapping(s:shortcut, '<Plug>' . s:vcsFunction, '''' . s:vcsFunction . '''')
1417 endfor
1418 unlet s:shortcut s:vcsFunction
1419 endif
1420 unlet s:defaultMappings
1422 " Section: Menu items {{{1
1424 let s:menuEnabled = !VCSCommandGetOption('VCSCommandDisableMenu', 0)
1425 let s:menuRoot = VCSCommandGetOption('VCSCommandMenuRoot', '&Plugin.VCS')
1426 let s:menuPriority = VCSCommandGetOption('VCSCommandMenuPriority', '')
1428 for [s:shortcut, s:command] in [
1429 \['&Add', '<Plug>VCSAdd'],
1430 \['A&nnotate', '<Plug>VCSAnnotate'],
1431 \['&Commit', '<Plug>VCSCommit'],
1432 \['Delete', '<Plug>VCSDelete'],
1433 \['&Diff', '<Plug>VCSDiff'],
1434 \['&Info', '<Plug>VCSInfo'],
1435 \['&Log', '<Plug>VCSLog'],
1436 \['Revert', '<Plug>VCSRevert'],
1437 \['&Review', '<Plug>VCSReview'],
1438 \['&Status', '<Plug>VCSStatus'],
1439 \['&Update', '<Plug>VCSUpdate'],
1440 \['&VimDiff', '<Plug>VCSVimDiff']
1441 \]
1442 call s:VCSCommandUtility.addMenuItem(s:shortcut, s:command)
1443 endfor
1444 unlet s:shortcut s:command
1446 " Section: Autocommands to restore vimdiff state {{{1
1447 augroup VimDiffRestore
1448 au!
1449 au BufUnload * call s:VimDiffRestore(str2nr(expand('<abuf>')))
1450 augroup END
1452 " Section: Optional activation of buffer management {{{1
1454 if VCSCommandGetOption('VCSCommandEnableBufferSetup', 0)
1455 call VCSCommandEnableBufferSetup()
1456 endif
1458 " Section: VIM shutdown hook {{{1
1460 " Close all result buffers when VIM exits, to prevent them from being restored
1461 " via viminfo.
1463 " Function: s:CloseAllResultBuffers() {{{2
1464 " Closes all vcscommand result buffers.
1465 function! s:CloseAllResultBuffers()
1466 " This avoids using bufdo as that may load buffers already loaded in another
1467 " vim process, resulting in an error.
1468 let buffnr = 1
1469 let buffmaxnr = bufnr('$')
1470 while buffnr <= buffmaxnr
1471 if getbufvar(buffnr, 'VCSCommandOriginalBuffer') != ""
1472 execute 'bw' buffnr
1473 endif
1474 let buffnr = buffnr + 1
1475 endwhile
1476 endfunction
1478 augroup VCSCommandVIMShutdown
1479 au!
1480 au VimLeavePre * call s:CloseAllResultBuffers()
1481 augroup END
1483 " Section: Plugin completion {{{1
1485 let loaded_VCSCommand = 2
1487 silent do VCSCommand User VCSPluginFinish
1489 let &cpo = s:save_cpo