CMakeLists.txt

   1 project(tcc C)
   2 cmake_minimum_required(VERSION 2.6)
   3 enable_testing()
   4
   5 # Detect native platform
   6 if(WIN32)
   7   set(BUILD_SHARED_LIBS ON)
   8   if(CMAKE_SYSTEM_PROCESSOR STREQUAL "ARM")
   9     set(TCC_NATIVE_TARGET "WinCE")
  10   elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
  11     set(TCC_NATIVE_TARGET "Win64")
  12   else()
  13     set(TCC_NATIVE_TARGET "Win32")
  14   endif()
  15 else()
  16   if(CMAKE_SYSTEM_PROCESSOR MATCHES "^arm")
  17     set(TCC_NATIVE_TARGET "ARM")
  18     if(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv5")
  19       set(TCC_ARM_VERSION_DEFAULT 5)
  20     elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv6")
  21       set(TCC_ARM_VERSION_DEFAULT 6)
  22     elseif(CMAKE_SYSTEM_PROCESSOR MATCHES "^armv7")
  23       set(TCC_ARM_VERSION_DEFAULT 7)
  24     else()
  25       set(TCC_ARM_VERSION_DEFAULT 4)
  26     endif()
  27   elseif(CMAKE_SIZEOF_VOID_P EQUAL 8)
  28     set(TCC_NATIVE_TARGET "x86_64")
  29     set(TCC_ARCH_DIR "x86_64-linux-gnu")
  30   else()
  31     set(TCC_NATIVE_TARGET "i386")
  32     set(TCC_ARCH_DIR "i386-linux-gnu")
  33   endif()
  34 endif()
  35
  36 if(WIN32)
  37   set(EXE_PATH ".")
  38   set(TCC_LIB_PATH lib)
  39   set(NATIVE_LIB_PATH)
  40   set(DOC_PATH doc)
  41 else()
  42   set(EXE_PATH bin)
  43   set(TCC_LIB_PATH lib/tcc)
  44   set(NATIVE_LIB_PATH lib)
  45   set(DOC_PATH share/doc/tcc)
  46 endif()
  47
  48 if(NOT WIN32)
  49   if(EXISTS /usr/lib/${TCC_ARCH_DIR}/crti.o)
  50     set(CONFIG_LDDIR lib/${TCC_ARCH_DIR})
  51     set(CONFIG_MULTIARCHDIR ${TCC_ARCH_DIR})
  52   elseif(EXISTS /usr/lib64/crti.o)
  53     set(CONFIG_LDDIR lib64)
  54   endif()
  55 endif()
  56
  57 # Use two variables to keep CMake configuration variable names consistent
  58 set(TCC_BCHECK OFF CACHE BOOL "Enable bounds checking")
  59 set(CONFIG_TCC_BCHECK ${TCC_BCHECK})
  60
  61 set(TCC_BUILD_NATIVE ON CACHE BOOL "Build native compiler")
  62 set(TCC_BUILD_I386 OFF CACHE BOOL "Build i386 cross compiler")
  63 set(TCC_BUILD_X64 OFF CACHE BOOL "Build x86-64 cross compiler")
  64 set(TCC_BUILD_WIN32 OFF CACHE BOOL "Build Windows i386 cross compiler")
  65 set(TCC_BUILD_WIN64 OFF CACHE BOOL "Build Windows x86-64 cross compiler")
  66 set(TCC_BUILD_WINCE OFF CACHE BOOL "Build Windows CE cross compiler")
  67 set(TCC_BUILD_ARM_FPA OFF CACHE BOOL "Build arm-fpa cross compiler")
  68 set(TCC_BUILD_ARM_FPA_LD OFF CACHE BOOL "Build arm-fpa-ld cross compiler")
  69 set(TCC_BUILD_ARM_VFP OFF CACHE BOOL "Build arm-vfp cross compiler")
  70 set(TCC_BUILD_ARM_EABI OFF CACHE BOOL "Build ARM EABI cross compiler")
  71 set(TCC_BUILD_ARM_EABIHF OFF CACHE BOOL "Build ARM EABI hardware float cross compiler")
  72 set(TCC_BUILD_ARM OFF CACHE BOOL "Build ARM cross compiler")
  73 set(TCC_BUILD_C67 OFF CACHE BOOL "Build C67 cross compiler")
  74
  75 set(TCC_ARM_VERSION ${TCC_ARM_VERSION_DEFAULT} CACHE STRING "ARM target CPU version")
  76 set_property(CACHE TCC_ARM_VERSION PROPERTY STRINGS 4 5 6 7)
  77
  78 if(WIN32)
  79   set(CONFIG_TCCDIR ${CMAKE_INSTALL_PREFIX})
  80 else()
  81   set(CONFIG_TCCDIR ${CMAKE_INSTALL_PREFIX}/lib/tcc)
  82 endif()
  83
  84 file(STRINGS "VERSION" TCC_VERSION)
  85 list(GET TCC_VERSION 0 TCC_VERSION)
  86 include_directories(${CMAKE_BINARY_DIR})
  87 configure_file(config.h.in config.h)
  88 configure_file(config.texi.in config.texi)
  89
  90 # Utility variables
  91 set(I386_SOURCES i386-gen.c i386-asm.c i386-asm.h i386-tok.h)
  92 set(X86_64_SOURCES x86_64-gen.c i386-asm.c x86_64-asm.h)
  93 set(ARM_SOURCES arm_gen.c)
  94
  95 set(LIBTCC1_I386_SOURCES lib/alloca86.S lib/alloca86-bt.S)
  96 set(LIBTCC1_WIN_SOURCES win32/lib/crt1.c win32/lib/wincrt1.c win32/lib/dllcrt1.c win32/lib/dllmain.c win32/lib/chkstk.S)
  97 if(NOT WIN32)
  98   set(LIBTCC1_I386_SOURCES ${LIBTCC1_I386_SOURCES} lib/bcheck.c)
  99 endif()
 100
 101 if(WIN32)
 102   add_executable(tiny_impdef win32/tools/tiny_impdef.c)
 103 endif()
 104 add_executable(tiny_libmaker_32 win32/tools/tiny_libmaker.c)
 105 set_target_properties(tiny_libmaker_32 PROPERTIES COMPILE_DEFINITIONS TCC_TARGET_I386)
 106 add_executable(tiny_libmaker_64 win32/tools/tiny_libmaker.c)
 107 set_target_properties(tiny_libmaker_64 PROPERTIES COMPILE_DEFINITIONS TCC_TARGET_X86_64)
 108
 109 macro(make_libtcc1 prefix xcc xar defs includes sources)
 110   set(libtcc1_prefix)
 111   if("${prefix}" STRGREATER "")
 112     set(libtcc1_prefix ${prefix}-)
 113   endif()
 114   set(libtcc1_flags -I${CMAKE_SOURCE_DIR}/include)
 115   foreach(i ${defs})
 116     set(libtcc1_flags ${libtcc1_flags} -D${i})
 117   endforeach()
 118   foreach(i ${includes})
 119     set(libtcc1_flags ${libtcc1_flags} -I${CMAKE_SOURCE_DIR}/${i})
 120   endforeach()
 121   set(libtcc1_objects)
 122   foreach(libtcc1_c lib/libtcc1.c ${sources})
 123     string(REGEX MATCH "[^/]+$" libtcc1_o ${libtcc1_c})
 124     string(REGEX MATCH "^[^.]+" libtcc1_o ${libtcc1_o})
 125     set(libtcc1_o ${libtcc1_prefix}${libtcc1_o}.o)
 126     add_custom_command(OUTPUT ${libtcc1_o}
 127       COMMAND ${xcc} ${libtcc1_flags} -c ${CMAKE_SOURCE_DIR}/${libtcc1_c} -o ${libtcc1_o}
 128       DEPENDS ${xcc} ${CMAKE_SOURCE_DIR}/${libtcc1_c}
 129     )
 130     list(APPEND libtcc1_objects ${libtcc1_o})
 131   endforeach()
 132   add_custom_command(OUTPUT ${libtcc1_prefix}libtcc1.a
 133     COMMAND ${xar} ${libtcc1_prefix}libtcc1.a ${libtcc1_objects}
 134     DEPENDS ${xar} ${libtcc1_objects}
 135   )
 136   add_custom_target(${libtcc1_prefix}libtcc1 ALL DEPENDS ${libtcc1_prefix}libtcc1.a)
 137   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/${libtcc1_prefix}libtcc1.a
 138     DESTINATION ${TCC_LIB_PATH}/${prefix} RENAME libtcc1.a)
 139 endmacro()
 140
 141 macro(make_tcc native_name cross_name cross_enabled definitions tcc_sources libtcc_ar libtcc_sources libtcc_includes)
 142   if (xx${native_name} STREQUAL xx${TCC_NATIVE_TARGET})
 143     set(TCC_NATIVE_DEFINITIONS ${definitions})
 144     if("${CONFIG_MULTIARCHDIR}" STRGREATER "")
 145       set(TCC_NATIVE_DEFINITIONS ${TCC_NATIVE_DEFINITIONS} CONFIG_MULTIARCHDIR="${CONFIG_MULTIARCHDIR}")
 146     endif()
 147     if("${CONFIG_LDDIR}" STRGREATER "")
 148       set(TCC_NATIVE_DEFINITIONS ${TCC_NATIVE_DEFINITIONS} CONFIG_LDDIR="${CONFIG_LDDIR}")
 149     endif()
 150
 151     set(TCC_NATIVE_FLAGS)
 152     foreach(make_tcc_def ${TCC_NATIVE_DEFINITIONS})
 153       set(TCC_NATIVE_FLAGS ${TCC_NATIVE_FLAGS} -D${make_tcc_def})
 154     endforeach()
 155
 156     if (TCC_BUILD_NATIVE)
 157       add_library(libtcc
 158         libtcc.c
 159         tccpp.c
 160         tccgen.c
 161         tccelf.c
 162         tccasm.c
 163         tccrun.c
 164         tcc.h
 165         libtcc.h
 166         tcctok.h
 167         ${tcc_sources}
 168       )
 169       set_target_properties(libtcc PROPERTIES OUTPUT_NAME tcc PREFIX lib)
 170       if(WIN32)
 171         set_target_properties(libtcc PROPERTIES LINK_FLAGS "-Wl,--output-def,libtcc.def")
 172       endif()
 173       add_executable(tcc tcc.c)
 174       target_link_libraries(tcc libtcc)
 175       if(NOT WIN32)
 176         target_link_libraries(tcc dl)
 177       endif()
 178       install(TARGETS tcc libtcc RUNTIME DESTINATION ${EXE_PATH} LIBRARY DESTINATION ${NATIVE_LIB_PATH} ARCHIVE DESTINATION ${NATIVE_LIB_PATH})
 179       set_target_properties(tcc libtcc PROPERTIES COMPILE_DEFINITIONS "${TCC_NATIVE_DEFINITIONS}")
 180
 181       if("${libtcc_sources}" STRGREATER "")
 182         make_libtcc1("" tcc "${libtcc_ar}" "${TCC_NATIVE_DEFINITIONS}" "${libtcc_includes}" "${libtcc_sources}")
 183       endif()
 184     endif()
 185   elseif(${cross_enabled})
 186     add_executable(${cross_name}-tcc tcc.c)
 187     set_target_properties(${cross_name}-tcc PROPERTIES COMPILE_DEFINITIONS "ONE_SOURCE;${definitions}")
 188     install(TARGETS ${cross_name}-tcc RUNTIME DESTINATION ${EXE_PATH})
 189
 190     if("${libtcc_sources}" STRGREATER "")
 191       make_libtcc1(${cross_name} "${cross_name}-tcc" "${libtcc_ar}" "${definitions}" "${libtcc_includes}" "${libtcc_sources}")
 192     endif()
 193   endif()
 194 endmacro()
 195
 196 make_tcc("Win32" i386-win32 TCC_BUILD_WIN32
 197   "TCC_TARGET_I386;TCC_TARGET_PE"
 198   "${I386_SOURCES};tccpe.c"
 199   tiny_libmaker_32 "${LIBTCC1_I386_SOURCES};${LIBTCC1_WIN_SOURCES}" "win32/include;win32/include/winapi"
 200 )
 201 make_tcc("Win64" x86_64-win32 TCC_BUILD_WIN64
 202   "TCC_TARGET_X86_64;TCC_TARGET_PE"
 203   "${X86_64_SOURCES};tccpe.c"
 204   tiny_libmaker_64 "lib/alloca86_64.S;${LIBTCC1_WIN_SOURCES}" "win32/include;win32/include/winapi"
 205 )
 206 make_tcc("WinCE" arm-win32 TCC_BUILD_WINCE
 207   "TCC_TARGET_ARM;TCC_ARM_VERSION=${TCC_ARM_VERSION};TCC_TARGET_PE"
 208   "${ARM_SOURCES};tccpe.c"
 209   "" "" ""
 210 )
 211 make_tcc("i386" i386 TCC_BUILD_I386
 212   TCC_TARGET_I386
 213   "${I386_SOURCES}"
 214   tiny_libmaker_32 "${LIBTCC1_I386_SOURCES}" ""
 215 )
 216 make_tcc("x86_64" x86_64 TCC_BUILD_X64
 217   TCC_TARGET_X86_64
 218   "${X86_64_SOURCES}"
 219   tiny_libmaker_64 "lib/alloca86_64.S" ""
 220 )
 221 set(ARM_DEFINITIONS TCC_TARGET_ARM TCC_ARM_VERSION=${TCC_ARM_VERSION})
 222 make_tcc("ARM" arm TCC_BUILD_ARM
 223   "${ARM_DEFINITIONS};WITHOUT_LIBTCC"
 224   "${ARM_SOURCES}"
 225   "" "" ""
 226 )
 227 make_tcc("" arm-eabihf TCC_BUILD_ARM_EABIHF
 228   "${ARM_DEFINITIONS};TCC_ARM_EABI;TCC_ARM_HARDFLOAT"
 229   "${ARM_SOURCES}"
 230   "" "" ""
 231 )
 232 make_tcc("" arm-eabi TCC_BUILD_ARM_EABI
 233   "${ARM_DEFINITIONS};TCC_ARM_EABI"
 234   "${ARM_SOURCES}"
 235   "" "" ""
 236 )
 237 make_tcc("" arm-fpa TCC_BUILD_ARM_FPA
 238   "${ARM_DEFINITIONS}"
 239   "${ARM_SOURCES}"
 240   "" "" ""
 241 )
 242 make_tcc("" arm-fpa-ld TCC_BUILD_ARM_FPA_LD
 243   "${ARM_DEFINITIONS};LDOUBLE_SIZE=12"
 244   "${ARM_SOURCES}"
 245   "" "" ""
 246 )
 247 make_tcc("" arm-vfp TCC_BUILD_ARM_VFP
 248   "${ARM_DEFINITIONS};TCC_ARM_VFP"
 249   "${ARM_SOURCES}"
 250   "" "" ""
 251 )
 252 make_tcc("" c67 TCC_BUILD_C67
 253   TCC_TARGET_C67
 254   "c67-gen.c;tcccoff.c"
 255   "" "" ""
 256 )
 257
 258 add_subdirectory(tests)
 259
 260 find_program(MAKEINFO NAMES makeinfo PATHS C:/MinGW/MSYS/1.0/bin)
 261 if(MAKEINFO)
 262   add_custom_command(OUTPUT tcc-doc.html
 263     COMMAND ${MAKEINFO} --no-split --html -o tcc-doc.html ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 264     DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 265   )
 266   set(TCC_DOC_FILES tcc-doc.html)
 267   if(NOT WIN32)
 268     add_custom_command(OUTPUT tcc-doc.info
 269       COMMAND ${MAKEINFO} -o tcc-doc.info ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 270       DEPENDS ${CMAKE_CURRENT_SOURCE_DIR}/tcc-doc.texi
 271     )
 272     set(TCC_DOC_FILES ${TCC_DOC_FILES} tcc-doc.info)
 273     install(FILES ${CMAKE_CURRENT_BINARY_DIR}/tcc-doc.info DESTINATION share/info)
 274   endif()
 275   add_custom_target(tcc-doc ALL DEPENDS ${TCC_DOC_FILES})
 276   install(FILES ${CMAKE_CURRENT_BINARY_DIR}/tcc-doc.html DESTINATION ${DOC_PATH})
 277 endif()
 278
 279 if(WIN32)
 280   file(GLOB WIN32_DEFS win32/lib/*.def)
 281   install(FILES ${WIN32_DEFS} DESTINATION lib)
 282   install(FILES tcclib.h DESTINATION include)
 283   install(DIRECTORY include/ DESTINATION include)
 284   install(DIRECTORY win32/include/ DESTINATION include)
 285   install(DIRECTORY win32/examples/ DESTINATION examples)
 286   install(FILES win32/tcc-win32.txt DESTINATION doc)
 287   install(FILES ${CMAKE_BINARY_DIR}/libtcc.def DESTINATION libtcc)
 288   install(FILES ${CMAKE_BINARY_DIR}/libtcc.dll.a DESTINATION libtcc RENAME libtcc.a)
 289   install(FILES libtcc.h DESTINATION libtcc)
 290 else()
 291   install(FILES libtcc.h tcclib.h DESTINATION include)
 292   install(DIRECTORY include/ DESTINATION lib/tcc/include)
 293   install(DIRECTORY win32/include/ DESTINATION lib/tcc/win32/include)
 294   install(DIRECTORY include/ DESTINATION lib/tcc/win32/include)
 295 endif()
 296