gitweb/gitweb.perl

   1 #!/usr/bin/perl
   2
   3 # gitweb - simple web interface to track changes in git repositories
   4 #
   5 # (C) 2005-2006, Kay Sievers <kay.sievers@vrfy.org>
   6 # (C) 2005, Christian Gierke
   7 #
   8 # This program is licensed under the GPLv2
   9
  10 use strict;
  11 use warnings;
  12 use CGI qw(:standard :escapeHTML -nosticky);
  13 use CGI::Util qw(unescape);
  14 use CGI::Carp qw(fatalsToBrowser);
  15 use Encode;
  16 use Fcntl ':mode';
  17 use File::Find qw();
  18 use File::Basename qw(basename);
  19 binmode STDOUT, ':utf8';
  20
  21 our $t0;
  22 if (eval { require Time::HiRes; 1; }) {
  23         $t0 = [Time::HiRes::gettimeofday()];
  24 }
  25 our $number_of_git_cmds = 0;
  26
  27 BEGIN {
  28         CGI->compile() if $ENV{'MOD_PERL'};
  29 }
  30
  31 our $cgi = new CGI;
  32 our $version = "++GIT_VERSION++";
  33 our $my_url = $cgi->url();
  34 our $my_uri = $cgi->url(-absolute => 1);
  35
  36 # Base URL for relative URLs in gitweb ($logo, $favicon, ...),
  37 # needed and used only for URLs with nonempty PATH_INFO
  38 our $base_url = $my_url;
  39
  40 # When the script is used as DirectoryIndex, the URL does not contain the name
  41 # of the script file itself, and $cgi->url() fails to strip PATH_INFO, so we
  42 # have to do it ourselves. We make $path_info global because it's also used
  43 # later on.
  44 #
  45 # Another issue with the script being the DirectoryIndex is that the resulting
  46 # $my_url data is not the full script URL: this is good, because we want
  47 # generated links to keep implying the script name if it wasn't explicitly
  48 # indicated in the URL we're handling, but it means that $my_url cannot be used
  49 # as base URL.
  50 # Therefore, if we needed to strip PATH_INFO, then we know that we have
  51 # to build the base URL ourselves:
  52 our $path_info = $ENV{"PATH_INFO"};
  53 if ($path_info) {
  54         if ($my_url =~ s,\Q$path_info\E$,, &&
  55             $my_uri =~ s,\Q$path_info\E$,, &&
  56             defined $ENV{'SCRIPT_NAME'}) {
  57                 $base_url = $cgi->url(-base => 1) . $ENV{'SCRIPT_NAME'};
  58         }
  59 }
  60
  61 # core git executable to use
  62 # this can just be "git" if your webserver has a sensible PATH
  63 our $GIT = "++GIT_BINDIR++/git";
  64
  65 # absolute fs-path which will be prepended to the project path
  66 #our $projectroot = "/pub/scm";
  67 our $projectroot = "++GITWEB_PROJECTROOT++";
  68
  69 # fs traversing limit for getting project list
  70 # the number is relative to the projectroot
  71 our $project_maxdepth = "++GITWEB_PROJECT_MAXDEPTH++";
  72
  73 # target of the home link on top of all pages
  74 our $home_link = $my_uri || "/";
  75
  76 # string of the home link on top of all pages
  77 our $home_link_str = "++GITWEB_HOME_LINK_STR++";
  78
  79 # name of your site or organization to appear in page titles
  80 # replace this with something more descriptive for clearer bookmarks
  81 our $site_name = "++GITWEB_SITENAME++"
  82                  || ($ENV{'SERVER_NAME'} || "Untitled") . " Git";
  83
  84 # filename of html text to include at top of each page
  85 our $site_header = "++GITWEB_SITE_HEADER++";
  86 # html text to include at home page
  87 our $home_text = "++GITWEB_HOMETEXT++";
  88 # filename of html text to include at bottom of each page
  89 our $site_footer = "++GITWEB_SITE_FOOTER++";
  90
  91 # URI of stylesheets
  92 our @stylesheets = ("++GITWEB_CSS++");
  93 # URI of a single stylesheet, which can be overridden in GITWEB_CONFIG.
  94 our $stylesheet = undef;
  95 # URI of GIT logo (72x27 size)
  96 our $logo = "++GITWEB_LOGO++";
  97 # URI of GIT favicon, assumed to be image/png type
  98 our $favicon = "++GITWEB_FAVICON++";
  99 # URI of gitweb.js (JavaScript code for gitweb)
 100 our $javascript = "++GITWEB_JS++";
 101
 102 # URI and label (title) of GIT logo link
 103 #our $logo_url = "http://www.kernel.org/pub/software/scm/git/docs/";
 104 #our $logo_label = "git documentation";
 105 our $logo_url = "http://git-scm.com/";
 106 our $logo_label = "git homepage";
 107
 108 # source of projects list
 109 our $projects_list = "++GITWEB_LIST++";
 110
 111 # the width (in characters) of the projects list "Description" column
 112 our $projects_list_description_width = 25;
 113
 114 # default order of projects list
 115 # valid values are none, project, descr, owner, and age
 116 our $default_projects_order = "project";
 117
 118 # show repository only if this file exists
 119 # (only effective if this variable evaluates to true)
 120 our $export_ok = "++GITWEB_EXPORT_OK++";
 121
 122 # show repository only if this subroutine returns true
 123 # when given the path to the project, for example:
 124 #    sub { return -e "$_[0]/git-daemon-export-ok"; }
 125 our $export_auth_hook = undef;
 126
 127 # only allow viewing of repositories also shown on the overview page
 128 our $strict_export = "++GITWEB_STRICT_EXPORT++";
 129
 130 # list of git base URLs used for URL to where fetch project from,
 131 # i.e. full URL is "$git_base_url/$project"
 132 our @git_base_url_list = grep { $_ ne '' } ("++GITWEB_BASE_URL++");
 133
 134 # default blob_plain mimetype and default charset for text/plain blob
 135 our $default_blob_plain_mimetype = 'text/plain';
 136 our $default_text_plain_charset  = undef;
 137
 138 # file to use for guessing MIME types before trying /etc/mime.types
 139 # (relative to the current git repository)
 140 our $mimetypes_file = undef;
 141
 142 # assume this charset if line contains non-UTF-8 characters;
 143 # it should be valid encoding (see Encoding::Supported(3pm) for list),
 144 # for which encoding all byte sequences are valid, for example
 145 # 'iso-8859-1' aka 'latin1' (it is decoded without checking, so it
 146 # could be even 'utf-8' for the old behavior)
 147 our $fallback_encoding = 'latin1';
 148
 149 # rename detection options for git-diff and git-diff-tree
 150 # - default is '-M', with the cost proportional to
 151 #   (number of removed files) * (number of new files).
 152 # - more costly is '-C' (which implies '-M'), with the cost proportional to
 153 #   (number of changed files + number of removed files) * (number of new files)
 154 # - even more costly is '-C', '--find-copies-harder' with cost
 155 #   (number of files in the original tree) * (number of new files)
 156 # - one might want to include '-B' option, e.g. '-B', '-M'
 157 our @diff_opts = ('-M'); # taken from git_commit
 158
 159 # Disables features that would allow repository owners to inject script into
 160 # the gitweb domain.
 161 our $prevent_xss = 0;
 162
 163 # information about snapshot formats that gitweb is capable of serving
 164 our %known_snapshot_formats = (
 165         # name => {
 166         #       'display' => display name,
 167         #       'type' => mime type,
 168         #       'suffix' => filename suffix,
 169         #       'format' => --format for git-archive,
 170         #       'compressor' => [compressor command and arguments]
 171         #                       (array reference, optional)
 172         #       'disabled' => boolean (optional)}
 173         #
 174         'tgz' => {
 175                 'display' => 'tar.gz',
 176                 'type' => 'application/x-gzip',
 177                 'suffix' => '.tar.gz',
 178                 'format' => 'tar',
 179                 'compressor' => ['gzip']},
 180
 181         'tbz2' => {
 182                 'display' => 'tar.bz2',
 183                 'type' => 'application/x-bzip2',
 184                 'suffix' => '.tar.bz2',
 185                 'format' => 'tar',
 186                 'compressor' => ['bzip2']},
 187
 188         'txz' => {
 189                 'display' => 'tar.xz',
 190                 'type' => 'application/x-xz',
 191                 'suffix' => '.tar.xz',
 192                 'format' => 'tar',
 193                 'compressor' => ['xz'],
 194                 'disabled' => 1},
 195
 196         'zip' => {
 197                 'display' => 'zip',
 198                 'type' => 'application/x-zip',
 199                 'suffix' => '.zip',
 200                 'format' => 'zip'},
 201 );
 202
 203 # Aliases so we understand old gitweb.snapshot values in repository
 204 # configuration.
 205 our %known_snapshot_format_aliases = (
 206         'gzip'  => 'tgz',
 207         'bzip2' => 'tbz2',
 208         'xz'    => 'txz',
 209
 210         # backward compatibility: legacy gitweb config support
 211         'x-gzip' => undef, 'gz' => undef,
 212         'x-bzip2' => undef, 'bz2' => undef,
 213         'x-zip' => undef, '' => undef,
 214 );
 215
 216 # Pixel sizes for icons and avatars. If the default font sizes or lineheights
 217 # are changed, it may be appropriate to change these values too via
 218 # $GITWEB_CONFIG.
 219 our %avatar_size = (
 220         'default' => 16,
 221         'double'  => 32
 222 );
 223
 224 # Used to set the maximum load that we will still respond to gitweb queries.
 225 # If server load exceed this value then return "503 server busy" error.
 226 # If gitweb cannot determined server load, it is taken to be 0.
 227 # Leave it undefined (or set to 'undef') to turn off load checking.
 228 our $maxload = 300;
 229
 230 # This enables/disables the caching layer in gitweb.  Currently supported
 231 # is only output (response) caching, similar to the one used on git.kernel.org.
 232 our $caching_enabled = 0;
 233 # Set to _initialized_ instance of cache interface implementing (at least)
 234 # get($key) and set($key, $data) methods (Cache::Cache and CHI interfaces).
 235 # If unset, GitwebCache::SimpleFileCache would be used, which is 'dumb'
 236 # (but fast) file based caching layer, currently without any support for
 237 # cache size limiting.  It is therefore recommended that the cache directory
 238 # be periodically completely deleted; this operation is safe to perform.
 239 # Suggested mechanism:
 240 # mv $cachedir $cachedir.flush && mkdir $cachedir && rm -rf $cachedir.flush
 241 our $cache;
 242 # Locations of 'cache.pm' file; if it is relative path, it is relative to
 243 # the directory gitweb is run from
 244 our $cache_pm = 'cache.pm';
 245 # You define site-wide cache options defaults here; override them with
 246 # $GITWEB_CONFIG as necessary.
 247 our %cache_options = (
 248         # The location in the filesystem that will hold the root of the cache.
 249         # This directory will be created as needed (if possible) on the first
 250         # cache set.  Note that either this directory must exists and web server
 251         # has to have write permissions to it, or web server must be able to
 252         # create this directory.
 253         # Possible values:
 254         # * 'cache' (relative to gitweb),
 255         # * File::Spec->catdir(File::Spec->tmpdir(), 'gitweb-cache'),
 256         # * '/var/cache/gitweb' (FHS compliant, requires being set up),
 257         'cache_root' => 'cache',
 258         # The number of subdirectories deep to cache object item.  This should be
 259         # large enough that no cache directory has more than a few hundred
 260         # objects.  Each non-leaf directory contains up to 256 subdirectories
 261         # (00-ff).  Must be larger than 0.
 262         'cache_depth' => 1,
 263         # The (global) expiration time for objects placed in the cache, in seconds.
 264         'expires_in' => 20,
 265 );
 266
 267
 268 # You define site-wide feature defaults here; override them with
 269 # $GITWEB_CONFIG as necessary.
 270 our %feature = (
 271         # feature => {
 272         #       'sub' => feature-sub (subroutine),
 273         #       'override' => allow-override (boolean),
 274         #       'default' => [ default options...] (array reference)}
 275         #
 276         # if feature is overridable (it means that allow-override has true value),
 277         # then feature-sub will be called with default options as parameters;
 278         # return value of feature-sub indicates if to enable specified feature
 279         #
 280         # if there is no 'sub' key (no feature-sub), then feature cannot be
 281         # overriden
 282         #
 283         # use gitweb_get_feature(<feature>) to retrieve the <feature> value
 284         # (an array) or gitweb_check_feature(<feature>) to check if <feature>
 285         # is enabled
 286
 287         # Enable the 'blame' blob view, showing the last commit that modified
 288         # each line in the file. This can be very CPU-intensive.
 289
 290         # To enable system wide have in $GITWEB_CONFIG
 291         # $feature{'blame'}{'default'} = [1];
 292         # To have project specific config enable override in $GITWEB_CONFIG
 293         # $feature{'blame'}{'override'} = 1;
 294         # and in project config gitweb.blame = 0|1;
 295         'blame' => {
 296                 'sub' => sub { feature_bool('blame', @_) },
 297                 'override' => 0,
 298                 'default' => [0]},
 299
 300         # Enable the 'snapshot' link, providing a compressed archive of any
 301         # tree. This can potentially generate high traffic if you have large
 302         # project.
 303
 304         # Value is a list of formats defined in %known_snapshot_formats that
 305         # you wish to offer.
 306         # To disable system wide have in $GITWEB_CONFIG
 307         # $feature{'snapshot'}{'default'} = [];
 308         # To have project specific config enable override in $GITWEB_CONFIG
 309         # $feature{'snapshot'}{'override'} = 1;
 310         # and in project config, a comma-separated list of formats or "none"
 311         # to disable.  Example: gitweb.snapshot = tbz2,zip;
 312         'snapshot' => {
 313                 'sub' => \&feature_snapshot,
 314                 'override' => 0,
 315                 'default' => ['tgz']},
 316
 317         # Enable text search, which will list the commits which match author,
 318         # committer or commit text to a given string.  Enabled by default.
 319         # Project specific override is not supported.
 320         'search' => {
 321                 'override' => 0,
 322                 'default' => [1]},
 323
 324         # Enable grep search, which will list the files in currently selected
 325         # tree containing the given string. Enabled by default. This can be
 326         # potentially CPU-intensive, of course.
 327
 328         # To enable system wide have in $GITWEB_CONFIG
 329         # $feature{'grep'}{'default'} = [1];
 330         # To have project specific config enable override in $GITWEB_CONFIG
 331         # $feature{'grep'}{'override'} = 1;
 332         # and in project config gitweb.grep = 0|1;
 333         'grep' => {
 334                 'sub' => sub { feature_bool('grep', @_) },
 335                 'override' => 0,
 336                 'default' => [1]},
 337
 338         # Enable the pickaxe search, which will list the commits that modified
 339         # a given string in a file. This can be practical and quite faster
 340         # alternative to 'blame', but still potentially CPU-intensive.
 341
 342         # To enable system wide have in $GITWEB_CONFIG
 343         # $feature{'pickaxe'}{'default'} = [1];
 344         # To have project specific config enable override in $GITWEB_CONFIG
 345         # $feature{'pickaxe'}{'override'} = 1;
 346         # and in project config gitweb.pickaxe = 0|1;
 347         'pickaxe' => {
 348                 'sub' => sub { feature_bool('pickaxe', @_) },
 349                 'override' => 0,
 350                 'default' => [1]},
 351
 352         # Enable showing size of blobs in a 'tree' view, in a separate
 353         # column, similar to what 'ls -l' does.  This cost a bit of IO.
 354
 355         # To disable system wide have in $GITWEB_CONFIG
 356         # $feature{'show-sizes'}{'default'} = [0];
 357         # To have project specific config enable override in $GITWEB_CONFIG
 358         # $feature{'show-sizes'}{'override'} = 1;
 359         # and in project config gitweb.showsizes = 0|1;
 360         'show-sizes' => {
 361                 'sub' => sub { feature_bool('showsizes', @_) },
 362                 'override' => 0,
 363                 'default' => [1]},
 364
 365         # Make gitweb use an alternative format of the URLs which can be
 366         # more readable and natural-looking: project name is embedded
 367         # directly in the path and the query string contains other
 368         # auxiliary information. All gitweb installations recognize
 369         # URL in either format; this configures in which formats gitweb
 370         # generates links.
 371
 372         # To enable system wide have in $GITWEB_CONFIG
 373         # $feature{'pathinfo'}{'default'} = [1];
 374         # Project specific override is not supported.
 375
 376         # Note that you will need to change the default location of CSS,
 377         # favicon, logo and possibly other files to an absolute URL. Also,
 378         # if gitweb.cgi serves as your indexfile, you will need to force
 379         # $my_uri to contain the script name in your $GITWEB_CONFIG.
 380         'pathinfo' => {
 381                 'override' => 0,
 382                 'default' => [0]},
 383
 384         # Make gitweb consider projects in project root subdirectories
 385         # to be forks of existing projects. Given project $projname.git,
 386         # projects matching $projname/*.git will not be shown in the main
 387         # projects list, instead a '+' mark will be added to $projname
 388         # there and a 'forks' view will be enabled for the project, listing
 389         # all the forks. If project list is taken from a file, forks have
 390         # to be listed after the main project.
 391
 392         # To enable system wide have in $GITWEB_CONFIG
 393         # $feature{'forks'}{'default'} = [1];
 394         # Project specific override is not supported.
 395         'forks' => {
 396                 'override' => 0,
 397                 'default' => [0]},
 398
 399         # Insert custom links to the action bar of all project pages.
 400         # This enables you mainly to link to third-party scripts integrating
 401         # into gitweb; e.g. git-browser for graphical history representation
 402         # or custom web-based repository administration interface.
 403
 404         # The 'default' value consists of a list of triplets in the form
 405         # (label, link, position) where position is the label after which
 406         # to insert the link and link is a format string where %n expands
 407         # to the project name, %f to the project path within the filesystem,
 408         # %h to the current hash (h gitweb parameter) and %b to the current
 409         # hash base (hb gitweb parameter); %% expands to %.
 410
 411         # To enable system wide have in $GITWEB_CONFIG e.g.
 412         # $feature{'actions'}{'default'} = [('graphiclog',
 413         #       '/git-browser/by-commit.html?r=%n', 'summary')];
 414         # Project specific override is not supported.
 415         'actions' => {
 416                 'override' => 0,
 417                 'default' => []},
 418
 419         # Allow gitweb scan project content tags described in ctags/
 420         # of project repository, and display the popular Web 2.0-ish
 421         # "tag cloud" near the project list. Note that this is something
 422         # COMPLETELY different from the normal Git tags.
 423
 424         # gitweb by itself can show existing tags, but it does not handle
 425         # tagging itself; you need an external application for that.
 426         # For an example script, check Girocco's cgi/tagproj.cgi.
 427         # You may want to install the HTML::TagCloud Perl module to get
 428         # a pretty tag cloud instead of just a list of tags.
 429
 430         # To enable system wide have in $GITWEB_CONFIG
 431         # $feature{'ctags'}{'default'} = ['path_to_tag_script'];
 432         # Project specific override is not supported.
 433         'ctags' => {
 434                 'override' => 0,
 435                 'default' => [0]},
 436
 437         # The maximum number of patches in a patchset generated in patch
 438         # view. Set this to 0 or undef to disable patch view, or to a
 439         # negative number to remove any limit.
 440
 441         # To disable system wide have in $GITWEB_CONFIG
 442         # $feature{'patches'}{'default'} = [0];
 443         # To have project specific config enable override in $GITWEB_CONFIG
 444         # $feature{'patches'}{'override'} = 1;
 445         # and in project config gitweb.patches = 0|n;
 446         # where n is the maximum number of patches allowed in a patchset.
 447         'patches' => {
 448                 'sub' => \&feature_patches,
 449                 'override' => 0,
 450                 'default' => [16]},
 451
 452         # Avatar support. When this feature is enabled, views such as
 453         # shortlog or commit will display an avatar associated with
 454         # the email of the committer(s) and/or author(s).
 455
 456         # Currently available providers are gravatar and picon.
 457         # If an unknown provider is specified, the feature is disabled.
 458
 459         # Gravatar depends on Digest::MD5.
 460         # Picon currently relies on the indiana.edu database.
 461
 462         # To enable system wide have in $GITWEB_CONFIG
 463         # $feature{'avatar'}{'default'} = ['<provider>'];
 464         # where <provider> is either gravatar or picon.
 465         # To have project specific config enable override in $GITWEB_CONFIG
 466         # $feature{'avatar'}{'override'} = 1;
 467         # and in project config gitweb.avatar = <provider>;
 468         'avatar' => {
 469                 'sub' => \&feature_avatar,
 470                 'override' => 0,
 471                 'default' => ['']},
 472
 473         # Enable displaying how much time and how many git commands
 474         # it took to generate and display page.  Disabled by default.
 475         # Project specific override is not supported.
 476         'timed' => {
 477                 'override' => 0,
 478                 'default' => [0]},
 479
 480         # Enable turning some links into links to actions which require
 481         # JavaScript to run (like 'blame_incremental').  Not enabled by
 482         # default.  Project specific override is currently not supported.
 483         'javascript-actions' => {
 484                 'override' => 0,
 485                 'default' => [0]},
 486 );
 487
 488 sub gitweb_get_feature {
 489         my ($name) = @_;
 490         return unless exists $feature{$name};
 491         my ($sub, $override, @defaults) = (
 492                 $feature{$name}{'sub'},
 493                 $feature{$name}{'override'},
 494                 @{$feature{$name}{'default'}});
 495         if (!$override) { return @defaults; }
 496         if (!defined $sub) {
 497                 warn "feature $name is not overridable";
 498                 return @defaults;
 499         }
 500         return $sub->(@defaults);
 501 }
 502
 503 # A wrapper to check if a given feature is enabled.
 504 # With this, you can say
 505 #
 506 #   my $bool_feat = gitweb_check_feature('bool_feat');
 507 #   gitweb_check_feature('bool_feat') or somecode;
 508 #
 509 # instead of
 510 #
 511 #   my ($bool_feat) = gitweb_get_feature('bool_feat');
 512 #   (gitweb_get_feature('bool_feat'))[0] or somecode;
 513 #
 514 sub gitweb_check_feature {
 515         return (gitweb_get_feature(@_))[0];
 516 }
 517
 518
 519 sub feature_bool {
 520         my $key = shift;
 521         my ($val) = git_get_project_config($key, '--bool');
 522
 523         if (!defined $val) {
 524                 return ($_[0]);
 525         } elsif ($val eq 'true') {
 526                 return (1);
 527         } elsif ($val eq 'false') {
 528                 return (0);
 529         }
 530 }
 531
 532 sub feature_snapshot {
 533         my (@fmts) = @_;
 534
 535         my ($val) = git_get_project_config('snapshot');
 536
 537         if ($val) {
 538                 @fmts = ($val eq 'none' ? () : split /\s*[,\s]\s*/, $val);
 539         }
 540
 541         return @fmts;
 542 }
 543
 544 sub feature_patches {
 545         my @val = (git_get_project_config('patches', '--int'));
 546
 547         if (@val) {
 548                 return @val;
 549         }
 550
 551         return ($_[0]);
 552 }
 553
 554 sub feature_avatar {
 555         my @val = (git_get_project_config('avatar'));
 556
 557         return @val ? @val : @_;
 558 }
 559
 560 # checking HEAD file with -e is fragile if the repository was
 561 # initialized long time ago (i.e. symlink HEAD) and was pack-ref'ed
 562 # and then pruned.
 563 sub check_head_link {
 564         my ($dir) = @_;
 565         my $headfile = "$dir/HEAD";
 566         return ((-e $headfile) ||
 567                 (-l $headfile && readlink($headfile) =~ /^refs\/heads\//));
 568 }
 569
 570 sub check_export_ok {
 571         my ($dir) = @_;
 572         return (check_head_link($dir) &&
 573                 (!$export_ok || -e "$dir/$export_ok") &&
 574                 (!$export_auth_hook || $export_auth_hook->($dir)));
 575 }
 576
 577 # process alternate names for backward compatibility
 578 # filter out unsupported (unknown) snapshot formats
 579 sub filter_snapshot_fmts {
 580         my @fmts = @_;
 581
 582         @fmts = map {
 583                 exists $known_snapshot_format_aliases{$_} ?
 584                        $known_snapshot_format_aliases{$_} : $_} @fmts;
 585         @fmts = grep {
 586                 exists $known_snapshot_formats{$_} &&
 587                 !$known_snapshot_formats{$_}{'disabled'}} @fmts;
 588 }
 589
 590 our $GITWEB_CONFIG = $ENV{'GITWEB_CONFIG'} || "++GITWEB_CONFIG++";
 591 if (-e $GITWEB_CONFIG) {
 592         do $GITWEB_CONFIG;
 593 } else {
 594         our $GITWEB_CONFIG_SYSTEM = $ENV{'GITWEB_CONFIG_SYSTEM'} || "++GITWEB_CONFIG_SYSTEM++";
 595         do $GITWEB_CONFIG_SYSTEM if -e $GITWEB_CONFIG_SYSTEM;
 596 }
 597
 598 # Get loadavg of system, to compare against $maxload.
 599 # Currently it requires '/proc/loadavg' present to get loadavg;
 600 # if it is not present it returns 0, which means no load checking.
 601 sub get_loadavg {
 602         if( -e '/proc/loadavg' ){
 603                 open my $fd, '<', '/proc/loadavg'
 604                         or return 0;
 605                 my @load = split(/\s+/, scalar <$fd>);
 606                 close $fd;
 607
 608                 # The first three columns measure CPU and IO utilization of the last one,
 609                 # five, and 10 minute periods.  The fourth column shows the number of
 610                 # currently running processes and the total number of processes in the m/n
 611                 # format.  The last column displays the last process ID used.
 612                 return $load[0] || 0;
 613         }
 614         # additional checks for load average should go here for things that don't export
 615         # /proc/loadavg
 616
 617         return 0;
 618 }
 619
 620 # version of the core git binary
 621 our $git_version = qx("$GIT" --version) =~ m/git version (.*)$/ ? $1 : "unknown";
 622 $number_of_git_cmds++;
 623
 624 $projects_list ||= $projectroot;
 625
 626 if (defined $maxload && get_loadavg() > $maxload) {
 627         die_error(503, "The load average on the server is too high");
 628 }
 629
 630 # ======================================================================
 631 # input validation and dispatch
 632
 633 # input parameters can be collected from a variety of sources (presently, CGI
 634 # and PATH_INFO), so we define an %input_params hash that collects them all
 635 # together during validation: this allows subsequent uses (e.g. href()) to be
 636 # agnostic of the parameter origin
 637
 638 our %input_params = ();
 639
 640 # input parameters are stored with the long parameter name as key. This will
 641 # also be used in the href subroutine to convert parameters to their CGI
 642 # equivalent, and since the href() usage is the most frequent one, we store
 643 # the name -> CGI key mapping here, instead of the reverse.
 644 #
 645 # XXX: Warning: If you touch this, check the search form for updating,
 646 # too.
 647
 648 our @cgi_param_mapping = (
 649         project => "p",
 650         action => "a",
 651         file_name => "f",
 652         file_parent => "fp",
 653         hash => "h",
 654         hash_parent => "hp",
 655         hash_base => "hb",
 656         hash_parent_base => "hpb",
 657         page => "pg",
 658         order => "o",
 659         searchtext => "s",
 660         searchtype => "st",
 661         snapshot_format => "sf",
 662         extra_options => "opt",
 663         search_use_regexp => "sr",
 664         # this must be last entry (for manipulation from JavaScript)
 665         javascript => "js"
 666 );
 667 our %cgi_param_mapping = @cgi_param_mapping;
 668
 669 # we will also need to know the possible actions, for validation
 670 our %actions = (
 671         "blame" => \&git_blame,
 672         "blame_incremental" => \&git_blame_incremental,
 673         "blame_data" => \&git_blame_data,
 674         "blobdiff" => \&git_blobdiff,
 675         "blobdiff_plain" => \&git_blobdiff_plain,
 676         "blob" => \&git_blob,
 677         "blob_plain" => \&git_blob_plain,
 678         "commitdiff" => \&git_commitdiff,
 679         "commitdiff_plain" => \&git_commitdiff_plain,
 680         "commit" => \&git_commit,
 681         "forks" => \&git_forks,
 682         "heads" => \&git_heads,
 683         "history" => \&git_history,
 684         "log" => \&git_log,
 685         "patch" => \&git_patch,
 686         "patches" => \&git_patches,
 687         "rss" => \&git_rss,
 688         "atom" => \&git_atom,
 689         "search" => \&git_search,
 690         "search_help" => \&git_search_help,
 691         "shortlog" => \&git_shortlog,
 692         "summary" => \&git_summary,
 693         "tag" => \&git_tag,
 694         "tags" => \&git_tags,
 695         "tree" => \&git_tree,
 696         "snapshot" => \&git_snapshot,
 697         "object" => \&git_object,
 698         # those below don't need $project
 699         "opml" => \&git_opml,
 700         "project_list" => \&git_project_list,
 701         "project_index" => \&git_project_index,
 702 );
 703
 704 # finally, we have the hash of allowed extra_options for the commands that
 705 # allow them
 706 our %allowed_options = (
 707         "--no-merges" => [ qw(rss atom log shortlog history) ],
 708 );
 709
 710 # fill %input_params with the CGI parameters. All values except for 'opt'
 711 # should be single values, but opt can be an array. We should probably
 712 # build an array of parameters that can be multi-valued, but since for the time
 713 # being it's only this one, we just single it out
 714 while (my ($name, $symbol) = each %cgi_param_mapping) {
 715         if ($symbol eq 'opt') {
 716                 $input_params{$name} = [ $cgi->param($symbol) ];
 717         } else {
 718                 $input_params{$name} = $cgi->param($symbol);
 719         }
 720 }
 721
 722 # now read PATH_INFO and update the parameter list for missing parameters
 723 sub evaluate_path_info {
 724         return if defined $input_params{'project'};
 725         return if !$path_info;
 726         $path_info =~ s,^/+,,;
 727         return if !$path_info;
 728
 729         # find which part of PATH_INFO is project
 730         my $project = $path_info;
 731         $project =~ s,/+$,,;
 732         while ($project && !check_head_link("$projectroot/$project")) {
 733                 $project =~ s,/*[^/]*$,,;
 734         }
 735         return unless $project;
 736         $input_params{'project'} = $project;
 737
 738         # do not change any parameters if an action is given using the query string
 739         return if $input_params{'action'};
 740         $path_info =~ s,^\Q$project\E/*,,;
 741
 742         # next, check if we have an action
 743         my $action = $path_info;
 744         $action =~ s,/.*$,,;
 745         if (exists $actions{$action}) {
 746                 $path_info =~ s,^$action/*,,;
 747                 $input_params{'action'} = $action;
 748         }
 749
 750         # list of actions that want hash_base instead of hash, but can have no
 751         # pathname (f) parameter
 752         my @wants_base = (
 753                 'tree',
 754                 'history',
 755         );
 756
 757         # we want to catch
 758         # [$hash_parent_base[:$file_parent]..]$hash_parent[:$file_name]
 759         my ($parentrefname, $parentpathname, $refname, $pathname) =
 760                 ($path_info =~ /^(?:(.+?)(?::(.+))?\.\.)?(.+?)(?::(.+))?$/);
 761
 762         # first, analyze the 'current' part
 763         if (defined $pathname) {
 764                 # we got "branch:filename" or "branch:dir/"
 765                 # we could use git_get_type(branch:pathname), but:
 766                 # - it needs $git_dir
 767                 # - it does a git() call
 768                 # - the convention of terminating directories with a slash
 769                 #   makes it superfluous
 770                 # - embedding the action in the PATH_INFO would make it even
 771                 #   more superfluous
 772                 $pathname =~ s,^/+,,;
 773                 if (!$pathname || substr($pathname, -1) eq "/") {
 774                         $input_params{'action'} ||= "tree";
 775                         $pathname =~ s,/$,,;
 776                 } else {
 777                         # the default action depends on whether we had parent info
 778                         # or not
 779                         if ($parentrefname) {
 780                                 $input_params{'action'} ||= "blobdiff_plain";
 781                         } else {
 782                                 $input_params{'action'} ||= "blob_plain";
 783                         }
 784                 }
 785                 $input_params{'hash_base'} ||= $refname;
 786                 $input_params{'file_name'} ||= $pathname;
 787         } elsif (defined $refname) {
 788                 # we got "branch". In this case we have to choose if we have to
 789                 # set hash or hash_base.
 790                 #
 791                 # Most of the actions without a pathname only want hash to be
 792                 # set, except for the ones specified in @wants_base that want
 793                 # hash_base instead. It should also be noted that hand-crafted
 794                 # links having 'history' as an action and no pathname or hash
 795                 # set will fail, but that happens regardless of PATH_INFO.
 796                 $input_params{'action'} ||= "shortlog";
 797                 if (grep { $_ eq $input_params{'action'} } @wants_base) {
 798                         $input_params{'hash_base'} ||= $refname;
 799                 } else {
 800                         $input_params{'hash'} ||= $refname;
 801                 }
 802         }
 803
 804         # next, handle the 'parent' part, if present
 805         if (defined $parentrefname) {
 806                 # a missing pathspec defaults to the 'current' filename, allowing e.g.
 807                 # someproject/blobdiff/oldrev..newrev:/filename
 808                 if ($parentpathname) {
 809                         $parentpathname =~ s,^/+,,;
 810                         $parentpathname =~ s,/$,,;
 811                         $input_params{'file_parent'} ||= $parentpathname;
 812                 } else {
 813                         $input_params{'file_parent'} ||= $input_params{'file_name'};
 814                 }
 815                 # we assume that hash_parent_base is wanted if a path was specified,
 816                 # or if the action wants hash_base instead of hash
 817                 if (defined $input_params{'file_parent'} ||
 818                         grep { $_ eq $input_params{'action'} } @wants_base) {
 819                         $input_params{'hash_parent_base'} ||= $parentrefname;
 820                 } else {
 821                         $input_params{'hash_parent'} ||= $parentrefname;
 822                 }
 823         }
 824
 825         # for the snapshot action, we allow URLs in the form
 826         # $project/snapshot/$hash.ext
 827         # where .ext determines the snapshot and gets removed from the
 828         # passed $refname to provide the $hash.
 829         #
 830         # To be able to tell that $refname includes the format extension, we
 831         # require the following two conditions to be satisfied:
 832         # - the hash input parameter MUST have been set from the $refname part
 833         #   of the URL (i.e. they must be equal)
 834         # - the snapshot format MUST NOT have been defined already (e.g. from
 835         #   CGI parameter sf)
 836         # It's also useless to try any matching unless $refname has a dot,
 837         # so we check for that too
 838         if (defined $input_params{'action'} &&
 839                 $input_params{'action'} eq 'snapshot' &&
 840                 defined $refname && index($refname, '.') != -1 &&
 841                 $refname eq $input_params{'hash'} &&
 842                 !defined $input_params{'snapshot_format'}) {
 843                 # We loop over the known snapshot formats, checking for
 844                 # extensions. Allowed extensions are both the defined suffix
 845                 # (which includes the initial dot already) and the snapshot
 846                 # format key itself, with a prepended dot
 847                 while (my ($fmt, $opt) = each %known_snapshot_formats) {
 848                         my $hash = $refname;
 849                         unless ($hash =~ s/(\Q$opt->{'suffix'}\E|\Q.$fmt\E)$//) {
 850                                 next;
 851                         }
 852                         my $sfx = $1;
 853                         # a valid suffix was found, so set the snapshot format
 854                         # and reset the hash parameter
 855                         $input_params{'snapshot_format'} = $fmt;
 856                         $input_params{'hash'} = $hash;
 857                         # we also set the format suffix to the one requested
 858                         # in the URL: this way a request for e.g. .tgz returns
 859                         # a .tgz instead of a .tar.gz
 860                         $known_snapshot_formats{$fmt}{'suffix'} = $sfx;
 861                         last;
 862                 }
 863         }
 864 }
 865 evaluate_path_info();
 866
 867 our $action = $input_params{'action'};
 868 if (defined $action) {
 869         if (!validate_action($action)) {
 870                 die_error(400, "Invalid action parameter");
 871         }
 872 }
 873
 874 # parameters which are pathnames
 875 our $project = $input_params{'project'};
 876 if (defined $project) {
 877         if (!validate_project($project)) {
 878                 undef $project;
 879                 die_error(404, "No such project");
 880         }
 881 }
 882
 883 our $file_name = $input_params{'file_name'};
 884 if (defined $file_name) {
 885         if (!validate_pathname($file_name)) {
 886                 die_error(400, "Invalid file parameter");
 887         }
 888 }
 889
 890 our $file_parent = $input_params{'file_parent'};
 891 if (defined $file_parent) {
 892         if (!validate_pathname($file_parent)) {
 893                 die_error(400, "Invalid file parent parameter");
 894         }
 895 }
 896
 897 # parameters which are refnames
 898 our $hash = $input_params{'hash'};
 899 if (defined $hash) {
 900         if (!validate_refname($hash)) {
 901                 die_error(400, "Invalid hash parameter");
 902         }
 903 }
 904
 905 our $hash_parent = $input_params{'hash_parent'};
 906 if (defined $hash_parent) {
 907         if (!validate_refname($hash_parent)) {
 908                 die_error(400, "Invalid hash parent parameter");
 909         }
 910 }
 911
 912 our $hash_base = $input_params{'hash_base'};
 913 if (defined $hash_base) {
 914         if (!validate_refname($hash_base)) {
 915                 die_error(400, "Invalid hash base parameter");
 916         }
 917 }
 918
 919 our @extra_options = @{$input_params{'extra_options'}};
 920 # @extra_options is always defined, since it can only be (currently) set from
 921 # CGI, and $cgi->param() returns the empty array in array context if the param
 922 # is not set
 923 foreach my $opt (@extra_options) {
 924         if (not exists $allowed_options{$opt}) {
 925                 die_error(400, "Invalid option parameter");
 926         }
 927         if (not grep(/^$action$/, @{$allowed_options{$opt}})) {
 928                 die_error(400, "Invalid option parameter for this action");
 929         }
 930 }
 931
 932 our $hash_parent_base = $input_params{'hash_parent_base'};
 933 if (defined $hash_parent_base) {
 934         if (!validate_refname($hash_parent_base)) {
 935                 die_error(400, "Invalid hash parent base parameter");
 936         }
 937 }
 938
 939 # other parameters
 940 our $page = $input_params{'page'};
 941 if (defined $page) {
 942         if ($page =~ m/[^0-9]/) {
 943                 die_error(400, "Invalid page parameter");
 944         }
 945 }
 946
 947 our $searchtype = $input_params{'searchtype'};
 948 if (defined $searchtype) {
 949         if ($searchtype =~ m/[^a-z]/) {
 950                 die_error(400, "Invalid searchtype parameter");
 951         }
 952 }
 953
 954 our $search_use_regexp = $input_params{'search_use_regexp'};
 955
 956 our $searchtext = $input_params{'searchtext'};
 957 our $search_regexp;
 958 if (defined $searchtext) {
 959         if (length($searchtext) < 2) {
 960                 die_error(403, "At least two characters are required for search parameter");
 961         }
 962         $search_regexp = $search_use_regexp ? $searchtext : quotemeta $searchtext;
 963 }
 964
 965 # path to the current git repository
 966 our $git_dir;
 967 $git_dir = "$projectroot/$project" if $project;
 968
 969 # list of supported snapshot formats
 970 our @snapshot_fmts = gitweb_get_feature('snapshot');
 971 @snapshot_fmts = filter_snapshot_fmts(@snapshot_fmts);
 972
 973 # check that the avatar feature is set to a known provider name,
 974 # and for each provider check if the dependencies are satisfied.
 975 # if the provider name is invalid or the dependencies are not met,
 976 # reset $git_avatar to the empty string.
 977 our ($git_avatar) = gitweb_get_feature('avatar');
 978 if ($git_avatar eq 'gravatar') {
 979         $git_avatar = '' unless (eval { require Digest::MD5; 1; });
 980 } elsif ($git_avatar eq 'picon') {
 981         # no dependencies
 982 } else {
 983         $git_avatar = '';
 984 }
 985
 986 # dispatch
 987 if (!defined $action) {
 988         if (defined $hash) {
 989                 $action = git_get_type($hash);
 990         } elsif (defined $hash_base && defined $file_name) {
 991                 $action = git_get_type("$hash_base:$file_name");
 992         } elsif (defined $project) {
 993                 $action = 'summary';
 994         } else {
 995                 $action = 'project_list';
 996         }
 997 }
 998 if (!defined($actions{$action})) {
 999         die_error(400, "Unknown action");
1000 }
1001 if ($action !~ m/^(?:opml|project_list|project_index)$/ &&
1002     !$project) {
1003         die_error(400, "Project needed");
1004 }
1005
1006 if ($caching_enabled) {
1007         die_error(500, 'Caching enabled and "'.esc_path($cache_pm).'" not found')
1008                 unless -f $cache_pm;
1009         do $cache_pm;
1010         die $@ if $@;
1011
1012         # $cache might be initialized (instantiated) cache, i.e. cache object,
1013         # or it might be name of class, or it might be undefined
1014         unless (defined $cache && ref($cache)) {
1015                 $cache ||= 'GitwebCache::SimpleFileCache';
1016                 $cache = $cache->new({
1017                         %cache_options,
1018                         #'cache_root' => '/tmp/cache',
1019                         #'cache_depth' => 2,
1020                         #'expires_in' => 20, # in seconds (CHI compatibile)
1021                         # (Cache::Cache compatibile initialization)
1022                         'default_expires_in' => $cache_options{'expires_in'},
1023                         # (CHI compatibile initialization)
1024                         'root_dir' => $cache_options{'cache_root'},
1025                         'depth' => $cache_options{'cache_depth'},
1026                 });
1027         }
1028         cache_fetch($cache, $action);
1029 } else {
1030         $actions{$action}->();
1031 }
1032
1033 exit;
1034
1035 ## ======================================================================
1036 ## action links
1037
1038 # possible values of extra options
1039 # -full => 0|1      - use absolute/full URL ($my_uri/$my_url as base)
1040 # -replay => 1      - start from a current view (replay with modifications)
1041 # -path_info => 0|1 - don't use/use path_info URL (if possible)
1042 sub href {
1043         my %params = @_;
1044         # default is to use -absolute url() i.e. $my_uri
1045         my $href = $params{-full} ? $my_url : $my_uri;
1046
1047         $params{'project'} = $project unless exists $params{'project'};
1048
1049         if ($params{-replay}) {
1050                 while (my ($name, $symbol) = each %cgi_param_mapping) {
1051                         if (!exists $params{$name}) {
1052                                 $params{$name} = $input_params{$name};
1053                         }
1054                 }
1055         }
1056
1057         my $use_pathinfo = gitweb_check_feature('pathinfo');
1058         if (defined $params{'project'} &&
1059             (exists $params{-path_info} ? $params{-path_info} : $use_pathinfo)) {
1060                 # try to put as many parameters as possible in PATH_INFO:
1061                 #   - project name
1062                 #   - action
1063                 #   - hash_parent or hash_parent_base:/file_parent
1064                 #   - hash or hash_base:/filename
1065                 #   - the snapshot_format as an appropriate suffix
1066
1067                 # When the script is the root DirectoryIndex for the domain,
1068                 # $href here would be something like http://gitweb.example.com/
1069                 # Thus, we strip any trailing / from $href, to spare us double
1070                 # slashes in the final URL
1071                 $href =~ s,/$,,;
1072
1073                 # Then add the project name, if present
1074                 $href .= "/".esc_url($params{'project'});
1075                 delete $params{'project'};
1076
1077                 # since we destructively absorb parameters, we keep this
1078                 # boolean that remembers if we're handling a snapshot
1079                 my $is_snapshot = $params{'action'} eq 'snapshot';
1080
1081                 # Summary just uses the project path URL, any other action is
1082                 # added to the URL
1083                 if (defined $params{'action'}) {
1084                         $href .= "/".esc_url($params{'action'}) unless $params{'action'} eq 'summary';
1085                         delete $params{'action'};
1086                 }
1087
1088                 # Next, we put hash_parent_base:/file_parent..hash_base:/file_name,
1089                 # stripping nonexistent or useless pieces
1090                 $href .= "/" if ($params{'hash_base'} || $params{'hash_parent_base'}
1091                         || $params{'hash_parent'} || $params{'hash'});
1092                 if (defined $params{'hash_base'}) {
1093                         if (defined $params{'hash_parent_base'}) {
1094                                 $href .= esc_url($params{'hash_parent_base'});
1095                                 # skip the file_parent if it's the same as the file_name
1096                                 if (defined $params{'file_parent'}) {
1097                                         if (defined $params{'file_name'} && $params{'file_parent'} eq $params{'file_name'}) {
1098                                                 delete $params{'file_parent'};
1099                                         } elsif ($params{'file_parent'} !~ /\.\./) {
1100                                                 $href .= ":/".esc_url($params{'file_parent'});
1101                                                 delete $params{'file_parent'};
1102                                         }
1103                                 }
1104                                 $href .= "..";
1105                                 delete $params{'hash_parent'};
1106                                 delete $params{'hash_parent_base'};
1107                         } elsif (defined $params{'hash_parent'}) {
1108                                 $href .= esc_url($params{'hash_parent'}). "..";
1109                                 delete $params{'hash_parent'};
1110                         }
1111
1112                         $href .= esc_url($params{'hash_base'});
1113                         if (defined $params{'file_name'} && $params{'file_name'} !~ /\.\./) {
1114                                 $href .= ":/".esc_url($params{'file_name'});
1115                                 delete $params{'file_name'};
1116                         }
1117                         delete $params{'hash'};
1118                         delete $params{'hash_base'};
1119                 } elsif (defined $params{'hash'}) {
1120                         $href .= esc_url($params{'hash'});
1121                         delete $params{'hash'};
1122                 }
1123
1124                 # If the action was a snapshot, we can absorb the
1125                 # snapshot_format parameter too
1126                 if ($is_snapshot) {
1127                         my $fmt = $params{'snapshot_format'};
1128                         # snapshot_format should always be defined when href()
1129                         # is called, but just in case some code forgets, we
1130                         # fall back to the default
1131                         $fmt ||= $snapshot_fmts[0];
1132                         $href .= $known_snapshot_formats{$fmt}{'suffix'};
1133                         delete $params{'snapshot_format'};
1134                 }
1135         }
1136
1137         # now encode the parameters explicitly
1138         my @result = ();
1139         for (my $i = 0; $i < @cgi_param_mapping; $i += 2) {
1140                 my ($name, $symbol) = ($cgi_param_mapping[$i], $cgi_param_mapping[$i+1]);
1141                 if (defined $params{$name}) {
1142                         if (ref($params{$name}) eq "ARRAY") {
1143                                 foreach my $par (@{$params{$name}}) {
1144                                         push @result, $symbol . "=" . esc_param($par);
1145                                 }
1146                         } else {
1147                                 push @result, $symbol . "=" . esc_param($params{$name});
1148                         }
1149                 }
1150         }
1151         $href .= "?" . join(';', @result) if scalar @result;
1152
1153         return $href;
1154 }
1155
1156
1157 ## ======================================================================
1158 ## validation, quoting/unquoting and escaping
1159
1160 sub validate_action {
1161         my $input = shift || return undef;
1162         return undef unless exists $actions{$input};
1163         return $input;
1164 }
1165
1166 sub validate_project {
1167         my $input = shift || return undef;
1168         if (!validate_pathname($input) ||
1169                 !(-d "$projectroot/$input") ||
1170                 !check_export_ok("$projectroot/$input") ||
1171                 ($strict_export && !project_in_list($input))) {
1172                 return undef;
1173         } else {
1174                 return $input;
1175         }
1176 }
1177
1178 sub validate_pathname {
1179         my $input = shift || return undef;
1180
1181         # no '.' or '..' as elements of path, i.e. no '.' nor '..'
1182         # at the beginning, at the end, and between slashes.
1183         # also this catches doubled slashes
1184         if ($input =~ m!(^|/)(|\.|\.\.)(/|$)!) {
1185                 return undef;
1186         }
1187         # no null characters
1188         if ($input =~ m!\0!) {
1189                 return undef;
1190         }
1191         return $input;
1192 }
1193
1194 sub validate_refname {
1195         my $input = shift || return undef;
1196
1197         # textual hashes are O.K.
1198         if ($input =~ m/^[0-9a-fA-F]{40}$/) {
1199                 return $input;
1200         }
1201         # it must be correct pathname
1202         $input = validate_pathname($input)
1203                 or return undef;
1204         # restrictions on ref name according to git-check-ref-format
1205         if ($input =~ m!(/\.|\.\.|[\000-\040\177 ~^:?*\[]|/$)!) {
1206                 return undef;
1207         }
1208         return $input;
1209 }
1210
1211 # decode sequences of octets in utf8 into Perl's internal form,
1212 # which is utf-8 with utf8 flag set if needed.  gitweb writes out
1213 # in utf-8 thanks to "binmode STDOUT, ':utf8'" at beginning
1214 sub to_utf8 {
1215         my $str = shift;
1216         if (utf8::valid($str)) {
1217                 utf8::decode($str);
1218                 return $str;
1219         } else {
1220                 return decode($fallback_encoding, $str, Encode::FB_DEFAULT);
1221         }
1222 }
1223
1224 # quote unsafe chars, but keep the slash, even when it's not
1225 # correct, but quoted slashes look too horrible in bookmarks
1226 sub esc_param {
1227         my $str = shift;
1228         $str =~ s/([^A-Za-z0-9\-_.~()\/:@ ]+)/CGI::escape($1)/eg;
1229         $str =~ s/ /\+/g;
1230         return $str;
1231 }
1232
1233 # quote unsafe chars in whole URL, so some charactrs cannot be quoted
1234 sub esc_url {
1235         my $str = shift;
1236         $str =~ s/([^A-Za-z0-9\-_.~();\/;?:@&=])/sprintf("%%%02X", ord($1))/eg;
1237         $str =~ s/\+/%2B/g;
1238         $str =~ s/ /\+/g;
1239         return $str;
1240 }
1241
1242 # replace invalid utf8 character with SUBSTITUTION sequence
1243 sub esc_html {
1244         my $str = shift;
1245         my %opts = @_;
1246
1247         $str = to_utf8($str);
1248         $str = $cgi->escapeHTML($str);
1249         if ($opts{'-nbsp'}) {
1250                 $str =~ s/ /&nbsp;/g;
1251         }
1252         $str =~ s|([[:cntrl:]])|(($1 ne "\t") ? quot_cec($1) : $1)|eg;
1253         return $str;
1254 }
1255
1256 # quote control characters and escape filename to HTML
1257 sub esc_path {
1258         my $str = shift;
1259         my %opts = @_;
1260
1261         $str = to_utf8($str);
1262         $str = $cgi->escapeHTML($str);
1263         if ($opts{'-nbsp'}) {
1264                 $str =~ s/ /&nbsp;/g;
1265         }
1266         $str =~ s|([[:cntrl:]])|quot_cec($1)|eg;
1267         return $str;
1268 }
1269
1270 # Make control characters "printable", using character escape codes (CEC)
1271 sub quot_cec {
1272         my $cntrl = shift;
1273         my %opts = @_;
1274         my %es = ( # character escape codes, aka escape sequences
1275                 "\t" => '\t',   # tab            (HT)
1276                 "\n" => '\n',   # line feed      (LF)
1277                 "\r" => '\r',   # carrige return (CR)
1278                 "\f" => '\f',   # form feed      (FF)
1279                 "\b" => '\b',   # backspace      (BS)
1280                 "\a" => '\a',   # alarm (bell)   (BEL)
1281                 "\e" => '\e',   # escape         (ESC)
1282                 "\013" => '\v', # vertical tab   (VT)
1283                 "\000" => '\0', # nul character  (NUL)
1284         );
1285         my $chr = ( (exists $es{$cntrl})
1286                     ? $es{$cntrl}
1287                     : sprintf('\%2x', ord($cntrl)) );
1288         if ($opts{-nohtml}) {
1289                 return $chr;
1290         } else {
1291                 return "<span class=\"cntrl\">$chr</span>";
1292         }
1293 }
1294
1295 # Alternatively use unicode control pictures codepoints,
1296 # Unicode "printable representation" (PR)
1297 sub quot_upr {
1298         my $cntrl = shift;
1299         my %opts = @_;
1300
1301         my $chr = sprintf('&#%04d;', 0x2400+ord($cntrl));
1302         if ($opts{-nohtml}) {
1303                 return $chr;
1304         } else {
1305                 return "<span class=\"cntrl\">$chr</span>";
1306         }
1307 }
1308
1309 # git may return quoted and escaped filenames
1310 sub unquote {
1311         my $str = shift;
1312
1313         sub unq {
1314                 my $seq = shift;
1315                 my %es = ( # character escape codes, aka escape sequences
1316                         't' => "\t",   # tab            (HT, TAB)
1317                         'n' => "\n",   # newline        (NL)
1318                         'r' => "\r",   # return         (CR)
1319                         'f' => "\f",   # form feed      (FF)
1320                         'b' => "\b",   # backspace      (BS)
1321                         'a' => "\a",   # alarm (bell)   (BEL)
1322                         'e' => "\e",   # escape         (ESC)
1323                         'v' => "\013", # vertical tab   (VT)
1324                 );
1325
1326                 if ($seq =~ m/^[0-7]{1,3}$/) {
1327                         # octal char sequence
1328                         return chr(oct($seq));
1329                 } elsif (exists $es{$seq}) {
1330                         # C escape sequence, aka character escape code
1331                         return $es{$seq};
1332                 }
1333                 # quoted ordinary character
1334                 return $seq;
1335         }
1336
1337         if ($str =~ m/^"(.*)"$/) {
1338                 # needs unquoting
1339                 $str = $1;
1340                 $str =~ s/\\([^0-7]|[0-7]{1,3})/unq($1)/eg;
1341         }
1342         return $str;
1343 }
1344
1345 # escape tabs (convert tabs to spaces)
1346 sub untabify {
1347         my $line = shift;
1348
1349         while ((my $pos = index($line, "\t")) != -1) {
1350                 if (my $count = (8 - ($pos % 8))) {
1351                         my $spaces = ' ' x $count;
1352                         $line =~ s/\t/$spaces/;
1353                 }
1354         }
1355
1356         return $line;
1357 }
1358
1359 sub project_in_list {
1360         my $project = shift;
1361         my @list = git_get_projects_list();
1362         return @list && scalar(grep { $_->{'path'} eq $project } @list);
1363 }
1364
1365 ## ----------------------------------------------------------------------
1366 ## HTML aware string manipulation
1367
1368 # Try to chop given string on a word boundary between position
1369 # $len and $len+$add_len. If there is no word boundary there,
1370 # chop at $len+$add_len. Do not chop if chopped part plus ellipsis
1371 # (marking chopped part) would be longer than given string.
1372 sub chop_str {
1373         my $str = shift;
1374         my $len = shift;
1375         my $add_len = shift || 10;
1376         my $where = shift || 'right'; # 'left' | 'center' | 'right'
1377
1378         # Make sure perl knows it is utf8 encoded so we don't
1379         # cut in the middle of a utf8 multibyte char.
1380         $str = to_utf8($str);
1381
1382         # allow only $len chars, but don't cut a word if it would fit in $add_len
1383         # if it doesn't fit, cut it if it's still longer than the dots we would add
1384         # remove chopped character entities entirely
1385
1386         # when chopping in the middle, distribute $len into left and right part
1387         # return early if chopping wouldn't make string shorter
1388         if ($where eq 'center') {
1389                 return $str if ($len + 5 >= length($str)); # filler is length 5
1390                 $len = int($len/2);
1391         } else {
1392                 return $str if ($len + 4 >= length($str)); # filler is length 4
1393         }
1394
1395         # regexps: ending and beginning with word part up to $add_len
1396         my $endre = qr/.{$len}\w{0,$add_len}/;
1397         my $begre = qr/\w{0,$add_len}.{$len}/;
1398
1399         if ($where eq 'left') {
1400                 $str =~ m/^(.*?)($begre)$/;
1401                 my ($lead, $body) = ($1, $2);
1402                 if (length($lead) > 4) {
1403                         $lead = " ...";
1404                 }
1405                 return "$lead$body";
1406
1407         } elsif ($where eq 'center') {
1408                 $str =~ m/^($endre)(.*)$/;
1409                 my ($left, $str)  = ($1, $2);
1410                 $str =~ m/^(.*?)($begre)$/;
1411                 my ($mid, $right) = ($1, $2);
1412                 if (length($mid) > 5) {
1413                         $mid = " ... ";
1414                 }
1415                 return "$left$mid$right";
1416
1417         } else {
1418                 $str =~ m/^($endre)(.*)$/;
1419                 my $body = $1;
1420                 my $tail = $2;
1421                 if (length($tail) > 4) {
1422                         $tail = "... ";
1423                 }
1424                 return "$body$tail";
1425         }
1426 }
1427
1428 # takes the same arguments as chop_str, but also wraps a <span> around the
1429 # result with a title attribute if it does get chopped. Additionally, the
1430 # string is HTML-escaped.
1431 sub chop_and_escape_str {
1432         my ($str) = @_;
1433
1434         my $chopped = chop_str(@_);
1435         if ($chopped eq $str) {
1436                 return esc_html($chopped);
1437         } else {
1438                 $str =~ s/[[:cntrl:]]/?/g;
1439                 return $cgi->span({-title=>$str}, esc_html($chopped));
1440         }
1441 }
1442
1443 ## ----------------------------------------------------------------------
1444 ## functions returning short strings
1445
1446 # CSS class for given age value (in seconds)
1447 sub age_class {
1448         my $age = shift;
1449
1450         if (!defined $age) {
1451                 return "noage";
1452         } elsif ($age < 60*60*2) {
1453                 return "age0";
1454         } elsif ($age < 60*60*24*2) {
1455                 return "age1";
1456         } else {
1457                 return "age2";
1458         }
1459 }
1460
1461 # convert age in seconds to "nn units ago" string
1462 sub age_string {
1463         my $age = shift;
1464         my $age_str;
1465
1466         if ($age > 60*60*24*365*2) {
1467                 $age_str = (int $age/60/60/24/365);
1468                 $age_str .= " years ago";
1469         } elsif ($age > 60*60*24*(365/12)*2) {
1470                 $age_str = int $age/60/60/24/(365/12);
1471                 $age_str .= " months ago";
1472         } elsif ($age > 60*60*24*7*2) {
1473                 $age_str = int $age/60/60/24/7;
1474                 $age_str .= " weeks ago";
1475         } elsif ($age > 60*60*24*2) {
1476                 $age_str = int $age/60/60/24;
1477                 $age_str .= " days ago";
1478         } elsif ($age > 60*60*2) {
1479                 $age_str = int $age/60/60;
1480                 $age_str .= " hours ago";
1481         } elsif ($age > 60*2) {
1482                 $age_str = int $age/60;
1483                 $age_str .= " min ago";
1484         } elsif ($age > 2) {
1485                 $age_str = int $age;
1486                 $age_str .= " sec ago";
1487         } else {
1488                 $age_str .= " right now";
1489         }
1490         return $age_str;
1491 }
1492
1493 use constant {
1494         S_IFINVALID => 0030000,
1495         S_IFGITLINK => 0160000,
1496 };
1497
1498 # submodule/subproject, a commit object reference
1499 sub S_ISGITLINK {
1500         my $mode = shift;
1501
1502         return (($mode & S_IFMT) == S_IFGITLINK)
1503 }
1504
1505 # convert file mode in octal to symbolic file mode string
1506 sub mode_str {
1507         my $mode = oct shift;
1508
1509         if (S_ISGITLINK($mode)) {
1510                 return 'm---------';
1511         } elsif (S_ISDIR($mode & S_IFMT)) {
1512                 return 'drwxr-xr-x';
1513         } elsif (S_ISLNK($mode)) {
1514                 return 'lrwxrwxrwx';
1515         } elsif (S_ISREG($mode)) {
1516                 # git cares only about the executable bit
1517                 if ($mode & S_IXUSR) {
1518                         return '-rwxr-xr-x';
1519                 } else {
1520                         return '-rw-r--r--';
1521                 };
1522         } else {
1523                 return '----------';
1524         }
1525 }
1526
1527 # convert file mode in octal to file type string
1528 sub file_type {
1529         my $mode = shift;
1530
1531         if ($mode !~ m/^[0-7]+$/) {
1532                 return $mode;
1533         } else {
1534                 $mode = oct $mode;
1535         }
1536
1537         if (S_ISGITLINK($mode)) {
1538                 return "submodule";
1539         } elsif (S_ISDIR($mode & S_IFMT)) {
1540                 return "directory";
1541         } elsif (S_ISLNK($mode)) {
1542                 return "symlink";
1543         } elsif (S_ISREG($mode)) {
1544                 return "file";
1545         } else {
1546                 return "unknown";
1547         }
1548 }
1549
1550 # convert file mode in octal to file type description string
1551 sub file_type_long {
1552         my $mode = shift;
1553
1554         if ($mode !~ m/^[0-7]+$/) {
1555                 return $mode;
1556         } else {
1557                 $mode = oct $mode;
1558         }
1559
1560         if (S_ISGITLINK($mode)) {
1561                 return "submodule";
1562         } elsif (S_ISDIR($mode & S_IFMT)) {
1563                 return "directory";
1564         } elsif (S_ISLNK($mode)) {
1565                 return "symlink";
1566         } elsif (S_ISREG($mode)) {
1567                 if ($mode & S_IXUSR) {
1568                         return "executable";
1569                 } else {
1570                         return "file";
1571                 };
1572         } else {
1573                 return "unknown";
1574         }
1575 }
1576
1577
1578 ## ----------------------------------------------------------------------
1579 ## functions returning short HTML fragments, or transforming HTML fragments
1580 ## which don't belong to other sections
1581
1582 # format line of commit message.
1583 sub format_log_line_html {
1584         my $line = shift;
1585
1586         $line = esc_html($line, -nbsp=>1);
1587         $line =~ s{\b([0-9a-fA-F]{8,40})\b}{
1588                 $cgi->a({-href => href(action=>"object", hash=>$1),
1589                                         -class => "text"}, $1);
1590         }eg;
1591
1592         return $line;
1593 }
1594
1595 # format marker of refs pointing to given object
1596
1597 # the destination action is chosen based on object type and current context:
1598 # - for annotated tags, we choose the tag view unless it's the current view
1599 #   already, in which case we go to shortlog view
1600 # - for other refs, we keep the current view if we're in history, shortlog or
1601 #   log view, and select shortlog otherwise
1602 sub format_ref_marker {
1603         my ($refs, $id) = @_;
1604         my $markers = '';
1605
1606         if (defined $refs->{$id}) {
1607                 foreach my $ref (@{$refs->{$id}}) {
1608                         # this code exploits the fact that non-lightweight tags are the
1609                         # only indirect objects, and that they are the only objects for which
1610                         # we want to use tag instead of shortlog as action
1611                         my ($type, $name) = qw();
1612                         my $indirect = ($ref =~ s/\^\{\}$//);
1613                         # e.g. tags/v2.6.11 or heads/next
1614                         if ($ref =~ m!^(.*?)s?/(.*)$!) {
1615                                 $type = $1;
1616                                 $name = $2;
1617                         } else {
1618                                 $type = "ref";
1619                                 $name = $ref;
1620                         }
1621
1622                         my $class = $type;
1623                         $class .= " indirect" if $indirect;
1624
1625                         my $dest_action = "shortlog";
1626
1627                         if ($indirect) {
1628                                 $dest_action = "tag" unless $action eq "tag";
1629                         } elsif ($action =~ /^(history|(short)?log)$/) {
1630                                 $dest_action = $action;
1631                         }
1632
1633                         my $dest = "";
1634                         $dest .= "refs/" unless $ref =~ m!^refs/!;
1635                         $dest .= $ref;
1636
1637                         my $link = $cgi->a({
1638                                 -href => href(
1639                                         action=>$dest_action,
1640                                         hash=>$dest
1641                                 )}, $name);
1642
1643                         $markers .= " <span class=\"$class\" title=\"$ref\">" .
1644                                 $link . "</span>";
1645                 }
1646         }
1647
1648         if ($markers) {
1649                 return ' <span class="refs">'. $markers . '</span>';
1650         } else {
1651                 return "";
1652         }
1653 }
1654
1655 # format, perhaps shortened and with markers, title line
1656 sub format_subject_html {
1657         my ($long, $short, $href, $extra) = @_;
1658         $extra = '' unless defined($extra);
1659
1660         if (length($short) < length($long)) {
1661                 $long =~ s/[[:cntrl:]]/?/g;
1662                 return $cgi->a({-href => $href, -class => "list subject",
1663                                 -title => to_utf8($long)},
1664                        esc_html($short)) . $extra;
1665         } else {
1666                 return $cgi->a({-href => $href, -class => "list subject"},
1667                        esc_html($long)) . $extra;
1668         }
1669 }
1670
1671 # Rather than recomputing the url for an email multiple times, we cache it
1672 # after the first hit. This gives a visible benefit in views where the avatar
1673 # for the same email is used repeatedly (e.g. shortlog).
1674 # The cache is shared by all avatar engines (currently gravatar only), which
1675 # are free to use it as preferred. Since only one avatar engine is used for any
1676 # given page, there's no risk for cache conflicts.
1677 our %avatar_cache = ();
1678
1679 # Compute the picon url for a given email, by using the picon search service over at
1680 # http://www.cs.indiana.edu/picons/search.html
1681 sub picon_url {
1682         my $email = lc shift;
1683         if (!$avatar_cache{$email}) {
1684                 my ($user, $domain) = split('@', $email);
1685                 $avatar_cache{$email} =
1686                         "http://www.cs.indiana.edu/cgi-pub/kinzler/piconsearch.cgi/" .
1687                         "$domain/$user/" .
1688                         "users+domains+unknown/up/single";
1689         }
1690         return $avatar_cache{$email};
1691 }
1692
1693 # Compute the gravatar url for a given email, if it's not in the cache already.
1694 # Gravatar stores only the part of the URL before the size, since that's the
1695 # one computationally more expensive. This also allows reuse of the cache for
1696 # different sizes (for this particular engine).
1697 sub gravatar_url {
1698         my $email = lc shift;
1699         my $size = shift;
1700         $avatar_cache{$email} ||=
1701                 "http://www.gravatar.com/avatar/" .
1702                         Digest::MD5::md5_hex($email) . "?s=";
1703         return $avatar_cache{$email} . $size;
1704 }
1705
1706 # Insert an avatar for the given $email at the given $size if the feature
1707 # is enabled.
1708 sub git_get_avatar {
1709         my ($email, %opts) = @_;
1710         my $pre_white  = ($opts{-pad_before} ? "&nbsp;" : "");
1711         my $post_white = ($opts{-pad_after}  ? "&nbsp;" : "");
1712         $opts{-size} ||= 'default';
1713         my $size = $avatar_size{$opts{-size}} || $avatar_size{'default'};
1714         my $url = "";
1715         if ($git_avatar eq 'gravatar') {
1716                 $url = gravatar_url($email, $size);
1717         } elsif ($git_avatar eq 'picon') {
1718                 $url = picon_url($email);
1719         }
1720         # Other providers can be added by extending the if chain, defining $url
1721         # as needed. If no variant puts something in $url, we assume avatars
1722         # are completely disabled/unavailable.
1723         if ($url) {
1724                 return $pre_white .
1725                        "<img width=\"$size\" " .
1726                             "class=\"avatar\" " .
1727                             "src=\"$url\" " .
1728                             "alt=\"\" " .
1729                        "/>" . $post_white;
1730         } else {
1731                 return "";
1732         }
1733 }
1734
1735 sub format_search_author {
1736         my ($author, $searchtype, $displaytext) = @_;
1737         my $have_search = gitweb_check_feature('search');
1738
1739         if ($have_search) {
1740                 my $performed = "";
1741                 if ($searchtype eq 'author') {
1742                         $performed = "authored";
1743                 } elsif ($searchtype eq 'committer') {
1744                         $performed = "committed";
1745                 }
1746
1747                 return $cgi->a({-href => href(action=>"search", hash=>$hash,
1748                                 searchtext=>$author,
1749                                 searchtype=>$searchtype), class=>"list",
1750                                 title=>"Search for commits $performed by $author"},
1751                                 $displaytext);
1752
1753         } else {
1754                 return $displaytext;
1755         }
1756 }
1757
1758 # format the author name of the given commit with the given tag
1759 # the author name is chopped and escaped according to the other
1760 # optional parameters (see chop_str).
1761 sub format_author_html {
1762         my $tag = shift;
1763         my $co = shift;
1764         my $author = chop_and_escape_str($co->{'author_name'}, @_);
1765         return "<$tag class=\"author\">" .
1766                format_search_author($co->{'author_name'}, "author",
1767                        git_get_avatar($co->{'author_email'}, -pad_after => 1) .
1768                        $author) .
1769                "</$tag>";
1770 }
1771
1772 # format git diff header line, i.e. "diff --(git|combined|cc) ..."
1773 sub format_git_diff_header_line {
1774         my $line = shift;
1775         my $diffinfo = shift;
1776         my ($from, $to) = @_;
1777
1778         if ($diffinfo->{'nparents'}) {
1779                 # combined diff
1780                 $line =~ s!^(diff (.*?) )"?.*$!$1!;
1781                 if ($to->{'href'}) {
1782                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1783                                          esc_path($to->{'file'}));
1784                 } else { # file was deleted (no href)
1785                         $line .= esc_path($to->{'file'});
1786                 }
1787         } else {
1788                 # "ordinary" diff
1789                 $line =~ s!^(diff (.*?) )"?a/.*$!$1!;
1790                 if ($from->{'href'}) {
1791                         $line .= $cgi->a({-href => $from->{'href'}, -class => "path"},
1792                                          'a/' . esc_path($from->{'file'}));
1793                 } else { # file was added (no href)
1794                         $line .= 'a/' . esc_path($from->{'file'});
1795                 }
1796                 $line .= ' ';
1797                 if ($to->{'href'}) {
1798                         $line .= $cgi->a({-href => $to->{'href'}, -class => "path"},
1799                                          'b/' . esc_path($to->{'file'}));
1800                 } else { # file was deleted
1801                         $line .= 'b/' . esc_path($to->{'file'});
1802                 }
1803         }
1804
1805         return "<div class=\"diff header\">$line</div>\n";
1806 }
1807
1808 # format extended diff header line, before patch itself
1809 sub format_extended_diff_header_line {
1810         my $line = shift;
1811         my $diffinfo = shift;
1812         my ($from, $to) = @_;
1813
1814         # match <path>
1815         if ($line =~ s!^((copy|rename) from ).*$!$1! && $from->{'href'}) {
1816                 $line .= $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1817                                        esc_path($from->{'file'}));
1818         }
1819         if ($line =~ s!^((copy|rename) to ).*$!$1! && $to->{'href'}) {
1820                 $line .= $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1821                                  esc_path($to->{'file'}));
1822         }
1823         # match single <mode>
1824         if ($line =~ m/\s(\d{6})$/) {
1825                 $line .= '<span class="info"> (' .
1826                          file_type_long($1) .
1827                          ')</span>';
1828         }
1829         # match <hash>
1830         if ($line =~ m/^index [0-9a-fA-F]{40},[0-9a-fA-F]{40}/) {
1831                 # can match only for combined diff
1832                 $line = 'index ';
1833                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1834                         if ($from->{'href'}[$i]) {
1835                                 $line .= $cgi->a({-href=>$from->{'href'}[$i],
1836                                                   -class=>"hash"},
1837                                                  substr($diffinfo->{'from_id'}[$i],0,7));
1838                         } else {
1839                                 $line .= '0' x 7;
1840                         }
1841                         # separator
1842                         $line .= ',' if ($i < $diffinfo->{'nparents'} - 1);
1843                 }
1844                 $line .= '..';
1845                 if ($to->{'href'}) {
1846                         $line .= $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1847                                          substr($diffinfo->{'to_id'},0,7));
1848                 } else {
1849                         $line .= '0' x 7;
1850                 }
1851
1852         } elsif ($line =~ m/^index [0-9a-fA-F]{40}..[0-9a-fA-F]{40}/) {
1853                 # can match only for ordinary diff
1854                 my ($from_link, $to_link);
1855                 if ($from->{'href'}) {
1856                         $from_link = $cgi->a({-href=>$from->{'href'}, -class=>"hash"},
1857                                              substr($diffinfo->{'from_id'},0,7));
1858                 } else {
1859                         $from_link = '0' x 7;
1860                 }
1861                 if ($to->{'href'}) {
1862                         $to_link = $cgi->a({-href=>$to->{'href'}, -class=>"hash"},
1863                                            substr($diffinfo->{'to_id'},0,7));
1864                 } else {
1865                         $to_link = '0' x 7;
1866                 }
1867                 my ($from_id, $to_id) = ($diffinfo->{'from_id'}, $diffinfo->{'to_id'});
1868                 $line =~ s!$from_id\.\.$to_id!$from_link..$to_link!;
1869         }
1870
1871         return $line . "<br/>\n";
1872 }
1873
1874 # format from-file/to-file diff header
1875 sub format_diff_from_to_header {
1876         my ($from_line, $to_line, $diffinfo, $from, $to, @parents) = @_;
1877         my $line;
1878         my $result = '';
1879
1880         $line = $from_line;
1881         #assert($line =~ m/^---/) if DEBUG;
1882         # no extra formatting for "^--- /dev/null"
1883         if (! $diffinfo->{'nparents'}) {
1884                 # ordinary (single parent) diff
1885                 if ($line =~ m!^--- "?a/!) {
1886                         if ($from->{'href'}) {
1887                                 $line = '--- a/' .
1888                                         $cgi->a({-href=>$from->{'href'}, -class=>"path"},
1889                                                 esc_path($from->{'file'}));
1890                         } else {
1891                                 $line = '--- a/' .
1892                                         esc_path($from->{'file'});
1893                         }
1894                 }
1895                 $result .= qq!<div class="diff from_file">$line</div>\n!;
1896
1897         } else {
1898                 # combined diff (merge commit)
1899                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
1900                         if ($from->{'href'}[$i]) {
1901                                 $line = '--- ' .
1902                                         $cgi->a({-href=>href(action=>"blobdiff",
1903                                                              hash_parent=>$diffinfo->{'from_id'}[$i],
1904                                                              hash_parent_base=>$parents[$i],
1905                                                              file_parent=>$from->{'file'}[$i],
1906                                                              hash=>$diffinfo->{'to_id'},
1907                                                              hash_base=>$hash,
1908                                                              file_name=>$to->{'file'}),
1909                                                  -class=>"path",
1910                                                  -title=>"diff" . ($i+1)},
1911                                                 $i+1) .
1912                                         '/' .
1913                                         $cgi->a({-href=>$from->{'href'}[$i], -class=>"path"},
1914                                                 esc_path($from->{'file'}[$i]));
1915                         } else {
1916                                 $line = '--- /dev/null';
1917                         }
1918                         $result .= qq!<div class="diff from_file">$line</div>\n!;
1919                 }
1920         }
1921
1922         $line = $to_line;
1923         #assert($line =~ m/^\+\+\+/) if DEBUG;
1924         # no extra formatting for "^+++ /dev/null"
1925         if ($line =~ m!^\+\+\+ "?b/!) {
1926                 if ($to->{'href'}) {
1927                         $line = '+++ b/' .
1928                                 $cgi->a({-href=>$to->{'href'}, -class=>"path"},
1929                                         esc_path($to->{'file'}));
1930                 } else {
1931                         $line = '+++ b/' .
1932                                 esc_path($to->{'file'});
1933                 }
1934         }
1935         $result .= qq!<div class="diff to_file">$line</div>\n!;
1936
1937         return $result;
1938 }
1939
1940 # create note for patch simplified by combined diff
1941 sub format_diff_cc_simplified {
1942         my ($diffinfo, @parents) = @_;
1943         my $result = '';
1944
1945         $result .= "<div class=\"diff header\">" .
1946                    "diff --cc ";
1947         if (!is_deleted($diffinfo)) {
1948                 $result .= $cgi->a({-href => href(action=>"blob",
1949                                                   hash_base=>$hash,
1950                                                   hash=>$diffinfo->{'to_id'},
1951                                                   file_name=>$diffinfo->{'to_file'}),
1952                                     -class => "path"},
1953                                    esc_path($diffinfo->{'to_file'}));
1954         } else {
1955                 $result .= esc_path($diffinfo->{'to_file'});
1956         }
1957         $result .= "</div>\n" . # class="diff header"
1958                    "<div class=\"diff nodifferences\">" .
1959                    "Simple merge" .
1960                    "</div>\n"; # class="diff nodifferences"
1961
1962         return $result;
1963 }
1964
1965 # format patch (diff) line (not to be used for diff headers)
1966 sub format_diff_line {
1967         my $line = shift;
1968         my ($from, $to) = @_;
1969         my $diff_class = "";
1970
1971         chomp $line;
1972
1973         if ($from && $to && ref($from->{'href'}) eq "ARRAY") {
1974                 # combined diff
1975                 my $prefix = substr($line, 0, scalar @{$from->{'href'}});
1976                 if ($line =~ m/^\@{3}/) {
1977                         $diff_class = " chunk_header";
1978                 } elsif ($line =~ m/^\\/) {
1979                         $diff_class = " incomplete";
1980                 } elsif ($prefix =~ tr/+/+/) {
1981                         $diff_class = " add";
1982                 } elsif ($prefix =~ tr/-/-/) {
1983                         $diff_class = " rem";
1984                 }
1985         } else {
1986                 # assume ordinary diff
1987                 my $char = substr($line, 0, 1);
1988                 if ($char eq '+') {
1989                         $diff_class = " add";
1990                 } elsif ($char eq '-') {
1991                         $diff_class = " rem";
1992                 } elsif ($char eq '@') {
1993                         $diff_class = " chunk_header";
1994                 } elsif ($char eq "\\") {
1995                         $diff_class = " incomplete";
1996                 }
1997         }
1998         $line = untabify($line);
1999         if ($from && $to && $line =~ m/^\@{2} /) {
2000                 my ($from_text, $from_start, $from_lines, $to_text, $to_start, $to_lines, $section) =
2001                         $line =~ m/^\@{2} (-(\d+)(?:,(\d+))?) (\+(\d+)(?:,(\d+))?) \@{2}(.*)$/;
2002
2003                 $from_lines = 0 unless defined $from_lines;
2004                 $to_lines   = 0 unless defined $to_lines;
2005
2006                 if ($from->{'href'}) {
2007                         $from_text = $cgi->a({-href=>"$from->{'href'}#l$from_start",
2008                                              -class=>"list"}, $from_text);
2009                 }
2010                 if ($to->{'href'}) {
2011                         $to_text   = $cgi->a({-href=>"$to->{'href'}#l$to_start",
2012                                              -class=>"list"}, $to_text);
2013                 }
2014                 $line = "<span class=\"chunk_info\">@@ $from_text $to_text @@</span>" .
2015                         "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2016                 return "<div class=\"diff$diff_class\">$line</div>\n";
2017         } elsif ($from && $to && $line =~ m/^\@{3}/) {
2018                 my ($prefix, $ranges, $section) = $line =~ m/^(\@+) (.*?) \@+(.*)$/;
2019                 my (@from_text, @from_start, @from_nlines, $to_text, $to_start, $to_nlines);
2020
2021                 @from_text = split(' ', $ranges);
2022                 for (my $i = 0; $i < @from_text; ++$i) {
2023                         ($from_start[$i], $from_nlines[$i]) =
2024                                 (split(',', substr($from_text[$i], 1)), 0);
2025                 }
2026
2027                 $to_text   = pop @from_text;
2028                 $to_start  = pop @from_start;
2029                 $to_nlines = pop @from_nlines;
2030
2031                 $line = "<span class=\"chunk_info\">$prefix ";
2032                 for (my $i = 0; $i < @from_text; ++$i) {
2033                         if ($from->{'href'}[$i]) {
2034                                 $line .= $cgi->a({-href=>"$from->{'href'}[$i]#l$from_start[$i]",
2035                                                   -class=>"list"}, $from_text[$i]);
2036                         } else {
2037                                 $line .= $from_text[$i];
2038                         }
2039                         $line .= " ";
2040                 }
2041                 if ($to->{'href'}) {
2042                         $line .= $cgi->a({-href=>"$to->{'href'}#l$to_start",
2043                                           -class=>"list"}, $to_text);
2044                 } else {
2045                         $line .= $to_text;
2046                 }
2047                 $line .= " $prefix</span>" .
2048                          "<span class=\"section\">" . esc_html($section, -nbsp=>1) . "</span>";
2049                 return "<div class=\"diff$diff_class\">$line</div>\n";
2050         }
2051         return "<div class=\"diff$diff_class\">" . esc_html($line, -nbsp=>1) . "</div>\n";
2052 }
2053
2054 # Generates undef or something like "_snapshot_" or "snapshot (_tbz2_ _zip_)",
2055 # linked.  Pass the hash of the tree/commit to snapshot.
2056 sub format_snapshot_links {
2057         my ($hash) = @_;
2058         my $num_fmts = @snapshot_fmts;
2059         if ($num_fmts > 1) {
2060                 # A parenthesized list of links bearing format names.
2061                 # e.g. "snapshot (_tar.gz_ _zip_)"
2062                 return "snapshot (" . join(' ', map
2063                         $cgi->a({
2064                                 -href => href(
2065                                         action=>"snapshot",
2066                                         hash=>$hash,
2067                                         snapshot_format=>$_
2068                                 )
2069                         }, $known_snapshot_formats{$_}{'display'})
2070                 , @snapshot_fmts) . ")";
2071         } elsif ($num_fmts == 1) {
2072                 # A single "snapshot" link whose tooltip bears the format name.
2073                 # i.e. "_snapshot_"
2074                 my ($fmt) = @snapshot_fmts;
2075                 return
2076                         $cgi->a({
2077                                 -href => href(
2078                                         action=>"snapshot",
2079                                         hash=>$hash,
2080                                         snapshot_format=>$fmt
2081                                 ),
2082                                 -title => "in format: $known_snapshot_formats{$fmt}{'display'}"
2083                         }, "snapshot");
2084         } else { # $num_fmts == 0
2085                 return undef;
2086         }
2087 }
2088
2089 ## ......................................................................
2090 ## functions returning values to be passed, perhaps after some
2091 ## transformation, to other functions; e.g. returning arguments to href()
2092
2093 # returns hash to be passed to href to generate gitweb URL
2094 # in -title key it returns description of link
2095 sub get_feed_info {
2096         my $format = shift || 'Atom';
2097         my %res = (action => lc($format));
2098
2099         # feed links are possible only for project views
2100         return unless (defined $project);
2101         # some views should link to OPML, or to generic project feed,
2102         # or don't have specific feed yet (so they should use generic)
2103         return if ($action =~ /^(?:tags|heads|forks|tag|search)$/x);
2104
2105         my $branch;
2106         # branches refs uses 'refs/heads/' prefix (fullname) to differentiate
2107         # from tag links; this also makes possible to detect branch links
2108         if ((defined $hash_base && $hash_base =~ m!^refs/heads/(.*)$!) ||
2109             (defined $hash      && $hash      =~ m!^refs/heads/(.*)$!)) {
2110                 $branch = $1;
2111         }
2112         # find log type for feed description (title)
2113         my $type = 'log';
2114         if (defined $file_name) {
2115                 $type  = "history of $file_name";
2116                 $type .= "/" if ($action eq 'tree');
2117                 $type .= " on '$branch'" if (defined $branch);
2118         } else {
2119                 $type = "log of $branch" if (defined $branch);
2120         }
2121
2122         $res{-title} = $type;
2123         $res{'hash'} = (defined $branch ? "refs/heads/$branch" : undef);
2124         $res{'file_name'} = $file_name;
2125
2126         return %res;
2127 }
2128
2129 ## ----------------------------------------------------------------------
2130 ## git utility subroutines, invoking git commands
2131
2132 # returns path to the core git executable and the --git-dir parameter as list
2133 sub git_cmd {
2134         $number_of_git_cmds++;
2135         return $GIT, '--git-dir='.$git_dir;
2136 }
2137
2138 # quote the given arguments for passing them to the shell
2139 # quote_command("command", "arg 1", "arg with ' and ! characters")
2140 # => "'command' 'arg 1' 'arg with '\'' and '\!' characters'"
2141 # Try to avoid using this function wherever possible.
2142 sub quote_command {
2143         return join(' ',
2144                 map { my $a = $_; $a =~ s/(['!])/'\\$1'/g; "'$a'" } @_ );
2145 }
2146
2147 # get HEAD ref of given project as hash
2148 sub git_get_head_hash {
2149         return git_get_full_hash(shift, 'HEAD');
2150 }
2151
2152 sub git_get_full_hash {
2153         return git_get_hash(@_);
2154 }
2155
2156 sub git_get_short_hash {
2157         return git_get_hash(@_, '--short=7');
2158 }
2159
2160 sub git_get_hash {
2161         my ($project, $hash, @options) = @_;
2162         my $o_git_dir = $git_dir;
2163         my $retval = undef;
2164         $git_dir = "$projectroot/$project";
2165         if (open my $fd, '-|', git_cmd(), 'rev-parse',
2166             '--verify', '-q', @options, $hash) {
2167                 $retval = <$fd>;
2168                 chomp $retval if defined $retval;
2169                 close $fd;
2170         }
2171         if (defined $o_git_dir) {
2172                 $git_dir = $o_git_dir;
2173         }
2174         return $retval;
2175 }
2176
2177 # get type of given object
2178 sub git_get_type {
2179         my $hash = shift;
2180
2181         open my $fd, "-|", git_cmd(), "cat-file", '-t', $hash or return;
2182         my $type = <$fd>;
2183         close $fd or return;
2184         chomp $type;
2185         return $type;
2186 }
2187
2188 # repository configuration
2189 our $config_file = '';
2190 our %config;
2191
2192 # store multiple values for single key as anonymous array reference
2193 # single values stored directly in the hash, not as [ <value> ]
2194 sub hash_set_multi {
2195         my ($hash, $key, $value) = @_;
2196
2197         if (!exists $hash->{$key}) {
2198                 $hash->{$key} = $value;
2199         } elsif (!ref $hash->{$key}) {
2200                 $hash->{$key} = [ $hash->{$key}, $value ];
2201         } else {
2202                 push @{$hash->{$key}}, $value;
2203         }
2204 }
2205
2206 # return hash of git project configuration
2207 # optionally limited to some section, e.g. 'gitweb'
2208 sub git_parse_project_config {
2209         my $section_regexp = shift;
2210         my %config;
2211
2212         local $/ = "\0";
2213
2214         open my $fh, "-|", git_cmd(), "config", '-z', '-l',
2215                 or return;
2216
2217         while (my $keyval = <$fh>) {
2218                 chomp $keyval;
2219                 my ($key, $value) = split(/\n/, $keyval, 2);
2220
2221                 hash_set_multi(\%config, $key, $value)
2222                         if (!defined $section_regexp || $key =~ /^(?:$section_regexp)\./o);
2223         }
2224         close $fh;
2225
2226         return %config;
2227 }
2228
2229 # convert config value to boolean: 'true' or 'false'
2230 # no value, number > 0, 'true' and 'yes' values are true
2231 # rest of values are treated as false (never as error)
2232 sub config_to_bool {
2233         my $val = shift;
2234
2235         return 1 if !defined $val;             # section.key
2236
2237         # strip leading and trailing whitespace
2238         $val =~ s/^\s+//;
2239         $val =~ s/\s+$//;
2240
2241         return (($val =~ /^\d+$/ && $val) ||   # section.key = 1
2242                 ($val =~ /^(?:true|yes)$/i));  # section.key = true
2243 }
2244
2245 # convert config value to simple decimal number
2246 # an optional value suffix of 'k', 'm', or 'g' will cause the value
2247 # to be multiplied by 1024, 1048576, or 1073741824
2248 sub config_to_int {
2249         my $val = shift;
2250
2251         # strip leading and trailing whitespace
2252         $val =~ s/^\s+//;
2253         $val =~ s/\s+$//;
2254
2255         if (my ($num, $unit) = ($val =~ /^([0-9]*)([kmg])$/i)) {
2256                 $unit = lc($unit);
2257                 # unknown unit is treated as 1
2258                 return $num * ($unit eq 'g' ? 1073741824 :
2259                                $unit eq 'm' ?    1048576 :
2260                                $unit eq 'k' ?       1024 : 1);
2261         }
2262         return $val;
2263 }
2264
2265 # convert config value to array reference, if needed
2266 sub config_to_multi {
2267         my $val = shift;
2268
2269         return ref($val) ? $val : (defined($val) ? [ $val ] : []);
2270 }
2271
2272 sub git_get_project_config {
2273         my ($key, $type) = @_;
2274
2275         # key sanity check
2276         return unless ($key);
2277         $key =~ s/^gitweb\.//;
2278         return if ($key =~ m/\W/);
2279
2280         # type sanity check
2281         if (defined $type) {
2282                 $type =~ s/^--//;
2283                 $type = undef
2284                         unless ($type eq 'bool' || $type eq 'int');
2285         }
2286
2287         # get config
2288         if (!defined $config_file ||
2289             $config_file ne "$git_dir/config") {
2290                 %config = git_parse_project_config('gitweb');
2291                 $config_file = "$git_dir/config";
2292         }
2293
2294         # check if config variable (key) exists
2295         return unless exists $config{"gitweb.$key"};
2296
2297         # ensure given type
2298         if (!defined $type) {
2299                 return $config{"gitweb.$key"};
2300         } elsif ($type eq 'bool') {
2301                 # backward compatibility: 'git config --bool' returns true/false
2302                 return config_to_bool($config{"gitweb.$key"}) ? 'true' : 'false';
2303         } elsif ($type eq 'int') {
2304                 return config_to_int($config{"gitweb.$key"});
2305         }
2306         return $config{"gitweb.$key"};
2307 }
2308
2309 # get hash of given path at given ref
2310 sub git_get_hash_by_path {
2311         my $base = shift;
2312         my $path = shift || return undef;
2313         my $type = shift;
2314
2315         $path =~ s,/+$,,;
2316
2317         open my $fd, "-|", git_cmd(), "ls-tree", $base, "--", $path
2318                 or die_error(500, "Open git-ls-tree failed");
2319         my $line = <$fd>;
2320         close $fd or return undef;
2321
2322         if (!defined $line) {
2323                 # there is no tree or hash given by $path at $base
2324                 return undef;
2325         }
2326
2327         #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2328         $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/;
2329         if (defined $type && $type ne $2) {
2330                 # type doesn't match
2331                 return undef;
2332         }
2333         return $3;
2334 }
2335
2336 # get path of entry with given hash at given tree-ish (ref)
2337 # used to get 'from' filename for combined diff (merge commit) for renames
2338 sub git_get_path_by_hash {
2339         my $base = shift || return;
2340         my $hash = shift || return;
2341
2342         local $/ = "\0";
2343
2344         open my $fd, "-|", git_cmd(), "ls-tree", '-r', '-t', '-z', $base
2345                 or return undef;
2346         while (my $line = <$fd>) {
2347                 chomp $line;
2348
2349                 #'040000 tree 595596a6a9117ddba9fe379b6b012b558bac8423  gitweb'
2350                 #'100644 blob e02e90f0429be0d2a69b76571101f20b8f75530f  gitweb/README'
2351                 if ($line =~ m/(?:[0-9]+) (?:.+) $hash\t(.+)$/) {
2352                         close $fd;
2353                         return $1;
2354                 }
2355         }
2356         close $fd;
2357         return undef;
2358 }
2359
2360 ## ......................................................................
2361 ## git utility functions, directly accessing git repository
2362
2363 sub git_get_project_description {
2364         my $path = shift;
2365
2366         $git_dir = "$projectroot/$path";
2367         open my $fd, '<', "$git_dir/description"
2368                 or return git_get_project_config('description');
2369         my $descr = <$fd>;
2370         close $fd;
2371         if (defined $descr) {
2372                 chomp $descr;
2373         }
2374         return $descr;
2375 }
2376
2377 sub git_get_project_ctags {
2378         my $path = shift;
2379         my $ctags = {};
2380
2381         $git_dir = "$projectroot/$path";
2382         opendir my $dh, "$git_dir/ctags"
2383                 or return $ctags;
2384         foreach (grep { -f $_ } map { "$git_dir/ctags/$_" } readdir($dh)) {
2385                 open my $ct, '<', $_ or next;
2386                 my $val = <$ct>;
2387                 chomp $val;
2388                 close $ct;
2389                 my $ctag = $_; $ctag =~ s#.*/##;
2390                 $ctags->{$ctag} = $val;
2391         }
2392         closedir $dh;
2393         $ctags;
2394 }
2395
2396 sub git_populate_project_tagcloud {
2397         my $ctags = shift;
2398
2399         # First, merge different-cased tags; tags vote on casing
2400         my %ctags_lc;
2401         foreach (keys %$ctags) {
2402                 $ctags_lc{lc $_}->{count} += $ctags->{$_};
2403                 if (not $ctags_lc{lc $_}->{topcount}
2404                     or $ctags_lc{lc $_}->{topcount} < $ctags->{$_}) {
2405                         $ctags_lc{lc $_}->{topcount} = $ctags->{$_};
2406                         $ctags_lc{lc $_}->{topname} = $_;
2407                 }
2408         }
2409
2410         my $cloud;
2411         if (eval { require HTML::TagCloud; 1; }) {
2412                 $cloud = HTML::TagCloud->new;
2413                 foreach (sort keys %ctags_lc) {
2414                         # Pad the title with spaces so that the cloud looks
2415                         # less crammed.
2416                         my $title = $ctags_lc{$_}->{topname};
2417                         $title =~ s/ /&nbsp;/g;
2418                         $title =~ s/^/&nbsp;/g;
2419                         $title =~ s/$/&nbsp;/g;
2420                         $cloud->add($title, $home_link."?by_tag=".$_, $ctags_lc{$_}->{count});
2421                 }
2422         } else {
2423                 $cloud = \%ctags_lc;
2424         }
2425         $cloud;
2426 }
2427
2428 sub git_show_project_tagcloud {
2429         my ($cloud, $count) = @_;
2430         print STDERR ref($cloud)."..\n";
2431         if (ref $cloud eq 'HTML::TagCloud') {
2432                 return $cloud->html_and_css($count);
2433         } else {
2434                 my @tags = sort { $cloud->{$a}->{count} <=> $cloud->{$b}->{count} } keys %$cloud;
2435                 return '<p align="center">' . join (', ', map {
2436                         "<a href=\"$home_link?by_tag=$_\">$cloud->{$_}->{topname}</a>"
2437                 } splice(@tags, 0, $count)) . '</p>';
2438         }
2439 }
2440
2441 sub git_get_project_url_list {
2442         my $path = shift;
2443
2444         $git_dir = "$projectroot/$path";
2445         open my $fd, '<', "$git_dir/cloneurl"
2446                 or return wantarray ?
2447                 @{ config_to_multi(git_get_project_config('url')) } :
2448                    config_to_multi(git_get_project_config('url'));
2449         my @git_project_url_list = map { chomp; $_ } <$fd>;
2450         close $fd;
2451
2452         return wantarray ? @git_project_url_list : \@git_project_url_list;
2453 }
2454
2455 sub git_get_projects_list {
2456         my ($filter) = @_;
2457         my @list;
2458
2459         $filter ||= '';
2460         $filter =~ s/\.git$//;
2461
2462         my $check_forks = gitweb_check_feature('forks');
2463
2464         if (-d $projects_list) {
2465                 # search in directory
2466                 my $dir = $projects_list . ($filter ? "/$filter" : '');
2467                 # remove the trailing "/"
2468                 $dir =~ s!/+$!!;
2469                 my $pfxlen = length("$dir");
2470                 my $pfxdepth = ($dir =~ tr!/!!);
2471
2472                 File::Find::find({
2473                         follow_fast => 1, # follow symbolic links
2474                         follow_skip => 2, # ignore duplicates
2475                         dangling_symlinks => 0, # ignore dangling symlinks, silently
2476                         wanted => sub {
2477                                 # skip project-list toplevel, if we get it.
2478                                 return if (m!^[/.]$!);
2479                                 # only directories can be git repositories
2480                                 return unless (-d $_);
2481                                 # don't traverse too deep (Find is super slow on os x)
2482                                 if (($File::Find::name =~ tr!/!!) - $pfxdepth > $project_maxdepth) {
2483                                         $File::Find::prune = 1;
2484                                         return;
2485                                 }
2486
2487                                 my $subdir = substr($File::Find::name, $pfxlen + 1);
2488                                 # we check related file in $projectroot
2489                                 my $path = ($filter ? "$filter/" : '') . $subdir;
2490                                 if (check_export_ok("$projectroot/$path")) {
2491                                         push @list, { path => $path };
2492                                         $File::Find::prune = 1;
2493                                 }
2494                         },
2495                 }, "$dir");
2496
2497         } elsif (-f $projects_list) {
2498                 # read from file(url-encoded):
2499                 # 'git%2Fgit.git Linus+Torvalds'
2500                 # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2501                 # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2502                 my %paths;
2503                 open my $fd, '<', $projects_list or return;
2504         PROJECT:
2505                 while (my $line = <$fd>) {
2506                         chomp $line;
2507                         my ($path, $owner) = split ' ', $line;
2508                         $path = unescape($path);
2509                         $owner = unescape($owner);
2510                         if (!defined $path) {
2511                                 next;
2512                         }
2513                         if ($filter ne '') {
2514                                 # looking for forks;
2515                                 my $pfx = substr($path, 0, length($filter));
2516                                 if ($pfx ne $filter) {
2517                                         next PROJECT;
2518                                 }
2519                                 my $sfx = substr($path, length($filter));
2520                                 if ($sfx !~ /^\/.*\.git$/) {
2521                                         next PROJECT;
2522                                 }
2523                         } elsif ($check_forks) {
2524                         PATH:
2525                                 foreach my $filter (keys %paths) {
2526                                         # looking for forks;
2527                                         my $pfx = substr($path, 0, length($filter));
2528                                         if ($pfx ne $filter) {
2529                                                 next PATH;
2530                                         }
2531                                         my $sfx = substr($path, length($filter));
2532                                         if ($sfx !~ /^\/.*\.git$/) {
2533                                                 next PATH;
2534                                         }
2535                                         # is a fork, don't include it in
2536                                         # the list
2537                                         next PROJECT;
2538                                 }
2539                         }
2540                         if (check_export_ok("$projectroot/$path")) {
2541                                 my $pr = {
2542                                         path => $path,
2543                                         owner => to_utf8($owner),
2544                                 };
2545                                 push @list, $pr;
2546                                 (my $forks_path = $path) =~ s/\.git$//;
2547                                 $paths{$forks_path}++;
2548                         }
2549                 }
2550                 close $fd;
2551         }
2552         return @list;
2553 }
2554
2555 our $gitweb_project_owner = undef;
2556 sub git_get_project_list_from_file {
2557
2558         return if (defined $gitweb_project_owner);
2559
2560         $gitweb_project_owner = {};
2561         # read from file (url-encoded):
2562         # 'git%2Fgit.git Linus+Torvalds'
2563         # 'libs%2Fklibc%2Fklibc.git H.+Peter+Anvin'
2564         # 'linux%2Fhotplug%2Fudev.git Greg+Kroah-Hartman'
2565         if (-f $projects_list) {
2566                 open(my $fd, '<', $projects_list);
2567                 while (my $line = <$fd>) {
2568                         chomp $line;
2569                         my ($pr, $ow) = split ' ', $line;
2570                         $pr = unescape($pr);
2571                         $ow = unescape($ow);
2572                         $gitweb_project_owner->{$pr} = to_utf8($ow);
2573                 }
2574                 close $fd;
2575         }
2576 }
2577
2578 sub git_get_project_owner {
2579         my $project = shift;
2580         my $owner;
2581
2582         return undef unless $project;
2583         $git_dir = "$projectroot/$project";
2584
2585         if (!defined $gitweb_project_owner) {
2586                 git_get_project_list_from_file();
2587         }
2588
2589         if (exists $gitweb_project_owner->{$project}) {
2590                 $owner = $gitweb_project_owner->{$project};
2591         }
2592         if (!defined $owner){
2593                 $owner = git_get_project_config('owner');
2594         }
2595         if (!defined $owner) {
2596                 $owner = get_file_owner("$git_dir");
2597         }
2598
2599         return $owner;
2600 }
2601
2602 sub git_get_last_activity {
2603         my ($path) = @_;
2604         my $fd;
2605
2606         $git_dir = "$projectroot/$path";
2607         open($fd, "-|", git_cmd(), 'for-each-ref',
2608              '--format=%(committer)',
2609              '--sort=-committerdate',
2610              '--count=1',
2611              'refs/heads') or return;
2612         my $most_recent = <$fd>;
2613         close $fd or return;
2614         if (defined $most_recent &&
2615             $most_recent =~ / (\d+) [-+][01]\d\d\d$/) {
2616                 my $timestamp = $1;
2617                 my $age = time - $timestamp;
2618                 return ($age, age_string($age));
2619         }
2620         return (undef, undef);
2621 }
2622
2623 sub git_get_references {
2624         my $type = shift || "";
2625         my %refs;
2626         # 5dc01c595e6c6ec9ccda4f6f69c131c0dd945f8c refs/tags/v2.6.11
2627         # c39ae07f393806ccf406ef966e9a15afc43cc36a refs/tags/v2.6.11^{}
2628         open my $fd, "-|", git_cmd(), "show-ref", "--dereference",
2629                 ($type ? ("--", "refs/$type") : ()) # use -- <pattern> if $type
2630                 or return;
2631
2632         while (my $line = <$fd>) {
2633                 chomp $line;
2634                 if ($line =~ m!^([0-9a-fA-F]{40})\srefs/($type.*)$!) {
2635                         if (defined $refs{$1}) {
2636                                 push @{$refs{$1}}, $2;
2637                         } else {
2638                                 $refs{$1} = [ $2 ];
2639                         }
2640                 }
2641         }
2642         close $fd or return;
2643         return \%refs;
2644 }
2645
2646 sub git_get_rev_name_tags {
2647         my $hash = shift || return undef;
2648
2649         open my $fd, "-|", git_cmd(), "name-rev", "--tags", $hash
2650                 or return;
2651         my $name_rev = <$fd>;
2652         close $fd;
2653
2654         if ($name_rev =~ m|^$hash tags/(.*)$|) {
2655                 return $1;
2656         } else {
2657                 # catches also '$hash undefined' output
2658                 return undef;
2659         }
2660 }
2661
2662 ## ----------------------------------------------------------------------
2663 ## parse to hash functions
2664
2665 sub parse_date {
2666         my $epoch = shift;
2667         my $tz = shift || "-0000";
2668
2669         my %date;
2670         my @months = ("Jan", "Feb", "Mar", "Apr", "May", "Jun", "Jul", "Aug", "Sep", "Oct", "Nov", "Dec");
2671         my @days = ("Sun", "Mon", "Tue", "Wed", "Thu", "Fri", "Sat");
2672         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($epoch);
2673         $date{'hour'} = $hour;
2674         $date{'minute'} = $min;
2675         $date{'mday'} = $mday;
2676         $date{'day'} = $days[$wday];
2677         $date{'month'} = $months[$mon];
2678         $date{'rfc2822'}   = sprintf "%s, %d %s %4d %02d:%02d:%02d +0000",
2679                              $days[$wday], $mday, $months[$mon], 1900+$year, $hour ,$min, $sec;
2680         $date{'mday-time'} = sprintf "%d %s %02d:%02d",
2681                              $mday, $months[$mon], $hour ,$min;
2682         $date{'iso-8601'}  = sprintf "%04d-%02d-%02dT%02d:%02d:%02dZ",
2683                              1900+$year, 1+$mon, $mday, $hour ,$min, $sec;
2684
2685         $tz =~ m/^([+\-][0-9][0-9])([0-9][0-9])$/;
2686         my $local = $epoch + ((int $1 + ($2/60)) * 3600);
2687         ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($local);
2688         $date{'hour_local'} = $hour;
2689         $date{'minute_local'} = $min;
2690         $date{'tz_local'} = $tz;
2691         $date{'iso-tz'} = sprintf("%04d-%02d-%02d %02d:%02d:%02d %s",
2692                                   1900+$year, $mon+1, $mday,
2693                                   $hour, $min, $sec, $tz);
2694         return %date;
2695 }
2696
2697 sub parse_tag {
2698         my $tag_id = shift;
2699         my %tag;
2700         my @comment;
2701
2702         open my $fd, "-|", git_cmd(), "cat-file", "tag", $tag_id or return;
2703         $tag{'id'} = $tag_id;
2704         while (my $line = <$fd>) {
2705                 chomp $line;
2706                 if ($line =~ m/^object ([0-9a-fA-F]{40})$/) {
2707                         $tag{'object'} = $1;
2708                 } elsif ($line =~ m/^type (.+)$/) {
2709                         $tag{'type'} = $1;
2710                 } elsif ($line =~ m/^tag (.+)$/) {
2711                         $tag{'name'} = $1;
2712                 } elsif ($line =~ m/^tagger (.*) ([0-9]+) (.*)$/) {
2713                         $tag{'author'} = $1;
2714                         $tag{'author_epoch'} = $2;
2715                         $tag{'author_tz'} = $3;
2716                         if ($tag{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2717                                 $tag{'author_name'}  = $1;
2718                                 $tag{'author_email'} = $2;
2719                         } else {
2720                                 $tag{'author_name'} = $tag{'author'};
2721                         }
2722                 } elsif ($line =~ m/--BEGIN/) {
2723                         push @comment, $line;
2724                         last;
2725                 } elsif ($line eq "") {
2726                         last;
2727                 }
2728         }
2729         push @comment, <$fd>;
2730         $tag{'comment'} = \@comment;
2731         close $fd or return;
2732         if (!defined $tag{'name'}) {
2733                 return
2734         };
2735         return %tag
2736 }
2737
2738 sub parse_commit_text {
2739         my ($commit_text, $withparents) = @_;
2740         my @commit_lines = split '\n', $commit_text;
2741         my %co;
2742
2743         pop @commit_lines; # Remove '\0'
2744
2745         if (! @commit_lines) {
2746                 return;
2747         }
2748
2749         my $header = shift @commit_lines;
2750         if ($header !~ m/^[0-9a-fA-F]{40}/) {
2751                 return;
2752         }
2753         ($co{'id'}, my @parents) = split ' ', $header;
2754         while (my $line = shift @commit_lines) {
2755                 last if $line eq "\n";
2756                 if ($line =~ m/^tree ([0-9a-fA-F]{40})$/) {
2757                         $co{'tree'} = $1;
2758                 } elsif ((!defined $withparents) && ($line =~ m/^parent ([0-9a-fA-F]{40})$/)) {
2759                         push @parents, $1;
2760                 } elsif ($line =~ m/^author (.*) ([0-9]+) (.*)$/) {
2761                         $co{'author'} = to_utf8($1);
2762                         $co{'author_epoch'} = $2;
2763                         $co{'author_tz'} = $3;
2764                         if ($co{'author'} =~ m/^([^<]+) <([^>]*)>/) {
2765                                 $co{'author_name'}  = $1;
2766                                 $co{'author_email'} = $2;
2767                         } else {
2768                                 $co{'author_name'} = $co{'author'};
2769                         }
2770                 } elsif ($line =~ m/^committer (.*) ([0-9]+) (.*)$/) {
2771                         $co{'committer'} = to_utf8($1);
2772                         $co{'committer_epoch'} = $2;
2773                         $co{'committer_tz'} = $3;
2774                         if ($co{'committer'} =~ m/^([^<]+) <([^>]*)>/) {
2775                                 $co{'committer_name'}  = $1;
2776                                 $co{'committer_email'} = $2;
2777                         } else {
2778                                 $co{'committer_name'} = $co{'committer'};
2779                         }
2780                 }
2781         }
2782         if (!defined $co{'tree'}) {
2783                 return;
2784         };
2785         $co{'parents'} = \@parents;
2786         $co{'parent'} = $parents[0];
2787
2788         foreach my $title (@commit_lines) {
2789                 $title =~ s/^    //;
2790                 if ($title ne "") {
2791                         $co{'title'} = chop_str($title, 80, 5);
2792                         # remove leading stuff of merges to make the interesting part visible
2793                         if (length($title) > 50) {
2794                                 $title =~ s/^Automatic //;
2795                                 $title =~ s/^merge (of|with) /Merge ... /i;
2796                                 if (length($title) > 50) {
2797                                         $title =~ s/(http|rsync):\/\///;
2798                                 }
2799                                 if (length($title) > 50) {
2800                                         $title =~ s/(master|www|rsync)\.//;
2801                                 }
2802                                 if (length($title) > 50) {
2803                                         $title =~ s/kernel.org:?//;
2804                                 }
2805                                 if (length($title) > 50) {
2806                                         $title =~ s/\/pub\/scm//;
2807                                 }
2808                         }
2809                         $co{'title_short'} = chop_str($title, 50, 5);
2810                         last;
2811                 }
2812         }
2813         if (! defined $co{'title'} || $co{'title'} eq "") {
2814                 $co{'title'} = $co{'title_short'} = '(no commit message)';
2815         }
2816         # remove added spaces
2817         foreach my $line (@commit_lines) {
2818                 $line =~ s/^    //;
2819         }
2820         $co{'comment'} = \@commit_lines;
2821
2822         my $age = time - $co{'committer_epoch'};
2823         $co{'age'} = $age;
2824         $co{'age_string'} = age_string($age);
2825         my ($sec, $min, $hour, $mday, $mon, $year, $wday, $yday) = gmtime($co{'committer_epoch'});
2826         if ($age > 60*60*24*7*2) {
2827                 $co{'age_string_date'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2828                 $co{'age_string_age'} = $co{'age_string'};
2829         } else {
2830                 $co{'age_string_date'} = $co{'age_string'};
2831                 $co{'age_string_age'} = sprintf "%4i-%02u-%02i", 1900 + $year, $mon+1, $mday;
2832         }
2833         return %co;
2834 }
2835
2836 sub parse_commit {
2837         my ($commit_id) = @_;
2838         my %co;
2839
2840         local $/ = "\0";
2841
2842         open my $fd, "-|", git_cmd(), "rev-list",
2843                 "--parents",
2844                 "--header",
2845                 "--max-count=1",
2846                 $commit_id,
2847                 "--",
2848                 or die_error(500, "Open git-rev-list failed");
2849         %co = parse_commit_text(<$fd>, 1);
2850         close $fd;
2851
2852         return %co;
2853 }
2854
2855 sub parse_commits {
2856         my ($commit_id, $maxcount, $skip, $filename, @args) = @_;
2857         my @cos;
2858
2859         $maxcount ||= 1;
2860         $skip ||= 0;
2861
2862         local $/ = "\0";
2863
2864         open my $fd, "-|", git_cmd(), "rev-list",
2865                 "--header",
2866                 @args,
2867                 ("--max-count=" . $maxcount),
2868                 ("--skip=" . $skip),
2869                 @extra_options,
2870                 $commit_id,
2871                 "--",
2872                 ($filename ? ($filename) : ())
2873                 or die_error(500, "Open git-rev-list failed");
2874         while (my $line = <$fd>) {
2875                 my %co = parse_commit_text($line);
2876                 push @cos, \%co;
2877         }
2878         close $fd;
2879
2880         return wantarray ? @cos : \@cos;
2881 }
2882
2883 # parse line of git-diff-tree "raw" output
2884 sub parse_difftree_raw_line {
2885         my $line = shift;
2886         my %res;
2887
2888         # ':100644 100644 03b218260e99b78c6df0ed378e59ed9205ccc96d 3b93d5e7cc7f7dd4ebed13a5cc1a4ad976fc94d8 M   ls-files.c'
2889         # ':100644 100644 7f9281985086971d3877aca27704f2aaf9c448ce bc190ebc71bbd923f2b728e505408f5e54bd073a M   rev-tree.c'
2890         if ($line =~ m/^:([0-7]{6}) ([0-7]{6}) ([0-9a-fA-F]{40}) ([0-9a-fA-F]{40}) (.)([0-9]{0,3})\t(.*)$/) {
2891                 $res{'from_mode'} = $1;
2892                 $res{'to_mode'} = $2;
2893                 $res{'from_id'} = $3;
2894                 $res{'to_id'} = $4;
2895                 $res{'status'} = $5;
2896                 $res{'similarity'} = $6;
2897                 if ($res{'status'} eq 'R' || $res{'status'} eq 'C') { # renamed or copied
2898                         ($res{'from_file'}, $res{'to_file'}) = map { unquote($_) } split("\t", $7);
2899                 } else {
2900                         $res{'from_file'} = $res{'to_file'} = $res{'file'} = unquote($7);
2901                 }
2902         }
2903         # '::100755 100755 100755 60e79ca1b01bc8b057abe17ddab484699a7f5fdb 94067cc5f73388f33722d52ae02f44692bc07490 94067cc5f73388f33722d52ae02f44692bc07490 MR git-gui/git-gui.sh'
2904         # combined diff (for merge commit)
2905         elsif ($line =~ s/^(::+)((?:[0-7]{6} )+)((?:[0-9a-fA-F]{40} )+)([a-zA-Z]+)\t(.*)$//) {
2906                 $res{'nparents'}  = length($1);
2907                 $res{'from_mode'} = [ split(' ', $2) ];
2908                 $res{'to_mode'} = pop @{$res{'from_mode'}};
2909                 $res{'from_id'} = [ split(' ', $3) ];
2910                 $res{'to_id'} = pop @{$res{'from_id'}};
2911                 $res{'status'} = [ split('', $4) ];
2912                 $res{'to_file'} = unquote($5);
2913         }
2914         # 'c512b523472485aef4fff9e57b229d9d243c967f'
2915         elsif ($line =~ m/^([0-9a-fA-F]{40})$/) {
2916                 $res{'commit'} = $1;
2917         }
2918
2919         return wantarray ? %res : \%res;
2920 }
2921
2922 # wrapper: return parsed line of git-diff-tree "raw" output
2923 # (the argument might be raw line, or parsed info)
2924 sub parsed_difftree_line {
2925         my $line_or_ref = shift;
2926
2927         if (ref($line_or_ref) eq "HASH") {
2928                 # pre-parsed (or generated by hand)
2929                 return $line_or_ref;
2930         } else {
2931                 return parse_difftree_raw_line($line_or_ref);
2932         }
2933 }
2934
2935 # parse line of git-ls-tree output
2936 sub parse_ls_tree_line {
2937         my $line = shift;
2938         my %opts = @_;
2939         my %res;
2940
2941         if ($opts{'-l'}) {
2942                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa   16717  panic.c'
2943                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40}) +(-|[0-9]+)\t(.+)$/s;
2944
2945                 $res{'mode'} = $1;
2946                 $res{'type'} = $2;
2947                 $res{'hash'} = $3;
2948                 $res{'size'} = $4;
2949                 if ($opts{'-z'}) {
2950                         $res{'name'} = $5;
2951                 } else {
2952                         $res{'name'} = unquote($5);
2953                 }
2954         } else {
2955                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
2956                 $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t(.+)$/s;
2957
2958                 $res{'mode'} = $1;
2959                 $res{'type'} = $2;
2960                 $res{'hash'} = $3;
2961                 if ($opts{'-z'}) {
2962                         $res{'name'} = $4;
2963                 } else {
2964                         $res{'name'} = unquote($4);
2965                 }
2966         }
2967
2968         return wantarray ? %res : \%res;
2969 }
2970
2971 # generates _two_ hashes, references to which are passed as 2 and 3 argument
2972 sub parse_from_to_diffinfo {
2973         my ($diffinfo, $from, $to, @parents) = @_;
2974
2975         if ($diffinfo->{'nparents'}) {
2976                 # combined diff
2977                 $from->{'file'} = [];
2978                 $from->{'href'} = [];
2979                 fill_from_file_info($diffinfo, @parents)
2980                         unless exists $diffinfo->{'from_file'};
2981                 for (my $i = 0; $i < $diffinfo->{'nparents'}; $i++) {
2982                         $from->{'file'}[$i] =
2983                                 defined $diffinfo->{'from_file'}[$i] ?
2984                                         $diffinfo->{'from_file'}[$i] :
2985                                         $diffinfo->{'to_file'};
2986                         if ($diffinfo->{'status'}[$i] ne "A") { # not new (added) file
2987                                 $from->{'href'}[$i] = href(action=>"blob",
2988                                                            hash_base=>$parents[$i],
2989                                                            hash=>$diffinfo->{'from_id'}[$i],
2990                                                            file_name=>$from->{'file'}[$i]);
2991                         } else {
2992                                 $from->{'href'}[$i] = undef;
2993                         }
2994                 }
2995         } else {
2996                 # ordinary (not combined) diff
2997                 $from->{'file'} = $diffinfo->{'from_file'};
2998                 if ($diffinfo->{'status'} ne "A") { # not new (added) file
2999                         $from->{'href'} = href(action=>"blob", hash_base=>$hash_parent,
3000                                                hash=>$diffinfo->{'from_id'},
3001                                                file_name=>$from->{'file'});
3002                 } else {
3003                         delete $from->{'href'};
3004                 }
3005         }
3006
3007         $to->{'file'} = $diffinfo->{'to_file'};
3008         if (!is_deleted($diffinfo)) { # file exists in result
3009                 $to->{'href'} = href(action=>"blob", hash_base=>$hash,
3010                                      hash=>$diffinfo->{'to_id'},
3011                                      file_name=>$to->{'file'});
3012         } else {
3013                 delete $to->{'href'};
3014         }
3015 }
3016
3017 ## ......................................................................
3018 ## parse to array of hashes functions
3019
3020 sub git_get_heads_list {
3021         my $limit = shift;
3022         my @headslist;
3023
3024         open my $fd, '-|', git_cmd(), 'for-each-ref',
3025                 ($limit ? '--count='.($limit+1) : ()), '--sort=-committerdate',
3026                 '--format=%(objectname) %(refname) %(subject)%00%(committer)',
3027                 'refs/heads'
3028                 or return;
3029         while (my $line = <$fd>) {
3030                 my %ref_item;
3031
3032                 chomp $line;
3033                 my ($refinfo, $committerinfo) = split(/\0/, $line);
3034                 my ($hash, $name, $title) = split(' ', $refinfo, 3);
3035                 my ($committer, $epoch, $tz) =
3036                         ($committerinfo =~ /^(.*) ([0-9]+) (.*)$/);
3037                 $ref_item{'fullname'}  = $name;
3038                 $name =~ s!^refs/heads/!!;
3039
3040                 $ref_item{'name'}  = $name;
3041                 $ref_item{'id'}    = $hash;
3042                 $ref_item{'title'} = $title || '(no commit message)';
3043                 $ref_item{'epoch'} = $epoch;
3044                 if ($epoch) {
3045                         $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3046                 } else {
3047                         $ref_item{'age'} = "unknown";
3048                 }
3049
3050                 push @headslist, \%ref_item;
3051         }
3052         close $fd;
3053
3054         return wantarray ? @headslist : \@headslist;
3055 }
3056
3057 sub git_get_tags_list {
3058         my $limit = shift;
3059         my @tagslist;
3060
3061         open my $fd, '-|', git_cmd(), 'for-each-ref',
3062                 ($limit ? '--count='.($limit+1) : ()), '--sort=-creatordate',
3063                 '--format=%(objectname) %(objecttype) %(refname) '.
3064                 '%(*objectname) %(*objecttype) %(subject)%00%(creator)',
3065                 'refs/tags'
3066                 or return;
3067         while (my $line = <$fd>) {
3068                 my %ref_item;
3069
3070                 chomp $line;
3071                 my ($refinfo, $creatorinfo) = split(/\0/, $line);
3072                 my ($id, $type, $name, $refid, $reftype, $title) = split(' ', $refinfo, 6);
3073                 my ($creator, $epoch, $tz) =
3074                         ($creatorinfo =~ /^(.*) ([0-9]+) (.*)$/);
3075                 $ref_item{'fullname'} = $name;
3076                 $name =~ s!^refs/tags/!!;
3077
3078                 $ref_item{'type'} = $type;
3079                 $ref_item{'id'} = $id;
3080                 $ref_item{'name'} = $name;
3081                 if ($type eq "tag") {
3082                         $ref_item{'subject'} = $title;
3083                         $ref_item{'reftype'} = $reftype;
3084                         $ref_item{'refid'}   = $refid;
3085                 } else {
3086                         $ref_item{'reftype'} = $type;
3087                         $ref_item{'refid'}   = $id;
3088                 }
3089
3090                 if ($type eq "tag" || $type eq "commit") {
3091                         $ref_item{'epoch'} = $epoch;
3092                         if ($epoch) {
3093                                 $ref_item{'age'} = age_string(time - $ref_item{'epoch'});
3094                         } else {
3095                                 $ref_item{'age'} = "unknown";
3096                         }
3097                 }
3098
3099                 push @tagslist, \%ref_item;
3100         }
3101         close $fd;
3102
3103         return wantarray ? @tagslist : \@tagslist;
3104 }
3105
3106 ## ----------------------------------------------------------------------
3107 ## filesystem-related functions
3108
3109 sub get_file_owner {
3110         my $path = shift;
3111
3112         my ($dev, $ino, $mode, $nlink, $st_uid, $st_gid, $rdev, $size) = stat($path);
3113         my ($name, $passwd, $uid, $gid, $quota, $comment, $gcos, $dir, $shell) = getpwuid($st_uid);
3114         if (!defined $gcos) {
3115                 return undef;
3116         }
3117         my $owner = $gcos;
3118         $owner =~ s/[,;].*$//;
3119         return to_utf8($owner);
3120 }
3121
3122 # assume that file exists
3123 sub insert_file {
3124         my $filename = shift;
3125
3126         open my $fd, '<', $filename;
3127         print map { to_utf8($_) } <$fd>;
3128         close $fd;
3129 }
3130
3131 ## ......................................................................
3132 ## mimetype related functions
3133
3134 sub mimetype_guess_file {
3135         my $filename = shift;
3136         my $mimemap = shift;
3137         -r $mimemap or return undef;
3138
3139         my %mimemap;
3140         open(my $mh, '<', $mimemap) or return undef;
3141         while (<$mh>) {
3142                 next if m/^#/; # skip comments
3143                 my ($mimetype, $exts) = split(/\t+/);
3144                 if (defined $exts) {
3145                         my @exts = split(/\s+/, $exts);
3146                         foreach my $ext (@exts) {
3147                                 $mimemap{$ext} = $mimetype;
3148                         }
3149                 }
3150         }
3151         close($mh);
3152
3153         $filename =~ /\.([^.]*)$/;
3154         return $mimemap{$1};
3155 }
3156
3157 sub mimetype_guess {
3158         my $filename = shift;
3159         my $mime;
3160         $filename =~ /\./ or return undef;
3161
3162         if ($mimetypes_file) {
3163                 my $file = $mimetypes_file;
3164                 if ($file !~ m!^/!) { # if it is relative path
3165                         # it is relative to project
3166                         $file = "$projectroot/$project/$file";
3167                 }
3168                 $mime = mimetype_guess_file($filename, $file);
3169         }
3170         $mime ||= mimetype_guess_file($filename, '/etc/mime.types');
3171         return $mime;
3172 }
3173
3174 sub blob_mimetype {
3175         my $fd = shift;
3176         my $filename = shift;
3177
3178         if ($filename) {
3179                 my $mime = mimetype_guess($filename);
3180                 $mime and return $mime;
3181         }
3182
3183         # just in case
3184         return $default_blob_plain_mimetype unless $fd;
3185
3186         if (-T $fd) {
3187                 return 'text/plain';
3188         } elsif (! $filename) {
3189                 return 'application/octet-stream';
3190         } elsif ($filename =~ m/\.png$/i) {
3191                 return 'image/png';
3192         } elsif ($filename =~ m/\.gif$/i) {
3193                 return 'image/gif';
3194         } elsif ($filename =~ m/\.jpe?g$/i) {
3195                 return 'image/jpeg';
3196         } else {
3197                 return 'application/octet-stream';
3198         }
3199 }
3200
3201 sub blob_contenttype {
3202         my ($fd, $file_name, $type) = @_;
3203
3204         $type ||= blob_mimetype($fd, $file_name);
3205         if ($type eq 'text/plain' && defined $default_text_plain_charset) {
3206                 $type .= "; charset=$default_text_plain_charset";
3207         }
3208
3209         return $type;
3210 }
3211
3212 ## ======================================================================
3213 ## functions printing HTML: header, footer, error page
3214
3215 sub git_header_html {
3216         my $status = shift || "200 OK";
3217         my $expires = shift;
3218
3219         my $title = "$site_name";
3220         if (defined $project) {
3221                 $title .= " - " . to_utf8($project);
3222                 if (defined $action) {
3223                         $title .= "/$action";
3224                         if (defined $file_name) {
3225                                 $title .= " - " . esc_path($file_name);
3226                                 if ($action eq "tree" && $file_name !~ m|/$|) {
3227                                         $title .= "/";
3228                                 }
3229                         }
3230                 }
3231         }
3232         my $content_type;
3233         # require explicit support from the UA if we are to send the page as
3234         # 'application/xhtml+xml', otherwise send it as plain old 'text/html'.
3235         # we have to do this because MSIE sometimes globs '*/*', pretending to
3236         # support xhtml+xml but choking when it gets what it asked for.
3237         # Disable content-type negotiation when caching (use mimetype good for all).
3238         if (!$caching_enabled &&
3239             defined $cgi->http('HTTP_ACCEPT') &&
3240             $cgi->http('HTTP_ACCEPT') =~ m/(,|;|\s|^)application\/xhtml\+xml(,|;|\s|$)/ &&
3241             $cgi->Accept('application/xhtml+xml') != 0) {
3242                 $content_type = 'application/xhtml+xml';
3243         } else {
3244                 $content_type = 'text/html';
3245         }
3246         print $cgi->header(-type=>$content_type, -charset => 'utf-8',
3247                            -status=> $status, -expires => $expires);
3248         my $mod_perl_version = $ENV{'MOD_PERL'} ? " $ENV{'MOD_PERL'}" : '';
3249         print <<EOF;
3250 <?xml version="1.0" encoding="utf-8"?>
3251 <!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
3252 <html xmlns="http://www.w3.org/1999/xhtml" xml:lang="en-US" lang="en-US">
3253 <!-- git web interface version $version, (C) 2005-2006, Kay Sievers <kay.sievers\@vrfy.org>, Christian Gierke -->
3254 <!-- git core binaries version $git_version -->
3255 <head>
3256 <meta http-equiv="content-type" content="$content_type; charset=utf-8"/>
3257 <meta name="generator" content="gitweb/$version git/$git_version$mod_perl_version"/>
3258 <meta name="robots" content="index, nofollow"/>
3259 <title>$title</title>
3260 EOF
3261         # the stylesheet, favicon etc urls won't work correctly with path_info
3262         # unless we set the appropriate base URL
3263         if ($ENV{'PATH_INFO'}) {
3264                 print "<base href=\"".esc_url($base_url)."\" />\n";
3265         }
3266         # print out each stylesheet that exist, providing backwards capability
3267         # for those people who defined $stylesheet in a config file
3268         if (defined $stylesheet) {
3269                 print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3270         } else {
3271                 foreach my $stylesheet (@stylesheets) {
3272                         next unless $stylesheet;
3273                         print '<link rel="stylesheet" type="text/css" href="'.$stylesheet.'"/>'."\n";
3274                 }
3275         }
3276         if (defined $project) {
3277                 my %href_params = get_feed_info();
3278                 if (!exists $href_params{'-title'}) {
3279                         $href_params{'-title'} = 'log';
3280                 }
3281
3282                 foreach my $format qw(RSS Atom) {
3283                         my $type = lc($format);
3284                         my %link_attr = (
3285                                 '-rel' => 'alternate',
3286                                 '-title' => "$project - $href_params{'-title'} - $format feed",
3287                                 '-type' => "application/$type+xml"
3288                         );
3289
3290                         $href_params{'action'} = $type;
3291                         $link_attr{'-href'} = href(%href_params);
3292                         print "<link ".
3293                               "rel=\"$link_attr{'-rel'}\" ".
3294                               "title=\"$link_attr{'-title'}\" ".
3295                               "href=\"$link_attr{'-href'}\" ".
3296                               "type=\"$link_attr{'-type'}\" ".
3297                               "/>\n";
3298
3299                         $href_params{'extra_options'} = '--no-merges';
3300                         $link_attr{'-href'} = href(%href_params);
3301                         $link_attr{'-title'} .= ' (no merges)';
3302                         print "<link ".
3303                               "rel=\"$link_attr{'-rel'}\" ".
3304                               "title=\"$link_attr{'-title'}\" ".
3305                               "href=\"$link_attr{'-href'}\" ".
3306                               "type=\"$link_attr{'-type'}\" ".
3307                               "/>\n";
3308                 }
3309
3310         } else {
3311                 printf('<link rel="alternate" title="%s projects list" '.
3312                        'href="%s" type="text/plain; charset=utf-8" />'."\n",
3313                        $site_name, href(project=>undef, action=>"project_index"));
3314                 printf('<link rel="alternate" title="%s projects feeds" '.
3315                        'href="%s" type="text/x-opml" />'."\n",
3316                        $site_name, href(project=>undef, action=>"opml"));
3317         }
3318         if (defined $favicon) {
3319                 print qq(<link rel="shortcut icon" href="$favicon" type="image/png" />\n);
3320         }
3321
3322         print "</head>\n" .
3323               "<body>\n";
3324
3325         if (defined $site_header && -f $site_header) {
3326                 insert_file($site_header);
3327         }
3328
3329         print "<div class=\"page_header\">\n" .
3330               $cgi->a({-href => esc_url($logo_url),
3331                        -title => $logo_label},
3332                       qq(<img src="$logo" width="72" height="27" alt="git" class="logo"/>));
3333         print $cgi->a({-href => esc_url($home_link)}, $home_link_str) . " / ";
3334         if (defined $project) {
3335                 print $cgi->a({-href => href(action=>"summary")}, esc_html($project));
3336                 if (defined $action) {
3337                         print " / $action";
3338                 }
3339                 print "\n";
3340         }
3341         print "</div>\n";
3342
3343         my $have_search = gitweb_check_feature('search');
3344         if (defined $project && $have_search) {
3345                 if (!defined $searchtext) {
3346                         $searchtext = "";
3347                 }
3348                 my $search_hash;
3349                 if (defined $hash_base) {
3350                         $search_hash = $hash_base;
3351                 } elsif (defined $hash) {
3352                         $search_hash = $hash;
3353                 } else {
3354                         $search_hash = "HEAD";
3355                 }
3356                 my $action = $my_uri;
3357                 my $use_pathinfo = gitweb_check_feature('pathinfo');
3358                 if ($use_pathinfo) {
3359                         $action .= "/".esc_url($project);
3360                 }
3361                 print $cgi->startform(-method => "get", -action => $action) .
3362                       "<div class=\"search\">\n" .
3363                       (!$use_pathinfo &&
3364                       $cgi->input({-name=>"p", -value=>$project, -type=>"hidden"}) . "\n") .
3365                       $cgi->input({-name=>"a", -value=>"search", -type=>"hidden"}) . "\n" .
3366                       $cgi->input({-name=>"h", -value=>$search_hash, -type=>"hidden"}) . "\n" .
3367                       $cgi->popup_menu(-name => 'st', -default => 'commit',
3368                                        -values => ['commit', 'grep', 'author', 'committer', 'pickaxe']) .
3369                       $cgi->sup($cgi->a({-href => href(action=>"search_help")}, "?")) .
3370                       " search:\n",
3371                       $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
3372                       "<span title=\"Extended regular expression\">" .
3373                       $cgi->checkbox(-name => 'sr', -value => 1, -label => 're',
3374                                      -checked => $search_use_regexp) .
3375                       "</span>" .
3376                       "</div>" .
3377                       $cgi->end_form() . "\n";
3378         }
3379 }
3380
3381 sub git_footer_html {
3382         my $feed_class = 'rss_logo';
3383
3384         print "<div class=\"page_footer\">\n";
3385         if (defined $project) {
3386                 my $descr = git_get_project_description($project);
3387                 if (defined $descr) {
3388                         print "<div class=\"page_footer_text\">" . esc_html($descr) . "</div>\n";
3389                 }
3390
3391                 my %href_params = get_feed_info();
3392                 if (!%href_params) {
3393                         $feed_class .= ' generic';
3394                 }
3395                 $href_params{'-title'} ||= 'log';
3396
3397                 foreach my $format qw(RSS Atom) {
3398                         $href_params{'action'} = lc($format);
3399                         print $cgi->a({-href => href(%href_params),
3400                                       -title => "$href_params{'-title'} $format feed",
3401                                       -class => $feed_class}, $format)."\n";
3402                 }
3403
3404         } else {
3405                 print $cgi->a({-href => href(project=>undef, action=>"opml"),
3406                               -class => $feed_class}, "OPML") . " ";
3407                 print $cgi->a({-href => href(project=>undef, action=>"project_index"),
3408                               -class => $feed_class}, "TXT") . "\n";
3409         }
3410         print "</div>\n"; # class="page_footer"
3411
3412         # timing info doesn't make much sense with output (response) caching,
3413         # so when caching is enabled gitweb prints the time of page generation
3414         if ((defined $t0 || $caching_enabled) &&
3415             gitweb_check_feature('timed')) {
3416                 print "<div id=\"generating_info\">\n";
3417                 if ($caching_enabled) {
3418                         print 'This page was generated at '.
3419                               gmtime( time() )." GMT\n";
3420                 } else {
3421                         print 'This page took '.
3422                               '<span id="generating_time" class="time_span">'.
3423                               Time::HiRes::tv_interval($t0, [Time::HiRes::gettimeofday()]).
3424                               ' seconds </span>'.
3425                               ' and '.
3426                               '<span id="generating_cmd">'.
3427                               $number_of_git_cmds.
3428                               '</span> git commands '.
3429                               " to generate.\n";
3430                 }
3431                 print "</div>\n"; # class="page_footer"
3432         }
3433
3434         if (defined $site_footer && -f $site_footer) {
3435                 insert_file($site_footer);
3436         }
3437
3438         print qq!<script type="text/javascript" src="$javascript"></script>\n!;
3439         if (defined $action &&
3440             $action eq 'blame_incremental') {
3441                 print qq!<script type="text/javascript">\n!.
3442                       qq!startBlame("!. href(action=>"blame_data", -replay=>1) .qq!",\n!.
3443                       qq!           "!. href() .qq!");\n!.
3444                       qq!</script>\n!;
3445         } elsif (gitweb_check_feature('javascript-actions')) {
3446                 print qq!<script type="text/javascript">\n!.
3447                       qq!window.onload = fixLinks;\n!.
3448                       qq!</script>\n!;
3449         }
3450
3451         print "</body>\n" .
3452               "</html>";
3453 }
3454
3455 # die_error(<http_status_code>, <error_message>)
3456 # Example: die_error(404, 'Hash not found')
3457 # By convention, use the following status codes (as defined in RFC 2616):
3458 # 400: Invalid or missing CGI parameters, or
3459 #      requested object exists but has wrong type.
3460 # 403: Requested feature (like "pickaxe" or "snapshot") not enabled on
3461 #      this server or project.
3462 # 404: Requested object/revision/project doesn't exist.
3463 # 500: The server isn't configured properly, or
3464 #      an internal error occurred (e.g. failed assertions caused by bugs), or
3465 #      an unknown error occurred (e.g. the git binary died unexpectedly).
3466 # 503: The server is currently unavailable (because it is overloaded,
3467 #      or down for maintenance).  Generally, this is a temporary state.
3468 sub die_error {
3469         my $status = shift || 500;
3470         my $error = shift || "Internal server error";
3471         my $extra = shift;
3472
3473         my %http_responses = (
3474                 400 => '400 Bad Request',
3475                 403 => '403 Forbidden',
3476                 404 => '404 Not Found',
3477                 500 => '500 Internal Server Error',
3478                 503 => '503 Service Unavailable',
3479         );
3480
3481         # Do not cache error pages (die_error() uses 'exit')
3482         cache_stop() if ($caching_enabled);
3483
3484         git_header_html($http_responses{$status});
3485         print <<EOF;
3486 <div class="page_body">
3487 <br /><br />
3488 $status - $error
3489 <br />
3490 EOF
3491         if (defined $extra) {
3492                 print "<hr />\n" .
3493                       "$extra\n";
3494         }
3495         print "</div>\n";
3496
3497         git_footer_html();
3498         exit;
3499 }
3500
3501 ## ----------------------------------------------------------------------
3502 ## functions printing or outputting HTML: navigation
3503
3504 sub git_print_page_nav {
3505         my ($current, $suppress, $head, $treehead, $treebase, $extra) = @_;
3506         $extra = '' if !defined $extra; # pager or formats
3507
3508         my @navs = qw(summary shortlog log commit commitdiff tree);
3509         if ($suppress) {
3510                 @navs = grep { $_ ne $suppress } @navs;
3511         }
3512
3513         my %arg = map { $_ => {action=>$_} } @navs;
3514         if (defined $head) {
3515                 for (qw(commit commitdiff)) {
3516                         $arg{$_}{'hash'} = $head;
3517                 }
3518                 if ($current =~ m/^(tree | log | shortlog | commit | commitdiff | search)$/x) {
3519                         for (qw(shortlog log)) {
3520                                 $arg{$_}{'hash'} = $head;
3521                         }
3522                 }
3523         }
3524
3525         $arg{'tree'}{'hash'} = $treehead if defined $treehead;
3526         $arg{'tree'}{'hash_base'} = $treebase if defined $treebase;
3527
3528         my @actions = gitweb_get_feature('actions');
3529         my %repl = (
3530                 '%' => '%',
3531                 'n' => $project,         # project name
3532                 'f' => $git_dir,         # project path within filesystem
3533                 'h' => $treehead || '',  # current hash ('h' parameter)
3534                 'b' => $treebase || '',  # hash base ('hb' parameter)
3535         );
3536         while (@actions) {
3537                 my ($label, $link, $pos) = splice(@actions,0,3);
3538                 # insert
3539                 @navs = map { $_ eq $pos ? ($_, $label) : $_ } @navs;
3540                 # munch munch
3541                 $link =~ s/%([%nfhb])/$repl{$1}/g;
3542                 $arg{$label}{'_href'} = $link;
3543         }
3544
3545         print "<div class=\"page_nav\">\n" .
3546                 (join " | ",
3547                  map { $_ eq $current ?
3548                        $_ : $cgi->a({-href => ($arg{$_}{_href} ? $arg{$_}{_href} : href(%{$arg{$_}}))}, "$_")
3549                  } @navs);
3550         print "<br/>\n$extra<br/>\n" .
3551               "</div>\n";
3552 }
3553
3554 sub format_paging_nav {
3555         my ($action, $page, $has_next_link) = @_;
3556         my $paging_nav;
3557
3558
3559         if ($page > 0) {
3560                 $paging_nav .=
3561                         $cgi->a({-href => href(-replay=>1, page=>undef)}, "first") .
3562                         " &sdot; " .
3563                         $cgi->a({-href => href(-replay=>1, page=>$page-1),
3564                                  -accesskey => "p", -title => "Alt-p"}, "prev");
3565         } else {
3566                 $paging_nav .= "first &sdot; prev";
3567         }
3568
3569         if ($has_next_link) {
3570                 $paging_nav .= " &sdot; " .
3571                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
3572                                  -accesskey => "n", -title => "Alt-n"}, "next");
3573         } else {
3574                 $paging_nav .= " &sdot; next";
3575         }
3576
3577         return $paging_nav;
3578 }
3579
3580 ## ......................................................................
3581 ## functions printing or outputting HTML: div
3582
3583 sub git_print_header_div {
3584         my ($action, $title, $hash, $hash_base) = @_;
3585         my %args = ();
3586
3587         $args{'action'} = $action;
3588         $args{'hash'} = $hash if $hash;
3589         $args{'hash_base'} = $hash_base if $hash_base;
3590
3591         print "<div class=\"header\">\n" .
3592               $cgi->a({-href => href(%args), -class => "title"},
3593               $title ? $title : $action) .
3594               "\n</div>\n";
3595 }
3596
3597 sub print_local_time {
3598         print format_local_time(@_);
3599 }
3600
3601 sub format_local_time {
3602         my $localtime = '';
3603         my %date = @_;
3604         if ($date{'hour_local'} < 6) {
3605                 $localtime .= sprintf(" (<span class=\"atnight\">%02d:%02d</span> %s)",
3606                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3607         } else {
3608                 $localtime .= sprintf(" (%02d:%02d %s)",
3609                         $date{'hour_local'}, $date{'minute_local'}, $date{'tz_local'});
3610         }
3611
3612         return $localtime;
3613 }
3614
3615 # Outputs the author name and date in long form
3616 sub git_print_authorship {
3617         my $co = shift;
3618         my %opts = @_;
3619         my $tag = $opts{-tag} || 'div';
3620         my $author = $co->{'author_name'};
3621
3622         my %ad = parse_date($co->{'author_epoch'}, $co->{'author_tz'});
3623         print "<$tag class=\"author_date\">" .
3624               format_search_author($author, "author", esc_html($author)) .
3625               " [$ad{'rfc2822'}";
3626         print_local_time(%ad) if ($opts{-localtime});
3627         print "]" . git_get_avatar($co->{'author_email'}, -pad_before => 1)
3628                   . "</$tag>\n";
3629 }
3630
3631 # Outputs table rows containing the full author or committer information,
3632 # in the format expected for 'commit' view (& similia).
3633 # Parameters are a commit hash reference, followed by the list of people
3634 # to output information for. If the list is empty it defalts to both
3635 # author and committer.
3636 sub git_print_authorship_rows {
3637         my $co = shift;
3638         # too bad we can't use @people = @_ || ('author', 'committer')
3639         my @people = @_;
3640         @people = ('author', 'committer') unless @people;
3641         foreach my $who (@people) {
3642                 my %wd = parse_date($co->{"${who}_epoch"}, $co->{"${who}_tz"});
3643                 print "<tr><td>$who</td><td>" .
3644                       format_search_author($co->{"${who}_name"}, $who,
3645                                esc_html($co->{"${who}_name"})) . " " .
3646                       format_search_author($co->{"${who}_email"}, $who,
3647                                esc_html("<" . $co->{"${who}_email"} . ">")) .
3648                       "</td><td rowspan=\"2\">" .
3649                       git_get_avatar($co->{"${who}_email"}, -size => 'double') .
3650                       "</td></tr>\n" .
3651                       "<tr>" .
3652                       "<td></td><td> $wd{'rfc2822'}";
3653                 print_local_time(%wd);
3654                 print "</td>" .
3655                       "</tr>\n";
3656         }
3657 }
3658
3659 sub git_print_page_path {
3660         my $name = shift;
3661         my $type = shift;
3662         my $hb = shift;
3663
3664
3665         print "<div class=\"page_path\">";
3666         print $cgi->a({-href => href(action=>"tree", hash_base=>$hb),
3667                       -title => 'tree root'}, to_utf8("[$project]"));
3668         print " / ";
3669         if (defined $name) {
3670                 my @dirname = split '/', $name;
3671                 my $basename = pop @dirname;
3672                 my $fullname = '';
3673
3674                 foreach my $dir (@dirname) {
3675                         $fullname .= ($fullname ? '/' : '') . $dir;
3676                         print $cgi->a({-href => href(action=>"tree", file_name=>$fullname,
3677                                                      hash_base=>$hb),
3678                                       -title => $fullname}, esc_path($dir));
3679                         print " / ";
3680                 }
3681                 if (defined $type && $type eq 'blob') {
3682                         print $cgi->a({-href => href(action=>"blob_plain", file_name=>$file_name,
3683                                                      hash_base=>$hb),
3684                                       -title => $name}, esc_path($basename));
3685                 } elsif (defined $type && $type eq 'tree') {
3686                         print $cgi->a({-href => href(action=>"tree", file_name=>$file_name,
3687                                                      hash_base=>$hb),
3688                                       -title => $name}, esc_path($basename));
3689                         print " / ";
3690                 } else {
3691                         print esc_path($basename);
3692                 }
3693         }
3694         print "<br/></div>\n";
3695 }
3696
3697 sub git_print_log {
3698         my $log = shift;
3699         my %opts = @_;
3700
3701         if ($opts{'-remove_title'}) {
3702                 # remove title, i.e. first line of log
3703                 shift @$log;
3704         }
3705         # remove leading empty lines
3706         while (defined $log->[0] && $log->[0] eq "") {
3707                 shift @$log;
3708         }
3709
3710         # print log
3711         my $signoff = 0;
3712         my $empty = 0;
3713         foreach my $line (@$log) {
3714                 if ($line =~ m/^ *(signed[ \-]off[ \-]by[ :]|acked[ \-]by[ :]|cc[ :])/i) {
3715                         $signoff = 1;
3716                         $empty = 0;
3717                         if (! $opts{'-remove_signoff'}) {
3718                                 print "<span class=\"signoff\">" . esc_html($line) . "</span><br/>\n";
3719                                 next;
3720                         } else {
3721                                 # remove signoff lines
3722                                 next;
3723                         }
3724                 } else {
3725                         $signoff = 0;
3726                 }
3727
3728                 # print only one empty line
3729                 # do not print empty line after signoff
3730                 if ($line eq "") {
3731                         next if ($empty || $signoff);
3732                         $empty = 1;
3733                 } else {
3734                         $empty = 0;
3735                 }
3736
3737                 print format_log_line_html($line) . "<br/>\n";
3738         }
3739
3740         if ($opts{'-final_empty_line'}) {
3741                 # end with single empty line
3742                 print "<br/>\n" unless $empty;
3743         }
3744 }
3745
3746 # return link target (what link points to)
3747 sub git_get_link_target {
3748         my $hash = shift;
3749         my $link_target;
3750
3751         # read link
3752         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
3753                 or return;
3754         {
3755                 local $/ = undef;
3756                 $link_target = <$fd>;
3757         }
3758         close $fd
3759                 or return;
3760
3761         return $link_target;
3762 }
3763
3764 # given link target, and the directory (basedir) the link is in,
3765 # return target of link relative to top directory (top tree);
3766 # return undef if it is not possible (including absolute links).
3767 sub normalize_link_target {
3768         my ($link_target, $basedir) = @_;
3769
3770         # absolute symlinks (beginning with '/') cannot be normalized
3771         return if (substr($link_target, 0, 1) eq '/');
3772
3773         # normalize link target to path from top (root) tree (dir)
3774         my $path;
3775         if ($basedir) {
3776                 $path = $basedir . '/' . $link_target;
3777         } else {
3778                 # we are in top (root) tree (dir)
3779                 $path = $link_target;
3780         }
3781
3782         # remove //, /./, and /../
3783         my @path_parts;
3784         foreach my $part (split('/', $path)) {
3785                 # discard '.' and ''
3786                 next if (!$part || $part eq '.');
3787                 # handle '..'
3788                 if ($part eq '..') {
3789                         if (@path_parts) {
3790                                 pop @path_parts;
3791                         } else {
3792                                 # link leads outside repository (outside top dir)
3793                                 return;
3794                         }
3795                 } else {
3796                         push @path_parts, $part;
3797                 }
3798         }
3799         $path = join('/', @path_parts);
3800
3801         return $path;
3802 }
3803
3804 # print tree entry (row of git_tree), but without encompassing <tr> element
3805 sub git_print_tree_entry {
3806         my ($t, $basedir, $hash_base, $have_blame) = @_;
3807
3808         my %base_key = ();
3809         $base_key{'hash_base'} = $hash_base if defined $hash_base;
3810
3811         # The format of a table row is: mode list link.  Where mode is
3812         # the mode of the entry, list is the name of the entry, an href,
3813         # and link is the action links of the entry.
3814
3815         print "<td class=\"mode\">" . mode_str($t->{'mode'}) . "</td>\n";
3816         if (exists $t->{'size'}) {
3817                 print "<td class=\"size\">$t->{'size'}</td>\n";
3818         }
3819         if ($t->{'type'} eq "blob") {
3820                 print "<td class=\"list\">" .
3821                         $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
3822                                                file_name=>"$basedir$t->{'name'}", %base_key),
3823                                 -class => "list"}, esc_path($t->{'name'}));
3824                 if (S_ISLNK(oct $t->{'mode'})) {
3825                         my $link_target = git_get_link_target($t->{'hash'});
3826                         if ($link_target) {
3827                                 my $norm_target = normalize_link_target($link_target, $basedir);
3828                                 if (defined $norm_target) {
3829                                         print " -> " .
3830                                               $cgi->a({-href => href(action=>"object", hash_base=>$hash_base,
3831                                                                      file_name=>$norm_target),
3832                                                        -title => $norm_target}, esc_path($link_target));
3833                                 } else {
3834                                         print " -> " . esc_path($link_target);
3835                                 }
3836                         }
3837                 }
3838                 print "</td>\n";
3839                 print "<td class=\"link\">";
3840                 print $cgi->a({-href => href(action=>"blob", hash=>$t->{'hash'},
3841                                              file_name=>"$basedir$t->{'name'}", %base_key)},
3842                               "blob");
3843                 if ($have_blame) {
3844                         print " | " .
3845                               $cgi->a({-href => href(action=>"blame", hash=>$t->{'hash'},
3846                                                      file_name=>"$basedir$t->{'name'}", %base_key)},
3847                                       "blame");
3848                 }
3849                 if (defined $hash_base) {
3850                         print " | " .
3851                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3852                                                      hash=>$t->{'hash'}, file_name=>"$basedir$t->{'name'}")},
3853                                       "history");
3854                 }
3855                 print " | " .
3856                         $cgi->a({-href => href(action=>"blob_plain", hash_base=>$hash_base,
3857                                                file_name=>"$basedir$t->{'name'}")},
3858                                 "raw");
3859                 print "</td>\n";
3860
3861         } elsif ($t->{'type'} eq "tree") {
3862                 print "<td class=\"list\">";
3863                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
3864                                              file_name=>"$basedir$t->{'name'}",
3865                                              %base_key)},
3866                               esc_path($t->{'name'}));
3867                 print "</td>\n";
3868                 print "<td class=\"link\">";
3869                 print $cgi->a({-href => href(action=>"tree", hash=>$t->{'hash'},
3870                                              file_name=>"$basedir$t->{'name'}",
3871                                              %base_key)},
3872                               "tree");
3873                 if (defined $hash_base) {
3874                         print " | " .
3875                               $cgi->a({-href => href(action=>"history", hash_base=>$hash_base,
3876                                                      file_name=>"$basedir$t->{'name'}")},
3877                                       "history");
3878                 }
3879                 print "</td>\n";
3880         } else {
3881                 # unknown object: we can only present history for it
3882                 # (this includes 'commit' object, i.e. submodule support)
3883                 print "<td class=\"list\">" .
3884                       esc_path($t->{'name'}) .
3885                       "</td>\n";
3886                 print "<td class=\"link\">";
3887                 if (defined $hash_base) {
3888                         print $cgi->a({-href => href(action=>"history",
3889                                                      hash_base=>$hash_base,
3890                                                      file_name=>"$basedir$t->{'name'}")},
3891                                       "history");
3892                 }
3893                 print "</td>\n";
3894         }
3895 }
3896
3897 ## ......................................................................
3898 ## functions printing large fragments of HTML
3899
3900 # get pre-image filenames for merge (combined) diff
3901 sub fill_from_file_info {
3902         my ($diff, @parents) = @_;
3903
3904         $diff->{'from_file'} = [ ];
3905         $diff->{'from_file'}[$diff->{'nparents'} - 1] = undef;
3906         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
3907                 if ($diff->{'status'}[$i] eq 'R' ||
3908                     $diff->{'status'}[$i] eq 'C') {
3909                         $diff->{'from_file'}[$i] =
3910                                 git_get_path_by_hash($parents[$i], $diff->{'from_id'}[$i]);
3911                 }
3912         }
3913
3914         return $diff;
3915 }
3916
3917 # is current raw difftree line of file deletion
3918 sub is_deleted {
3919         my $diffinfo = shift;
3920
3921         return $diffinfo->{'to_id'} eq ('0' x 40);
3922 }
3923
3924 # does patch correspond to [previous] difftree raw line
3925 # $diffinfo  - hashref of parsed raw diff format
3926 # $patchinfo - hashref of parsed patch diff format
3927 #              (the same keys as in $diffinfo)
3928 sub is_patch_split {
3929         my ($diffinfo, $patchinfo) = @_;
3930
3931         return defined $diffinfo && defined $patchinfo
3932                 && $diffinfo->{'to_file'} eq $patchinfo->{'to_file'};
3933 }
3934
3935
3936 sub git_difftree_body {
3937         my ($difftree, $hash, @parents) = @_;
3938         my ($parent) = $parents[0];
3939         my $have_blame = gitweb_check_feature('blame');
3940         print "<div class=\"list_head\">\n";
3941         if ($#{$difftree} > 10) {
3942                 print(($#{$difftree} + 1) . " files changed:\n");
3943         }
3944         print "</div>\n";
3945
3946         print "<table class=\"" .
3947               (@parents > 1 ? "combined " : "") .
3948               "diff_tree\">\n";
3949
3950         # header only for combined diff in 'commitdiff' view
3951         my $has_header = @$difftree && @parents > 1 && $action eq 'commitdiff';
3952         if ($has_header) {
3953                 # table header
3954                 print "<thead><tr>\n" .
3955                        "<th></th><th></th>\n"; # filename, patchN link
3956                 for (my $i = 0; $i < @parents; $i++) {
3957                         my $par = $parents[$i];
3958                         print "<th>" .
3959                               $cgi->a({-href => href(action=>"commitdiff",
3960                                                      hash=>$hash, hash_parent=>$par),
3961                                        -title => 'commitdiff to parent number ' .
3962                                                   ($i+1) . ': ' . substr($par,0,7)},
3963                                       $i+1) .
3964                               "&nbsp;</th>\n";
3965                 }
3966                 print "</tr></thead>\n<tbody>\n";
3967         }
3968
3969         my $alternate = 1;
3970         my $patchno = 0;
3971         foreach my $line (@{$difftree}) {
3972                 my $diff = parsed_difftree_line($line);
3973
3974                 if ($alternate) {
3975                         print "<tr class=\"dark\">\n";
3976                 } else {
3977                         print "<tr class=\"light\">\n";
3978                 }
3979                 $alternate ^= 1;
3980
3981                 if (exists $diff->{'nparents'}) { # combined diff
3982
3983                         fill_from_file_info($diff, @parents)
3984                                 unless exists $diff->{'from_file'};
3985
3986                         if (!is_deleted($diff)) {
3987                                 # file exists in the result (child) commit
3988                                 print "<td>" .
3989                                       $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
3990                                                              file_name=>$diff->{'to_file'},
3991                                                              hash_base=>$hash),
3992                                               -class => "list"}, esc_path($diff->{'to_file'})) .
3993                                       "</td>\n";
3994                         } else {
3995                                 print "<td>" .
3996                                       esc_path($diff->{'to_file'}) .
3997                                       "</td>\n";
3998                         }
3999
4000                         if ($action eq 'commitdiff') {
4001                                 # link to patch
4002                                 $patchno++;
4003                                 print "<td class=\"link\">" .
4004                                       $cgi->a({-href => "#patch$patchno"}, "patch") .
4005                                       " | " .
4006                                       "</td>\n";
4007                         }
4008
4009                         my $has_history = 0;
4010                         my $not_deleted = 0;
4011                         for (my $i = 0; $i < $diff->{'nparents'}; $i++) {
4012                                 my $hash_parent = $parents[$i];
4013                                 my $from_hash = $diff->{'from_id'}[$i];
4014                                 my $from_path = $diff->{'from_file'}[$i];
4015                                 my $status = $diff->{'status'}[$i];
4016
4017                                 $has_history ||= ($status ne 'A');
4018                                 $not_deleted ||= ($status ne 'D');
4019
4020                                 if ($status eq 'A') {
4021                                         print "<td  class=\"link\" align=\"right\"> | </td>\n";
4022                                 } elsif ($status eq 'D') {
4023                                         print "<td class=\"link\">" .
4024                                               $cgi->a({-href => href(action=>"blob",
4025                                                                      hash_base=>$hash,
4026                                                                      hash=>$from_hash,
4027                                                                      file_name=>$from_path)},
4028                                                       "blob" . ($i+1)) .
4029                                               " | </td>\n";
4030                                 } else {
4031                                         if ($diff->{'to_id'} eq $from_hash) {
4032                                                 print "<td class=\"link nochange\">";
4033                                         } else {
4034                                                 print "<td class=\"link\">";
4035                                         }
4036                                         print $cgi->a({-href => href(action=>"blobdiff",
4037                                                                      hash=>$diff->{'to_id'},
4038                                                                      hash_parent=>$from_hash,
4039                                                                      hash_base=>$hash,
4040                                                                      hash_parent_base=>$hash_parent,
4041                                                                      file_name=>$diff->{'to_file'},
4042                                                                      file_parent=>$from_path)},
4043                                                       "diff" . ($i+1)) .
4044                                               " | </td>\n";
4045                                 }
4046                         }
4047
4048                         print "<td class=\"link\">";
4049                         if ($not_deleted) {
4050                                 print $cgi->a({-href => href(action=>"blob",
4051                                                              hash=>$diff->{'to_id'},
4052                                                              file_name=>$diff->{'to_file'},
4053                                                              hash_base=>$hash)},
4054                                               "blob");
4055                                 print " | " if ($has_history);
4056                         }
4057                         if ($has_history) {
4058                                 print $cgi->a({-href => href(action=>"history",
4059                                                              file_name=>$diff->{'to_file'},
4060                                                              hash_base=>$hash)},
4061                                               "history");
4062                         }
4063                         print "</td>\n";
4064
4065                         print "</tr>\n";
4066                         next; # instead of 'else' clause, to avoid extra indent
4067                 }
4068                 # else ordinary diff
4069
4070                 my ($to_mode_oct, $to_mode_str, $to_file_type);
4071                 my ($from_mode_oct, $from_mode_str, $from_file_type);
4072                 if ($diff->{'to_mode'} ne ('0' x 6)) {
4073                         $to_mode_oct = oct $diff->{'to_mode'};
4074                         if (S_ISREG($to_mode_oct)) { # only for regular file
4075                                 $to_mode_str = sprintf("%04o", $to_mode_oct & 0777); # permission bits
4076                         }
4077                         $to_file_type = file_type($diff->{'to_mode'});
4078                 }
4079                 if ($diff->{'from_mode'} ne ('0' x 6)) {
4080                         $from_mode_oct = oct $diff->{'from_mode'};
4081                         if (S_ISREG($to_mode_oct)) { # only for regular file
4082                                 $from_mode_str = sprintf("%04o", $from_mode_oct & 0777); # permission bits
4083                         }
4084                         $from_file_type = file_type($diff->{'from_mode'});
4085                 }
4086
4087                 if ($diff->{'status'} eq "A") { # created
4088                         my $mode_chng = "<span class=\"file_status new\">[new $to_file_type";
4089                         $mode_chng   .= " with mode: $to_mode_str" if $to_mode_str;
4090                         $mode_chng   .= "]</span>";
4091                         print "<td>";
4092                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4093                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4094                                       -class => "list"}, esc_path($diff->{'file'}));
4095                         print "</td>\n";
4096                         print "<td>$mode_chng</td>\n";
4097                         print "<td class=\"link\">";
4098                         if ($action eq 'commitdiff') {
4099                                 # link to patch
4100                                 $patchno++;
4101                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4102                                 print " | ";
4103                         }
4104                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4105                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4106                                       "blob");
4107                         print "</td>\n";
4108
4109                 } elsif ($diff->{'status'} eq "D") { # deleted
4110                         my $mode_chng = "<span class=\"file_status deleted\">[deleted $from_file_type]</span>";
4111                         print "<td>";
4112                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4113                                                      hash_base=>$parent, file_name=>$diff->{'file'}),
4114                                        -class => "list"}, esc_path($diff->{'file'}));
4115                         print "</td>\n";
4116                         print "<td>$mode_chng</td>\n";
4117                         print "<td class=\"link\">";
4118                         if ($action eq 'commitdiff') {
4119                                 # link to patch
4120                                 $patchno++;
4121                                 print $cgi->a({-href => "#patch$patchno"}, "patch");
4122                                 print " | ";
4123                         }
4124                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'from_id'},
4125                                                      hash_base=>$parent, file_name=>$diff->{'file'})},
4126                                       "blob") . " | ";
4127                         if ($have_blame) {
4128                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$parent,
4129                                                              file_name=>$diff->{'file'})},
4130                                               "blame") . " | ";
4131                         }
4132                         print $cgi->a({-href => href(action=>"history", hash_base=>$parent,
4133                                                      file_name=>$diff->{'file'})},
4134                                       "history");
4135                         print "</td>\n";
4136
4137                 } elsif ($diff->{'status'} eq "M" || $diff->{'status'} eq "T") { # modified, or type changed
4138                         my $mode_chnge = "";
4139                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4140                                 $mode_chnge = "<span class=\"file_status mode_chnge\">[changed";
4141                                 if ($from_file_type ne $to_file_type) {
4142                                         $mode_chnge .= " from $from_file_type to $to_file_type";
4143                                 }
4144                                 if (($from_mode_oct & 0777) != ($to_mode_oct & 0777)) {
4145                                         if ($from_mode_str && $to_mode_str) {
4146                                                 $mode_chnge .= " mode: $from_mode_str->$to_mode_str";
4147                                         } elsif ($to_mode_str) {
4148                                                 $mode_chnge .= " mode: $to_mode_str";
4149                                         }
4150                                 }
4151                                 $mode_chnge .= "]</span>\n";
4152                         }
4153                         print "<td>";
4154                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4155                                                      hash_base=>$hash, file_name=>$diff->{'file'}),
4156                                       -class => "list"}, esc_path($diff->{'file'}));
4157                         print "</td>\n";
4158                         print "<td>$mode_chnge</td>\n";
4159                         print "<td class=\"link\">";
4160                         if ($action eq 'commitdiff') {
4161                                 # link to patch
4162                                 $patchno++;
4163                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4164                                       " | ";
4165                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4166                                 # "commit" view and modified file (not onlu mode changed)
4167                                 print $cgi->a({-href => href(action=>"blobdiff",
4168                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4169                                                              hash_base=>$hash, hash_parent_base=>$parent,
4170                                                              file_name=>$diff->{'file'})},
4171                                               "diff") .
4172                                       " | ";
4173                         }
4174                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4175                                                      hash_base=>$hash, file_name=>$diff->{'file'})},
4176                                        "blob") . " | ";
4177                         if ($have_blame) {
4178                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4179                                                              file_name=>$diff->{'file'})},
4180                                               "blame") . " | ";
4181                         }
4182                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4183                                                      file_name=>$diff->{'file'})},
4184                                       "history");
4185                         print "</td>\n";
4186
4187                 } elsif ($diff->{'status'} eq "R" || $diff->{'status'} eq "C") { # renamed or copied
4188                         my %status_name = ('R' => 'moved', 'C' => 'copied');
4189                         my $nstatus = $status_name{$diff->{'status'}};
4190                         my $mode_chng = "";
4191                         if ($diff->{'from_mode'} != $diff->{'to_mode'}) {
4192                                 # mode also for directories, so we cannot use $to_mode_str
4193                                 $mode_chng = sprintf(", mode: %04o", $to_mode_oct & 0777);
4194                         }
4195                         print "<td>" .
4196                               $cgi->a({-href => href(action=>"blob", hash_base=>$hash,
4197                                                      hash=>$diff->{'to_id'}, file_name=>$diff->{'to_file'}),
4198                                       -class => "list"}, esc_path($diff->{'to_file'})) . "</td>\n" .
4199                               "<td><span class=\"file_status $nstatus\">[$nstatus from " .
4200                               $cgi->a({-href => href(action=>"blob", hash_base=>$parent,
4201                                                      hash=>$diff->{'from_id'}, file_name=>$diff->{'from_file'}),
4202                                       -class => "list"}, esc_path($diff->{'from_file'})) .
4203                               " with " . (int $diff->{'similarity'}) . "% similarity$mode_chng]</span></td>\n" .
4204                               "<td class=\"link\">";
4205                         if ($action eq 'commitdiff') {
4206                                 # link to patch
4207                                 $patchno++;
4208                                 print $cgi->a({-href => "#patch$patchno"}, "patch") .
4209                                       " | ";
4210                         } elsif ($diff->{'to_id'} ne $diff->{'from_id'}) {
4211                                 # "commit" view and modified file (not only pure rename or copy)
4212                                 print $cgi->a({-href => href(action=>"blobdiff",
4213                                                              hash=>$diff->{'to_id'}, hash_parent=>$diff->{'from_id'},
4214                                                              hash_base=>$hash, hash_parent_base=>$parent,
4215                                                              file_name=>$diff->{'to_file'}, file_parent=>$diff->{'from_file'})},
4216                                               "diff") .
4217                                       " | ";
4218                         }
4219                         print $cgi->a({-href => href(action=>"blob", hash=>$diff->{'to_id'},
4220                                                      hash_base=>$parent, file_name=>$diff->{'to_file'})},
4221                                       "blob") . " | ";
4222                         if ($have_blame) {
4223                                 print $cgi->a({-href => href(action=>"blame", hash_base=>$hash,
4224                                                              file_name=>$diff->{'to_file'})},
4225                                               "blame") . " | ";
4226                         }
4227                         print $cgi->a({-href => href(action=>"history", hash_base=>$hash,
4228                                                     file_name=>$diff->{'to_file'})},
4229                                       "history");
4230                         print "</td>\n";
4231
4232                 } # we should not encounter Unmerged (U) or Unknown (X) status
4233                 print "</tr>\n";
4234         }
4235         print "</tbody>" if $has_header;
4236         print "</table>\n";
4237 }
4238
4239 sub git_patchset_body {
4240         my ($fd, $difftree, $hash, @hash_parents) = @_;
4241         my ($hash_parent) = $hash_parents[0];
4242
4243         my $is_combined = (@hash_parents > 1);
4244         my $patch_idx = 0;
4245         my $patch_number = 0;
4246         my $patch_line;
4247         my $diffinfo;
4248         my $to_name;
4249         my (%from, %to);
4250
4251         print "<div class=\"patchset\">\n";
4252
4253         # skip to first patch
4254         while ($patch_line = <$fd>) {
4255                 chomp $patch_line;
4256
4257                 last if ($patch_line =~ m/^diff /);
4258         }
4259
4260  PATCH:
4261         while ($patch_line) {
4262
4263                 # parse "git diff" header line
4264                 if ($patch_line =~ m/^diff --git (\"(?:[^\\\"]*(?:\\.[^\\\"]*)*)\"|[^ "]*) (.*)$/) {
4265                         # $1 is from_name, which we do not use
4266                         $to_name = unquote($2);
4267                         $to_name =~ s!^b/!!;
4268                 } elsif ($patch_line =~ m/^diff --(cc|combined) ("?.*"?)$/) {
4269                         # $1 is 'cc' or 'combined', which we do not use
4270                         $to_name = unquote($2);
4271                 } else {
4272                         $to_name = undef;
4273                 }
4274
4275                 # check if current patch belong to current raw line
4276                 # and parse raw git-diff line if needed
4277                 if (is_patch_split($diffinfo, { 'to_file' => $to_name })) {
4278                         # this is continuation of a split patch
4279                         print "<div class=\"patch cont\">\n";
4280                 } else {
4281                         # advance raw git-diff output if needed
4282                         $patch_idx++ if defined $diffinfo;
4283
4284                         # read and prepare patch information
4285                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4286
4287                         # compact combined diff output can have some patches skipped
4288                         # find which patch (using pathname of result) we are at now;
4289                         if ($is_combined) {
4290                                 while ($to_name ne $diffinfo->{'to_file'}) {
4291                                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4292                                               format_diff_cc_simplified($diffinfo, @hash_parents) .
4293                                               "</div>\n";  # class="patch"
4294
4295                                         $patch_idx++;
4296                                         $patch_number++;
4297
4298                                         last if $patch_idx > $#$difftree;
4299                                         $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4300                                 }
4301                         }
4302
4303                         # modifies %from, %to hashes
4304                         parse_from_to_diffinfo($diffinfo, \%from, \%to, @hash_parents);
4305
4306                         # this is first patch for raw difftree line with $patch_idx index
4307                         # we index @$difftree array from 0, but number patches from 1
4308                         print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n";
4309                 }
4310
4311                 # git diff header
4312                 #assert($patch_line =~ m/^diff /) if DEBUG;
4313                 #assert($patch_line !~ m!$/$!) if DEBUG; # is chomp-ed
4314                 $patch_number++;
4315                 # print "git diff" header
4316                 print format_git_diff_header_line($patch_line, $diffinfo,
4317                                                   \%from, \%to);
4318
4319                 # print extended diff header
4320                 print "<div class=\"diff extended_header\">\n";
4321         EXTENDED_HEADER:
4322                 while ($patch_line = <$fd>) {
4323                         chomp $patch_line;
4324
4325                         last EXTENDED_HEADER if ($patch_line =~ m/^--- |^diff /);
4326
4327                         print format_extended_diff_header_line($patch_line, $diffinfo,
4328                                                                \%from, \%to);
4329                 }
4330                 print "</div>\n"; # class="diff extended_header"
4331
4332                 # from-file/to-file diff header
4333                 if (! $patch_line) {
4334                         print "</div>\n"; # class="patch"
4335                         last PATCH;
4336                 }
4337                 next PATCH if ($patch_line =~ m/^diff /);
4338                 #assert($patch_line =~ m/^---/) if DEBUG;
4339
4340                 my $last_patch_line = $patch_line;
4341                 $patch_line = <$fd>;
4342                 chomp $patch_line;
4343                 #assert($patch_line =~ m/^\+\+\+/) if DEBUG;
4344
4345                 print format_diff_from_to_header($last_patch_line, $patch_line,
4346                                                  $diffinfo, \%from, \%to,
4347                                                  @hash_parents);
4348
4349                 # the patch itself
4350         LINE:
4351                 while ($patch_line = <$fd>) {
4352                         chomp $patch_line;
4353
4354                         next PATCH if ($patch_line =~ m/^diff /);
4355
4356                         print format_diff_line($patch_line, \%from, \%to);
4357                 }
4358
4359         } continue {
4360                 print "</div>\n"; # class="patch"
4361         }
4362
4363         # for compact combined (--cc) format, with chunk and patch simpliciaction
4364         # patchset might be empty, but there might be unprocessed raw lines
4365         for (++$patch_idx if $patch_number > 0;
4366              $patch_idx < @$difftree;
4367              ++$patch_idx) {
4368                 # read and prepare patch information
4369                 $diffinfo = parsed_difftree_line($difftree->[$patch_idx]);
4370
4371                 # generate anchor for "patch" links in difftree / whatchanged part
4372                 print "<div class=\"patch\" id=\"patch". ($patch_idx+1) ."\">\n" .
4373                       format_diff_cc_simplified($diffinfo, @hash_parents) .
4374                       "</div>\n";  # class="patch"
4375
4376                 $patch_number++;
4377         }
4378
4379         if ($patch_number == 0) {
4380                 if (@hash_parents > 1) {
4381                         print "<div class=\"diff nodifferences\">Trivial merge</div>\n";
4382                 } else {
4383                         print "<div class=\"diff nodifferences\">No differences found</div>\n";
4384                 }
4385         }
4386
4387         print "</div>\n"; # class="patchset"
4388 }
4389
4390 # . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . . .
4391
4392 # fills project list info (age, description, owner, forks) for each
4393 # project in the list, removing invalid projects from returned list
4394 # NOTE: modifies $projlist, but does not remove entries from it
4395 sub fill_project_list_info {
4396         my ($projlist, $check_forks) = @_;
4397         my @projects;
4398
4399         my $show_ctags = gitweb_check_feature('ctags');
4400  PROJECT:
4401         foreach my $pr (@$projlist) {
4402                 my (@activity) = git_get_last_activity($pr->{'path'});
4403                 unless (@activity) {
4404                         next PROJECT;
4405                 }
4406                 ($pr->{'age'}, $pr->{'age_string'}) = @activity;
4407                 if (!defined $pr->{'descr'}) {
4408                         my $descr = git_get_project_description($pr->{'path'}) || "";
4409                         $descr = to_utf8($descr);
4410                         $pr->{'descr_long'} = $descr;
4411                         $pr->{'descr'} = chop_str($descr, $projects_list_description_width, 5);
4412                 }
4413                 if (!defined $pr->{'owner'}) {
4414                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}") || "";
4415                 }
4416                 if ($check_forks) {
4417                         my $pname = $pr->{'path'};
4418                         if (($pname =~ s/\.git$//) &&
4419                             ($pname !~ /\/$/) &&
4420                             (-d "$projectroot/$pname")) {
4421                                 $pr->{'forks'} = "-d $projectroot/$pname";
4422                         } else {
4423                                 $pr->{'forks'} = 0;
4424                         }
4425                 }
4426                 $show_ctags and $pr->{'ctags'} = git_get_project_ctags($pr->{'path'});
4427                 push @projects, $pr;
4428         }
4429
4430         return @projects;
4431 }
4432
4433 # print 'sort by' <th> element, generating 'sort by $name' replay link
4434 # if that order is not selected
4435 sub print_sort_th {
4436         print format_sort_th(@_);
4437 }
4438
4439 sub format_sort_th {
4440         my ($name, $order, $header) = @_;
4441         my $sort_th = "";
4442         $header ||= ucfirst($name);
4443
4444         if ($order eq $name) {
4445                 $sort_th .= "<th>$header</th>\n";
4446         } else {
4447                 $sort_th .= "<th>" .
4448                             $cgi->a({-href => href(-replay=>1, order=>$name),
4449                                      -class => "header"}, $header) .
4450                             "</th>\n";
4451         }
4452
4453         return $sort_th;
4454 }
4455
4456 sub git_project_list_body {
4457         # actually uses global variable $project
4458         my ($projlist, $order, $from, $to, $extra, $no_header) = @_;
4459
4460         my $check_forks = gitweb_check_feature('forks');
4461         my @projects = fill_project_list_info($projlist, $check_forks);
4462
4463         $order ||= $default_projects_order;
4464         $from = 0 unless defined $from;
4465         $to = $#projects if (!defined $to || $#projects < $to);
4466
4467         my %order_info = (
4468                 project => { key => 'path', type => 'str' },
4469                 descr => { key => 'descr_long', type => 'str' },
4470                 owner => { key => 'owner', type => 'str' },
4471                 age => { key => 'age', type => 'num' }
4472         );
4473         my $oi = $order_info{$order};
4474         if ($oi->{'type'} eq 'str') {
4475                 @projects = sort {$a->{$oi->{'key'}} cmp $b->{$oi->{'key'}}} @projects;
4476         } else {
4477                 @projects = sort {$a->{$oi->{'key'}} <=> $b->{$oi->{'key'}}} @projects;
4478         }
4479
4480         my $show_ctags = gitweb_check_feature('ctags');
4481         if ($show_ctags) {
4482                 my %ctags;
4483                 foreach my $p (@projects) {
4484                         foreach my $ct (keys %{$p->{'ctags'}}) {
4485                                 $ctags{$ct} += $p->{'ctags'}->{$ct};
4486                         }
4487                 }
4488                 my $cloud = git_populate_project_tagcloud(\%ctags);
4489                 print git_show_project_tagcloud($cloud, 64);
4490         }
4491
4492         print "<table class=\"project_list\">\n";
4493         unless ($no_header) {
4494                 print "<tr>\n";
4495                 if ($check_forks) {
4496                         print "<th></th>\n";
4497                 }
4498                 print_sort_th('project', $order, 'Project');
4499                 print_sort_th('descr', $order, 'Description');
4500                 print_sort_th('owner', $order, 'Owner');
4501                 print_sort_th('age', $order, 'Last Change');
4502                 print "<th></th>\n" . # for links
4503                       "</tr>\n";
4504         }
4505         my $alternate = 1;
4506         my $tagfilter = $cgi->param('by_tag');
4507         for (my $i = $from; $i <= $to; $i++) {
4508                 my $pr = $projects[$i];
4509
4510                 next if $tagfilter and $show_ctags and not grep { lc $_ eq lc $tagfilter } keys %{$pr->{'ctags'}};
4511                 next if $searchtext and not $pr->{'path'} =~ /$searchtext/
4512                         and not $pr->{'descr_long'} =~ /$searchtext/;
4513                 # Weed out forks or non-matching entries of search
4514                 if ($check_forks) {
4515                         my $forkbase = $project; $forkbase ||= ''; $forkbase =~ s#\.git$#/#;
4516                         $forkbase="^$forkbase" if $forkbase;
4517                         next if not $searchtext and not $tagfilter and $show_ctags
4518                                 and $pr->{'path'} =~ m#$forkbase.*/.*#; # regexp-safe
4519                 }
4520
4521                 if ($alternate) {
4522                         print "<tr class=\"dark\">\n";
4523                 } else {
4524                         print "<tr class=\"light\">\n";
4525                 }
4526                 $alternate ^= 1;
4527                 if ($check_forks) {
4528                         print "<td>";
4529                         if ($pr->{'forks'}) {
4530                                 print "<!-- $pr->{'forks'} -->\n";
4531                                 print $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "+");
4532                         }
4533                         print "</td>\n";
4534                 }
4535                 print "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4536                                         -class => "list"}, esc_html($pr->{'path'})) . "</td>\n" .
4537                       "<td>" . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary"),
4538                                         -class => "list", -title => $pr->{'descr_long'}},
4539                                         esc_html($pr->{'descr'})) . "</td>\n" .
4540                       "<td><i>" . chop_and_escape_str($pr->{'owner'}, 15) . "</i></td>\n";
4541                 print "<td class=\"". age_class($pr->{'age'}) . "\">" .
4542                       (defined $pr->{'age_string'} ? $pr->{'age_string'} : "No commits") . "</td>\n" .
4543                       "<td class=\"link\">" .
4544                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"summary")}, "summary")   . " | " .
4545                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"shortlog")}, "shortlog") . " | " .
4546                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"log")}, "log") . " | " .
4547                       $cgi->a({-href => href(project=>$pr->{'path'}, action=>"tree")}, "tree") .
4548                       ($pr->{'forks'} ? " | " . $cgi->a({-href => href(project=>$pr->{'path'}, action=>"forks")}, "forks") : '') .
4549                       "</td>\n" .
4550                       "</tr>\n";
4551         }
4552         if (defined $extra) {
4553                 print "<tr>\n";
4554                 if ($check_forks) {
4555                         print "<td></td>\n";
4556                 }
4557                 print "<td colspan=\"5\">$extra</td>\n" .
4558                       "</tr>\n";
4559         }
4560         print "</table>\n";
4561 }
4562
4563 sub git_log_body {
4564         # uses global variable $project
4565         my ($commitlist, $from, $to, $refs, $extra) = @_;
4566
4567         $from = 0 unless defined $from;
4568         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4569
4570         for (my $i = 0; $i <= $to; $i++) {
4571                 my %co = %{$commitlist->[$i]};
4572                 next if !%co;
4573                 my $commit = $co{'id'};
4574                 my $ref = format_ref_marker($refs, $commit);
4575                 my %ad = parse_date($co{'author_epoch'});
4576                 git_print_header_div('commit',
4577                                "<span class=\"age\">$co{'age_string'}</span>" .
4578                                esc_html($co{'title'}) . $ref,
4579                                $commit);
4580                 print "<div class=\"title_text\">\n" .
4581                       "<div class=\"log_link\">\n" .
4582                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") .
4583                       " | " .
4584                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") .
4585                       " | " .
4586                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree") .
4587                       "<br/>\n" .
4588                       "</div>\n";
4589                       git_print_authorship(\%co, -tag => 'span');
4590                       print "<br/>\n</div>\n";
4591
4592                 print "<div class=\"log_body\">\n";
4593                 git_print_log($co{'comment'}, -final_empty_line=> 1);
4594                 print "</div>\n";
4595         }
4596         if ($extra) {
4597                 print "<div class=\"page_nav\">\n";
4598                 print "$extra\n";
4599                 print "</div>\n";
4600         }
4601 }
4602
4603 sub git_shortlog_body {
4604         # uses global variable $project
4605         my ($commitlist, $from, $to, $refs, $extra) = @_;
4606
4607         $from = 0 unless defined $from;
4608         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4609
4610         print "<table class=\"shortlog\">\n";
4611         my $alternate = 1;
4612         for (my $i = $from; $i <= $to; $i++) {
4613                 my %co = %{$commitlist->[$i]};
4614                 my $commit = $co{'id'};
4615                 my $ref = format_ref_marker($refs, $commit);
4616                 if ($alternate) {
4617                         print "<tr class=\"dark\">\n";
4618                 } else {
4619                         print "<tr class=\"light\">\n";
4620                 }
4621                 $alternate ^= 1;
4622                 # git_summary() used print "<td><i>$co{'age_string'}</i></td>\n" .
4623                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4624                       format_author_html('td', \%co, 10) . "<td>";
4625                 print format_subject_html($co{'title'}, $co{'title_short'},
4626                                           href(action=>"commit", hash=>$commit), $ref);
4627                 print "</td>\n" .
4628                       "<td class=\"link\">" .
4629                       $cgi->a({-href => href(action=>"commit", hash=>$commit)}, "commit") . " | " .
4630                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff") . " | " .
4631                       $cgi->a({-href => href(action=>"tree", hash=>$commit, hash_base=>$commit)}, "tree");
4632                 my $snapshot_links = format_snapshot_links($commit);
4633                 if (defined $snapshot_links) {
4634                         print " | " . $snapshot_links;
4635                 }
4636                 print "</td>\n" .
4637                       "</tr>\n";
4638         }
4639         if (defined $extra) {
4640                 print "<tr>\n" .
4641                       "<td colspan=\"4\">$extra</td>\n" .
4642                       "</tr>\n";
4643         }
4644         print "</table>\n";
4645 }
4646
4647 sub git_history_body {
4648         # Warning: assumes constant type (blob or tree) during history
4649         my ($commitlist, $from, $to, $refs, $extra,
4650             $file_name, $file_hash, $ftype) = @_;
4651
4652         $from = 0 unless defined $from;
4653         $to = $#{$commitlist} unless (defined $to && $to <= $#{$commitlist});
4654
4655         print "<table class=\"history\">\n";
4656         my $alternate = 1;
4657         for (my $i = $from; $i <= $to; $i++) {
4658                 my %co = %{$commitlist->[$i]};
4659                 if (!%co) {
4660                         next;
4661                 }
4662                 my $commit = $co{'id'};
4663
4664                 my $ref = format_ref_marker($refs, $commit);
4665
4666                 if ($alternate) {
4667                         print "<tr class=\"dark\">\n";
4668                 } else {
4669                         print "<tr class=\"light\">\n";
4670                 }
4671                 $alternate ^= 1;
4672                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4673         # shortlog:   format_author_html('td', \%co, 10)
4674                       format_author_html('td', \%co, 15, 3) . "<td>";
4675                 # originally git_history used chop_str($co{'title'}, 50)
4676                 print format_subject_html($co{'title'}, $co{'title_short'},
4677                                           href(action=>"commit", hash=>$commit), $ref);
4678                 print "</td>\n" .
4679                       "<td class=\"link\">" .
4680                       $cgi->a({-href => href(action=>$ftype, hash_base=>$commit, file_name=>$file_name)}, $ftype) . " | " .
4681                       $cgi->a({-href => href(action=>"commitdiff", hash=>$commit)}, "commitdiff");
4682
4683                 if ($ftype eq 'blob') {
4684                         my $blob_current = $file_hash;
4685                         my $blob_parent  = git_get_hash_by_path($commit, $file_name);
4686                         if (defined $blob_current && defined $blob_parent &&
4687                                         $blob_current ne $blob_parent) {
4688                                 print " | " .
4689                                         $cgi->a({-href => href(action=>"blobdiff",
4690                                                                hash=>$blob_current, hash_parent=>$blob_parent,
4691                                                                hash_base=>$hash_base, hash_parent_base=>$commit,
4692                                                                file_name=>$file_name)},
4693                                                 "diff to current");
4694                         }
4695                 }
4696                 print "</td>\n" .
4697                       "</tr>\n";
4698         }
4699         if (defined $extra) {
4700                 print "<tr>\n" .
4701                       "<td colspan=\"4\">$extra</td>\n" .
4702                       "</tr>\n";
4703         }
4704         print "</table>\n";
4705 }
4706
4707 sub git_tags_body {
4708         # uses global variable $project
4709         my ($taglist, $from, $to, $extra) = @_;
4710         $from = 0 unless defined $from;
4711         $to = $#{$taglist} if (!defined $to || $#{$taglist} < $to);
4712
4713         print "<table class=\"tags\">\n";
4714         my $alternate = 1;
4715         for (my $i = $from; $i <= $to; $i++) {
4716                 my $entry = $taglist->[$i];
4717                 my %tag = %$entry;
4718                 my $comment = $tag{'subject'};
4719                 my $comment_short;
4720                 if (defined $comment) {
4721                         $comment_short = chop_str($comment, 30, 5);
4722                 }
4723                 if ($alternate) {
4724                         print "<tr class=\"dark\">\n";
4725                 } else {
4726                         print "<tr class=\"light\">\n";
4727                 }
4728                 $alternate ^= 1;
4729                 if (defined $tag{'age'}) {
4730                         print "<td><i>$tag{'age'}</i></td>\n";
4731                 } else {
4732                         print "<td></td>\n";
4733                 }
4734                 print "<td>" .
4735                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'}),
4736                                -class => "list name"}, esc_html($tag{'name'})) .
4737                       "</td>\n" .
4738                       "<td>";
4739                 if (defined $comment) {
4740                         print format_subject_html($comment, $comment_short,
4741                                                   href(action=>"tag", hash=>$tag{'id'}));
4742                 }
4743                 print "</td>\n" .
4744                       "<td class=\"selflink\">";
4745                 if ($tag{'type'} eq "tag") {
4746                         print $cgi->a({-href => href(action=>"tag", hash=>$tag{'id'})}, "tag");
4747                 } else {
4748                         print "&nbsp;";
4749                 }
4750                 print "</td>\n" .
4751                       "<td class=\"link\">" . " | " .
4752                       $cgi->a({-href => href(action=>$tag{'reftype'}, hash=>$tag{'refid'})}, $tag{'reftype'});
4753                 if ($tag{'reftype'} eq "commit") {
4754                         print " | " . $cgi->a({-href => href(action=>"shortlog", hash=>$tag{'fullname'})}, "shortlog") .
4755                               " | " . $cgi->a({-href => href(action=>"log", hash=>$tag{'fullname'})}, "log");
4756                 } elsif ($tag{'reftype'} eq "blob") {
4757                         print " | " . $cgi->a({-href => href(action=>"blob_plain", hash=>$tag{'refid'})}, "raw");
4758                 }
4759                 print "</td>\n" .
4760                       "</tr>";
4761         }
4762         if (defined $extra) {
4763                 print "<tr>\n" .
4764                       "<td colspan=\"5\">$extra</td>\n" .
4765                       "</tr>\n";
4766         }
4767         print "</table>\n";
4768 }
4769
4770 sub git_heads_body {
4771         # uses global variable $project
4772         my ($headlist, $head, $from, $to, $extra) = @_;
4773         $from = 0 unless defined $from;
4774         $to = $#{$headlist} if (!defined $to || $#{$headlist} < $to);
4775
4776         print "<table class=\"heads\">\n";
4777         my $alternate = 1;
4778         for (my $i = $from; $i <= $to; $i++) {
4779                 my $entry = $headlist->[$i];
4780                 my %ref = %$entry;
4781                 my $curr = $ref{'id'} eq $head;
4782                 if ($alternate) {
4783                         print "<tr class=\"dark\">\n";
4784                 } else {
4785                         print "<tr class=\"light\">\n";
4786                 }
4787                 $alternate ^= 1;
4788                 print "<td><i>$ref{'age'}</i></td>\n" .
4789                       ($curr ? "<td class=\"current_head\">" : "<td>") .
4790                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'}),
4791                                -class => "list name"},esc_html($ref{'name'})) .
4792                       "</td>\n" .
4793                       "<td class=\"link\">" .
4794                       $cgi->a({-href => href(action=>"shortlog", hash=>$ref{'fullname'})}, "shortlog") . " | " .
4795                       $cgi->a({-href => href(action=>"log", hash=>$ref{'fullname'})}, "log") . " | " .
4796                       $cgi->a({-href => href(action=>"tree", hash=>$ref{'fullname'}, hash_base=>$ref{'name'})}, "tree") .
4797                       "</td>\n" .
4798                       "</tr>";
4799         }
4800         if (defined $extra) {
4801                 print "<tr>\n" .
4802                       "<td colspan=\"3\">$extra</td>\n" .
4803                       "</tr>\n";
4804         }
4805         print "</table>\n";
4806 }
4807
4808 sub git_search_grep_body {
4809         my ($commitlist, $from, $to, $extra) = @_;
4810         $from = 0 unless defined $from;
4811         $to = $#{$commitlist} if (!defined $to || $#{$commitlist} < $to);
4812
4813         print "<table class=\"commit_search\">\n";
4814         my $alternate = 1;
4815         for (my $i = $from; $i <= $to; $i++) {
4816                 my %co = %{$commitlist->[$i]};
4817                 if (!%co) {
4818                         next;
4819                 }
4820                 my $commit = $co{'id'};
4821                 if ($alternate) {
4822                         print "<tr class=\"dark\">\n";
4823                 } else {
4824                         print "<tr class=\"light\">\n";
4825                 }
4826                 $alternate ^= 1;
4827                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
4828                       format_author_html('td', \%co, 15, 5) .
4829                       "<td>" .
4830                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
4831                                -class => "list subject"},
4832                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
4833                 my $comment = $co{'comment'};
4834                 foreach my $line (@$comment) {
4835                         if ($line =~ m/^(.*?)($search_regexp)(.*)$/i) {
4836                                 my ($lead, $match, $trail) = ($1, $2, $3);
4837                                 $match = chop_str($match, 70, 5, 'center');
4838                                 my $contextlen = int((80 - length($match))/2);
4839                                 $contextlen = 30 if ($contextlen > 30);
4840                                 $lead  = chop_str($lead,  $contextlen, 10, 'left');
4841                                 $trail = chop_str($trail, $contextlen, 10, 'right');
4842
4843                                 $lead  = esc_html($lead);
4844                                 $match = esc_html($match);
4845                                 $trail = esc_html($trail);
4846
4847                                 print "$lead<span class=\"match\">$match</span>$trail<br />";
4848                         }
4849                 }
4850                 print "</td>\n" .
4851                       "<td class=\"link\">" .
4852                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
4853                       " | " .
4854                       $cgi->a({-href => href(action=>"commitdiff", hash=>$co{'id'})}, "commitdiff") .
4855                       " | " .
4856                       $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
4857                 print "</td>\n" .
4858                       "</tr>\n";
4859         }
4860         if (defined $extra) {
4861                 print "<tr>\n" .
4862                       "<td colspan=\"3\">$extra</td>\n" .
4863                       "</tr>\n";
4864         }
4865         print "</table>\n";
4866 }
4867
4868 ## ======================================================================
4869 ## ======================================================================
4870 ## actions
4871
4872 sub git_project_list {
4873         my $order = $input_params{'order'};
4874         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
4875                 die_error(400, "Unknown order parameter");
4876         }
4877
4878         my @list = git_get_projects_list();
4879         if (!@list) {
4880                 die_error(404, "No projects found");
4881         }
4882
4883         git_header_html();
4884         if (defined $home_text && -f $home_text) {
4885                 print "<div class=\"index_include\">\n";
4886                 insert_file($home_text);
4887                 print "</div>\n";
4888         }
4889         print $cgi->startform(-method => "get") .
4890               "<p class=\"projsearch\">Search:\n" .
4891               $cgi->textfield(-name => "s", -value => $searchtext) . "\n" .
4892               "</p>" .
4893               $cgi->end_form() . "\n";
4894         git_project_list_body(\@list, $order);
4895         git_footer_html();
4896 }
4897
4898 sub git_forks {
4899         my $order = $input_params{'order'};
4900         if (defined $order && $order !~ m/none|project|descr|owner|age/) {
4901                 die_error(400, "Unknown order parameter");
4902         }
4903
4904         my @list = git_get_projects_list($project);
4905         if (!@list) {
4906                 die_error(404, "No forks found");
4907         }
4908
4909         git_header_html();
4910         git_print_page_nav('','');
4911         git_print_header_div('summary', "$project forks");
4912         git_project_list_body(\@list, $order);
4913         git_footer_html();
4914 }
4915
4916 sub git_project_index {
4917         my @projects = git_get_projects_list($project);
4918
4919         print $cgi->header(
4920                 -type => 'text/plain',
4921                 -charset => 'utf-8',
4922                 -content_disposition => 'inline; filename="index.aux"');
4923
4924         foreach my $pr (@projects) {
4925                 if (!exists $pr->{'owner'}) {
4926                         $pr->{'owner'} = git_get_project_owner("$pr->{'path'}");
4927                 }
4928
4929                 my ($path, $owner) = ($pr->{'path'}, $pr->{'owner'});
4930                 # quote as in CGI::Util::encode, but keep the slash, and use '+' for ' '
4931                 $path  =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
4932                 $owner =~ s/([^a-zA-Z0-9_.\-\/ ])/sprintf("%%%02X", ord($1))/eg;
4933                 $path  =~ s/ /\+/g;
4934                 $owner =~ s/ /\+/g;
4935
4936                 print "$path $owner\n";
4937         }
4938 }
4939
4940 sub git_summary {
4941         my $descr = git_get_project_description($project) || "none";
4942         my %co = parse_commit("HEAD");
4943         my %cd = %co ? parse_date($co{'committer_epoch'}, $co{'committer_tz'}) : ();
4944         my $head = $co{'id'};
4945
4946         my $owner = git_get_project_owner($project);
4947
4948         my $refs = git_get_references();
4949         # These get_*_list functions return one more to allow us to see if
4950         # there are more ...
4951         my @taglist  = git_get_tags_list(16);
4952         my @headlist = git_get_heads_list(16);
4953         my @forklist;
4954         my $check_forks = gitweb_check_feature('forks');
4955
4956         if ($check_forks) {
4957                 @forklist = git_get_projects_list($project);
4958         }
4959
4960         git_header_html();
4961         git_print_page_nav('summary','', $head);
4962
4963         print "<div class=\"title\">&nbsp;</div>\n";
4964         print "<table class=\"projects_list\">\n" .
4965               "<tr id=\"metadata_desc\"><td>description</td><td>" . esc_html($descr) . "</td></tr>\n" .
4966               "<tr id=\"metadata_owner\"><td>owner</td><td>" . esc_html($owner) . "</td></tr>\n";
4967         if (defined $cd{'rfc2822'}) {
4968                 print "<tr id=\"metadata_lchange\"><td>last change</td><td>$cd{'rfc2822'}</td></tr>\n";
4969         }
4970
4971         # use per project git URL list in $projectroot/$project/cloneurl
4972         # or make project git URL from git base URL and project name
4973         my $url_tag = "URL";
4974         my @url_list = git_get_project_url_list($project);
4975         @url_list = map { "$_/$project" } @git_base_url_list unless @url_list;
4976         foreach my $git_url (@url_list) {
4977                 next unless $git_url;
4978                 print "<tr class=\"metadata_url\"><td>$url_tag</td><td>$git_url</td></tr>\n";
4979                 $url_tag = "";
4980         }
4981
4982         # Tag cloud
4983         my $show_ctags = gitweb_check_feature('ctags');
4984         if ($show_ctags) {
4985                 my $ctags = git_get_project_ctags($project);
4986                 my $cloud = git_populate_project_tagcloud($ctags);
4987                 print "<tr id=\"metadata_ctags\"><td>Content tags:<br />";
4988                 print "</td>\n<td>" unless %$ctags;
4989                 print "<form action=\"$show_ctags\" method=\"post\"><input type=\"hidden\" name=\"p\" value=\"$project\" />Add: <input type=\"text\" name=\"t\" size=\"8\" /></form>";
4990                 print "</td>\n<td>" if %$ctags;
4991                 print git_show_project_tagcloud($cloud, 48);
4992                 print "</td></tr>";
4993         }
4994
4995         print "</table>\n";
4996
4997         # If XSS prevention is on, we don't include README.html.
4998         # TODO: Allow a readme in some safe format.
4999         if (!$prevent_xss && -s "$projectroot/$project/README.html") {
5000                 print "<div class=\"title\">readme</div>\n" .
5001                       "<div class=\"readme\">\n";
5002                 insert_file("$projectroot/$project/README.html");
5003                 print "\n</div>\n"; # class="readme"
5004         }
5005
5006         # we need to request one more than 16 (0..15) to check if
5007         # those 16 are all
5008         my @commitlist = $head ? parse_commits($head, 17) : ();
5009         if (@commitlist) {
5010                 git_print_header_div('shortlog');
5011                 git_shortlog_body(\@commitlist, 0, 15, $refs,
5012                                   $#commitlist <=  15 ? undef :
5013                                   $cgi->a({-href => href(action=>"shortlog")}, "..."));
5014         }
5015
5016         if (@taglist) {
5017                 git_print_header_div('tags');
5018                 git_tags_body(\@taglist, 0, 15,
5019                               $#taglist <=  15 ? undef :
5020                               $cgi->a({-href => href(action=>"tags")}, "..."));
5021         }
5022
5023         if (@headlist) {
5024                 git_print_header_div('heads');
5025                 git_heads_body(\@headlist, $head, 0, 15,
5026                                $#headlist <= 15 ? undef :
5027                                $cgi->a({-href => href(action=>"heads")}, "..."));
5028         }
5029
5030         if (@forklist) {
5031                 git_print_header_div('forks');
5032                 git_project_list_body(\@forklist, 'age', 0, 15,
5033                                       $#forklist <= 15 ? undef :
5034                                       $cgi->a({-href => href(action=>"forks")}, "..."),
5035                                       'no_header');
5036         }
5037
5038         git_footer_html();
5039 }
5040
5041 sub git_tag {
5042         my $head = git_get_head_hash($project);
5043         git_header_html();
5044         git_print_page_nav('','', $head,undef,$head);
5045         my %tag = parse_tag($hash);
5046
5047         if (! %tag) {
5048                 die_error(404, "Unknown tag object");
5049         }
5050
5051         git_print_header_div('commit', esc_html($tag{'name'}), $hash);
5052         print "<div class=\"title_text\">\n" .
5053               "<table class=\"object_header\">\n" .
5054               "<tr>\n" .
5055               "<td>object</td>\n" .
5056               "<td>" . $cgi->a({-class => "list", -href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5057                                $tag{'object'}) . "</td>\n" .
5058               "<td class=\"link\">" . $cgi->a({-href => href(action=>$tag{'type'}, hash=>$tag{'object'})},
5059                                               $tag{'type'}) . "</td>\n" .
5060               "</tr>\n";
5061         if (defined($tag{'author'})) {
5062                 git_print_authorship_rows(\%tag, 'author');
5063         }
5064         print "</table>\n\n" .
5065               "</div>\n";
5066         print "<div class=\"page_body\">";
5067         my $comment = $tag{'comment'};
5068         foreach my $line (@$comment) {
5069                 chomp $line;
5070                 print esc_html($line, -nbsp=>1) . "<br/>\n";
5071         }
5072         print "</div>\n";
5073         git_footer_html();
5074 }
5075
5076 sub git_blame_common {
5077         my $format = shift || 'porcelain';
5078         if ($format eq 'porcelain' && $cgi->param('js')) {
5079                 $format = 'incremental';
5080                 $action = 'blame_incremental'; # for page title etc
5081         }
5082
5083         # permissions
5084         gitweb_check_feature('blame')
5085                 or die_error(403, "Blame view not allowed");
5086
5087         # error checking
5088         die_error(400, "No file name given") unless $file_name;
5089         $hash_base ||= git_get_head_hash($project);
5090         die_error(404, "Couldn't find base commit") unless $hash_base;
5091         my %co = parse_commit($hash_base)
5092                 or die_error(404, "Commit not found");
5093         my $ftype = "blob";
5094         if (!defined $hash) {
5095                 $hash = git_get_hash_by_path($hash_base, $file_name, "blob")
5096                         or die_error(404, "Error looking up file");
5097         } else {
5098                 $ftype = git_get_type($hash);
5099                 if ($ftype !~ "blob") {
5100                         die_error(400, "Object is not a blob");
5101                 }
5102         }
5103
5104         my $fd;
5105         if ($format eq 'incremental') {
5106                 # get file contents (as base)
5107                 open $fd, "-|", git_cmd(), 'cat-file', 'blob', $hash
5108                         or die_error(500, "Open git-cat-file failed");
5109         } elsif ($format eq 'data') {
5110                 # run git-blame --incremental
5111                 open $fd, "-|", git_cmd(), "blame", "--incremental",
5112                         $hash_base, "--", $file_name
5113                         or die_error(500, "Open git-blame --incremental failed");
5114         } else {
5115                 # run git-blame --porcelain
5116                 open $fd, "-|", git_cmd(), "blame", '-p',
5117                         $hash_base, '--', $file_name
5118                         or die_error(500, "Open git-blame --porcelain failed");
5119         }
5120
5121         # incremental blame data returns early
5122         if ($format eq 'data') {
5123                 print $cgi->header(
5124                         -type=>"text/plain", -charset => "utf-8",
5125                         -status=> "200 OK");
5126                 local $| = 1; # output autoflush
5127                 print while <$fd>;
5128                 close $fd
5129                         or print "ERROR $!\n";
5130
5131                 print 'END';
5132                 if (!$caching_enabled &&
5133                     defined $t0 && gitweb_check_feature('timed')) {
5134                         print ' '.
5135                               Time::HiRes::tv_interval($t0, [Time::HiRes::gettimeofday()]).
5136                               ' '.$number_of_git_cmds;
5137                 }
5138                 print "\n";
5139
5140                 return;
5141         }
5142
5143         # page header
5144         git_header_html();
5145         my $formats_nav =
5146                 $cgi->a({-href => href(action=>"blob", -replay=>1)},
5147                         "blob") .
5148                 " | ";
5149         if ($format eq 'incremental') {
5150                 $formats_nav .=
5151                         $cgi->a({-href => href(action=>"blame", javascript=>0, -replay=>1)},
5152                                 "blame") . " (non-incremental)";
5153         } else {
5154                 $formats_nav .=
5155                         $cgi->a({-href => href(action=>"blame_incremental", -replay=>1)},
5156                                 "blame") . " (incremental)";
5157         }
5158         $formats_nav .=
5159                 " | " .
5160                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5161                         "history") .
5162                 " | " .
5163                 $cgi->a({-href => href(action=>$action, file_name=>$file_name)},
5164                         "HEAD");
5165         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5166         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5167         git_print_page_path($file_name, $ftype, $hash_base);
5168
5169         # page body
5170         if ($format eq 'incremental') {
5171                 print "<noscript>\n<div class=\"error\"><center><b>\n".
5172                       "This page requires JavaScript to run.\n Use ".
5173                       $cgi->a({-href => href(action=>'blame',javascript=>0,-replay=>1)},
5174                               'this page').
5175                       " instead.\n".
5176                       "</b></center></div>\n</noscript>\n";
5177
5178                 print qq!<div id="progress_bar" style="width: 100%; background-color: yellow"></div>\n!;
5179         }
5180
5181         print qq!<div class="page_body">\n!;
5182         print qq!<div id="progress_info">... / ...</div>\n!
5183                 if ($format eq 'incremental');
5184         print qq!<table id="blame_table" class="blame" width="100%">\n!.
5185               #qq!<col width="5.5em" /><col width="2.5em" /><col width="*" />\n!.
5186               qq!<thead>\n!.
5187               qq!<tr><th>Commit</th><th>Line</th><th>Data</th></tr>\n!.
5188               qq!</thead>\n!.
5189               qq!<tbody>\n!;
5190
5191         my @rev_color = qw(light dark);
5192         my $num_colors = scalar(@rev_color);
5193         my $current_color = 0;
5194
5195         if ($format eq 'incremental') {
5196                 my $color_class = $rev_color[$current_color];
5197
5198                 #contents of a file
5199                 my $linenr = 0;
5200         LINE:
5201                 while (my $line = <$fd>) {
5202                         chomp $line;
5203                         $linenr++;
5204
5205                         print qq!<tr id="l$linenr" class="$color_class">!.
5206                               qq!<td class="sha1"><a href=""> </a></td>!.
5207                               qq!<td class="linenr">!.
5208                               qq!<a class="linenr" href="">$linenr</a></td>!;
5209                         print qq!<td class="pre">! . esc_html($line) . "</td>\n";
5210                         print qq!</tr>\n!;
5211                 }
5212
5213         } else { # porcelain, i.e. ordinary blame
5214                 my %metainfo = (); # saves information about commits
5215
5216                 # blame data
5217         LINE:
5218                 while (my $line = <$fd>) {
5219                         chomp $line;
5220                         # the header: <SHA-1> <src lineno> <dst lineno> [<lines in group>]
5221                         # no <lines in group> for subsequent lines in group of lines
5222                         my ($full_rev, $orig_lineno, $lineno, $group_size) =
5223                            ($line =~ /^([0-9a-f]{40}) (\d+) (\d+)(?: (\d+))?$/);
5224                         if (!exists $metainfo{$full_rev}) {
5225                                 $metainfo{$full_rev} = { 'nprevious' => 0 };
5226                         }
5227                         my $meta = $metainfo{$full_rev};
5228                         my $data;
5229                         while ($data = <$fd>) {
5230                                 chomp $data;
5231                                 last if ($data =~ s/^\t//); # contents of line
5232                                 if ($data =~ /^(\S+)(?: (.*))?$/) {
5233                                         $meta->{$1} = $2 unless exists $meta->{$1};
5234                                 }
5235                                 if ($data =~ /^previous /) {
5236                                         $meta->{'nprevious'}++;
5237                                 }
5238                         }
5239                         my $short_rev = substr($full_rev, 0, 8);
5240                         my $author = $meta->{'author'};
5241                         my %date =
5242                                 parse_date($meta->{'author-time'}, $meta->{'author-tz'});
5243                         my $date = $date{'iso-tz'};
5244                         if ($group_size) {
5245                                 $current_color = ($current_color + 1) % $num_colors;
5246                         }
5247                         my $tr_class = $rev_color[$current_color];
5248                         $tr_class .= ' boundary' if (exists $meta->{'boundary'});
5249                         $tr_class .= ' no-previous' if ($meta->{'nprevious'} == 0);
5250                         $tr_class .= ' multiple-previous' if ($meta->{'nprevious'} > 1);
5251                         print "<tr id=\"l$lineno\" class=\"$tr_class\">\n";
5252                         if ($group_size) {
5253                                 print "<td class=\"sha1\"";
5254                                 print " title=\"". esc_html($author) . ", $date\"";
5255                                 print " rowspan=\"$group_size\"" if ($group_size > 1);
5256                                 print ">";
5257                                 print $cgi->a({-href => href(action=>"commit",
5258                                                              hash=>$full_rev,
5259                                                              file_name=>$file_name)},
5260                                               esc_html($short_rev));
5261                                 if ($group_size >= 2) {
5262                                         my @author_initials = ($author =~ /\b([[:upper:]])\B/g);
5263                                         if (@author_initials) {
5264                                                 print "<br />" .
5265                                                       esc_html(join('', @author_initials));
5266                                                 #           or join('.', ...)
5267                                         }
5268                                 }
5269                                 print "</td>\n";
5270                         }
5271                         # 'previous' <sha1 of parent commit> <filename at commit>
5272                         if (exists $meta->{'previous'} &&
5273                             $meta->{'previous'} =~ /^([a-fA-F0-9]{40}) (.*)$/) {
5274                                 $meta->{'parent'} = $1;
5275                                 $meta->{'file_parent'} = unquote($2);
5276                         }
5277                         my $linenr_commit =
5278                                 exists($meta->{'parent'}) ?
5279                                 $meta->{'parent'} : $full_rev;
5280                         my $linenr_filename =
5281                                 exists($meta->{'file_parent'}) ?
5282                                 $meta->{'file_parent'} : unquote($meta->{'filename'});
5283                         my $blamed = href(action => 'blame',
5284                                           file_name => $linenr_filename,
5285                                           hash_base => $linenr_commit);
5286                         print "<td class=\"linenr\">";
5287                         print $cgi->a({ -href => "$blamed#l$orig_lineno",
5288                                         -class => "linenr" },
5289                                       esc_html($lineno));
5290                         print "</td>";
5291                         print "<td class=\"pre\">" . esc_html($data) . "</td>\n";
5292                         print "</tr>\n";
5293                 } # end while
5294
5295         }
5296
5297         # footer
5298         print "</tbody>\n".
5299               "</table>\n"; # class="blame"
5300         print "</div>\n";   # class="blame_body"
5301         close $fd
5302                 or print "Reading blob failed\n";
5303
5304         git_footer_html();
5305 }
5306
5307 sub git_blame {
5308         git_blame_common();
5309 }
5310
5311 sub git_blame_incremental {
5312         git_blame_common('incremental');
5313 }
5314
5315 sub git_blame_data {
5316         git_blame_common('data');
5317 }
5318
5319 sub git_tags {
5320         my $head = git_get_head_hash($project);
5321         git_header_html();
5322         git_print_page_nav('','', $head,undef,$head);
5323         git_print_header_div('summary', $project);
5324
5325         my @tagslist = git_get_tags_list();
5326         if (@tagslist) {
5327                 git_tags_body(\@tagslist);
5328         }
5329         git_footer_html();
5330 }
5331
5332 sub git_heads {
5333         my $head = git_get_head_hash($project);
5334         git_header_html();
5335         git_print_page_nav('','', $head,undef,$head);
5336         git_print_header_div('summary', $project);
5337
5338         my @headslist = git_get_heads_list();
5339         if (@headslist) {
5340                 git_heads_body(\@headslist, $head);
5341         }
5342         git_footer_html();
5343 }
5344
5345 sub git_blob_plain {
5346         my $type = shift;
5347         my $expires;
5348
5349         if (!defined $hash) {
5350                 if (defined $file_name) {
5351                         my $base = $hash_base || git_get_head_hash($project);
5352                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5353                                 or die_error(404, "Cannot find file");
5354                 } else {
5355                         die_error(400, "No file name defined");
5356                 }
5357         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5358                 # blobs defined by non-textual hash id's can be cached
5359                 $expires = "+1d";
5360         }
5361
5362         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5363                 or die_error(500, "Open git-cat-file blob '$hash' failed");
5364
5365         # content-type (can include charset)
5366         $type = blob_contenttype($fd, $file_name, $type);
5367
5368         # "save as" filename, even when no $file_name is given
5369         my $save_as = "$hash";
5370         if (defined $file_name) {
5371                 $save_as = $file_name;
5372         } elsif ($type =~ m/^text\//) {
5373                 $save_as .= '.txt';
5374         }
5375
5376         # With XSS prevention on, blobs of all types except a few known safe
5377         # ones are served with "Content-Disposition: attachment" to make sure
5378         # they don't run in our security domain.  For certain image types,
5379         # blob view writes an <img> tag referring to blob_plain view, and we
5380         # want to be sure not to break that by serving the image as an
5381         # attachment (though Firefox 3 doesn't seem to care).
5382         my $sandbox = $prevent_xss &&
5383                 $type !~ m!^(?:text/plain|image/(?:gif|png|jpeg))$!;
5384
5385         print $cgi->header(
5386                 -type => $type,
5387                 -expires => $expires,
5388                 -content_disposition =>
5389                         ($sandbox ? 'attachment' : 'inline')
5390                         . '; filename="' . $save_as . '"');
5391         local $/ = undef;
5392         binmode STDOUT, ':raw';
5393         print <$fd>;
5394         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5395         close $fd;
5396 }
5397
5398 sub git_blob {
5399         my $expires;
5400
5401         if (!defined $hash) {
5402                 if (defined $file_name) {
5403                         my $base = $hash_base || git_get_head_hash($project);
5404                         $hash = git_get_hash_by_path($base, $file_name, "blob")
5405                                 or die_error(404, "Cannot find file");
5406                 } else {
5407                         die_error(400, "No file name defined");
5408                 }
5409         } elsif ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5410                 # blobs defined by non-textual hash id's can be cached
5411                 $expires = "+1d";
5412         }
5413
5414         my $have_blame = gitweb_check_feature('blame');
5415         open my $fd, "-|", git_cmd(), "cat-file", "blob", $hash
5416                 or die_error(500, "Couldn't cat $file_name, $hash");
5417         my $mimetype = blob_mimetype($fd, $file_name);
5418         if ($mimetype !~ m!^(?:text/|image/(?:gif|png|jpeg)$)! && -B $fd) {
5419                 close $fd;
5420                 return git_blob_plain($mimetype);
5421         }
5422         # we can have blame only for text/* mimetype
5423         $have_blame &&= ($mimetype =~ m!^text/!);
5424
5425         git_header_html(undef, $expires);
5426         my $formats_nav = '';
5427         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5428                 if (defined $file_name) {
5429                         if ($have_blame) {
5430                                 $formats_nav .=
5431                                         $cgi->a({-href => href(action=>"blame", -replay=>1)},
5432                                                 "blame") .
5433                                         " | ";
5434                         }
5435                         $formats_nav .=
5436                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5437                                         "history") .
5438                                 " | " .
5439                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5440                                         "raw") .
5441                                 " | " .
5442                                 $cgi->a({-href => href(action=>"blob",
5443                                                        hash_base=>"HEAD", file_name=>$file_name)},
5444                                         "HEAD");
5445                 } else {
5446                         $formats_nav .=
5447                                 $cgi->a({-href => href(action=>"blob_plain", -replay=>1)},
5448                                         "raw");
5449                 }
5450                 git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
5451                 git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
5452         } else {
5453                 print "<div class=\"page_nav\">\n" .
5454                       "<br/><br/></div>\n" .
5455                       "<div class=\"title\">$hash</div>\n";
5456         }
5457         git_print_page_path($file_name, "blob", $hash_base);
5458         print "<div class=\"page_body\">\n";
5459         if ($mimetype =~ m!^image/!) {
5460                 print qq!<img type="$mimetype"!;
5461                 if ($file_name) {
5462                         print qq! alt="$file_name" title="$file_name"!;
5463                 }
5464                 print qq! src="! .
5465                       href(action=>"blob_plain", hash=>$hash,
5466                            hash_base=>$hash_base, file_name=>$file_name) .
5467                       qq!" />\n!;
5468         } else {
5469                 my $nr;
5470                 while (my $line = <$fd>) {
5471                         chomp $line;
5472                         $nr++;
5473                         $line = untabify($line);
5474                         printf "<div class=\"pre\"><a id=\"l%i\" href=\"" . href(-replay => 1)
5475                                 . "#l%i\" class=\"linenr\">%4i</a> %s</div>\n",
5476                                $nr, $nr, $nr, esc_html($line, -nbsp=>1);
5477                 }
5478         }
5479         close $fd
5480                 or print "Reading blob failed.\n";
5481         print "</div>";
5482         git_footer_html();
5483 }
5484
5485 sub git_tree {
5486         if (!defined $hash_base) {
5487                 $hash_base = "HEAD";
5488         }
5489         if (!defined $hash) {
5490                 if (defined $file_name) {
5491                         $hash = git_get_hash_by_path($hash_base, $file_name, "tree");
5492                 } else {
5493                         $hash = $hash_base;
5494                 }
5495         }
5496         die_error(404, "No such tree") unless defined($hash);
5497
5498         my $show_sizes = gitweb_check_feature('show-sizes');
5499         my $have_blame = gitweb_check_feature('blame');
5500
5501         my @entries = ();
5502         {
5503                 local $/ = "\0";
5504                 open my $fd, "-|", git_cmd(), "ls-tree", '-z',
5505                         ($show_sizes ? '-l' : ()), @extra_options, $hash
5506                         or die_error(500, "Open git-ls-tree failed");
5507                 @entries = map { chomp; $_ } <$fd>;
5508                 close $fd
5509                         or die_error(404, "Reading tree failed");
5510         }
5511
5512         my $refs = git_get_references();
5513         my $ref = format_ref_marker($refs, $hash_base);
5514         git_header_html();
5515         my $basedir = '';
5516         if (defined $hash_base && (my %co = parse_commit($hash_base))) {
5517                 my @views_nav = ();
5518                 if (defined $file_name) {
5519                         push @views_nav,
5520                                 $cgi->a({-href => href(action=>"history", -replay=>1)},
5521                                         "history"),
5522                                 $cgi->a({-href => href(action=>"tree",
5523                                                        hash_base=>"HEAD", file_name=>$file_name)},
5524                                         "HEAD"),
5525                 }
5526                 my $snapshot_links = format_snapshot_links($hash);
5527                 if (defined $snapshot_links) {
5528                         # FIXME: Should be available when we have no hash base as well.
5529                         push @views_nav, $snapshot_links;
5530                 }
5531                 git_print_page_nav('tree','', $hash_base, undef, undef,
5532                                    join(' | ', @views_nav));
5533                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash_base);
5534         } else {
5535                 undef $hash_base;
5536                 print "<div class=\"page_nav\">\n";
5537                 print "<br/><br/></div>\n";
5538                 print "<div class=\"title\">$hash</div>\n";
5539         }
5540         if (defined $file_name) {
5541                 $basedir = $file_name;
5542                 if ($basedir ne '' && substr($basedir, -1) ne '/') {
5543                         $basedir .= '/';
5544                 }
5545                 git_print_page_path($file_name, 'tree', $hash_base);
5546         }
5547         print "<div class=\"page_body\">\n";
5548         print "<table class=\"tree\">\n";
5549         my $alternate = 1;
5550         # '..' (top directory) link if possible
5551         if (defined $hash_base &&
5552             defined $file_name && $file_name =~ m![^/]+$!) {
5553                 if ($alternate) {
5554                         print "<tr class=\"dark\">\n";
5555                 } else {
5556                         print "<tr class=\"light\">\n";
5557                 }
5558                 $alternate ^= 1;
5559
5560                 my $up = $file_name;
5561                 $up =~ s!/?[^/]+$!!;
5562                 undef $up unless $up;
5563                 # based on git_print_tree_entry
5564                 print '<td class="mode">' . mode_str('040000') . "</td>\n";
5565                 print '<td class="size">&nbsp;</td>'."\n" if $show_sizes;
5566                 print '<td class="list">';
5567                 print $cgi->a({-href => href(action=>"tree",
5568                                              hash_base=>$hash_base,
5569                                              file_name=>$up)},
5570                               "..");
5571                 print "</td>\n";
5572                 print "<td class=\"link\"></td>\n";
5573
5574                 print "</tr>\n";
5575         }
5576         foreach my $line (@entries) {
5577                 my %t = parse_ls_tree_line($line, -z => 1, -l => $show_sizes);
5578
5579                 if ($alternate) {
5580                         print "<tr class=\"dark\">\n";
5581                 } else {
5582                         print "<tr class=\"light\">\n";
5583                 }
5584                 $alternate ^= 1;
5585
5586                 git_print_tree_entry(\%t, $basedir, $hash_base, $have_blame);
5587
5588                 print "</tr>\n";
5589         }
5590         print "</table>\n" .
5591               "</div>";
5592         git_footer_html();
5593 }
5594
5595 sub snapshot_name {
5596         my ($project, $hash) = @_;
5597
5598         # path/to/project.git  -> project
5599         # path/to/project/.git -> project
5600         my $name = to_utf8($project);
5601         $name =~ s,([^/])/*\.git$,$1,;
5602         $name = basename($name);
5603         # sanitize name
5604         $name =~ s/[[:cntrl:]]/?/g;
5605
5606         my $ver = $hash;
5607         if ($hash =~ /^[0-9a-fA-F]+$/) {
5608                 # shorten SHA-1 hash
5609                 my $full_hash = git_get_full_hash($project, $hash);
5610                 if ($full_hash =~ /^$hash/ && length($hash) > 7) {
5611                         $ver = git_get_short_hash($project, $hash);
5612                 }
5613         } elsif ($hash =~ m!^refs/tags/(.*)$!) {
5614                 # tags don't need shortened SHA-1 hash
5615                 $ver = $1;
5616         } else {
5617                 # branches and other need shortened SHA-1 hash
5618                 if ($hash =~ m!^refs/(?:heads|remotes)/(.*)$!) {
5619                         $ver = $1;
5620                 }
5621                 $ver .= '-' . git_get_short_hash($project, $hash);
5622         }
5623         # in case of hierarchical branch names
5624         $ver =~ s!/!.!g;
5625
5626         # name = project-version_string
5627         $name = "$name-$ver";
5628
5629         return wantarray ? ($name, $name) : $name;
5630 }
5631
5632 sub git_snapshot {
5633         my $format = $input_params{'snapshot_format'};
5634         if (!@snapshot_fmts) {
5635                 die_error(403, "Snapshots not allowed");
5636         }
5637         # default to first supported snapshot format
5638         $format ||= $snapshot_fmts[0];
5639         if ($format !~ m/^[a-z0-9]+$/) {
5640                 die_error(400, "Invalid snapshot format parameter");
5641         } elsif (!exists($known_snapshot_formats{$format})) {
5642                 die_error(400, "Unknown snapshot format");
5643         } elsif ($known_snapshot_formats{$format}{'disabled'}) {
5644                 die_error(403, "Snapshot format not allowed");
5645         } elsif (!grep($_ eq $format, @snapshot_fmts)) {
5646                 die_error(403, "Unsupported snapshot format");
5647         }
5648
5649         my $type = git_get_type("$hash^{}");
5650         if (!$type) {
5651                 die_error(404, 'Object does not exist');
5652         }  elsif ($type eq 'blob') {
5653                 die_error(400, 'Object is not a tree-ish');
5654         }
5655
5656         my ($name, $prefix) = snapshot_name($project, $hash);
5657         my $filename = "$name$known_snapshot_formats{$format}{'suffix'}";
5658         my $cmd = quote_command(
5659                 git_cmd(), 'archive',
5660                 "--format=$known_snapshot_formats{$format}{'format'}",
5661                 "--prefix=$prefix/", $hash);
5662         if (exists $known_snapshot_formats{$format}{'compressor'}) {
5663                 $cmd .= ' | ' . quote_command(@{$known_snapshot_formats{$format}{'compressor'}});
5664         }
5665
5666         $filename =~ s/(["\\])/\\$1/g;
5667         print $cgi->header(
5668                 -type => $known_snapshot_formats{$format}{'type'},
5669                 -content_disposition => 'inline; filename="' . $filename . '"',
5670                 -status => '200 OK');
5671
5672         open my $fd, "-|", $cmd
5673                 or die_error(500, "Execute git-archive failed");
5674         binmode STDOUT, ':raw';
5675         print <$fd>;
5676         binmode STDOUT, ':utf8'; # as set at the beginning of gitweb.cgi
5677         close $fd;
5678 }
5679
5680 sub git_log_generic {
5681         my ($fmt_name, $body_subr, $base, $parent, $file_name, $file_hash) = @_;
5682
5683         my $head = git_get_head_hash($project);
5684         if (!defined $base) {
5685                 $base = $head;
5686         }
5687         if (!defined $page) {
5688                 $page = 0;
5689         }
5690         my $refs = git_get_references();
5691
5692         my $commit_hash = $base;
5693         if (defined $parent) {
5694                 $commit_hash = "$parent..$base";
5695         }
5696         my @commitlist =
5697                 parse_commits($commit_hash, 101, (100 * $page),
5698                               defined $file_name ? ($file_name, "--full-history") : ());
5699
5700         my $ftype;
5701         if (!defined $file_hash && defined $file_name) {
5702                 # some commits could have deleted file in question,
5703                 # and not have it in tree, but one of them has to have it
5704                 for (my $i = 0; $i < @commitlist; $i++) {
5705                         $file_hash = git_get_hash_by_path($commitlist[$i]{'id'}, $file_name);
5706                         last if defined $file_hash;
5707                 }
5708         }
5709         if (defined $file_hash) {
5710                 $ftype = git_get_type($file_hash);
5711         }
5712         if (defined $file_name && !defined $ftype) {
5713                 die_error(500, "Unknown type of object");
5714         }
5715         my %co;
5716         if (defined $file_name) {
5717                 %co = parse_commit($base)
5718                         or die_error(404, "Unknown commit object");
5719         }
5720
5721
5722         my $paging_nav = format_paging_nav($fmt_name, $page, $#commitlist >= 100);
5723         my $next_link = '';
5724         if ($#commitlist >= 100) {
5725                 $next_link =
5726                         $cgi->a({-href => href(-replay=>1, page=>$page+1),
5727                                  -accesskey => "n", -title => "Alt-n"}, "next");
5728         }
5729         my $patch_max = gitweb_get_feature('patches');
5730         if ($patch_max && !defined $file_name) {
5731                 if ($patch_max < 0 || @commitlist <= $patch_max) {
5732                         $paging_nav .= " &sdot; " .
5733                                 $cgi->a({-href => href(action=>"patches", -replay=>1)},
5734                                         "patches");
5735                 }
5736         }
5737
5738         git_header_html();
5739         git_print_page_nav($fmt_name,'', $hash,$hash,$hash, $paging_nav);
5740         if (defined $file_name) {
5741                 git_print_header_div('commit', esc_html($co{'title'}), $base);
5742         } else {
5743                 git_print_header_div('summary', $project)
5744         }
5745         git_print_page_path($file_name, $ftype, $hash_base)
5746                 if (defined $file_name);
5747
5748         $body_subr->(\@commitlist, 0, 99, $refs, $next_link,
5749                      $file_name, $file_hash, $ftype);
5750
5751         git_footer_html();
5752 }
5753
5754 sub git_log {
5755         git_log_generic('log', \&git_log_body,
5756                         $hash, $hash_parent);
5757 }
5758
5759 sub git_commit {
5760         $hash ||= $hash_base || "HEAD";
5761         my %co = parse_commit($hash)
5762             or die_error(404, "Unknown commit object");
5763
5764         my $parent  = $co{'parent'};
5765         my $parents = $co{'parents'}; # listref
5766
5767         # we need to prepare $formats_nav before any parameter munging
5768         my $formats_nav;
5769         if (!defined $parent) {
5770                 # --root commitdiff
5771                 $formats_nav .= '(initial)';
5772         } elsif (@$parents == 1) {
5773                 # single parent commit
5774                 $formats_nav .=
5775                         '(parent: ' .
5776                         $cgi->a({-href => href(action=>"commit",
5777                                                hash=>$parent)},
5778                                 esc_html(substr($parent, 0, 7))) .
5779                         ')';
5780         } else {
5781                 # merge commit
5782                 $formats_nav .=
5783                         '(merge: ' .
5784                         join(' ', map {
5785                                 $cgi->a({-href => href(action=>"commit",
5786                                                        hash=>$_)},
5787                                         esc_html(substr($_, 0, 7)));
5788                         } @$parents ) .
5789                         ')';
5790         }
5791         if (gitweb_check_feature('patches') && @$parents <= 1) {
5792                 $formats_nav .= " | " .
5793                         $cgi->a({-href => href(action=>"patch", -replay=>1)},
5794                                 "patch");
5795         }
5796
5797         if (!defined $parent) {
5798                 $parent = "--root";
5799         }
5800         my @difftree;
5801         open my $fd, "-|", git_cmd(), "diff-tree", '-r', "--no-commit-id",
5802                 @diff_opts,
5803                 (@$parents <= 1 ? $parent : '-c'),
5804                 $hash, "--"
5805                 or die_error(500, "Open git-diff-tree failed");
5806         @difftree = map { chomp; $_ } <$fd>;
5807         close $fd or die_error(404, "Reading git-diff-tree failed");
5808
5809         # non-textual hash id's can be cached
5810         my $expires;
5811         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
5812                 $expires = "+1d";
5813         }
5814         my $refs = git_get_references();
5815         my $ref = format_ref_marker($refs, $co{'id'});
5816
5817         git_header_html(undef, $expires);
5818         git_print_page_nav('commit', '',
5819                            $hash, $co{'tree'}, $hash,
5820                            $formats_nav);
5821
5822         if (defined $co{'parent'}) {
5823                 git_print_header_div('commitdiff', esc_html($co{'title'}) . $ref, $hash);
5824         } else {
5825                 git_print_header_div('tree', esc_html($co{'title'}) . $ref, $co{'tree'}, $hash);
5826         }
5827         print "<div class=\"title_text\">\n" .
5828               "<table class=\"object_header\">\n";
5829         git_print_authorship_rows(\%co);
5830         print "<tr><td>commit</td><td class=\"sha1\">$co{'id'}</td></tr>\n";
5831         print "<tr>" .
5832               "<td>tree</td>" .
5833               "<td class=\"sha1\">" .
5834               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash),
5835                        class => "list"}, $co{'tree'}) .
5836               "</td>" .
5837               "<td class=\"link\">" .
5838               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$hash)},
5839                       "tree");
5840         my $snapshot_links = format_snapshot_links($hash);
5841         if (defined $snapshot_links) {
5842                 print " | " . $snapshot_links;
5843         }
5844         print "</td>" .
5845               "</tr>\n";
5846
5847         foreach my $par (@$parents) {
5848                 print "<tr>" .
5849                       "<td>parent</td>" .
5850                       "<td class=\"sha1\">" .
5851                       $cgi->a({-href => href(action=>"commit", hash=>$par),
5852                                class => "list"}, $par) .
5853                       "</td>" .
5854                       "<td class=\"link\">" .
5855                       $cgi->a({-href => href(action=>"commit", hash=>$par)}, "commit") .
5856                       " | " .
5857                       $cgi->a({-href => href(action=>"commitdiff", hash=>$hash, hash_parent=>$par)}, "diff") .
5858                       "</td>" .
5859                       "</tr>\n";
5860         }
5861         print "</table>".
5862               "</div>\n";
5863
5864         print "<div class=\"page_body\">\n";
5865         git_print_log($co{'comment'});
5866         print "</div>\n";
5867
5868         git_difftree_body(\@difftree, $hash, @$parents);
5869
5870         git_footer_html();
5871 }
5872
5873 sub git_object {
5874         # object is defined by:
5875         # - hash or hash_base alone
5876         # - hash_base and file_name
5877         my $type;
5878
5879         # - hash or hash_base alone
5880         if ($hash || ($hash_base && !defined $file_name)) {
5881                 my $object_id = $hash || $hash_base;
5882
5883                 open my $fd, "-|", quote_command(
5884                         git_cmd(), 'cat-file', '-t', $object_id) . ' 2> /dev/null'
5885                         or die_error(404, "Object does not exist");
5886                 $type = <$fd>;
5887                 chomp $type;
5888                 close $fd
5889                         or die_error(404, "Object does not exist");
5890
5891         # - hash_base and file_name
5892         } elsif ($hash_base && defined $file_name) {
5893                 $file_name =~ s,/+$,,;
5894
5895                 system(git_cmd(), "cat-file", '-e', $hash_base) == 0
5896                         or die_error(404, "Base object does not exist");
5897
5898                 # here errors should not hapen
5899                 open my $fd, "-|", git_cmd(), "ls-tree", $hash_base, "--", $file_name
5900                         or die_error(500, "Open git-ls-tree failed");
5901                 my $line = <$fd>;
5902                 close $fd;
5903
5904                 #'100644 blob 0fa3f3a66fb6a137f6ec2c19351ed4d807070ffa  panic.c'
5905                 unless ($line && $line =~ m/^([0-9]+) (.+) ([0-9a-fA-F]{40})\t/) {
5906                         die_error(404, "File or directory for given base does not exist");
5907                 }
5908                 $type = $2;
5909                 $hash = $3;
5910         } else {
5911                 die_error(400, "Not enough information to find object");
5912         }
5913
5914         print $cgi->redirect(-uri => href(action=>$type, -full=>1,
5915                                           hash=>$hash, hash_base=>$hash_base,
5916                                           file_name=>$file_name),
5917                              -status => '302 Found');
5918 }
5919
5920 sub git_blobdiff {
5921         my $format = shift || 'html';
5922
5923         my $fd;
5924         my @difftree;
5925         my %diffinfo;
5926         my $expires;
5927
5928         # preparing $fd and %diffinfo for git_patchset_body
5929         # new style URI
5930         if (defined $hash_base && defined $hash_parent_base) {
5931                 if (defined $file_name) {
5932                         # read raw output
5933                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5934                                 $hash_parent_base, $hash_base,
5935                                 "--", (defined $file_parent ? $file_parent : ()), $file_name
5936                                 or die_error(500, "Open git-diff-tree failed");
5937                         @difftree = map { chomp; $_ } <$fd>;
5938                         close $fd
5939                                 or die_error(404, "Reading git-diff-tree failed");
5940                         @difftree
5941                                 or die_error(404, "Blob diff not found");
5942
5943                 } elsif (defined $hash &&
5944                          $hash =~ /[0-9a-fA-F]{40}/) {
5945                         # try to find filename from $hash
5946
5947                         # read filtered raw output
5948                         open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5949                                 $hash_parent_base, $hash_base, "--"
5950                                 or die_error(500, "Open git-diff-tree failed");
5951                         @difftree =
5952                                 # ':100644 100644 03b21826... 3b93d5e7... M     ls-files.c'
5953                                 # $hash == to_id
5954                                 grep { /^:[0-7]{6} [0-7]{6} [0-9a-fA-F]{40} $hash/ }
5955                                 map { chomp; $_ } <$fd>;
5956                         close $fd
5957                                 or die_error(404, "Reading git-diff-tree failed");
5958                         @difftree
5959                                 or die_error(404, "Blob diff not found");
5960
5961                 } else {
5962                         die_error(400, "Missing one of the blob diff parameters");
5963                 }
5964
5965                 if (@difftree > 1) {
5966                         die_error(400, "Ambiguous blob diff specification");
5967                 }
5968
5969                 %diffinfo = parse_difftree_raw_line($difftree[0]);
5970                 $file_parent ||= $diffinfo{'from_file'} || $file_name;
5971                 $file_name   ||= $diffinfo{'to_file'};
5972
5973                 $hash_parent ||= $diffinfo{'from_id'};
5974                 $hash        ||= $diffinfo{'to_id'};
5975
5976                 # non-textual hash id's can be cached
5977                 if ($hash_base =~ m/^[0-9a-fA-F]{40}$/ &&
5978                     $hash_parent_base =~ m/^[0-9a-fA-F]{40}$/) {
5979                         $expires = '+1d';
5980                 }
5981
5982                 # open patch output
5983                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
5984                         '-p', ($format eq 'html' ? "--full-index" : ()),
5985                         $hash_parent_base, $hash_base,
5986                         "--", (defined $file_parent ? $file_parent : ()), $file_name
5987                         or die_error(500, "Open git-diff-tree failed");
5988         }
5989
5990         # old/legacy style URI -- not generated anymore since 1.4.3.
5991         if (!%diffinfo) {
5992                 die_error('404 Not Found', "Missing one of the blob diff parameters")
5993         }
5994
5995         # header
5996         if ($format eq 'html') {
5997                 my $formats_nav =
5998                         $cgi->a({-href => href(action=>"blobdiff_plain", -replay=>1)},
5999                                 "raw");
6000                 git_header_html(undef, $expires);
6001                 if (defined $hash_base && (my %co = parse_commit($hash_base))) {
6002                         git_print_page_nav('','', $hash_base,$co{'tree'},$hash_base, $formats_nav);
6003                         git_print_header_div('commit', esc_html($co{'title'}), $hash_base);
6004                 } else {
6005                         print "<div class=\"page_nav\"><br/>$formats_nav<br/></div>\n";
6006                         print "<div class=\"title\">$hash vs $hash_parent</div>\n";
6007                 }
6008                 if (defined $file_name) {
6009                         git_print_page_path($file_name, "blob", $hash_base);
6010                 } else {
6011                         print "<div class=\"page_path\"></div>\n";
6012                 }
6013
6014         } elsif ($format eq 'plain') {
6015                 print $cgi->header(
6016                         -type => 'text/plain',
6017                         -charset => 'utf-8',
6018                         -expires => $expires,
6019                         -content_disposition => 'inline; filename="' . "$file_name" . '.patch"');
6020
6021                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6022
6023         } else {
6024                 die_error(400, "Unknown blobdiff format");
6025         }
6026
6027         # patch
6028         if ($format eq 'html') {
6029                 print "<div class=\"page_body\">\n";
6030
6031                 git_patchset_body($fd, [ \%diffinfo ], $hash_base, $hash_parent_base);
6032                 close $fd;
6033
6034                 print "</div>\n"; # class="page_body"
6035                 git_footer_html();
6036
6037         } else {
6038                 while (my $line = <$fd>) {
6039                         $line =~ s!a/($hash|$hash_parent)!'a/'.esc_path($diffinfo{'from_file'})!eg;
6040                         $line =~ s!b/($hash|$hash_parent)!'b/'.esc_path($diffinfo{'to_file'})!eg;
6041
6042                         print $line;
6043
6044                         last if $line =~ m!^\+\+\+!;
6045                 }
6046                 local $/ = undef;
6047                 print <$fd>;
6048                 close $fd;
6049         }
6050 }
6051
6052 sub git_blobdiff_plain {
6053         git_blobdiff('plain');
6054 }
6055
6056 sub git_commitdiff {
6057         my %params = @_;
6058         my $format = $params{-format} || 'html';
6059
6060         my ($patch_max) = gitweb_get_feature('patches');
6061         if ($format eq 'patch') {
6062                 die_error(403, "Patch view not allowed") unless $patch_max;
6063         }
6064
6065         $hash ||= $hash_base || "HEAD";
6066         my %co = parse_commit($hash)
6067             or die_error(404, "Unknown commit object");
6068
6069         # choose format for commitdiff for merge
6070         if (! defined $hash_parent && @{$co{'parents'}} > 1) {
6071                 $hash_parent = '--cc';
6072         }
6073         # we need to prepare $formats_nav before almost any parameter munging
6074         my $formats_nav;
6075         if ($format eq 'html') {
6076                 $formats_nav =
6077                         $cgi->a({-href => href(action=>"commitdiff_plain", -replay=>1)},
6078                                 "raw");
6079                 if ($patch_max && @{$co{'parents'}} <= 1) {
6080                         $formats_nav .= " | " .
6081                                 $cgi->a({-href => href(action=>"patch", -replay=>1)},
6082                                         "patch");
6083                 }
6084
6085                 if (defined $hash_parent &&
6086                     $hash_parent ne '-c' && $hash_parent ne '--cc') {
6087                         # commitdiff with two commits given
6088                         my $hash_parent_short = $hash_parent;
6089                         if ($hash_parent =~ m/^[0-9a-fA-F]{40}$/) {
6090                                 $hash_parent_short = substr($hash_parent, 0, 7);
6091                         }
6092                         $formats_nav .=
6093                                 ' (from';
6094                         for (my $i = 0; $i < @{$co{'parents'}}; $i++) {
6095                                 if ($co{'parents'}[$i] eq $hash_parent) {
6096                                         $formats_nav .= ' parent ' . ($i+1);
6097                                         last;
6098                                 }
6099                         }
6100                         $formats_nav .= ': ' .
6101                                 $cgi->a({-href => href(action=>"commitdiff",
6102                                                        hash=>$hash_parent)},
6103                                         esc_html($hash_parent_short)) .
6104                                 ')';
6105                 } elsif (!$co{'parent'}) {
6106                         # --root commitdiff
6107                         $formats_nav .= ' (initial)';
6108                 } elsif (scalar @{$co{'parents'}} == 1) {
6109                         # single parent commit
6110                         $formats_nav .=
6111                                 ' (parent: ' .
6112                                 $cgi->a({-href => href(action=>"commitdiff",
6113                                                        hash=>$co{'parent'})},
6114                                         esc_html(substr($co{'parent'}, 0, 7))) .
6115                                 ')';
6116                 } else {
6117                         # merge commit
6118                         if ($hash_parent eq '--cc') {
6119                                 $formats_nav .= ' | ' .
6120                                         $cgi->a({-href => href(action=>"commitdiff",
6121                                                                hash=>$hash, hash_parent=>'-c')},
6122                                                 'combined');
6123                         } else { # $hash_parent eq '-c'
6124                                 $formats_nav .= ' | ' .
6125                                         $cgi->a({-href => href(action=>"commitdiff",
6126                                                                hash=>$hash, hash_parent=>'--cc')},
6127                                                 'compact');
6128                         }
6129                         $formats_nav .=
6130                                 ' (merge: ' .
6131                                 join(' ', map {
6132                                         $cgi->a({-href => href(action=>"commitdiff",
6133                                                                hash=>$_)},
6134                                                 esc_html(substr($_, 0, 7)));
6135                                 } @{$co{'parents'}} ) .
6136                                 ')';
6137                 }
6138         }
6139
6140         my $hash_parent_param = $hash_parent;
6141         if (!defined $hash_parent_param) {
6142                 # --cc for multiple parents, --root for parentless
6143                 $hash_parent_param =
6144                         @{$co{'parents'}} > 1 ? '--cc' : $co{'parent'} || '--root';
6145         }
6146
6147         # read commitdiff
6148         my $fd;
6149         my @difftree;
6150         if ($format eq 'html') {
6151                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6152                         "--no-commit-id", "--patch-with-raw", "--full-index",
6153                         $hash_parent_param, $hash, "--"
6154                         or die_error(500, "Open git-diff-tree failed");
6155
6156                 while (my $line = <$fd>) {
6157                         chomp $line;
6158                         # empty line ends raw part of diff-tree output
6159                         last unless $line;
6160                         push @difftree, scalar parse_difftree_raw_line($line);
6161                 }
6162
6163         } elsif ($format eq 'plain') {
6164                 open $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6165                         '-p', $hash_parent_param, $hash, "--"
6166                         or die_error(500, "Open git-diff-tree failed");
6167         } elsif ($format eq 'patch') {
6168                 # For commit ranges, we limit the output to the number of
6169                 # patches specified in the 'patches' feature.
6170                 # For single commits, we limit the output to a single patch,
6171                 # diverging from the git-format-patch default.
6172                 my @commit_spec = ();
6173                 if ($hash_parent) {
6174                         if ($patch_max > 0) {
6175                                 push @commit_spec, "-$patch_max";
6176                         }
6177                         push @commit_spec, '-n', "$hash_parent..$hash";
6178                 } else {
6179                         if ($params{-single}) {
6180                                 push @commit_spec, '-1';
6181                         } else {
6182                                 if ($patch_max > 0) {
6183                                         push @commit_spec, "-$patch_max";
6184                                 }
6185                                 push @commit_spec, "-n";
6186                         }
6187                         push @commit_spec, '--root', $hash;
6188                 }
6189                 open $fd, "-|", git_cmd(), "format-patch", '--encoding=utf8',
6190                         '--stdout', @commit_spec
6191                         or die_error(500, "Open git-format-patch failed");
6192         } else {
6193                 die_error(400, "Unknown commitdiff format");
6194         }
6195
6196         # non-textual hash id's can be cached
6197         my $expires;
6198         if ($hash =~ m/^[0-9a-fA-F]{40}$/) {
6199                 $expires = "+1d";
6200         }
6201
6202         # write commit message
6203         if ($format eq 'html') {
6204                 my $refs = git_get_references();
6205                 my $ref = format_ref_marker($refs, $co{'id'});
6206
6207                 git_header_html(undef, $expires);
6208                 git_print_page_nav('commitdiff','', $hash,$co{'tree'},$hash, $formats_nav);
6209                 git_print_header_div('commit', esc_html($co{'title'}) . $ref, $hash);
6210                 print "<div class=\"title_text\">\n" .
6211                       "<table class=\"object_header\">\n";
6212                 git_print_authorship_rows(\%co);
6213                 print "</table>".
6214                       "</div>\n";
6215                 print "<div class=\"page_body\">\n";
6216                 if (@{$co{'comment'}} > 1) {
6217                         print "<div class=\"log\">\n";
6218                         git_print_log($co{'comment'}, -final_empty_line=> 1, -remove_title => 1);
6219                         print "</div>\n"; # class="log"
6220                 }
6221
6222         } elsif ($format eq 'plain') {
6223                 my $refs = git_get_references("tags");
6224                 my $tagname = git_get_rev_name_tags($hash);
6225                 my $filename = basename($project) . "-$hash.patch";
6226
6227                 print $cgi->header(
6228                         -type => 'text/plain',
6229                         -charset => 'utf-8',
6230                         -expires => $expires,
6231                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6232                 my %ad = parse_date($co{'author_epoch'}, $co{'author_tz'});
6233                 print "From: " . to_utf8($co{'author'}) . "\n";
6234                 print "Date: $ad{'rfc2822'} ($ad{'tz_local'})\n";
6235                 print "Subject: " . to_utf8($co{'title'}) . "\n";
6236
6237                 print "X-Git-Tag: $tagname\n" if $tagname;
6238                 print "X-Git-Url: " . $cgi->self_url() . "\n\n";
6239
6240                 foreach my $line (@{$co{'comment'}}) {
6241                         print to_utf8($line) . "\n";
6242                 }
6243                 print "---\n\n";
6244         } elsif ($format eq 'patch') {
6245                 my $filename = basename($project) . "-$hash.patch";
6246
6247                 print $cgi->header(
6248                         -type => 'text/plain',
6249                         -charset => 'utf-8',
6250                         -expires => $expires,
6251                         -content_disposition => 'inline; filename="' . "$filename" . '"');
6252         }
6253
6254         # write patch
6255         if ($format eq 'html') {
6256                 my $use_parents = !defined $hash_parent ||
6257                         $hash_parent eq '-c' || $hash_parent eq '--cc';
6258                 git_difftree_body(\@difftree, $hash,
6259                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6260                 print "<br/>\n";
6261
6262                 git_patchset_body($fd, \@difftree, $hash,
6263                                   $use_parents ? @{$co{'parents'}} : $hash_parent);
6264                 close $fd;
6265                 print "</div>\n"; # class="page_body"
6266                 git_footer_html();
6267
6268         } elsif ($format eq 'plain') {
6269                 local $/ = undef;
6270                 print <$fd>;
6271                 close $fd
6272                         or print "Reading git-diff-tree failed\n";
6273         } elsif ($format eq 'patch') {
6274                 local $/ = undef;
6275                 print <$fd>;
6276                 close $fd
6277                         or print "Reading git-format-patch failed\n";
6278         }
6279 }
6280
6281 sub git_commitdiff_plain {
6282         git_commitdiff(-format => 'plain');
6283 }
6284
6285 # format-patch-style patches
6286 sub git_patch {
6287         git_commitdiff(-format => 'patch', -single => 1);
6288 }
6289
6290 sub git_patches {
6291         git_commitdiff(-format => 'patch');
6292 }
6293
6294 sub git_history {
6295         git_log_generic('history', \&git_history_body,
6296                         $hash_base, $hash_parent_base,
6297                         $file_name, $hash);
6298 }
6299
6300 sub git_search {
6301         gitweb_check_feature('search') or die_error(403, "Search is disabled");
6302         if (!defined $searchtext) {
6303                 die_error(400, "Text field is empty");
6304         }
6305         if (!defined $hash) {
6306                 $hash = git_get_head_hash($project);
6307         }
6308         my %co = parse_commit($hash);
6309         if (!%co) {
6310                 die_error(404, "Unknown commit object");
6311         }
6312         if (!defined $page) {
6313                 $page = 0;
6314         }
6315
6316         $searchtype ||= 'commit';
6317         if ($searchtype eq 'pickaxe') {
6318                 # pickaxe may take all resources of your box and run for several minutes
6319                 # with every query - so decide by yourself how public you make this feature
6320                 gitweb_check_feature('pickaxe')
6321                     or die_error(403, "Pickaxe is disabled");
6322         }
6323         if ($searchtype eq 'grep') {
6324                 gitweb_check_feature('grep')
6325                     or die_error(403, "Grep is disabled");
6326         }
6327
6328         git_header_html();
6329
6330         if ($searchtype eq 'commit' or $searchtype eq 'author' or $searchtype eq 'committer') {
6331                 my $greptype;
6332                 if ($searchtype eq 'commit') {
6333                         $greptype = "--grep=";
6334                 } elsif ($searchtype eq 'author') {
6335                         $greptype = "--author=";
6336                 } elsif ($searchtype eq 'committer') {
6337                         $greptype = "--committer=";
6338                 }
6339                 $greptype .= $searchtext;
6340                 my @commitlist = parse_commits($hash, 101, (100 * $page), undef,
6341                                                $greptype, '--regexp-ignore-case',
6342                                                $search_use_regexp ? '--extended-regexp' : '--fixed-strings');
6343
6344                 my $paging_nav = '';
6345                 if ($page > 0) {
6346                         $paging_nav .=
6347                                 $cgi->a({-href => href(action=>"search", hash=>$hash,
6348                                                        searchtext=>$searchtext,
6349                                                        searchtype=>$searchtype)},
6350                                         "first");
6351                         $paging_nav .= " &sdot; " .
6352                                 $cgi->a({-href => href(-replay=>1, page=>$page-1),
6353                                          -accesskey => "p", -title => "Alt-p"}, "prev");
6354                 } else {
6355                         $paging_nav .= "first";
6356                         $paging_nav .= " &sdot; prev";
6357                 }
6358                 my $next_link = '';
6359                 if ($#commitlist >= 100) {
6360                         $next_link =
6361                                 $cgi->a({-href => href(-replay=>1, page=>$page+1),
6362                                          -accesskey => "n", -title => "Alt-n"}, "next");
6363                         $paging_nav .= " &sdot; $next_link";
6364                 } else {
6365                         $paging_nav .= " &sdot; next";
6366                 }
6367
6368                 if ($#commitlist >= 100) {
6369                 }
6370
6371                 git_print_page_nav('','', $hash,$co{'tree'},$hash, $paging_nav);
6372                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6373                 git_search_grep_body(\@commitlist, 0, 99, $next_link);
6374         }
6375
6376         if ($searchtype eq 'pickaxe') {
6377                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6378                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6379
6380                 print "<table class=\"pickaxe search\">\n";
6381                 my $alternate = 1;
6382                 local $/ = "\n";
6383                 open my $fd, '-|', git_cmd(), '--no-pager', 'log', @diff_opts,
6384                         '--pretty=format:%H', '--no-abbrev', '--raw', "-S$searchtext",
6385                         ($search_use_regexp ? '--pickaxe-regex' : ());
6386                 undef %co;
6387                 my @files;
6388                 while (my $line = <$fd>) {
6389                         chomp $line;
6390                         next unless $line;
6391
6392                         my %set = parse_difftree_raw_line($line);
6393                         if (defined $set{'commit'}) {
6394                                 # finish previous commit
6395                                 if (%co) {
6396                                         print "</td>\n" .
6397                                               "<td class=\"link\">" .
6398                                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6399                                               " | " .
6400                                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6401                                         print "</td>\n" .
6402                                               "</tr>\n";
6403                                 }
6404
6405                                 if ($alternate) {
6406                                         print "<tr class=\"dark\">\n";
6407                                 } else {
6408                                         print "<tr class=\"light\">\n";
6409                                 }
6410                                 $alternate ^= 1;
6411                                 %co = parse_commit($set{'commit'});
6412                                 my $author = chop_and_escape_str($co{'author_name'}, 15, 5);
6413                                 print "<td title=\"$co{'age_string_age'}\"><i>$co{'age_string_date'}</i></td>\n" .
6414                                       "<td><i>$author</i></td>\n" .
6415                                       "<td>" .
6416                                       $cgi->a({-href => href(action=>"commit", hash=>$co{'id'}),
6417                                               -class => "list subject"},
6418                                               chop_and_escape_str($co{'title'}, 50) . "<br/>");
6419                         } elsif (defined $set{'to_id'}) {
6420                                 next if ($set{'to_id'} =~ m/^0{40}$/);
6421
6422                                 print $cgi->a({-href => href(action=>"blob", hash_base=>$co{'id'},
6423                                                              hash=>$set{'to_id'}, file_name=>$set{'to_file'}),
6424                                               -class => "list"},
6425                                               "<span class=\"match\">" . esc_path($set{'file'}) . "</span>") .
6426                                       "<br/>\n";
6427                         }
6428                 }
6429                 close $fd;
6430
6431                 # finish last commit (warning: repetition!)
6432                 if (%co) {
6433                         print "</td>\n" .
6434                               "<td class=\"link\">" .
6435                               $cgi->a({-href => href(action=>"commit", hash=>$co{'id'})}, "commit") .
6436                               " | " .
6437                               $cgi->a({-href => href(action=>"tree", hash=>$co{'tree'}, hash_base=>$co{'id'})}, "tree");
6438                         print "</td>\n" .
6439                               "</tr>\n";
6440                 }
6441
6442                 print "</table>\n";
6443         }
6444
6445         if ($searchtype eq 'grep') {
6446                 git_print_page_nav('','', $hash,$co{'tree'},$hash);
6447                 git_print_header_div('commit', esc_html($co{'title'}), $hash);
6448
6449                 print "<table class=\"grep_search\">\n";
6450                 my $alternate = 1;
6451                 my $matches = 0;
6452                 local $/ = "\n";
6453                 open my $fd, "-|", git_cmd(), 'grep', '-n',
6454                         $search_use_regexp ? ('-E', '-i') : '-F',
6455                         $searchtext, $co{'tree'};
6456                 my $lastfile = '';
6457                 while (my $line = <$fd>) {
6458                         chomp $line;
6459                         my ($file, $lno, $ltext, $binary);
6460                         last if ($matches++ > 1000);
6461                         if ($line =~ /^Binary file (.+) matches$/) {
6462                                 $file = $1;
6463                                 $binary = 1;
6464                         } else {
6465                                 (undef, $file, $lno, $ltext) = split(/:/, $line, 4);
6466                         }
6467                         if ($file ne $lastfile) {
6468                                 $lastfile and print "</td></tr>\n";
6469                                 if ($alternate++) {
6470                                         print "<tr class=\"dark\">\n";
6471                                 } else {
6472                                         print "<tr class=\"light\">\n";
6473                                 }
6474                                 print "<td class=\"list\">".
6475                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6476                                                                file_name=>"$file"),
6477                                                 -class => "list"}, esc_path($file));
6478                                 print "</td><td>\n";
6479                                 $lastfile = $file;
6480                         }
6481                         if ($binary) {
6482                                 print "<div class=\"binary\">Binary file</div>\n";
6483                         } else {
6484                                 $ltext = untabify($ltext);
6485                                 if ($ltext =~ m/^(.*)($search_regexp)(.*)$/i) {
6486                                         $ltext = esc_html($1, -nbsp=>1);
6487                                         $ltext .= '<span class="match">';
6488                                         $ltext .= esc_html($2, -nbsp=>1);
6489                                         $ltext .= '</span>';
6490                                         $ltext .= esc_html($3, -nbsp=>1);
6491                                 } else {
6492                                         $ltext = esc_html($ltext, -nbsp=>1);
6493                                 }
6494                                 print "<div class=\"pre\">" .
6495                                         $cgi->a({-href => href(action=>"blob", hash=>$co{'hash'},
6496                                                                file_name=>"$file").'#l'.$lno,
6497                                                 -class => "linenr"}, sprintf('%4i', $lno))
6498                                         . ' ' .  $ltext . "</div>\n";
6499                         }
6500                 }
6501                 if ($lastfile) {
6502                         print "</td></tr>\n";
6503                         if ($matches > 1000) {
6504                                 print "<div class=\"diff nodifferences\">Too many matches, listing trimmed</div>\n";
6505                         }
6506                 } else {
6507                         print "<div class=\"diff nodifferences\">No matches found</div>\n";
6508                 }
6509                 close $fd;
6510
6511                 print "</table>\n";
6512         }
6513         git_footer_html();
6514 }
6515
6516 sub git_search_help {
6517         git_header_html();
6518         git_print_page_nav('','', $hash,$hash,$hash);
6519         print <<EOT;
6520 <p><strong>Pattern</strong> is by default a normal string that is matched precisely (but without
6521 regard to case, except in the case of pickaxe). However, when you check the <em>re</em> checkbox,
6522 the pattern entered is recognized as the POSIX extended
6523 <a href="http://en.wikipedia.org/wiki/Regular_expression">regular expression</a> (also case
6524 insensitive).</p>
6525 <dl>
6526 <dt><b>commit</b></dt>
6527 <dd>The commit messages and authorship information will be scanned for the given pattern.</dd>
6528 EOT
6529         my $have_grep = gitweb_check_feature('grep');
6530         if ($have_grep) {
6531                 print <<EOT;
6532 <dt><b>grep</b></dt>
6533 <dd>All files in the currently selected tree (HEAD unless you are explicitly browsing
6534     a different one) are searched for the given pattern. On large trees, this search can take
6535 a while and put some strain on the server, so please use it with some consideration. Note that
6536 due to git-grep peculiarity, currently if regexp mode is turned off, the matches are
6537 case-sensitive.</dd>
6538 EOT
6539         }
6540         print <<EOT;
6541 <dt><b>author</b></dt>
6542 <dd>Name and e-mail of the change author and date of birth of the patch will be scanned for the given pattern.</dd>
6543 <dt><b>committer</b></dt>
6544 <dd>Name and e-mail of the committer and date of commit will be scanned for the given pattern.</dd>
6545 EOT
6546         my $have_pickaxe = gitweb_check_feature('pickaxe');
6547         if ($have_pickaxe) {
6548                 print <<EOT;
6549 <dt><b>pickaxe</b></dt>
6550 <dd>All commits that caused the string to appear or disappear from any file (changes that
6551 added, removed or "modified" the string) will be listed. This search can take a while and
6552 takes a lot of strain on the server, so please use it wisely. Note that since you may be
6553 interested even in changes just changing the case as well, this search is case sensitive.</dd>
6554 EOT
6555         }
6556         print "</dl>\n";
6557         git_footer_html();
6558 }
6559
6560 sub git_shortlog {
6561         git_log_generic('shortlog', \&git_shortlog_body,
6562                         $hash, $hash_parent);
6563 }
6564
6565 ## ......................................................................
6566 ## feeds (RSS, Atom; OPML)
6567
6568 sub git_feed {
6569         my $format = shift || 'atom';
6570         my $have_blame = gitweb_check_feature('blame');
6571
6572         # Atom: http://www.atomenabled.org/developers/syndication/
6573         # RSS:  http://www.notestips.com/80256B3A007F2692/1/NAMO5P9UPQ
6574         if ($format ne 'rss' && $format ne 'atom') {
6575                 die_error(400, "Unknown web feed format");
6576         }
6577
6578         # log/feed of current (HEAD) branch, log of given branch, history of file/directory
6579         my $head = $hash || 'HEAD';
6580         my @commitlist = parse_commits($head, 150, 0, $file_name);
6581
6582         my %latest_commit;
6583         my %latest_date;
6584         my $content_type = "application/$format+xml";
6585         if (defined $cgi->http('HTTP_ACCEPT') &&
6586                  $cgi->Accept('text/xml') > $cgi->Accept($content_type)) {
6587                 # browser (feed reader) prefers text/xml
6588                 $content_type = 'text/xml';
6589         }
6590         if (defined($commitlist[0])) {
6591                 %latest_commit = %{$commitlist[0]};
6592                 my $latest_epoch = $latest_commit{'committer_epoch'};
6593                 %latest_date   = parse_date($latest_epoch);
6594                 my $if_modified = $cgi->http('IF_MODIFIED_SINCE');
6595                 if (defined $if_modified) {
6596                         my $since;
6597                         if (eval { require HTTP::Date; 1; }) {
6598                                 $since = HTTP::Date::str2time($if_modified);
6599                         } elsif (eval { require Time::ParseDate; 1; }) {
6600                                 $since = Time::ParseDate::parsedate($if_modified, GMT => 1);
6601                         }
6602                         if (defined $since && $latest_epoch <= $since) {
6603                                 print $cgi->header(
6604                                         -type => $content_type,
6605                                         -charset => 'utf-8',
6606                                         -last_modified => $latest_date{'rfc2822'},
6607                                         -status => '304 Not Modified');
6608                                 return;
6609                         }
6610                 }
6611                 print $cgi->header(
6612                         -type => $content_type,
6613                         -charset => 'utf-8',
6614                         -last_modified => $latest_date{'rfc2822'});
6615         } else {
6616                 print $cgi->header(
6617                         -type => $content_type,
6618                         -charset => 'utf-8');
6619         }
6620
6621         # Optimization: skip generating the body if client asks only
6622         # for Last-Modified date.
6623         return if ($cgi->request_method() eq 'HEAD');
6624
6625         # header variables
6626         my $title = "$site_name - $project/$action";
6627         my $feed_type = 'log';
6628         if (defined $hash) {
6629                 $title .= " - '$hash'";
6630                 $feed_type = 'branch log';
6631                 if (defined $file_name) {
6632                         $title .= " :: $file_name";
6633                         $feed_type = 'history';
6634                 }
6635         } elsif (defined $file_name) {
6636                 $title .= " - $file_name";
6637                 $feed_type = 'history';
6638         }
6639         $title .= " $feed_type";
6640         my $descr = git_get_project_description($project);
6641         if (defined $descr) {
6642                 $descr = esc_html($descr);
6643         } else {
6644                 $descr = "$project " .
6645                          ($format eq 'rss' ? 'RSS' : 'Atom') .
6646                          " feed";
6647         }
6648         my $owner = git_get_project_owner($project);
6649         $owner = esc_html($owner);
6650
6651         #header
6652         my $alt_url;
6653         if (defined $file_name) {
6654                 $alt_url = href(-full=>1, action=>"history", hash=>$hash, file_name=>$file_name);
6655         } elsif (defined $hash) {
6656                 $alt_url = href(-full=>1, action=>"log", hash=>$hash);
6657         } else {
6658                 $alt_url = href(-full=>1, action=>"summary");
6659         }
6660         print qq!<?xml version="1.0" encoding="utf-8"?>\n!;
6661         if ($format eq 'rss') {
6662                 print <<XML;
6663 <rss version="2.0" xmlns:content="http://purl.org/rss/1.0/modules/content/">
6664 <channel>
6665 XML
6666                 print "<title>$title</title>\n" .
6667                       "<link>$alt_url</link>\n" .
6668                       "<description>$descr</description>\n" .
6669                       "<language>en</language>\n" .
6670                       # project owner is responsible for 'editorial' content
6671                       "<managingEditor>$owner</managingEditor>\n";
6672                 if (defined $logo || defined $favicon) {
6673                         # prefer the logo to the favicon, since RSS
6674                         # doesn't allow both
6675                         my $img = esc_url($logo || $favicon);
6676                         print "<image>\n" .
6677                               "<url>$img</url>\n" .
6678                               "<title>$title</title>\n" .
6679                               "<link>$alt_url</link>\n" .
6680                               "</image>\n";
6681                 }
6682                 if (%latest_date) {
6683                         print "<pubDate>$latest_date{'rfc2822'}</pubDate>\n";
6684                         print "<lastBuildDate>$latest_date{'rfc2822'}</lastBuildDate>\n";
6685                 }
6686                 print "<generator>gitweb v.$version/$git_version</generator>\n";
6687         } elsif ($format eq 'atom') {
6688                 print <<XML;
6689 <feed xmlns="http://www.w3.org/2005/Atom">
6690 XML
6691                 print "<title>$title</title>\n" .
6692                       "<subtitle>$descr</subtitle>\n" .
6693                       '<link rel="alternate" type="text/html" href="' .
6694                       $alt_url . '" />' . "\n" .
6695                       '<link rel="self" type="' . $content_type . '" href="' .
6696                       $cgi->self_url() . '" />' . "\n" .
6697                       "<id>" . href(-full=>1) . "</id>\n" .
6698                       # use project owner for feed author
6699                       "<author><name>$owner</name></author>\n";
6700                 if (defined $favicon) {
6701                         print "<icon>" . esc_url($favicon) . "</icon>\n";
6702                 }
6703                 if (defined $logo_url) {
6704                         # not twice as wide as tall: 72 x 27 pixels
6705                         print "<logo>" . esc_url($logo) . "</logo>\n";
6706                 }
6707                 if (! %latest_date) {
6708                         # dummy date to keep the feed valid until commits trickle in:
6709                         print "<updated>1970-01-01T00:00:00Z</updated>\n";
6710                 } else {
6711                         print "<updated>$latest_date{'iso-8601'}</updated>\n";
6712                 }
6713                 print "<generator version='$version/$git_version'>gitweb</generator>\n";
6714         }
6715
6716         # contents
6717         for (my $i = 0; $i <= $#commitlist; $i++) {
6718                 my %co = %{$commitlist[$i]};
6719                 my $commit = $co{'id'};
6720                 # we read 150, we always show 30 and the ones more recent than 48 hours
6721                 if (($i >= 20) && ((time - $co{'author_epoch'}) > 48*60*60)) {
6722                         last;
6723                 }
6724                 my %cd = parse_date($co{'author_epoch'});
6725
6726                 # get list of changed files
6727                 open my $fd, "-|", git_cmd(), "diff-tree", '-r', @diff_opts,
6728                         $co{'parent'} || "--root",
6729                         $co{'id'}, "--", (defined $file_name ? $file_name : ())
6730                         or next;
6731                 my @difftree = map { chomp; $_ } <$fd>;
6732                 close $fd
6733                         or next;
6734
6735                 # print element (entry, item)
6736                 my $co_url = href(-full=>1, action=>"commitdiff", hash=>$commit);
6737                 if ($format eq 'rss') {
6738                         print "<item>\n" .
6739                               "<title>" . esc_html($co{'title'}) . "</title>\n" .
6740                               "<author>" . esc_html($co{'author'}) . "</author>\n" .
6741                               "<pubDate>$cd{'rfc2822'}</pubDate>\n" .
6742                               "<guid isPermaLink=\"true\">$co_url</guid>\n" .
6743                               "<link>$co_url</link>\n" .
6744                               "<description>" . esc_html($co{'title'}) . "</description>\n" .
6745                               "<content:encoded>" .
6746                               "<![CDATA[\n";
6747                 } elsif ($format eq 'atom') {
6748                         print "<entry>\n" .
6749                               "<title type=\"html\">" . esc_html($co{'title'}) . "</title>\n" .
6750                               "<updated>$cd{'iso-8601'}</updated>\n" .
6751                               "<author>\n" .
6752                               "  <name>" . esc_html($co{'author_name'}) . "</name>\n";
6753                         if ($co{'author_email'}) {
6754                                 print "  <email>" . esc_html($co{'author_email'}) . "</email>\n";
6755                         }
6756                         print "</author>\n" .
6757                               # use committer for contributor
6758                               "<contributor>\n" .
6759                               "  <name>" . esc_html($co{'committer_name'}) . "</name>\n";
6760                         if ($co{'committer_email'}) {
6761                                 print "  <email>" . esc_html($co{'committer_email'}) . "</email>\n";
6762                         }
6763                         print "</contributor>\n" .
6764                               "<published>$cd{'iso-8601'}</published>\n" .
6765                               "<link rel=\"alternate\" type=\"text/html\" href=\"$co_url\" />\n" .
6766                               "<id>$co_url</id>\n" .
6767                               "<content type=\"xhtml\" xml:base=\"" . esc_url($my_url) . "\">\n" .
6768                               "<div xmlns=\"http://www.w3.org/1999/xhtml\">\n";
6769                 }
6770                 my $comment = $co{'comment'};
6771                 print "<pre>\n";
6772                 foreach my $line (@$comment) {
6773                         $line = esc_html($line);
6774                         print "$line\n";
6775                 }
6776                 print "</pre><ul>\n";
6777                 foreach my $difftree_line (@difftree) {
6778                         my %difftree = parse_difftree_raw_line($difftree_line);
6779                         next if !$difftree{'from_id'};
6780
6781                         my $file = $difftree{'file'} || $difftree{'to_file'};
6782
6783                         print "<li>" .
6784                               "[" .
6785                               $cgi->a({-href => href(-full=>1, action=>"blobdiff",
6786                                                      hash=>$difftree{'to_id'}, hash_parent=>$difftree{'from_id'},
6787                                                      hash_base=>$co{'id'}, hash_parent_base=>$co{'parent'},
6788                                                      file_name=>$file, file_parent=>$difftree{'from_file'}),
6789                                       -title => "diff"}, 'D');
6790                         if ($have_blame) {
6791                                 print $cgi->a({-href => href(-full=>1, action=>"blame",
6792                                                              file_name=>$file, hash_base=>$commit),
6793                                               -title => "blame"}, 'B');
6794                         }
6795                         # if this is not a feed of a file history
6796                         if (!defined $file_name || $file_name ne $file) {
6797                                 print $cgi->a({-href => href(-full=>1, action=>"history",
6798                                                              file_name=>$file, hash=>$commit),
6799                                               -title => "history"}, 'H');
6800                         }
6801                         $file = esc_path($file);
6802                         print "] ".
6803                               "$file</li>\n";
6804                 }
6805                 if ($format eq 'rss') {
6806                         print "</ul>]]>\n" .
6807                               "</content:encoded>\n" .
6808                               "</item>\n";
6809                 } elsif ($format eq 'atom') {
6810                         print "</ul>\n</div>\n" .
6811                               "</content>\n" .
6812                               "</entry>\n";
6813                 }
6814         }
6815
6816         # end of feed
6817         if ($format eq 'rss') {
6818                 print "</channel>\n</rss>\n";
6819         } elsif ($format eq 'atom') {
6820                 print "</feed>\n";
6821         }
6822 }
6823
6824 sub git_rss {
6825         git_feed('rss');
6826 }
6827
6828 sub git_atom {
6829         git_feed('atom');
6830 }
6831
6832 sub git_opml {
6833         my @list = git_get_projects_list();
6834
6835         print $cgi->header(
6836                 -type => 'text/xml',
6837                 -charset => 'utf-8',
6838                 -content_disposition => 'inline; filename="opml.xml"');
6839
6840         print <<XML;
6841 <?xml version="1.0" encoding="utf-8"?>
6842 <opml version="1.0">
6843 <head>
6844   <title>$site_name OPML Export</title>
6845 </head>
6846 <body>
6847 <outline text="git RSS feeds">
6848 XML
6849
6850         foreach my $pr (@list) {
6851                 my %proj = %$pr;
6852                 my $head = git_get_head_hash($proj{'path'});
6853                 if (!defined $head) {
6854                         next;
6855                 }
6856                 $git_dir = "$projectroot/$proj{'path'}";
6857                 my %co = parse_commit($head);
6858                 if (!%co) {
6859                         next;
6860                 }
6861
6862                 my $path = esc_html(chop_str($proj{'path'}, 25, 5));
6863                 my $rss  = href('project' => $proj{'path'}, 'action' => 'rss', -full => 1);
6864                 my $html = href('project' => $proj{'path'}, 'action' => 'summary', -full => 1);
6865                 print "<outline type=\"rss\" text=\"$path\" title=\"$path\" xmlUrl=\"$rss\" htmlUrl=\"$html\"/>\n";
6866         }
6867         print <<XML;
6868 </outline>
6869 </body>
6870 </opml>
6871 XML
6872 }