lisp/org-src.el

   1 ;;; org-src.el --- Source code examples in Org
   2 ;;
   3 ;; Copyright (C) 2004-2012 Free Software Foundation, Inc.
   4 ;;
   5 ;; Author: Carsten Dominik <carsten at orgmode dot org>
   6 ;;         Bastien Guerry <bzg AT gnu DOT org>
   7 ;;         Dan Davison <davison at stats dot ox dot ac dot uk>
   8 ;; Keywords: outlines, hypermedia, calendar, wp
   9 ;; Homepage: http://orgmode.org
  10 ;;
  11 ;; This file is part of GNU Emacs.
  12 ;;
  13 ;; GNU Emacs is free software: you can redistribute it and/or modify
  14 ;; it under the terms of the GNU General Public License as published by
  15 ;; the Free Software Foundation, either version 3 of the License, or
  16 ;; (at your option) any later version.
  17
  18 ;; GNU Emacs is distributed in the hope that it will be useful,
  19 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  20 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  21 ;; GNU General Public License for more details.
  22
  23 ;; You should have received a copy of the GNU General Public License
  24 ;; along with GNU Emacs.  If not, see <http://www.gnu.org/licenses/>.
  25 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  26 ;;
  27 ;;; Commentary:
  28
  29 ;; This file contains the code dealing with source code examples in Org-mode.
  30
  31 ;;; Code:
  32
  33 (require 'org-macs)
  34 (require 'org-compat)
  35 (require 'ob-keys)
  36 (require 'ob-comint)
  37 (eval-when-compile
  38   (require 'cl))
  39
  40 (declare-function org-do-remove-indentation "org" (&optional n))
  41 (declare-function org-at-table.el-p "org" ())
  42 (declare-function org-in-src-block-p "org" (&optional inside))
  43 (declare-function org-in-block-p "org" (names))
  44 (declare-function org-get-indentation "org" (&optional line))
  45 (declare-function org-switch-to-buffer-other-window "org" (&rest args))
  46 (declare-function org-pop-to-buffer-same-window
  47                   "org-compat" (&optional buffer-or-name norecord label))
  48 (declare-function org-base-buffer "org" (buffer))
  49
  50 (defcustom org-edit-src-region-extra nil
  51   "Additional regexps to identify regions for editing with `org-edit-src-code'.
  52 For examples see the function `org-edit-src-find-region-and-lang'.
  53 The regular expression identifying the begin marker should end with a newline,
  54 and the regexp marking the end line should start with a newline, to make sure
  55 there are kept outside the narrowed region."
  56   :group 'org-edit-structure
  57   :type '(repeat
  58           (list
  59            (regexp :tag "begin regexp")
  60            (regexp :tag "end regexp")
  61            (choice :tag "language"
  62                    (string :tag "specify")
  63                    (integer :tag "from match group")
  64                    (const :tag "from `lang' element")
  65                    (const :tag "from `style' element")))))
  66
  67 (defcustom org-coderef-label-format "(ref:%s)"
  68   "The default coderef format.
  69 This format string will be used to search for coderef labels in literal
  70 examples (EXAMPLE and SRC blocks).  The format can be overwritten in
  71 an individual literal example with the -l option, like
  72
  73 #+BEGIN_SRC pascal +n -r -l \"((%s))\"
  74 ...
  75 #+END_SRC
  76
  77 If you want to use this for HTML export, make sure that the format does
  78 not introduce special font-locking, and avoid the HTML special
  79 characters `<', `>', and `&'.  The reason for this restriction is that
  80 the labels are searched for only after htmlize has done its job."
  81   :group 'org-edit-structure ; FIXME this is not in the right group
  82   :type 'string)
  83
  84 (defcustom org-edit-fixed-width-region-mode 'artist-mode
  85   "The mode that should be used to edit fixed-width regions.
  86 These are the regions where each line starts with a colon."
  87   :group 'org-edit-structure
  88   :type '(choice
  89           (const artist-mode)
  90           (const picture-mode)
  91           (const fundamental-mode)
  92           (function :tag "Other (specify)")))
  93
  94 (defcustom org-src-preserve-indentation nil
  95   "If non-nil preserve leading whitespace characters on export.
  96 If non-nil leading whitespace characters in source code blocks
  97 are preserved on export, and when switching between the org
  98 buffer and the language mode edit buffer.  If this variable is nil
  99 then, after editing with \\[org-edit-src-code], the
 100 minimum (across-lines) number of leading whitespace characters
 101 are removed from all lines, and the code block is uniformly
 102 indented according to the value of `org-edit-src-content-indentation'."
 103   :group 'org-edit-structure
 104   :type 'boolean)
 105
 106 (defcustom org-edit-src-content-indentation 2
 107   "Indentation for the content of a source code block.
 108 This should be the number of spaces added to the indentation of the #+begin
 109 line in order to compute the indentation of the block content after
 110 editing it with \\[org-edit-src-code].  Has no effect if
 111 `org-src-preserve-indentation' is non-nil."
 112   :group 'org-edit-structure
 113   :type 'integer)
 114
 115 (defvar org-src-strip-leading-and-trailing-blank-lines nil
 116   "If non-nil, blank lines are removed when exiting the code edit buffer.")
 117
 118 (defcustom org-edit-src-persistent-message t
 119   "Non-nil means show persistent exit help message while editing src examples.
 120 The message is shown in the header-line, which will be created in the
 121 first line of the window showing the editing buffer."
 122   :group 'org-edit-structure
 123   :type 'boolean)
 124
 125 (defcustom org-src-window-setup 'reorganize-frame
 126   "How the source code edit buffer should be displayed.
 127 Possible values for this option are:
 128
 129 current-window    Show edit buffer in the current window, keeping all other
 130                   windows.
 131 other-window      Use `switch-to-buffer-other-window' to display edit buffer.
 132 reorganize-frame  Show only two windows on the current frame, the current
 133                   window and the edit buffer.  When exiting the edit buffer,
 134                   return to one window.
 135 other-frame       Use `switch-to-buffer-other-frame' to display edit buffer.
 136                   Also, when exiting the edit buffer, kill that frame."
 137   :group 'org-edit-structure
 138   :type '(choice
 139           (const current-window)
 140           (const other-frame)
 141           (const other-window)
 142           (const reorganize-frame)))
 143
 144 (defvar org-src-mode-hook nil
 145   "Hook  run after Org switched a source code snippet to its Emacs mode.
 146 This hook will run
 147
 148 - when editing a source code snippet with \"C-c '\".
 149 - When formatting a source code snippet for export with htmlize.
 150
 151 You may want to use this hook for example to turn off `outline-minor-mode'
 152 or similar things which you want to have when editing a source code file,
 153 but which mess up the display of a snippet in Org exported files.")
 154
 155 (defcustom org-src-lang-modes
 156   '(("ocaml" . tuareg) ("elisp" . emacs-lisp) ("ditaa" . artist)
 157     ("asymptote" . asy) ("dot" . fundamental) ("sqlite" . sql)
 158     ("calc" . fundamental) ("C" . c) ("cpp" . c++)
 159     ("screen" . shell-script))
 160   "Alist mapping languages to their major mode.
 161 The key is the language name, the value is the string that should
 162 be inserted as the name of the major mode.  For many languages this is
 163 simple, but for language where this is not the case, this variable
 164 provides a way to simplify things on the user side.
 165 For example, there is no ocaml-mode in Emacs, but the mode to use is
 166 `tuareg-mode'."
 167   :group 'org-edit-structure
 168   :type '(repeat
 169           (cons
 170            (string "Language name")
 171            (symbol "Major mode"))))
 172
 173 ;;; Editing source examples
 174
 175 (defvar org-src-mode-map (make-sparse-keymap))
 176 (define-key org-src-mode-map "\C-c'" 'org-edit-src-exit)
 177 (define-key org-src-mode-map "\C-x\C-s" 'org-edit-src-save)
 178
 179 (defvar org-edit-src-force-single-line nil)
 180 (defvar org-edit-src-from-org-mode nil)
 181 (defvar org-edit-src-allow-write-back-p t)
 182 (defvar org-edit-src-picture nil)
 183 (defvar org-edit-src-beg-marker nil)
 184 (defvar org-edit-src-end-marker nil)
 185 (defvar org-edit-src-overlay nil)
 186 (defvar org-edit-src-block-indentation nil)
 187 (defvar org-edit-src-saved-temp-window-config nil)
 188
 189 (defvar org-src-ask-before-returning-to-edit-buffer t
 190   "If nil, when org-edit-src code is used on a block that already
 191 has an active edit buffer, it will switch to that edit buffer
 192 immediately; otherwise it will ask whether you want to return to
 193 the existing edit buffer.")
 194
 195 (defvar org-src-babel-info nil)
 196
 197 (define-minor-mode org-src-mode
 198   "Minor mode for language major mode buffers generated by org.
 199 This minor mode is turned on in two situations:
 200 - when editing a source code snippet with \"C-c '\".
 201 - When formatting a source code snippet for export with htmlize.
 202 There is a mode hook, and keybindings for `org-edit-src-exit' and
 203 `org-edit-src-save'")
 204
 205 (defun org-edit-src-code (&optional context code edit-buffer-name)
 206   "Edit the source CODE block at point.
 207 The code is copied to a separate buffer and the appropriate mode
 208 is turned on.  When done, exit with \\[org-edit-src-exit].  This will
 209 remove the original code in the Org buffer, and replace it with the
 210 edited version.  An optional argument CONTEXT is used by \\[org-edit-src-save]
 211 when calling this function.  See `org-src-window-setup' to configure
 212 the display of windows containing the Org buffer and the code buffer."
 213   (interactive)
 214   (if (not (org-in-block-p '("src" "example" "latex" "html")))
 215       (user-error "Not in a source code or example block")
 216     (unless (eq context 'save)
 217       (setq org-edit-src-saved-temp-window-config (current-window-configuration)))
 218     (let* ((mark (and (org-region-active-p) (mark)))
 219            (case-fold-search t)
 220            (info
 221             ;; If the src region consists in no lines, we insert a blank
 222             ;; line.
 223             (let* ((temp (org-edit-src-find-region-and-lang))
 224                    (beg (nth 0 temp))
 225                    (end (nth 1 temp)))
 226               (if (>= end beg) temp
 227                 (goto-char beg)
 228                 (insert "\n")
 229                 (org-edit-src-find-region-and-lang))))
 230            (full-info (org-babel-get-src-block-info 'light))
 231            (org-mode-p (derived-mode-p 'org-mode)) ;; derived-mode-p is reflexive
 232            (beg (make-marker))
 233            ;; Move marker with inserted text for case when src block is
 234            ;; just one empty line, i.e. beg == end.
 235            (end (copy-marker (make-marker) t))
 236            (allow-write-back-p (null code))
 237            block-nindent total-nindent ovl lang lang-f single lfmt buffer msg
 238            begline markline markcol line col transmitted-variables)
 239       (setq beg (move-marker beg (nth 0 info))
 240             end (move-marker end (nth 1 info))
 241             msg (if allow-write-back-p
 242                     (substitute-command-keys
 243                      "Edit, then exit with C-c ' (C-c and single quote)")
 244                   "Exit with C-c ' (C-c and single quote)")
 245             code (or code (buffer-substring-no-properties beg end))
 246             lang (or (cdr (assoc (nth 2 info) org-src-lang-modes))
 247                      (nth 2 info))
 248             lang (if (symbolp lang) (symbol-name lang) lang)
 249             single (nth 3 info)
 250             block-nindent (nth 5 info)
 251             lang-f (intern (concat lang "-mode"))
 252             begline (save-excursion (goto-char beg) (org-current-line))
 253             transmitted-variables
 254             `((org-edit-src-content-indentation
 255                ,org-edit-src-content-indentation)
 256               (org-edit-src-force-single-line ,single)
 257               (org-edit-src-from-org-mode ,org-mode-p)
 258               (org-edit-src-allow-write-back-p ,allow-write-back-p)
 259               (org-src-preserve-indentation ,org-src-preserve-indentation)
 260               (org-src-babel-info ,(org-babel-get-src-block-info 'light))
 261               (org-coderef-label-format
 262                ,(or (nth 4 info) org-coderef-label-format))
 263               (org-edit-src-beg-marker ,beg)
 264               (org-edit-src-end-marker ,end)
 265               (org-edit-src-block-indentation ,block-nindent)))
 266       (if (and mark (>= mark beg) (<= mark (1+ end)))
 267           (save-excursion (goto-char (min mark end))
 268                           (setq markline (org-current-line)
 269                                 markcol (current-column))))
 270       (if (equal lang-f 'table.el-mode)
 271           (setq lang-f (lambda ()
 272                          (text-mode)
 273                          (if (org-bound-and-true-p flyspell-mode)
 274                              (flyspell-mode -1))
 275                          (table-recognize)
 276                          (org-set-local 'org-edit-src-content-indentation 0))))
 277       (unless (functionp lang-f)
 278         (error "No such language mode: %s" lang-f))
 279       (save-excursion
 280         (if (> (point) end) (goto-char end))
 281         (setq line (org-current-line)
 282               col (current-column)))
 283       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 284                (or (eq context 'save)
 285                    (if org-src-ask-before-returning-to-edit-buffer
 286                        (y-or-n-p "Return to existing edit buffer ([n] will revert changes)? ") t)))
 287           (org-src-switch-to-buffer buffer 'return)
 288         (when buffer
 289           (with-current-buffer buffer
 290             (if (boundp 'org-edit-src-overlay)
 291                 (delete-overlay org-edit-src-overlay)))
 292           (kill-buffer buffer))
 293         (setq buffer (generate-new-buffer
 294                       (or edit-buffer-name
 295                           (org-src-construct-edit-buffer-name (buffer-name) lang))))
 296         (setq ovl (make-overlay beg end))
 297         (overlay-put ovl 'edit-buffer buffer)
 298         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 299         (overlay-put ovl 'face 'secondary-selection)
 300         (overlay-put ovl
 301                      'keymap
 302                      (let ((map (make-sparse-keymap)))
 303                        (define-key map [mouse-1] 'org-edit-src-continue)
 304                        map))
 305         (overlay-put ovl :read-only "Leave me alone")
 306         (setq transmitted-variables
 307               (append transmitted-variables `((org-edit-src-overlay ,ovl))))
 308         (org-src-switch-to-buffer buffer 'edit)
 309         (if (eq single 'macro-definition)
 310             (setq code (replace-regexp-in-string "\\\\n" "\n" code t t)))
 311         (insert code)
 312         (remove-text-properties (point-min) (point-max)
 313                                 '(display nil invisible nil intangible nil))
 314         (unless (cadr (assq 'org-src-preserve-indentation transmitted-variables))
 315           (setq total-nindent (or (org-do-remove-indentation) 0)))
 316         (let ((org-inhibit-startup t))
 317           (condition-case e
 318               (funcall lang-f)
 319             (error
 320              (error "Language mode `%s' fails with: %S" lang-f (nth 1 e)))))
 321         (dolist (pair transmitted-variables)
 322           (org-set-local (car pair) (cadr pair)))
 323         ;; Remove protecting commas from visible part of buffer.
 324         (org-unescape-code-in-region (point-min) (point-max))
 325         (when markline
 326           (org-goto-line (1+ (- markline begline)))
 327           (org-move-to-column
 328            (if org-src-preserve-indentation markcol
 329              (max 0 (- markcol total-nindent))))
 330           (push-mark (point) 'no-message t)
 331           (setq deactivate-mark nil))
 332         (org-goto-line (1+ (- line begline)))
 333         (org-move-to-column
 334          (if org-src-preserve-indentation col (max 0 (- col total-nindent))))
 335         (org-src-mode)
 336         (set-buffer-modified-p nil)
 337         (setq buffer-file-name nil)
 338         (and org-edit-src-persistent-message
 339              (org-set-local 'header-line-format msg))
 340         (let ((edit-prep-func (intern (concat "org-babel-edit-prep:" lang))))
 341           (when (fboundp edit-prep-func)
 342             (funcall edit-prep-func full-info))))
 343       t)))
 344
 345 (defun org-edit-src-continue (e)
 346   "Continue editing source blocks." ;; Fixme: be more accurate
 347   (interactive "e")
 348   (mouse-set-point e)
 349   (let ((buf (get-char-property (point) 'edit-buffer)))
 350     (if buf (org-src-switch-to-buffer buf 'continue)
 351       (error "Something is wrong here"))))
 352
 353 (defun org-src-switch-to-buffer (buffer context)
 354   (case org-src-window-setup
 355     ('current-window
 356      (org-pop-to-buffer-same-window buffer))
 357     ('other-window
 358      (switch-to-buffer-other-window buffer))
 359     ('other-frame
 360      (case context
 361        ('exit
 362         (let ((frame (selected-frame)))
 363           (switch-to-buffer-other-frame buffer)
 364           (delete-frame frame)))
 365        ('save
 366         (kill-buffer (current-buffer))
 367         (org-pop-to-buffer-same-window buffer))
 368        (t
 369         (switch-to-buffer-other-frame buffer))))
 370     ('reorganize-frame
 371      (if (eq context 'edit) (delete-other-windows))
 372      (org-switch-to-buffer-other-window buffer)
 373      (if (eq context 'exit) (delete-other-windows)))
 374     ('switch-invisibly
 375      (set-buffer buffer))
 376     (t
 377      (message "Invalid value %s for org-src-window-setup"
 378               (symbol-name org-src-window-setup))
 379      (org-pop-to-buffer-same-window buffer))))
 380
 381 (defun org-src-construct-edit-buffer-name (org-buffer-name lang)
 382   "Construct the buffer name for a source editing buffer."
 383   (concat "*Org Src " org-buffer-name "[ " lang " ]*"))
 384
 385 (defun org-src-edit-buffer-p (&optional buffer)
 386   "Test whether BUFFER (or the current buffer if BUFFER is nil)
 387 is a source block editing buffer."
 388   (let ((buffer (org-base-buffer (or buffer (current-buffer)))))
 389     (and (buffer-name buffer)
 390          (string-match "\\`*Org Src " (buffer-name buffer))
 391          (local-variable-p 'org-edit-src-beg-marker buffer)
 392          (local-variable-p 'org-edit-src-end-marker buffer))))
 393
 394 (defun org-edit-src-find-buffer (beg end)
 395   "Find a source editing buffer that is already editing the region BEG to END."
 396   (catch 'exit
 397     (mapc
 398      (lambda (b)
 399        (with-current-buffer b
 400          (if (and (string-match "\\`*Org Src " (buffer-name))
 401                   (local-variable-p 'org-edit-src-beg-marker (current-buffer))
 402                   (local-variable-p 'org-edit-src-end-marker (current-buffer))
 403                   (equal beg org-edit-src-beg-marker)
 404                   (equal end org-edit-src-end-marker))
 405              (throw 'exit (current-buffer)))))
 406      (buffer-list))
 407     nil))
 408
 409 (defun org-edit-fixed-width-region ()
 410   "Edit the fixed-width ascii drawing at point.
 411 This must be a region where each line starts with a colon followed by
 412 a space character.
 413 An new buffer is created and the fixed-width region is copied into it,
 414 and the buffer is switched into `artist-mode' for editing.  When done,
 415 exit with \\[org-edit-src-exit].  The edited text will then replace
 416 the fragment in the Org-mode buffer."
 417   (interactive)
 418   (let ((line (org-current-line))
 419         (col (current-column))
 420         (case-fold-search t)
 421         (msg (substitute-command-keys
 422               "Edit, then exit with C-c ' (C-c and single quote)"))
 423         (org-mode-p (derived-mode-p 'org-mode))
 424         (beg (make-marker))
 425         (end (make-marker))
 426         (preserve-indentation org-src-preserve-indentation)
 427         block-nindent ovl beg1 end1 code begline buffer)
 428     (beginning-of-line 1)
 429     (if (looking-at "[ \t]*[^:\n \t]")
 430         nil
 431       (if (looking-at "[ \t]*\\(\n\\|\\'\\)")
 432           (setq beg1 (point) end1 beg1)
 433         (save-excursion
 434           (if (re-search-backward "^[ \t]*[^: \t]" nil 'move)
 435               (setq beg1 (point-at-bol 2))
 436             (setq beg1 (point))))
 437         (save-excursion
 438           (if (re-search-forward "^[ \t]*[^: \t]" nil 'move)
 439               (setq end1 (1- (match-beginning 0)))
 440             (setq end1 (point))))
 441         (org-goto-line line))
 442       (setq beg (move-marker beg beg1)
 443             end (move-marker end end1)
 444             code (buffer-substring-no-properties beg end)
 445             begline (save-excursion (goto-char beg) (org-current-line)))
 446       (if (and (setq buffer (org-edit-src-find-buffer beg end))
 447                (y-or-n-p "Return to existing edit buffer ([n] will revert changes)? "))
 448           (org-pop-to-buffer-same-window buffer)
 449         (when buffer
 450           (with-current-buffer buffer
 451             (if (boundp 'org-edit-src-overlay)
 452                 (delete-overlay org-edit-src-overlay)))
 453           (kill-buffer buffer))
 454         (setq buffer (generate-new-buffer
 455                       (org-src-construct-edit-buffer-name
 456                        (buffer-name) "Fixed Width")))
 457         (setq ovl (make-overlay beg end))
 458         (overlay-put ovl 'face 'secondary-selection)
 459         (overlay-put ovl 'edit-buffer buffer)
 460         (overlay-put ovl 'help-echo "Click with mouse-1 to switch to buffer editing this segment")
 461         (overlay-put ovl 'face 'secondary-selection)
 462         (overlay-put ovl
 463                      'keymap
 464                      (let ((map (make-sparse-keymap)))
 465                        (define-key map [mouse-1] 'org-edit-src-continue)
 466                        map))
 467         (overlay-put ovl :read-only "Leave me alone")
 468         (org-pop-to-buffer-same-window buffer)
 469         (insert code)
 470         (remove-text-properties (point-min) (point-max)
 471                                 '(display nil invisible nil intangible nil))
 472         (setq block-nindent (or (org-do-remove-indentation) 0))
 473         (cond
 474          ((eq org-edit-fixed-width-region-mode 'artist-mode)
 475           (fundamental-mode)
 476           (artist-mode 1))
 477          (t (funcall org-edit-fixed-width-region-mode)))
 478         (set (make-local-variable 'org-edit-src-force-single-line) nil)
 479         (set (make-local-variable 'org-edit-src-from-org-mode) org-mode-p)
 480         (set (make-local-variable 'org-edit-src-picture) t)
 481         (goto-char (point-min))
 482         (while (re-search-forward "^[ \t]*: ?" nil t)
 483           (replace-match ""))
 484         (org-goto-line (1+ (- line begline)))
 485         (org-move-to-column (max 0 (- col block-nindent 2)))
 486         (org-set-local 'org-edit-src-beg-marker beg)
 487         (org-set-local 'org-edit-src-end-marker end)
 488         (org-set-local 'org-edit-src-overlay ovl)
 489         (org-set-local 'org-edit-src-block-indentation block-nindent)
 490         (org-set-local 'org-edit-src-content-indentation 0)
 491         (org-set-local 'org-src-preserve-indentation nil)
 492         (org-src-mode)
 493         (set-buffer-modified-p nil)
 494         (and org-edit-src-persistent-message
 495              (org-set-local 'header-line-format msg)))
 496       (message "%s" msg)
 497       t)))
 498
 499 (defun org-edit-src-find-region-and-lang ()
 500   "Find the region and language for a local edit.
 501 Return a list with beginning and end of the region, a string representing
 502 the language, a switch telling if the content should be in a single line."
 503   (let ((re-list
 504          (append
 505           org-edit-src-region-extra
 506           '(
 507             ("<src\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</src>" lang)
 508             ("<literal\\>[^<]*>[ \t]*\n?" "\n?[ \t]*</literal>" style)
 509             ("<example>[ \t]*\n?" "\n?[ \t]*</example>" "fundamental")
 510             ("<lisp>[ \t]*\n?" "\n?[ \t]*</lisp>" "emacs-lisp")
 511             ("<perl>[ \t]*\n?" "\n?[ \t]*</perl>" "perl")
 512             ("<python>[ \t]*\n?" "\n?[ \t]*</python>" "python")
 513             ("<ruby>[ \t]*\n?" "\n?[ \t]*</ruby>" "ruby")
 514             ("^[ \t]*#\\+begin_src\\( \\([^ \t\n]+\\)\\)?.*\n" "\n[ \t]*#\\+end_src" 2)
 515             ("^[ \t]*#\\+begin_example.*\n" "\n[ \t]*#\\+end_example" "fundamental")
 516             ("^[ \t]*#\\+html:" "\n" "html" single-line)
 517             ("^[ \t]*#\\+begin_html.*\n" "\n[ \t]*#\\+end_html" "html")
 518             ("^[ \t]*#\\+latex:" "\n" "latex" single-line)
 519             ("^[ \t]*#\\+begin_latex.*\n" "\n[ \t]*#\\+end_latex" "latex")
 520             ("^[ \t]*#\\+ascii:" "\n" "fundamental" single-line)
 521             ("^[ \t]*#\\+begin_ascii.*\n" "\n[ \t]*#\\+end_ascii" "fundamental")
 522             ("^[ \t]*#\\+docbook:" "\n" "xml" single-line)
 523             ("^[ \t]*#\\+macro:[ \t]+\\S-+\\( \\|$\\)"
 524              "\n" "fundamental" macro-definition)
 525             ("^[ \t]*#\\+begin_docbook.*\n" "\n[ \t]*#\\+end_docbook" "xml")
 526             )))
 527         (pos (point))
 528         re1 re2 single beg end lang lfmt match-re1 ind entry)
 529     (catch 'exit
 530       (while (setq entry (pop re-list))
 531         (setq re1 (car entry) re2 (nth 1 entry) lang (nth 2 entry)
 532               single (nth 3 entry))
 533         (save-excursion
 534           (if (or (looking-at re1)
 535                   (re-search-backward re1 nil t))
 536               (progn
 537                 (setq match-re1 (match-string 0))
 538                 (setq beg (match-end 0)
 539                       lang (org-edit-src-get-lang lang)
 540                       lfmt (org-edit-src-get-label-format match-re1)
 541                       ind (org-edit-src-get-indentation (match-beginning 0)))
 542                 (if (and (re-search-forward re2 nil t)
 543                          (>= (match-end 0) pos))
 544                     (throw 'exit (list beg (match-beginning 0)
 545                                        lang single lfmt ind))))
 546             (if (or (looking-at re2)
 547                     (re-search-forward re2 nil t))
 548                 (progn
 549                   (setq end (match-beginning 0))
 550                   (if (and (re-search-backward re1 nil t)
 551                            (<= (match-beginning 0) pos))
 552                       (progn
 553                         (setq lfmt (org-edit-src-get-label-format
 554                                     (match-string 0))
 555                               ind (org-edit-src-get-indentation
 556                                    (match-beginning 0)))
 557                         (throw 'exit
 558                                (list (match-end 0) end
 559                                      (org-edit-src-get-lang lang)
 560                                      single lfmt ind)))))))))
 561       (when (org-at-table.el-p)
 562         (re-search-backward "^[\t]*[^ \t|\\+]" nil t)
 563         (setq beg (1+ (point-at-eol)))
 564         (goto-char beg)
 565         (or (re-search-forward "^[\t]*[^ \t|\\+]" nil t)
 566             (progn (goto-char (point-max)) (newline)))
 567         (setq end (point-at-bol))
 568         (setq ind (org-edit-src-get-indentation beg))
 569         (throw 'exit (list beg end 'table.el nil nil ind))))))
 570
 571 (defun org-edit-src-get-lang (lang)
 572   "Extract the src language."
 573   (let ((m (match-string 0)))
 574     (cond
 575      ((stringp lang) lang)
 576      ((integerp lang) (match-string lang))
 577      ((and (eq lang 'lang)
 578            (string-match "\\<lang=\"\\([^ \t\n\"]+\\)\"" m))
 579       (match-string 1 m))
 580      ((and (eq lang 'style)
 581            (string-match "\\<style=\"\\([^ \t\n\"]+\\)\"" m))
 582       (match-string 1 m))
 583      (t "fundamental"))))
 584
 585 (defun org-edit-src-get-label-format (s)
 586   "Extract the label format."
 587   (save-match-data
 588     (if (string-match "-l[ \t]+\\\\?\"\\([^\t\r\n\"]+\\)\\\\?\"" s)
 589         (match-string 1 s))))
 590
 591 (defun org-edit-src-get-indentation (pos)
 592   "Count leading whitespace characters on line."
 593   (save-match-data
 594     (goto-char pos)
 595     (org-get-indentation)))
 596
 597 (defun org-escape-code-in-region (beg end)
 598   "Escape lines between BEG and END.
 599 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 600 \",#+\" by appending a comma to it."
 601   (interactive "r")
 602   (save-excursion
 603     (goto-char beg)
 604     (while (re-search-forward "^[ \t]*,?\\(\\*\\|#\\+\\)" end t)
 605       (replace-match ",\\1" nil nil nil 1))))
 606
 607 (defun org-escape-code-in-string (s)
 608   "Escape lines in string S.
 609 Escaping happens when a line starts with \"*\", \"#+\", \",*\" or
 610 \",#+\" by appending a comma to it."
 611   (replace-regexp-in-string "^[ \t]*,?\\(\\*\\|#\\+\\)" ",\\1" s nil nil 1))
 612
 613 (defun org-unescape-code-in-region (beg end)
 614   "Un-escape lines between BEG and END.
 615 Un-escaping happens by removing the first comma on lines starting
 616 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 617   (interactive "r")
 618   (save-excursion
 619     (goto-char beg)
 620     (while (re-search-forward "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" end t)
 621       (replace-match "" nil nil nil 1))))
 622
 623 (defun org-unescape-code-in-string (s)
 624   "Un-escape lines in string S.
 625 Un-escaping happens by removing the first comma on lines starting
 626 with \",*\", \",#+\", \",,*\" and \",,#+\"."
 627   (replace-regexp-in-string
 628    "^[ \t]*,?\\(,\\)\\(?:\\*\\|#\\+\\)" "" s nil nil 1))
 629
 630 (defun org-edit-src-exit (&optional context)
 631   "Exit special edit and protect problematic lines."
 632   (interactive)
 633   (unless (org-bound-and-true-p org-edit-src-from-org-mode)
 634     (error "This is not a sub-editing buffer, something is wrong"))
 635   (widen)
 636   (let* ((fixed-width-p (string-match "Fixed Width" (buffer-name)))
 637          (beg org-edit-src-beg-marker)
 638          (end org-edit-src-end-marker)
 639          (ovl org-edit-src-overlay)
 640          (bufstr (buffer-string))
 641          (buffer (current-buffer))
 642          (single (org-bound-and-true-p org-edit-src-force-single-line))
 643          (macro (eq single 'macro-definition))
 644          (total-nindent (+ (or org-edit-src-block-indentation 0)
 645                            org-edit-src-content-indentation))
 646          (preserve-indentation org-src-preserve-indentation)
 647          (allow-write-back-p (org-bound-and-true-p org-edit-src-allow-write-back-p))
 648          (delta 0) code line col indent)
 649     (when allow-write-back-p
 650       (unless preserve-indentation (untabify (point-min) (point-max)))
 651       (if org-src-strip-leading-and-trailing-blank-lines
 652           (save-excursion
 653             (goto-char (point-min))
 654             (if (looking-at "[ \t\n]*\n") (replace-match ""))
 655             (unless macro
 656               (if (re-search-forward "\n[ \t\n]*\\'" nil t) (replace-match ""))))))
 657     (setq line (if (org-bound-and-true-p org-edit-src-force-single-line)
 658                    1
 659                  (org-current-line))
 660           col (current-column))
 661     (when allow-write-back-p
 662       (when single
 663         (goto-char (point-min))
 664         (if (re-search-forward "\\s-+\\'" nil t) (replace-match ""))
 665         (goto-char (point-min))
 666         (let ((cnt 0))
 667           (while (re-search-forward "\n" nil t)
 668             (setq cnt (1+ cnt))
 669             (replace-match (if macro "\\n" " ") t t))
 670           (when (and macro (> cnt 0))
 671             (goto-char (point-max)) (insert "\\n")))
 672         (goto-char (point-min))
 673         (if (looking-at "\\s-*") (replace-match " ")))
 674       (when (and (org-bound-and-true-p org-edit-src-from-org-mode)
 675                  (not fixed-width-p))
 676         (org-escape-code-in-region (point-min) (point-max))
 677         (setq delta (+ delta
 678                        (save-excursion
 679                          (org-goto-line line)
 680                          (if (looking-at "[ \t]*\\(,,\\)?\\(\\*\\|#+\\)") 1
 681                            0)))))
 682       (when (org-bound-and-true-p org-edit-src-picture)
 683         (setq preserve-indentation nil)
 684         (untabify (point-min) (point-max))
 685         (goto-char (point-min))
 686         (while (re-search-forward "^" nil t)
 687           (replace-match ": ")))
 688       (unless (or single preserve-indentation (= total-nindent 0))
 689         (setq indent (make-string total-nindent ?\ ))
 690         (goto-char (point-min))
 691         (while (re-search-forward "^" nil t)
 692           (replace-match indent)))
 693       (if (org-bound-and-true-p org-edit-src-picture)
 694           (setq total-nindent (+ total-nindent 2)))
 695       (setq code (buffer-string))
 696       (when (eq context 'save)
 697         (erase-buffer)
 698         (insert bufstr))
 699       (set-buffer-modified-p nil))
 700     (org-src-switch-to-buffer (marker-buffer beg) (or context 'exit))
 701     (if (eq context 'save) (save-buffer)
 702       (kill-buffer buffer))
 703     (goto-char beg)
 704     (when allow-write-back-p
 705       (delete-region beg (max beg end))
 706       (unless (string-match "\\`[ \t]*\\'" code)
 707         (insert code))
 708       (goto-char beg)
 709       (if single (just-one-space)))
 710     (if (memq t (mapcar (lambda (overlay)
 711                           (eq (overlay-get overlay 'invisible)
 712                               'org-hide-block))
 713                         (overlays-at (point))))
 714         ;; Block is hidden; put point at start of block
 715         (beginning-of-line 0)
 716       ;; Block is visible, put point where it was in the code buffer
 717       (org-goto-line (1- (+ (org-current-line) line)))
 718       (org-move-to-column (if preserve-indentation col (+ col total-nindent delta))))
 719     (unless (eq context 'save)
 720       (move-marker beg nil)
 721       (move-marker end nil)))
 722   (unless (eq context 'save)
 723     (when org-edit-src-saved-temp-window-config
 724       (set-window-configuration org-edit-src-saved-temp-window-config)
 725       (setq org-edit-src-saved-temp-window-config nil))))
 726
 727 (defmacro org-src-in-org-buffer (&rest body)
 728   `(let ((p (point)) (m (mark)) (ul buffer-undo-list) msg)
 729      (save-window-excursion
 730        (org-edit-src-exit 'save)
 731        ,@body
 732        (setq msg (current-message))
 733        (if (eq org-src-window-setup 'other-frame)
 734            (let ((org-src-window-setup 'current-window))
 735              (org-edit-src-code 'save))
 736          (org-edit-src-code 'save)))
 737      (setq buffer-undo-list ul)
 738      (push-mark m 'nomessage)
 739      (goto-char (min p (point-max)))
 740      (message (or msg ""))))
 741 (def-edebug-spec org-src-in-org-buffer (body))
 742
 743 (defun org-edit-src-save ()
 744   "Save parent buffer with current state source-code buffer."
 745   (interactive)
 746   (org-src-in-org-buffer (save-buffer)))
 747
 748 (declare-function org-babel-tangle "ob-tangle" (&optional only-this-block target-file lang))
 749
 750 (defun org-src-tangle (arg)
 751   "Tangle the parent buffer."
 752   (interactive)
 753   (org-src-in-org-buffer (org-babel-tangle arg)))
 754
 755 (defun org-src-mode-configure-edit-buffer ()
 756   (when (org-bound-and-true-p org-edit-src-from-org-mode)
 757     (org-add-hook 'kill-buffer-hook
 758                   #'(lambda () (delete-overlay org-edit-src-overlay)) nil 'local)
 759     (if (org-bound-and-true-p org-edit-src-allow-write-back-p)
 760         (progn
 761           (setq buffer-offer-save t)
 762           (setq buffer-file-name
 763                 (concat (buffer-file-name (marker-buffer org-edit-src-beg-marker))
 764                         "[" (buffer-name) "]"))
 765           (if (featurep 'xemacs)
 766               (progn
 767                 (make-variable-buffer-local 'write-contents-hooks) ; needed only for 21.4
 768                 (setq write-contents-hooks '(org-edit-src-save)))
 769             (setq write-contents-functions '(org-edit-src-save))))
 770       (setq buffer-read-only t))))
 771
 772 (org-add-hook 'org-src-mode-hook 'org-src-mode-configure-edit-buffer)
 773
 774
 775 (defun org-src-associate-babel-session (info)
 776   "Associate edit buffer with comint session."
 777   (interactive)
 778   (let ((session (cdr (assoc :session (nth 2 info)))))
 779     (and session (not (string= session "none"))
 780          (org-babel-comint-buffer-livep session)
 781          ((lambda (f) (and (fboundp f) (funcall f session)))
 782           (intern (format "org-babel-%s-associate-session" (nth 0 info)))))))
 783
 784 (defun org-src-babel-configure-edit-buffer ()
 785   (when org-src-babel-info
 786     (org-src-associate-babel-session org-src-babel-info)))
 787
 788 (org-add-hook 'org-src-mode-hook 'org-src-babel-configure-edit-buffer)
 789 (defmacro org-src-do-at-code-block (&rest body)
 790   "Execute a command from an edit buffer in the Org-mode buffer."
 791   `(let ((beg-marker org-edit-src-beg-marker))
 792      (if beg-marker
 793          (with-current-buffer (marker-buffer beg-marker)
 794            (goto-char (marker-position beg-marker))
 795            ,@body))))
 796 (def-edebug-spec org-src-do-at-code-block (body))
 797
 798 (defun org-src-do-key-sequence-at-code-block (&optional key)
 799   "Execute key sequence at code block in the source Org buffer.
 800 The command bound to KEY in the Org-babel key map is executed
 801 remotely with point temporarily at the start of the code block in
 802 the Org buffer.
 803
 804 This command is not bound to a key by default, to avoid conflicts
 805 with language major mode bindings.  To bind it to C-c @ in all
 806 language major modes, you could use
 807
 808   (add-hook 'org-src-mode-hook
 809             (lambda () (define-key org-src-mode-map \"\\C-c@\"
 810                     'org-src-do-key-sequence-at-code-block)))
 811
 812 In that case, for example, C-c @ t issued in code edit buffers
 813 would tangle the current Org code block, C-c @ e would execute
 814 the block and C-c @ h would display the other available
 815 Org-babel commands."
 816   (interactive "kOrg-babel key: ")
 817   (if (equal key (kbd "C-g")) (keyboard-quit)
 818     (org-edit-src-save)
 819     (org-src-do-at-code-block
 820      (call-interactively
 821       (lookup-key org-babel-map key)))))
 822
 823 (defcustom org-src-tab-acts-natively nil
 824   "If non-nil, the effect of TAB in a code block is as if it were
 825 issued in the language major mode buffer."
 826   :type 'boolean
 827   :version "24.1"
 828   :group 'org-babel)
 829
 830 (defun org-src-native-tab-command-maybe ()
 831   "Perform language-specific TAB action.
 832 Alter code block according to effect of TAB in the language major
 833 mode."
 834   (and org-src-tab-acts-natively
 835        (not (equal this-command 'org-shifttab))
 836        (let ((org-src-strip-leading-and-trailing-blank-lines nil))
 837          (org-babel-do-key-sequence-in-edit-buffer (kbd "TAB")))))
 838
 839 (add-hook 'org-tab-first-hook 'org-src-native-tab-command-maybe)
 840
 841 (defun org-src-font-lock-fontify-block (lang start end)
 842   "Fontify code block.
 843 This function is called by emacs automatic fontification, as long
 844 as `org-src-fontify-natively' is non-nil.  For manual
 845 fontification of code blocks see `org-src-fontify-block' and
 846 `org-src-fontify-buffer'"
 847   (let ((lang-mode (org-src-get-lang-mode lang)))
 848     (if (fboundp lang-mode)
 849         (let ((string (buffer-substring-no-properties start end))
 850               (modified (buffer-modified-p))
 851               (org-buffer (current-buffer)) pos next)
 852           (remove-text-properties start end '(face nil))
 853           (with-current-buffer
 854               (get-buffer-create
 855                (concat " org-src-fontification:" (symbol-name lang-mode)))
 856             (delete-region (point-min) (point-max))
 857             (insert string " ") ;; so there's a final property change
 858             (unless (eq major-mode lang-mode) (funcall lang-mode))
 859             (font-lock-fontify-buffer)
 860             (setq pos (point-min))
 861             (while (setq next (next-single-property-change pos 'face))
 862               (put-text-property
 863                (+ start (1- pos)) (1- (+ start next)) 'face
 864                (get-text-property pos 'face) org-buffer)
 865               (setq pos next)))
 866           (add-text-properties
 867            start end
 868            '(font-lock-fontified t fontified t font-lock-multiline t))
 869           (set-buffer-modified-p modified)))))
 870
 871 (defun org-src-fontify-block ()
 872   "Fontify code block at point."
 873   (interactive)
 874   (save-excursion
 875     (let ((org-src-fontify-natively t)
 876           (info (org-edit-src-find-region-and-lang)))
 877       (font-lock-fontify-region (nth 0 info) (nth 1 info)))))
 878
 879 (defun org-src-fontify-buffer ()
 880   "Fontify all code blocks in the current buffer."
 881   (interactive)
 882   (org-babel-map-src-blocks nil
 883     (org-src-fontify-block)))
 884
 885 (defun org-src-get-lang-mode (lang)
 886   "Return major mode that should be used for LANG.
 887 LANG is a string, and the returned major mode is a symbol."
 888   (intern
 889    (concat
 890     ((lambda (l) (if (symbolp l) (symbol-name l) l))
 891      (or (cdr (assoc lang org-src-lang-modes)) lang)) "-mode")))
 892
 893 (provide 'org-src)
 894
 895 ;;; org-src.el ends here