sysdeps/unix/sysv/linux/arm/clone.S

   1 /* Copyright (C) 1996, 1997, 1998, 1999, 2002, 2005, 2008, 2009, 2010
   2    Free Software Foundation, Inc.
   3    This file is part of the GNU C Library.
   4    Contributed by Pat Beirne <patb@corelcomputer.com>
   5
   6    The GNU C Library is free software; you can redistribute it and/or
   7    modify it under the terms of the GNU Lesser General Public
   8    License as published by the Free Software Foundation; either
   9    version 2.1 of the License, or (at your option) any later version.
  10
  11    The GNU C Library is distributed in the hope that it will be useful,
  12    but WITHOUT ANY WARRANTY; without even the implied warranty of
  13    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  14    Lesser General Public License for more details.
  15
  16    You should have received a copy of the GNU Lesser General Public
  17    License along with the GNU C Library; if not, write to the Free
  18    Software Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA
  19    02111-1307 USA.  */
  20
  21 /* clone() is even more special than fork() as it mucks with stacks
  22    and invokes a function in the right context after its all over.  */
  23
  24 #include <sysdep.h>
  25 #define _ERRNO_H        1
  26 #include <bits/errno.h>
  27
  28 #define CLONE_VM      0x00000100
  29 #define CLONE_THREAD  0x00010000
  30
  31 /* int clone(int (*fn)(void *arg), void *child_stack, int flags, void *arg,
  32              pid_t *ptid, struct user_desc *tls, pid_t *ctid); */
  33
  34         .text
  35 ENTRY(__clone)
  36         @ sanity check args
  37         cmp     r0, #0
  38         cmpne   r1, #0
  39         moveq   r0, #-EINVAL
  40         beq     PLTJMP(syscall_error)
  41
  42         @ insert the args onto the new stack
  43         str     r3, [r1, #-4]!
  44         str     r0, [r1, #-4]!
  45
  46         @ do the system call
  47         @ get flags
  48         mov     r0, r2
  49 #ifdef RESET_PID
  50         mov     ip, r2
  51 #endif
  52         @ new sp is already in r1
  53 #ifdef __ARM_EABI__
  54         stmfd   sp!, {r4, r7}
  55         cfi_adjust_cfa_offset (8)
  56         cfi_rel_offset (r4, 0)
  57         cfi_rel_offset (r7, 4)
  58 #else
  59         str     r4, [sp, #-8]!
  60         cfi_adjust_cfa_offset (8)
  61         cfi_rel_offset (r4, 0)
  62 #endif
  63         ldr     r2, [sp, #8]
  64         ldr     r3, [sp, #12]
  65         ldr     r4, [sp, #16]
  66 #ifdef __ARM_EABI__
  67         ldr     r7, =SYS_ify(clone)
  68         swi     0x0
  69 #else
  70         swi     SYS_ify(clone)
  71 #endif
  72         cfi_endproc
  73         cmp     r0, #0
  74         beq     1f
  75 #ifdef __ARM_EABI__
  76         ldmfd   sp!, {r4, r7}
  77 #else
  78         ldr     r4, [sp], #8
  79 #endif
  80         blt     PLTJMP(C_SYMBOL_NAME(__syscall_error))
  81         RETINSTR(, lr)
  82
  83         cfi_startproc
  84 PSEUDO_END (__clone)
  85
  86 1:
  87         .fnstart
  88         .cantunwind
  89 #ifdef RESET_PID
  90         tst     ip, #CLONE_THREAD
  91         bne     3f
  92         mov     r0, #0xffff0fff
  93         mov     lr, pc
  94         sub     pc, r0, #31
  95         mov     r1, r0
  96         tst     ip, #CLONE_VM
  97         movne   r0, #-1
  98 #ifdef __ARM_EABI__
  99         ldr     r7, =SYS_ify(getpid)
 100         swieq   0x0
 101 #else
 102         swieq   SYS_ify(getpid)
 103 #endif
 104         str     r0, [r1, #PID_OFFSET]
 105         str     r0, [r1, #TID_OFFSET]
 106 3:
 107 #endif
 108         @ pick the function arg and call address off the stack and execute
 109         ldr     r0, [sp, #4]
 110 #if defined(__ARM_ARCH_4T__) && defined(__THUMB_INTERWORK__)
 111         ldr     ip, [sp], #8
 112         mov     lr, pc
 113         bx      ip
 114 #else
 115         mov     lr, pc
 116         ldr     pc, [sp], #8
 117 #endif
 118
 119         @ and we are done, passing the return value through r0
 120         b       PLTJMP(HIDDEN_JUMPTARGET(_exit))
 121
 122         .fnend
 123
 124 weak_alias (__clone, clone)