lisp/muse-latex.el

   1 ;;; muse-latex.el --- publish entries in LaTex or PDF format
   2
   3 ;; Copyright (C) 2004, 2005, 2006, 2007, 2008, 2009
   4 ;;   Free Software Foundation, Inc.
   5
   6 ;; This file is part of Emacs Muse.  It is not part of GNU Emacs.
   7
   8 ;; Emacs Muse is free software; you can redistribute it and/or modify
   9 ;; it under the terms of the GNU General Public License as published
  10 ;; by the Free Software Foundation; either version 3, or (at your
  11 ;; option) any later version.
  12
  13 ;; Emacs Muse is distributed in the hope that it will be useful, but
  14 ;; WITHOUT ANY WARRANTY; without even the implied warranty of
  15 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 ;; General Public License for more details.
  17
  18 ;; You should have received a copy of the GNU General Public License
  19 ;; along with Emacs Muse; see the file COPYING.  If not, write to the
  20 ;; Free Software Foundation, Inc., 51 Franklin Street, Fifth Floor,
  21 ;; Boston, MA 02110-1301, USA.
  22
  23 ;;; Commentary:
  24
  25 ;;; Contributors:
  26
  27 ;; Li Daobing (lidaobing AT gmail DOT com) provided CJK support.
  28
  29 ;; Trent Buck (trentbuck AT gmail DOT com) gave valuable advice for
  30 ;; how to treat LaTeX specials and the like.
  31
  32 ;; Matthias Kegelmann (mathias DOT kegelmann AT sdm DOT de) provided a
  33 ;; scenario where we would need to respect the <contents> tag.
  34
  35 ;; Jean Magnan de Bornier (jean AT bornier DOT net) provided the
  36 ;; markup string for link-and-anchor.
  37
  38 ;; Jim Ottaway (j DOT ottaway AT lse DOT ac DOT uk) implemented slides
  39 ;; and lecture notes.
  40
  41 ;; Karl Berry (karl AT freefriends DOT org) suggested how to escape
  42 ;; additional special characters in image filenames.
  43
  44 ;;; Code:
  45
  46 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  47 ;;
  48 ;; Muse LaTeX Publishing
  49 ;;
  50 ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
  51
  52 (require 'muse-publish)
  53
  54 (defgroup muse-latex nil
  55   "Rules for marking up a Muse file as a LaTeX article."
  56   :group 'muse-publish)
  57
  58 (defcustom muse-latex-extension ".tex"
  59   "Default file extension for publishing LaTeX files."
  60   :type 'string
  61   :group 'muse-latex)
  62
  63 (defcustom muse-latex-pdf-extension ".pdf"
  64   "Default file extension for publishing LaTeX files to PDF."
  65   :type 'string
  66   :group 'muse-latex)
  67
  68 (defcustom muse-latex-pdf-browser "open %s"
  69   "The program to use when browsing a published PDF file.
  70 This should be a format string."
  71   :type 'string
  72   :group 'muse-latex)
  73
  74 (defcustom muse-latex-pdf-program "pdflatex"
  75   "The program that is called to generate PDF content from LaTeX content."
  76   :type 'string
  77   :group 'muse-latex)
  78
  79 (defcustom muse-latex-pdf-cruft
  80   '(".aux" ".log" ".nav" ".out" ".snm" ".toc" ".vrb")
  81   "Extensions of files to remove after generating PDF output successfully."
  82   :type 'string
  83   :group 'muse-latex)
  84
  85 (defcustom muse-latex-header
  86   "\\documentclass{article}
  87
  88 \\usepackage[english]{babel}
  89 \\usepackage{ucs}
  90 \\usepackage[utf8x]{inputenc}
  91 \\usepackage[T1]{fontenc}
  92 \\usepackage{hyperref}
  93 \\usepackage[pdftex]{graphicx}
  94
  95 \\def\\museincludegraphics{%
  96   \\begingroup
  97   \\catcode`\\|=0
  98   \\catcode`\\\\=12
  99   \\catcode`\\#=12
 100   \\includegraphics[width=0.75\\textwidth]
 101 }
 102
 103 \\begin{document}
 104
 105 \\title{<lisp>(muse-publish-escape-specials-in-string
 106   (muse-publishing-directive \"title\") 'document)</lisp>}
 107 \\author{<lisp>(muse-publishing-directive \"author\")</lisp>}
 108 \\date{<lisp>(muse-publishing-directive \"date\")</lisp>}
 109
 110 \\maketitle
 111
 112 <lisp>(and muse-publish-generate-contents
 113            (not muse-latex-permit-contents-tag)
 114            \"\\\\tableofcontents\n\\\\newpage\")</lisp>\n\n"
 115   "Header used for publishing LaTeX files.  This may be text or a filename."
 116   :type 'string
 117   :group 'muse-latex)
 118
 119 (defcustom muse-latex-footer "<lisp>(muse-latex-bibliography)</lisp>
 120 \\end{document}\n"
 121   "Footer used for publishing LaTeX files.  This may be text or a filename."
 122   :type 'string
 123   :group 'muse-latex)
 124
 125 (defcustom muse-latexcjk-header
 126   "\\documentclass{article}
 127
 128 \\usepackage{CJK}
 129 \\usepackage{indentfirst}
 130 \\usepackage[CJKbookmarks=true]{hyperref}
 131 \\usepackage[pdftex]{graphicx}
 132
 133 \\begin{document}
 134 \\begin{CJK*}<lisp>(muse-latexcjk-encoding)</lisp>
 135
 136 \\title{<lisp>(muse-publish-escape-specials-in-string
 137   (muse-publishing-directive \"title\") 'document)</lisp>}
 138 \\author{<lisp>(muse-publishing-directive \"author\")</lisp>}
 139 \\date{<lisp>(muse-publishing-directive \"date\")</lisp>}
 140
 141 \\maketitle
 142
 143 <lisp>(and muse-publish-generate-contents
 144            (not muse-latex-permit-contents-tag)
 145            \"\\\\tableofcontents\n\\\\newpage\")</lisp>\n\n"
 146   "Header used for publishing LaTeX files (CJK).  This may be text or a
 147 filename."
 148   :type 'string
 149   :group 'muse-latex)
 150
 151 (defcustom muse-latexcjk-footer
 152   "\n\\end{CJK*}
 153 \\end{document}\n"
 154   "Footer used for publishing LaTeX files (CJK).  This may be text or a
 155 filename."
 156   :type 'string
 157   :group 'muse-latex)
 158
 159 (defcustom muse-latex-slides-header
 160   "\\documentclass[ignorenonframetext]{beamer}
 161
 162 \\usepackage[english]{babel}
 163 \\usepackage{ucs}
 164 \\usepackage[utf8x]{inputenc}
 165 \\usepackage[T1]{fontenc}
 166 \\usepackage{hyperref}
 167
 168 \\def\\museincludegraphics{%
 169   \\begingroup
 170   \\catcode`\\|=0
 171   \\catcode`\\\\=12
 172   \\catcode`\\#=12
 173   \\includegraphics[width=0.50\\textwidth]
 174 }
 175
 176 \\title{<lisp>(muse-publish-escape-specials-in-string
 177   (muse-publishing-directive \"title\") 'document)</lisp>}
 178 \\author{<lisp>(muse-publishing-directive \"author\")</lisp>}
 179 \\date{<lisp>(muse-publishing-directive \"date\")</lisp>}
 180
 181 \\begin{document}
 182
 183 \\frame{\\titlepage}
 184
 185 <lisp>(and muse-publish-generate-contents
 186            \"\\\\frame{\\\\tableofcontents}\")</lisp>\n\n"
 187   "Header for publishing of slides using LaTeX.
 188 This may be text or a filename.
 189
 190 You must have the Beamer extension for LaTeX installed for this to work."
 191   :type 'string
 192   :group 'muse-latex)
 193
 194 (defcustom muse-latex-lecture-notes-header
 195   "\\documentclass{article}
 196 \\usepackage{beamerarticle}
 197
 198 \\usepackage[english]{babel}
 199 \\usepackage{ucs}
 200 \\usepackage[utf8x]{inputenc}
 201 \\usepackage[T1]{fontenc}
 202 \\usepackage{hyperref}
 203 \\usepackage[pdftex]{graphicx}
 204
 205 \\def\\museincludegraphics{%
 206   \\begingroup
 207   \\catcode`\\|=0
 208   \\catcode`\\\\=12
 209   \\catcode`\\#=12
 210   \\includegraphics[width=0.50\\textwidth]
 211 }
 212
 213 \\title{<lisp>(muse-publish-escape-specials-in-string
 214   (muse-publishing-directive \"title\") 'document)</lisp>}
 215 \\author{<lisp>(muse-publishing-directive \"author\")</lisp>}
 216 \\date{<lisp>(muse-publishing-directive \"date\")</lisp>}
 217
 218 \\begin{document}
 219
 220 \\frame{\\titlepage}
 221
 222 <lisp>(and muse-publish-generate-contents
 223            \"\\\\frame{\\\\tableofcontents}\")</lisp>\n\n"
 224   "Header for publishing of lecture notes using LaTeX.
 225 This may be text or a filename.
 226
 227 You must have the Beamer extension for LaTeX installed for this to work."
 228   :type 'string
 229   :group 'muse-latex)
 230
 231 (defcustom muse-latex-markup-regexps
 232   `(;; numeric ranges
 233     (10000 "\\([0-9]+\\)-\\([0-9]+\\)" 0 "\\1--\\2")
 234
 235     ;; be careful of closing quote pairs
 236     (10100 "\"'" 0 "\"\\\\-'"))
 237   "List of markup regexps for identifying regions in a Muse page.
 238 For more on the structure of this list, see `muse-publish-markup-regexps'."
 239   :type '(repeat (choice
 240                   (list :tag "Markup rule"
 241                         integer
 242                         (choice regexp symbol)
 243                         integer
 244                         (choice string function symbol))
 245                   function))
 246   :group 'muse-latex)
 247
 248 (defcustom muse-latex-markup-functions
 249   '((table . muse-latex-markup-table))
 250   "An alist of style types to custom functions for that kind of text.
 251 For more on the structure of this list, see
 252 `muse-publish-markup-functions'."
 253   :type '(alist :key-type symbol :value-type function)
 254   :group 'muse-latex)
 255
 256 (defcustom muse-latex-markup-strings
 257   '((image-with-desc . "\\begin{figure}[h]
 258 \\centering\\museincludegraphics{%s.%s}|endgroup
 259 \\caption{%s}
 260 \\end{figure}")
 261     (image           . "\\begin{figure}[h]
 262 \\centering\\museincludegraphics{%s.%s}|endgroup
 263 \\end{figure}")
 264     (image-link      . "%% %s
 265 \\museincludegraphics{%s.%s}|endgroup")
 266     (anchor-ref      . "\\ref{%s}")
 267     (url             . "\\url{%s}")
 268     (url-and-desc    . "\\href{%s}{%s}\\footnote{%1%}")
 269     (link            . "\\href{%s}{%s}\\footnote{%1%}")
 270     (link-and-anchor . "\\href{%1%}{%3%}\\footnote{%1%}")
 271     (email-addr      . "\\verb|%s|")
 272     (anchor          . "\\label{%s}")
 273     (emdash          . "---")
 274     (comment-begin   . "% ")
 275     (rule            . "\\vspace{.5cm}\\hrule\\vspace{.5cm}")
 276     (no-break-space  . "~")
 277     (line-break      . "\\\\")
 278     (enddots         . "\\ldots{}")
 279     (dots            . "\\dots{}")
 280     (part            . "\\part{")
 281     (part-end        . "}")
 282     (chapter         . "\\chapter{")
 283     (chapter-end     . "}")
 284     (section         . "\\section{")
 285     (section-end     . "}")
 286     (subsection      . "\\subsection{")
 287     (subsection-end  . "}")
 288     (subsubsection   . "\\subsubsection{")
 289     (subsubsection-end . "}")
 290     (section-other   . "\\paragraph{")
 291     (section-other-end . "}")
 292     (footnote        . "\\footnote{")
 293     (footnote-end    . "}")
 294     (footnotetext    . "\\footnotetext[%d]{")
 295     (begin-underline . "\\underline{")
 296     (end-underline   . "}")
 297     (begin-literal   . "\\texttt{")
 298     (end-literal     . "}")
 299     (begin-emph      . "\\emph{")
 300     (end-emph        . "}")
 301     (begin-more-emph . "\\textbf{")
 302     (end-more-emph   . "}")
 303     (begin-most-emph . "\\textbf{\\emph{")
 304     (end-most-emph   . "}}")
 305     (begin-verse     . "\\begin{verse}\n")
 306     (end-verse-line  . " \\\\")
 307     (verse-space     . "~~~~")
 308     (end-verse       . "\n\\end{verse}")
 309     (begin-example   . "\\begin{quote}\n\\begin{verbatim}")
 310     (end-example     . "\\end{verbatim}\n\\end{quote}")
 311     (begin-center    . "\\begin{center}\n")
 312     (end-center      . "\n\\end{center}")
 313     (begin-quote     . "\\begin{quote}\n")
 314     (end-quote       . "\n\\end{quote}")
 315     (begin-cite     . "\\cite{")
 316     (begin-cite-author . "\\citet{")
 317     (begin-cite-year . "\\citet{")
 318     (end-cite        . "}")
 319     (begin-uli       . "\\begin{itemize}\n")
 320     (end-uli         . "\n\\end{itemize}")
 321     (begin-uli-item  . "\\item ")
 322     (begin-oli       . "\\begin{enumerate}\n")
 323     (end-oli         . "\n\\end{enumerate}")
 324     (begin-oli-item  . "\\item ")
 325     (begin-dl        . "\\begin{description}\n")
 326     (end-dl          . "\n\\end{description}")
 327     (begin-ddt       . "\\item[")
 328     (end-ddt         . "] \\mbox{}\n"))
 329   "Strings used for marking up text.
 330 These cover the most basic kinds of markup, the handling of which
 331 differs little between the various styles."
 332   :type '(alist :key-type symbol :value-type string)
 333   :group 'muse-latex)
 334
 335 (defcustom muse-latex-slides-markup-tags
 336   '(("slide" t t nil muse-latex-slide-tag))
 337  "A list of tag specifications, for specially marking up LaTeX slides."
 338   :type '(repeat (list (string :tag "Markup tag")
 339                        (boolean :tag "Expect closing tag" :value t)
 340                        (boolean :tag "Parse attributes" :value nil)
 341                        (boolean :tag "Nestable" :value nil)
 342                        function))
 343   :group 'muse-latex)
 344
 345 (defcustom muse-latexcjk-encoding-map
 346   '((utf-8              . "{UTF8}{song}")
 347     (japanese-iso-8bit  . "[dnp]{JIS}{min}")
 348     (chinese-big5       . "{Bg5}{bsmi}")
 349     (mule-utf-8         . "{UTF8}{song}")
 350     (chinese-iso-8bit   . "{GB}{song}")
 351     (chinese-gbk        . "{GBK}{song}"))
 352   "An alist mapping emacs coding systems to appropriate CJK codings.
 353 Use the base name of the coding system (ie, without the -unix)."
 354   :type '(alist :key-type coding-system :value-type string)
 355   :group 'muse-latex)
 356
 357 (defcustom muse-latexcjk-encoding-default "{GB}{song}"
 358   "The default Emacs buffer encoding to use in published files.
 359 This will be used if no special characters are found."
 360   :type 'string
 361   :group 'muse-latex)
 362
 363 (defun muse-latexcjk-encoding ()
 364   (when (boundp 'buffer-file-coding-system)
 365     (muse-latexcjk-transform-content-type buffer-file-coding-system)))
 366
 367 (defun muse-latexcjk-transform-content-type (content-type)
 368   "Using `muse-cjklatex-encoding-map', try and resolve an emacs coding
 369 system to an associated CJK coding system."
 370   (let ((match (and (fboundp 'coding-system-base)
 371                     (assoc (coding-system-base content-type)
 372                            muse-latexcjk-encoding-map))))
 373     (if match
 374         (cdr match)
 375       muse-latexcjk-encoding-default)))
 376
 377 (defcustom muse-latex-markup-specials-document
 378   '((?\\ . "\\textbackslash{}")
 379     (?\_ . "\\textunderscore{}")
 380     (?\< . "\\textless{}")
 381     (?\> . "\\textgreater{}")
 382     (?^  . "\\^{}")
 383     (?\~ . "\\~{}")
 384     (?\@ . "\\@")
 385     (?\$ . "\\$")
 386     (?\% . "\\%")
 387     (?\{ . "\\{")
 388     (?\} . "\\}")
 389     (?\& . "\\&")
 390     (?\# . "\\#"))
 391   "A table of characters which must be represented specially.
 392 These are applied to the entire document, sans already-escaped
 393 regions."
 394   :type '(alist :key-type character :value-type string)
 395   :group 'muse-latex)
 396
 397 (defcustom muse-latex-markup-specials-example
 398   '()
 399   "A table of characters which must be represented specially.
 400 These are applied to <example> regions.
 401
 402 With the default interpretation of <example> regions, no specials
 403 need to be escaped."
 404   :type '(alist :key-type character :value-type string)
 405   :group 'muse-latex)
 406
 407 (defcustom muse-latex-markup-specials-literal
 408   '((?\n . "\\\n")
 409     (?\\ . "\\textbackslash{}")
 410     (?_  . "\\textunderscore{}")
 411     (?\< . "\\textless{}")
 412     (?\> . "\\textgreater{}")
 413     (?^  . "\\^{}")
 414     (?\~ . "\\~{}")
 415     (?\$ . "\\$")
 416     (?\% . "\\%")
 417     (?\{ . "\\{")
 418     (?\} . "\\}")
 419     (?\& . "\\&")
 420     (?\# . "\\#"))
 421   "A table of characters which must be represented specially.
 422 This applies to =monospaced text= and <code> regions."
 423   :type '(alist :key-type character :value-type string)
 424   :group 'muse-latex)
 425
 426 (defcustom muse-latex-markup-specials-url
 427   '((?\\ . "\\textbackslash{}")
 428     (?\_ . "\\_")
 429     (?\< . "\\<")
 430     (?\> . "\\>")
 431     (?\$ . "\\$")
 432     (?\% . "\\%")
 433     (?\{ . "\\{")
 434     (?\} . "\\}")
 435     (?\& . "\\&")
 436     (?\# . "\\#"))
 437   "A table of characters which must be represented specially.
 438 These are applied to URLs."
 439   :type '(alist :key-type character :value-type string)
 440   :group 'muse-latex)
 441
 442 (defcustom muse-latex-markup-specials-image
 443   '((?\\ . "\\\\")
 444     (?\< . "\\<")
 445     (?\> . "\\>")
 446     (?\$ . "\\$")
 447     (?\% . "\\%")
 448     (?\{ . "\\{")
 449     (?\} . "\\}")
 450     (?\& . "\\&")
 451     (?\# . "\\#")
 452     (?\| . "\\|"))
 453   "A table of characters which must be represented specially.
 454 These are applied to image filenames."
 455   :type '(alist :key-type character :value-type string)
 456   :group 'muse-latex)
 457
 458 (defun muse-latex-decide-specials (context)
 459   "Determine the specials to escape, depending on CONTEXT."
 460   (cond ((memq context '(underline emphasis document url-desc verbatim
 461                                    footnote))
 462          muse-latex-markup-specials-document)
 463         ((eq context 'image)
 464          muse-latex-markup-specials-image)
 465         ((memq context '(email url))
 466          muse-latex-markup-specials-url)
 467         ((eq context 'literal)
 468          muse-latex-markup-specials-literal)
 469         ((eq context 'example)
 470          muse-latex-markup-specials-example)
 471         (t (error "Invalid context '%s' in muse-latex" context))))
 472
 473 (defcustom muse-latex-permit-contents-tag nil
 474   "If nil, ignore <contents> tags.  Otherwise, insert table of contents.
 475
 476 Most of the time, it is best to have a table of contents on the
 477 first page, with a new page immediately following.  To make this
 478 work with documents published in both HTML and LaTeX, we need to
 479 ignore the <contents> tag.
 480
 481 If you don't agree with this, then set this option to non-nil,
 482 and it will do what you expect."
 483   :type 'boolean
 484   :group 'muse-latex)
 485
 486 (defun muse-latex-markup-table ()
 487   (let* ((table-info (muse-publish-table-fields (match-beginning 0)
 488                                                 (match-end 0)))
 489          (row-len (car table-info))
 490          (field-list (cdr table-info)))
 491     (when table-info
 492       (muse-insert-markup "\\begin{tabular}{" (make-string row-len ?l) "}\n")
 493       (dolist (fields field-list)
 494         (let ((type (car fields)))
 495           (setq fields (cdr fields))
 496           (if (eq type 'hline)
 497               (muse-insert-markup "\\hline\n")
 498             (when (= type 3)
 499               (muse-insert-markup "\\hline\n"))
 500             (insert (car fields))
 501             (setq fields (cdr fields))
 502             (dolist (field fields)
 503               (muse-insert-markup " & ")
 504               (insert field))
 505             (muse-insert-markup " \\\\\n")
 506             (when (= type 2)
 507               (muse-insert-markup "\\hline\n")))))
 508       (muse-insert-markup "\\end{tabular}"))))
 509
 510 ;;; Tags for LaTeX
 511
 512 (defun muse-latex-slide-tag (beg end attrs)
 513   "Publish the <slide> tag in LaTeX.
 514 This is used by the slides and lecture-notes publishing styles."
 515   (let ((title (cdr (assoc "title" attrs))))
 516     (goto-char beg)
 517     (muse-insert-markup "\\begin{frame}[fragile]\n")
 518     (when title
 519       (muse-insert-markup "\\frametitle{")
 520       (insert title)
 521       (muse-insert-markup "}\n"))
 522     (save-excursion
 523       (goto-char end)
 524       (muse-insert-markup "\n\\end{frame}"))))
 525
 526 ;;; Post-publishing functions
 527
 528 (defun muse-latex-fixup-dquotes ()
 529   "Fixup double quotes."
 530   (goto-char (point-min))
 531   (let ((open t))
 532     (while (search-forward "\"" nil t)
 533       (unless (get-text-property (match-beginning 0) 'read-only)
 534         (when (or (bobp)
 535                   (eq (char-before) ?\n))
 536           (setq open t))
 537         (if open
 538             (progn
 539               (replace-match "``")
 540               (setq open nil))
 541           (replace-match "''")
 542           (setq open t))))))
 543
 544 (defun muse-latex-fixup-citations ()
 545   "Replace semicolons in multi-head citations with colons."
 546   (goto-char (point-min))
 547   (while (re-search-forward "\\\\cite.?{" nil t)
 548     (let ((start (point))
 549           (end (re-search-forward "}")))
 550       (save-restriction
 551         (narrow-to-region start end)
 552         (goto-char (point-min))
 553         (while (re-search-forward ";" nil t)
 554           (replace-match ","))))))
 555
 556 (defun muse-latex-fixup-headings ()
 557   "Remove footnotes in headings, since LaTeX does not permit them to exist.
 558
 559 This can happen if there is a link in a heading, because by
 560 default Muse will add a footnote for each link."
 561   (goto-char (point-min))
 562   (while (re-search-forward "^\\\\section.?{" nil t)
 563     (save-restriction
 564       (narrow-to-region (match-beginning 0) (muse-line-end-position))
 565       (goto-char (point-min))
 566       (while (re-search-forward "\\\\footnote{[^}\n]+}" nil t)
 567         (replace-match ""))
 568       (forward-line 1))))
 569
 570 (defun muse-latex-munge-buffer ()
 571   (muse-latex-fixup-dquotes)
 572   (muse-latex-fixup-citations)
 573   (muse-latex-fixup-headings)
 574   (when (and muse-latex-permit-contents-tag
 575              muse-publish-generate-contents)
 576     (goto-char (car muse-publish-generate-contents))
 577     (muse-insert-markup "\\tableofcontents")))
 578
 579 (defun muse-latex-bibliography ()
 580   (save-excursion
 581     (goto-char (point-min))
 582     (if (re-search-forward "\\\\cite.?{" nil t)
 583         (concat
 584          "\\bibliography{"
 585          (muse-publishing-directive "bibsource")
 586          "}\n")
 587       "")))
 588
 589 (defun muse-latex-pdf-browse-file (file)
 590   (shell-command (format muse-latex-pdf-browser file)))
 591
 592 (defun muse-latex-pdf-generate (file output-path final-target)
 593   (apply
 594    #'muse-publish-transform-output
 595    file output-path final-target "PDF"
 596    (function
 597     (lambda (file output-path)
 598       (let* ((fnd (file-name-directory output-path))
 599              (command (format "%s \"%s\""
 600                               muse-latex-pdf-program
 601                               (file-relative-name file fnd)))
 602              (times 0)
 603              (default-directory fnd)
 604              result)
 605         ;; XEmacs can sometimes return a non-number result.  We'll err
 606         ;; on the side of caution by continuing to attempt to generate
 607         ;; the PDF if this happens and treat the final result as
 608         ;; successful.
 609         (while (and (< times 2)
 610                     (or (not (numberp result))
 611                         (not (eq result 0))
 612                         ;; table of contents takes 2 passes
 613                         (file-readable-p
 614                          (muse-replace-regexp-in-string
 615                           "\\.tex\\'" ".toc" file t t))))
 616           (setq result (shell-command command)
 617                 times (1+ times)))
 618         (if (or (not (numberp result))
 619                 (eq result 0))
 620             t
 621           nil))))
 622    muse-latex-pdf-cruft))
 623
 624 ;;; Register the Muse LATEX Publishers
 625
 626 (muse-define-style "latex"
 627                    :suffix    'muse-latex-extension
 628                    :regexps   'muse-latex-markup-regexps
 629                    :functions 'muse-latex-markup-functions
 630                    :strings   'muse-latex-markup-strings
 631                    :specials  'muse-latex-decide-specials
 632                    :before-end 'muse-latex-munge-buffer
 633                    :header    'muse-latex-header
 634                    :footer    'muse-latex-footer
 635                    :browser   'find-file)
 636
 637 (muse-derive-style "pdf" "latex"
 638                    :final   'muse-latex-pdf-generate
 639                    :browser 'muse-latex-pdf-browse-file
 640                    :link-suffix 'muse-latex-pdf-extension
 641                    :osuffix 'muse-latex-pdf-extension)
 642
 643 (muse-derive-style "latexcjk" "latex"
 644                    :header    'muse-latexcjk-header
 645                    :footer    'muse-latexcjk-footer)
 646
 647 (muse-derive-style "pdfcjk" "latexcjk"
 648                    :final   'muse-latex-pdf-generate
 649                    :browser 'muse-latex-pdf-browse-file
 650                    :link-suffix 'muse-latex-pdf-extension
 651                    :osuffix 'muse-latex-pdf-extension)
 652
 653 (muse-derive-style "slides" "latex"
 654                    :header 'muse-latex-slides-header
 655                    :tags   'muse-latex-slides-markup-tags)
 656
 657 (muse-derive-style "slides-pdf" "pdf"
 658                    :header 'muse-latex-slides-header
 659                    :tags   'muse-latex-slides-markup-tags)
 660
 661 (muse-derive-style "lecture-notes" "slides"
 662                    :header 'muse-latex-lecture-notes-header)
 663
 664 (muse-derive-style "lecture-notes-pdf" "slides-pdf"
 665                    :header 'muse-latex-lecture-notes-header)
 666
 667 (provide 'muse-latex)
 668
 669 ;;; muse-latex.el ends here