| blob | 8996977ddb429ad099962e263c078e3d726a8faa |
1 .file "expf_m1.s"
4 // Copyright (c) 2000 - 2005, Intel Corporation
5 // All rights reserved.
6 //
7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
8 //
9 // Redistribution and use in source and binary forms, with or without
10 // modification, are permitted provided that the following conditions are
11 // met:
12 //
13 // * Redistributions of source code must retain the above copyright
14 // notice, this list of conditions and the following disclaimer.
15 //
16 // * Redistributions in binary form must reproduce the above copyright
17 // notice, this list of conditions and the following disclaimer in the
18 // documentation and/or other materials provided with the distribution.
19 //
20 // * The name of Intel Corporation may not be used to endorse or promote
21 // products derived from this software without specific prior written
22 // permission.
24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
35 //
36 // Intel Corporation is the author of this code, and requests that all
37 // problem reports or change requests be submitted to it directly at
38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
40 // History
41 //*********************************************************************
42 // 02/02/00 Initial Version
43 // 04/04/00 Unwind support added
44 // 08/15/00 Bundle added after call to __libm_error_support to properly
45 // set [the previously overwritten] GR_Parameter_RESULT.
46 // 07/07/01 Improved speed of all paths
47 // 05/20/02 Cleaned up namespace and sf0 syntax
48 // 11/20/02 Improved speed, algorithm based on expf
49 // 03/31/05 Reformatted delimiters between data tables
50 //
51 //
52 // API
53 //*********************************************************************
54 // float expm1f(float)
55 //
56 // Overview of operation
57 //*********************************************************************
58 // 1. Inputs of Nan, Inf, Zero, NatVal handled with special paths
59 //
60 // 2. |x| < 2^-40
61 // Result = x, computed by x + x*x to handle appropriate flags and rounding
62 //
63 // 3. 2^-40 <= |x| < 2^-2
64 // Result determined by 8th order Taylor series polynomial
65 // expm1f(x) = x + A2*x^2 + ... + A8*x^8
66 //
67 // 4. x < -24.0
68 // Here we know result is essentially -1 + eps, where eps only affects
69 // rounded result. Set I.
70 //
71 // 5. x >= 88.7228
72 // Result overflows. Set I, O, and call error support
73 //
74 // 6. 2^-2 <= x < 88.7228 or -24.0 <= x < -2^-2
75 // This is the main path. The algorithm is described below:
77 // Take the input x. w is "how many log2/128 in x?"
78 // w = x * 64/log2
79 // NJ = int(w)
80 // x = NJ*log2/64 + R
82 // NJ = 64*n + j
83 // x = n*log2 + (log2/64)*j + R
84 //
85 // So, exp(x) = 2^n * 2^(j/64)* exp(R)
86 //
87 // T = 2^n * 2^(j/64)
88 // Construct 2^n
89 // Get 2^(j/64) table
90 // actually all the entries of 2^(j/64) table are stored in DP and
91 // with exponent bits set to 0 -> multiplication on 2^n can be
92 // performed by doing logical "or" operation with bits presenting 2^n
94 // exp(R) = 1 + (exp(R) - 1)
95 // P = exp(R) - 1 approximated by Taylor series of 3rd degree
96 // P = A3*R^3 + A2*R^2 + R, A3 = 1/6, A2 = 1/2
97 //
99 // The final result is reconstructed as follows
100 // expm1f(x) = T*P + (T - 1.0)
102 // Special values
103 //*********************************************************************
104 // expm1f(+0) = +0.0
105 // expm1f(-0) = -0.0
107 // expm1f(+qnan) = +qnan
108 // expm1f(-qnan) = -qnan
109 // expm1f(+snan) = +qnan
110 // expm1f(-snan) = -qnan
112 // expm1f(-inf) = -1.0
113 // expm1f(+inf) = +inf
115 // Overflow and Underflow
116 //*********************************************************************
117 // expm1f(x) = largest single normal when
118 // x = 88.7228 = 0x42b17217
119 //
120 // Underflow is handled as described in case 2 above.
123 // Registers used
124 //*********************************************************************
125 // Floating Point registers used:
126 // f8, input
127 // f6,f7, f9 -> f15, f32 -> f45
129 // General registers used:
130 // r3, r20 -> r38
132 // Predicate registers used:
133 // p9 -> p15
135 // Assembly macros
136 //*********************************************************************
137 // integer registers used
138 // scratch
139 rNJ = r3
141 rExp_half = r20
142 rSignexp_x = r21
143 rExp_x = r22
144 rExp_mask = r23
145 rExp_bias = r24
146 rTmp = r25
147 rM1_lim = r25
148 rGt_ln = r25
149 rJ = r26
150 rN = r27
151 rTblAddr = r28
152 rLn2Div64 = r29
153 rRightShifter = r30
154 r64DivLn2 = r31
155 // stacked
156 GR_SAVE_PFS = r32
157 GR_SAVE_B0 = r33
158 GR_SAVE_GP = r34
159 GR_Parameter_X = r35
160 GR_Parameter_Y = r36
161 GR_Parameter_RESULT = r37
162 GR_Parameter_TAG = r38
164 // floating point registers used
165 FR_X = f10
166 FR_Y = f1
167 FR_RESULT = f8
168 // scratch
169 fRightShifter = f6
170 f64DivLn2 = f7
171 fNormX = f9
172 fNint = f10
173 fN = f11
174 fR = f12
175 fLn2Div64 = f13
176 fA2 = f14
177 fA3 = f15
178 // stacked
179 fP = f32
180 fX3 = f33
181 fT = f34
182 fMIN_SGL_OFLOW_ARG = f35
183 fMAX_SGL_NORM_ARG = f36
184 fMAX_SGL_MINUS_1_ARG = f37
185 fA4 = f38
186 fA43 = f38
187 fA432 = f38
188 fRSqr = f39
189 fA5 = f40
190 fTmp = f41
191 fGt_pln = f41
192 fXsq = f41
193 fA7 = f42
194 fA6 = f43
195 fA65 = f43
196 fTm1 = f44
197 fA8 = f45
198 fA87 = f45
199 fA8765 = f45
200 fA8765432 = f45
201 fWre_urm_f8 = f45
203 RODATA
204 .align 16
205 LOCAL_OBJECT_START(_expf_table)
206 data8 0x3efa01a01a01a01a // A8 = 1/8!
207 data8 0x3f2a01a01a01a01a // A7 = 1/7!
208 data8 0x3f56c16c16c16c17 // A6 = 1/6!
209 data8 0x3f81111111111111 // A5 = 1/5!
210 data8 0x3fa5555555555555 // A4 = 1/4!
211 data8 0x3fc5555555555555 // A3 = 1/3!
212 //
213 data4 0x42b17218 // Smallest sgl arg to overflow sgl result
214 data4 0x42b17217 // Largest sgl arg to give sgl result
215 //
216 // 2^(j/64) table, j goes from 0 to 63
217 data8 0x0000000000000000 // 2^(0/64)
218 data8 0x00002C9A3E778061 // 2^(1/64)
219 data8 0x000059B0D3158574 // 2^(2/64)
220 data8 0x0000874518759BC8 // 2^(3/64)
221 data8 0x0000B5586CF9890F // 2^(4/64)
222 data8 0x0000E3EC32D3D1A2 // 2^(5/64)
223 data8 0x00011301D0125B51 // 2^(6/64)
224 data8 0x0001429AAEA92DE0 // 2^(7/64)
225 data8 0x000172B83C7D517B // 2^(8/64)
226 data8 0x0001A35BEB6FCB75 // 2^(9/64)
227 data8 0x0001D4873168B9AA // 2^(10/64)
228 data8 0x0002063B88628CD6 // 2^(11/64)
229 data8 0x0002387A6E756238 // 2^(12/64)
230 data8 0x00026B4565E27CDD // 2^(13/64)
231 data8 0x00029E9DF51FDEE1 // 2^(14/64)
232 data8 0x0002D285A6E4030B // 2^(15/64)
233 data8 0x000306FE0A31B715 // 2^(16/64)
234 data8 0x00033C08B26416FF // 2^(17/64)
235 data8 0x000371A7373AA9CB // 2^(18/64)
236 data8 0x0003A7DB34E59FF7 // 2^(19/64)
237 data8 0x0003DEA64C123422 // 2^(20/64)
238 data8 0x0004160A21F72E2A // 2^(21/64)
239 data8 0x00044E086061892D // 2^(22/64)
240 data8 0x000486A2B5C13CD0 // 2^(23/64)
241 data8 0x0004BFDAD5362A27 // 2^(24/64)
242 data8 0x0004F9B2769D2CA7 // 2^(25/64)
243 data8 0x0005342B569D4F82 // 2^(26/64)
244 data8 0x00056F4736B527DA // 2^(27/64)
245 data8 0x0005AB07DD485429 // 2^(28/64)
246 data8 0x0005E76F15AD2148 // 2^(29/64)
247 data8 0x0006247EB03A5585 // 2^(30/64)
248 data8 0x0006623882552225 // 2^(31/64)
249 data8 0x0006A09E667F3BCD // 2^(32/64)
250 data8 0x0006DFB23C651A2F // 2^(33/64)
251 data8 0x00071F75E8EC5F74 // 2^(34/64)
252 data8 0x00075FEB564267C9 // 2^(35/64)
253 data8 0x0007A11473EB0187 // 2^(36/64)
254 data8 0x0007E2F336CF4E62 // 2^(37/64)
255 data8 0x00082589994CCE13 // 2^(38/64)
256 data8 0x000868D99B4492ED // 2^(39/64)
257 data8 0x0008ACE5422AA0DB // 2^(40/64)
258 data8 0x0008F1AE99157736 // 2^(41/64)
259 data8 0x00093737B0CDC5E5 // 2^(42/64)
260 data8 0x00097D829FDE4E50 // 2^(43/64)
261 data8 0x0009C49182A3F090 // 2^(44/64)
262 data8 0x000A0C667B5DE565 // 2^(45/64)
263 data8 0x000A5503B23E255D // 2^(46/64)
264 data8 0x000A9E6B5579FDBF // 2^(47/64)
265 data8 0x000AE89F995AD3AD // 2^(48/64)
266 data8 0x000B33A2B84F15FB // 2^(49/64)
267 data8 0x000B7F76F2FB5E47 // 2^(50/64)
268 data8 0x000BCC1E904BC1D2 // 2^(51/64)
269 data8 0x000C199BDD85529C // 2^(52/64)
270 data8 0x000C67F12E57D14B // 2^(53/64)
271 data8 0x000CB720DCEF9069 // 2^(54/64)
272 data8 0x000D072D4A07897C // 2^(55/64)
273 data8 0x000D5818DCFBA487 // 2^(56/64)
274 data8 0x000DA9E603DB3285 // 2^(57/64)
275 data8 0x000DFC97337B9B5F // 2^(58/64)
276 data8 0x000E502EE78B3FF6 // 2^(59/64)
277 data8 0x000EA4AFA2A490DA // 2^(60/64)
278 data8 0x000EFA1BEE615A27 // 2^(61/64)
279 data8 0x000F50765B6E4540 // 2^(62/64)
280 data8 0x000FA7C1819E90D8 // 2^(63/64)
281 LOCAL_OBJECT_END(_expf_table)
284 .section .text
285 GLOBAL_IEEE754_ENTRY(expm1f)
287 { .mlx
288 getf.exp rSignexp_x = f8 // Must recompute if x unorm
289 movl r64DivLn2 = 0x40571547652B82FE // 64/ln(2)
290 }
291 { .mlx
292 addl rTblAddr = @ltoff(_expf_table),gp
293 movl rRightShifter = 0x43E8000000000000 // DP Right Shifter
294 }
295 ;;
297 { .mfi
298 // point to the beginning of the table
299 ld8 rTblAddr = [rTblAddr]
300 fclass.m p14, p0 = f8 , 0x22 // test for -INF
301 mov rExp_mask = 0x1ffff // Exponent mask
302 }
303 { .mfi
304 nop.m 0
305 fnorm.s1 fNormX = f8 // normalized x
306 nop.i 0
307 }
308 ;;
310 { .mfi
311 setf.d f64DivLn2 = r64DivLn2 // load 64/ln(2) to FP reg
312 fclass.m p9, p0 = f8 , 0x0b // test for x unorm
313 mov rExp_bias = 0xffff // Exponent bias
314 }
315 { .mlx
316 // load Right Shifter to FP reg
317 setf.d fRightShifter = rRightShifter
318 movl rLn2Div64 = 0x3F862E42FEFA39EF // DP ln(2)/64 in GR
319 }
320 ;;
322 { .mfi
323 ldfpd fA8, fA7 = [rTblAddr], 16
324 fcmp.eq.s1 p13, p0 = f0, f8 // test for x = 0.0
325 mov rExp_half = 0xfffe
326 }
327 { .mfb
328 setf.d fLn2Div64 = rLn2Div64 // load ln(2)/64 to FP reg
329 nop.f 0
330 (p9) br.cond.spnt EXPM1_UNORM // Branch if x unorm
331 }
332 ;;
334 EXPM1_COMMON:
335 { .mfb
336 ldfpd fA6, fA5 = [rTblAddr], 16
337 (p14) fms.s.s0 f8 = f0, f0, f1 // result if x = -inf
338 (p14) br.ret.spnt b0 // exit here if x = -inf
339 }
340 ;;
342 { .mfb
343 ldfpd fA4, fA3 = [rTblAddr], 16
344 fclass.m p15, p0 = f8 , 0x1e1 // test for NaT,NaN,+Inf
345 (p13) br.ret.spnt b0 // exit here if x =0.0, result is x
346 }
347 ;;
349 { .mfi
350 // overflow thresholds
351 ldfps fMIN_SGL_OFLOW_ARG, fMAX_SGL_NORM_ARG = [rTblAddr], 8
352 fma.s1 fXsq = fNormX, fNormX, f0 // x^2 for small path
353 and rExp_x = rExp_mask, rSignexp_x // Biased exponent of x
354 }
355 { .mlx
356 nop.m 0
357 movl rM1_lim = 0xc1c00000 // Minus -1 limit (-24.0), SP
358 }
359 ;;
361 { .mfi
362 setf.exp fA2 = rExp_half
363 // x*(64/ln(2)) + Right Shifter
364 fma.s1 fNint = fNormX, f64DivLn2, fRightShifter
365 sub rExp_x = rExp_x, rExp_bias // True exponent of x
366 }
367 { .mfb
368 nop.m 0
369 (p15) fma.s.s0 f8 = f8, f1, f0 // result if x = NaT,NaN,+Inf
370 (p15) br.ret.spnt b0 // exit here if x = NaT,NaN,+Inf
371 }
372 ;;
374 { .mfi
375 setf.s fMAX_SGL_MINUS_1_ARG = rM1_lim // -1 threshold, -24.0
376 nop.f 0
377 cmp.gt p7, p8 = -2, rExp_x // Test |x| < 2^(-2)
378 }
379 ;;
381 { .mfi
382 (p7) cmp.gt.unc p6, p7 = -40, rExp_x // Test |x| < 2^(-40)
383 fma.s1 fA87 = fA8, fNormX, fA7 // Small path, A8*x+A7
384 nop.i 0
385 }
386 { .mfi
387 nop.m 0
388 fma.s1 fA65 = fA6, fNormX, fA5 // Small path, A6*x+A5
389 nop.i 0
390 }
391 ;;
393 { .mfb
394 nop.m 0
395 (p6) fma.s.s0 f8 = f8, f8, f8 // If x < 2^-40, result=x+x*x
396 (p6) br.ret.spnt b0 // Exit if x < 2^-40
397 }
398 ;;
400 { .mfi
401 nop.m 0
402 // check for overflow
403 fcmp.gt.s1 p15, p14 = fNormX, fMIN_SGL_OFLOW_ARG
404 nop.i 0
405 }
406 { .mfi
407 nop.m 0
408 fms.s1 fN = fNint, f1, fRightShifter // n in FP register
409 nop.i 0
410 }
411 ;;
413 { .mfi
414 nop.m 0
415 (p7) fma.s1 fA43 = fA4, fNormX, fA3 // Small path, A4*x+A3
416 nop.i 0
417 }
418 ;;
420 { .mfi
421 getf.sig rNJ = fNint // bits of n, j
422 (p7) fma.s1 fA8765 = fA87, fXsq, fA65 // Small path, A87*xsq+A65
423 nop.i 0
424 }
425 { .mfb
426 nop.m 0
427 (p7) fma.s1 fX3 = fXsq, fNormX, f0 // Small path, x^3
428 // branch out if overflow
429 (p15) br.cond.spnt EXPM1_CERTAIN_OVERFLOW
430 }
431 ;;
433 { .mfi
434 addl rN = 0xffff-63, rNJ // biased and shifted n
435 fnma.s1 fR = fLn2Div64, fN, fNormX // R = x - N*ln(2)/64
436 extr.u rJ = rNJ , 0 , 6 // bits of j
437 }
438 ;;
440 { .mfi
441 shladd rJ = rJ, 3, rTblAddr // address in the 2^(j/64) table
442 // check for certain -1
443 fcmp.le.s1 p13, p0 = fNormX, fMAX_SGL_MINUS_1_ARG
444 shr rN = rN, 6 // biased n
445 }
446 { .mfi
447 nop.m 0
448 (p7) fma.s1 fA432 = fA43, fNormX, fA2 // Small path, A43*x+A2
449 nop.i 0
450 }
451 ;;
453 { .mfi
454 ld8 rJ = [rJ]
455 nop.f 0
456 shl rN = rN , 52 // 2^n bits in DP format
457 }
458 ;;
460 { .mmi
461 or rN = rN, rJ // bits of 2^n * 2^(j/64) in DP format
462 (p13) mov rTmp = 1 // Make small value for -1 path
463 nop.i 0
464 }
465 ;;
467 { .mfi
468 setf.d fT = rN // 2^n
469 // check for possible overflow (only happens if input higher precision)
470 (p14) fcmp.gt.s1 p14, p0 = fNormX, fMAX_SGL_NORM_ARG
471 nop.i 0
472 }
473 { .mfi
474 nop.m 0
475 (p7) fma.s1 fA8765432 = fA8765, fX3, fA432 // A8765*x^3+A432
476 nop.i 0
477 }
478 ;;
480 { .mfi
481 (p13) setf.exp fTmp = rTmp // Make small value for -1 path
482 fma.s1 fP = fA3, fR, fA2 // A3*R + A2
483 nop.i 0
484 }
485 { .mfb
486 nop.m 0
487 fma.s1 fRSqr = fR, fR, f0 // R^2
488 (p13) br.cond.spnt EXPM1_CERTAIN_MINUS_ONE // Branch if x < -24.0
489 }
490 ;;
492 { .mfb
493 nop.m 0
494 (p7) fma.s.s0 f8 = fA8765432, fXsq, fNormX // Small path,
495 // result=xsq*A8765432+x
496 (p7) br.ret.spnt b0 // Exit if 2^-40 <= |x| < 2^-2
497 }
498 ;;
500 { .mfi
501 nop.m 0
502 fma.s1 fP = fP, fRSqr, fR // P = (A3*R + A2)*Rsqr + R
503 nop.i 0
504 }
505 ;;
507 { .mfb
508 nop.m 0
509 fms.s1 fTm1 = fT, f1, f1 // T - 1.0
510 (p14) br.cond.spnt EXPM1_POSSIBLE_OVERFLOW
511 }
512 ;;
514 { .mfb
515 nop.m 0
516 fma.s.s0 f8 = fP, fT, fTm1
517 br.ret.sptk b0 // Result for main path
518 // minus_one_limit < x < -2^-2
519 // and +2^-2 <= x < overflow_limit
520 }
521 ;;
523 // Here if x unorm
524 EXPM1_UNORM:
525 { .mfb
526 getf.exp rSignexp_x = fNormX // Must recompute if x unorm
527 fcmp.eq.s0 p6, p0 = f8, f0 // Set D flag
528 br.cond.sptk EXPM1_COMMON
529 }
530 ;;
532 // here if result will be -1 and inexact, x <= -24.0
533 EXPM1_CERTAIN_MINUS_ONE:
534 { .mfb
535 nop.m 0
536 fms.s.s0 f8 = fTmp, fTmp, f1 // Result -1, and Inexact set
537 br.ret.sptk b0
538 }
539 ;;
541 EXPM1_POSSIBLE_OVERFLOW:
543 // Here if fMAX_SGL_NORM_ARG < x < fMIN_SGL_OFLOW_ARG
544 // This cannot happen if input is a single, only if input higher precision.
545 // Overflow is a possibility, not a certainty.
547 // Recompute result using status field 2 with user's rounding mode,
548 // and wre set. If result is larger than largest single, then we have
549 // overflow
551 { .mfi
552 mov rGt_ln = 0x1007f // Exponent for largest sgl + 1 ulp
553 fsetc.s2 0x7F,0x42 // Get user's round mode, set wre
554 nop.i 0
555 }
556 ;;
558 { .mfi
559 setf.exp fGt_pln = rGt_ln // Create largest single + 1 ulp
560 fma.s.s2 fWre_urm_f8 = fP, fT, fTm1 // Result with wre set
561 nop.i 0
562 }
563 ;;
565 { .mfi
566 nop.m 0
567 fsetc.s2 0x7F,0x40 // Turn off wre in sf2
568 nop.i 0
569 }
570 ;;
572 { .mfi
573 nop.m 0
574 fcmp.ge.s1 p6, p0 = fWre_urm_f8, fGt_pln // Test for overflow
575 nop.i 0
576 }
577 ;;
579 { .mfb
580 nop.m 0
581 nop.f 0
582 (p6) br.cond.spnt EXPM1_CERTAIN_OVERFLOW // Branch if overflow
583 }
584 ;;
586 { .mfb
587 nop.m 0
588 fma.s.s0 f8 = fP, fT, fTm1
589 br.ret.sptk b0 // Exit if really no overflow
590 }
591 ;;
593 // here if overflow
594 EXPM1_CERTAIN_OVERFLOW:
595 { .mmi
596 addl rTmp = 0x1FFFE, r0;;
597 setf.exp fTmp = rTmp
598 nop.i 999
599 }
600 ;;
602 { .mfi
603 alloc r32 = ar.pfs, 0, 3, 4, 0 // get some registers
604 fmerge.s FR_X = fNormX,fNormX
605 nop.i 0
606 }
607 { .mfb
608 mov GR_Parameter_TAG = 43
609 fma.s.s0 FR_RESULT = fTmp, fTmp, f0 // Set I,O and +INF result
610 br.cond.sptk __libm_error_region
611 }
612 ;;
614 GLOBAL_IEEE754_END(expm1f)
617 LOCAL_LIBM_ENTRY(__libm_error_region)
618 .prologue
619 { .mfi
620 add GR_Parameter_Y=-32,sp // Parameter 2 value
621 nop.f 999
622 .save ar.pfs,GR_SAVE_PFS
623 mov GR_SAVE_PFS=ar.pfs // Save ar.pfs
624 }
625 { .mfi
626 .fframe 64
627 add sp=-64,sp // Create new stack
628 nop.f 0
629 mov GR_SAVE_GP=gp // Save gp
630 };;
631 { .mmi
632 stfs [GR_Parameter_Y] = FR_Y,16 // Store Parameter 2 on stack
633 add GR_Parameter_X = 16,sp // Parameter 1 address
634 .save b0, GR_SAVE_B0
635 mov GR_SAVE_B0=b0 // Save b0
636 };;
637 .body
638 { .mfi
639 stfs [GR_Parameter_X] = FR_X // Store Parameter 1 on stack
640 nop.f 0
641 add GR_Parameter_RESULT = 0,GR_Parameter_Y // Parameter 3 address
642 }
643 { .mib
644 stfs [GR_Parameter_Y] = FR_RESULT // Store Parameter 3 on stack
645 add GR_Parameter_Y = -16,GR_Parameter_Y
646 br.call.sptk b0=__libm_error_support# // Call error handling function
647 };;
649 { .mmi
650 add GR_Parameter_RESULT = 48,sp
651 nop.m 0
652 nop.i 0
653 };;
655 { .mmi
656 ldfs f8 = [GR_Parameter_RESULT] // Get return result off stack
657 .restore sp
658 add sp = 64,sp // Restore stack pointer
659 mov b0 = GR_SAVE_B0 // Restore return address
660 };;
661 { .mib
662 mov gp = GR_SAVE_GP // Restore gp
663 mov ar.pfs = GR_SAVE_PFS // Restore ar.pfs
664 br.ret.sptk b0 // Return
665 };;
667 LOCAL_LIBM_END(__libm_error_region)
670 .type __libm_error_support#,@function
671 .global __libm_error_support#