| blob | a2f80c8858e83f236213714d5f8fe8b84cdfceb3 |
1 .file "tancot.s"
4 // Copyright (c) 2000 - 2003, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
39 //
40 // History
41 //==============================================================
42 // 02/02/00 Initial version
43 // 04/04/00 Unwind support added
44 // 12/27/00 Improved speed
45 // 02/21/01 Updated to call tanl
46 // 05/30/02 Added cot
47 // 02/10/03 Reordered header: .section, .global, .proc, .align
48 //
49 // API
50 //==============================================================
51 // double tan(double x);
52 // double cot(double x);
53 //
54 // Overview of operation
55 //==============================================================
56 // If the input value in radians is |x| >= 1.xxxxx 2^10 call the
57 // older slower version.
58 //
59 // The new algorithm is used when |x| <= 1.xxxxx 2^9.
60 //
61 // Represent the input X as Nfloat * pi/2 + r
62 // where r can be negative and |r| <= pi/4
63 //
64 // tan_W = x * 2/pi
65 // Nfloat = round_int(tan_W)
66 //
67 // tan_r = x - Nfloat * (pi/2)_hi
68 // a) tan_r = tan_r - Nfloat * (pi/2)_lo (for tan)
69 // b) tan_r = Nfloat * (pi/2)_lo - tan_r (for cot)
70 //
71 // We have two paths: p8, when Nfloat is even and p9. when Nfloat is odd.
72 // a) for tan: p8: tan(X) = tan(r)
73 // p9: tan(X) = -cot(r)
74 // b) for cot: p9: cot(X) = cot(r)
75 // p8: cot(X) = -tan(r)
76 //
77 // Each is evaluated as a series. The p9 path requires 1/r.
78 //
79 // The coefficients used in the series are stored in a table as
80 // are the pi constants.
81 //
82 // Registers used
83 //==============================================================
84 //
85 // predicate registers used:
86 // p6-12
87 //
88 // floating-point registers used:
89 // f10-15, f32-106
90 // f8, input
91 //
92 // general registers used
93 // r14-26, r32-39
94 //
95 // Assembly macros
96 //==============================================================
97 TAN_INV_PI_BY_2_2TO64 = f10
98 TAN_RSHF_2TO64 = f11
99 TAN_2TOM64 = f12
100 TAN_RSHF = f13
101 TAN_W_2TO64_RSH = f14
102 TAN_NFLOAT = f15
104 tan_Inv_Pi_by_2 = f32
105 tan_Pi_by_2_hi = f33
106 tan_Pi_by_2_lo = f34
109 tan_P0 = f35
110 tan_P1 = f36
111 tan_P2 = f37
112 tan_P3 = f38
113 tan_P4 = f39
114 tan_P5 = f40
115 tan_P6 = f41
116 tan_P7 = f42
117 tan_P8 = f43
118 tan_P9 = f44
119 tan_P10 = f45
120 tan_P11 = f46
121 tan_P12 = f47
122 tan_P13 = f48
123 tan_P14 = f49
124 tan_P15 = f50
126 tan_Q0 = f51
127 tan_Q1 = f52
128 tan_Q2 = f53
129 tan_Q3 = f54
130 tan_Q4 = f55
131 tan_Q5 = f56
132 tan_Q6 = f57
133 tan_Q7 = f58
134 tan_Q8 = f59
135 tan_Q9 = f60
136 tan_Q10 = f61
138 tan_r = f62
139 tan_rsq = f63
140 tan_rcube = f64
142 tan_v18 = f65
143 tan_v16 = f66
144 tan_v17 = f67
145 tan_v12 = f68
146 tan_v13 = f69
147 tan_v7 = f70
148 tan_v8 = f71
149 tan_v4 = f72
150 tan_v5 = f73
151 tan_v15 = f74
152 tan_v11 = f75
153 tan_v14 = f76
154 tan_v3 = f77
155 tan_v6 = f78
156 tan_v10 = f79
157 tan_v2 = f80
158 tan_v9 = f81
159 tan_v1 = f82
160 tan_int_Nfloat = f83
161 tan_Nfloat = f84
163 tan_NORM_f8 = f85
164 tan_W = f86
166 tan_y0 = f87
167 tan_d = f88
168 tan_y1 = f89
169 tan_dsq = f90
170 tan_y2 = f91
171 tan_d4 = f92
172 tan_inv_r = f93
174 tan_z1 = f94
175 tan_z2 = f95
176 tan_z3 = f96
177 tan_z4 = f97
178 tan_z5 = f98
179 tan_z6 = f99
180 tan_z7 = f100
181 tan_z8 = f101
182 tan_z9 = f102
183 tan_z10 = f103
184 tan_z11 = f104
185 tan_z12 = f105
187 arg_copy = f106
189 /////////////////////////////////////////////////////////////
191 tan_GR_sig_inv_pi_by_2 = r14
192 tan_GR_rshf_2to64 = r15
193 tan_GR_exp_2tom64 = r16
194 tan_GR_n = r17
195 tan_GR_rshf = r18
196 tan_AD = r19
197 tan_GR_10009 = r20
198 tan_GR_17_ones = r21
199 tan_GR_N_odd_even = r22
200 tan_GR_N = r23
201 tan_signexp = r24
202 tan_exp = r25
203 tan_ADQ = r26
205 GR_SAVE_B0 = r33
206 GR_SAVE_PFS = r34
207 GR_SAVE_GP = r35
208 GR_Parameter_X = r36
209 GR_Parameter_Y = r37
210 GR_Parameter_RESULT = r38
211 GR_Parameter_Tag = r39
214 RODATA
216 .align 16
218 LOCAL_OBJECT_START(double_tan_constants)
219 data8 0xC90FDAA22168C234, 0x00003FFF // pi/2 hi
220 data8 0xBEEA54580DDEA0E1 // P14
221 data8 0x3ED3021ACE749A59 // P15
222 data8 0xBEF312BD91DC8DA1 // P12
223 data8 0x3EFAE9AFC14C5119 // P13
224 data8 0x3F2F342BF411E769 // P8
225 data8 0x3F1A60FC9F3B0227 // P9
226 data8 0x3EFF246E78E5E45B // P10
227 data8 0x3F01D9D2E782875C // P11
228 data8 0x3F8226E34C4499B6 // P4
229 data8 0x3F6D6D3F12C236AC // P5
230 data8 0x3F57DA1146DCFD8B // P6
231 data8 0x3F43576410FE3D75 // P7
232 data8 0x3FD5555555555555 // P0
233 data8 0x3FC11111111111C2 // P1
234 data8 0x3FABA1BA1BA0E850 // P2
235 data8 0x3F9664F4886725A7 // P3
236 LOCAL_OBJECT_END(double_tan_constants)
238 LOCAL_OBJECT_START(double_Q_tan_constants)
239 data8 0xC4C6628B80DC1CD1, 0x00003FBF // pi/2 lo
240 data8 0x3E223A73BA576E48 // Q8
241 data8 0x3DF54AD8D1F2CA43 // Q9
242 data8 0x3EF66A8EE529A6AA // Q4
243 data8 0x3EC2281050410EE6 // Q5
244 data8 0x3E8D6BB992CC3CF5 // Q6
245 data8 0x3E57F88DE34832E4 // Q7
246 data8 0x3FD5555555555555 // Q0
247 data8 0x3F96C16C16C16DB8 // Q1
248 data8 0x3F61566ABBFFB489 // Q2
249 data8 0x3F2BBD77945C1733 // Q3
250 data8 0x3D927FB33E2B0E04 // Q10
251 LOCAL_OBJECT_END(double_Q_tan_constants)
254 .section .text
256 ////////////////////////////////////////////////////////
258 LOCAL_LIBM_ENTRY(cot)
259 // The initial fnorm will take any unmasked faults and
260 // normalize any single/double unorms
262 { .mlx
263 cmp.eq p12, p11 = r0, r0 // set p12=1, p11=0 for cot
264 movl tan_GR_sig_inv_pi_by_2 = 0xA2F9836E4E44152A // significand of 2/pi
265 }
266 { .mlx
267 addl tan_AD = @ltoff(double_tan_constants), gp
268 movl tan_GR_rshf_2to64 = 0x47e8000000000000 // 1.1000 2^(63+63+1)
269 }
270 ;;
272 { .mlx
273 mov tan_GR_exp_2tom64 = 0xffff-64 // exponent of scaling factor 2^-64
274 movl tan_GR_rshf = 0x43e8000000000000 // 1.1000 2^63 for right shift
275 }
276 { .mfb
277 ld8 tan_AD = [tan_AD]
278 fnorm.s0 tan_NORM_f8 = f8
279 br.cond.sptk COMMON_PATH
280 }
281 ;;
283 LOCAL_LIBM_END(cot)
286 GLOBAL_IEEE754_ENTRY(tan)
287 // The initial fnorm will take any unmasked faults and
288 // normalize any single/double unorms
290 { .mlx
291 cmp.eq p11, p12 = r0, r0 // set p11=1, p12=0 for tan
292 movl tan_GR_sig_inv_pi_by_2 = 0xA2F9836E4E44152A // significand of 2/pi
293 }
294 { .mlx
295 addl tan_AD = @ltoff(double_tan_constants), gp
296 movl tan_GR_rshf_2to64 = 0x47e8000000000000 // 1.1000 2^(63+63+1)
297 }
298 ;;
300 { .mlx
301 mov tan_GR_exp_2tom64 = 0xffff-64 // exponent of scaling factor 2^-64
302 movl tan_GR_rshf = 0x43e8000000000000 // 1.1000 2^63 for right shift
303 }
304 { .mfi
305 ld8 tan_AD = [tan_AD]
306 fnorm.s0 tan_NORM_f8 = f8
307 nop.i 0
308 }
309 ;;
312 // Common path for both tan and cot
313 COMMON_PATH:
314 // Form two constants we need
315 // 2/pi * 2^1 * 2^63, scaled by 2^64 since we just loaded the significand
316 // 1.1000...000 * 2^(63+63+1) to right shift int(W) into the significand
317 { .mmi
318 setf.sig TAN_INV_PI_BY_2_2TO64 = tan_GR_sig_inv_pi_by_2
319 setf.d TAN_RSHF_2TO64 = tan_GR_rshf_2to64
320 mov tan_GR_17_ones = 0x1ffff ;;
321 }
324 // Form another constant
325 // 2^-64 for scaling Nfloat
326 // 1.1000...000 * 2^63, the right shift constant
327 { .mmf
328 setf.exp TAN_2TOM64 = tan_GR_exp_2tom64
329 adds tan_ADQ = double_Q_tan_constants - double_tan_constants, tan_AD
330 (p11) fclass.m.unc p6,p0 = f8, 0x07 // Test for x=0 (tan)
331 }
332 ;;
335 // Form another constant
336 // 2^-64 for scaling Nfloat
337 // 1.1000...000 * 2^63, the right shift constant
338 { .mmf
339 setf.d TAN_RSHF = tan_GR_rshf
340 ldfe tan_Pi_by_2_hi = [tan_AD],16
341 fclass.m.unc p7,p0 = f8, 0x23 // Test for x=inf
342 }
343 ;;
345 { .mfb
346 ldfe tan_Pi_by_2_lo = [tan_ADQ],16
347 fclass.m.unc p8,p0 = f8, 0xc3 // Test for x=nan
348 (p6) br.ret.spnt b0 ;; // Exit for x=0 (tan only)
349 }
351 { .mfi
352 ldfpd tan_P14,tan_P15 = [tan_AD],16
353 (p7) frcpa.s0 f8,p9=f0,f0 // Set qnan indef if x=inf
354 mov tan_GR_10009 = 0x10009
355 }
356 { .mib
357 ldfpd tan_Q8,tan_Q9 = [tan_ADQ],16
358 nop.i 999
359 (p7) br.ret.spnt b0 ;; // Exit for x=inf
360 }
362 { .mfi
363 ldfpd tan_P12,tan_P13 = [tan_AD],16
364 (p12) fclass.m.unc p6,p0 = f8, 0x07 // Test for x=0 (cot)
365 nop.i 999
366 }
367 { .mfb
368 ldfpd tan_Q4,tan_Q5 = [tan_ADQ],16
369 (p8) fma.d.s0 f8=f8,f1,f8 // Set qnan if x=nan
370 (p8) br.ret.spnt b0 ;; // Exit for x=nan
371 }
373 { .mmf
374 getf.exp tan_signexp = tan_NORM_f8
375 ldfpd tan_P8,tan_P9 = [tan_AD],16
376 fmerge.s arg_copy = f8, f8 ;; // Save input for error call
377 }
379 // Multiply x by scaled 2/pi and add large const to shift integer part of W to
380 // rightmost bits of significand
381 { .mmf
382 alloc r32=ar.pfs,0,4,4,0
383 ldfpd tan_Q6,tan_Q7 = [tan_ADQ],16
384 fma.s1 TAN_W_2TO64_RSH = tan_NORM_f8,TAN_INV_PI_BY_2_2TO64,TAN_RSHF_2TO64
385 };;
387 { .mmf
388 ldfpd tan_P10,tan_P11 = [tan_AD],16
389 and tan_exp = tan_GR_17_ones, tan_signexp
390 (p6) frcpa.s0 f8, p0 = f1, f8 ;; // cot(+-0) = +-Inf
391 }
394 // p7 is true if we must call DBX TAN
395 // p7 is true if f8 exp is > 0x10009 (which includes all ones
396 // NAN or inf)
397 { .mmb
398 ldfpd tan_Q0,tan_Q1 = [tan_ADQ],16
399 cmp.ge.unc p7,p0 = tan_exp,tan_GR_10009
400 (p7) br.cond.spnt TAN_DBX ;;
401 }
404 { .mmb
405 ldfpd tan_P4,tan_P5 = [tan_AD],16
406 (p6) mov GR_Parameter_Tag = 226 // (cot)
407 (p6) br.cond.spnt __libm_error_region ;; // call error support if cot(+-0)
408 }
411 { .mmi
412 ldfpd tan_Q2,tan_Q3 = [tan_ADQ],16
413 nop.m 999
414 nop.i 999 ;;
415 }
419 // TAN_NFLOAT = Round_Int_Nearest(tan_W)
420 { .mfi
421 ldfpd tan_P6,tan_P7 = [tan_AD],16
422 fms.s1 TAN_NFLOAT = TAN_W_2TO64_RSH,TAN_2TOM64,TAN_RSHF
423 nop.i 999 ;;
424 }
427 { .mfi
428 ldfd tan_Q10 = [tan_ADQ]
429 nop.f 999
430 nop.i 999 ;;
431 }
434 { .mfi
435 ldfpd tan_P0,tan_P1 = [tan_AD],16
436 nop.f 999
437 nop.i 999 ;;
438 }
441 { .mmi
442 getf.sig tan_GR_n = TAN_W_2TO64_RSH
443 ldfpd tan_P2,tan_P3 = [tan_AD]
444 nop.i 999 ;;
445 }
447 // tan_r = -tan_Nfloat * tan_Pi_by_2_hi + x
448 { .mfi
449 (p12) add tan_GR_n = 0x1, tan_GR_n // N = N + 1 (for cot)
450 fnma.s1 tan_r = TAN_NFLOAT, tan_Pi_by_2_hi, tan_NORM_f8
451 nop.i 999 ;;
452 }
455 // p8 ==> even
456 // p9 ==> odd
457 { .mmi
458 and tan_GR_N_odd_even = 0x1, tan_GR_n ;;
459 nop.m 999
460 cmp.eq.unc p8,p9 = tan_GR_N_odd_even, r0 ;;
461 }
464 .pred.rel "mutex", p11, p12
465 // tan_r = tan_r -tan_Nfloat * tan_Pi_by_2_lo (tan)
466 { .mfi
467 nop.m 999
468 (p11) fnma.s1 tan_r = TAN_NFLOAT, tan_Pi_by_2_lo, tan_r
469 nop.i 999
470 }
471 // tan_r = -(tan_r -tan_Nfloat * tan_Pi_by_2_lo) (cot)
472 { .mfi
473 nop.m 999
474 (p12) fms.s1 tan_r = TAN_NFLOAT, tan_Pi_by_2_lo, tan_r
475 nop.i 999 ;;
476 }
479 { .mfi
480 nop.m 999
481 fma.s1 tan_rsq = tan_r, tan_r, f0
482 nop.i 999 ;;
483 }
486 { .mfi
487 nop.m 999
488 (p9) frcpa.s1 tan_y0, p0 = f1,tan_r
489 nop.i 999 ;;
490 }
493 { .mfi
494 nop.m 999
495 (p8) fma.s1 tan_v18 = tan_rsq, tan_P15, tan_P14
496 nop.i 999
497 }
498 { .mfi
499 nop.m 999
500 (p8) fma.s1 tan_v4 = tan_rsq, tan_P1, tan_P0
501 nop.i 999 ;;
502 }
506 { .mfi
507 nop.m 999
508 (p8) fma.s1 tan_v16 = tan_rsq, tan_P13, tan_P12
509 nop.i 999
510 }
511 { .mfi
512 nop.m 999
513 (p8) fma.s1 tan_v17 = tan_rsq, tan_rsq, f0
514 nop.i 999 ;;
515 }
519 { .mfi
520 nop.m 999
521 (p8) fma.s1 tan_v12 = tan_rsq, tan_P9, tan_P8
522 nop.i 999
523 }
524 { .mfi
525 nop.m 999
526 (p8) fma.s1 tan_v13 = tan_rsq, tan_P11, tan_P10
527 nop.i 999 ;;
528 }
532 { .mfi
533 nop.m 999
534 (p8) fma.s1 tan_v7 = tan_rsq, tan_P5, tan_P4
535 nop.i 999
536 }
537 { .mfi
538 nop.m 999
539 (p8) fma.s1 tan_v8 = tan_rsq, tan_P7, tan_P6
540 nop.i 999 ;;
541 }
545 { .mfi
546 nop.m 999
547 (p9) fnma.s1 tan_d = tan_r, tan_y0, f1
548 nop.i 999
549 }
550 { .mfi
551 nop.m 999
552 (p8) fma.s1 tan_v5 = tan_rsq, tan_P3, tan_P2
553 nop.i 999 ;;
554 }
558 { .mfi
559 nop.m 999
560 (p9) fma.s1 tan_z11 = tan_rsq, tan_Q9, tan_Q8
561 nop.i 999
562 }
563 { .mfi
564 nop.m 999
565 (p9) fma.s1 tan_z12 = tan_rsq, tan_rsq, f0
566 nop.i 999 ;;
567 }
570 { .mfi
571 nop.m 999
572 (p8) fma.s1 tan_v15 = tan_v17, tan_v18, tan_v16
573 nop.i 999
574 }
575 { .mfi
576 nop.m 999
577 (p9) fma.s1 tan_z7 = tan_rsq, tan_Q5, tan_Q4
578 nop.i 999 ;;
579 }
582 { .mfi
583 nop.m 999
584 (p8) fma.s1 tan_v11 = tan_v17, tan_v13, tan_v12
585 nop.i 999
586 }
587 { .mfi
588 nop.m 999
589 (p9) fma.s1 tan_z8 = tan_rsq, tan_Q7, tan_Q6
590 nop.i 999 ;;
591 }
595 { .mfi
596 nop.m 999
597 (p8) fma.s1 tan_v14 = tan_v17, tan_v17, f0
598 nop.i 999
599 }
600 { .mfi
601 nop.m 999
602 (p9) fma.s1 tan_z3 = tan_rsq, tan_Q1, tan_Q0
603 nop.i 999 ;;
604 }
609 { .mfi
610 nop.m 999
611 (p8) fma.s1 tan_v3 = tan_v17, tan_v5, tan_v4
612 nop.i 999
613 }
614 { .mfi
615 nop.m 999
616 (p8) fma.s1 tan_v6 = tan_v17, tan_v8, tan_v7
617 nop.i 999 ;;
618 }
622 { .mfi
623 nop.m 999
624 (p9) fma.s1 tan_y1 = tan_y0, tan_d, tan_y0
625 nop.i 999
626 }
627 { .mfi
628 nop.m 999
629 (p9) fma.s1 tan_dsq = tan_d, tan_d, f0
630 nop.i 999 ;;
631 }
634 { .mfi
635 nop.m 999
636 (p9) fma.s1 tan_z10 = tan_z12, tan_Q10, tan_z11
637 nop.i 999
638 }
639 { .mfi
640 nop.m 999
641 (p9) fma.s1 tan_z9 = tan_z12, tan_z12,f0
642 nop.i 999 ;;
643 }
646 { .mfi
647 nop.m 999
648 (p9) fma.s1 tan_z4 = tan_rsq, tan_Q3, tan_Q2
649 nop.i 999
650 }
651 { .mfi
652 nop.m 999
653 (p9) fma.s1 tan_z6 = tan_z12, tan_z8, tan_z7
654 nop.i 999 ;;
655 }
659 { .mfi
660 nop.m 999
661 (p8) fma.s1 tan_v10 = tan_v14, tan_v15, tan_v11
662 nop.i 999 ;;
663 }
667 { .mfi
668 nop.m 999
669 (p9) fma.s1 tan_y2 = tan_y1, tan_d, tan_y0
670 nop.i 999
671 }
672 { .mfi
673 nop.m 999
674 (p9) fma.s1 tan_d4 = tan_dsq, tan_dsq, tan_d
675 nop.i 999 ;;
676 }
679 { .mfi
680 nop.m 999
681 (p8) fma.s1 tan_v2 = tan_v14, tan_v6, tan_v3
682 nop.i 999
683 }
684 { .mfi
685 nop.m 999
686 (p8) fma.s1 tan_v9 = tan_v14, tan_v14, f0
687 nop.i 999 ;;
688 }
691 { .mfi
692 nop.m 999
693 (p9) fma.s1 tan_z2 = tan_z12, tan_z4, tan_z3
694 nop.i 999
695 }
696 { .mfi
697 nop.m 999
698 (p9) fma.s1 tan_z5 = tan_z9, tan_z10, tan_z6
699 nop.i 999 ;;
700 }
703 { .mfi
704 nop.m 999
705 (p9) fma.s1 tan_inv_r = tan_d4, tan_y2, tan_y0
706 nop.i 999
707 }
708 { .mfi
709 nop.m 999
710 (p8) fma.s1 tan_rcube = tan_rsq, tan_r, f0
711 nop.i 999 ;;
712 }
716 { .mfi
717 nop.m 999
718 (p8) fma.s1 tan_v1 = tan_v9, tan_v10, tan_v2
719 nop.i 999
720 }
721 { .mfi
722 nop.m 999
723 (p9) fma.s1 tan_z1 = tan_z9, tan_z5, tan_z2
724 nop.i 999 ;;
725 }
729 { .mfi
730 nop.m 999
731 (p8) fma.d.s0 f8 = tan_v1, tan_rcube, tan_r
732 nop.i 999
733 }
734 { .mfb
735 nop.m 999
736 (p9) fms.d.s0 f8 = tan_r, tan_z1, tan_inv_r
737 br.ret.sptk b0 ;;
738 }
739 GLOBAL_IEEE754_END(tan)
742 LOCAL_LIBM_ENTRY(__libm_callout)
743 TAN_DBX:
744 .prologue
746 { .mfi
747 nop.m 0
748 fmerge.s f9 = f0,f0
749 .save ar.pfs,GR_SAVE_PFS
750 mov GR_SAVE_PFS=ar.pfs
751 }
752 ;;
754 { .mfi
755 mov GR_SAVE_GP=gp
756 nop.f 0
757 .save b0, GR_SAVE_B0
758 mov GR_SAVE_B0=b0
759 }
761 .body
762 { .mmb
763 nop.m 999
764 nop.m 999
765 (p11) br.cond.sptk.many call_tanl ;;
766 }
768 // Here if we should call cotl
769 { .mmb
770 nop.m 999
771 nop.m 999
772 br.call.sptk.many b0=__libm_cotl# ;;
773 }
775 { .mfi
776 mov gp = GR_SAVE_GP
777 fnorm.d.s0 f8 = f8
778 mov b0 = GR_SAVE_B0
779 }
780 ;;
782 { .mib
783 nop.m 999
784 mov ar.pfs = GR_SAVE_PFS
785 br.ret.sptk b0
786 ;;
787 }
789 // Here if we should call tanl
790 call_tanl:
791 { .mmb
792 nop.m 999
793 nop.m 999
794 br.call.sptk.many b0=__libm_tanl# ;;
795 }
797 { .mfi
798 mov gp = GR_SAVE_GP
799 fnorm.d.s0 f8 = f8
800 mov b0 = GR_SAVE_B0
801 }
802 ;;
804 { .mib
805 nop.m 999
806 mov ar.pfs = GR_SAVE_PFS
807 br.ret.sptk b0
808 ;;
809 }
811 LOCAL_LIBM_END(__libm_callout)
813 .type __libm_tanl#,@function
814 .global __libm_tanl#
815 .type __libm_cotl#,@function
816 .global __libm_cotl#
818 LOCAL_LIBM_ENTRY(__libm_error_region)
819 .prologue
821 // (1)
822 { .mfi
823 add GR_Parameter_Y=-32,sp // Parameter 2 value
824 nop.f 0
825 .save ar.pfs,GR_SAVE_PFS
826 mov GR_SAVE_PFS=ar.pfs // Save ar.pfs
827 }
828 { .mfi
829 .fframe 64
830 add sp=-64,sp // Create new stack
831 nop.f 0
832 mov GR_SAVE_GP=gp // Save gp
833 };;
835 // (2)
836 { .mmi
837 stfd [GR_Parameter_Y] = f1,16 // STORE Parameter 2 on stack
838 add GR_Parameter_X = 16,sp // Parameter 1 address
839 .save b0, GR_SAVE_B0
840 mov GR_SAVE_B0=b0 // Save b0
841 };;
843 .body
844 // (3)
845 { .mib
846 stfd [GR_Parameter_X] = arg_copy // STORE Parameter 1 on stack
847 add GR_Parameter_RESULT = 0,GR_Parameter_Y // Parameter 3 address
848 nop.b 0
849 }
850 { .mib
851 stfd [GR_Parameter_Y] = f8 // STORE Parameter 3 on stack
852 add GR_Parameter_Y = -16,GR_Parameter_Y
853 br.call.sptk b0=__libm_error_support# // Call error handling function
854 };;
855 { .mmi
856 nop.m 0
857 nop.m 0
858 add GR_Parameter_RESULT = 48,sp
859 };;
861 // (4)
862 { .mmi
863 ldfd f8 = [GR_Parameter_RESULT] // Get return result off stack
864 .restore sp
865 add sp = 64,sp // Restore stack pointer
866 mov b0 = GR_SAVE_B0 // Restore return address
867 };;
868 { .mib
869 mov gp = GR_SAVE_GP // Restore gp
870 mov ar.pfs = GR_SAVE_PFS // Restore ar.pfs
871 br.ret.sptk b0 // Return
872 };;
874 LOCAL_LIBM_END(__libm_error_region)
876 .type __libm_error_support#,@function
877 .global __libm_error_support#