lisp-unit.lisp

   1 ;;;-*- Mode: Lisp; Syntax: ANSI-Common-Lisp -*-
   2
   3 #|
   4 Copyright (c) 2004-2005 Christopher K. Riesbeck
   5
   6 Permission is hereby granted, free of charge, to any person obtaining
   7 a copy of this software and associated documentation files (the "Software"),
   8 to deal in the Software without restriction, including without limitation
   9 the rights to use, copy, modify, merge, publish, distribute, sublicense,
  10 and/or sell copies of the Software, and to permit persons to whom the
  11 Software is furnished to do so, subject to the following conditions:
  12
  13 The above copyright notice and this permission notice shall be included
  14 in all copies or substantial portions of the Software.
  15
  16 THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  17 OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  18 FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT. IN NO EVENT SHALL
  19 THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR
  20 OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE,
  21 ARISING FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR
  22 OTHER DEALINGS IN THE SOFTWARE.
  23
  24
  25 How to use
  26 ----------
  27
  28 1. Read the documentation at:
  29    https://github.com/OdonataResearchLLC/lisp-unit/wiki
  30
  31 2. Make a file of DEFINE-TEST's. See exercise-tests.lisp for many
  32 examples. If you want, start your test file with (REMOVE-TESTS :ALL)
  33 to clear any previously defined tests.
  34
  35 3. Load this file.
  36
  37 4. (use-package :lisp-unit)
  38
  39 5. Load your code file and your file of tests.
  40
  41 6. Test your code with (RUN-TESTS '(test-name1 test-name2 ...)) or
  42 simply (RUN-TESTS :ALL) to run all defined tests.
  43
  44 A summary of how many tests passed and failed will be printed.
  45
  46 NOTE: Nothing is compiled until RUN-TESTS is expanded. Redefining
  47 functions or even macros does not require reloading any tests.
  48
  49 |#
  50
  51 ;;; Packages
  52
  53 (in-package :cl-user)
  54
  55 (defpackage :lisp-unit
  56   (:use :common-lisp)
  57   ;; Print parameters
  58   (:export :*print-summary*
  59            :*print-failures*
  60            :*print-errors*)
  61   ;; Forms for assertions
  62   (:export :assert-eq
  63            :assert-eql
  64            :assert-equal
  65            :assert-equalp
  66            :assert-equality
  67            :assert-prints
  68            :assert-expands
  69            :assert-true
  70            :assert-false
  71            :assert-error)
  72   ;; Functions for managing tests
  73   (:export :define-test
  74            :list-tests
  75            :test-code
  76            :test-documentation
  77            :remove-tests
  78            :run-tests
  79            :use-debugger)
  80   ;; Functions for managing tags
  81   (:export :list-tags
  82            :tagged-tests
  83            :remove-tags
  84            :run-tags)
  85   ;; Functions for reporting test results
  86   (:export :test-names
  87            :failed-tests
  88            :error-tests
  89            :missing-tests
  90            :print-failures
  91            :print-errors
  92            :summarize-results)
  93   ;; Functions for extensibility via signals
  94   (:export :signal-results
  95            :test-run-complete
  96            :results)
  97   ;; Utility predicates
  98   (:export :logically-equal :set-equal))
  99
 100 (in-package :lisp-unit)
 101
 102 ;;; Global counters
 103
 104 (defparameter *pass* 0
 105   "The passed assertion results.")
 106
 107 (defparameter *fail* ()
 108   "The failed assertion results.")
 109
 110 (defun reset-counters ()
 111   "Reset the counters to empty lists."
 112   (setf *pass* 0 *fail* ()))
 113
 114 ;;; Global options
 115
 116 (defparameter *print-summary* nil
 117   "Print a summary of the pass, fail, and error count if non-nil.")
 118
 119 (defparameter *print-failures* nil
 120   "Print failure messages if non-NIL.")
 121
 122 (defparameter *print-errors* nil
 123   "Print error messages if non-NIL.")
 124
 125 (defparameter *use-debugger* nil
 126   "If not NIL, enter the debugger when an error is encountered in an
 127 assertion.")
 128
 129 (defparameter *signal-results* nil
 130   "Signal the result if non NIL.")
 131
 132 (defun use-debugger-p (condition)
 133   "Debug or ignore errors."
 134   (cond
 135    ((eq :ask *use-debugger*)
 136     (y-or-n-p "~A -- debug?" condition))
 137    (*use-debugger*)))
 138
 139 (defun use-debugger (&optional (flag t))
 140   "Use the debugger when testing, or not."
 141   (setq *use-debugger* flag))
 142
 143 (defun signal-results (&optional (flag t))
 144   "Signal the results for extensibility."
 145   (setq *signal-results* flag))
 146
 147 ;;; Global unit test database
 148
 149 (defparameter *test-db* (make-hash-table :test #'eq)
 150   "The unit test database is simply a hash table.")
 151
 152 (defun package-table (package &optional create)
 153   (cond
 154    ((gethash (find-package package) *test-db*))
 155    (create
 156     (setf (gethash package *test-db*) (make-hash-table)))
 157    (t (error "No tests defined for package ~A."
 158              (package-name package)))))
 159
 160 ;;; Global tags database
 161
 162 (defparameter *tag-db* (make-hash-table :test #'eq)
 163   "The tag database is simply a hash table.")
 164
 165 (defun package-tags (package &optional create)
 166   "Return the tags DB for the package."
 167   (cond
 168    ((gethash (find-package package) *tag-db*))
 169    (create
 170     (setf (gethash package *tag-db*) (make-hash-table)))
 171    (t (error "No tags defined for package ~A."
 172              (package-name package)))))
 173
 174 ;;; Unit test definition
 175
 176 (defclass unit-test ()
 177   ((doc
 178     :type string
 179     :initarg :doc
 180     :reader doc)
 181    (code
 182     :type list
 183     :initarg :code
 184     :reader code))
 185   (:default-initargs :doc "" :code ())
 186   (:documentation
 187    "Organize the unit test documentation and code."))
 188
 189 ;;; NOTE: Shamelessly taken from PG's analyze-body
 190 (defun parse-body (body &optional doc tag)
 191   "Separate the components of the body."
 192   (let ((item (first body)))
 193     (cond
 194      ((and (listp item) (eq :tag (first item)))
 195       (parse-body (rest body) doc (nconc (rest item) tag)))
 196      ((and (stringp item) (not doc) (rest body))
 197       (if tag
 198           (values doc tag (rest body))
 199           (parse-body (rest body) doc tag)))
 200      (t (values doc tag body)))))
 201
 202 (defun test-name-error-report (test-name-error stream)
 203   "Write the test-name-error to the stream."
 204   (format stream "Test name ~S is not of type ~A."
 205           (type-error-datum test-name-error)
 206           (type-error-expected-type test-name-error)))
 207
 208 (define-condition test-name-error (type-error)
 209   ()
 210   (:default-initargs :expected-type 'symbol)
 211   (:report test-name-error-report)
 212   (:documentation
 213    "The test name error is a type error."))
 214
 215 (defun valid-test-name (name)
 216   "Signal a type-error if the test name is not a symbol."
 217   (if (symbolp name)
 218       name
 219       (error 'test-name-error :datum name)))
 220
 221 (defmacro define-test (name &body body)
 222   "Store the test in the test database."
 223   (let ((qname (gensym "NAME-")))
 224     (multiple-value-bind (doc tag code) (parse-body body)
 225       `(let* ((,qname (valid-test-name ',name))
 226               (doc (or ,doc (string ,qname))))
 227          (setf
 228           ;; Unit test
 229           (gethash ,qname (package-table *package* t))
 230           (make-instance 'unit-test :doc doc :code ',code))
 231          ;; Tags
 232          (loop for tag in ',tag do
 233                (pushnew
 234                 ,qname (gethash tag (package-tags *package* t))))
 235          ;; Return the name of the test
 236          ,qname))))
 237
 238 ;;; Manage tests
 239
 240 (defun list-tests (&optional (package *package*))
 241   "Return a list of the tests in package."
 242   (let ((table (package-table package)))
 243     (when table
 244       (loop for test-name being each hash-key in table
 245             collect test-name))))
 246
 247 (defun test-documentation (name &optional (package *package*))
 248   "Return the documentation for the test."
 249   (let ((unit-test (gethash name (package-table package))))
 250     (if (null unit-test)
 251         (warn "No test ~A in package ~A."
 252               name (package-name package))
 253         (doc unit-test))))
 254
 255 (defun test-code (name &optional (package *package*))
 256   "Returns the code stored for the test name."
 257   (let ((unit-test (gethash name (package-table package))))
 258     (if (null unit-test)
 259         (warn "No test ~A in package ~A."
 260               name (package-name package))
 261         (code unit-test))))
 262
 263 (defun remove-tests (&optional (names :all) (package *package*))
 264   "Remove individual tests or entire sets."
 265   (if (eq :all names)
 266       (if (null package)
 267           (clrhash *test-db*)
 268           (progn
 269             (remhash (find-package package) *test-db*)
 270             (remhash (find-package package) *tag-db*)))
 271       (let ((table (package-table package)))
 272         (unless (null table)
 273           ;; Remove tests
 274           (loop for name in names
 275                 unless (remhash name table) do
 276                 (warn "No test ~A in package ~A to remove."
 277                       name (package-name package)))
 278           ;; Remove tests from tags
 279           (loop with tags = (package-tags package)
 280                 for tag being each hash-key in tags
 281                 using (hash-value tagged-tests)
 282                 do
 283                 (setf
 284                  (gethash tag tags)
 285                  (set-difference tagged-tests names)))))))
 286
 287 ;;; Manage tags
 288
 289 (defun %tests-from-all-tags (&optional (package *package*))
 290   "Return all of the tests that have been tagged."
 291   (loop for tests being each hash-value in (package-tags package)
 292         nconc (copy-list tests) into all-tests
 293         finally (return (delete-duplicates all-tests))))
 294
 295 (defun %tests-from-tags (tags &optional (package *package*))
 296   "Return the tests associated with the tags."
 297   (loop with table = (package-tags package)
 298         for tag in tags
 299         as tests = (gethash tag table)
 300         if (null tests) do (warn "No tests tagged with ~S." tag)
 301         else nconc (copy-list tests) into all-tests
 302         finally (return (delete-duplicates all-tests))))
 303
 304 (defun list-tags (&optional (package *package*))
 305   "Return a list of the tags in package."
 306   (let ((tags (package-tags package)))
 307     (when tags
 308       (loop for tag being each hash-key in tags collect tag))))
 309
 310 (defun tagged-tests (&optional (tags :all) (package *package*))
 311   "Return a list of the tests associated with the tags."
 312   (if (eq :all tags)
 313       (%tests-from-all-tags package)
 314       (%tests-from-tags tags package)))
 315
 316 (defun remove-tags (&optional (tags :all) (package *package*))
 317   "Remove individual tags or entire sets."
 318   (if (eq :all tags)
 319       (if (null package)
 320           (clrhash *tag-db*)
 321           (remhash (find-package package) *tag-db*))
 322       (let ((table (package-tags package)))
 323         (unless (null table)
 324           (loop for tag in tags
 325                 unless (remhash tag table) do
 326                 (warn "No tag ~A in package ~A to remove."
 327                       tag (package-name package)))))))
 328
 329 ;;; Assert macros
 330
 331 (defmacro assert-eq (expected form &rest extras)
 332   "Assert whether expected and form are EQ."
 333   `(expand-assert :equal ,form ,form ,expected ,extras :test #'eq))
 334
 335 (defmacro assert-eql (expected form &rest extras)
 336   "Assert whether expected and form are EQL."
 337   `(expand-assert :equal ,form ,form ,expected ,extras :test #'eql))
 338
 339 (defmacro assert-equal (expected form &rest extras)
 340   "Assert whether expected and form are EQUAL."
 341   `(expand-assert :equal ,form ,form ,expected ,extras :test #'equal))
 342
 343 (defmacro assert-equalp (expected form &rest extras)
 344   "Assert whether expected and form are EQUALP."
 345   `(expand-assert :equal ,form ,form ,expected ,extras :test #'equalp))
 346
 347 (defmacro assert-error (condition form &rest extras)
 348   "Assert whether form signals condition."
 349   `(expand-assert :error ,form (expand-error-form ,form)
 350                   ,condition ,extras))
 351
 352 (defmacro assert-expands (expansion form &rest extras)
 353   "Assert whether form expands to expansion."
 354   `(expand-assert :macro ,form
 355                   (expand-macro-form ,form nil)
 356                   ',expansion ,extras))
 357
 358 (defmacro assert-false (form &rest extras)
 359   "Assert whether the form is false."
 360   `(expand-assert :result ,form ,form nil ,extras))
 361
 362 (defmacro assert-equality (test expected form &rest extras)
 363   "Assert whether expected and form are equal according to test."
 364   `(expand-assert :equal ,form ,form ,expected ,extras :test ,test))
 365
 366 (defmacro assert-prints (output form &rest extras)
 367   "Assert whether printing the form generates the output."
 368   `(expand-assert :output ,form (expand-output-form ,form)
 369                   ,output ,extras))
 370
 371 (defmacro assert-true (form &rest extras)
 372   "Assert whether the form is true."
 373   `(expand-assert :result ,form ,form t ,extras))
 374
 375 (defmacro expand-assert (type form body expected extras &key (test '#'eql))
 376   "Expand the assertion to the internal format."
 377   `(internal-assert ,type ',form
 378                     (lambda () ,body)
 379                     (lambda () ,expected)
 380                     (expand-extras ,extras)
 381                     ,test))
 382
 383 (defmacro expand-error-form (form)
 384   "Wrap the error assertion in HANDLER-CASE."
 385   `(handler-case ,form
 386      (condition (error) error)))
 387
 388 (defmacro expand-output-form (form)
 389   "Capture the output of the form in a string."
 390   (let ((out (gensym)))
 391     `(let* ((,out (make-string-output-stream))
 392             (*standard-output*
 393              (make-broadcast-stream *standard-output* ,out)))
 394        ,form
 395        (get-output-stream-string ,out))))
 396
 397 (defmacro expand-macro-form (form env)
 398   "Expand the macro form once."
 399   `(let ((*gensym-counter* 1))
 400      (macroexpand-1 ',form ,env)))
 401
 402 (defmacro expand-extras (extras)
 403   "Expand extra forms."
 404   `(lambda ()
 405      (list ,@(mapcan (lambda (form) (list `',form form)) extras))))
 406
 407 (defgeneric assert-result (type test expected actual)
 408   (:documentation
 409    "Return the result of the assertion."))
 410
 411 (defgeneric record-failure (type form actual expected extras test)
 412   (:documentation
 413    "Record the details of the failure."))
 414
 415 (defclass failure-result ()
 416   ((form
 417     :initarg :form
 418     :reader form)
 419    (actual
 420     :type list
 421     :initarg :actual
 422     :reader actual)
 423    (expected
 424     :type list
 425     :initarg :expected
 426     :reader expected)
 427    (extras
 428     :type list
 429     :initarg :extras
 430     :reader extras)
 431    (test
 432     :type function
 433     :initarg :test
 434     :reader test))
 435   (:documentation
 436    "Failure details of the assertion."))
 437
 438 (defmethod record-failure (class form actual expected extras test)
 439   "Return an instance of the failure result."
 440   (make-instance class
 441                  :form form
 442                  :actual actual
 443                  :expected expected
 444                  :extras extras
 445                  :test test))
 446
 447 (defclass equal-result (failure-result)
 448   ()
 449   (:documentation
 450    "Result of a failed equal assertion."))
 451
 452 (defmethod assert-result ((type (eql :equal)) test expected actual)
 453   "Return the result of an equal assertion."
 454   (and
 455    (<= (length expected) (length actual))
 456    (every test expected actual)))
 457
 458 (defmethod record-failure ((type (eql :equal))
 459                            form actual expected extras test)
 460   "Return an instance of an equal failure result."
 461   (call-next-method 'equal-result form actual expected extras test))
 462
 463 (defclass error-result (failure-result)
 464   ()
 465   (:documentation
 466    "Result of a failed error assertion."))
 467
 468 (defmethod assert-result ((type (eql :error)) test expected actual)
 469   "Return the result of an error assertion."
 470   (declare (ignore test))
 471   (or
 472    (eql (car actual) (car expected))
 473    (typep (car actual) (car expected))))
 474
 475 (defmethod record-failure ((type (eql :error))
 476                            form actual expected extras test)
 477   "Return an instance of an error failure result."
 478   (call-next-method 'error-result form actual expected extras test))
 479
 480 (defclass macro-result (failure-result)
 481   ()
 482   (:documentation
 483    "Result of a failed macro expansion assertion."))
 484
 485 (defun %expansion-equal (form1 form2)
 486   "Descend into the forms checking for equality."
 487   (let ((item1 (first form1))
 488         (item2 (first form2)))
 489     (cond
 490      ((and (null item1) (null item2)))
 491      ((and (listp item1) (listp item2))
 492       (and
 493        (%expansion-equal item1 item2)
 494        (%expansion-equal (rest form1) (rest form2))))
 495      ((and (symbolp item1) (symbolp item2))
 496       (and
 497        (string= (symbol-name item1) (symbol-name item2))
 498        (%expansion-equal (rest form1) (rest form2))))
 499      (t (and
 500          (equal item1 item2)
 501          (%expansion-equal (rest form1) (rest form2)))))))
 502
 503 (defmethod assert-result ((type (eql  :macro)) test expected actual)
 504   "Return the result of a macro assertion."
 505   (declare (ignore test))
 506   (%expansion-equal (first expected) (first actual)))
 507
 508 (defmethod record-failure ((type (eql :macro))
 509                            form actual expected extras test)
 510   "Return an instance of a macro failure result."
 511   (call-next-method 'macro-result form actual expected extras test))
 512
 513 (defclass boolean-result (failure-result)
 514   ()
 515   (:documentation
 516    "Result of a failed boolean assertion."))
 517
 518 (defmethod assert-result ((type (eql :result)) test expected actual)
 519   "Return the result of a result assertion."
 520   (declare (ignore test))
 521   (logically-equal (car actual) (car expected)))
 522
 523 (defmethod record-failure ((type (eql :result))
 524                            form actual expected extras test)
 525   "Return an instance of a boolean failure result."
 526   (call-next-method 'boolean-result form actual expected extras test))
 527
 528 (defclass output-result (failure-result)
 529   ()
 530   (:documentation
 531    "Result of a failed output assertion."))
 532
 533 (defmethod assert-result ((type (eql :output)) test expected actual)
 534   "Return the result of an output assertion."
 535   (declare (ignore test))
 536   (string=
 537    (string-trim '(#\newline #\return #\space) (car actual))
 538    (car expected)))
 539
 540 (defmethod record-failure ((type (eql :output))
 541                            form actual expected extras test)
 542   "Return an instance of an output failure result."
 543   (call-next-method 'output-result form actual expected extras test))
 544
 545 (defun internal-assert
 546        (type form code-thunk expected-thunk extras test)
 547   "Perform the assertion and record the results."
 548   (let* ((actual (multiple-value-list (funcall code-thunk)))
 549          (expected (multiple-value-list (funcall expected-thunk)))
 550          (result (assert-result type test expected actual)))
 551     (if result
 552         (incf *pass*)
 553         (push
 554          (record-failure
 555           type form actual expected
 556           (when extras (funcall extras)) test)
 557          *fail*))
 558     ;; Return the result
 559     result))
 560
 561 ;;; Unit test results
 562
 563 (defclass test-result ()
 564   ((name
 565     :type symbol
 566     :initarg :name
 567     :reader name)
 568    (pass
 569     :type fixnum
 570     :initarg :pass
 571     :reader pass)
 572    (fail
 573     :type list
 574     :initarg :fail
 575     :reader fail)
 576    (exerr
 577     :initarg :exerr
 578     :reader exerr)
 579    (run-time
 580     :initarg :run-time
 581     :reader run-time
 582     :documentation
 583     "Test run time measured in internal time units"))
 584   (:default-initargs :exerr nil)
 585   (:documentation
 586    "Store the results of the unit test."))
 587
 588 (defun print-summary (test-result &optional
 589                       (stream *standard-output*))
 590   "Print a summary of the test result."
 591   (format stream "~&~A: ~S assertions passed, ~S failed"
 592           (name test-result)
 593           (pass test-result)
 594           (length (fail test-result)))
 595   (if (exerr test-result)
 596       (format stream ", and an execution error.")
 597       (write-char #\. stream))
 598   (terpri stream)
 599   (terpri stream))
 600
 601 (defun run-code (code)
 602   "Run the code to test the assertions."
 603   (funcall (coerce `(lambda () ,@code) 'function)))
 604
 605 (defun run-test-thunk (name code)
 606   (let ((*pass* 0)
 607         (*fail* ())
 608         (start (get-internal-run-time)))
 609     (handler-bind
 610         ((error
 611           (lambda (condition)
 612             (if (use-debugger-p condition)
 613                 condition
 614                 (return-from run-test-thunk
 615                   (make-instance
 616                    'test-result
 617                    :name name
 618                    :pass *pass*
 619                    :fail *fail*
 620                    :run-time (- (get-internal-run-time) start)
 621                    :exerr condition))))))
 622       (run-code code))
 623     ;; Return the result count
 624     (make-instance
 625      'test-result
 626      :name name
 627      :pass *pass*
 628      :fail *fail*
 629      :run-time (- (get-internal-run-time) start))))
 630
 631 ;;; Test results database
 632
 633 (defclass test-results-db ()
 634   ((database
 635     :type hash-table
 636     :initform (make-hash-table :test #'eq)
 637     :reader database)
 638    (pass
 639     :type fixnum
 640     :initform 0
 641     :accessor pass)
 642    (fail
 643     :type fixnum
 644     :initform 0
 645     :accessor fail)
 646    (exerr
 647     :type fixnum
 648     :initform 0
 649     :accessor exerr)
 650    (failed-tests
 651     :type list
 652     :initform ()
 653     :accessor failed-tests)
 654    (error-tests
 655     :type list
 656     :initform ()
 657     :accessor error-tests)
 658    (missing-tests
 659     :type list
 660     :initform ()
 661     :accessor missing-tests))
 662   (:documentation
 663    "Store the results of the tests for further evaluation."))
 664
 665 (defmethod print-object ((object test-results-db) stream)
 666   "Print the summary counts with the object."
 667   (let ((pass (pass object))
 668         (fail (fail object))
 669         (exerr (exerr object)))
 670     (format
 671      stream "#<~A Total(~D) Passed(~D) Failed(~D) Errors(~D)>~%"
 672      (class-name (class-of object))
 673      (+ pass fail) pass fail exerr)))
 674
 675 (defun test-names (test-results-db)
 676   "Return a list of the test names in the database."
 677   (loop for name being each hash-key in (database test-results-db)
 678         collect name))
 679
 680 (defun record-result (test-name code results)
 681   "Run the test code and record the result."
 682   (let ((result (run-test-thunk test-name code)))
 683     ;; Store the result
 684     (setf (gethash test-name (database results)) result)
 685     ;; Count passed tests
 686     (when (plusp (pass result))
 687       (incf (pass results) (pass result)))
 688     ;; Count failed tests and record the name
 689     (when (fail result)
 690       (incf (fail results) (length (fail result)))
 691       (push test-name (failed-tests results)))
 692     ;; Count errors and record the name
 693     (when (exerr result)
 694       (incf (exerr results))
 695       (push test-name (error-tests results)))
 696     ;; Running output
 697     (when *print-failures* (print-failures result))
 698     (when *print-errors* (print-errors result))
 699     (when (or *print-summary* *print-failures* *print-errors*)
 700       (print-summary result))))
 701
 702 (defun summarize-results (results &optional
 703                           (stream *standard-output*))
 704   "Print a summary of all results to the stream."
 705   (let ((pass (pass results))
 706         (fail (fail results)))
 707     (format stream "~&Unit Test Summary~%")
 708     (format stream " | ~D assertions total~%" (+ pass fail))
 709     (format stream " | ~D passed~%" pass)
 710     (format stream " | ~D failed~%" fail)
 711     (format stream " | ~D execution errors~%" (exerr results))
 712     (format stream " | ~D missing tests~2%"
 713             (length (missing-tests results)))))
 714
 715 ;;; Run the tests
 716
 717 (define-condition test-run-complete ()
 718   ((results
 719     :type 'test-results-db
 720     :initarg :results
 721     :reader results))
 722   (:documentation
 723    "Signaled when a test run is finished."))
 724
 725 (defun %run-all-thunks (&optional (package *package*))
 726   "Run all of the test thunks in the package."
 727   (loop
 728    with results = (make-instance 'test-results-db)
 729    for test-name being each hash-key in (package-table package)
 730    using (hash-value unit-test)
 731    if unit-test do
 732    (record-result test-name (code unit-test) results)
 733    else do
 734    (push test-name (missing-tests results))
 735    ;; Summarize and return the test results
 736    finally
 737    (when *signal-results*
 738      (signal 'test-run-complete :results results))
 739    (summarize-results results)
 740    (return results)))
 741
 742 (defun %run-thunks (test-names &optional (package *package*))
 743   "Run the list of test thunks in the package."
 744   (loop
 745    with table = (package-table package)
 746    and results = (make-instance 'test-results-db)
 747    for test-name in test-names
 748    as unit-test = (gethash test-name table)
 749    if unit-test do
 750    (record-result test-name (code unit-test) results)
 751    else do
 752    (push test-name (missing-tests results))
 753    finally
 754    (when *signal-results*
 755      (signal 'test-run-complete :results results))
 756    (summarize-results results)
 757    (return results)))
 758
 759 (defun run-tests (&optional (test-names :all) (package *package*))
 760   "Run the specified tests in package."
 761   (reset-counters)
 762   (if (eq :all test-names)
 763       (%run-all-thunks package)
 764       (%run-thunks test-names package)))
 765
 766 (defun run-tags (&optional (tags :all) (package *package*))
 767   "Run the tests associated with the specified tags in package."
 768   (reset-counters)
 769   (%run-thunks (tagged-tests tags package) package))
 770
 771 ;;; Print failures
 772
 773 (defgeneric print-failures (result &optional stream)
 774   (:documentation
 775    "Report the results of the failed assertion."))
 776
 777 (defmethod print-failures :around ((result failure-result) &optional
 778                                    (stream *standard-output*))
 779   "Failure header and footer output."
 780   (format stream "~& | Failed Form: ~S" (form result))
 781   (call-next-method)
 782   (when (extras result)
 783     (format stream "~{~& | ~S => ~S~}~%" (extras result)))
 784   (format stream "~& |~%"))
 785
 786 (defmethod print-failures ((result failure-result) &optional
 787                            (stream *standard-output*))
 788   (format stream "~& | Expected ~{~S~^; ~} " (expected result))
 789   (format stream "~<~% | ~:;but saw ~{~S~^; ~}~>" (actual result)))
 790
 791 (defmethod print-failures ((result error-result) &optional
 792                            (stream *standard-output*))
 793   (format stream "~& | ~@[Should have signalled ~{~S~^; ~} but saw~]"
 794           (expected result))
 795   (format stream " ~{~S~^; ~}" (actual result)))
 796
 797 (defmethod print-failures ((result macro-result) &optional
 798                            (stream *standard-output*))
 799   (format stream "~& | Should have expanded to ~{~S~^; ~} "
 800           (expected result))
 801   (format stream "~<~%~:;but saw ~{~S~^; ~}~>" (actual result)))
 802
 803 (defmethod print-failures ((result output-result) &optional
 804                            (stream *standard-output*))
 805   (format stream "~& | Should have printed ~{~S~^; ~} "
 806           (expected result))
 807   (format stream "~<~%~:;but saw ~{~S~^; ~}~>"
 808           (actual result)))
 809
 810 (defmethod print-failures ((result test-result) &optional
 811                            (stream *standard-output*))
 812   "Print the failed assertions in the unit test."
 813   (loop for fail in (fail result) do
 814         (print-failures fail stream)))
 815
 816 (defmethod print-failures ((results test-results-db) &optional
 817                            (stream *standard-output*))
 818   "Print all of the failure tests."
 819   (loop with db = (database results)
 820         for test in (failed-tests results)
 821         as result = (gethash test db)
 822         do
 823         (print-failures result stream)
 824         (print-summary result stream)))
 825
 826 ;;; Print errors
 827
 828 (defgeneric print-errors (result &optional stream)
 829   (:documentation
 830    "Print the error condition."))
 831
 832 (defmethod print-errors ((result test-result) &optional
 833                          (stream *standard-output*))
 834   "Print the error condition."
 835   (let ((exerr (exerr result))
 836         (*print-escape* nil))
 837     (when exerr
 838       (format stream "~& | Execution error:~% | ~W" exerr)
 839       (format stream "~& |~%"))))
 840
 841 (defmethod print-errors ((results test-results-db) &optional
 842                          (stream *standard-output*))
 843   "Print all of the error tests."
 844   (loop with db = (database results)
 845         for test in (error-tests results)
 846         as result = (gethash test db)
 847         do
 848         (print-errors result stream)
 849         (print-summary result stream)))
 850
 851 ;;; Useful equality predicates for tests
 852
 853 (defun logically-equal (x y)
 854   "Return true if x and y are both false or both true."
 855   (eql (not x) (not y)))
 856
 857 (defun set-equal (list1 list2 &rest initargs &key key (test #'equal))
 858   "Return true if every element of list1 is an element of list2 and
 859 vice versa."
 860   (declare (ignore key test))
 861   (and
 862    (listp list1)
 863    (listp list2)
 864    (apply #'subsetp list1 list2 initargs)
 865    (apply #'subsetp list2 list1 initargs)))
 866
 867 (pushnew :lisp-unit common-lisp:*features*)