configure.ac

   1 AC_INIT([isl], [0.13], [isl-development@googlegroups.com])
   2 AC_CONFIG_AUX_DIR([.])
   3 AC_CONFIG_MACRO_DIR([m4])
   4 AM_INIT_AUTOMAKE([foreign])
   5 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])])
   6 AC_SUBST(versioninfo)
   7 versioninfo=13:0:0
   8
   9 if test "x$prefix" != "xNONE"; then
  10         prefix_wd=`cd $prefix && pwd`
  11         srcdir_wd=`cd $srcdir && pwd`
  12         wd=`pwd`
  13         if test "x$prefix_wd" = "x$srcdir_wd"; then
  14                 AC_MSG_ERROR(Installation in source directory not supported)
  15         fi
  16         if test "x$prefix_wd" = "x$wd"; then
  17                 AC_MSG_ERROR(Installation in build directory not supported)
  18         fi
  19 fi
  20
  21 AC_PROG_CC
  22 AC_PROG_CXX
  23
  24 AX_CC_MAXOPT
  25 AX_GCC_WARN_UNUSED_RESULT
  26 AX_C___ATTRIBUTE__
  27
  28 AC_PROG_LIBTOOL
  29
  30 AC_CHECK_PROG(PERL, perl, perl, [])
  31 AC_CHECK_PROG(PDFLATEX, pdflatex, pdflatex, [])
  32 AC_CHECK_PROG(POD2HTML, pod2html, pod2html, [])
  33
  34 AM_CONDITIONAL(GENERATE_DOC, test -n "$PERL" -a -n "$PDFLATEX" -a -n "$POD2HTML")
  35
  36 AX_CREATE_STDINT_H(include/isl/stdint.h)
  37
  38 AC_SUBST(GMP_CPPFLAGS)
  39 AC_SUBST(GMP_LDFLAGS)
  40 AC_SUBST(GMP_LIBS)
  41 AX_DETECT_GMP
  42
  43 AC_CHECK_DECLS(ffs,[],[],[#include <strings.h>])
  44 AC_CHECK_DECLS(__builtin_ffs,[],[],[])
  45
  46 AC_SUBST(CLANG_CXXFLAGS)
  47 AC_SUBST(CLANG_LDFLAGS)
  48 AC_SUBST(CLANG_LIBS)
  49 AX_SUBMODULE(clang,system|no,no)
  50 case "$with_clang" in
  51 system)
  52         AC_PROG_GREP
  53         llvm_config="llvm-config"
  54         AC_CHECK_PROG([llvm_config_found], ["$llvm_config"], [yes])
  55         if test "x$with_clang_prefix" != "x"; then
  56                 llvm_config="$with_clang_prefix/bin/llvm-config"
  57                 if test -x "$llvm_config"; then
  58                         llvm_config_found=yes
  59                 fi
  60         fi
  61         if test "$llvm_config_found" != yes; then
  62                 AC_MSG_ERROR([llvm-config not found])
  63         fi
  64         CLANG_CXXFLAGS=`$llvm_config --cxxflags`
  65         CLANG_LDFLAGS=`$llvm_config --ldflags`
  66         targets=`$llvm_config --targets-built`
  67         components="$targets asmparser bitreader support mc"
  68         $llvm_config --components | $GREP option > /dev/null 2> /dev/null
  69         if test $? -eq 0; then
  70                 components="$components option"
  71         fi
  72         CLANG_LIBS=`$llvm_config --libs $components`
  73         systemlibs=`$llvm_config --system-libs 2> /dev/null | tail -1`
  74         if test $? -eq 0; then
  75                 CLANG_LIBS="$CLANG_LIBS $systemlibs"
  76         fi
  77         CLANG_PREFIX=`$llvm_config --prefix`
  78         AC_DEFINE_UNQUOTED(CLANG_PREFIX, ["$CLANG_PREFIX"],
  79                                 [Clang installation prefix])
  80
  81         SAVE_CPPFLAGS="$CPPFLAGS"
  82         CPPFLAGS="$CLANG_CXXFLAGS $CPPFLAGS"
  83         AC_LANG_PUSH(C++)
  84         AC_CHECK_HEADER([clang/Basic/SourceLocation.h], [],
  85                 [AC_ERROR([clang header file not found])])
  86         AC_EGREP_HEADER([getDefaultTargetTriple], [llvm/Support/Host.h], [],
  87                 [AC_DEFINE([getDefaultTargetTriple], [getHostTriple],
  88                 [Define to getHostTriple for older versions of clang])])
  89         AC_EGREP_HEADER([getExpansionLineNumber],
  90                 [clang/Basic/SourceLocation.h], [],
  91                 [AC_DEFINE([getExpansionLineNumber],
  92                         [getInstantiationLineNumber],
  93             [Define to getInstantiationLineNumber for older versions of clang])])
  94         AC_EGREP_HEADER([DiagnosticsEngine],
  95                 [clang/Basic/Diagnostic.h], [],
  96                 [AC_DEFINE([DiagnosticsEngine],
  97                         [Diagnostic],
  98             [Define to Diagnostic for older versions of clang])])
  99         AC_EGREP_HEADER([ArrayRef], [clang/Driver/Driver.h],
 100                 [AC_DEFINE([USE_ARRAYREF], [],
 101                         [Define if Driver::BuildCompilation takes ArrayRef])])
 102         AC_EGREP_HEADER([CXXIsProduction], [clang/Driver/Driver.h],
 103                 [AC_DEFINE([HAVE_CXXISPRODUCTION], [],
 104                 [Define if Driver constructor takes CXXIsProduction argument])])
 105         AC_EGREP_HEADER([ IsProduction], [clang/Driver/Driver.h],
 106                 [AC_DEFINE([HAVE_ISPRODUCTION], [],
 107                 [Define if Driver constructor takes IsProduction argument])])
 108         AC_EGREP_HEADER([void HandleTopLevelDecl\(], [clang/AST/ASTConsumer.h],
 109                 [AC_DEFINE([HandleTopLevelDeclReturn], [void],
 110                            [Return type of HandleTopLevelDeclReturn])
 111                  AC_DEFINE([HandleTopLevelDeclContinue], [],
 112                            [Return type of HandleTopLevelDeclReturn])],
 113                 [AC_DEFINE([HandleTopLevelDeclReturn], [bool],
 114                            [Return type of HandleTopLevelDeclReturn])
 115                  AC_DEFINE([HandleTopLevelDeclContinue], [true],
 116                            [Return type of HandleTopLevelDeclReturn])])
 117         AC_CHECK_HEADER([clang/Basic/DiagnosticOptions.h],
 118                 [AC_DEFINE([HAVE_BASIC_DIAGNOSTICOPTIONS_H], [],
 119                            [Define if clang/Basic/DiagnosticOptions.h exists])])
 120         AC_TRY_COMPILE([#include <clang/Basic/TargetInfo.h>], [
 121                 using namespace clang;
 122                 TargetOptions *TO;
 123                 DiagnosticsEngine *Diags;
 124                 TargetInfo::CreateTargetInfo(*Diags, TO);
 125         ], [AC_DEFINE([CREATETARGETINFO_TAKES_POINTER], [],
 126                       [Define if TargetInfo::CreateTargetInfo takes pointer])])
 127         AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 128                 using namespace clang;
 129                 DiagnosticConsumer *client;
 130                 CompilerInstance *Clang;
 131                 Clang->createDiagnostics(client);
 132         ], [], [AC_DEFINE([CREATEDIAGNOSTICS_TAKES_ARG], [],
 133         [Define if CompilerInstance::createDiagnostics takes argc and argv])])
 134         AC_TRY_COMPILE([#include <clang/Lex/HeaderSearchOptions.h>], [
 135                 using namespace clang;
 136                 HeaderSearchOptions HSO;
 137                 HSO.AddPath("", frontend::Angled, false, false);
 138         ], [AC_DEFINE([ADDPATH_TAKES_4_ARGUMENTS], [],
 139                 [Define if HeaderSearchOptions::AddPath takes 4 arguments])])
 140         AC_EGREP_HEADER([getNumParams],
 141                 [clang/AST/CanonicalType.h],
 142                 [AC_DEFINE([getNumArgs], [getNumParams],
 143                     [Define to getNumParams for newer versions of clang])
 144                  AC_DEFINE([getArgType], [getParamType],
 145                     [Define to getParamType for newer versions of clang])])
 146         AC_EGREP_HEADER([getReturnType],
 147                 [clang/AST/CanonicalType.h], [],
 148                 [AC_DEFINE([getReturnType], [getResultType],
 149                     [Define to getResultType for older versions of clang])])
 150         AC_TRY_COMPILE([#include <clang/Frontend/CompilerInstance.h>], [
 151                 using namespace clang;
 152                 CompilerInstance *Clang;
 153                 Clang->createPreprocessor(TU_Complete);
 154         ], [AC_DEFINE([CREATEPREPROCESSOR_TAKES_TUKIND], [],
 155         [Define if CompilerInstance::createPreprocessor takes
 156          TranslationUnitKind])])
 157         AC_LANG_POP
 158         CPPFLAGS="$SAVE_CPPFLAGS"
 159
 160         SAVE_LDFLAGS="$LDFLAGS"
 161         LDFLAGS="$CLANG_LDFLAGS $LDFLAGS"
 162         AC_SUBST(LIB_CLANG_EDIT)
 163         AC_CHECK_LIB([clangEdit], [main], [LIB_CLANG_EDIT=-lclangEdit], [])
 164         LDFLAGS="$SAVE_LDFLAGS"
 165         ;;
 166 esac
 167 AM_CONDITIONAL(HAVE_CLANG, test $with_clang = system)
 168
 169 AX_SET_WARNING_FLAGS
 170
 171 AC_SUBST(WARNING_FLAGS)
 172
 173 PACKAGE_CFLAGS="$GMP_CPPFLAGS"
 174 PACKAGE_LDFLAGS="$GMP_LDFLAGS"
 175 PACKAGE_LIBS="-lisl -lgmp"
 176 AX_CREATE_PKGCONFIG_INFO
 177
 178 AX_DETECT_GIT_HEAD
 179 echo '#define GIT_HEAD_ID "'$GIT_HEAD_ID'"' > gitversion.h
 180
 181 AH_BOTTOM([#include <isl_config_post.h>])
 182 AC_CONFIG_HEADERS(isl_config.h)
 183 AC_CONFIG_FILES(Makefile)
 184 AC_CONFIG_FILES(doc/Makefile)
 185 if test $with_clang = system; then
 186         AC_CONFIG_FILES(interface/Makefile)
 187 fi
 188 AC_CONFIG_FILES([bound_test.sh], [chmod +x bound_test.sh])
 189 AC_CONFIG_FILES([codegen_test.sh], [chmod +x codegen_test.sh])
 190 AC_CONFIG_FILES([pip_test.sh], [chmod +x pip_test.sh])
 191 AC_CONFIG_COMMANDS_POST([
 192         dnl pass on arguments to subdir configures, but don't
 193         dnl add them to config.status
 194         ac_configure_args="$ac_configure_args $isl_configure_args"
 195 ])
 196 AC_OUTPUT