sysdeps/ia64/fpu/e_fmod.S

   1 .file "fmod.s"
   2
   3
   4 // Copyright (c) 2000 - 2003, Intel Corporation
   5 // All rights reserved.
   6 //
   7 // Contributed 2000 by the Intel Numerics Group, Intel Corporation
   8 //
   9 // Redistribution and use in source and binary forms, with or without
  10 // modification, are permitted provided that the following conditions are
  11 // met:
  12 //
  13 // * Redistributions of source code must retain the above copyright
  14 // notice, this list of conditions and the following disclaimer.
  15 //
  16 // * Redistributions in binary form must reproduce the above copyright
  17 // notice, this list of conditions and the following disclaimer in the
  18 // documentation and/or other materials provided with the distribution.
  19 //
  20 // * The name of Intel Corporation may not be used to endorse or promote
  21 // products derived from this software without specific prior written
  22 // permission.
  23
  24 // THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  25 // "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  26 // LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  27 // A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL INTEL OR ITS
  28 // CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  29 // EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  30 // PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  31 // PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY
  32 // OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY OR TORT (INCLUDING
  33 // NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  34 // SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  35 //
  36 // Intel Corporation is the author of this code, and requests that all
  37 // problem reports or change requests be submitted to it directly at
  38 // http://www.intel.com/software/products/opensource/libraries/num.htm.
  39 //
  40 // History
  41 //====================================================================
  42 // 02/02/00 Initial version
  43 // 03/02/00 New Algorithm
  44 // 04/04/00 Unwind support added
  45 // 08/15/00 Bundle added after call to __libm_error_support to properly
  46 //          set [the previously overwritten] GR_Parameter_RESULT.
  47 // 11/28/00 Set FR_Y to f9
  48 // 03/11/02 Fixed flags for fmod(qnan,zero)
  49 // 05/20/02 Cleaned up namespace and sf0 syntax
  50 // 02/10/03 Reordered header: .section, .global, .proc, .align
  51 // 04/28/03 Fix: fmod(sNaN,0) no longer sets errno
  52 //
  53 // API
  54 //====================================================================
  55 // double fmod(double,double);
  56 //
  57 // Overview of operation
  58 //====================================================================
  59 //  fmod(a,b)=a-i*b,
  60 //  where i is an integer such that, if b!=0,
  61 //  |i|<|a/b| and |a/b-i|<1
  62 //
  63 // Algorithm
  64 //====================================================================
  65 // a). if |a|<|b|, return a
  66 // b). get quotient and reciprocal overestimates accurate to
  67 //     33 bits (q2,y2)
  68 // c). if the exponent difference (exponent(a)-exponent(b))
  69 //     is less than 32, truncate quotient to integer and
  70 //     finish in one iteration
  71 // d). if exponent(a)-exponent(b)>=32 (q2>=2^32)
  72 //     round quotient estimate to single precision (k=RN(q2)),
  73 //     calculate partial remainder (a'=a-k*b),
  74 //     get quotient estimate (a'*y2), and repeat from c).
  75 //
  76 // Special cases
  77 //====================================================================
  78 // b=+/-0: return NaN, call libm_error_support
  79 // a=+/-Inf, a=NaN or b=NaN: return NaN
  80 //
  81 // Registers used
  82 //====================================================================
  83 // Predicate registers: p6-p11
  84 // General registers:   r2,r29,r32 (ar.pfs), r33-r39
  85 // Floating point registers: f6-f15
  86
  87 GR_SAVE_B0                    = r33
  88 GR_SAVE_PFS                   = r34
  89 GR_SAVE_GP                    = r35
  90 GR_SAVE_SP                    = r36
  91
  92 GR_Parameter_X                = r37
  93 GR_Parameter_Y                = r38
  94 GR_Parameter_RESULT           = r39
  95 GR_Parameter_TAG              = r40
  96
  97 FR_X             = f10
  98 FR_Y             = f9
  99 FR_RESULT        = f8
 100
 101
 102 .section .text
 103 GLOBAL_IEEE754_ENTRY(fmod)
 104
 105 // inputs in f8, f9
 106 // result in f8
 107
 108 { .mfi
 109   alloc r32=ar.pfs,1,4,4,0
 110   // f6=|a|
 111   fmerge.s f6=f0,f8
 112   mov r2 = 0x0ffdd
 113 }
 114   {.mfi
 115   nop.m 0
 116   // f7=|b|
 117   fmerge.s f7=f0,f9
 118   nop.i 0;;
 119 }
 120
 121 { .mfi
 122   setf.exp f11 = r2
 123   // (1) y0
 124   frcpa.s1 f10,p6=f6,f7
 125   nop.i 0
 126 }
 127
 128 // Y +-NAN, +-inf, +-0?     p7
 129 { .mfi
 130       nop.m 999
 131       fclass.m.unc  p7,p0 = f9, 0xe7
 132       nop.i 999;;
 133 }
 134
 135 // qnan snan inf norm     unorm 0 -+
 136 // 1    1    1   0        0     0 11
 137 // e                      3
 138 // X +-NAN, +-inf, ?        p9
 139
 140 { .mfi
 141       nop.m 999
 142       fclass.m.unc  p9,p0 = f8, 0xe3
 143       nop.i 999
 144 }
 145
 146 // |x| < |y|? Return x p8
 147 { .mfi
 148       nop.m 999
 149       fcmp.lt.unc.s1 p8,p0 = f6,f7
 150       nop.i 999 ;;
 151 }
 152
 153 { .mfi
 154   nop.m 0
 155   // normalize y (if |x|<|y|)
 156   (p8) fma.s0 f9=f9,f1,f0
 157   nop.i 0;;
 158 }
 159
 160   { .mfi
 161   mov r2=0x1001f
 162   // (2) q0=a*y0
 163   (p6) fma.s1 f13=f6,f10,f0
 164   nop.i 0
 165 }
 166 { .mfi
 167   nop.m 0
 168   // (3) e0 = 1 - b * y0
 169   (p6) fnma.s1 f12=f7,f10,f1
 170   nop.i 0;;
 171 }
 172
 173   {.mfi
 174   nop.m 0
 175   // normalize x (if |x|<|y|)
 176   (p8) fma.d.s0 f8=f8,f1,f0
 177   nop.i 0
 178 }
 179 {.bbb
 180   (p9) br.cond.spnt FMOD_X_NAN_INF
 181   (p7) br.cond.spnt FMOD_Y_NAN_INF_ZERO
 182   // if |x|<|y|, return
 183   (p8) br.ret.spnt    b0;;
 184 }
 185
 186   {.mfi
 187   nop.m 0
 188   // normalize x
 189   fma.s0 f6=f6,f1,f0
 190   nop.i 0
 191 }
 192 {.mfi
 193   nop.m 0
 194   // normalize y
 195   fma.s0 f7=f7,f1,f0
 196   nop.i 0;;
 197 }
 198
 199   {.mfi
 200   // f15=2^32
 201   setf.exp f15=r2
 202   // (4) q1=q0+e0*q0
 203   (p6) fma.s1 f13=f12,f13,f13
 204   nop.i 0
 205 }
 206 { .mfi
 207   nop.m 0
 208   // (5) e1 = e0 * e0 + 2^-34
 209   (p6) fma.s1 f14=f12,f12,f11
 210   nop.i 0;;
 211 }
 212 {.mlx
 213   nop.m 0
 214   movl r2=0x33a00000;;
 215 }
 216 { .mfi
 217   nop.m 0
 218   // (6) y1 = y0 + e0 * y0
 219   (p6) fma.s1 f10=f12,f10,f10
 220   nop.i 0;;
 221 }
 222 {.mfi
 223   // set f12=1.25*2^{-24}
 224   setf.s f12=r2
 225   // (7) q2=q1+e1*q1
 226   (p6) fma.s1 f13=f13,f14,f13
 227   nop.i 0;;
 228 }
 229 {.mfi
 230   nop.m 0
 231   fmerge.s f9=f8,f9
 232   nop.i 0
 233 }
 234 { .mfi
 235   nop.m 0
 236   // (8) y2 = y1 + e1 * y1
 237   (p6) fma.s1 f10=f14,f10,f10
 238   // set p6=0, p10=0
 239   cmp.ne.and p6,p10=r0,r0;;
 240 }
 241
 242 .align 32
 243 loop53:
 244   {.mfi
 245   nop.m 0
 246   // compare q2, 2^32
 247   fcmp.lt.unc.s1 p8,p7=f13,f15
 248   nop.i 0
 249 }
 250   {.mfi
 251   nop.m 0
 252   // will truncate quotient to integer, if exponent<32 (in advance)
 253   fcvt.fx.trunc.s1 f11=f13
 254   nop.i 0;;
 255 }
 256   {.mfi
 257   nop.m 0
 258   // if exponent>32, round quotient to single precision (perform in advance)
 259   fma.s.s1 f13=f13,f1,f0
 260   nop.i 0;;
 261 }
 262   {.mfi
 263   nop.m 0
 264   // set f12=sgn(a)
 265   (p8) fmerge.s f12=f8,f1
 266   nop.i 0
 267 }
 268   {.mfi
 269   nop.m 0
 270   // normalize truncated quotient
 271   (p8) fcvt.xf f13=f11
 272   nop.i 0;;
 273 }
 274   { .mfi
 275   nop.m 0
 276   // calculate remainder (assuming f13=RZ(Q))
 277   (p7) fnma.s1 f14=f13,f7,f6
 278   nop.i 0
 279 }
 280   {.mfi
 281   nop.m 0
 282   // also if exponent>32, round quotient to single precision
 283   // and subtract 1 ulp: q=q-q*(1.25*2^{-24})
 284   (p7) fnma.s.s1 f11=f13,f12,f13
 285   nop.i 0;;
 286 }
 287
 288   {.mfi
 289   nop.m 0
 290   // (p8) calculate remainder (82-bit format)
 291   (p8) fnma.s1 f11=f13,f7,f6
 292   nop.i 0
 293 }
 294   {.mfi
 295   nop.m 0
 296   // (p7) calculate remainder (assuming f11=RZ(Q))
 297   (p7) fnma.s1 f6=f11,f7,f6
 298   nop.i 0;;
 299 }
 300
 301
 302   {.mfi
 303   nop.m 0
 304   // Final iteration (p8): is f6 the correct remainder (quotient was not overestimated) ?
 305   (p8) fcmp.lt.unc.s1 p6,p10=f11,f0
 306   nop.i 0;;
 307 }
 308   {.mfi
 309   nop.m 0
 310   // get new quotient estimation: a'*y2
 311   (p7) fma.s1 f13=f14,f10,f0
 312   nop.i 0
 313 }
 314   {.mfb
 315   nop.m 0
 316   // was f14=RZ(Q) ? (then new remainder f14>=0)
 317   (p7) fcmp.lt.unc.s1 p7,p9=f14,f0
 318   nop.b 0;;
 319 }
 320
 321
 322 .pred.rel "mutex",p6,p10
 323   {.mfb
 324   nop.m 0
 325   // add b to estimated remainder (to cover the case when the quotient was overestimated)
 326   // also set correct sign by using f9=|b|*sgn(a), f12=sgn(a)
 327   (p6) fma.d.s0 f8=f11,f12,f9
 328   nop.b 0
 329 }
 330   {.mfb
 331   nop.m 0
 332   // calculate remainder (single precision)
 333   // set correct sign of result before returning
 334   (p10) fma.d.s0 f8=f11,f12,f0
 335   (p8) br.ret.sptk b0;;
 336 }
 337   {.mfi
 338   nop.m 0
 339   // if f13!=RZ(Q), get alternative quotient estimation: a''*y2
 340   (p7) fma.s1 f13=f6,f10,f0
 341   nop.i 0
 342 }
 343   {.mfb
 344   nop.m 0
 345   // if f14 was RZ(Q), set remainder to f14
 346   (p9) mov f6=f14
 347   br.cond.sptk loop53;;
 348 }
 349
 350
 351
 352 FMOD_X_NAN_INF:
 353
 354 // Y zero ?
 355 {.mfi
 356   nop.m 0
 357   fclass.m p10,p0=f8,0xc3     // Test x=nan
 358   nop.i 0
 359 }
 360 {.mfi
 361   nop.m 0
 362   fma.s1 f10=f9,f1,f0
 363   nop.i 0;;
 364 }
 365
 366 {.mfi
 367   nop.m 0
 368   fma.s0 f8=f8,f1,f0
 369   nop.i 0
 370 }
 371 {.mfi
 372   nop.m 0
 373 (p10) fclass.m p10,p0=f9,0x07 // Test x=nan, and y=zero
 374   nop.i 0;;
 375 }
 376
 377 {.mfb
 378  nop.m 0
 379  fcmp.eq.unc.s1 p11,p0=f10,f0
 380 (p10) br.ret.spnt b0;;        // Exit with result=x if x=nan and y=zero
 381 }
 382 {.mib
 383   nop.m 0
 384   nop.i 0
 385   // if Y zero
 386   (p11) br.cond.spnt FMOD_Y_ZERO;;
 387 }
 388
 389 // X infinity? Return QNAN indefinite
 390 { .mfi
 391       nop.m 999
 392       fclass.m.unc  p8,p9 = f8, 0x23
 393       nop.i 999;;
 394 }
 395 // Y NaN ?
 396 {.mfi
 397      nop.m 999
 398 (p8) fclass.m p9,p8=f9,0xc3
 399      nop.i 0;;
 400 }
 401 {.mfi
 402       nop.m 999
 403 (p8)  frcpa.s0 f8,p0 = f8,f8
 404       nop.i 0
 405 }
 406 { .mfi
 407       nop.m 999
 408     // also set Denormal flag if necessary
 409 (p8)  fma.s0 f9=f9,f1,f0
 410       nop.i 999 ;;
 411 }
 412
 413 { .mfb
 414       nop.m 999
 415 (p8)  fma.d.s0 f8=f8,f1,f0
 416       nop.b 999 ;;
 417 }
 418
 419 { .mfb
 420       nop.m 999
 421 (p9)  frcpa.s0 f8,p7=f8,f9
 422       br.ret.sptk   b0 ;;
 423 }
 424
 425
 426 FMOD_Y_NAN_INF_ZERO:
 427
 428 // Y INF
 429 { .mfi
 430       nop.m 999
 431       fclass.m.unc  p7,p0 = f9, 0x23
 432       nop.i 999 ;;
 433 }
 434
 435 { .mfb
 436       nop.m 999
 437 (p7)  fma.d.s0 f8=f8,f1,f0
 438 (p7)  br.ret.spnt    b0 ;;
 439 }
 440
 441 // Y NAN?
 442 { .mfi
 443       nop.m 999
 444       fclass.m.unc  p9,p0 = f9, 0xc3
 445       nop.i 999 ;;
 446 }
 447
 448 { .mfb
 449       nop.m 999
 450 (p9)  fma.d.s0 f8=f9,f1,f0
 451 (p9)  br.ret.spnt    b0 ;;
 452 }
 453
 454 FMOD_Y_ZERO:
 455 // Y zero? Must be zero at this point
 456 // because it is the only choice left.
 457 // Return QNAN indefinite
 458
 459 {.mfi
 460   nop.m 0
 461   // set Invalid
 462   frcpa.s0 f12,p0=f0,f0
 463   nop.i 0
 464 }
 465 // X NAN?
 466 { .mfi
 467       nop.m 999
 468       fclass.m.unc  p9,p10 = f8, 0xc3
 469       nop.i 999 ;;
 470 }
 471 { .mfi
 472       nop.m 999
 473 (p10)  fclass.nm  p9,p10 = f8, 0xff
 474       nop.i 999 ;;
 475 }
 476
 477 {.mfi
 478  nop.m 999
 479  (p9) frcpa.s0 f11,p7=f8,f0
 480  nop.i 0;;
 481 }
 482
 483 { .mfi
 484       nop.m 999
 485 (p10)  frcpa.s0         f11,p7 = f9,f9
 486       mov        GR_Parameter_TAG = 121 ;;
 487 }
 488
 489 { .mfi
 490       nop.m 999
 491       fmerge.s      f10 = f8, f8
 492       nop.i 999
 493 }
 494
 495 { .mfb
 496       nop.m 999
 497       fma.d.s0 f8=f11,f1,f0
 498       br.sptk __libm_error_region;;
 499 }
 500
 501 GLOBAL_IEEE754_END(fmod)
 502
 503 LOCAL_LIBM_ENTRY(__libm_error_region)
 504 .prologue
 505 { .mfi
 506         add   GR_Parameter_Y=-32,sp             // Parameter 2 value
 507         nop.f 0
 508 .save   ar.pfs,GR_SAVE_PFS
 509         mov  GR_SAVE_PFS=ar.pfs                 // Save ar.pfs
 510 }
 511 { .mfi
 512 .fframe 64
 513         add sp=-64,sp                           // Create new stack
 514         nop.f 0
 515         mov GR_SAVE_GP=gp                       // Save gp
 516 };;
 517 { .mmi
 518         stfd [GR_Parameter_Y] = FR_Y,16         // Save Parameter 2 on stack
 519         add GR_Parameter_X = 16,sp              // Parameter 1 address
 520 .save   b0, GR_SAVE_B0
 521         mov GR_SAVE_B0=b0                       // Save b0
 522 };;
 523 .body
 524 { .mib
 525         stfd [GR_Parameter_X] = FR_X            // Store Parameter 1 on stack
 526         add   GR_Parameter_RESULT = 0,GR_Parameter_Y
 527     nop.b 0                                 // Parameter 3 address
 528 }
 529 { .mib
 530         stfd [GR_Parameter_Y] = FR_RESULT      // Store Parameter 3 on stack
 531         add   GR_Parameter_Y = -16,GR_Parameter_Y
 532         br.call.sptk b0=__libm_error_support#  // Call error handling function
 533 };;
 534 { .mmi
 535         nop.m 0
 536         nop.m 0
 537         add   GR_Parameter_RESULT = 48,sp
 538 };;
 539 { .mmi
 540         ldfd  f8 = [GR_Parameter_RESULT]       // Get return result off stack
 541 .restore sp
 542         add   sp = 64,sp                       // Restore stack pointer
 543         mov   b0 = GR_SAVE_B0                  // Restore return address
 544 };;
 545 { .mib
 546         mov   gp = GR_SAVE_GP                  // Restore gp
 547         mov   ar.pfs = GR_SAVE_PFS             // Restore ar.pfs
 548         br.ret.sptk     b0                     // Return
 549 };;
 550
 551 LOCAL_LIBM_END(__libm_error_region)
 552
 553
 554 .type   __libm_error_support#,@function
 555 .global __libm_error_support#
 556
 557
 558
 559