sysdeps/x86_64/multiarch/memcpy.S

   1 /* Multiple versions of memcpy
   2    Copyright (C) 2010 Free Software Foundation, Inc.
   3    Contributed by Intel Corporation.
   4    This file is part of the GNU C Library.
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 #include <sysdep.h>
  22 #include <init-arch.h>
  23
  24 /* Define multiple versions only for the definition in lib and for
  25    DSO.  In static binaries we need memcpy before the initialization
  26    happened.  */
  27 #if defined SHARED && !defined NOT_IN_libc
  28         .text
  29 ENTRY(memcpy)
  30         .type   memcpy, @gnu_indirect_function
  31         cmpl    $0, KIND_OFFSET+__cpu_features(%rip)
  32         jne     1f
  33         call    __init_cpu_features
  34 1:      leaq    __memcpy_sse2(%rip), %rax
  35         testl   $bit_SSSE3, __cpu_features+CPUID_OFFSET+index_SSSE3(%rip)
  36         jz      2f
  37         leaq    __memcpy_ssse3(%rip), %rax
  38         testl   $bit_Fast_Copy_Backward, __cpu_features+FEATURE_OFFSET+index_Fast_Copy_Backward(%rip)
  39         jz      2f
  40         leaq    __memcpy_ssse3_back(%rip), %rax
  41 2:      ret
  42 END(memcpy)
  43
  44 # undef ENTRY
  45 # define ENTRY(name) \
  46         .type __memcpy_sse2, @function; \
  47         .p2align 4; \
  48         __memcpy_sse2: cfi_startproc; \
  49         CALL_MCOUNT
  50 # undef END
  51 # define END(name) \
  52         cfi_endproc; .size __memcpy_sse2, .-__memcpy_sse2
  53
  54 # undef ENTRY_CHK
  55 # define ENTRY_CHK(name) \
  56         .type __memcpy_chk_sse2, @function; \
  57         .globl __memcpy_chk_sse2; \
  58         .p2align 4; \
  59         __memcpy_chk_sse2: cfi_startproc; \
  60         CALL_MCOUNT
  61 # undef END_CHK
  62 # define END_CHK(name) \
  63         cfi_endproc; .size __memcpy_chk_sse2, .-__memcpy_chk_sse2
  64
  65 # undef libc_hidden_builtin_def
  66 /* It doesn't make sense to send libc-internal memcpy calls through a PLT.
  67    The speedup we get from using SSSE3 instruction is likely eaten away
  68    by the indirect call in the PLT.  */
  69 # define libc_hidden_builtin_def(name) \
  70         .globl __GI_memcpy; __GI_memcpy = __memcpy_sse2
  71 #endif
  72
  73 #include "../memcpy.S"