CMakeLists.txt

   1 project(tcc C)
   2 cmake_minimum_required(VERSION 2.6)
   3 enable_testing()
   4
   5 # Detect native platform
   6 if(WIN32)
   7   set(BUILD_SHARED_LIBS ON)
   8   if(CMAKE_SYSTEM_PROCESSOR STREQUAL "ARM")
   9     set(TCC_NATIVE_TARGET "WinCE")
  10   elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
  11     set(TCC_NATIVE_TARGET "Win64")
  12   else()
  13     set(TCC_NATIVE_TARGET "Win32")
  14   endif()
  15 else()
  16   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^arm")
  17     set(TCC_NATIVE_TARGET "ARM")
  18     if(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv5")
  19       set(TCC_ARM_VERSION_DEFAULT 5)
  20     elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv6")
  21       set(TCC_ARM_VERSION_DEFAULT 6)
  22     elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv7")
  23       set(TCC_ARM_VERSION_DEFAULT 7)
  24     else()
  25       set(TCC_ARM_VERSION_DEFAULT 4)
  26     endif()
  27   elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
  28     set(TCC_NATIVE_TARGET "x86_64")
  29   else()
  30     set(TCC_NATIVE_TARGET "i386")
  31   endif()
  32 endif()
  33
  34 if(WIN32)
  35   set(EXE_PATH ".")
  36   set(TCC_LIB_PATH lib)
  37   set(NATIVE_LIB_PATH)
  38   set(DOC_PATH doc)
  39 else()
  40   set(EXE_PATH bin)
  41   set(TCC_LIB_PATH lib/tcc)
  42   set(NATIVE_LIB_PATH lib)
  43   set(DOC_PATH share/doc/tcc)
  44 endif()
  45
  46 if(NOT WIN32)
  47   if(EXISTS /usr/lib/${CMAKE_SYSTEM_PROCESSOR}-linux-gnu/crti.o)
  48     set(CONFIG_LDDIR lib/${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  49     set(CONFIG_MULTIARCHDIR ${CMAKE_SYSTEM_PROCESSOR}-linux-gnu)
  50   elseif(EXISTS /usr/lib64/crti.o)
  51     set(CONFIG_LDDIR lib64)
  52   endif()
  53 endif()
  54
  55 # Use two variables to keep CMake configuration variable names consistent
  56 set(TCC_BCHECK OFF CACHE BOOL "Enable bounds checking")
  57 set(CONFIG_TCC_BCHECK ${TCC_BCHECK})
  58
  59 set(TCC_BUILD_NATIVE ON CACHE BOOL "Build native compiler")
  60 set(TCC_BUILD_I386 OFF CACHE BOOL "Build i386 cross compiler")
  61 set(TCC_BUILD_X64 OFF CACHE BOOL "Build x86-64 cross compiler")
  62 set(TCC_BUILD_WIN32 OFF CACHE BOOL "Build Windows i386 cross compiler")
  63 set(TCC_BUILD_WIN64 OFF CACHE BOOL "Build Windows x86-64 cross compiler")
  64 set(TCC_BUILD_WINCE OFF CACHE BOOL "Build Windows CE cross compiler")
  65 set(TCC_BUILD_ARM_FPA OFF CACHE BOOL "Build arm-fpa cross compiler")
  66 set(TCC_BUILD_ARM_FPA_LD OFF CACHE BOOL "Build arm-fpa-ld cross compiler")
  67 set(TCC_BUILD_ARM_VFP OFF CACHE BOOL "Build arm-vfp cross compiler")
  68 set(TCC_BUILD_ARM_EABI OFF CACHE BOOL "Build ARM EABI cross compiler")
  69 set(TCC_BUILD_ARM_EABIHF OFF CACHE BOOL "Build ARM EABI hardware float cross compiler")
  70 set(TCC_BUILD_ARM OFF CACHE BOOL "Build ARM cross compiler")
  71 set(TCC_BUILD_C67 OFF CACHE BOOL "Build C67 cross compiler")
  72
  73 set(TCC_ARM_VERSION ${TCC_ARM_VERSION_DEFAULT} CACHE STRING "ARM target CPU version")
  74 set_property(CACHE TCC_ARM_VERSION PROPERTY STRINGS 4 5 6 7)
  75
  76 if(WIN32)
  77   set(CONFIG_TCCDIR ${CMAKE_INSTALL_PREFIX})
  78 else()
  79   set(CONFIG_TCCDIR ${CMAKE_INSTALL_PREFIX}/lib/tcc)
  80 endif()
  81
  82 file(STRINGS "VERSION" TCC_VERSION)
  83 list(GET TCC_VERSION 0 TCC_VERSION)
  84 include_directories(${CMAKE_BINARY_DIR})
  85 configure_file(config.h.in config.h)
  86 configure_file(config.texi.in config.texi)
  87
  88 # Utility variables
  89 set(I386_SOURCES i386-gen.c i386-asm.c i386-asm.h i386-tok.h)
  90 set(X86_64_SOURCES x86_64-gen.c i386-asm.c x86_64-asm.h)
  91 set(ARM_SOURCES arm_gen.c)
  92
  93 set(LIBTCC1_I386_SOURCES lib/alloca86.S lib/alloca86-bt.S)
  94 set(LIBTCC1_WIN_SOURCES win32/lib/crt1.c win32/lib/wincrt1.c win32/lib/dllcrt1.c win32/lib/dllmain.c win32/lib/chkstk.S)
  95 if(NOT WIN32)
  96   set(LIBTCC1_I386_SOURCES ${LIBTCC1_I386_SOURCES} lib/bcheck.c)
  97 endif()
  98
  99 if(WIN32)
 100   add_executable(tiny_impdef win32/tools/tiny_impdef.c)
 101 endif()
 102 add_executable(tiny_libmaker_32 win32/tools/tiny_libmaker.c)
 103 set_target_properties(tiny_libmaker_32 PROPERTIES COMPILE_DEFINITIONS TCC_TARGET_I386)
 104 add_executable(tiny_libmaker_64 win32/tools/tiny_libmaker.c)
 105 set_target_properties(tiny_libmaker_64 PROPERTIES COMPILE_DEFINITIONS TCC_TARGET_X86_64)
 106
 107 macro(make_libtcc1 prefix xcc xar defs includes sources)
 108   set(libtcc1_prefix)
 109   if("${prefix}" STRGREATER "")
 110     set(libtcc1_prefix ${prefix}-)
 111   endif()
 112   set(libtcc1_flags -I${CMAKE_SOURCE_DIR}/include)
 113   foreach(i ${defs})
 114     set(libtcc1_flags ${libtcc1_flags} -D${i})
 115   endforeach()
 116   foreach(i ${includes})
 117     set(libtcc1_flags ${libtcc1_flags} -I${CMAKE_SOURCE_DIR}/${i})
 118   endforeach()
 119   set(libtcc1_objects)
 120   foreach(libtcc1_c lib/libtcc1.c ${sources})
 121     string(REGEX MATCH "[^/]+$" libtcc1_o ${libtcc1_c})
 122     string(REGEX MATCH "^[^.]+" libtcc1_o ${libtcc1_o})
 123     set(libtcc1_o ${libtcc1_prefix}${libtcc1_o}.o)
 124     add_custom_command(OUTPUT ${libtcc1_o}
 125       COMMAND ${xcc} ${libtcc1_flags} -c ${CMAKE_SOURCE_DIR}/${libtcc1_c} -o ${libtcc1_o}
 126       DEPENDS ${xcc} ${CMAKE_SOURCE_DIR}/${libtcc1_c}
 127     )
 128     list(APPEND libtcc1_objects ${libtcc1_o})
 129   endforeach()
 130   add_custom_command(OUTPUT ${libtcc1_prefix}libtcc1.a
 131     COMMAND ${xar} ${libtcc1_prefix}libtcc1.a ${libtcc1_objects}
 132     DEPENDS ${xar} ${libtcc1_objects}
 133   )
 134   add_custom_target(${libtcc1_prefix}libtcc1 ALL DEPENDS ${libtcc1_prefix}libtcc1.a)
 135   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${libtcc1_prefix}libtcc1.a
 136     DESTINATION ${TCC_LIB_PATH}/${prefix} RENAME libtcc1.a)
 137 endmacro()
 138
 139 macro(make_tcc native_name cross_name cross_enabled definitions tcc_sources libtcc_ar libtcc_sources libtcc_includes)
 140   if (xx${native_name} STREQUAL xx${TCC_NATIVE_TARGET})
 141     set(TCC_NATIVE_DEFINITIONS ${definitions})
 142     if("${CONFIG_MULTIARCHDIR}" STRGREATER "")
 143       set(TCC_NATIVE_DEFINITIONS ${TCC_NATIVE_DEFINITIONS} CONFIG_MULTIARCHDIR="${CONFIG_MULTIARCHDIR}")
 144     endif()
 145     if("${CONFIG_LDDIR}" STRGREATER "")
 146       set(TCC_NATIVE_DEFINITIONS ${TCC_NATIVE_DEFINITIONS} CONFIG_LDDIR="${CONFIG_LDDIR}")
 147     endif()
 148
 149     set(TCC_NATIVE_FLAGS)
 150     foreach(make_tcc_def ${TCC_NATIVE_DEFINITIONS})
 151       set(TCC_NATIVE_FLAGS ${TCC_NATIVE_FLAGS} -D${make_tcc_def})
 152     endforeach()
 153
 154     if (TCC_BUILD_NATIVE)
 155       add_library(libtcc
 156         libtcc.c
 157         tccpp.c
 158         tccgen.c
 159         tccelf.c
 160         tccasm.c
 161         tccrun.c
 162         tcc.h
 163         libtcc.h
 164         tcctok.h
 165         ${tcc_sources}
 166       )
 167       set_target_properties(libtcc PROPERTIES OUTPUT_NAME tcc PREFIX lib LINK_FLAGS "-Wl,--output-def,libtcc.def")
 168       add_executable(tcc tcc.c)
 169       target_link_libraries(tcc libtcc)
 170       if(NOT WIN32)
 171         target_link_libraries(tcc dl)
 172       endif()
 173       install(TARGETS tcc libtcc RUNTIME DESTINATION ${EXE_PATH} LIBRARY DESTINATION ${NATIVE_LIB_PATH} ARCHIVE DESTINATION ${NATIVE_LIB_PATH})
 174       set_target_properties(tcc libtcc PROPERTIES COMPILE_DEFINITIONS "${TCC_NATIVE_DEFINITIONS}")
 175
 176       if("${libtcc_sources}" STRGREATER "")
 177         make_libtcc1("" tcc "${libtcc_ar}" "${TCC_NATIVE_DEFINITIONS}" "${libtcc_includes}" "${libtcc_sources}")
 178       endif()
 179     endif()
 180   elseif(${cross_enabled})
 181     add_executable(${cross_name}-tcc tcc.c)
 182     set_target_properties(${cross_name}-tcc PROPERTIES COMPILE_DEFINITIONS "ONE_SOURCE;${definitions}")
 183     install(TARGETS ${cross_name}-tcc RUNTIME DESTINATION ${EXE_PATH})
 184
 185     if("${libtcc_sources}" STRGREATER "")
 186       make_libtcc1(${cross_name} "${cross_name}-tcc" "${libtcc_ar}" "${definitions}" "${libtcc_includes}" "${libtcc_sources}")
 187     endif()
 188   endif()
 189 endmacro()
 190
 191 make_tcc("Win32" i386-win32 TCC_BUILD_WIN32
 192   "TCC_TARGET_I386;TCC_TARGET_PE"
 193   "${I386_SOURCES};tccpe.c"
 194   tiny_libmaker_32 "${LIBTCC1_I386_SOURCES};${LIBTCC1_WIN_SOURCES}" "win32/include;win32/include/winapi"
 195 )
 196 make_tcc("Win64" x86_64-win32 TCC_BUILD_WIN64
 197   "TCC_TARGET_X86_64;TCC_TARGET_PE"
 198   "${X86_64_SOURCES};tccpe.c"
 199   tiny_libmaker_64 "lib/alloca86_64.S;${LIBTCC1_WIN_SOURCES}" "win32/include;win32/include/winapi"
 200 )
 201 make_tcc("WinCE" arm-win32 TCC_BUILD_WINCE
 202   "TCC_TARGET_ARM;TCC_ARM_VERSION=${TCC_ARM_VERSION};TCC_TARGET_PE"
 203   "${ARM_SOURCES};tccpe.c"
 204   "" "" ""
 205 )
 206 make_tcc("i386" i386 TCC_BUILD_I386
 207   TCC_TARGET_I386
 208   "${I386_SOURCES}"
 209   tiny_libmaker_32 "${LIBTCC1_I386_SOURCES}" ""
 210 )
 211 make_tcc("x86_64" x86_64 TCC_BUILD_X64
 212   TCC_TARGET_X86_64
 213   "${X86_64_SOURCES}"
 214   tiny_libmaker_64 "lib/alloca86_64.S" ""
 215 )
 216 set(ARM_DEFINITIONS TCC_TARGET_ARM TCC_ARM_VERSION=${TCC_ARM_VERSION})
 217 make_tcc("ARM" arm TCC_BUILD_ARM
 218   "${ARM_DEFINITIONS};WITHOUT_LIBTCC"
 219   "${ARM_SOURCES}"
 220   "" "" ""
 221 )
 222 make_tcc("" arm-eabihf TCC_BUILD_ARM_EABIHF
 223   "${ARM_DEFINITIONS};TCC_ARM_EABI;TCC_ARM_HARDFLOAT"
 224   "${ARM_SOURCES}"
 225   "" "" ""
 226 )
 227 make_tcc("" arm-eabi TCC_BUILD_ARM_EABI
 228   "${ARM_DEFINITIONS};TCC_ARM_EABI"
 229   "${ARM_SOURCES}"
 230   "" "" ""
 231 )
 232 make_tcc("" arm-fpa TCC_BUILD_ARM_FPA
 233   "${ARM_DEFINITIONS}"
 234   "${ARM_SOURCES}"
 235   "" "" ""
 236 )
 237 make_tcc("" arm-fpa-ld TCC_BUILD_ARM_FPA_LD
 238   "${ARM_DEFINITIONS};LDOUBLE_SIZE=12"
 239   "${ARM_SOURCES}"
 240   "" "" ""
 241 )
 242 make_tcc("" arm-vfp TCC_BUILD_ARM_VFP
 243   "${ARM_DEFINITIONS};TCC_ARM_VFP"
 244   "${ARM_SOURCES}"
 245   "" "" ""
 246 )
 247 make_tcc("" c67 TCC_BUILD_C67
 248   TCC_TARGET_C67
 249   "c67-gen.c;tcccoff.c"
 250   "" "" ""
 251 )
 252
 253 add_subdirectory(tests)
 254
 255 find_program(MAKEINFO NAMES makeinfo PATHS C:/MinGW/MSYS/1.0/bin)
 256 if(MAKEINFO)
 257   add_custom_command(OUTPUT tcc-doc.html
 258     COMMAND ${MAKEINFO} --no-split --html -o tcc-doc.html ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 259     DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 260   )
 261   set(TCC_DOC_FILES tcc-doc.html)
 262   if(NOT WIN32)
 263     add_custom_command(OUTPUT tcc-doc.info
 264       COMMAND ${MAKEINFO} -o tcc-doc.info ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 265       DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 266     )
 267     set(TCC_DOC_FILES ${TCC_DOC_FILES} tcc-doc.info)
 268     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/tcc-doc.info DESTINATION share/info)
 269   endif()
 270   add_custom_target(tcc-doc ALL DEPENDS ${TCC_DOC_FILES})
 271   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/tcc-doc.html DESTINATION ${DOC_PATH})
 272 endif()
 273
 274 if(WIN32)
 275   file(GLOB WIN32_DEFS win32/lib/*.def)
 276   install(FILES ${WIN32_DEFS} DESTINATION lib)
 277   install(FILES tcclib.h DESTINATION include)
 278   install(DIRECTORY include/ DESTINATION include)
 279   install(DIRECTORY win32/include/ DESTINATION include)
 280   install(DIRECTORY win32/examples/ DESTINATION examples)
 281   install(FILES win32/tcc-win32.txt DESTINATION doc)
 282   install(FILES ${CMAKE_BINARY_DIR}/libtcc.def DESTINATION libtcc)
 283   install(FILES ${CMAKE_BINARY_DIR}/libtcc.dll.a DESTINATION libtcc RENAME libtcc.a)
 284   install(FILES libtcc.h DESTINATION libtcc)
 285 else()
 286   install(FILES libtcc.h tcclib.h DESTINATION include)
 287   install(DIRECTORY include/ DESTINATION lib/tcc/include)
 288   install(DIRECTORY win32/include/ DESTINATION lib/tcc/win32/include)
 289   install(DIRECTORY include/ DESTINATION lib/tcc/win32/include)
 290 endif()
 291