CMakeLists.txt

   1 #  Copyright (c) 2008 Peter Kuemmel
   2 #  Copyright (c) 2008 Mauro Iazzi
   3 #
   4 #  Permission is hereby granted, free of charge, to any person
   5 #  obtaining a copy of this software and associated documentation
   6 #  files (the "Software"), to deal in the Software without
   7 #  restriction, including without limitation the rights to use,
   8 #  copy, modify, merge, publish, distribute, sublicense, and/or sell
   9 #  copies of the Software, and to permit persons to whom the
  10 #  Software is furnished to do so, subject to the following
  11 #  conditions:
  12 #
  13 #  The above copyright notice and this permission notice shall be
  14 #  included in all copies or substantial portions of the Software.
  15 #
  16 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND,
  17 #  EXPRESS OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES
  18 #  OF MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND
  19 #  NONINFRINGEMENT. IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT
  20 #  HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
  21 #  WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  22 #  FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  23 #  OTHER DEALINGS IN THE SOFTWARE.
  24
  25 cmake_minimum_required(VERSION 2.6)
  26
  27 project(lqt)
  28
  29
  30 set(CMAKE_RUNTIME_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/bin)
  31 set(CMAKE_LIBRARY_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/lib)
  32 set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY  ${CMAKE_BINARY_DIR}/lib)
  33
  34 #set(CMAKE_VERBOSE_MAKEFILE TRUE)
  35
  36
  37 find_package(Qt4 REQUIRED)
  38 set(QT_USE_QTCORE 1)
  39 set(QT_USE_QTGUI 1)
  40 set(QT_USE_QTNETWORK 1)
  41 set(QT_USE_QTWEBKIT 1)
  42 set(QT_USE_QTOPENGL 1)
  43 set(QT_USE_QTSCRIPT 1)
  44 set(QT_USE_QTSVG 1)
  45 set(QT_USE_QTXML 1)
  46 #set(QT_USE_QTSQL 1)
  47 set(QT_USE_QTXMLPATTERNS 1)
  48 include(${QT_USE_FILE})
  49
  50 if(noqt)
  51         set(QT_INCLUDE_DIR ${CMAKE_CURRENT_SOURCE_DIR}/test)
  52         #set(nomerge TRUE)
  53 endif()
  54
  55 if(SYSTEM_LUA)
  56         find_package(Lua51 REQUIRED)
  57         set(LUA_INCLUDE_DIRS ${LUA_INCLUDE_DIR})
  58         set(LUA_CMD lua)
  59 else()
  60         add_subdirectory(lua)
  61         set(LUA_CMD luaexec)
  62         set(LUA_INCLUDE_DIRS ${CMAKE_CURRENT_SOURCE_DIR}/lua/lua/src)
  63         set(LUA_LIBRARIES lua)
  64 endif()
  65
  66 if(MSVC)
  67         set(CMAKE_SUPPRESS_REGENERATION TRUE)
  68         add_definitions(-D_CRT_SECURE_NO_DEPRECATE -D_CRT_SECURE_NO_WARNINGS -D_SCL_SECURE_NO_WARNINGS -DLUA_BUILD_AS_DLL)
  69         set(CMAKE_DEBUG_POSTFIX)
  70 endif()
  71
  72 if(MINGW)
  73         set(CMAKE_SHARED_LINKER_FLAGS "-Wl,-add-stdcall-alias")
  74         SET(CMAKE_VERBOSE_MAKEFILE ON)
  75 endif()
  76
  77
  78 macro(lqt_files name folder)
  79         file(GLOB ${name}_sources ${folder}/*.cpp)
  80         file(GLOB ${name}_headers ${folder}/*.hpp)
  81         qt4_wrap_cpp(${name}_moc ${${name}_headers})
  82         qt4_automoc(${${name}_sources})
  83         set(${name}_src ${${name}_sources} ${${name}_moc})
  84         set(${name}_h ${${name}_headers})
  85         source_group(generated FILES ${${name}_moc})
  86         project_source_group("${GROUP_CODE}" ${name}_sources ${name}_headers)
  87 endmacro()
  88
  89
  90 # folders in the msvc projects
  91 # mode==flat  : headers and sources not in folders
  92 # mode==split : standard behavior of cmake, split headers and sources
  93 # mode==<other values> : code is in this folder
  94 macro(project_source_group mode sources headers)
  95         if(${mode} MATCHES "flat")
  96                 source_group("Source Files" Files)
  97                 source_group("Header Files" Files)
  98                 source_group("cmake" FILES CMakeLists.txt)
  99         else()
 100                 if(NOT ${mode} MATCHES "split")
 101                         source_group("${mode}" FILES ${${sources}} ${${headers}})
 102                 endif()
 103         endif()
 104 endmacro()
 105 set(GROUP_CODE "Source Files")
 106
 107 set(LQT_BUILDIN_CPPTOXML 1)
 108 if(LQT_BUILDIN_CPPTOXML)
 109         add_subdirectory(cpptoxml)
 110 else()
 111         #TODO find cpptpxml
 112 endif()
 113
 114
 115 function(build_qt_lib_binding BINDING_HEADER)
 116
 117         string(TOLOWER ${BINDING_HEADER} BINDING_NAME)
 118
 119         # hardcoded in generator.lua
 120         set (LQT_GEN_DIR ${CMAKE_BINARY_DIR}/${BINDING_NAME}_src)
 121         file(MAKE_DIRECTORY ${LQT_GEN_DIR})
 122
 123         set (BINDING_SRC ${LQT_GEN_DIR}/${BINDING_NAME}_merged_build.cpp)
 124         set_source_files_properties(${BINDING_SRC} PROPERTIES  GENERATED TRUE)
 125
 126         if (UNIX)
 127                 set (PP_CONFIG ${CMAKE_SOURCE_DIR}/cpptoxml/parser/rpp/pp-qt-configuration)
 128         else()
 129                 set (PP_CONFIG ${CMAKE_SOURCE_DIR}/cpptoxml/parser/rpp/pp-qt-configuration-win)
 130         endif()
 131
 132         if(NOT REUSE_FILES)
 133                 set (GEN_XML ${LQT_GEN_DIR}/${BINDING_NAME}.xml)
 134                 add_custom_target(generate_${BINDING_NAME}_xml  COMMAND cpptoxml
 135                                                                 ${BINDING_HEADER}
 136                                                                 -C ${PP_CONFIG}
 137                                                                 -Q ${QT_INCLUDE_DIR}
 138                                                                 -o ${GEN_XML}
 139                                                         COMMENT "Generating XML: running cpptoxml on ${BINDING_NAME} "
 140                                                         VERBATIM)
 141
 142
 143                 math(EXPR MAX ${ARGC}-1)
 144                 if(MAX)
 145                         foreach(I RANGE 1 ${MAX})
 146                                 string(TOLOWER ${ARGV${I}} DEPNAME)
 147                                 set(${BINDING_NAME}_TYPES ${${BINDING_NAME}_TYPES} -t ${DEPNAME}_src/${DEPNAME}_types.lua)
 148                                 set(${BINDING_NAME}_DEPENDS ${${BINDING_NAME}_DEPENDS} generate_${DEPNAME}_cpp)
 149                         endforeach()
 150                 endif()
 151
 152                 add_custom_target(generate_${BINDING_NAME}_cpp
 153                                                         COMMAND ${LUA_CMD}
 154                                                                 "${CMAKE_SOURCE_DIR}/generator/generator.lua"
 155                                                                 ${GEN_XML}
 156                                                                 -i ${BINDING_HEADER} -i lqt_qt.hpp
 157                                                                 -n ${BINDING_NAME}
 158                                                                 -t ${CMAKE_SOURCE_DIR}/generator/qtypes.lua
 159                                                                 ${${BINDING_NAME}_TYPES}
 160                                                                 -f ${CMAKE_SOURCE_DIR}/generator/qt_internal.lua
 161                                                         COMMENT "Generating binding code with Lua"
 162                                                         VERBATIM)
 163         else()
 164                 add_custom_target(generate_${BINDING_NAME}_xml  COMMAND
 165                                                         COMMENT "Reusing old XML on ${BINDING_NAME} "
 166                                                         VERBATIM)
 167                 add_custom_target(generate_${BINDING_NAME}_cpp
 168                                                         COMMENT "Reusing old binding code with Lua"
 169                                                         VERBATIM)
 170         endif()
 171
 172         set(COMMON COMMON_${BINDING_NAME})
 173         file(GLOB ${COMMON}_SRC ${CMAKE_SOURCE_DIR}/common/*.cpp)
 174         file(GLOB ${COMMON}_HPP ${CMAKE_SOURCE_DIR}/common/*.hpp)
 175
 176
 177         set(${BINDING_NAME}_GENERATED ${LQT_GEN_DIR}/${BINDING_NAME}_enum.cpp
 178                                                                         ${LQT_GEN_DIR}/${BINDING_NAME}_meta.cpp
 179                                                                         ${LQT_GEN_DIR}/${BINDING_NAME}_slot.cpp)
 180         set_source_files_properties(${${BINDING_NAME}_GENERATED} PROPERTIES GENERATED TRUE)
 181
 182         if(nomerge)
 183                 #TODO fix this build process:
 184                 #       1. cmake ../lqt -Dnomerge=1
 185                 #       2. make -> will generate cpp files but they are not part of the Makefile (GLOB was at 1.)
 186                 #       3. cmake ../lqt -Dnomerge=1 -> GLOB now finds the generated cpp files
 187                 #       4. make
 188                 file(GLOB BINDING_SRC ${LQT_GEN_DIR}/*.cpp)
 189                 set(${COMMON}_SRC)
 190                 list(REMOVE_ITEM BINDING_SRC ${LQT_GEN_DIR}/${BINDING_NAME}_merged_build.cpp)
 191         else()
 192                 set(${COMMON}_SRC ${${COMMON}_SRC}      ${${BINDING_NAME}_GENERATED})
 193         endif()
 194
 195         qt4_wrap_cpp(${COMMON}_MOC ${LQT_GEN_DIR}/${BINDING_NAME}_slot.hpp)
 196
 197         include_directories(${CMAKE_SOURCE_DIR}/common ${LUA_INCLUDE_DIRS} ${QT_INCLUDES})
 198
 199         add_library(${BINDING_NAME} SHARED  ${BINDING_SRC}
 200                                                                                         ${${COMMON}_SRC}
 201                                                                                         ${${COMMON}_HPP}
 202                                                                                         ${${COMMON}_MOC})
 203
 204         target_link_libraries(${BINDING_NAME} ${QT_LIBRARIES} ${LUA_LIBRARIES})
 205
 206         if(LQT_BUILDIN_CPPTOXML)
 207                 add_dependencies(generate_${BINDING_NAME}_xml  cpptoxml)
 208         endif()
 209
 210         add_dependencies(generate_${BINDING_NAME}_cpp  generate_${BINDING_NAME}_xml ${${BINDING_NAME}_DEPENDS})
 211         add_dependencies(${BINDING_NAME} generate_${BINDING_NAME}_cpp)
 212         if(NOT SYSTEM_LUA)
 213                 add_dependencies(generate_${BINDING_NAME}_cpp luaexec)
 214         endif()
 215 endfunction()
 216
 217 if(noqt)
 218         include_directories(${CMAKE_CURRENT_SOURCE_DIR}/test/noqt)
 219         build_qt_lib_binding(noqt)
 220 else()
 221         build_qt_lib_binding(QtCore)
 222         build_qt_lib_binding(QtNetwork QtCore)
 223         build_qt_lib_binding(QtGui QtNetwork QtCore)
 224         build_qt_lib_binding(QtScript QtGui QtNetwork QtCore)
 225         build_qt_lib_binding(QtOpenGL QtGui QtNetwork QtCore)
 226         build_qt_lib_binding(QtSvg QtScript QtGui QtNetwork QtCore)
 227         build_qt_lib_binding(QtXml QtSvg QtScript QtGui QtNetwork QtCore)
 228         build_qt_lib_binding(QtXmlPatterns QtCore QtXml)
 229         build_qt_lib_binding(QtWebKit QtXmlPatterns QtSvg QtScript QtOpenGL QtGui QtNetwork QtCore QtXml)
 230         # TODO
 231         #build_qt_lib_binding(QtSql)
 232         #build_qt_lib_binding(QtScriptTools) # 4.5 only
 233         #build_qt_lib_binding(Phonon)
 234 endif()
 235
 236
 237
 238
 239
 240
 241