configure.ac

   1 AC_INIT([isl], [0.27], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=27:0:4
   8
   9 if test "x$prefix" != "xNONE"; then
  10         prefix_wd=`cd $prefix && pwd`
  11         srcdir_wd=`cd $srcdir && pwd`
  12         wd=`pwd`
  13         if test "x$prefix_wd" = "x$srcdir_wd"; then
  14                 AC_MSG_ERROR(Installation in source directory not supported)
  15         fi
  16         if test "x$prefix_wd" = "x$wd"; then
  17                 AC_MSG_ERROR(Installation in build directory not supported)
  18         fi
  19 fi
  20
  21 AC_PROG_CC
  22 AC_PROG_CXX
  23 AX_PROG_CC_FOR_BUILD
  24
  25 AX_CC_MAXOPT
  26 AX_GCC_WARN_UNUSED_RESULT
  27 AX_C___ATTRIBUTE__
  28
  29 AX_CXX_COMPILE_STDCXX_11_NO_OVERRIDE
  30 AX_CXX_COMPILE_STDCXX_17([], [optional])
  31
  32 AC_PROG_GREP
  33 LT_INIT
  34 AC_PROG_SED
  35 AM_PATH_PYTHON([3.6], [], [:])
  36 AM_CONDITIONAL([HAVE_PYTHON], [test "$PYTHON" != :])
  37
  38 AC_CHECK_PROG(CYGPATH, cygpath, cygpath, [])
  39 AC_CHECK_PROG(PERL, perl, perl, [])
  40 AC_CHECK_PROG(PDFLATEX, pdflatex, pdflatex, [])
  41 AC_CHECK_PROG(POD2HTML, pod2html, pod2html, [])
  42
  43 ISL_DETECT_DIFF_OPTIONS
  44
  45 AC_SUBST(OS_SRCDIR)
  46 if test "$host_os" = "mingw32" -a -n "$CYGPATH"; then
  47         OS_SRCDIR=`$CYGPATH -m "$srcdir"`
  48 else
  49         OS_SRCDIR="$srcdir"
  50 fi
  51
  52 AM_CONDITIONAL(GENERATE_DOC, test -n "$PERL" -a -n "$PDFLATEX" -a -n "$POD2HTML")
  53
  54 AX_CREATE_STDINT_H(include/isl/stdint.h)
  55
  56 AC_ARG_WITH([int],
  57             [AS_HELP_STRING([--with-int=gmp|imath|imath-32],
  58                             [Which package to use to represent
  59                                 multi-precision integers [default=gmp]])],
  60             [], [with_int=gmp])
  61 case "$with_int" in
  62 gmp|imath|imath-32)
  63         ;;
  64 *)
  65         AC_MSG_ERROR(
  66             [bad value ${withval} for --with-int (use gmp, imath or imath-32)])
  67 esac
  68
  69 AC_SUBST(MP_CPPFLAGS)
  70 AC_SUBST(MP_CFLAGS)
  71 AC_SUBST(MP_LDFLAGS)
  72 AC_SUBST(MP_LIBS)
  73 case "$with_int" in
  74 gmp)
  75         AX_DETECT_GMP
  76         ;;
  77 imath|imath-32)
  78         AX_DETECT_IMATH
  79         ;;
  80 esac
  81 if test "x$with_int" = "ximath-32" -a "x$GCC" = "xyes"; then
  82         MP_CFLAGS="-std=gnu99 $MP_CFLAGS"
  83 fi
  84
  85 AM_CONDITIONAL(IMATH_FOR_MP, test x$with_int = ximath -o x$with_int = ximath-32)
  86 AM_CONDITIONAL(GMP_FOR_MP, test x$with_int = xgmp)
  87
  88 AM_CONDITIONAL(HAVE_CXX11, test "x$HAVE_CXX11" = "x1")
  89 AM_CONDITIONAL(HAVE_CXX17, test "x$HAVE_CXX17" = "x1")
  90 AM_CONDITIONAL(SMALL_INT_OPT, test "x$with_int" = "ximath-32")
  91 AS_IF([test "x$with_int" = "ximath-32"], [
  92         AC_DEFINE([USE_SMALL_INT_OPT], [], [Use small integer optimization])
  93 ])
  94
  95 AC_CHECK_DECLS(ffs,[],[],[#include <strings.h>])
  96 AC_CHECK_DECLS(__builtin_ffs,[],[],[])
  97 AC_CHECK_DECLS([_BitScanForward],[],[],[#include <intrin.h>])
  98 if test "x$ac_cv_have_decl_ffs" = xno -a \
  99                 "x$ac_cv_have_decl___builtin_ffs" = xno -a \
 100                 "x$ac_cv_have_decl__BitScanForward" = xno; then
 101         AC_MSG_ERROR([No ffs implementation found])
 102 fi
 103 AC_CHECK_DECLS([strcasecmp,strncasecmp],[],[],[#include <strings.h>])
 104 AC_CHECK_DECLS([_stricmp,_strnicmp],[],[],[#include <string.h>])
 105 if test "x$ac_cv_have_decl_strcasecmp" = xno -a \
 106                 "x$ac_cv_have_decl__stricmp" = xno; then
 107         AC_MSG_ERROR([No strcasecmp implementation found])
 108 fi
 109 if test "x$ac_cv_have_decl_strncasecmp" = xno -a \
 110                 "x$ac_cv_have_decl__strnicmp" = xno; then
 111         AC_MSG_ERROR([No strncasecmp implementation found])
 112 fi
 113 AC_CHECK_DECLS([snprintf,_snprintf],[],[],[#include <stdio.h>])
 114 if test "x$ac_cv_have_decl_snprintf" = xno -a \
 115                 "x$ac_cv_have_decl__snprintf" = xno; then
 116         AC_MSG_ERROR([No snprintf implementation found])
 117 fi
 118
 119 AX_SUBMODULE(clang,system|no,no)
 120 AM_CONDITIONAL(HAVE_CLANG, test $with_clang = system)
 121
 122 AX_SET_WARNING_FLAGS
 123
 124 AC_SUBST(WARNING_FLAGS)
 125
 126 PACKAGE_CFLAGS="$MP_CPPFLAGS"
 127 PACKAGE_LDFLAGS="$MP_LDFLAGS"
 128 PACKAGE_LIBS="-lisl $MP_LIBS"
 129 AX_CREATE_PKGCONFIG_INFO
 130
 131 AX_DETECT_GIT_HEAD
 132
 133 AH_BOTTOM([#include <isl_config_post.h>])
 134 AC_CONFIG_HEADERS(isl_config.h)
 135 AC_CONFIG_FILES(isl_srcdir.c)
 136 AC_CONFIG_FILES(Makefile)
 137 AC_CONFIG_FILES(doc/Makefile)
 138 if test $with_clang = system; then
 139         AC_CONFIG_SUBDIRS(interface)
 140 fi
 141 AC_CONFIG_FILES([bound_test.sh], [chmod +x bound_test.sh])
 142 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 143 AC_CONFIG_FILES([pip_test.sh], [chmod +x pip_test.sh])
 144 AC_CONFIG_FILES([flow_test.sh], [chmod +x flow_test.sh])
 145 AC_CONFIG_FILES([schedule_test.sh], [chmod +x schedule_test.sh])
 146 AC_OUTPUT