plugin/vcscommand.vim

   1 " vim600: set foldmethod=marker:
   2 "
   3 " Vim plugin to assist in working with files under control of various Version
   4 " Control Systems, such as CVS, SVN, SVK, and git.
   5 "
   6 " Maintainer:    Bob Hiestand <bob.hiestand@gmail.com>
   7 " License:
   8 " Copyright (c) 2008 Bob Hiestand
   9 "
  10 " Permission is hereby granted, free of charge, to any person obtaining a copy
  11 " of this software and associated documentation files (the "Software"), to
  12 " deal in the Software without restriction, including without limitation the
  13 " rights to use, copy, modify, merge, publish, distribute, sublicense, and/or
  14 " sell copies of the Software, and to permit persons to whom the Software is
  15 " furnished to do so, subject to the following conditions:
  16 "
  17 " The above copyright notice and this permission notice shall be included in
  18 " all copies or substantial portions of the Software.
  19 "
  20 " THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  21 " IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  22 " FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL THE
  23 " AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  24 " LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  25 " FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS
  26 " IN THE SOFTWARE.
  27 "
  28 " Section: Documentation {{{1
  29 "
  30 " Provides functions to invoke various source control commands on the current
  31 " file (either the current buffer, or, in the case of an directory buffer, the
  32 " directory and all subdirectories associated with the current buffer).  The
  33 " output of the commands is captured in a new scratch window.
  34 "
  35 " This plugin needs additional extension plugins, each specific to a source
  36 " control system, to function.  Several options include the name of the
  37 " version control system in the option name.  Such options use the placeholder
  38 " text '{VCSType}', which would be replaced in actual usage with 'CVS' or
  39 " 'SVN', for instance.
  40 "
  41 " Command documentation {{{2
  42 "
  43 " VCSAdd           Adds the current file to source control.
  44 "
  45 " VCSAnnotate[!]   Displays the current file with each line annotated with the
  46 "                  version in which it was most recently changed.  If an
  47 "                  argument is given, the argument is used as a revision
  48 "                  number to display.  If not given an argument, it uses the
  49 "                  most recent version of the file on the current branch.
  50 "                  Additionally, if the current buffer is a VCSAnnotate buffer
  51 "                  already, the version number on the current line is used.
  52 "
  53 "                  If '!' is used, the view of the annotated buffer is split
  54 "                  so that the annotation is in a separate window from the
  55 "                  content, and each is highlighted separately.
  56 "
  57 " VCSBlame         Alias for 'VCSAnnotate'.
  58 "
  59 " VCSCommit[!]     Commits changes to the current file to source control.
  60 "
  61 "                  If called with arguments, the arguments are the log message.
  62 "
  63 "                  If '!' is used, an empty log message is committed.
  64 "
  65 "                  If called with no arguments, this is a two-step command.
  66 "                  The first step opens a buffer to accept a log message.
  67 "                  When that buffer is written, it is automatically closed and
  68 "                  the file is committed using the information from that log
  69 "                  message.  The commit can be abandoned if the log message
  70 "                  buffer is deleted or wiped before being written.
  71 "
  72 " VCSDelete        Deletes the current file and removes it from source control.
  73 "
  74 " VCSDiff          With no arguments, this displays the differences between
  75 "                  the current file and its parent version under source
  76 "                  control in a new scratch buffer.
  77 "
  78 "                  With one argument, the diff is performed on the
  79 "                  current file against the specified revision.
  80 "
  81 "                  With two arguments, the diff is performed between the
  82 "                  specified revisions of the current file.
  83 "
  84 "                  This command uses the 'VCSCommand{VCSType}DiffOpt' variable
  85 "                  to specify diff options.  If that variable does not exist,
  86 "                  a plugin-specific default is used.  If you wish to have no
  87 "                  options, then set it to the empty string.
  88 "
  89 " VCSGotoOriginal  Jumps to the source buffer if the current buffer is a VCS
  90 "                  scratch buffer.  If VCSGotoOriginal[!] is used, remove all
  91 "                  VCS scratch buffers associated with the original file.
  92 "
  93 " VCSInfo          Displays extended information about the current file in a
  94 "                  new scratch buffer.
  95 "
  96 " VCSLock          Locks the current file in order to prevent other users from
  97 "                  concurrently modifying it.  The exact semantics of this
  98 "                  command depend on the underlying VCS.
  99 "
 100 " VCSLog           Displays the version history of the current file in a new
 101 "                  scratch buffer.
 102 "
 103 " VCSRemove        Alias for 'VCSDelete'.
 104 "
 105 " VCSRevert        Replaces the modified version of the current file with the
 106 "                  most recent version from the repository.
 107 "
 108 " VCSReview        Displays a particular version of the current file in a new
 109 "                  scratch buffer.  If no argument is given, the most recent
 110 "                  version of the file on the current branch is retrieved.
 111 "
 112 " VCSStatus        Displays versioning information about the current file in a
 113 "                  new scratch buffer.
 114 "
 115 " VCSUnlock        Unlocks the current file in order to allow other users from
 116 "                  concurrently modifying it.  The exact semantics of this
 117 "                  command depend on the underlying VCS.
 118 "
 119 " VCSUpdate        Updates the current file with any relevant changes from the
 120 "                  repository.
 121 "
 122 " VCSVimDiff       Uses vimdiff to display differences between versions of the
 123 "                  current file.
 124 "
 125 "                  If no revision is specified, the most recent version of the
 126 "                  file on the current branch is used.  With one argument,
 127 "                  that argument is used as the revision as above.  With two
 128 "                  arguments, the differences between the two revisions is
 129 "                  displayed using vimdiff.
 130 "
 131 "                  With either zero or one argument, the original buffer is
 132 "                  used to perform the vimdiff.  When the scratch buffer is
 133 "                  closed, the original buffer will be returned to normal
 134 "                  mode.
 135 "
 136 "                  Once vimdiff mode is started using the above methods,
 137 "                  additional vimdiff buffers may be added by passing a single
 138 "                  version argument to the command.  There may be up to 4
 139 "                  vimdiff buffers total.
 140 "
 141 "                  Using the 2-argument form of the command resets the vimdiff
 142 "                  to only those 2 versions.  Additionally, invoking the
 143 "                  command on a different file will close the previous vimdiff
 144 "                  buffers.
 145 "
 146 " Mapping documentation: {{{2
 147 "
 148 " By default, a mapping is defined for each command.  User-provided mappings
 149 " can be used instead by mapping to <Plug>CommandName, for instance:
 150 "
 151 " nmap ,ca <Plug>VCSAdd
 152 "
 153 " The default mappings are as follow:
 154 "
 155 "   <Leader>ca VCSAdd
 156 "   <Leader>cn VCSAnnotate
 157 "   <Leader>cN VCSAnnotate!
 158 "   <Leader>cc VCSCommit
 159 "   <Leader>cD VCSDelete
 160 "   <Leader>cd VCSDiff
 161 "   <Leader>cg VCSGotoOriginal
 162 "   <Leader>cG VCSGotoOriginal!
 163 "   <Leader>ci VCSInfo
 164 "   <Leader>cl VCSLog
 165 "   <Leader>cL VCSLock
 166 "   <Leader>cr VCSReview
 167 "   <Leader>cs VCSStatus
 168 "   <Leader>cu VCSUpdate
 169 "   <Leader>cU VCSUnlock
 170 "   <Leader>cv VCSVimDiff
 171 "
 172 " Options documentation: {{{2
 173 "
 174 " Several variables are checked by the script to determine behavior as follow:
 175 "
 176 " VCSCommandCommitOnWrite
 177 "   This variable, if set to a non-zero value, causes the pending commit to
 178 "   take place immediately as soon as the log message buffer is written.  If
 179 "   set to zero, only the VCSCommit mapping will cause the pending commit to
 180 "   occur.  If not set, it defaults to 1.
 181 "
 182 " VCSCommandDeleteOnHide
 183 "   This variable, if set to a non-zero value, causes the temporary VCS result
 184 "   buffers to automatically delete themselves when hidden.
 185 "
 186 " VCSCommand{VCSType}DiffOpt
 187 "   This variable, if set, determines the options passed to the diff command
 188 "   of the underlying VCS.  Each VCS plugin defines a default value.
 189 "
 190 " VCSCommandDiffSplit
 191 "   This variable overrides the VCSCommandSplit variable, but only for buffers
 192 "   created with VCSVimDiff.
 193 "
 194 " VCSCommandDisableAll
 195 "   This variable, if set, prevents the plugin or any extensions from loading
 196 "   at all.  This is useful when a single runtime distribution is used on
 197 "   multiple systems with varying versions.
 198 "
 199 " VCSCommandDisableMappings
 200 "   This variable, if set to a non-zero value, prevents the default command
 201 "   mappings from being set.
 202 "
 203 " VCSCommandDisableExtensionMappings
 204 "   This variable, if set to a non-zero value, prevents the default command
 205 "   mappings from being set for commands specific to an individual VCS.
 206 "
 207 " VCSCommandEdit
 208 "   This variable controls whether to split the current window to display a
 209 "   scratch buffer ('split'), or to display it in the current buffer ('edit').
 210 "   If not set, it defaults to 'split'.
 211 "
 212 " VCSCommandEnableBufferSetup
 213 "   This variable, if set to a non-zero value, activates VCS buffer management
 214 "   mode.  This mode means that the buffer variable 'VCSRevision' is set if
 215 "   the file is VCS-controlled.  This is useful for displaying version
 216 "   information in the status bar.  Additional options may be set by
 217 "   individual VCS plugins.
 218 "
 219 " VCSCommandMappings
 220 "   This variable, if set, overrides the default mappings used for shortcuts.
 221 "   It should be a List of 2-element Lists, each containing a shortcut and
 222 "   function name pair.
 223 "
 224 " VCSCommandMapPrefix
 225 "   This variable, if set, overrides the default mapping prefix ('<Leader>c').
 226 "   This allows customization of the mapping space used by the vcscommand
 227 "   shortcuts.
 228 "
 229 " VCSCommandResultBufferNameExtension
 230 "   This variable, if set to a non-blank value, is appended to the name of the
 231 "   VCS command output buffers.  For example, '.vcs'.  Using this option may
 232 "   help avoid problems caused by autocommands dependent on file extension.
 233 "
 234 " VCSCommandResultBufferNameFunction
 235 "   This variable, if set, specifies a custom function for naming VCS command
 236 "   output buffers.  This function will be passed the following arguments:
 237 "
 238 "   command - name of the VCS command being executed (such as 'Log' or
 239 "   'Diff').
 240 "
 241 "   originalBuffer - buffer number of the source file.
 242 "
 243 "   vcsType - type of VCS controlling this file (such as 'CVS' or 'SVN').
 244 "
 245 "   statusText - extra text associated with the VCS action (such as version
 246 "   numbers).
 247 "
 248 " VCSCommandSplit
 249 "   This variable controls the orientation of the various window splits that
 250 "   may occur (such as with VCSVimDiff, when using a VCS command on a VCS
 251 "   command buffer, or when the 'VCSCommandEdit' variable is set to 'split'.
 252 "   If set to 'horizontal', the resulting windows will be on stacked on top of
 253 "   one another.  If set to 'vertical', the resulting windows will be
 254 "   side-by-side.  If not set, it defaults to 'horizontal' for all but
 255 "   VCSVimDiff windows.
 256 "
 257 " VCSCommandVCSTypeOverride
 258 "   This variable allows the VCS type detection to be overridden on a
 259 "   path-by-path basis.  The value of this variable is expected to be a List
 260 "   of Lists.  Each high-level List item is a List containing two elements.
 261 "   The first element is a regular expression that will be matched against the
 262 "   full file name of a given buffer.  If it matches, the second element will
 263 "   be used as the VCS type.
 264 "
 265 " Event documentation {{{2
 266 "   For additional customization, VCSCommand.vim uses User event autocommand
 267 "   hooks.  Each event is in the VCSCommand group, and different patterns
 268 "   match the various hooks.
 269 "
 270 "   For instance, the following could be added to the vimrc to provide a 'q'
 271 "   mapping to quit a VCS scratch buffer:
 272 "
 273 "   augroup VCSCommand
 274 "     au VCSCommand User VCSBufferCreated silent! nmap <unique> <buffer> q :bwipeout<cr>
 275 "   augroup END
 276 "
 277 "   The following hooks are available:
 278 "
 279 "   VCSBufferCreated           This event is fired just after a VCS command
 280 "                              output buffer is created.  It is executed
 281 "                              within the context of the new buffer.
 282 "
 283 "   VCSBufferSetup             This event is fired just after VCS buffer setup
 284 "                              occurs, if enabled.
 285 "
 286 "   VCSPluginInit              This event is fired when the VCSCommand plugin
 287 "                              first loads.
 288 "
 289 "   VCSPluginFinish            This event is fired just after the VCSCommand
 290 "                              plugin loads.
 291 "
 292 "   VCSVimDiffFinish           This event is fired just after the VCSVimDiff
 293 "                              command executes to allow customization of,
 294 "                              for instance, window placement and focus.
 295 "
 296 " Section: Plugin header {{{1
 297
 298 " loaded_VCSCommand is set to 1 when the initialization begins, and 2 when it
 299 " completes.  This allows various actions to only be taken by functions after
 300 " system initialization.
 301
 302 if exists('VCSCommandDisableAll')
 303         finish
 304 endif
 305
 306 if exists('loaded_VCSCommand')
 307         finish
 308 endif
 309 let loaded_VCSCommand = 1
 310
 311 if v:version < 700
 312         echohl WarningMsg|echomsg 'VCSCommand requires at least VIM 7.0'|echohl None
 313         finish
 314 endif
 315
 316 let s:save_cpo=&cpo
 317 set cpo&vim
 318
 319 " Section: Event group setup {{{1
 320
 321 augroup VCSCommand
 322 augroup END
 323
 324 augroup VCSCommandCommit
 325 augroup END
 326
 327 " Section: Plugin initialization {{{1
 328 silent do VCSCommand User VCSPluginInit
 329
 330 " Section: Constants declaration {{{1
 331
 332 let g:VCSCOMMAND_IDENTIFY_EXACT = 1
 333 let g:VCSCOMMAND_IDENTIFY_INEXACT = -1
 334
 335 " Section: Script variable initialization {{{1
 336
 337 " Hidden functions for use by extensions
 338 let s:VCSCommandUtility = {}
 339
 340 " plugin-specific information:  {vcs -> [script, {command -> function}, {key -> mapping}]}
 341 let s:plugins = {}
 342
 343 " temporary values of overridden configuration variables
 344 let s:optionOverrides = {}
 345
 346 " state flag used to vary behavior of certain automated actions
 347 let s:isEditFileRunning = 0
 348
 349 " commands needed to restore diff buffers to their original state
 350 unlet! s:vimDiffRestoreCmd
 351
 352 " original buffer currently reflected in vimdiff windows
 353 unlet! s:vimDiffSourceBuffer
 354
 355 "
 356 unlet! s:vimDiffScratchList
 357
 358 " Section: Utility functions {{{1
 359
 360 " Function: s:ReportError(mapping) {{{2
 361 " Displays the given error in a consistent faction.  This is intended to be
 362 " invoked from a catch statement.
 363
 364 function! s:ReportError(error)
 365         echohl WarningMsg|echomsg 'VCSCommand:  ' . a:error|echohl None
 366 endfunction
 367
 368 " Function s:VCSCommandUtility.system(...) {{{2
 369 " Replacement for system() function.  This version protects the quoting in the
 370 " command line on Windows systems.
 371
 372 function! s:VCSCommandUtility.system(...)
 373         if (has("win32") || has("win64")) && &sxq !~ '"'
 374                 let save_sxq = &sxq
 375                 set sxq=\"
 376         endif
 377         try
 378                 return call('system', a:000)
 379         finally
 380                 if exists("save_sxq")
 381                         let &sxq = save_sxq
 382                 endif
 383         endtry
 384 endfunction
 385
 386 " Function: s:CreateMapping(shortcut, expansion, display) {{{2
 387 " Creates the given mapping by prepending the contents of
 388 " 'VCSCommandMapPrefix' (by default '<Leader>c') to the given shortcut and
 389 " mapping it to the given plugin function.  If a mapping exists for the
 390 " specified shortcut + prefix, emit an error but continue.  If a mapping
 391 " exists for the specified function, do nothing.
 392
 393 function! s:CreateMapping(shortcut, expansion, display)
 394         let lhs = VCSCommandGetOption('VCSCommandMapPrefix', '<Leader>c') . a:shortcut
 395         if !hasmapto(a:expansion)
 396                 try
 397                         execute 'nmap <silent> <unique>' lhs a:expansion
 398                 catch /^Vim(.*):E227:/
 399                         if(&verbose != 0)
 400                                 echohl WarningMsg|echomsg 'VCSCommand:  mapping ''' . lhs . ''' already exists, refusing to overwrite.  The mapping for ' . a:display . ' will not be available.'|echohl None
 401                         endif
 402                 endtry
 403         endif
 404 endfunction
 405
 406 " Function: s:ExecuteExtensionMapping(mapping) {{{2
 407 " Invokes the appropriate extension mapping depending on the type of the
 408 " current buffer.
 409
 410 function! s:ExecuteExtensionMapping(mapping)
 411         let buffer = bufnr('%')
 412         let vcsType = VCSCommandGetVCSType(buffer)
 413         if !has_key(s:plugins, vcsType)
 414                 throw 'Unknown VCS type:  ' . vcsType
 415         endif
 416         if !has_key(s:plugins[vcsType][2], a:mapping)
 417                 throw 'This extended mapping is not defined for ' . vcsType
 418         endif
 419         silent execute 'normal' ':' .  s:plugins[vcsType][2][a:mapping] . "\<CR>"
 420 endfunction
 421
 422 " Function: s:ExecuteVCSCommand(command, argList) {{{2
 423 " Calls the indicated plugin-specific VCS command on the current buffer.
 424 " Returns: buffer number of resulting output scratch buffer, or -1 if an error
 425 " occurs.
 426
 427 function! s:ExecuteVCSCommand(command, argList)
 428         try
 429                 let buffer = bufnr('%')
 430
 431                 let vcsType = VCSCommandGetVCSType(buffer)
 432                 if !has_key(s:plugins, vcsType)
 433                         throw 'Unknown VCS type:  ' . vcsType
 434                 endif
 435
 436                 let originalBuffer = VCSCommandGetOriginalBuffer(buffer)
 437                 let bufferName = bufname(originalBuffer)
 438
 439                 " It is already known that the directory is under VCS control.  No further
 440                 " checks are needed.  Otherwise, perform some basic sanity checks to avoid
 441                 " VCS-specific error messages from confusing things.
 442                 if !isdirectory(bufferName)
 443                         if !filereadable(bufferName)
 444                                 throw 'No such file ' . bufferName
 445                         endif
 446                 endif
 447
 448                 let functionMap = s:plugins[vcsType][1]
 449                 if !has_key(functionMap, a:command)
 450                         throw 'Command ''' . a:command . ''' not implemented for ' . vcsType
 451                 endif
 452                 return functionMap[a:command](a:argList)
 453         catch
 454                 call s:ReportError(v:exception)
 455                 return -1
 456         endtry
 457 endfunction
 458
 459 " Function: s:GenerateResultBufferName(command, originalBuffer, vcsType, statusText) {{{2
 460 " Default method of generating the name for VCS result buffers.  This can be
 461 " overridden with the VCSResultBufferNameFunction variable.
 462
 463 function! s:GenerateResultBufferName(command, originalBuffer, vcsType, statusText)
 464         let fileName = bufname(a:originalBuffer)
 465         let bufferName = a:vcsType . ' ' . a:command
 466         if strlen(a:statusText) > 0
 467                 let bufferName .= ' ' . a:statusText
 468         endif
 469         let bufferName .= ' ' . fileName
 470         let counter = 0
 471         let versionedBufferName = bufferName
 472         while bufexists(versionedBufferName)
 473                 let counter += 1
 474                 let versionedBufferName = bufferName . ' (' . counter . ')'
 475         endwhile
 476         return versionedBufferName
 477 endfunction
 478
 479 " Function: s:GenerateResultBufferNameWithExtension(command, originalBuffer, vcsType, statusText) {{{2
 480 " Method of generating the name for VCS result buffers that uses the original
 481 " file name with the VCS type and command appended as extensions.
 482
 483 function! s:GenerateResultBufferNameWithExtension(command, originalBuffer, vcsType, statusText)
 484         let fileName = bufname(a:originalBuffer)
 485         let bufferName = a:vcsType . ' ' . a:command
 486         if strlen(a:statusText) > 0
 487                 let bufferName .= ' ' . a:statusText
 488         endif
 489         let bufferName .= ' ' . fileName . VCSCommandGetOption('VCSCommandResultBufferNameExtension', '.vcs')
 490         let counter = 0
 491         let versionedBufferName = bufferName
 492         while bufexists(versionedBufferName)
 493                 let counter += 1
 494                 let versionedBufferName = '(' . counter . ') ' . bufferName
 495         endwhile
 496         return versionedBufferName
 497 endfunction
 498
 499 " Function: s:EditFile(command, originalBuffer, statusText) {{{2
 500 " Creates a new buffer of the given name and associates it with the given
 501 " original buffer.
 502
 503 function! s:EditFile(command, originalBuffer, statusText)
 504         let vcsType = getbufvar(a:originalBuffer, 'VCSCommandVCSType')
 505
 506         " Protect against useless buffer set-up
 507         let s:isEditFileRunning += 1
 508         try
 509                 let editCommand = VCSCommandGetOption('VCSCommandEdit', 'split')
 510                 if editCommand == 'split'
 511                         if VCSCommandGetOption('VCSCommandSplit', 'horizontal') == 'horizontal'
 512                                 rightbelow split
 513                         else
 514                                 vert rightbelow split
 515                         endif
 516                 endif
 517
 518                 enew
 519
 520                 call s:SetupScratchBuffer(a:command, vcsType, a:originalBuffer, a:statusText)
 521
 522         finally
 523                 let s:isEditFileRunning -= 1
 524         endtry
 525 endfunction
 526
 527 " Function: s:SetupScratchBuffer(command, vcsType, originalBuffer, statusText) {{{2
 528 " Creates convenience buffer variables and the name of a vcscommand result
 529 " buffer.
 530
 531 function! s:SetupScratchBuffer(command, vcsType, originalBuffer, statusText)
 532         let nameExtension = VCSCommandGetOption('VCSCommandResultBufferNameExtension', '')
 533         if nameExtension == ''
 534                 let nameFunction = VCSCommandGetOption('VCSCommandResultBufferNameFunction', 's:GenerateResultBufferName')
 535         else
 536                 let nameFunction = VCSCommandGetOption('VCSCommandResultBufferNameFunction', 's:GenerateResultBufferNameWithExtension')
 537         endif
 538
 539         let name = call(nameFunction, [a:command, a:originalBuffer, a:vcsType, a:statusText])
 540
 541         let b:VCSCommandCommand = a:command
 542         let b:VCSCommandOriginalBuffer = a:originalBuffer
 543         let b:VCSCommandSourceFile = bufname(a:originalBuffer)
 544         let b:VCSCommandVCSType = a:vcsType
 545         if a:statusText != ''
 546                 let b:VCSCommandStatusText = a:statusText
 547         endif
 548
 549         setlocal buftype=nofile
 550         setlocal noswapfile
 551         let &filetype = tolower(a:vcsType . a:command)
 552
 553         if VCSCommandGetOption('VCSCommandDeleteOnHide', 0)
 554                 setlocal bufhidden=delete
 555         endif
 556         silent noautocmd file `=name`
 557 endfunction
 558
 559 " Function: s:SetupBuffer() {{{2
 560 " Attempts to set the b:VCSCommandBufferInfo variable
 561
 562 function! s:SetupBuffer()
 563         if (exists('b:VCSCommandBufferSetup') && b:VCSCommandBufferSetup)
 564                 " This buffer is already set up.
 565                 return
 566         endif
 567
 568         if !isdirectory(@%) && (strlen(&buftype) > 0 || !filereadable(@%))
 569                 " No special status for special buffers other than directory buffers.
 570                 return
 571         endif
 572
 573         if !VCSCommandGetOption('VCSCommandEnableBufferSetup', 0) || s:isEditFileRunning > 0
 574                 unlet! b:VCSCommandBufferSetup
 575                 return
 576         endif
 577
 578         try
 579                 let vcsType = VCSCommandGetVCSType(bufnr('%'))
 580                 let b:VCSCommandBufferInfo = s:plugins[vcsType][1].GetBufferInfo()
 581                 silent do VCSCommand User VCSBufferSetup
 582         catch /No suitable plugin/
 583                 " This is not a VCS-controlled file.
 584                 let b:VCSCommandBufferInfo = []
 585         endtry
 586
 587         let b:VCSCommandBufferSetup = 1
 588 endfunction
 589
 590 " Function: s:MarkOrigBufferForSetup(buffer) {{{2
 591 " Resets the buffer setup state of the original buffer for a given VCS scratch
 592 " buffer.
 593 " Returns:  The VCS buffer number in a passthrough mode.
 594
 595 function! s:MarkOrigBufferForSetup(buffer)
 596         checktime
 597         if a:buffer > 0
 598                 let origBuffer = VCSCommandGetOriginalBuffer(a:buffer)
 599                 " This should never not work, but I'm paranoid
 600                 if origBuffer != a:buffer
 601                         call setbufvar(origBuffer, 'VCSCommandBufferSetup', 0)
 602                 endif
 603         endif
 604         return a:buffer
 605 endfunction
 606
 607 " Function: s:OverrideOption(option, [value]) {{{2
 608 " Provides a temporary override for the given VCS option.  If no value is
 609 " passed, the override is disabled.
 610
 611 function! s:OverrideOption(option, ...)
 612         if a:0 == 0
 613                 call remove(s:optionOverrides[a:option], -1)
 614         else
 615                 if !has_key(s:optionOverrides, a:option)
 616                         let s:optionOverrides[a:option] = []
 617                 endif
 618                 call add(s:optionOverrides[a:option], a:1)
 619         endif
 620 endfunction
 621
 622 " Function: s:WipeoutCommandBuffers() {{{2
 623 " Clears all current VCS output buffers of the specified type for a given source.
 624
 625 function! s:WipeoutCommandBuffers(originalBuffer, VCSCommand)
 626         let buffer = 1
 627         while buffer <= bufnr('$')
 628                 if getbufvar(buffer, 'VCSCommandOriginalBuffer') == a:originalBuffer
 629                         if getbufvar(buffer, 'VCSCommandCommand') == a:VCSCommand
 630                                 execute 'bw' buffer
 631                         endif
 632                 endif
 633                 let buffer = buffer + 1
 634         endwhile
 635 endfunction
 636
 637 " Function: s:VimDiffRestore(vimDiffBuff) {{{2
 638 " Checks whether the given buffer is one whose deletion should trigger
 639 " restoration of an original buffer after it was diffed.  If so, it executes
 640 " the appropriate setting command stored with that original buffer.
 641
 642 function! s:VimDiffRestore(vimDiffBuff)
 643         let s:isEditFileRunning += 1
 644         try
 645                 if exists('s:vimDiffSourceBuffer')
 646                         if a:vimDiffBuff == s:vimDiffSourceBuffer
 647                                 " Original file is being removed.
 648                                 unlet! s:vimDiffSourceBuffer
 649                                 unlet! s:vimDiffRestoreCmd
 650                                 unlet! s:vimDiffScratchList
 651                         else
 652                                 let index = index(s:vimDiffScratchList, a:vimDiffBuff)
 653                                 if index >= 0
 654                                         call remove(s:vimDiffScratchList, index)
 655                                         if len(s:vimDiffScratchList) == 0
 656                                                 if exists('s:vimDiffRestoreCmd')
 657                                                         " All scratch buffers are gone, reset the original.
 658                                                         " Only restore if the source buffer is still in Diff mode
 659
 660                                                         let sourceWinNR = bufwinnr(s:vimDiffSourceBuffer)
 661                                                         if sourceWinNR != -1
 662                                                                 " The buffer is visible in at least one window
 663                                                                 let currentWinNR = winnr()
 664                                                                 while winbufnr(sourceWinNR) != -1
 665                                                                         if winbufnr(sourceWinNR) == s:vimDiffSourceBuffer
 666                                                                                 execute sourceWinNR . 'wincmd w'
 667                                                                                 if getwinvar(0, '&diff')
 668                                                                                         execute s:vimDiffRestoreCmd
 669                                                                                 endif
 670                                                                         endif
 671                                                                         let sourceWinNR = sourceWinNR + 1
 672                                                                 endwhile
 673                                                                 execute currentWinNR . 'wincmd w'
 674                                                         else
 675                                                                 " The buffer is hidden.  It must be visible in order to set the
 676                                                                 " diff option.
 677                                                                 let currentBufNR = bufnr('')
 678                                                                 execute 'hide buffer' s:vimDiffSourceBuffer
 679                                                                 if getwinvar(0, '&diff')
 680                                                                         execute s:vimDiffRestoreCmd
 681                                                                 endif
 682                                                                 execute 'hide buffer' currentBufNR
 683                                                         endif
 684
 685                                                         unlet s:vimDiffRestoreCmd
 686                                                 endif
 687                                                 " All buffers are gone.
 688                                                 unlet s:vimDiffSourceBuffer
 689                                                 unlet s:vimDiffScratchList
 690                                         endif
 691                                 endif
 692                         endif
 693                 endif
 694         finally
 695                 let s:isEditFileRunning -= 1
 696         endtry
 697 endfunction
 698
 699 " Section: Generic VCS command functions {{{1
 700
 701 " Function: s:VCSAnnotate(...) {{{2
 702 function! s:VCSAnnotate(bang, ...)
 703         try
 704                 let line = line('.')
 705                 let currentBuffer = bufnr('%')
 706                 let originalBuffer = VCSCommandGetOriginalBuffer(currentBuffer)
 707
 708                 let annotateBuffer = s:ExecuteVCSCommand('Annotate', a:000)
 709                 if annotateBuffer == -1
 710                         return -1
 711                 endif
 712                 if a:bang == '!' && VCSCommandGetOption('VCSCommandDisableSplitAnnotate', 0) == 0
 713                         let vcsType = VCSCommandGetVCSType(annotateBuffer)
 714                         let functionMap = s:plugins[vcsType][1]
 715                         let splitRegex = ''
 716                         if has_key(s:plugins[vcsType][1], 'AnnotateSplitRegex')
 717                                 let splitRegex = s:plugins[vcsType][1]['AnnotateSplitRegex']
 718                         endif
 719                         let splitRegex = VCSCommandGetOption('VCSCommand' . vcsType . 'AnnotateSplitRegex', splitRegex)
 720                         if splitRegex == ''
 721                                 return annotateBuffer
 722                         endif
 723                         let originalFileType = getbufvar(originalBuffer, '&ft')
 724                         let annotateFileType = getbufvar(annotateBuffer, '&ft')
 725                         execute "normal 0zR\<c-v>G/" . splitRegex . "/e\<cr>d"
 726                         call setbufvar('%', '&filetype', getbufvar(originalBuffer, '&filetype'))
 727                         set scrollbind
 728                         leftabove vert new
 729                         normal 0P
 730                         execute "normal" . col('$') . "\<c-w>|"
 731                         call s:SetupScratchBuffer('annotate', vcsType, originalBuffer, 'header')
 732                         wincmd l
 733                 endif
 734
 735                 if currentBuffer == originalBuffer
 736                         " Starting from the original source buffer, so the
 737                         " current line is relevant.
 738                         if a:0 == 0
 739                                 " No argument list means that we're annotating
 740                                 " the current version, so jumping to the same
 741                                 " line is the expected action.
 742                                 execute "normal" line . 'G'
 743                                 if has('folding')
 744                                         " The execution of the buffer created autocommand
 745                                         " re-folds the buffer.  Display the current line
 746                                         " unfolded.
 747                                         normal zv
 748                                 endif
 749                         endif
 750                 endif
 751
 752                 return annotateBuffer
 753         catch
 754                 call s:ReportError(v:exception)
 755                 return -1
 756         endtry
 757 endfunction
 758
 759 " Function: s:VCSCommit() {{{2
 760 function! s:VCSCommit(bang, message)
 761         try
 762                 let vcsType = VCSCommandGetVCSType(bufnr('%'))
 763                 if !has_key(s:plugins, vcsType)
 764                         throw 'Unknown VCS type:  ' . vcsType
 765                 endif
 766
 767                 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 768
 769                 " Handle the commit message being specified.  If a message is supplied, it
 770                 " is used; if bang is supplied, an empty message is used; otherwise, the
 771                 " user is provided a buffer from which to edit the commit message.
 772
 773                 if strlen(a:message) > 0 || a:bang == '!'
 774                         return s:VCSFinishCommit([a:message], originalBuffer)
 775                 endif
 776
 777                 call s:EditFile('commitlog', originalBuffer, '')
 778                 setlocal ft=vcscommit
 779
 780                 " Create a commit mapping.
 781
 782                 nnoremap <silent> <buffer> <Plug>VCSCommit :call <SID>VCSFinishCommitWithBuffer()<CR>
 783
 784                 silent 0put ='VCS: ----------------------------------------------------------------------'
 785                 silent put ='VCS: Please enter log message.  Lines beginning with ''VCS:'' are removed automatically.'
 786                 silent put ='VCS: To finish the commit, Type <leader>cc (or your own <Plug>VCSCommit mapping)'
 787
 788                 if VCSCommandGetOption('VCSCommandCommitOnWrite', 1) == 1
 789                         setlocal buftype=acwrite
 790                         au VCSCommandCommit BufWriteCmd <buffer> call s:VCSFinishCommitWithBuffer()
 791                         silent put ='VCS: or write this buffer'
 792                 endif
 793
 794                 silent put ='VCS: ----------------------------------------------------------------------'
 795                 $
 796                 setlocal nomodified
 797                 silent do VCSCommand User VCSBufferCreated
 798         catch
 799                 call s:ReportError(v:exception)
 800                 return -1
 801         endtry
 802 endfunction
 803
 804 " Function: s:VCSFinishCommitWithBuffer() {{{2
 805 " Wrapper for s:VCSFinishCommit which is called only from a commit log buffer
 806 " which removes all lines starting with 'VCS:'.
 807
 808 function! s:VCSFinishCommitWithBuffer()
 809         setlocal nomodified
 810         let currentBuffer = bufnr('%')
 811         let logMessageList = getbufline('%', 1, '$')
 812         call filter(logMessageList, 'v:val !~ ''^\s*VCS:''')
 813         let resultBuffer = s:VCSFinishCommit(logMessageList, b:VCSCommandOriginalBuffer)
 814         if resultBuffer >= 0
 815                 execute 'bw' currentBuffer
 816         endif
 817         return resultBuffer
 818 endfunction
 819
 820 " Function: s:VCSFinishCommit(logMessageList, originalBuffer) {{{2
 821 function! s:VCSFinishCommit(logMessageList, originalBuffer)
 822         let messageFileName = tempname()
 823         call writefile(a:logMessageList, messageFileName)
 824         try
 825                 let resultBuffer = s:ExecuteVCSCommand('Commit', [messageFileName])
 826                 if resultBuffer < 0
 827                         return resultBuffer
 828                 endif
 829                 return s:MarkOrigBufferForSetup(resultBuffer)
 830         finally
 831                 call delete(messageFileName)
 832         endtry
 833 endfunction
 834
 835 " Function: s:VCSGotoOriginal(bang) {{{2
 836 function! s:VCSGotoOriginal(bang)
 837         let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 838         if originalBuffer > 0
 839                 let origWinNR = bufwinnr(originalBuffer)
 840                 if origWinNR == -1
 841                         execute 'buffer' originalBuffer
 842                 else
 843                         execute origWinNR . 'wincmd w'
 844                 endif
 845                 if a:bang == '!'
 846                         let buffnr = 1
 847                         let buffmaxnr = bufnr('$')
 848                         while buffnr <= buffmaxnr
 849                                 if getbufvar(buffnr, 'VCSCommandOriginalBuffer') == originalBuffer
 850                                         execute 'bw' buffnr
 851                                 endif
 852                                 let buffnr = buffnr + 1
 853                         endwhile
 854                 endif
 855         endif
 856 endfunction
 857
 858 function! s:VCSDiff(...)  "{{{2
 859         let resultBuffer = s:ExecuteVCSCommand('Diff', a:000)
 860         if resultBuffer > 0
 861                 let &filetype = 'diff'
 862         elseif resultBuffer == 0
 863                 echomsg 'No differences found'
 864         endif
 865         return resultBuffer
 866 endfunction
 867
 868 function! s:VCSReview(...)  "{{{2
 869         let resultBuffer = s:ExecuteVCSCommand('Review', a:000)
 870         if resultBuffer > 0
 871                 let &filetype = getbufvar(b:VCSCommandOriginalBuffer, '&filetype')
 872         endif
 873         return resultBuffer
 874 endfunction
 875
 876 " Function: s:VCSVimDiff(...) {{{2
 877 function! s:VCSVimDiff(...)
 878         try
 879                 let vcsType = VCSCommandGetVCSType(bufnr('%'))
 880                 if !has_key(s:plugins, vcsType)
 881                         throw 'Unknown VCS type:  ' . vcsType
 882                 endif
 883                 let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
 884                 let s:isEditFileRunning = s:isEditFileRunning + 1
 885                 try
 886                         " If there's already a VimDiff'ed window, restore it.
 887                         " There may only be one VCSVimDiff original window at a time.
 888
 889                         if exists('s:vimDiffSourceBuffer') && s:vimDiffSourceBuffer != originalBuffer
 890                                 " Clear the existing vimdiff setup by removing the result buffers.
 891                                 call s:WipeoutCommandBuffers(s:vimDiffSourceBuffer, 'vimdiff')
 892                         endif
 893
 894                         let orientation = &diffopt =~ 'horizontal' ? 'horizontal' : 'vertical'
 895                         let orientation = VCSCommandGetOption('VCSCommandSplit', orientation)
 896                         let orientation = VCSCommandGetOption('VCSCommandDiffSplit', orientation)
 897
 898                         " Split and diff
 899                         if(a:0 == 2)
 900                                 " Reset the vimdiff system, as 2 explicit versions were provided.
 901                                 if exists('s:vimDiffSourceBuffer')
 902                                         call s:WipeoutCommandBuffers(s:vimDiffSourceBuffer, 'vimdiff')
 903                                 endif
 904                                 let resultBuffer = s:VCSReview(a:1)
 905                                 if resultBuffer < 0
 906                                         echomsg 'Can''t open revision ' . a:1
 907                                         return resultBuffer
 908                                 endif
 909                                 let b:VCSCommandCommand = 'vimdiff'
 910                                 diffthis
 911                                 let s:vimDiffScratchList = [resultBuffer]
 912                                 " If no split method is defined, cheat, and set it to vertical.
 913                                 try
 914                                         call s:OverrideOption('VCSCommandSplit', orientation)
 915                                         let resultBuffer = s:VCSReview(a:2)
 916                                 finally
 917                                         call s:OverrideOption('VCSCommandSplit')
 918                                 endtry
 919                                 if resultBuffer < 0
 920                                         echomsg 'Can''t open revision ' . a:1
 921                                         return resultBuffer
 922                                 endif
 923                                 let b:VCSCommandCommand = 'vimdiff'
 924                                 diffthis
 925                                 let s:vimDiffScratchList += [resultBuffer]
 926                         else
 927                                 " Add new buffer
 928                                 call s:OverrideOption('VCSCommandEdit', 'split')
 929                                 try
 930                                         " Force splitting behavior, otherwise why use vimdiff?
 931                                         call s:OverrideOption('VCSCommandSplit', orientation)
 932                                         try
 933                                                 if(a:0 == 0)
 934                                                         let resultBuffer = s:VCSReview()
 935                                                 else
 936                                                         let resultBuffer = s:VCSReview(a:1)
 937                                                 endif
 938                                         finally
 939                                                 call s:OverrideOption('VCSCommandSplit')
 940                                         endtry
 941                                 finally
 942                                         call s:OverrideOption('VCSCommandEdit')
 943                                 endtry
 944                                 if resultBuffer < 0
 945                                         echomsg 'Can''t open current revision'
 946                                         return resultBuffer
 947                                 endif
 948                                 let b:VCSCommandCommand = 'vimdiff'
 949                                 diffthis
 950
 951                                 if !exists('s:vimDiffSourceBuffer')
 952                                         " New instance of vimdiff.
 953                                         let s:vimDiffScratchList = [resultBuffer]
 954
 955                                         " This could have been invoked on a VCS result buffer, not the
 956                                         " original buffer.
 957                                         wincmd W
 958                                         execute 'buffer' originalBuffer
 959                                         " Store info for later original buffer restore
 960                                         let s:vimDiffRestoreCmd =
 961                                                                 \    'call setbufvar('.originalBuffer.', ''&diff'', '.getbufvar(originalBuffer, '&diff').')'
 962                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldcolumn'', '.getbufvar(originalBuffer, '&foldcolumn').')'
 963                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldenable'', '.getbufvar(originalBuffer, '&foldenable').')'
 964                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldmethod'', '''.getbufvar(originalBuffer, '&foldmethod').''')'
 965                                                                 \ . '|call setbufvar('.originalBuffer.', ''&foldlevel'', '''.getbufvar(originalBuffer, '&foldlevel').''')'
 966                                                                 \ . '|call setbufvar('.originalBuffer.', ''&scrollbind'', '.getbufvar(originalBuffer, '&scrollbind').')'
 967                                                                 \ . '|call setbufvar('.originalBuffer.', ''&wrap'', '.getbufvar(originalBuffer, '&wrap').')'
 968                                                                 \ . '|if &foldmethod==''manual''|execute ''normal zE''|endif'
 969                                         diffthis
 970                                         wincmd w
 971                                 else
 972                                         " Adding a window to an existing vimdiff
 973                                         let s:vimDiffScratchList += [resultBuffer]
 974                                 endif
 975                         endif
 976
 977                         let s:vimDiffSourceBuffer = originalBuffer
 978
 979                         " Avoid executing the modeline in the current buffer after the autocommand.
 980
 981                         let currentBuffer = bufnr('%')
 982                         let saveModeline = getbufvar(currentBuffer, '&modeline')
 983                         try
 984                                 call setbufvar(currentBuffer, '&modeline', 0)
 985                                 silent do VCSCommand User VCSVimDiffFinish
 986                         finally
 987                                 call setbufvar(currentBuffer, '&modeline', saveModeline)
 988                         endtry
 989                         return resultBuffer
 990                 finally
 991                         let s:isEditFileRunning = s:isEditFileRunning - 1
 992                 endtry
 993         catch
 994                 call s:ReportError(v:exception)
 995                 return -1
 996         endtry
 997 endfunction
 998
 999 " Section: Public functions {{{1
1000
1001 " Function: VCSCommandGetVCSType() {{{2
1002 " Sets the b:VCSCommandVCSType variable in the given buffer to the
1003 " appropriate source control system name.
1004 "
1005 " This uses the Identify extension function to test the buffer.  If the
1006 " Identify function returns VCSCOMMAND_IDENTIFY_EXACT, the match is considered
1007 " exact.  If the Identify function returns VCSCOMMAND_IDENTIFY_INEXACT, the
1008 " match is considered inexact, and is only applied if no exact match is found.
1009 " Multiple inexact matches is currently considered an error.
1010
1011 function! VCSCommandGetVCSType(buffer)
1012         let vcsType = getbufvar(a:buffer, 'VCSCommandVCSType')
1013         if strlen(vcsType) > 0
1014                 return vcsType
1015         endif
1016         if exists("g:VCSCommandVCSTypeOverride")
1017                 let fullpath = fnamemodify(bufname(a:buffer), ':p')
1018                 for [path, vcsType] in g:VCSCommandVCSTypeOverride
1019                         if match(fullpath, path) > -1
1020                                 call setbufvar(a:buffer, 'VCSCommandVCSType', vcsType)
1021                                 return vcsType
1022                         endif
1023                 endfor
1024         endif
1025         let matches = []
1026         for vcsType in keys(s:plugins)
1027                 let identified = s:plugins[vcsType][1].Identify(a:buffer)
1028                 if identified
1029                         if identified == g:VCSCOMMAND_IDENTIFY_EXACT
1030                                 let matches = [vcsType]
1031                                 break
1032                         else
1033                                 let matches += [vcsType]
1034                         endif
1035                 endif
1036         endfor
1037         if len(matches) == 1
1038                 call setbufvar(a:buffer, 'VCSCommandVCSType', matches[0])
1039                 return matches[0]
1040         elseif len(matches) == 0
1041                 throw 'No suitable plugin'
1042         else
1043                 throw 'Too many matching VCS:  ' . join(matches)
1044         endif
1045 endfunction
1046
1047 " Function: VCSCommandChdir(directory) {{{2
1048 " Changes the current directory, respecting :lcd changes.
1049
1050 function! VCSCommandChdir(directory)
1051         let command = 'cd'
1052         if exists("*haslocaldir") && haslocaldir()
1053                 let command = 'lcd'
1054         endif
1055         execute command escape(a:directory, ' ')
1056 endfunction
1057
1058 " Function: VCSCommandChangeToCurrentFileDir() {{{2
1059 " Go to the directory in which the given file is located.
1060
1061 function! VCSCommandChangeToCurrentFileDir(fileName)
1062         let oldCwd = getcwd()
1063         let newCwd = fnamemodify(resolve(a:fileName), ':p:h')
1064         if strlen(newCwd) > 0
1065                 call VCSCommandChdir(newCwd)
1066         endif
1067         return oldCwd
1068 endfunction
1069
1070 " Function: VCSCommandGetOriginalBuffer(vcsBuffer) {{{2
1071 " Attempts to locate the original file to which VCS operations were applied
1072 " for a given buffer.
1073
1074 function! VCSCommandGetOriginalBuffer(vcsBuffer)
1075         let origBuffer = getbufvar(a:vcsBuffer, 'VCSCommandOriginalBuffer')
1076         if origBuffer
1077                 if bufexists(origBuffer)
1078                         return origBuffer
1079                 else
1080                         " Original buffer no longer exists.
1081                         throw 'Original buffer for this VCS buffer no longer exists.'
1082                 endif
1083         else
1084                 " No original buffer
1085                 return a:vcsBuffer
1086         endif
1087 endfunction
1088
1089 " Function: VCSCommandRegisterModule(name, file, commandMap) {{{2
1090 " Allows VCS modules to register themselves.
1091
1092 function! VCSCommandRegisterModule(name, path, commandMap, mappingMap)
1093         let s:plugins[a:name] = [a:path, a:commandMap, a:mappingMap]
1094         if !empty(a:mappingMap)
1095                                 \ && !VCSCommandGetOption('VCSCommandDisableMappings', 0)
1096                                 \ && !VCSCommandGetOption('VCSCommandDisableExtensionMappings', 0)
1097                 for shortcut in keys(a:mappingMap)
1098                         let expansion = ":call <SID>ExecuteExtensionMapping('" . shortcut . "')<CR>"
1099                         call s:CreateMapping(shortcut, expansion, a:name . " extension mapping " . shortcut)
1100                 endfor
1101         endif
1102         return s:VCSCommandUtility
1103 endfunction
1104
1105 " Function: VCSCommandDoCommand(cmd, cmdName, statusText, [options]) {{{2
1106 " General skeleton for VCS function execution.  The given command is executed
1107 " after appending the current buffer name (or substituting it for
1108 " <VCSCOMMANDFILE>, if such a token is present).  The output is captured in a
1109 " new buffer.
1110 "
1111 " The optional 'options' Dictionary may contain the following options:
1112 "       allowNonZeroExit:  if non-zero, if the underlying VCS command has a
1113 "               non-zero exit status, the command is still considered
1114 "               successfuly.  This defaults to zero.
1115 " Returns: name of the new command buffer containing the command results
1116
1117 function! VCSCommandDoCommand(cmd, cmdName, statusText, options)
1118         let allowNonZeroExit = 0
1119         if has_key(a:options, 'allowNonZeroExit')
1120                 let allowNonZeroExit = a:options.allowNonZeroExit
1121         endif
1122
1123         let originalBuffer = VCSCommandGetOriginalBuffer(bufnr('%'))
1124         if originalBuffer == -1
1125                 throw 'Original buffer no longer exists, aborting.'
1126         endif
1127
1128         let path = resolve(bufname(originalBuffer))
1129
1130         " Work with netrw or other systems where a directory listing is displayed in
1131         " a buffer.
1132
1133         if isdirectory(path)
1134                 let fileName = '.'
1135         else
1136                 let fileName = fnamemodify(path, ':t')
1137         endif
1138
1139         if match(a:cmd, '<VCSCOMMANDFILE>') > 0
1140                 let fullCmd = substitute(a:cmd, '<VCSCOMMANDFILE>', fileName, 'g')
1141         else
1142                 let fullCmd = a:cmd . ' -- "' . fileName . '"'
1143         endif
1144
1145         " Change to the directory of the current buffer.  This is done for CVS, but
1146         " is left in for other systems as it does not affect them negatively.
1147
1148         let oldCwd = VCSCommandChangeToCurrentFileDir(path)
1149         try
1150                 let output = s:VCSCommandUtility.system(fullCmd)
1151         finally
1152                 call VCSCommandChdir(oldCwd)
1153         endtry
1154
1155         " HACK:  if line endings in the repository have been corrupted, the output
1156         " of the command will be confused.
1157         let output = substitute(output, "\r", '', 'g')
1158
1159         if v:shell_error && !allowNonZeroExit
1160                 if strlen(output) == 0
1161                         throw 'Version control command failed'
1162                 else
1163                         let output = substitute(output, '\n', '  ', 'g')
1164                         throw 'Version control command failed:  ' . output
1165                 endif
1166         endif
1167
1168         if strlen(output) == 0
1169                 " Handle case of no output.  In this case, it is important to check the
1170                 " file status, especially since cvs edit/unedit may change the attributes
1171                 " of the file with no visible output.
1172
1173                 checktime
1174                 return 0
1175         endif
1176
1177         call s:EditFile(a:cmdName, originalBuffer, a:statusText)
1178
1179         silent 0put=output
1180
1181         " The last command left a blank line at the end of the buffer.  If the
1182         " last line is folded (a side effect of the 'put') then the attempt to
1183         " remove the blank line will kill the last fold.
1184         "
1185         " This could be fixed by explicitly detecting whether the last line is
1186         " within a fold, but I prefer to simply unfold the result buffer altogether.
1187
1188         if has('folding')
1189                 normal zR
1190         endif
1191
1192         $d
1193         1
1194
1195         " Define the environment and execute user-defined hooks.
1196
1197         silent do VCSCommand User VCSBufferCreated
1198         return bufnr('%')
1199 endfunction
1200
1201 " Function: VCSCommandGetOption(name, default) {{{2
1202 " Grab a user-specified option to override the default provided.  Options are
1203 " searched in the window, buffer, then global spaces.
1204
1205 function! VCSCommandGetOption(name, default)
1206         if has_key(s:optionOverrides, a:name) && len(s:optionOverrides[a:name]) > 0
1207                 return s:optionOverrides[a:name][-1]
1208         elseif exists('w:' . a:name)
1209                 return w:{a:name}
1210         elseif exists('b:' . a:name)
1211                 return b:{a:name}
1212         elseif exists('g:' . a:name)
1213                 return g:{a:name}
1214         else
1215                 return a:default
1216         endif
1217 endfunction
1218
1219 " Function: VCSCommandDisableBufferSetup() {{{2
1220 " Global function for deactivating the buffer autovariables.
1221
1222 function! VCSCommandDisableBufferSetup()
1223         let g:VCSCommandEnableBufferSetup = 0
1224         silent! augroup! VCSCommandPlugin
1225 endfunction
1226
1227 " Function: VCSCommandEnableBufferSetup() {{{2
1228 " Global function for activating the buffer autovariables.
1229
1230 function! VCSCommandEnableBufferSetup()
1231         let g:VCSCommandEnableBufferSetup = 1
1232         augroup VCSCommandPlugin
1233                 au!
1234                 au BufEnter * call s:SetupBuffer()
1235         augroup END
1236
1237         " Only auto-load if the plugin is fully loaded.  This gives other plugins a
1238         " chance to run.
1239         if g:loaded_VCSCommand == 2
1240                 call s:SetupBuffer()
1241         endif
1242 endfunction
1243
1244 " Function: VCSCommandGetStatusLine() {{{2
1245 " Default (sample) status line entry for VCS-controlled files.  This is only
1246 " useful if VCS-managed buffer mode is on (see the VCSCommandEnableBufferSetup
1247 " variable for how to do this).
1248
1249 function! VCSCommandGetStatusLine()
1250         if exists('b:VCSCommandCommand')
1251                 " This is a result buffer.  Return nothing because the buffer name
1252                 " contains information already.
1253                 return ''
1254         endif
1255
1256         if exists('b:VCSCommandVCSType')
1257                                 \ && exists('g:VCSCommandEnableBufferSetup')
1258                                 \ && g:VCSCommandEnableBufferSetup
1259                                 \ && exists('b:VCSCommandBufferInfo')
1260                 return '[' . join(extend([b:VCSCommandVCSType], b:VCSCommandBufferInfo), ' ') . ']'
1261         else
1262                 return ''
1263         endif
1264 endfunction
1265
1266 " Section: Command definitions {{{1
1267 " Section: Primary commands {{{2
1268 com! -nargs=* VCSAdd call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Add', [<f-args>]))
1269 com! -nargs=* -bang VCSAnnotate call s:VCSAnnotate(<q-bang>, <f-args>)
1270 com! -nargs=* -bang VCSBlame call s:VCSAnnotate(<q-bang>, <f-args>)
1271 com! -nargs=? -bang VCSCommit call s:VCSCommit(<q-bang>, <q-args>)
1272 com! -nargs=* VCSDelete call s:ExecuteVCSCommand('Delete', [<f-args>])
1273 com! -nargs=* VCSDiff call s:VCSDiff(<f-args>)
1274 com! -nargs=0 -bang VCSGotoOriginal call s:VCSGotoOriginal(<q-bang>)
1275 com! -nargs=* VCSInfo call s:ExecuteVCSCommand('Info', [<f-args>])
1276 com! -nargs=* VCSLock call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Lock', [<f-args>]))
1277 com! -nargs=* VCSLog call s:ExecuteVCSCommand('Log', [<f-args>])
1278 com! -nargs=* VCSRemove call s:ExecuteVCSCommand('Delete', [<f-args>])
1279 com! -nargs=0 VCSRevert call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Revert', []))
1280 com! -nargs=? VCSReview call s:VCSReview(<f-args>)
1281 com! -nargs=* VCSStatus call s:ExecuteVCSCommand('Status', [<f-args>])
1282 com! -nargs=* VCSUnlock call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Unlock', [<f-args>]))
1283 com! -nargs=0 VCSUpdate call s:MarkOrigBufferForSetup(s:ExecuteVCSCommand('Update', []))
1284 com! -nargs=* VCSVimDiff call s:VCSVimDiff(<f-args>)
1285
1286 " Section: VCS buffer management commands {{{2
1287 com! VCSCommandDisableBufferSetup call VCSCommandDisableBufferSetup()
1288 com! VCSCommandEnableBufferSetup call VCSCommandEnableBufferSetup()
1289
1290 " Allow reloading VCSCommand.vim
1291 com! VCSReload let savedPlugins = s:plugins|let s:plugins = {}|aunmenu Plugin.VCS|unlet! g:loaded_VCSCommand|runtime plugin/vcscommand.vim|for plugin in values(savedPlugins)|execute 'source' plugin[0]|endfor|unlet savedPlugins
1292
1293 " Section: Plugin command mappings {{{1
1294 nnoremap <silent> <Plug>VCSAdd :VCSAdd<CR>
1295 nnoremap <silent> <Plug>VCSAnnotate :VCSAnnotate<CR>
1296 nnoremap <silent> <Plug>VCSCommit :VCSCommit<CR>
1297 nnoremap <silent> <Plug>VCSDelete :VCSDelete<CR>
1298 nnoremap <silent> <Plug>VCSDiff :VCSDiff<CR>
1299 nnoremap <silent> <Plug>VCSGotoOriginal :VCSGotoOriginal<CR>
1300 nnoremap <silent> <Plug>VCSClearAndGotoOriginal :VCSGotoOriginal!<CR>
1301 nnoremap <silent> <Plug>VCSInfo :VCSInfo<CR>
1302 nnoremap <silent> <Plug>VCSLock :VCSLock<CR>
1303 nnoremap <silent> <Plug>VCSLog :VCSLog<CR>
1304 nnoremap <silent> <Plug>VCSRevert :VCSRevert<CR>
1305 nnoremap <silent> <Plug>VCSReview :VCSReview<CR>
1306 nnoremap <silent> <Plug>VCSSplitAnnotate :VCSAnnotate!<CR>
1307 nnoremap <silent> <Plug>VCSStatus :VCSStatus<CR>
1308 nnoremap <silent> <Plug>VCSUnlock :VCSUnlock<CR>
1309 nnoremap <silent> <Plug>VCSUpdate :VCSUpdate<CR>
1310 nnoremap <silent> <Plug>VCSVimDiff :VCSVimDiff<CR>
1311
1312 " Section: Default mappings {{{1
1313
1314 let s:defaultMappings = [
1315                         \['a', 'VCSAdd'],
1316                         \['c', 'VCSCommit'],
1317                         \['D', 'VCSDelete'],
1318                         \['d', 'VCSDiff'],
1319                         \['G', 'VCSClearAndGotoOriginal'],
1320                         \['g', 'VCSGotoOriginal'],
1321                         \['i', 'VCSInfo'],
1322                         \['L', 'VCSLock'],
1323                         \['l', 'VCSLog'],
1324                         \['N', 'VCSSplitAnnotate'],
1325                         \['n', 'VCSAnnotate'],
1326                         \['q', 'VCSRevert'],
1327                         \['r', 'VCSReview'],
1328                         \['s', 'VCSStatus'],
1329                         \['U', 'VCSUnlock'],
1330                         \['u', 'VCSUpdate'],
1331                         \['v', 'VCSVimDiff'],
1332                         \]
1333
1334 if !VCSCommandGetOption('VCSCommandDisableMappings', 0)
1335         for [shortcut, vcsFunction] in VCSCommandGetOption('VCSCommandMappings', s:defaultMappings)
1336                 call s:CreateMapping(shortcut, '<Plug>' . vcsFunction, '''' . vcsFunction . '''')
1337         endfor
1338 endif
1339
1340 " Section: Menu items {{{1
1341 amenu <silent> &Plugin.VCS.&Add        <Plug>VCSAdd
1342 amenu <silent> &Plugin.VCS.A&nnotate   <Plug>VCSAnnotate
1343 amenu <silent> &Plugin.VCS.&Commit     <Plug>VCSCommit
1344 amenu <silent> &Plugin.VCS.Delete      <Plug>VCSDelete
1345 amenu <silent> &Plugin.VCS.&Diff       <Plug>VCSDiff
1346 amenu <silent> &Plugin.VCS.&Info       <Plug>VCSInfo
1347 amenu <silent> &Plugin.VCS.&Log        <Plug>VCSLog
1348 amenu <silent> &Plugin.VCS.Revert      <Plug>VCSRevert
1349 amenu <silent> &Plugin.VCS.&Review     <Plug>VCSReview
1350 amenu <silent> &Plugin.VCS.&Status     <Plug>VCSStatus
1351 amenu <silent> &Plugin.VCS.&Update     <Plug>VCSUpdate
1352 amenu <silent> &Plugin.VCS.&VimDiff    <Plug>VCSVimDiff
1353
1354 " Section: Autocommands to restore vimdiff state {{{1
1355 augroup VimDiffRestore
1356         au!
1357         au BufUnload * call s:VimDiffRestore(str2nr(expand('<abuf>')))
1358 augroup END
1359
1360 " Section: Optional activation of buffer management {{{1
1361
1362 if VCSCommandGetOption('VCSCommandEnableBufferSetup', 0)
1363         call VCSCommandEnableBufferSetup()
1364 endif
1365
1366 " Section: VIM shutdown hook {{{1
1367
1368 " Close all result buffers when VIM exits, to prevent them from being restored
1369 " via viminfo.
1370
1371 " Function: s:CloseAllResultBuffers() {{{2
1372 " Closes all vcscommand result buffers.
1373 function! s:CloseAllResultBuffers()
1374         " This avoids using bufdo as that may load buffers already loaded in another
1375         " vim process, resulting in an error.
1376         let buffnr = 1
1377         let buffmaxnr = bufnr('$')
1378         while buffnr <= buffmaxnr
1379                 if getbufvar(buffnr, 'VCSCommandOriginalBuffer') != ""
1380                         execute 'bw' buffnr
1381                 endif
1382                 let buffnr = buffnr + 1
1383         endwhile
1384 endfunction
1385
1386 augroup VCSCommandVIMShutdown
1387         au!
1388         au VimLeavePre * call s:CloseAllResultBuffers()
1389 augroup END
1390
1391 " Section: Plugin completion {{{1
1392
1393 let loaded_VCSCommand = 2
1394
1395 silent do VCSCommand User VCSPluginFinish
1396
1397 let &cpo = s:save_cpo