configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_REVISION($Revision$)
   3 AC_PREREQ(2.62)
   4 test -z "$CFLAGS" && CFLAGS="-g"
   5 AC_INIT([Heimdal],[1.3.2rc1],[heimdal-bugs@h5l.org])
   6 AC_CONFIG_SRCDIR([kuser/kinit.c])
   7 AC_CONFIG_HEADERS(include/config.h)
   8 AC_CONFIG_MACRO_DIR([cf])
   9
  10 AM_INIT_AUTOMAKE([foreign 1.10])
  11 AM_MAINTAINER_MODE
  12
  13 dnl Checks for programs.
  14 AC_PROG_CC
  15 AM_PROG_CC_C_O
  16 AC_PROG_CPP
  17 AC_PROG_LIBTOOL
  18
  19 AC_PREFIX_DEFAULT(/usr/heimdal)
  20
  21 test "$sysconfdir" = '${prefix}/etc' && sysconfdir='/etc'
  22 test "$localstatedir" = '${prefix}/var' && localstatedir='/var/heimdal'
  23
  24 AC_CANONICAL_HOST
  25 CANONICAL_HOST=$host
  26 AC_SUBST(CANONICAL_HOST)
  27
  28 dnl Hints for autobuild
  29 AB_INIT
  30
  31 rk_SYS_LARGEFILE
  32
  33 rk_AIX
  34 rk_IRIX
  35 rk_SUNOS
  36
  37 dnl
  38 dnl this is needed to run the configure tests against glibc
  39 dnl
  40 AC_DEFINE([_GNU_SOURCE], 1,
  41         [Define to enable extensions on glibc-based systems such as Linux.])
  42
  43 AC_OBJEXT
  44 AC_EXEEXT
  45
  46 dnl AC_KRB_PROG_YACC
  47 AC_PROG_YACC
  48 AM_PROG_LEX
  49 dnl AC_PROG_RANLIB
  50 AC_PROG_AWK
  51 AC_KRB_PROG_LN_S
  52
  53 AC_MIPS_ABI
  54 CC="$CC $abi"
  55 libdir="$libdir$abilibdirext"
  56
  57 AC_C___ATTRIBUTE__
  58
  59 LT_PREREQ([2.2])
  60 LT_INIT([shared static win32-dll])
  61
  62 AM_CONDITIONAL(ENABLE_SHARED, test "$enable_shared" = "yes")
  63 rk_VERSIONSCRIPT
  64
  65 dnl
  66 dnl Helper bits for cross compiling
  67 dnl
  68
  69
  70
  71 AM_CONDITIONAL(CROSS_COMPILE, test "${cross_compiling}" = yes)
  72
  73 AC_ARG_WITH(cross-tools,
  74         AS_HELP_STRING([--with-cross-tools=dir], [use cross tools in dir]),
  75         [if test "$withval" = "yes"; then
  76                 AC_MSG_ERROR([Need path to cross tools])
  77         fi
  78         with_cross_tools="${with_cross_tools}/"
  79         ])
  80
  81 if test "${cross_compiling}" != yes ; then
  82
  83    ASN1_COMPILE="\$(top_builddir)/lib/asn1/asn1_compile\$(EXEEXT)"
  84    SLC="\$(top_builddir)/lib/sl/slc"
  85
  86    ASN1_COMPILE_DEP="\$(ASN1_COMPILE)"
  87    SLC_DEP="\$(SLC)"
  88 else
  89    ASN1_COMPILE="${with_cross_tools}asn1_compile"
  90    SLC="${with_cross_tools}slc"
  91
  92    ASN1_COMPILE_DEP=
  93    SLC_DEP=
  94 fi
  95
  96 AC_SUBST([ASN1_COMPILE])
  97 AC_SUBST([ASN1_COMPILE_DEP])
  98 AC_SUBST([SLC])
  99 AC_SUBST([SLC_DEP])
 100
 101
 102 dnl ---
 103
 104 AC_DEFINE(HEIM_WEAK_CRYPTO, 1, [Define if you want support for weak crypto])
 105
 106 rk_TEST_PACKAGE(openldap,
 107 [#include <lber.h>
 108 #include <ldap.h>],
 109 [-lldap -llber],,,OPENLDAP)
 110
 111 AC_ARG_ENABLE(hdb-openldap-module,
 112         AS_HELP_STRING([--enable-hdb-openldap-module],
 113                 [if you want support to build openldap hdb as shared object]))
 114 if test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes; then
 115     AC_DEFINE(OPENLDAP_MODULE, 1, [Define if you want support for hdb ldap module])
 116 fi
 117 AM_CONDITIONAL(OPENLDAP_MODULE, test "$enable_hdb_openldap_module" = yes -a "$with_openldap" = yes)
 118
 119 dnl
 120 dnl Optional modules, pk-init, digest, kx509
 121 dnl
 122
 123 AC_ARG_ENABLE(pk-init,
 124         AS_HELP_STRING([--disable-pk-init],
 125                 [if you want disable to PK-INIT support]))
 126 if test "$enable_pk_init" != no ;then
 127         AC_DEFINE([PKINIT], 1, [Define to enable PKINIT.])
 128 fi
 129 AM_CONDITIONAL(PKINIT, test "$enable_pk_init" != no)
 130
 131 AC_ARG_ENABLE(digest,
 132         AS_HELP_STRING([--disable-digest],
 133                 [if you want disable to DIGEST support]))
 134 if test "$enable_digest" != no ;then
 135         AC_DEFINE([DIGEST], 1, [Define to enable DIGEST.])
 136 fi
 137
 138 AC_ARG_ENABLE(kx509,
 139         AS_HELP_STRING([--disable-kx509],
 140                 [if you want disable to kx509 support]))
 141 if test "$enable_kx509" != no ;then
 142         AC_DEFINE([KX509], 1, [Define to enable kx509.])
 143 fi
 144
 145 AC_ARG_ENABLE(krb4,
 146         AS_HELP_STRING([--disable-krb4],
 147                 [if you want disable to krb4 support]))
 148 if test "$enable_krb4" != no ;then
 149         AC_DEFINE([KRB4], 1, [Define to enable Kerberos 4.])
 150 fi
 151
 152
 153 dnl Check for sqlite
 154 rk_TEST_PACKAGE(sqlite3,
 155 [#include <sqlite3.h>
 156 #ifndef SQLITE_OPEN_CREATE
 157 #error "old version"
 158 #endif],
 159 [-lsqlite3],,,SQLITE3)
 160
 161 if test "X$with_sqlite3" != Xyes ; then
 162    INCLUDE_sqlite3="-I\$(top_srcdir)/lib/sqlite"
 163    LIB_sqlite3="\$(top_builddir)/lib/sqlite/libheimsqlite.la"
 164 fi
 165 AM_CONDITIONAL(SQLITE3,  test "X$with_sqlite3" = Xyes)
 166
 167 dnl check for libintl
 168 rk_TEST_PACKAGE(libintl,
 169 [#include <libintl.h>],
 170 [-lintl],,,LIBINTL)
 171
 172 dnl path where the hdb directory is stored
 173 AC_ARG_WITH([hdbdir],
 174         [AS_HELP_STRING([--with-hdbdir],[Default location for KDC database @<:@default=/var/heimdal@:>@])],
 175         [],
 176         [with_hdbdir=/var/heimdal])
 177 DIR_hdbdir="$with_hdbdir"
 178 AC_SUBST([DIR_hdbdir])
 179
 180
 181 dnl no kerberos4 any more
 182 with_krb4=no
 183 AC_SUBST(INCLUDE_krb4)
 184 AC_SUBST(LIB_krb4)
 185 AM_CONDITIONAL(KRB4, false)
 186
 187 AM_CONDITIONAL(KRB5, true)
 188 AM_CONDITIONAL(do_roken_rename, true)
 189
 190 AC_DEFINE(KRB5, 1, [Enable Kerberos 5 support in applications.])dnl
 191 AC_SUBST(LIB_kdb)dnl
 192
 193 KRB_CRYPTO
 194
 195 KRB_PTHREADS
 196
 197 AC_ARG_ENABLE(dce,
 198         AS_HELP_STRING([--enable-dce],[if you want support for DCE/DFS PAG's]))
 199 if test "$enable_dce" = yes; then
 200     AC_DEFINE(DCE, 1, [Define if you want support for DCE/DFS PAG's.])
 201 fi
 202 AM_CONDITIONAL(DCE, test "$enable_dce" = yes)
 203
 204 ## XXX quite horrible:
 205 if test -f /etc/ibmcxx.cfg; then
 206         dpagaix_ldadd=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/libraries/{;s/^[[^=]]*=\(.*\)/\1/;s/,/ /gp;}'`
 207         dpagaix_cflags=`sed -n '/^xlc_r4/,/^$/p' /etc/ibmcxx.cfg | sed -n -e '/options/{;s/^[[^=]]*=\(.*\)/\1/;s/-q[^,]*//;s/,/ /gp;}'`
 208         dpagaix_ldflags=
 209 else
 210         dpagaix_cflags="-D_THREAD_SAFE -D_AIX_PTHREADS_D7 -D_AIX32_THREADS=1 -D_AES_SOURCE -D_AIX41 -I/usr/include/dce"
 211         dpagaix_ldadd="-L/usr/lib/threads -ldcelibc_r -ldcepthreads -lpthreads_compat lpthreads -lc_r"
 212         dpagaix_ldflags="-Wl,-bI:dfspag.exp"
 213 fi
 214 AC_SUBST(dpagaix_cflags)
 215 AC_SUBST(dpagaix_ldadd)
 216 AC_SUBST(dpagaix_ldflags)
 217
 218 AC_ARG_ENABLE([afs-support],
 219         AS_HELP_STRING([--disable-afs-support],[if you don't want support for AFS]))
 220 if test "$enable_afs_support" = no; then
 221         AC_DEFINE(NO_AFS, 1, [Define if you don't wan't support for AFS.])
 222 fi
 223
 224 rk_DB
 225
 226 dnl AC_ROKEN(10,[/usr/heimdal /usr/athena],[lib/roken],[$(top_builddir)/lib/roken/libroken.la],[-I$(top_builddir)/lib/roken -I$(top_srcdir)/lib/roken])
 227
 228 rk_ROKEN(lib/roken)
 229 LIBADD_roken="$LIB_roken"
 230 AC_SUBST(LIBADD_roken)dnl
 231 LIB_roken="\$(top_builddir)/lib/vers/libvers.la $LIB_roken"
 232
 233 rk_OTP
 234
 235 AC_CHECK_OSFC2
 236
 237 AC_ARG_ENABLE(mmap,
 238         AS_HELP_STRING([--disable-mmap],[disable use of mmap]))
 239 if test "$enable_mmap" = "no"; then
 240         AC_DEFINE(NO_MMAP, 1, [Define if you don't want to use mmap.])
 241 fi
 242
 243 AC_ARG_ENABLE(afs-string-to-key,
 244         AS_HELP_STRING([--disable-afs-string-to-key],
 245         [disable use of weak AFS string-to-key functions]),
 246         [], [enable_afs_string_to_key=yes])
 247
 248 if test "$enable_afs_string_to_key" = "yes"; then
 249         AC_DEFINE(ENABLE_AFS_STRING_TO_KEY, 1, [Define if want to use the weak AFS string to key functions.])
 250 fi
 251
 252
 253 rk_CHECK_MAN
 254
 255 rk_TEST_PACKAGE(readline,
 256 [#include <stdio.h>
 257  #include <readline.h>],-lreadline,,, READLINE)
 258
 259 rk_TEST_PACKAGE(hesiod,[#include <hesiod.h>],-lhesiod,,, HESIOD)
 260
 261 KRB_C_BIGENDIAN
 262 AC_C_INLINE
 263
 264 KRB_CHECK_X
 265
 266 AM_CONDITIONAL(HAVE_X, test "$no_x" != yes)
 267
 268 AC_CHECK_XAU
 269
 270 dnl AM_C_PROTOTYPES
 271
 272 dnl Checks for typedefs, structures, and compiler characteristics.
 273 AC_C_CONST
 274 AC_TYPE_OFF_T
 275 AC_CHECK_TYPE_EXTRA(mode_t, unsigned short, [])
 276 AC_CHECK_TYPE_EXTRA(sig_atomic_t, int, [#include <signal.h>])
 277 AC_HAVE_TYPE([long long])
 278 AC_HEADER_TIME
 279 AC_STRUCT_TM
 280
 281 dnl Checks for header files.
 282 AC_HEADER_STDC
 283
 284 AC_CHECK_HEADERS([\
 285         arpa/ftp.h                              \
 286         arpa/telnet.h                           \
 287         bind/bitypes.h                          \
 288         bsdsetjmp.h                             \
 289         curses.h                                \
 290         dlfcn.h                                 \
 291         fnmatch.h                               \
 292         inttypes.h                              \
 293         io.h                                    \
 294         libutil.h                               \
 295         limits.h                                \
 296         maillock.h                              \
 297         netgroup.h                              \
 298         netinet/in6_machtypes.h                 \
 299         pthread.h                               \
 300         pty.h                                   \
 301         sac.h                                   \
 302         sgtty.h                                 \
 303         siad.h                                  \
 304         signal.h                                \
 305         strings.h                               \
 306         stropts.h                               \
 307         sys/bitypes.h                           \
 308         sys/category.h                          \
 309         sys/file.h                              \
 310         sys/filio.h                             \
 311         sys/ioccom.h                            \
 312         sys/mman.h                              \
 313         sys/param.h                             \
 314         sys/pty.h                               \
 315         sys/ptyio.h                             \
 316         sys/select.h                            \
 317         sys/socket.h                            \
 318         sys/str_tty.h                           \
 319         sys/stream.h                            \
 320         sys/stropts.h                           \
 321         sys/syscall.h                           \
 322         sys/termio.h                            \
 323         sys/timeb.h                             \
 324         sys/times.h                             \
 325         sys/types.h                             \
 326         sys/un.h                                \
 327         locale.h                                \
 328         termcap.h                               \
 329         termio.h                                \
 330         termios.h                               \
 331         time.h                                  \
 332         tmpdir.h                                \
 333         udb.h                                   \
 334         util.h                                  \
 335         utmp.h                                  \
 336         utmpx.h                                 \
 337 ])
 338
 339 dnl On Solaris 8 there's a compilation warning for term.h because
 340 dnl it doesn't define `bool'.
 341 AC_CHECK_HEADERS(term.h, , , -)
 342
 343 dnl aix have asl.h (A/IX screen library) that we don't want
 344 AC_CHECK_HEADERS(asl.h, , , [
 345 #include <asl.h>
 346 #ifndef ASL_STRING_EMERG
 347 #error ASL_STRING_EMERG missing
 348 #endif])
 349
 350 AC_CHECK_HEADERS(net/if.h, , , [AC_INCLUDES_DEFAULT
 351 #if HAVE_SYS_SOCKET_H
 352 #include <sys/socket.h>
 353 #endif])
 354
 355 AC_CHECK_HEADERS(sys/ptyvar.h, , , [AC_INCLUDES_DEFAULT
 356 #if HAVE_SYS_TTY_H
 357 #include <sys/tty.h>
 358 #endif])
 359
 360 AC_CHECK_HEADERS(sys/strtty.h, , , [AC_INCLUDES_DEFAULT
 361 #if HAVE_TERMIOS_H
 362 #include <termios.h>
 363 #endif
 364 #if HAVE_SYS_STREAM_H
 365 #include <sys/stream.h>
 366 #endif])
 367
 368 AC_CHECK_HEADERS(sys/ucred.h, , , [AC_INCLUDES_DEFAULT
 369 #if HAVE_SYS_TYPES_H
 370 #include <sys/types.h>
 371 #endif
 372 #if HAVE_SYS_PARAM_H
 373 #include <sys/param.h>
 374 #endif])
 375
 376 AC_CHECK_HEADERS(security/pam_modules.h, , , [AC_INCLUDES_DEFAULT
 377 #include <security/pam_appl.h>
 378 ])
 379
 380 dnl export symbols
 381 rk_WIN32_EXPORT(BUILD_KRB5_LIB, KRB5_LIB)
 382 rk_WIN32_EXPORT(BUILD_ROKEN_LIB, ROKEN_LIB)
 383 rk_WIN32_EXPORT(BUILD_GSSAPI_LIB, GSSAPI_LIB)
 384
 385 dnl Checks for libraries.
 386
 387 AC_FIND_FUNC_NO_LIBS(logwtmp, util,[
 388 #ifdef HAVE_UTIL_H
 389 #include <util.h>
 390 #endif
 391 ],[0,0,0])
 392 AC_FIND_FUNC_NO_LIBS(logout, util,[
 393 #ifdef HAVE_UTIL_H
 394 #include <util.h>
 395 #endif
 396 ],[0])
 397 AC_FIND_FUNC_NO_LIBS(openpty, util,[
 398 #ifdef HAVE_UTIL_H
 399 #include <util.h>
 400 #endif
 401 ],[0,0,0,0,0])
 402
 403 AC_FIND_FUNC_NO_LIBS(tgetent, termcap ncurses curses,[
 404 #ifdef HAVE_TERMCAP_H
 405 #include <termcap.h>
 406 #endif
 407 #ifdef HAVE_CURSES_H
 408 #include <curses.h>
 409 #endif
 410 ],[0,0])
 411
 412 dnl Checks for library functions.
 413
 414 AC_CHECK_FUNCS([                                \
 415         _getpty                                 \
 416         _scrsize                                \
 417         arc4random                              \
 418         fcntl                                   \
 419         getpeereid                              \
 420         getpeerucred                            \
 421         grantpt                                 \
 422         mktime                                  \
 423         ptsname                                 \
 424         rand                                    \
 425         revoke                                  \
 426         select                                  \
 427         setitimer                               \
 428         setpcred                                \
 429         setpgid                                 \
 430         setproctitle                            \
 431         setregid                                \
 432         setresgid                               \
 433         setresuid                               \
 434         setreuid                                \
 435         setsid                                  \
 436         setutent                                \
 437         sigaction                               \
 438         strstr                                  \
 439         ttyname                                 \
 440         ttyslot                                 \
 441         umask                                   \
 442         unlockpt                                \
 443         vhangup                                 \
 444         yp_get_default_domain                   \
 445 ])
 446
 447 AC_FUNC_MMAP
 448
 449 KRB_CAPABILITIES
 450
 451 AC_CHECK_GETPWNAM_R_POSIX
 452
 453 dnl detect doors on solaris
 454 if test "$enable_pthread_support" != no; then
 455    saved_LIBS="$LIBS"
 456    LIBS="$LIBS $PTHREADS_LIBS"
 457    AC_FIND_FUNC_NO_LIBS(door_create, door)
 458    LIBS="$saved_LIBS"
 459 fi
 460
 461 AC_ARG_ENABLE(kcm,
 462         AS_HELP_STRING([--enable-kcm],[enable Kerberos Credentials Manager]),
 463 ,[enable_kcm=yes])
 464
 465 if test "$enable_kcm" = yes ; then
 466    if test  "$ac_cv_header_sys_un_h" != yes -a "$ac_cv_funclib_door_create" != yes ; then
 467         enable_kcm=no
 468    fi
 469 fi
 470 if test "$enable_kcm" = yes; then
 471        AC_DEFINE(HAVE_KCM, 1,
 472                [Define if you want to use the Kerberos Credentials Manager.])
 473 fi
 474 AM_CONDITIONAL(KCM, test "$enable_kcm" = yes)
 475
 476
 477
 478 dnl Cray stuff
 479 AC_CHECK_FUNCS(getudbnam setlim)
 480
 481 dnl AC_KRB_FUNC_GETCWD_BROKEN
 482
 483 dnl
 484 dnl Check for fields in struct utmp
 485 dnl
 486
 487 AC_HAVE_STRUCT_FIELD(struct utmp, ut_addr, [#include <utmp.h>])
 488 AC_HAVE_STRUCT_FIELD(struct utmp, ut_host, [#include <utmp.h>])
 489 AC_HAVE_STRUCT_FIELD(struct utmp, ut_id, [#include <utmp.h>])
 490 AC_HAVE_STRUCT_FIELD(struct utmp, ut_pid, [#include <utmp.h>])
 491 AC_HAVE_STRUCT_FIELD(struct utmp, ut_type, [#include <utmp.h>])
 492 AC_HAVE_STRUCT_FIELD(struct utmp, ut_user, [#include <utmp.h>])
 493 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_exit, [#include <utmpx.h>])
 494 AC_HAVE_STRUCT_FIELD(struct utmpx, ut_syslen, [#include <utmpx.h>])
 495
 496 AC_CHECK_TYPES([int8_t, int16_t, int32_t, int64_t,
 497         u_int8_t, u_int16_t, u_int32_t, u_int64_t,
 498         uint8_t, uint16_t, uint32_t, uint64_t],,,[
 499 #ifdef HAVE_INTTYPES_H
 500 #include <inttypes.h>
 501 #endif
 502 #ifdef HAVE_SYS_TYPES_H
 503 #include <sys/types.h>
 504 #endif
 505 #ifdef HAVE_SYS_BITYPES_H
 506 #include <sys/bitypes.h>
 507 #endif
 508 #ifdef HAVE_BIND_BITYPES_H
 509 #include <bind/bitypes.h>
 510 #endif
 511 #ifdef HAVE_NETINET_IN6_MACHTYPES_H
 512 #include <netinet/in6_machtypes.h>
 513 #endif
 514 ])
 515
 516 rk_FRAMEWORK_SECURITY
 517
 518 KRB_READLINE
 519
 520 rk_TELNET
 521
 522 dnl Some operating systems already have com_err and compile_et
 523 CHECK_COMPILE_ET
 524
 525 rk_AUTH_MODULES([sia afskauthlib])
 526
 527 rk_DESTDIRS
 528
 529 rk_WFLAGS([-Wall -Wmissing-prototypes -Wpointer-arith -Wbad-function-cast -Wmissing-declarations -Wnested-externs])
 530
 531
 532 AH_BOTTOM([#ifdef ROKEN_RENAME
 533 #include "roken_rename.h"
 534 #endif])
 535
 536 AC_CONFIG_FILES(Makefile                \
 537         etc/Makefile                    \
 538         include/Makefile                \
 539         include/gssapi/Makefile         \
 540         include/hcrypto/Makefile        \
 541         include/kadm5/Makefile          \
 542         lib/Makefile                    \
 543         lib/auth/Makefile               \
 544         lib/auth/afskauthlib/Makefile   \
 545         lib/auth/pam/Makefile           \
 546         lib/auth/sia/Makefile           \
 547         lib/asn1/Makefile               \
 548         lib/com_err/Makefile            \
 549         lib/hcrypto/Makefile            \
 550         lib/editline/Makefile           \
 551         lib/hx509/Makefile              \
 552         lib/gssapi/Makefile             \
 553         lib/ntlm/Makefile               \
 554         lib/hdb/Makefile                \
 555         lib/kadm5/Makefile              \
 556         lib/kafs/Makefile               \
 557         lib/kdfs/Makefile               \
 558         lib/krb5/Makefile               \
 559         lib/otp/Makefile                \
 560         lib/roken/Makefile              \
 561         lib/sl/Makefile                 \
 562         lib/sqlite/Makefile             \
 563         lib/vers/Makefile               \
 564         lib/wind/Makefile               \
 565         po/Makefile                     \
 566         kuser/Makefile                  \
 567         kpasswd/Makefile                \
 568         kadmin/Makefile                 \
 569         admin/Makefile                  \
 570         kcm/Makefile                    \
 571         kdc/Makefile                    \
 572         appl/Makefile                   \
 573         appl/afsutil/Makefile           \
 574         appl/ftp/Makefile               \
 575         appl/ftp/common/Makefile        \
 576         appl/ftp/ftp/Makefile           \
 577         appl/ftp/ftpd/Makefile          \
 578         appl/gssmask/Makefile           \
 579         appl/kx/Makefile                \
 580         appl/login/Makefile             \
 581         appl/otp/Makefile               \
 582         appl/popper/Makefile            \
 583         appl/push/Makefile              \
 584         appl/rsh/Makefile               \
 585         appl/rcp/Makefile               \
 586         appl/su/Makefile                \
 587         appl/xnlock/Makefile            \
 588         appl/telnet/Makefile            \
 589         appl/telnet/libtelnet/Makefile  \
 590         appl/telnet/telnet/Makefile     \
 591         appl/telnet/telnetd/Makefile    \
 592         appl/test/Makefile              \
 593         appl/kf/Makefile                \
 594         appl/dceutils/Makefile          \
 595         tests/Makefile                  \
 596         tests/bin/Makefile              \
 597         tests/can/Makefile              \
 598         tests/db/Makefile               \
 599         tests/kdc/Makefile              \
 600         tests/ldap/Makefile             \
 601         tests/gss/Makefile              \
 602         tests/java/Makefile             \
 603         tests/plugin/Makefile           \
 604         packages/Makefile               \
 605         packages/mac/Makefile           \
 606         doc/Makefile                    \
 607         tools/Makefile                  \
 608 )
 609
 610 AC_OUTPUT
 611
 612 dnl
 613 dnl This is the release version name-number[beta]
 614 dnl
 615
 616 cat > include/newversion.h.in <<EOF
 617 const char *heimdal_long_version = "@([#])\$Version: $PACKAGE_STRING by @USER@ on @HOST@ ($host) @DATE@ \$";
 618 const char *heimdal_version = "AC_PACKAGE_STRING";
 619 EOF
 620
 621 if test -f include/version.h && cmp -s include/newversion.h.in include/version.h.in; then
 622         echo "include/version.h is unchanged"
 623         rm -f include/newversion.h.in
 624 else
 625         echo "creating include/version.h"
 626         User=${USER-${LOGNAME}}
 627         Host=`(hostname || uname -n || echo unknown) 2>/dev/null | sed 1q`
 628         Date=`date`
 629         mv -f include/newversion.h.in include/version.h.in
 630         sed -e "s/@USER@/$User/" -e "s/@HOST@/$Host/" -e "s/@DATE@/$Date/" include/version.h.in > include/version.h
 631 fi