packaging/gentoo/tuxanci-9999.ebuild

   1 # Copyright 1999-2009 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Header: $
   4
   5 EAPI="2"
   6
   7 [[ ${PV} = 9999* ]] && GIT="git"
   8 EGIT_REPO_URI="git://repo.or.cz/tuxanci.git"
   9
  10 inherit games cmake-utils ${GIT}
  11
  12 DESCRIPTION="Tuxanci is first tux shooter inspired by game Bulanci."
  13 HOMEPAGE="http://www.tuxanci.org/"
  14 if [[ ${PV} = 9999* ]]; then
  15         SRC_URI=""
  16         KEYWORDS=""
  17 else
  18         SRC_URI="http://download.${PN}.org/${P}.tar.bz2"
  19         KEYWORDS="~amd64 ~x86"
  20 fi
  21 LICENSE="GPL-2"
  22
  23 SLOT="0"
  24 IUSE="debug dedicated +ipv6 nls opengl physfs +sound"
  25
  26 # >=x11-libs/cairo-1.8.8[X,svg]
  27 RDEPEND="
  28         !dedicated? (
  29                 >=media-libs/fontconfig-2.7.0
  30                 media-libs/libsdl[X,opengl?]
  31                 media-libs/sdl-ttf[X]
  32                 >=media-libs/sdl-image-1.2.10[png]
  33                 sound? (
  34                         >=media-libs/sdl-mixer-1.2.11[vorbis]
  35                 )
  36         )
  37         physfs? ( >=dev-games/physfs-2.0.0[zip] )
  38         !physfs? ( >=dev-libs/libzip-0.9 )"
  39 DEPEND="${RDEPEND}
  40         dev-util/pkgconfig
  41         nls? ( sys-devel/gettext )"
  42
  43 src_configure() {
  44         local mycmakeargs+=(
  45                 $(cmake-utils_use_with sound AUDIO)
  46                 $(cmake-utils_use_build dedicated SERVER)
  47                 $(cmake-utils_use_with nls)
  48                 $(cmake-utils_use_with opengl)
  49                 $(cmake-utils_use_with physfs)
  50                 $(cmake-utils_use_enable ipv6)
  51                 $(cmake-utils_use_enable debug)
  52         )
  53
  54         mycmakeargs+=(
  55                 "-DCMAKE_INSTALL_PREFIX=${GAMES_PREFIX}"
  56                 "-DCMAKE_INSTALL_ICONDIR=${GAMES_DATADIR_BASE}/pixmaps/"
  57                 "-DCMAKE_INSTALL_DESKTOPDIR=${GAMES_DATADIR_BASE}/applications/"
  58                 "-DCMAKE_DATA_PATH=${GAMES_DATADIR}"
  59                 "-DCMAKE_LOCALE_PATH=${GAMES_DATADIR_BASE}/locale/"
  60                 "-DCMAKE_DOC_PATH=${GAMES_DATADIR_BASE}/doc/${PF}"
  61                 "-DCMAKE_CONF_PATH=${GAMES_SYSCONFDIR}"
  62         )
  63
  64         cmake-utils_src_configure
  65 }
  66
  67 src_install() {
  68         cmake-utils_src_install
  69
  70         prepgamesdirs
  71 }