src/sockets/socket-methods.lisp

   1 ;;;; -*- Mode: Lisp; indent-tabs-mode: nil -*-
   2 ;;;
   3 ;;; --- Various socket methods.
   4 ;;;
   5
   6 (in-package :iolib.sockets)
   7
   8 ;;;-------------------------------------------------------------------------
   9 ;;; Shared Initialization
  10 ;;;-------------------------------------------------------------------------
  11
  12 (defun translate-make-socket-keywords-to-constants (address-family type protocol)
  13   (let ((sf (ecase address-family
  14               (:ipv4  af-inet)
  15               (:ipv6  af-inet6)
  16               (:local af-local)))
  17         (st (ecase type
  18               (:stream   sock-stream)
  19               (:datagram sock-dgram)
  20               (:raw      sock-raw)))
  21         (sp (etypecase protocol
  22               ((eql :default) 0)
  23               (integer        protocol))))
  24     (values sf st sp)))
  25
  26 (defmethod socket-os-fd ((socket socket))
  27   (fd-of socket))
  28
  29 (defmethod shared-initialize :after
  30     ((socket socket) slot-names
  31      &key file-descriptor (dup t) address-family type protocol)
  32   (declare (ignore slot-names))
  33   (with-accessors ((fd fd-of) (fam socket-address-family) (proto socket-protocol))
  34       socket
  35     (setf fd (or (and file-descriptor (if dup
  36                                           (isys:dup file-descriptor)
  37                                           file-descriptor))
  38                  (multiple-value-call #'%socket
  39                    (translate-make-socket-keywords-to-constants
  40                     address-family type protocol))))
  41     (setf fam address-family
  42           proto protocol)))
  43
  44 (defmethod (setf external-format-of) (external-format (socket passive-socket))
  45   (setf (slot-value socket 'external-format)
  46         (babel:ensure-external-format (or external-format :default))))
  47
  48 (defmethod shared-initialize :after ((socket passive-socket) slot-names
  49                                      &key external-format
  50                                      input-buffer-size output-buffer-size)
  51   ;; Makes CREATE-SOCKET simpler
  52   (declare (ignore slot-names input-buffer-size output-buffer-size))
  53   (setf (external-format-of socket) (or external-format :default)))
  54 \f
  55
  56 ;;;-------------------------------------------------------------------------
  57 ;;; Misc
  58 ;;;-------------------------------------------------------------------------
  59
  60 (defmethod socket-type ((socket stream-socket))
  61   :stream)
  62
  63 (defmethod socket-type ((socket datagram-socket))
  64   :datagram)
  65
  66 (defun socket-ipv6-p (socket)
  67   "Return T if SOCKET is an AF_INET6 socket."
  68   (eql :ipv6 (socket-address-family socket)))
  69
  70 (defun ipv6-socket-p (&rest args)
  71   (apply #'socket-ipv6-p args))
  72
  73 (defobsolete ipv6-socket-p socket-ipv6-p)
  74 \f
  75
  76 ;;;-------------------------------------------------------------------------
  77 ;;; PRINT-OBJECT
  78 ;;;-------------------------------------------------------------------------
  79
  80 (defun sock-fam (socket)
  81   (ecase (socket-address-family socket)
  82     (:ipv4 "IPv4")
  83     (:ipv6 "IPv6")))
  84
  85 (defmethod print-object ((socket socket-stream-internet-active) stream)
  86   (print-unreadable-object (socket stream :identity t)
  87     (format stream "active ~A stream socket" (sock-fam socket))
  88     (if (socket-connected-p socket)
  89         (multiple-value-bind (host port) (remote-name socket)
  90           (format stream " connected to ~A/~A"
  91                   (address-to-string host) port))
  92         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
  93
  94 (defmethod print-object ((socket socket-stream-internet-passive) stream)
  95   (print-unreadable-object (socket stream :identity t)
  96     (format stream "passive ~A stream socket" (sock-fam socket))
  97     (if (socket-bound-p socket)
  98         (multiple-value-bind (host port) (local-name socket)
  99           (format stream " ~:[bound to~;waiting @~] ~A/~A"
 100                   (socket-listening-p socket)
 101                   (address-to-string host) port))
 102         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 103
 104 (defmethod print-object ((socket socket-stream-local-active) stream)
 105   (print-unreadable-object (socket stream :identity t)
 106     (format stream "active local stream socket")
 107     (if (socket-connected-p socket)
 108         (format stream " connected to ~S"
 109                 (address-to-string (remote-filename socket)))
 110         (format stream ", ~:[closed~;unconnected~]" (fd-of socket)))))
 111
 112 (defmethod print-object ((socket socket-stream-local-passive) stream)
 113   (print-unreadable-object (socket stream :identity t)
 114     (format stream "passive local stream socket")
 115     (if (socket-bound-p socket)
 116         (format stream " ~:[bound to~;waiting @~] ~A"
 117                   (socket-listening-p socket)
 118                   (address-to-string (local-filename socket)))
 119         (format stream ", ~:[closed~;unbound~]" (fd-of socket)))))
 120
 121 (defmethod print-object ((socket socket-datagram-local) stream)
 122   (print-unreadable-object (socket stream :identity t)
 123     (format stream "local datagram socket")
 124     (if (socket-connected-p socket)
 125         (format stream " connected to ~S"
 126                 (address-to-string (remote-filename socket)))
 127         (if (fd-of socket)
 128             (format stream " waiting @ ~S" (address-to-string (local-filename socket)))
 129             (format stream ", closed" )))))
 130
 131 (defmethod print-object ((socket socket-datagram-internet) stream)
 132   (print-unreadable-object (socket stream :identity t)
 133     (format stream "~A datagram socket" (sock-fam socket))
 134     (if (socket-connected-p socket)
 135         (multiple-value-bind (host port) (remote-name socket)
 136           (format stream " connected to ~A/~A"
 137                   (address-to-string host) port))
 138         (if (fd-of socket)
 139             (multiple-value-bind (host port) (local-name socket)
 140               (format stream " waiting @ ~A/~A"
 141                       (address-to-string host) port))
 142             (format stream ", closed" )))))
 143 \f
 144
 145 ;;;-------------------------------------------------------------------------
 146 ;;; CLOSE
 147 ;;;-------------------------------------------------------------------------
 148
 149 (defmethod close :before ((socket socket) &key abort)
 150   (declare (ignore abort))
 151   (setf (slot-value socket 'bound) nil))
 152
 153 (defmethod close ((socket socket) &key abort)
 154   (declare (ignore abort))
 155   (when (next-method-p)
 156     (call-next-method))
 157   (socket-open-p socket))
 158
 159 (defmethod close :before ((socket passive-socket) &key abort)
 160   (declare (ignore abort))
 161   (setf (slot-value socket 'listening) nil))
 162
 163 (defmethod socket-open-p ((socket socket))
 164   (if (null (fd-of socket))
 165       nil
 166       (with-sockaddr-storage-and-socklen (ss size)
 167         (handler-case
 168             (%getsockname (fd-of socket) ss size)
 169           (isys:ebadf () nil)
 170           (socket-connection-reset-error () nil)
 171           (:no-error (_) (declare (ignore _)) t)))))
 172 \f
 173
 174 ;;;-------------------------------------------------------------------------
 175 ;;; GETSOCKNAME
 176 ;;;-------------------------------------------------------------------------
 177
 178 (defun %local-name (socket)
 179   (with-sockaddr-storage-and-socklen (ss size)
 180     (%getsockname (fd-of socket) ss size)
 181     (sockaddr-storage->sockaddr ss)))
 182
 183 (defmethod local-name ((socket socket))
 184   (%local-name socket))
 185
 186 (defmethod local-host ((socket internet-socket))
 187   (nth-value 0 (%local-name socket)))
 188
 189 (defmethod local-port ((socket internet-socket))
 190   (nth-value 1 (%local-name socket)))
 191
 192 (defmethod local-filename ((socket local-socket))
 193   (%local-name socket))
 194 \f
 195
 196 ;;;-------------------------------------------------------------------------
 197 ;;; GETPEERNAME
 198 ;;;-------------------------------------------------------------------------
 199
 200 (defun %remote-name (socket)
 201   (with-sockaddr-storage-and-socklen (ss size)
 202     (%getpeername (fd-of socket) ss size)
 203     (sockaddr-storage->sockaddr ss)))
 204
 205 (defmethod remote-name ((socket socket))
 206   (%remote-name socket))
 207
 208 (defmethod remote-host ((socket internet-socket))
 209   (nth-value 0 (%remote-name socket)))
 210
 211 (defmethod remote-port ((socket internet-socket))
 212   (nth-value 1 (%remote-name socket)))
 213
 214 (defmethod remote-filename ((socket local-socket))
 215   (%remote-name socket))
 216 \f
 217
 218 ;;;-------------------------------------------------------------------------
 219 ;;; BIND
 220 ;;;-------------------------------------------------------------------------
 221
 222 (defmethod bind-address :before ((socket internet-socket) address
 223                                  &key (reuse-address t))
 224   (declare (ignore address))
 225   (when reuse-address
 226     (setf (socket-option socket :reuse-address) t)))
 227
 228 (defun bind-ipv4-address (fd address port)
 229   (with-sockaddr-in (sin address port)
 230     (%bind fd sin (isys:sizeof 'sockaddr-in))))
 231
 232 (defun bind-ipv6-address (fd address port)
 233   (with-sockaddr-in6 (sin6 address port)
 234     (%bind fd sin6 (isys:sizeof 'sockaddr-in6))))
 235
 236 (defmethod bind-address ((socket internet-socket) (address ipv4-address)
 237                          &key (port 0))
 238   (let ((port (ensure-numerical-service port)))
 239     (if (socket-ipv6-p socket)
 240         (bind-ipv6-address (fd-of socket)
 241                            (map-ipv4-vector-to-ipv6 (address-name address))
 242                            port)
 243         (bind-ipv4-address (fd-of socket) (address-name address) port)))
 244   (values socket))
 245
 246 (defmethod bind-address ((socket internet-socket) (address ipv6-address)
 247                          &key (port 0))
 248   (bind-ipv6-address (fd-of socket)
 249                      (address-name address)
 250                      (ensure-numerical-service port))
 251   (values socket))
 252
 253 (defmethod bind-address ((socket local-socket) (address local-address) &key)
 254   (with-sockaddr-un (sun (address-name address) (abstract-address-p address))
 255     (%bind (fd-of socket) sun (actual-size-of-sockaddr-un sun)))
 256   (values socket))
 257
 258 (defmethod bind-address :after ((socket socket) (address address) &key)
 259   (setf (slot-value socket 'bound) t))
 260 \f
 261
 262 ;;;-------------------------------------------------------------------------
 263 ;;; LISTEN
 264 ;;;-------------------------------------------------------------------------
 265
 266 (defmethod listen-on ((socket socket) &key backlog)
 267   (unless backlog (setf backlog (min *default-backlog-size*
 268                                      +max-backlog-size+)))
 269   (check-type backlog unsigned-byte "a non-negative integer")
 270   (%listen (fd-of socket) backlog)
 271   (setf (slot-value socket 'listening) t)
 272   (values socket))
 273 \f
 274
 275 ;;;-------------------------------------------------------------------------
 276 ;;; ACCEPT
 277 ;;;-------------------------------------------------------------------------
 278
 279 (defmethod accept-connection ((socket passive-socket) &key external-format
 280                               input-buffer-size output-buffer-size (wait t))
 281   (check-type wait timeout-designator)
 282   (flet ((make-client-socket (fd)
 283            (make-instance (active-class socket)
 284                           :address-family (socket-address-family socket)
 285                           :file-descriptor fd :dup nil
 286                           :external-format (or external-format
 287                                                (external-format-of socket))
 288                           :input-buffer-size input-buffer-size
 289                           :output-buffer-size output-buffer-size)))
 290     (ignore-some-conditions (isys:ewouldblock iomux:poll-timeout)
 291       (iomux:wait-until-fd-ready (fd-of socket) :input (wait->timeout wait) t)
 292       (with-sockaddr-storage-and-socklen (ss size)
 293         (multiple-value-call #'values
 294           (make-client-socket (%accept (fd-of socket) ss size))
 295           (sockaddr-storage->sockaddr ss))))))
 296 \f
 297
 298 ;;;-------------------------------------------------------------------------
 299 ;;; CONNECT
 300 ;;;-------------------------------------------------------------------------
 301
 302 (defun ipv4-connect (fd address port)
 303   (with-sockaddr-in (sin address port)
 304     (%connect fd sin (isys:sizeof 'sockaddr-in))))
 305
 306 (defun ipv6-connect (fd address port)
 307   (with-sockaddr-in6 (sin6 address port)
 308     (%connect fd sin6 (isys:sizeof 'sockaddr-in6))))
 309
 310 (defun call-with-socket-to-wait-connect (socket thunk wait)
 311   (check-type wait timeout-designator)
 312   (let ((timeout (wait->timeout wait)))
 313     (flet
 314         ((wait-connect ()
 315            (when (or (null  timeout)
 316                      (plusp timeout))
 317              (handler-case
 318                  (iomux:wait-until-fd-ready (fd-of socket) :output timeout t)
 319                (iomux:poll-error ()
 320                  (let ((errcode (socket-option socket :error)))
 321                    (if (zerop errcode)
 322                        (bug "Polling socket signalled an error but SO_ERROR is 0")
 323                        (signal-socket-error errcode "connect" (fd-of socket)))))))))
 324       (ignore-some-conditions (iomux:poll-timeout)
 325         (handler-case
 326             (funcall thunk)
 327           ((or isys:ewouldblock
 328                isys:einprogress) ()
 329             (wait-connect)))))))
 330
 331 (defmacro with-socket-to-wait-connect ((socket wait) &body body)
 332   `(call-with-socket-to-wait-connect ,socket (lambda () ,@body) ,wait))
 333
 334 (defmethod connect ((socket internet-socket) (address inet-address)
 335                     &key (port 0) (wait t))
 336   (let ((name (address-name address))
 337         (port (ensure-numerical-service port)))
 338     (with-socket-to-wait-connect (socket wait)
 339       (cond
 340         ((socket-ipv6-p socket)
 341          (when (ipv4-address-p address)
 342            (setf name (map-ipv4-vector-to-ipv6 name)))
 343          (ipv6-connect (fd-of socket) name port))
 344         (t (ipv4-connect (fd-of socket) name port)))))
 345   (values socket))
 346
 347 (defmethod connect ((socket local-socket) (address local-address) &key (wait t))
 348   (with-socket-to-wait-connect (socket wait)
 349     (with-sockaddr-un (sun (address-name address) (abstract-address-p address))
 350         (%connect (fd-of socket) sun (actual-size-of-sockaddr-un sun))))
 351   (values socket))
 352
 353 (defmethod socket-connected-p ((socket socket))
 354   (if (fd-of socket)
 355       (with-sockaddr-storage-and-socklen (ss size)
 356         (handler-case
 357             (%getpeername (fd-of socket) ss size)
 358           ((or isys:enotconn isys:einval) ()  nil)
 359           (:no-error (_) (declare (ignore _)) t)))
 360       nil))
 361 \f
 362
 363 ;;;-------------------------------------------------------------------------
 364 ;;; DISCONNECT
 365 ;;;-------------------------------------------------------------------------
 366
 367 (defmethod disconnect ((socket datagram-socket))
 368   (with-foreign-object (sin 'sockaddr-in)
 369     (isys:bzero sin (isys:sizeof 'sockaddr-in))
 370     (setf (foreign-slot-value sin 'sockaddr-in 'addr) af-unspec)
 371     (%connect (fd-of socket) sin (isys:sizeof 'sockaddr-in))
 372     (values socket)))
 373 \f
 374
 375 ;;;-------------------------------------------------------------------------
 376 ;;; SHUTDOWN
 377 ;;;-------------------------------------------------------------------------
 378
 379 (defmethod shutdown ((socket socket) &key read write)
 380   (assert (or read write) (read write)
 381           "You must select at least one direction to shut down.")
 382   (%shutdown (fd-of socket)
 383              (multiple-value-case ((read write))
 384                ((*   nil) shut-rd)
 385                ((nil *)   shut-wr)
 386                (t         shut-rdwr)))
 387   (values socket))
 388 \f
 389
 390 ;;;-------------------------------------------------------------------------
 391 ;;; Socket flag definition
 392 ;;;-------------------------------------------------------------------------
 393
 394 (defmacro define-socket-flag (place name value platform)
 395   (let ((val (cond ((or (not platform)
 396                         (featurep platform)) value)
 397                    ((not (featurep platform)) 0))))
 398     `(pushnew (cons ,name ,val) ,place)))
 399
 400 (defmacro define-socket-flags (place &body definitions)
 401   (flet ((dflag (form)
 402            (destructuring-bind (name value &optional platform) form
 403              `(define-socket-flag ,place ,name ,value ,platform))))
 404     `(progn
 405        ,@(mapcar #'dflag definitions))))
 406 \f
 407
 408 ;;;-------------------------------------------------------------------------
 409 ;;; SENDTO
 410 ;;;-------------------------------------------------------------------------
 411
 412 (defvar *sendto-flags* ())
 413
 414 (define-socket-flags *sendto-flags*
 415   (:dont-route    msg-dontroute)
 416   (:dont-wait     msg-dontwait  (:not :windows))
 417   (:out-of-band   msg-oob)
 418   (:more          msg-more      :linux)
 419   (:confirm       msg-confirm   :linux))
 420
 421 (defun %%send-to (fd ss got-peer buff-sap start length flags)
 422   (incf-pointer buff-sap start)
 423   (loop
 424     (restart-case
 425         (return*
 426          (%sendto fd buff-sap length flags
 427                   (if got-peer ss (null-pointer))
 428                   (if got-peer (sockaddr-size ss) 0)))
 429       (ignore-syscall-error ()
 430         :report "Ignore this socket condition"
 431         :test isys:syscall-error-p
 432         (return* 0))
 433       (retry-syscall (&optional (timeout 15.0d0))
 434         :report "Try to send data again"
 435         :test isys:syscall-error-p
 436         (when (plusp timeout)
 437           (iomux:wait-until-fd-ready fd :output timeout nil))))))
 438
 439 (defun %send-to (fd ss got-peer buffer start end flags)
 440   (etypecase buffer
 441     (ub8-sarray
 442      (check-bounds buffer start end)
 443      (with-pointer-to-vector-data (buff-sap buffer)
 444        (%%send-to fd ss got-peer buff-sap start (- end start) flags)))
 445     ((or ub8-vector (vector t))
 446      (check-bounds buffer start end)
 447      (with-pointer-to-vector-data (buff-sap (coerce buffer 'ub8-sarray))
 448        (%%send-to fd ss got-peer buff-sap start (- end start) flags)))
 449     (foreign-pointer
 450      (check-type start unsigned-byte)
 451      (check-type end   unsigned-byte)
 452      (%%send-to fd ss got-peer buffer start (- end start) flags))))
 453
 454 (defmethod send-to ((socket internet-socket) buffer &rest args
 455                     &key (start 0) end remote-host (remote-port 0) flags (ipv6 *ipv6*))
 456   (let ((*ipv6* ipv6))
 457     (with-sockaddr-storage (ss)
 458       (when remote-host
 459         (sockaddr->sockaddr-storage ss (ensure-hostname remote-host)
 460                                     (ensure-numerical-service remote-port)))
 461       (%send-to (fd-of socket) ss (if remote-host t) buffer start end
 462                 (or flags (compute-flags *sendto-flags* args))))))
 463
 464 (defmethod send-to ((socket local-socket) buffer &rest args
 465                     &key (start 0) end remote-filename flags)
 466   (with-sockaddr-storage (ss)
 467     (when remote-filename
 468       (sockaddr->sockaddr-storage ss (ensure-address remote-filename :family :local) 0))
 469     (%send-to (fd-of socket) ss (if remote-filename t) buffer start end
 470               (or flags (compute-flags *sendto-flags* args)))))
 471
 472 (define-compiler-macro send-to (&whole form &environment env socket buffer &rest args
 473                                 &key (start 0) end (remote-host nil host-p) (remote-port 0 port-p)
 474                                 (remote-filename nil file-p) flags (ipv6 '*ipv6* ipv6-p) &allow-other-keys)
 475   (let ((flags-val (compute-flags *sendto-flags* args env)))
 476     (cond
 477       ((and (not flags) flags-val)
 478        (append
 479         `(send-to ,socket ,buffer :start ,start :end ,end :flags ,flags-val)
 480         (when host-p `(:remote-host ,remote-host))
 481         (when port-p `(:remote-port ,remote-port))
 482         (when ipv6-p `(:ipv6 ,ipv6))
 483         (when file-p `(:remote-filename ,remote-filename))))
 484       (t
 485        form))))
 486 \f
 487
 488 ;;;-------------------------------------------------------------------------
 489 ;;; RECVFROM
 490 ;;;-------------------------------------------------------------------------
 491
 492 (defvar *recvfrom-flags* ())
 493
 494 (define-socket-flags *recvfrom-flags*
 495   (:out-of-band msg-oob)
 496   (:peek        msg-peek)
 497   (:wait-all    msg-waitall  (:not :windows))
 498   (:dont-wait   msg-dontwait (:not :windows)))
 499
 500 (defun %%receive-from (fd ss size buffer start length flags)
 501   (with-pointer-to-vector-data (buff-sap buffer)
 502     (incf-pointer buff-sap start)
 503     (loop
 504        (restart-case
 505            (return* (%recvfrom fd buff-sap length flags ss size))
 506          (ignore-syscall-error ()
 507            :report "Ignore this socket condition"
 508            :test isys:syscall-error-p
 509            (return* 0))
 510          (retry-syscall (&optional (timeout 15.0d0))
 511            :report "Try to receive data again"
 512            :test isys:syscall-error-p
 513            (when (plusp timeout)
 514              (iomux:wait-until-fd-ready fd :input timeout nil)))))))
 515
 516 (defun %receive-from (fd ss size buffer start end flags)
 517   (check-bounds buffer start end)
 518   (flet ((%do-recvfrom (buff start length)
 519            (%%receive-from fd ss size buff start length flags)))
 520     (let (nbytes)
 521       (etypecase buffer
 522         (ub8-sarray
 523          (setf nbytes (%do-recvfrom buffer start (- end start))))
 524         ((or ub8-vector (vector t))
 525          (let ((tmpbuff (make-array (- end start) :element-type 'ub8)))
 526            (setf nbytes (%do-recvfrom tmpbuff 0 (- end start)))
 527            (replace buffer tmpbuff :start1 start :end1 end :start2 0 :end2 nbytes))))
 528       (values nbytes))))
 529
 530 (defmethod receive-from :around ((socket socket) &rest args
 531                                  &key buffer size (start 0) end flags &allow-other-keys)
 532   (let ((flags-val (or flags (compute-flags *recvfrom-flags* args))))
 533     (cond
 534       (buffer
 535        (call-next-method socket :buffer buffer :start start :end end :flags flags-val))
 536       (t
 537        (check-type size unsigned-byte "a non-negative integer")
 538        (call-next-method socket :buffer (make-array size :element-type 'ub8)
 539                          :start 0 :end size :flags flags-val)))))
 540
 541 (defmethod receive-from ((socket stream-socket) &key buffer start end flags)
 542   (with-sockaddr-storage-and-socklen (ss size)
 543     (let ((nbytes (%receive-from (fd-of socket) ss size buffer start end flags)))
 544       (values buffer nbytes))))
 545
 546 (defmethod receive-from ((socket datagram-socket) &key buffer start end flags)
 547   (with-sockaddr-storage-and-socklen (ss size)
 548     (let ((nbytes (%receive-from (fd-of socket) ss size buffer start end flags)))
 549       (multiple-value-call #'values buffer nbytes
 550                            (sockaddr-storage->sockaddr ss)))))
 551
 552 (define-compiler-macro receive-from (&whole form &environment env socket &rest args
 553                                      &key buffer size (start 0) end flags &allow-other-keys)
 554   (let ((flags-val (compute-flags *recvfrom-flags* args env)))
 555     (cond
 556       ((and (not flags) flags-val)
 557        `(receive-from ,socket :buffer ,buffer :start ,start :end ,end
 558                       :size ,size :flags ,flags-val))
 559       (t
 560        form))))