src/code/interr.lisp

   1 ;;;; functions and macros to define and deal with internal errors
   2 ;;;; (i.e. problems that can be signaled from assembler code)
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!KERNEL")
  14 \f
  15 ;;;; internal errors
  16
  17 (defvar *internal-errors*
  18   #.(map 'vector #'cdr sb!c:*backend-internal-errors*))
  19
  20 (eval-when (:compile-toplevel :execute)
  21
  22 (sb!xc:defmacro deferr (name args &rest body)
  23   (let* ((rest-pos (position '&rest args))
  24          (required (if rest-pos (subseq args 0 rest-pos) args))
  25          (fn-name (symbolicate name "-HANDLER")))
  26     (with-unique-names (fp context sc-offsets)
  27       `(progn
  28          ;; FIXME: Having a separate full DEFUN for each error doesn't
  29          ;; seem to add much value, and it takes a lot of space. Perhaps
  30          ;; we could do this dispatch with a big CASE statement instead?
  31          (defun ,fn-name (name ,fp ,context ,sc-offsets)
  32            ;; FIXME: It would probably be good to do *STACK-TOP-HINT*
  33            ;; tricks to hide this internal error-handling logic from the
  34            ;; poor high level user, so his debugger tells him about
  35            ;; where his error was detected instead of telling him where
  36            ;; he ended up inside the system error-handling logic.
  37            (declare (ignorable name ,fp ,context ,sc-offsets))
  38            (let (,@(let ((offset -1))
  39                         (mapcar (lambda (var)
  40                                   `(,var (sb!di::sub-access-debug-var-slot
  41                                           ,fp
  42                                           (nth ,(incf offset)
  43                                            ,sc-offsets)
  44                                           ,context)))
  45                                 required))
  46                  ,@(when rest-pos
  47                      `((,(nth (1+ rest-pos) args)
  48                         (mapcar (lambda (sc-offset)
  49                                   (sb!di::sub-access-debug-var-slot
  50                                    ,fp
  51                                    sc-offset
  52                                    ,context))
  53                          (nthcdr ,rest-pos ,sc-offsets))))))
  54              ,@body))
  55         (setf (svref *internal-errors* ,(error-number-or-lose name))
  56               #',fn-name)))))
  57
  58 ) ; EVAL-WHEN
  59
  60 (deferr unknown-error (&rest args)
  61   (error "unknown error:~{ ~S~})" args))
  62
  63 (deferr object-not-fun-error (object)
  64   (error 'type-error
  65          :datum object
  66          :expected-type 'function))
  67
  68 (deferr object-not-list-error (object)
  69   (error 'type-error
  70          :datum object
  71          :expected-type 'list))
  72
  73 (deferr object-not-bignum-error (object)
  74   (error 'type-error
  75          :datum object
  76          :expected-type 'bignum))
  77
  78 (deferr object-not-ratio-error (object)
  79   (error 'type-error
  80          :datum object
  81          :expected-type 'ratio))
  82
  83 (deferr object-not-single-float-error (object)
  84   (error 'type-error
  85          :datum object
  86          :expected-type 'single-float))
  87
  88 (deferr object-not-double-float-error (object)
  89   (error 'type-error
  90          :datum object
  91          :expected-type 'double-float))
  92
  93 #!+long-float
  94 (deferr object-not-long-float-error (object)
  95   (error 'type-error
  96          :datum object
  97          :expected-type 'long-float))
  98
  99 (deferr object-not-simple-string-error (object)
 100   (error 'type-error
 101          :datum object
 102          :expected-type 'simple-string))
 103
 104 (deferr object-not-fixnum-error (object)
 105   (error 'type-error
 106          :datum object
 107          :expected-type 'fixnum))
 108
 109 (deferr object-not-vector-error (object)
 110   (error 'type-error
 111          :datum object
 112          :expected-type 'vector))
 113
 114 (deferr object-not-string-error (object)
 115   (error 'type-error
 116          :datum object
 117          :expected-type 'string))
 118
 119 (deferr object-not-base-string-error (object)
 120   (error 'type-error
 121          :datum object
 122          :expected-type 'base-string))
 123
 124 (deferr object-not-vector-nil-error (object)
 125   (error 'type-error
 126          :datum object
 127          :expected-type '(vector nil)))
 128
 129 #!+sb-unicode
 130 (deferr object-not-character-string-error (object)
 131   (error 'type-error
 132          :datum object
 133          :expected-type '(vector character)))
 134
 135 (deferr object-not-bit-vector-error (object)
 136   (error 'type-error
 137          :datum object
 138          :expected-type 'bit-vector))
 139
 140 (deferr object-not-array-error (object)
 141   (error 'type-error
 142          :datum object
 143          :expected-type 'array))
 144
 145 (deferr object-not-number-error (object)
 146   (error 'type-error
 147          :datum object
 148          :expected-type 'number))
 149
 150 (deferr object-not-rational-error (object)
 151   (error 'type-error
 152          :datum object
 153          :expected-type 'rational))
 154
 155 (deferr object-not-float-error (object)
 156   (error 'type-error
 157          :datum object
 158          :expected-type 'float))
 159
 160 (deferr object-not-real-error (object)
 161   (error 'type-error
 162          :datum object
 163          :expected-type 'real))
 164
 165 (deferr object-not-integer-error (object)
 166   (error 'type-error
 167          :datum object
 168          :expected-type 'integer))
 169
 170 (deferr object-not-cons-error (object)
 171   (error 'type-error
 172          :datum object
 173          :expected-type 'cons))
 174
 175 (deferr object-not-symbol-error (object)
 176   (error 'type-error
 177          :datum object
 178          :expected-type 'symbol))
 179
 180 (deferr undefined-fun-error (fdefn-or-symbol)
 181   (error 'undefined-function
 182          :name (etypecase fdefn-or-symbol
 183                  (symbol fdefn-or-symbol)
 184                  (fdefn (fdefn-name fdefn-or-symbol)))))
 185
 186 (deferr invalid-arg-count-error (nargs)
 187   (error 'simple-program-error
 188          :format-control "invalid number of arguments: ~S"
 189          :format-arguments (list nargs)))
 190
 191 (deferr bogus-arg-to-values-list-error (list)
 192   (error 'simple-type-error
 193          :datum list
 194          :expected-type 'list
 195          :format-control
 196          "~@<attempt to use VALUES-LIST on a dotted list: ~2I~_~S~:>"
 197          :format-arguments (list list)))
 198
 199 (deferr unbound-symbol-error (symbol)
 200   (error 'unbound-variable :name symbol))
 201
 202 (deferr object-not-character-error (object)
 203   (error 'type-error
 204          :datum object
 205          :expected-type 'character))
 206
 207 (deferr object-not-sap-error (object)
 208   (error 'type-error
 209          :datum object
 210          :expected-type 'system-area-pointer))
 211
 212 (deferr invalid-unwind-error ()
 213   (error 'simple-control-error
 214          :format-control
 215          "attempt to RETURN-FROM a block or GO to a tag that no longer exists"
 216          ))
 217
 218 (deferr unseen-throw-tag-error (tag)
 219   (error 'simple-control-error
 220          :format-control "attempt to THROW to a tag that does not exist: ~S"
 221          :format-arguments (list tag)))
 222
 223 (deferr nil-fun-returned-error (function)
 224   (error 'simple-control-error
 225          :format-control
 226          "A function with declared result type NIL returned:~%  ~S"
 227          :format-arguments (list function)))
 228
 229 (deferr nil-array-accessed-error (array)
 230   (error 'nil-array-accessed-error
 231          :datum array :expected-type '(not (array nil))))
 232
 233 (deferr division-by-zero-error (this that)
 234   (error 'division-by-zero
 235          :operation 'division
 236          :operands (list this that)))
 237
 238 (deferr object-not-type-error (object type)
 239   (if (invalid-array-p object)
 240       (invalid-array-error object)
 241       (error (if (and (%instancep object)
 242                       (layout-invalid (%instance-layout object)))
 243                  'layout-invalid
 244                  'type-error)
 245              :datum object
 246              :expected-type type)))
 247
 248 (deferr layout-invalid-error (object layout)
 249   (error 'layout-invalid
 250          :datum object
 251          :expected-type (layout-classoid layout)))
 252
 253 (deferr odd-key-args-error ()
 254   (error 'simple-program-error
 255          :format-control "odd number of &KEY arguments"))
 256
 257 (deferr unknown-key-arg-error (key-name)
 258   (error 'simple-program-error
 259          :format-control "unknown &KEY argument: ~S"
 260          :format-arguments (list key-name)))
 261
 262 (deferr invalid-array-index-error (array bound index)
 263   (invalid-array-index-error array index bound))
 264
 265 (deferr object-not-simple-array-error (object)
 266   (error 'type-error
 267          :datum object
 268          :expected-type 'simple-array))
 269
 270 (deferr object-not-signed-byte-32-error (object)
 271   (error 'type-error
 272          :datum object
 273          :expected-type '(signed-byte 32)))
 274
 275 (deferr object-not-unsigned-byte-32-error (object)
 276   (error 'type-error
 277          :datum object
 278          :expected-type '(unsigned-byte 32)))
 279
 280 (deferr tls-exhausted-error ()
 281   ;; There is nothing we can do about it. A number of entries in the
 282   ;; tls could be reserved and made available for recovery but since
 283   ;; tls indices are never reused it would be kind of silly and
 284   ;; without it signalling an error is more than likely to end in a
 285   ;; recursive error.
 286   (%primitive print "Thread local storage exhausted.")
 287   (sb!impl::%halt))
 288
 289 (macrolet
 290     ((define-simple-array-internal-errors ()
 291          `(progn
 292            ,@(map 'list
 293                   (lambda (saetp)
 294                     `(deferr ,(symbolicate
 295                                "OBJECT-NOT-"
 296                                (sb!vm:saetp-primitive-type-name saetp)
 297                                "-ERROR")
 298                               (object)
 299                       (error 'type-error
 300                              :datum object
 301                              :expected-type '(simple-array
 302                                               ,(sb!vm:saetp-specifier saetp)
 303                                               (*)))))
 304                   sb!vm:*specialized-array-element-type-properties*))))
 305   (define-simple-array-internal-errors))
 306
 307 (deferr object-not-complex-error (object)
 308   (error 'type-error
 309          :datum object
 310          :expected-type 'complex))
 311
 312 (deferr object-not-complex-rational-error (object)
 313   (error 'type-error
 314          :datum object
 315          :expected-type '(complex rational)))
 316
 317 (deferr object-not-complex-single-float-error (object)
 318   (error 'type-error
 319          :datum object
 320          :expected-type '(complex single-float)))
 321
 322 (deferr object-not-complex-double-float-error (object)
 323   (error 'type-error
 324          :datum object
 325          :expected-type '(complex double-float)))
 326
 327 #!+long-float
 328 (deferr object-not-complex-long-float-error (object)
 329   (error 'type-error
 330          :datum object
 331          :expected-type '(complex long-float)))
 332
 333 (deferr object-not-weak-pointer-error (object)
 334   (error 'type-error
 335          :datum object
 336          :expected-type 'weak-pointer))
 337
 338 (deferr object-not-instance-error (object)
 339   (error 'type-error
 340          :datum object
 341          :expected-type 'instance))
 342
 343 (deferr object-not-complex-vector-error (object)
 344   (error 'type-error
 345          :datum object
 346          :expected-type '(and vector (not simple-array))))
 347 \f
 348 ;;;; fetching errorful function name
 349
 350 ;;; This flag is used to prevent infinite recursive lossage when
 351 ;;; we can't find the caller for some reason.
 352 (defvar *finding-name* nil)
 353
 354 (defun find-caller-name-and-frame ()
 355   (if *finding-name*
 356       (values "<error finding caller name -- already finding name>" nil)
 357       (handler-case
 358           (let* ((*finding-name* t)
 359                  (frame (sb!di:frame-down (sb!di:frame-down (sb!di:top-frame))))
 360                  (name (sb!di:debug-fun-name
 361                         (sb!di:frame-debug-fun frame))))
 362             (sb!di:flush-frames-above frame)
 363             (values name frame))
 364         (error ()
 365           (values "<error finding caller name -- trapped error>" nil))
 366         (sb!di:debug-condition ()
 367           (values "<error finding caller name -- trapped debug-condition>"
 368                   nil)))))
 369
 370 (defun find-interrupted-name-and-frame ()
 371   (/show0 "entering FIND-INTERRUPTED-NAME-AND-FRAME")
 372   (if *finding-name*
 373       (values "<error finding interrupted name -- already finding name>" nil)
 374       (handler-case
 375           (let ((*finding-name* t))
 376             (/show0 "in ordinary case")
 377             (do ((frame (sb!di:top-frame) (sb!di:frame-down frame)))
 378                 ((null frame)
 379                  (/show0 "null frame")
 380                  (values "<error finding interrupted name -- null frame>" nil))
 381               (/show0 "at head of DO loop")
 382               (when (and (sb!di::compiled-frame-p frame)
 383                          (sb!di::compiled-frame-escaped frame))
 384                 (sb!di:flush-frames-above frame)
 385                 (/show0 "returning from within DO loop")
 386                 (return (values (sb!di:debug-fun-name
 387                                  (sb!di:frame-debug-fun frame))
 388                                 frame)))))
 389         (error ()
 390           (/show0 "trapped ERROR")
 391           (values "<error finding interrupted name -- trapped error>" nil))
 392         (sb!di:debug-condition ()
 393           (/show0 "trapped DEBUG-CONDITION")
 394           (values "<error finding interrupted name -- trapped debug-condition>"
 395                   nil)))))
 396 \f
 397
 398 ;;;; INTERNAL-ERROR signal handler
 399
 400 (defun internal-error (context continuable)
 401   (declare (type system-area-pointer context))
 402   (declare (ignore continuable))
 403   (/show0 "entering INTERNAL-ERROR, CONTEXT=..")
 404   (/hexstr context)
 405   (infinite-error-protect
 406    (/show0 "about to bind ALIEN-CONTEXT")
 407    (let ((alien-context (locally
 408                             (declare (optimize (inhibit-warnings 3)))
 409                           (sb!alien:sap-alien context (* os-context-t)))))
 410      (/show0 "about to bind ERROR-NUMBER and ARGUMENTS")
 411      (multiple-value-bind (error-number arguments)
 412          (sb!vm:internal-error-args alien-context)
 413
 414        ;; There's a limit to how much error reporting we can usefully
 415        ;; do before initialization is complete, but try to be a little
 416        ;; bit helpful before we die.
 417        (/show0 "back from INTERNAL-ERROR-ARGS, ERROR-NUMBER=..")
 418        (/hexstr error-number)
 419        (/show0 "cold/low ARGUMENTS=..")
 420        (/hexstr arguments)
 421        (unless *cold-init-complete-p*
 422          (%primitive print "can't recover from error in cold init, halting")
 423          (%primitive sb!c:halt))
 424
 425        (with-interrupt-bindings
 426          (multiple-value-bind (name sb!debug:*stack-top-hint*)
 427              (find-interrupted-name-and-frame)
 428            (/show0 "back from FIND-INTERRUPTED-NAME")
 429            (let ((fp (int-sap (sb!vm:context-register alien-context
 430                                                       sb!vm::cfp-offset)))
 431                  (handler (and (< -1 error-number (length *internal-errors*))
 432                                (svref *internal-errors* error-number))))
 433              (cond ((null handler)
 434                     (error 'simple-error
 435                            :format-control
 436                            "unknown internal error, ~D, args=~S"
 437                            :format-arguments
 438                            (list error-number
 439                                  (mapcar (lambda (sc-offset)
 440                                            (sb!di::sub-access-debug-var-slot
 441                                             fp sc-offset alien-context))
 442                                          arguments))))
 443                    ((not (functionp handler))
 444                     (error 'simple-error
 445                            :format-control "internal error ~D: ~A; args=~S"
 446                            :format-arguments
 447                            (list error-number
 448                                  handler
 449                                  (mapcar (lambda (sc-offset)
 450                                            (sb!di::sub-access-debug-var-slot
 451                                             fp sc-offset alien-context))
 452                                          arguments))))
 453                    (t
 454                     (funcall handler name fp alien-context arguments))))))))))
 455
 456 (defun control-stack-exhausted-error ()
 457   (let ((sb!debug:*stack-top-hint* nil))
 458     (infinite-error-protect
 459      (format *error-output*
 460              "Control stack guard page temporarily disabled: proceed with caution~%")
 461      (error 'control-stack-exhausted))))
 462
 463 (defun binding-stack-exhausted-error ()
 464   (let ((sb!debug:*stack-top-hint* nil))
 465     (infinite-error-protect
 466      (format *error-output*
 467              "Binding stack guard page temporarily disabled: proceed with caution~%")
 468      (error 'binding-stack-exhausted))))
 469
 470 (defun alien-stack-exhausted-error ()
 471   (let ((sb!debug:*stack-top-hint* nil))
 472     (infinite-error-protect
 473      (format *error-output*
 474              "Alien stack guard page temporarily disabled: proceed with caution~%")
 475      (error 'alien-stack-exhausted))))
 476
 477 ;;; KLUDGE: we keep a single HEAP-EXHAUSTED-ERROR object around, so
 478 ;;; that we don't need to allocate it when running out of
 479 ;;; memory. Similarly we pass the amounts in special variables as
 480 ;;; there may be multiple threads running into trouble at the same
 481 ;;; time. The condition is created by GC-REINIT.
 482 (defvar *heap-exhausted-error-condition*)
 483 (defvar *heap-exhausted-error-available-bytes*)
 484 (defvar *heap-exhausted-error-requested-bytes*)
 485
 486 (defun heap-exhausted-error (available requested)
 487   (infinite-error-protect
 488    (let ((*heap-exhausted-error-available-bytes* available)
 489          (*heap-exhausted-error-requested-bytes* requested))
 490      (error *heap-exhausted-error-condition*))))
 491
 492 (defun undefined-alien-variable-error ()
 493   (error 'undefined-alien-variable-error))
 494
 495 (defun undefined-alien-function-error ()
 496   (error 'undefined-alien-function-error))
 497
 498 #!-win32
 499 (define-alien-variable current-memory-fault-address unsigned-long)
 500
 501 #!-win32
 502 (defun memory-fault-error ()
 503   (error 'memory-fault-error
 504          :address current-memory-fault-address))
 505
 506 ;;; This is SIGTRAP / EXCEPTION_BREAKPOINT that runtime could not deal
 507 ;;; with. Prior to Windows we just had a Lisp side handler for
 508 ;;; SIGTRAP, but now we need to deal with this portably.
 509 (defun unhandled-trap-error (context-sap)
 510   (declare (type system-area-pointer context-sap))
 511   (infinite-error-protect
 512    (let ((context (sap-alien context-sap (* os-context-t))))
 513      (error 'breakpoint-error
 514             :context context
 515             :address (sap-int (sb!vm:context-pc context))))))