configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ([2.59])
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.1],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8
   9 AM_INIT_AUTOMAKE([foreign no-dependencies 1.8])
  10 AM_MAINTAINER_MODE
  11
  12 dnl Checks for programs.
  13 AC_PROG_CC
  14 AM_PROG_CC_C_O
  15 AC_PROG_CPP
  16
  17 AC_PREFIX_DEFAULT(/usr/heimdal)
  18
  19 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  20 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  21
  22 AC_CANONICAL_HOST
  23 CANONICAL_HOST=$host
  24 AC_SUBST(CANONICAL_HOST)
  25
  26 dnl Hints for autobuild
  27 AB_INIT
  28
  29 rk_SYS_LARGEFILE
  30
  31 dnl
  32 dnl this is needed to run the configure tests against glibc
  33 dnl
  34 AC_DEFINE([_GNU_SOURCE], 1,
  35         [Define to enable extensions on glibc-based systems such as Linux.])
  36
  37 AC_OBJEXT
  38 AC_EXEEXT
  39
  40 dnl AC_KRB_PROG_YACC
  41 AC_PROG_YACC
  42 AM_PROG_LEX
  43 dnl AC_PROG_RANLIB
  44 AC_PROG_AWK
  45 AC_KRB_PROG_LN_S
  46
  47 AC_MIPS_ABI
  48 CC="$CC $abi"
  49 libdir="$libdir$abilibdirext"
  50
  51 AC_C___ATTRIBUTE__
  52
  53 AC_PROG_LIBTOOL
  54
  55 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  56 rk_VERSIONSCRIPT
  57
  58 rk_TEST_PACKAGE(openldap,
  59 [#include <lber.h>
  60 #include <ldap.h>],
  61 [-lldap -llber],,,OPENLDAP)
  62
  63 AC_ARG_ENABLE(hdb-openldap-module,
  64         AS_HELP_STRING([--enable-hdb-openldap-module],
  65                 [if you want support to build openldap hdb as shared object]))
  66 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
  67     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
  68 fi
  69 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
  70
  71 AC_ARG_ENABLE(pk-init,
  72         AS_HELP_STRING([--disable-pk-init],
  73                 [if you want disable to PK-INIT support]))
  74 if test "$enable_pk_init" != no ;then
  75         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
  76 fi
  77 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
  78
  79
  80 dnl path where the hdb directory is stored
  81 AC_ARG_WITH([hdbdir],
  82         [AC_HELP_STRING([--with-hdbdir],
  83                 [Default location for KDC database @<:@default=/var/heimdal@:>@])],
  84         [],
  85         [with_hdbdir=/var/heimdal])
  86 DIR_hdbdir="$with_hdbdir"
  87 AC_SUBST([DIR_hdbdir])
  88
  89
  90 dnl no kerberos4 any more
  91 with_krb4=no
  92 AC_SUBST(INCLUDE_krb4)
  93 AC_SUBST(LIB_krb4)
  94 AM_CONDITIONAL(KRB4, false)
  95
  96 AM_CONDITIONAL(KRB5, true)
  97 AM_CONDITIONAL(do_roken_rename, true)
  98
  99 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 100 AC_SUBST(LIB_kdb)dnl
 101
 102 KRB_CRYPTO
 103
 104 KRB_PTHREADS
 105
 106 AC_ARG_ENABLE(dce,
 107         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 108 if test "$enable_dce" = yes; then
 109     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 110 fi
 111 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 112
 113 ## XXX quite horrible:
 114 if test -f /etc/ibmcxx.cfg; then
 115         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 116         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 117         dpagaix_ldflags=
 118 else
 119         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 120         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 121         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 122 fi
 123 AC_SUBST(dpagaix_cflags)
 124 AC_SUBST(dpagaix_ldadd)
 125 AC_SUBST(dpagaix_ldflags)
 126
 127 AC_ARG_ENABLE([afs-support],
 128         AC_HELP_STRING([--disable-afs-support],
 129                 [if you don't want support for AFS]))
 130 if test "$enable_afs_support" = no; then
 131         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 132 fi
 133
 134 rk_DB
 135
 136 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 137
 138 rk_ROKEN(lib/roken)
 139 LIBADD_roken="$LIB_roken"
 140 AC_SUBST(LIBADD_roken)dnl
 141 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 142
 143 rk_OTP
 144
 145 AC_CHECK_OSFC2
 146
 147 AC_ARG_ENABLE(mmap,
 148         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 149 if test "$enable_mmap" = "no"; then
 150         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 151 fi
 152
 153 AC_ARG_ENABLE(afs-string-to-key,
 154         AS_HELP_STRING([--disable-afs-string-to-key],
 155         [disable use of weak AFS string-to-key functions]),
 156         [], [enable_afs_string_to_key=yes])
 157
 158 if test "$enable_afs_string_to_key" = "yes"; then
 159         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 160 fi
 161
 162
 163 rk_CHECK_MAN
 164
 165 rk_TEST_PACKAGE(readline,
 166 [#include <stdio.h>
 167  #include <readline.h>],-lreadline,,, READLINE)
 168
 169 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 170
 171 KRB_C_BIGENDIAN
 172 AC_C_INLINE
 173
 174 rk_AIX
 175 rk_IRIX
 176 rk_SUNOS
 177
 178 KRB_CHECK_X
 179
 180 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 181
 182 AC_CHECK_XAU
 183
 184 dnl AM_C_PROTOTYPES
 185
 186 dnl Checks for typedefs, structures, and compiler characteristics.
 187 AC_C_CONST
 188 AC_TYPE_OFF_T
 189 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 190 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 191 AC_HAVE_TYPE([long long])
 192 AC_HEADER_TIME
 193 AC_STRUCT_TM
 194
 195 dnl Checks for header files.
 196 AC_HEADER_STDC
 197
 198 AC_CHECK_HEADERS([\
 199         arpa/ftp.h                              \
 200         arpa/telnet.h                           \
 201         bind/bitypes.h                          \
 202         bsdsetjmp.h                             \
 203         curses.h                                \
 204         dlfcn.h                                 \
 205         fnmatch.h                               \
 206         inttypes.h                              \
 207         io.h                                    \
 208         libutil.h                               \
 209         limits.h                                \
 210         maillock.h                              \
 211         netgroup.h                              \
 212         netinet/in6_machtypes.h                 \
 213         netinfo/ni.h                            \
 214         pthread.h                               \
 215         pty.h                                   \
 216         sac.h                                   \
 217         sgtty.h                                 \
 218         siad.h                                  \
 219         signal.h                                \
 220         strings.h                               \
 221         stropts.h                               \
 222         sys/bitypes.h                           \
 223         sys/category.h                          \
 224         sys/file.h                              \
 225         sys/filio.h                             \
 226         sys/ioccom.h                            \
 227         sys/mman.h                              \
 228         sys/param.h                             \
 229         sys/pty.h                               \
 230         sys/ptyio.h                             \
 231         sys/select.h                            \
 232         sys/socket.h                            \
 233         sys/str_tty.h                           \
 234         sys/stream.h                            \
 235         sys/stropts.h                           \
 236         sys/syscall.h                           \
 237         sys/termio.h                            \
 238         sys/timeb.h                             \
 239         sys/times.h                             \
 240         sys/types.h                             \
 241         sys/un.h                                \
 242         termcap.h                               \
 243         termio.h                                \
 244         termios.h                               \
 245         time.h                                  \
 246         tmpdir.h                                \
 247         udb.h                                   \
 248         util.h                                  \
 249         utmp.h                                  \
 250         utmpx.h                                 \
 251 ])
 252
 253 dnl On Solaris 8 there's a compilation warning for term.h because
 254 dnl it doesn't define `bool'.
 255 AC_CHECK_HEADERS(term.h, , , -)
 256
 257 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 258 #if HAVE_SYS_SOCKET_H
 259 #include <sys/socket.h>
 260 #endif])
 261
 262 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 263 #if HAVE_SYS_TTY_H
 264 #include <sys/tty.h>
 265 #endif])
 266
 267 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 268 #if HAVE_TERMIOS_H
 269 #include <termios.h>
 270 #endif
 271 #if HAVE_SYS_STREAM_H
 272 #include <sys/stream.h>
 273 #endif])
 274
 275 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 276 #if HAVE_SYS_TYPES_H
 277 #include <sys/types.h>
 278 #endif
 279 #if HAVE_SYS_PARAM_H
 280 #include <sys/param.h>
 281 #endif])
 282
 283 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 284 #include <security/pam_appl.h>
 285 ])
 286
 287 AC_ARG_ENABLE(netinfo,
 288         AS_HELP_STRING([--enable-netinfo],[enable netinfo for configuration lookup]))
 289
 290 if test "$ac_cv_header_netinfo_ni_h" = yes -a "$enable_netinfo" = yes; then
 291        AC_DEFINE(HAVE_NETINFO, 1,
 292                [Define if you want to use Netinfo instead of krb5.conf.])
 293 fi
 294
 295 dnl export symbols
 296 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB_FUNCTION)
 297 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB_FUNCTION)
 298
 299 dnl Checks for libraries.
 300
 301 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 302 #ifdef HAVE_UTIL_H
 303 #include <util.h>
 304 #endif
 305 ],[0,0,0])
 306 AC_FIND_FUNC_NO_LIBS(logout, util,[
 307 #ifdef HAVE_UTIL_H
 308 #include <util.h>
 309 #endif
 310 ],[0])
 311 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 312 #ifdef HAVE_UTIL_H
 313 #include <util.h>
 314 #endif
 315 ],[0,0,0,0,0])
 316
 317 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 318 #ifdef HAVE_TERMCAP_H
 319 #include <termcap.h>
 320 #endif
 321 #ifdef HAVE_CURSES_H
 322 #include <curses.h>
 323 #endif
 324 ],[0,0])
 325
 326 dnl Checks for library functions.
 327
 328 AC_CHECK_FUNCS([                                \
 329         _getpty                                 \
 330         _scrsize                                \
 331         arc4random                              \
 332         fcntl                                   \
 333         getpeereid                              \
 334         getpeerucred                            \
 335         grantpt                                 \
 336         mktime                                  \
 337         ptsname                                 \
 338         rand                                    \
 339         revoke                                  \
 340         select                                  \
 341         setitimer                               \
 342         setpcred                                \
 343         setpgid                                 \
 344         setproctitle                            \
 345         setregid                                \
 346         setresgid                               \
 347         setresuid                               \
 348         setreuid                                \
 349         setsid                                  \
 350         setutent                                \
 351         sigaction                               \
 352         strstr                                  \
 353         ttyname                                 \
 354         ttyslot                                 \
 355         umask                                   \
 356         unlockpt                                \
 357         vhangup                                 \
 358         yp_get_default_domain                   \
 359 ])
 360
 361 AC_FUNC_MMAP
 362
 363 KRB_CAPABILITIES
 364
 365 AC_CHECK_GETPWNAM_R_POSIX
 366
 367 dnl detect doors on solaris
 368 if test "$enable_pthread_support" != no; then
 369    saved_LIBS="$LIBS"
 370    LIBS="$LIBS $PTHREADS_LIBS"
 371    AC_FIND_FUNC_NO_LIBS(door_create, door)
 372    LIBS="$saved_LIBS"
 373 fi
 374
 375 AC_ARG_ENABLE(kcm,
 376         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 377 ,[enable_kcm=yes])
 378
 379 if test "$enable_kcm" = yes ; then
 380    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 381         enable_kcm=no
 382    fi
 383 fi
 384 if test "$enable_kcm" = yes; then
 385        AC_DEFINE(HAVE_KCM, 1,
 386                [Define if you want to use the Kerberos Credentials Manager.])
 387 fi
 388 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 389
 390
 391
 392 dnl Cray stuff
 393 AC_CHECK_FUNCS(getudbnam setlim)
 394
 395 dnl AC_KRB_FUNC_GETCWD_BROKEN
 396
 397 dnl
 398 dnl Check for fields in struct utmp
 399 dnl
 400
 401 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 402 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 403 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 404 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 405 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 406 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 407 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 408 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 409
 410 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 411         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 412         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 413 #ifdef HAVE_INTTYPES_H
 414 #include <inttypes.h>
 415 #endif
 416 #ifdef HAVE_SYS_TYPES_H
 417 #include <sys/types.h>
 418 #endif
 419 #ifdef HAVE_SYS_BITYPES_H
 420 #include <sys/bitypes.h>
 421 #endif
 422 #ifdef HAVE_BIND_BITYPES_H
 423 #include <bind/bitypes.h>
 424 #endif
 425 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 426 #include <netinet/in6_machtypes.h>
 427 #endif
 428 ])
 429
 430 rk_FRAMEWORK_SECURITY
 431
 432 KRB_READLINE
 433
 434 rk_TELNET
 435
 436 dnl Some operating systems already have com_err and compile_et
 437 CHECK_COMPILE_ET
 438
 439 rk_AUTH_MODULES([sia afskauthlib])
 440
 441 rk_DESTDIRS
 442
 443 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 444
 445
 446 AH_BOTTOM([#ifdef ROKEN_RENAME
 447 #include "roken_rename.h"
 448 #endif])
 449
 450 AC_CONFIG_FILES(Makefile                \
 451         etc/Makefile                    \
 452         include/Makefile                \
 453         include/gssapi/Makefile         \
 454         include/hcrypto/Makefile        \
 455         include/kadm5/Makefile          \
 456         lib/Makefile                    \
 457         lib/45/Makefile                 \
 458         lib/auth/Makefile               \
 459         lib/auth/afskauthlib/Makefile   \
 460         lib/auth/pam/Makefile           \
 461         lib/auth/sia/Makefile           \
 462         lib/asn1/Makefile               \
 463         lib/com_err/Makefile            \
 464         lib/hcrypto/Makefile            \
 465         lib/editline/Makefile           \
 466         lib/hx509/Makefile              \
 467         lib/gssapi/Makefile             \
 468         lib/ntlm/Makefile               \
 469         lib/hdb/Makefile                \
 470         lib/kadm5/Makefile              \
 471         lib/kafs/Makefile               \
 472         lib/kdfs/Makefile               \
 473         lib/krb5/Makefile               \
 474         lib/otp/Makefile                \
 475         lib/roken/Makefile              \
 476         lib/sl/Makefile                 \
 477         lib/vers/Makefile               \
 478         kuser/Makefile                  \
 479         kpasswd/Makefile                \
 480         kadmin/Makefile                 \
 481         admin/Makefile                  \
 482         kcm/Makefile                    \
 483         kdc/Makefile                    \
 484         appl/Makefile                   \
 485         appl/afsutil/Makefile           \
 486         appl/ftp/Makefile               \
 487         appl/ftp/common/Makefile        \
 488         appl/ftp/ftp/Makefile           \
 489         appl/ftp/ftpd/Makefile          \
 490         appl/gssmask/Makefile           \
 491         appl/kx/Makefile                \
 492         appl/login/Makefile             \
 493         appl/otp/Makefile               \
 494         appl/popper/Makefile            \
 495         appl/push/Makefile              \
 496         appl/rsh/Makefile               \
 497         appl/rcp/Makefile               \
 498         appl/su/Makefile                \
 499         appl/xnlock/Makefile            \
 500         appl/telnet/Makefile            \
 501         appl/telnet/libtelnet/Makefile  \
 502         appl/telnet/telnet/Makefile     \
 503         appl/telnet/telnetd/Makefile    \
 504         appl/test/Makefile              \
 505         appl/kf/Makefile                \
 506         appl/dceutils/Makefile          \
 507         tests/Makefile                  \
 508         tests/can/Makefile              \
 509         tests/db/Makefile               \
 510         tests/kdc/Makefile              \
 511         tests/ldap/Makefile             \
 512         tests/gss/Makefile              \
 513         tests/java/Makefile             \
 514         tests/plugin/Makefile           \
 515         packages/Makefile               \
 516         packages/mac/Makefile           \
 517         packages/debian/Makefile        \
 518         doc/Makefile                    \
 519         tools/Makefile                  \
 520 )
 521
 522 AC_OUTPUT
 523
 524 dnl
 525 dnl This is the release version name-number[beta]
 526 dnl
 527
 528 cat > include/newversion.h.in <<EOF
 529 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 530 const char *heimdal_version = "AC_PACKAGE_STRING";
 531 EOF
 532
 533 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 534         echo "include/version.h is unchanged"
 535         rm -f include/newversion.h.in
 536 else
 537         echo "creating include/version.h"
 538         User=${USER-${LOGNAME}}
 539         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 540         Date=`date`
 541         mv -f include/newversion.h.in include/version.h.in
 542         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 543 fi