CMakeLists.txt

   1 project(tcc C)
   2 cmake_minimum_required(VERSION 2.6)
   3 enable_testing()
   4
   5 # Detect native platform
   6 if(WIN32)
   7   set(BUILD_SHARED_LIBS ON)
   8   if(CMAKE_SYSTEM_PROCESSOR STREQUAL "ARM")
   9     set(TCC_NATIVE_TARGET "WinCE")
  10   elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
  11     set(TCC_NATIVE_TARGET "Win64")
  12   else()
  13     set(TCC_NATIVE_TARGET "Win32")
  14   endif()
  15 else()
  16   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^arm")
  17     set(TCC_NATIVE_TARGET "ARM")
  18     if(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv5")
  19       set(TCC_ARM_VERSION_DEFAULT 5)
  20     elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv6")
  21       set(TCC_ARM_VERSION_DEFAULT 6)
  22     elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv7")
  23       set(TCC_ARM_VERSION_DEFAULT 7)
  24     else()
  25       set(TCC_ARM_VERSION_DEFAULT 4)
  26     endif()
  27   elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
  28     set(TCC_NATIVE_TARGET "x86_64")
  29   else()
  30     set(TCC_NATIVE_TARGET "i386")
  31   endif()
  32 endif()
  33
  34 if(WIN32)
  35   set(EXE_PATH ".")
  36   set(TCC_LIB_PATH lib)
  37   set(NATIVE_LIB_PATH)
  38   set(DOC_PATH doc)
  39 else()
  40   set(EXE_PATH bin)
  41   set(TCC_LIB_PATH lib/tcc)
  42   set(NATIVE_LIB_PATH lib)
  43   set(DOC_PATH share/doc/tcc)
  44 endif()
  45
  46 # Use two variables to keep CMake configuration variable names consistent
  47 set(TCC_BCHECK OFF CACHE BOOL "Enable bounds checking")
  48 set(CONFIG_TCC_BCHECK ${TCC_BCHECK})
  49
  50 set(TCC_BUILD_NATIVE ON CACHE BOOL "Build native compiler")
  51 set(TCC_BUILD_I386 OFF CACHE BOOL "Build i386 cross compiler")
  52 set(TCC_BUILD_X64 OFF CACHE BOOL "Build x86-64 cross compiler")
  53 set(TCC_BUILD_WIN32 OFF CACHE BOOL "Build Windows i386 cross compiler")
  54 set(TCC_BUILD_WIN64 OFF CACHE BOOL "Build Windows x86-64 cross compiler")
  55 set(TCC_BUILD_WINCE OFF CACHE BOOL "Build Windows CE cross compiler")
  56 set(TCC_BUILD_ARM_FPA OFF CACHE BOOL "Build arm-fpa cross compiler")
  57 set(TCC_BUILD_ARM_FPA_LD OFF CACHE BOOL "Build arm-fpa-ld cross compiler")
  58 set(TCC_BUILD_ARM_VFP OFF CACHE BOOL "Build arm-vfp cross compiler")
  59 set(TCC_BUILD_ARM_EABI OFF CACHE BOOL "Build ARM EABI cross compiler")
  60 set(TCC_BUILD_ARM_EABIHF OFF CACHE BOOL "Build ARM EABI hardware float cross compiler")
  61 set(TCC_BUILD_ARM OFF CACHE BOOL "Build ARM cross compiler")
  62 set(TCC_BUILD_C67 OFF CACHE BOOL "Build C67 cross compiler")
  63
  64 set(TCC_ARM_VERSION ${TCC_ARM_VERSION_DEFAULT} CACHE STRING "ARM target CPU version")
  65 set_property(CACHE TCC_ARM_VERSION PROPERTY STRINGS 4 5 6 7)
  66
  67 file(STRINGS "VERSION" TCC_VERSION)
  68 list(GET TCC_VERSION 0 TCC_VERSION)
  69 include_directories(${CMAKE_BINARY_DIR})
  70 configure_file(config.h.in config.h)
  71 configure_file(config.texi.in config.texi)
  72
  73 # Utility variables
  74 set(I386_SOURCES i386-gen.c i386-asm.c i386-asm.h i386-tok.h)
  75 set(X86_64_SOURCES x86_64-gen.c i386-asm.c x86_64-asm.h)
  76 set(ARM_SOURCES arm_gen.c)
  77
  78 set(LIBTCC1_I386_SOURCES lib/alloca86.S lib/alloca86-bt.S)
  79 set(LIBTCC1_WIN_SOURCES win32/lib/crt1.c win32/lib/wincrt1.c win32/lib/dllcrt1.c win32/lib/dllmain.c win32/lib/chkstk.S)
  80 if(NOT WIN32)
  81   set(LIBTCC1_I386_SOURCES ${LIBTCC1_I386_SOURCES} lib/bcheck.c)
  82 endif()
  83
  84 if(WIN32)
  85   add_executable(tiny_impdef win32/tools/tiny_impdef.c)
  86 endif()
  87 add_executable(tiny_libmaker_32 win32/tools/tiny_libmaker.c)
  88 set_target_properties(tiny_libmaker_32 PROPERTIES COMPILE_DEFINITIONS TCC_TARGET_I386)
  89 add_executable(tiny_libmaker_64 win32/tools/tiny_libmaker.c)
  90 set_target_properties(tiny_libmaker_64 PROPERTIES COMPILE_DEFINITIONS TCC_TARGET_X86_64)
  91
  92 macro(make_libtcc1 prefix xcc xar defs includes sources)
  93   set(libtcc1_prefix)
  94   if("${prefix}" STRGREATER "")
  95     set(libtcc1_prefix ${prefix}-)
  96   endif()
  97   set(libtcc1_flags -I${CMAKE_SOURCE_DIR}/include)
  98   foreach(i ${defs})
  99     set(libtcc1_flags ${libtcc1_flags} -D${i})
 100   endforeach()
 101   foreach(i ${includes})
 102     set(libtcc1_flags ${libtcc1_flags} -I${CMAKE_SOURCE_DIR}/${i})
 103   endforeach()
 104   set(libtcc1_objects)
 105   foreach(libtcc1_c lib/libtcc1.c ${sources})
 106     string(REGEX MATCH "[^/]+$" libtcc1_o ${libtcc1_c})
 107     string(REGEX MATCH "^[^.]+" libtcc1_o ${libtcc1_o})
 108     set(libtcc1_o ${libtcc1_prefix}${libtcc1_o}.o)
 109     add_custom_command(OUTPUT ${libtcc1_o}
 110       COMMAND ${xcc} ${libtcc1_flags} -c ${CMAKE_SOURCE_DIR}/${libtcc1_c} -o ${libtcc1_o}
 111       DEPENDS ${xcc} ${CMAKE_SOURCE_DIR}/${libtcc1_c}
 112     )
 113     list(APPEND libtcc1_objects ${libtcc1_o})
 114   endforeach()
 115   add_custom_command(OUTPUT ${libtcc1_prefix}libtcc1.a
 116     COMMAND ${xar} ${libtcc1_prefix}libtcc1.a ${libtcc1_objects}
 117     DEPENDS ${xar} ${libtcc1_objects}
 118   )
 119   add_custom_target(${libtcc1_prefix}libtcc1 ALL DEPENDS ${libtcc1_prefix}libtcc1.a)
 120   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${libtcc1_prefix}libtcc1.a
 121     DESTINATION ${TCC_LIB_PATH}/${prefix} RENAME libtcc1.a)
 122 endmacro()
 123
 124 macro(make_tcc native_name cross_name cross_enabled definitions tcc_sources libtcc_ar libtcc_sources libtcc_includes)
 125   if (xx${native_name} STREQUAL xx${TCC_NATIVE_TARGET})
 126     set(TCC_NATIVE_FLAGS)
 127     foreach(make_tcc_def ${definitions})
 128       set(TCC_NATIVE_FLAGS ${TCC_NATIVE_FLAGS} -D${make_tcc_def})
 129     endforeach()
 130
 131     if (TCC_BUILD_NATIVE)
 132       add_library(libtcc
 133         libtcc.c
 134         tccpp.c
 135         tccgen.c
 136         tccelf.c
 137         tccasm.c
 138         tccrun.c
 139         tcc.h
 140         libtcc.h
 141         tcctok.h
 142         ${tcc_sources}
 143       )
 144       set_target_properties(libtcc PROPERTIES OUTPUT_NAME tcc PREFIX lib LINK_FLAGS "-Wl,--output-def,libtcc.def")
 145       add_executable(tcc tcc.c)
 146       target_link_libraries(tcc libtcc)
 147       install(TARGETS tcc libtcc RUNTIME DESTINATION ${EXE_PATH} LIBRARY DESTINATION ${NATIVE_LIB_PATH})
 148       set_target_properties(tcc libtcc PROPERTIES COMPILE_DEFINITIONS "${definitions}")
 149
 150       if("${libtcc_sources}" STRGREATER "")
 151         make_libtcc1("" tcc "${libtcc_ar}" "${definitions}" "${libtcc_includes}" "${libtcc_sources}")
 152       endif()
 153     endif()
 154   endif()
 155
 156   if(${cross_enabled})
 157     add_executable(${cross_name}-tcc tcc.c)
 158     set_target_properties(${cross_name}-tcc PROPERTIES COMPILE_DEFINITIONS "ONE_SOURCE;${definitions}")
 159     install(TARGETS ${cross_name}-tcc RUNTIME DESTINATION ${EXE_PATH})
 160
 161     if("${libtcc_sources}" STRGREATER "")
 162       make_libtcc1(${cross_name} "${cross_name}-tcc" "${libtcc_ar}" "${definitions}" "${libtcc_includes}" "${libtcc_sources}")
 163     endif()
 164   endif()
 165 endmacro()
 166
 167 make_tcc("Win32" i386-win32 TCC_BUILD_WIN32
 168   "TCC_TARGET_I386;TCC_TARGET_PE"
 169   "${I386_SOURCES};tccpe.c"
 170   tiny_libmaker_32 "${LIBTCC1_I386_SOURCES};${LIBTCC1_WIN_SOURCES}" "win32/include;win32/include/winapi"
 171 )
 172 make_tcc("Win64" x86_64-win32 TCC_BUILD_WIN64
 173   "TCC_TARGET_X86_64;TCC_TARGET_PE"
 174   "${X86_64_SOURCES};tccpe.c"
 175   tiny_libmaker_64 "lib/alloca86_64.S;${LIBTCC1_WIN_SOURCES}" "win32/include;win32/include/winapi"
 176 )
 177 make_tcc("WinCE" arm-win32 TCC_BUILD_WINCE
 178   "TCC_TARGET_ARM;TCC_ARM_VERSION=${TCC_ARM_VERSION};TCC_TARGET_PE"
 179   "${ARM_SOURCES};tccpe.c"
 180   "" "" ""
 181 )
 182 make_tcc("i386" i386 TCC_BUILD_I386
 183   TCC_TARGET_I386
 184   "${I386_SOURCES}"
 185   tiny_libmaker_32 "${LIBTCC1_I386_SOURCES}" ""
 186 )
 187 make_tcc("x86_64" x86_64 TCC_BUILD_X64
 188   TCC_TARGET_X86_64
 189   "${X86_64_SOURCES}"
 190   tiny_libmaker_64 "lib/alloca86_64.S" ""
 191 )
 192 set(ARM_DEFINITIONS TCC_TARGET_ARM TCC_ARM_VERSION=${TCC_ARM_VERSION})
 193 make_tcc("ARM" arm TCC_BUILD_ARM
 194   "${ARM_DEFINITIONS};WITHOUT_LIBTCC"
 195   "${ARM_SOURCES}"
 196   "" "" ""
 197 )
 198 make_tcc("" arm-eabihf TCC_BUILD_ARM_EABIHF
 199   "${ARM_DEFINITIONS};TCC_ARM_EABI;TCC_ARM_HARDFLOAT"
 200   "${ARM_SOURCES}"
 201   "" "" ""
 202 )
 203 make_tcc("" arm-eabi TCC_BUILD_ARM_EABI
 204   "${ARM_DEFINITIONS};TCC_ARM_EABI"
 205   "${ARM_SOURCES}"
 206   "" "" ""
 207 )
 208 make_tcc("" arm-fpa TCC_BUILD_ARM_FPA
 209   "${ARM_DEFINITIONS}"
 210   "${ARM_SOURCES}"
 211   "" "" ""
 212 )
 213 make_tcc("" arm-fpa-ld TCC_BUILD_ARM_FPA_LD
 214   "${ARM_DEFINITIONS};LDOUBLE_SIZE=12"
 215   "${ARM_SOURCES}"
 216   "" "" ""
 217 )
 218 make_tcc("" arm-vfp TCC_BUILD_ARM_VFP
 219   "${ARM_DEFINITIONS};TCC_ARM_VFP"
 220   "${ARM_SOURCES}"
 221   "" "" ""
 222 )
 223 make_tcc("" c67 TCC_BUILD_C67
 224   TCC_TARGET_C67
 225   "c67-gen.c;tcccoff.c"
 226   "" "" ""
 227 )
 228
 229 add_subdirectory(tests)
 230
 231 find_program(MAKEINFO NAMES makeinfo PATHS C:/MinGW/MSYS/1.0/bin)
 232 if(MAKEINFO)
 233   add_custom_command(OUTPUT tcc-doc.html
 234     COMMAND ${MAKEINFO} --no-split --html -o tcc-doc.html ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 235     DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 236   )
 237   set(TCC_DOC_FILES tcc-doc.html)
 238   if(NOT WIN32)
 239     add_custom_command(OUTPUT tcc-doc.info
 240       COMMAND ${MAKEINFO} -o tcc-doc.info ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 241       DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 242     )
 243     set(TCC_DOC_FILES ${TCC_DOC_FILES} tcc-doc.info)
 244     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/tcc-doc.info DESTINATION share/info)
 245   endif()
 246   add_custom_target(tcc-doc ALL DEPENDS ${TCC_DOC_FILES})
 247   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/tcc-doc.html DESTINATION ${DOC_PATH})
 248 endif()
 249
 250 if(WIN32)
 251   file(GLOB WIN32_DEFS win32/lib/*.def)
 252   install(FILES ${WIN32_DEFS} DESTINATION lib)
 253   install(DIRECTORY include/ DESTINATION include)
 254   install(DIRECTORY win32/include/ DESTINATION include)
 255   install(DIRECTORY win32/examples/ DESTINATION examples)
 256   install(FILES win32/tcc-win32.txt DESTINATION doc)
 257   install(FILES ${CMAKE_BINARY_DIR}/libtcc.def DESTINATION libtcc)
 258   install(FILES ${CMAKE_BINARY_DIR}/libtcc.dll.a DESTINATION libtcc RENAME libtcc.a)
 259   install(FILES libtcc.h DESTINATION libtcc)
 260 else()
 261   install(FILES libtcc.h DESTINATION include)
 262   install(DIRECTORY include/ DESTINATION lib/tcc/include)
 263   install(DIRECTORY win32/include/ DESTINATION lib/tcc/win32/include)
 264   install(DIRECTORY include/ DESTINATION lib/tcc/win32/include)
 265 endif()
 266