configure.ac

   1 AC_INIT([isl], [0.12], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=12:0:2
   8
   9 if test "x$prefix" != "xNONE"; then
  10         prefix_wd=`cd $prefix && pwd`
  11         srcdir_wd=`cd $srcdir && pwd`
  12         wd=`pwd`
  13         if test "x$prefix_wd" = "x$srcdir_wd"; then
  14                 AC_MSG_ERROR(Installation in source directory not supported)
  15         fi
  16         if test "x$prefix_wd" = "x$wd"; then
  17                 AC_MSG_ERROR(Installation in build directory not supported)
  18         fi
  19 fi
  20
  21 AC_PROG_CC
  22 AC_PROG_CXX
  23
  24 AX_CC_MAXOPT
  25 AX_GCC_WARN_UNUSED_RESULT
  26 AX_C___ATTRIBUTE__
  27
  28 AC_PROG_LIBTOOL
  29
  30 AC_CHECK_PROG(PERL, perl, perl, [])
  31 AC_CHECK_PROG(PDFLATEX, pdflatex, pdflatex, [])
  32 AC_CHECK_PROG(POD2HTML, pod2html, pod2html, [])
  33
  34 AM_CONDITIONAL(GENERATE_DOC, test -n "$PERL" -a -n "$PDFLATEX" -a -n "$POD2HTML")
  35
  36 AX_CREATE_STDINT_H(include/isl/stdint.h)
  37
  38 AX_SUBMODULE(gmp,system|build,system)
  39
  40 AC_SUBST(GMP_CPPFLAGS)
  41 AC_SUBST(GMP_LDFLAGS)
  42 AC_SUBST(GMP_LIBS)
  43 case "$with_gmp" in
  44 system)
  45         if test "x$with_gmp_prefix" != "x"; then
  46                 isl_configure_args="$isl_configure_args --with-gmp=$with_gmp_prefix"
  47                 GMP_CPPFLAGS="-I$with_gmp_prefix/include"
  48                 GMP_LDFLAGS="-L$with_gmp_prefix/lib"
  49         fi
  50         GMP_LIBS=-lgmp
  51         SAVE_CPPFLAGS="$CPPFLAGS"
  52         SAVE_LDFLAGS="$LDFLAGS"
  53         SAVE_LIBS="$LIBS"
  54         CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
  55         LDFLAGS="$GMP_LDFLAGS $LDFLAGS"
  56         LIBS="$GMP_LIBS $LIBS"
  57         AC_CHECK_HEADER([gmp.h], [], [AC_ERROR([gmp.h header not found])])
  58         AC_CHECK_LIB([gmp], [main], [], [AC_ERROR([gmp library not found])])
  59         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <gmp.h>]], [[
  60                 mpz_t n, d;
  61                 if (mpz_divisible_p(n, d))
  62                         mpz_divexact_ui(n, n, 4);
  63         ]])], [], [AC_ERROR([gmp library too old])])
  64         CPPFLAGS="$SAVE_CPPFLAGS"
  65         LDFLAGS="$SAVE_LDFLAGS"
  66         LIBS="$SAVE_LIBS"
  67         ;;
  68 build)
  69         GMP_CPPFLAGS="-I$gmp_srcdir -I$with_gmp_builddir"
  70         GMP_LIBS="$with_gmp_builddir/libgmp.la"
  71         ;;
  72 esac
  73 SAVE_CPPFLAGS="$CPPFLAGS"
  74 SAVE_LDFLAGS="$LDFLAGS"
  75 SAVE_LIBS="$LIBS"
  76 CPPFLAGS="$GMP_CPPFLAGS $CPPFLAGS"
  77 LDFLAGS="$GMP_LDFLAGS $LDFLAGS"
  78 LIBS="$GMP_LIBS $LIBS"
  79 need_get_memory_functions=false
  80 AC_CHECK_DECLS(mp_get_memory_functions,[],[
  81         need_get_memory_functions=true
  82 ],[#include <gmp.h>])
  83 AC_RUN_IFELSE([AC_LANG_PROGRAM([[#include <gmp.h>]], [[
  84         mpz_t x,y,g,a,b;
  85         mpz_init(x);
  86         mpz_init(y);
  87         mpz_init(g);
  88         mpz_init(a);
  89         mpz_init(b);
  90         mpz_set_si(x, -1);
  91         mpz_set_si(y, 9);
  92         mpz_gcdext(g, a, b, x, y);
  93         if (mpz_get_si(a) == -1 && mpz_get_si(b) == 0)
  94                 return 0;
  95         else
  96                 return 1;
  97 ]])], [need_normalized_gcdext=false], [need_normalized_gcdext=true],
  98 [need_normalized_gcdext=true])
  99 CPPFLAGS="$SAVE_CPPFLAGS"
 100 LDFLAGS="$SAVE_LDFLAGS"
 101 LIBS="$SAVE_LIBS"
 102 AM_CONDITIONAL(NEED_GET_MEMORY_FUNCTIONS, test x$need_get_memory_functions = xtrue)
 103 if test $need_normalized_gcdext = true; then
 104 AC_DEFINE([GMP_NORMALIZE_GCDEXT], [],
 105         [result of mpz_gcdext needs to be normalized])
 106 fi
 107
 108 AC_SUBST(CLANG_CXXFLAGS)
 109 AC_SUBST(CLANG_LDFLAGS)
 110 AC_SUBST(CLANG_LIBS)
 111 AX_SUBMODULE(clang,system|no,no)
 112 case "$with_clang" in
 113 system)
 114         llvm_config="llvm-config"
 115         AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
 116         if test "x$with_clang_prefix" != "x"; then
 117                 llvm_config="$with_clang_prefix/bin/llvm-config"
 118                 if test -x "$llvm_config"; then
 119                         llvm_config_found=yes
 120                 fi
 121         fi
 122         if test "$llvm_config_found" != yes; then
 123                 AC_MSG_ERROR([llvm-config not found])
 124         fi
 125         CLANG_CXXFLAGS=`$llvm_config --cxxflags`
 126         CLANG_LDFLAGS=`$llvm_config --ldflags`
 127         targets=`$llvm_config --targets-built`
 128         CLANG_LIBS=`$llvm_config --libs $targets asmparser bitreader support mc`
 129         CLANG_PREFIX=`$llvm_config --prefix`
 130         AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"],
 131                                 [Clang installation prefix])
 132
 133         SAVE_CPPFLAGS="$CPPFLAGS"
 134         CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
 135         AC_LANG_PUSH(C++)
 136         AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
 137                 [AC_ERROR([clang header file not found])])
 138         AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
 139                 [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
 140                 [Define to getHostTriple for older versions of clang])])
 141         AC_EGREP_HEADER([getExpansionLineNumber],
 142                 [clang/Basic/SourceLocation.h], [],
 143                 [AC_DEFINE([getExpansionLineNumber],
 144                         [getInstantiationLineNumber],
 145             [Define to getInstantiationLineNumber for older versions of clang])])
 146         AC_EGREP_HEADER([DiagnosticsEngine],
 147                 [clang/Basic/Diagnostic.h], [],
 148                 [AC_DEFINE([DiagnosticsEngine],
 149                         [Diagnostic],
 150             [Define to Diagnostic for older versions of clang])])
 151         AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
 152                 [AC_DEFINE([USE_ARRAYREF], [],
 153                         [Define if Driver::BuildCompilation takes ArrayRef])])
 154         AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
 155                 [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
 156                 [Define if Driver constructor takes CXXIsProduction argument])])
 157         AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
 158                 [AC_DEFINE([HAVE_ISPRODUCTION], [],
 159                 [Define if Driver constructor takes IsProduction argument])])
 160         AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
 161                 [AC_DEFINE([HandleTopLevelDeclReturn], [void],
 162                            [Return type of HandleTopLevelDeclReturn])
 163                  AC_DEFINE([HandleTopLevelDeclContinue], [],
 164                            [Return type of HandleTopLevelDeclReturn])],
 165                 [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
 166                            [Return type of HandleTopLevelDeclReturn])
 167                  AC_DEFINE([HandleTopLevelDeclContinue], [true],
 168                            [Return type of HandleTopLevelDeclReturn])])
 169         AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 170                 [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 171                            [Define if clang/Basic/DiagnosticOptions.h exists])])
 172         AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 173                 using namespace clang;
 174                 TargetOptions *TO;
 175                 DiagnosticsEngine *Diags;
 176                 TargetInfo::CreateTargetInfo(*Diags, TO);
 177         ], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 178                       [Define if TargetInfo::CreateTargetInfo takes pointer])])
 179         AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 180                 using namespace clang;
 181                 DiagnosticConsumer *client;
 182                 CompilerInstance *Clang;
 183                 Clang->createDiagnostics(client);
 184         ], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 185         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 186         AC_TRY_COMPILE([#include <clang/Lex/HeaderSearchOptions.h>], [
 187                 using namespace clang;
 188                 HeaderSearchOptions HSO;
 189                 HSO.AddPath("", frontend::Angled, false, false);
 190         ], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 191                 [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 192         AC_LANG_POP
 193         CPPFLAGS="$SAVE_CPPFLAGS"
 194
 195         SAVE_LDFLAGS="$LDFLAGS"
 196         LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 197         AC_SUBST(LIB_CLANG_EDIT)
 198         AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 199         LDFLAGS="$SAVE_LDFLAGS"
 200         ;;
 201 esac
 202 AM_CONDITIONAL(HAVE_CLANG, test $with_clang = system)
 203
 204 AX_SET_WARNING_FLAGS
 205
 206 AC_SUBST(WARNING_FLAGS)
 207
 208 PACKAGE_CFLAGS="$GMP_CPPFLAGS"
 209 PACKAGE_LDFLAGS="$GMP_LDFLAGS"
 210 PACKAGE_LIBS="-lisl -lgmp"
 211 AX_CREATE_PKGCONFIG_INFO
 212
 213 AX_DETECT_GIT_HEAD
 214 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
 215
 216 AH_BOTTOM([#include <isl_config_post.h>])
 217 AC_CONFIG_HEADERS(isl_config.h)
 218 AC_CONFIG_HEADERS(include/isl/config.h)
 219 AC_CONFIG_FILES(Makefile)
 220 AC_CONFIG_FILES(doc/Makefile)
 221 if test $with_clang = system; then
 222         AC_CONFIG_FILES(interface/Makefile)
 223 fi
 224 AC_CONFIG_FILES([bound_test.sh], [chmod +x bound_test.sh])
 225 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 226 AC_CONFIG_FILES([pip_test.sh], [chmod +x pip_test.sh])
 227 AC_CONFIG_COMMANDS_POST([
 228         dnl pass on arguments to subdir configures, but don't
 229         dnl add them to config.status
 230         ac_configure_args="$ac_configure_args $isl_configure_args"
 231 ])
 232 AC_OUTPUT