qemu.nsi

   1 ;!/usr/bin/makensis
   2
   3 ; This NSIS script creates an installer for QEMU on Windows.
   4
   5 ; Copyright (C) 2006-2021 Stefan Weil
   6 ;
   7 ; This program is free software: you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 2 of the License, or
  10 ; (at your option) version 3 or any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ; NSIS_WIN32_MAKENSIS
  21
  22 !define PRODUCT "QEMU"
  23 !define URL     "https://www.qemu.org/"
  24
  25 !define UNINST_EXE "$INSTDIR\qemu-uninstall.exe"
  26 !define UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT}"
  27
  28 !ifndef BINDIR
  29 !define BINDIR nsis.tmp
  30 !endif
  31 !ifndef DATADIR
  32 !define DATADIR "${BINDIR}\share"
  33 !endif
  34 !ifndef SRCDIR
  35 !define SRCDIR .
  36 !endif
  37 !ifndef ICONSDIR
  38 !ifdef W64
  39 !define ICONSDIR /mingw64/share/icons
  40 !else
  41 !define ICONSDIR /mingw32/share/icons
  42 !endif
  43 !endif
  44 !ifndef OUTFILE
  45 !define OUTFILE "qemu-setup.exe"
  46 !endif
  47
  48 ; Build a unicode installer
  49 Unicode true
  50
  51 ; Use maximum compression.
  52 SetCompressor /SOLID lzma
  53
  54 !include "MUI2.nsh"
  55
  56 ; The name of the installer.
  57 Name "QEMU"
  58
  59 ; The file to write
  60 OutFile "${OUTFILE}"
  61
  62 !ifdef SIGNCODE
  63 !finalize "${SIGNCODE} %1"
  64 !uninstfinalize "${SIGNCODE} %1"
  65 !endif
  66
  67 !ifdef DISPLAYVERSION
  68 ; Caption for installer window.
  69 !ifdef W64
  70 Caption "QEMU ${DISPLAYVERSION} (64bit)"
  71 !else
  72 Caption "QEMU ${DISPLAYVERSION} (32bit)"
  73 !endif
  74 !endif
  75
  76 ; File properties.
  77 !ifdef DISPLAYVERSION
  78 !define /date DATEVERSION "%Y%m%d%H%M%S"
  79 VIProductVersion "${DISPLAYVERSION}.${DATEVERSION}"
  80 !endif
  81 VIAddVersionKey "ProductName" "QEMU"
  82 VIAddVersionKey "Comments" "patched version provided by Stefan Weil"
  83 VIAddVersionKey "CompanyName" "https://qemu.weilnetz.de"
  84 VIAddVersionKey "FileDescription" "QEMU machine emulators and tools"
  85 !define /date DATETIME "%Y-%m-%d-%H-%M-%S"
  86 VIAddVersionKey "FileVersion" "${DATETIME}"
  87 VIAddVersionKey "InternalName" "QEMU"
  88 VIAddVersionKey "LegalCopyright" "GNU General Public License version 2"
  89 VIAddVersionKey "LegalTrademarks" "QEMU is a trademark of Fabrice Bellard."
  90 VIAddVersionKey "OriginalFilename" "${OUTFILE}"
  91 !ifdef DISPLAYVERSION
  92 VIAddVersionKey "ProductVersion" "${DISPLAYVERSION}"
  93 !endif
  94
  95 ; The default installation directory.
  96 !ifdef W64
  97 InstallDir $PROGRAMFILES64\qemu
  98 !else
  99 InstallDir $PROGRAMFILES\qemu
 100 !endif
 101
 102 ; Registry key to check for directory (so if you install again, it will
 103 ; overwrite the old one automatically)
 104 !ifdef W64
 105 InstallDirRegKey HKLM "Software\qemu64" "Install_Dir"
 106 !else
 107 InstallDirRegKey HKLM "Software\qemu32" "Install_Dir"
 108 !endif
 109
 110 ; Request administrator privileges for Windows Vista.
 111 RequestExecutionLevel admin
 112
 113 ;--------------------------------
 114 ; Interface Settings.
 115 ;!define MUI_HEADERIMAGE "qemu-nsis.bmp"
 116 ; !define MUI_SPECIALBITMAP "qemu.bmp"
 117 !define MUI_ICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
 118 !define MUI_UNICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
 119 !define MUI_WELCOMEFINISHPAGE_BITMAP "${SRCDIR}\pc-bios\qemu-nsis.bmp"
 120 ; !define MUI_HEADERIMAGE_BITMAP "qemu-install.bmp"
 121 ; !define MUI_HEADERIMAGE_UNBITMAP "qemu-uninstall.bmp"
 122 ; !define MUI_COMPONENTSPAGE_SMALLDESC
 123 ; !define MUI_WELCOMEPAGE_TEXT "Insert text here.$\r$\n$\r$\n$\r$\n$_CLICK"
 124
 125 ;--------------------------------
 126 ; Pages.
 127
 128 !insertmacro MUI_PAGE_WELCOME
 129 !insertmacro MUI_PAGE_LICENSE "${SRCDIR}\COPYING"
 130 !insertmacro MUI_PAGE_COMPONENTS
 131 !insertmacro MUI_PAGE_DIRECTORY
 132 !insertmacro MUI_PAGE_INSTFILES
 133 !define MUI_FINISHPAGE_LINK $(Visit_QEMU_Wiki_Link)
 134 !define MUI_FINISHPAGE_LINK_LOCATION "${URL}"
 135 !insertmacro MUI_PAGE_FINISH
 136
 137 !insertmacro MUI_UNPAGE_CONFIRM
 138 !insertmacro MUI_UNPAGE_INSTFILES
 139
 140 ;--------------------------------
 141 ; Languages.
 142
 143 !insertmacro MUI_LANGUAGE "English"
 144 !insertmacro MUI_LANGUAGE "French"
 145 !insertmacro MUI_LANGUAGE "German"
 146 !insertmacro MUI_LANGUAGE "Italian"
 147 !insertmacro MUI_LANGUAGE "Spanish"
 148
 149 ;--------------------------------
 150 ; Functions.
 151
 152 Function .onInit
 153     !insertmacro MUI_LANGDLL_DISPLAY
 154 FunctionEnd
 155
 156
 157 ;--------------------------------
 158
 159 ; The stuff to install.
 160 ;
 161 ; Remember to keep the "Uninstall" section in sync.
 162
 163 Section "${PRODUCT}" QEMU_System_File_Section_Description
 164
 165     SectionIn RO
 166
 167     ; Set output path to the installation directory.
 168     SetOutPath "$INSTDIR"
 169
 170     File "${SRCDIR}\COPYING"
 171     File "${SRCDIR}\COPYING.LIB"
 172     File "${SRCDIR}\README.rst"
 173     File "${SRCDIR}\VERSION"
 174
 175     File /r "${BINDIR}\share"
 176
 177     SetOutPath "$INSTDIR\lib\gdk-pixbuf-2.0\2.10.0"
 178     FileOpen $0 "loaders.cache" w
 179     FileClose $0
 180
 181 !ifdef W64
 182     SetRegView 64
 183 !endif
 184
 185     ; Write the installation path into the registry
 186     WriteRegStr HKLM SOFTWARE\${PRODUCT} "Install_Dir" "$INSTDIR"
 187
 188     ; Write the uninstall keys for Windows
 189     WriteRegStr HKLM "${UNINST_KEY}" "DisplayName" "QEMU"
 190     WriteRegStr HKLM "${UNINST_KEY}" "DisplayIcon" "$INSTDIR\qemu-uninstall.exe"
 191 !ifdef DISPLAYVERSION
 192     WriteRegStr HKLM "${UNINST_KEY}" "DisplayVersion" "${DISPLAYVERSION}"
 193 !endif
 194     WriteRegStr HKLM "${UNINST_KEY}" "Publisher" "QEMU Community"
 195     WriteRegStr HKLM "${UNINST_KEY}" "UninstallString" '"${UNINST_EXE}"'
 196     WriteRegDWORD HKLM "${UNINST_KEY}" "NoModify" 1
 197     WriteRegDWORD HKLM "${UNINST_KEY}" "NoRepair" 1
 198     WriteUninstaller "qemu-uninstall.exe"
 199 SectionEnd
 200
 201 Section "$(Tools_Section_Name)" Tools_Section_Description
 202     SetOutPath "$INSTDIR"
 203     File "${BINDIR}\qemu-edid.exe"
 204     File "${BINDIR}\qemu-ga.exe"
 205     File "${BINDIR}\qemu-img.exe"
 206     File "${BINDIR}\qemu-io.exe"
 207     File "${BINDIR}\qemu-nbd.exe"
 208     File "${BINDIR}\qemu-storage-daemon.exe"
 209 SectionEnd
 210
 211 SectionGroup "$(System_Emulation_Section_Name)" System_Emulation_Section_Description
 212
 213 !include "${BINDIR}\system-emulations.nsh"
 214
 215 SectionGroupEnd
 216
 217 Section "$(Desktop_Icon_Section_Name)" Desktop_Icon_Section_Description
 218     SetOutPath "$INSTDIR\share"
 219     File /r ${ICONSDIR}
 220 SectionEnd
 221
 222 !ifdef DLLDIR
 223 Section "$(DLL_Library_Section_Name)" DLL_Library_Section_Description
 224     SetOutPath "$INSTDIR"
 225     File "${DLLDIR}\*.dll"
 226 SectionEnd
 227 !endif
 228
 229 !ifdef CONFIG_DOCUMENTATION
 230 Section "$(Documentation_Section_Name)" Documentation_Section_Description
 231     ; SetOutPath "$INSTDIR\share\doc"
 232     ; File /r "${BINDIR}\share\doc"
 233     SetOutPath "$INSTDIR"
 234     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 235     CreateShortCut "$SMPROGRAMS\${PRODUCT}\$(Link_Description_User_Documentation).lnk" "$INSTDIR\share\doc\index.html" "" "$INSTDIR\share\doc\index.html" 0
 236 SectionEnd
 237 !endif
 238
 239 ; Optional section (can be disabled by the user)
 240 Section "$(Start_Menu_Section_Name)" Start_Menu_Section_Description
 241     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 242     CreateShortCut "$SMPROGRAMS\${PRODUCT}\$(Link_Description_Uninstall).lnk" "${UNINST_EXE}" "" "${UNINST_EXE}" 0
 243 SectionEnd
 244
 245 ;--------------------------------
 246
 247 ; Uninstaller
 248
 249 Section "Uninstall" Uninstall_Section_Description
 250     ; Remove registry keys
 251 !ifdef W64
 252     SetRegView 64
 253 !endif
 254     DeleteRegKey HKLM "${UNINST_KEY}"
 255     DeleteRegKey HKLM SOFTWARE\${PRODUCT}
 256
 257     ; Remove shortcuts, if any
 258     Delete "$SMPROGRAMS\${PRODUCT}\$(Link_Description_User_Documentation).lnk"
 259     Delete "$SMPROGRAMS\${PRODUCT}\$(Link_Description_Technical_Documentation).lnk"
 260     Delete "$SMPROGRAMS\${PRODUCT}\$(Link_Description_Uninstall).lnk"
 261     RMDir "$SMPROGRAMS\${PRODUCT}"
 262
 263     ; Remove files and directories used
 264     Delete "$INSTDIR\COPYING"
 265     Delete "$INSTDIR\COPYING.LIB"
 266     Delete "$INSTDIR\README.rst"
 267     Delete "$INSTDIR\VERSION"
 268     Delete "$INSTDIR\*.dll"
 269     Delete "$INSTDIR\qemu-*.exe"
 270     RMDir /r "$INSTDIR\lib"
 271     RMDir /r "$INSTDIR\share"
 272     ; Remove generated files
 273     Delete "$INSTDIR\stderr.txt"
 274     Delete "$INSTDIR\stdout.txt"
 275     ; Remove uninstaller
 276     Delete "${UNINST_EXE}"
 277     RMDir "$INSTDIR"
 278 SectionEnd
 279
 280 ; Include files with language installer strings.
 281 ; Language ID table - https://www.science.co.il/language/Locale-codes.php
 282 ; Language ID 1033 - English
 283 ; Language ID 1031 - German
 284 ; Language ID 1034 - Spanish
 285 ; Language ID 1036 - French
 286 ; Language ID 1040 - Italian
 287 !addincludedir ${SRCDIR}/installer
 288 !include installer_strings_english.nsh
 289 !include installer_strings_french.nsh
 290 !include installer_strings_german.nsh
 291 !include installer_strings_italian.nsh
 292 !include installer_strings_spanish.nsh
 293
 294
 295 ; ---------------------
 296
 297 ; Descriptions (mouse-over).
 298 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 299     !insertmacro MUI_DESCRIPTION_TEXT ${QEMU_System_File_Section_Description}  $(QEMU_System_File_Section_Description_Text)
 300     !insertmacro MUI_DESCRIPTION_TEXT ${Tools_Section_Description}             $(Tools_Section_Description_Text)
 301     !insertmacro MUI_DESCRIPTION_TEXT ${System_Emulation_Section_Description}  $(System_Emulation_Section_Description_Text)
 302     !insertmacro MUI_DESCRIPTION_TEXT ${Desktop_Icon_Section_Description}      $(Desktop_Icon_Section_Description_Text)
 303     !insertmacro MUI_DESCRIPTION_TEXT ${Uninstall_Section_Description}         $(Uninstall_Section_Description_Text)
 304 !include "${BINDIR}\system-mui-text.nsh"
 305 !ifdef DLLDIR
 306     !insertmacro MUI_DESCRIPTION_TEXT ${DLL_Library_Section_Description}       $(DLL_Library_Section_Description_Text)
 307 !endif
 308 !ifdef CONFIG_DOCUMENTATION
 309     !insertmacro MUI_DESCRIPTION_TEXT ${Documentation_Section_Description}     $(Documentation_Section_Description_Text)
 310 !endif
 311     !insertmacro MUI_DESCRIPTION_TEXT ${Start_Menu_Section_Description}        $(Start_Menu_Section_Description_Text)
 312 !insertmacro MUI_FUNCTION_DESCRIPTION_END