Girocco/Util.pm

   1 package Girocco::Util;
   2
   3 use strict;
   4 use warnings;
   5
   6 use Girocco::Config;
   7 use Time::Local;
   8
   9 BEGIN {
  10         use base qw(Exporter);
  11         our @EXPORT = qw(scrypt jailed_file sendmail_pipe mailer_pipe
  12                          lock_file unlock_file valid_tag rand_adjust
  13                          filedb_atomic_append filedb_atomic_edit filedb_grep
  14                          filedb_atomic_grep valid_email valid_email_multi
  15                          valid_repo_url valid_web_url url_base url_path url_server
  16                          projects_html_list parse_rfc2822_date parse_any_date);
  17 }
  18
  19
  20 sub scrypt {
  21         my ($pwd) = @_;
  22         crypt($pwd||'', join ('', ('.', '/', 0..9, 'A'..'Z', 'a'..'z')[rand 64, rand 64]));
  23 }
  24
  25 sub jailed_file {
  26         my ($filename) = @_;
  27         $filename =~ s,^/,,;
  28         $Girocco::Config::chroot."/$filename";
  29 }
  30
  31 sub lock_file {
  32         my ($path) = @_;
  33
  34         $path .= '.lock';
  35
  36         use Errno qw(EEXIST);
  37         use Fcntl qw(O_WRONLY O_CREAT O_EXCL);
  38         use IO::Handle;
  39         my $handle = new IO::Handle;
  40
  41         unless (sysopen($handle, $path, O_WRONLY|O_CREAT|O_EXCL)) {
  42                 my $cnt = 0;
  43                 while (not sysopen($handle, $path, O_WRONLY|O_CREAT|O_EXCL)) {
  44                         ($! == EEXIST) or die "$path open failed: $!";
  45                         ($cnt++ < 16) or die "$path open failed: cannot open lockfile";
  46                         sleep(1);
  47                 }
  48         }
  49         # XXX: filedb-specific
  50         chmod 0664, $path or die "$path g+w failed: $!";
  51
  52         $handle;
  53 }
  54
  55 sub _is_passwd_file {
  56         return defined($_[0]) && $_[0] eq jailed_file('/etc/passwd');
  57 }
  58
  59 sub _run_update_pwd_db {
  60         my ($path, $updatearg) = @_;
  61         my @cmd = ($Girocco::Config::basedir.'/bin/update-pwd-db', "$path");
  62         push(@cmd, $updatearg) if $updatearg;
  63         system(@cmd) == 0 or die "update-pwd-db failed: $?";
  64 }
  65
  66 sub unlock_file {
  67         my ($path, $noreplace, $updatearg) = @_;
  68
  69         if (!$noreplace) {
  70                 _run_update_pwd_db("$path.lock", $updatearg)
  71                         if $Girocco::Config::update_pwd_db && _is_passwd_file($path);
  72                 rename "$path.lock", $path or die "$path unlock failed: $!";
  73         } else {
  74                 unlink "$path.lock" or die "$path unlock failed: $!";
  75         }
  76 }
  77
  78 sub filedb_atomic_append {
  79         my ($file, $line, $updatearg) = @_;
  80         my $id = 65536;
  81
  82         open my $src, '<', $file or die "$file open for reading failed: $!";
  83         my $dst = lock_file($file);
  84
  85         while (<$src>) {
  86                 my $aid = (split /:/)[2];
  87                 $id = $aid + 1 if ($aid >= $id);
  88
  89                 print $dst $_ or die "$file(l) write failed: $!";
  90         }
  91
  92         $line =~ s/\\i/$id/g;
  93         print $dst "$line\n" or die "$file(l) write failed: $!";
  94
  95         close $dst or die "$file(l) close failed: $!";
  96         close $src;
  97
  98         unlock_file($file, 0, $updatearg);
  99
 100         $id;
 101 }
 102
 103 sub filedb_atomic_edit {
 104         my ($file, $fn, $updatearg) = @_;
 105
 106         open my $src, '<', $file or die "$file open for reading failed: $!";
 107         my $dst = lock_file($file);
 108
 109         while (<$src>) {
 110                 print $dst $fn->($_) or die "$file(l) write failed: $!";
 111         }
 112
 113         close $dst or die "$file(l) close failed: $!";
 114         close $src;
 115
 116         unlock_file($file, 0, $updatearg);
 117 }
 118
 119 sub filedb_atomic_grep {
 120         my ($file, $fn) = @_;
 121         my @results = ();
 122
 123         open my $src, '<', $file or die "$file open for reading failed: $!";
 124         my $dst = lock_file($file);
 125
 126         while (<$src>) {
 127                 my $result = $fn->($_);
 128                 push(@results, $result) if $result;
 129         }
 130
 131         close $dst or die "$file(l) close failed: $!";
 132         close $src;
 133
 134         unlock_file($file, 1);
 135         return @results;
 136 }
 137
 138 sub filedb_grep {
 139         my ($file, $fn) = @_;
 140         my @results = ();
 141
 142         open my $src, '<', $file or die "$file open for reading failed: $!";
 143
 144         while (<$src>) {
 145                 my $result = $fn->($_);
 146                 push(@results, $result) if $result;
 147         }
 148
 149         close $src;
 150
 151         return @results;
 152 }
 153
 154 sub valid_email {
 155         local $_ = $_[0];
 156         /^[a-zA-Z0-9+._-]+@[a-zA-Z0-9.-]+$/;
 157 }
 158 sub valid_email_multi {
 159         local $_ = $_[0];
 160         # More relaxed, we just want to avoid too dangerous characters.
 161         /^[a-zA-Z0-9+._, @-]+$/;
 162 }
 163 sub valid_web_url {
 164         local $_ = $_[0];
 165         /^https?:\/\/[a-zA-Z0-9.:-]+(\/[_\%a-zA-Z0-9.\/~:?&=;-]*)?(#[a-zA-Z0-9._-]+)?$/;
 166 }
 167 sub valid_repo_url {
 168         local $_ = $_[0];
 169         /^(https?|git|svn(\+http)?|svn(\+https)?|darcs|bzr):\/\/[a-zA-Z0-9.:-]+(\/[_\%a-zA-Z0-9.\/~-]*)?$/;
 170 }
 171 my %_badtags;
 172 BEGIN {
 173         %_badtags = (
 174         about=>1, after=>1, all=>1, also=>1, an=>1, and=>1, another=>1, any=>1,
 175         are=>1, as=>1, at=>1, be=>1, because=>1, been=>1, before=>1, being=>1,
 176         between=>1, both=>1, but=>1, by=>1, came=>1, can=>1, come=>1, could=>1,
 177         did=>1, do=>1, each=>1, for=>1, from=>1, get=>1, got=>1, had=>1, has=>1,
 178         have=>1, he=>1, her=>1, here=>1, him=>1, himself=>1, his=>1, how=>1,
 179         if=>1, in=>1, into=>1, is=>1, it=>1, like=>1, make=>1, many=>1, me=>1,
 180         might=>1, more=>1, most=>1, much=>1, must=>1, my=>1, never=>1, now=>1,
 181         of=>1, on=>1, only=>1, or=>1, other=>1, our=>1, out=>1, over=>1,
 182         said=>1, same=>1, see=>1, should=>1, since=>1, some=>1, still=>1,
 183         such=>1, take=>1, than=>1, that=>1, the=>1, their=>1, them=>1, then=>1,
 184         there=>1, these=>1, they=>1, this=>1, those=>1, through=>1, to=>1,
 185         too=>1, under=>1, up=>1, very=>1, was=>1, way=>1, we=>1, well=>1,
 186         were=>1, what=>1, where=>1, which=>1, while=>1, who=>1, with=>1,
 187         would=>1, you=>1, your=>1
 188         );
 189 }
 190 # A valid tag must only have [a-zA-Z0-9:.+#_-] characters, must start with a
 191 # letter, must not be a noise word and except for 'C' must be more than one
 192 # character long and no more than 32 characters long.
 193 sub valid_tag {
 194         local $_ = $_[0] || '';
 195         return 1 if $_ eq 'C'; # Currently only allowed single letter tag
 196         return 0 unless /^[a-zA-Z][a-zA-Z0-9:.+#_-]+$/;
 197         return 0 if $_badtags{lc($_)};
 198         return length($_) <= 32 ? 1 : 0;
 199 }
 200
 201 # If the passed in argument looks like a URL, return only the stuff up through
 202 # the host:port part otherwise return the entire argument.
 203 sub url_base {
 204         my $url = shift || '';
 205         # See RFC 3968
 206         $url = $1.$2.$3.$4 if $url =~ m,^( [A-Za-z][A-Za-z0-9+.-]*: ) # scheme
 207                 ( // )          # // separator
 208                 ((?:[^\@]+\@)?) # optional userinfo
 209                 ( [^/?#]+ )     # host and port
 210                 (?:[/?#].*)?$,x; # path and optional query string and/or anchor
 211         return $url;
 212 }
 213
 214 # If the passed in argument looks like a URL, return only the stuff following
 215 # the host:port part otherwise return the entire argument.
 216 sub url_path {
 217         my $url = shift || '';
 218         # See RFC 3968
 219         $url = $1 if $url =~ m,^(?: [A-Za-z][A-Za-z0-9+.-]*: ) # scheme
 220                 (?: // )        # // separator
 221                 (?: [^\@]+\@ )? # optional userinfo
 222                 (?: [^/?#]+ )   # host and port
 223                 ((?:[/?#].*)?)$,x; # path and optional query string and/or anchor
 224         return $url;
 225 }
 226
 227 # If both SERVER_NAME and SERVER_PORT are set pass the argument through url_path
 228 # and then prefix it with the appropriate scheme (HTTPS=?on), host and port and
 229 # return it.  If a something that doesn't look like it could be the start of a
 230 # URL path comes back from url_path or SERVER_NAME is a link-local IPv6 address
 231 # then just return the argument unchanged.
 232 sub url_server {
 233         my $url = shift || '';
 234         my $path = url_path($url);
 235         return $url unless $path eq '' || $path =~ m|^[/?#]|;
 236         return $url unless $ENV{'SERVER_NAME'} && $ENV{'SERVER_PORT'} &&
 237                 $ENV{'SERVER_PORT'} =~ /^[1-9][0-9]{0,4}$/;
 238         return $url if $ENV{'SERVER_NAME'} =~ /^[[]?fe80:/i;
 239         my $server = $ENV{'SERVER_NAME'};
 240         # Deal with Apache bug where IPv6 literal server names do not include
 241         # the required surrounding '[' and ']' characters
 242         $server = '[' . $server . ']' if $server =~ /:/ && $server !~ /^[[]/;
 243         my $ishttps = $ENV{'HTTPS'} && $ENV{'HTTPS'} =~ /^on$/i;
 244         my $portnum = 0 + $ENV{'SERVER_PORT'};
 245         my $port = '';
 246         if (($ishttps && $portnum != 443) || (!$ishttps && $portnum != 80)) {
 247                 $port = ':' . $portnum;
 248         }
 249         return 'http' . ($ishttps ? 's' : '') . '://' . $server . $port . $path;
 250 }
 251
 252 sub _escapeHTML {
 253         my $str = shift;
 254         $str =~ s/\&/\&amp;/gs;
 255         $str =~ s/\</\&lt;/gs;
 256         $str =~ s/\>/\&gt;/gs;
 257         $str =~ s/\"/\&quot;/gs; #"
 258         return $str;
 259 }
 260
 261 # create relative time string from passed in age in seconds
 262 sub _rel_age {
 263         my $age = shift;
 264         my $age_str;
 265
 266         if ($age > 60*60*24*365*2) {
 267                 $age_str = (int $age/60/60/24/365);
 268                 $age_str .= " years ago";
 269         } elsif ($age > 60*60*24*(365/12)*2) {
 270                 $age_str = int $age/60/60/24/(365/12);
 271                 $age_str .= " months ago";
 272         } elsif ($age > 60*60*24*7*2) {
 273                 $age_str = int $age/60/60/24/7;
 274                 $age_str .= " weeks ago";
 275         } elsif ($age > 60*60*24*2) {
 276                 $age_str = int $age/60/60/24;
 277                 $age_str .= " days ago";
 278         } elsif ($age > 60*60*2) {
 279                 $age_str = int $age/60/60;
 280                 $age_str .= " hours ago";
 281         } elsif ($age > 60*2) {
 282                 $age_str = int $age/60;
 283                 $age_str .= " mins ago";
 284         } elsif ($age > 2) {
 285                 $age_str = int $age;
 286                 $age_str .= " secs ago";
 287         } elsif ($age >= 0) {
 288                 $age_str = "right now";
 289         } else {
 290                 $age_str = "future time";
 291         }
 292         return $age_str;
 293 }
 294
 295 # create relative time string from passed in idle in seconds
 296 sub _rel_idle {
 297         my $idle_str = _rel_age(shift);
 298         $idle_str =~ s/ ago//;
 299         $idle_str = "not at all" if $idle_str eq "right now";
 300         return $idle_str;
 301 }
 302
 303 sub _strftime {
 304         use POSIX qw(strftime);
 305         my ($fmt, $secs, $zonesecs) = @_;
 306         my ($S,$M,$H,$d,$m,$y) = gmtime($secs + $zonesecs);
 307         $zonesecs = int($zonesecs / 60);
 308         $fmt =~ s/%z/\$z/g;
 309         my $ans = strftime($fmt, $S, $M, $H, $d, $m, $y, -1, -1, -1);
 310         my $z;
 311         if ($zonesecs < 0) {
 312                 $z = "-";
 313                 $zonesecs = -$zonesecs;
 314         } else {
 315                 $z = "+";
 316         }
 317         $z .= sprintf("%02d%02d", int($zonesecs/60), $zonesecs % 60);
 318         $ans =~ s/\$z/$z/g;
 319         return $ans;
 320 }
 321
 322 # Take a list of project names and produce a nicely formated table that
 323 # includes owner links and descriptions.  If the list is empty returns ''.
 324 # The first argument may be a hash ref that contains options.  The following
 325 # options are available:
 326 #   target  -- sets the target value of the owner link
 327 #   emptyok -- if true returns an empty table rather than ''
 328 #   typecol -- if true include type column with hover info
 329 #   changed -- if true include a changed and idle column
 330 sub projects_html_list {
 331         my $options = {};
 332         if (defined($_[0]) && ref($_[0]) eq 'HASH') {
 333                 $options = shift;
 334         }
 335         return '' unless @_ || (defined($options->{emptyok}) && $options->{emptyok});
 336         require Girocco::Project;
 337         my $count = 0;
 338         my $target = '';
 339         $target = " target=\""._escapeHTML($options->{target})."\""
 340                 if defined($options->{target});
 341         my $withtype = defined($options->{typecol}) && $options->{typecol};
 342         my $withchanged = defined($options->{changed}) && $options->{changed};
 343         my $typehead = '';
 344         $typehead = '<th>Type</th>' if $withtype;
 345         my $chghead = '';
 346         $chghead = substr(<<EOT, 0, -1) if $withchanged;
 347 <th><span class="hover">Changed<span><span class="head">Changed</span
 348 />The last time a ref change was received by this site.</span></span></th
 349 ><th><span class="hover">Idle<span><span class="head">Idle</span
 350 />The most recent committer time in <i>refs/heads</i>.</span></span></th
 351 >
 352 EOT
 353         my $html = <<EOT;
 354 <table class='projectlist'><tr><th>Project</th>$typehead$chghead<th class="desc">Description</th></tr>
 355 EOT
 356         my $trclass = ' class="odd"';
 357         foreach (sort({lc($a) cmp lc($b)} @_)) {
 358                 if (Girocco::Project::does_exist($_, 1)) {
 359                         my $proj = Girocco::Project->load($_);
 360                         my $projname = $proj->{name}.".git";
 361                         my $projdesc = $proj->{desc}||'';
 362                         utf8::decode($projdesc) if utf8::valid($projdesc);
 363                         my $typecol = '';
 364                         if ($withtype) {
 365                                 if ($proj->{mirror}) {
 366                                         $typecol = substr(<<EOT, 0, -1);
 367 <td class="type"><span class="hover">mirror<span class="nowrap">@{[_escapeHTML($proj->{url})]}</span></span></td>
 368 EOT
 369                                 } else {
 370                                         my $users = @{$proj->{users}};
 371                                         $users .= ' user';
 372                                         $users .= 's' unless @{$proj->{users}} == 1;
 373                                         my $userlist = join(', ', sort({lc($a) cmp lc($b)} @{$proj->{users}}));
 374                                         my $spncls = length($userlist) > 25 ? '' : ' class="nowrap"';
 375                                         $typecol = $userlist ? substr(<<EOT, 0, -1) : substr(<<EOT, 0, -1);
 376 <td class="type"><span class="hover">$users<span$spncls>$userlist</span></span></td>
 377 EOT
 378 <td class="type">$users</td>
 379 EOT
 380                                 }
 381                         }
 382                         my $changecol = '';
 383                         if ($withchanged) {
 384                                 my $rel = '';
 385                                 my $changetime = $proj->{lastchange};
 386                                 if ($changetime) {
 387                                         $rel = "<span class=\"hover\">" .
 388                                                 _rel_age(time - parse_rfc2822_date($changetime)) .
 389                                                 "<span class=\"nowrap\">$changetime</span></span>";
 390                                 } else {
 391                                         $rel = "no commits";
 392                                 }
 393                                 $changecol = substr(<<EOT, 0, -1);
 394 <td class="change">$rel</td>
 395 EOT
 396                                 my $idletime = $proj->{lastactivity};
 397                                 my ($idlesecs, $tz);
 398                                 $idlesecs = parse_any_date($idletime, \$tz) if $idletime;
 399                                 if ($idlesecs) {
 400                                         my $idle2822 = _strftime("%a, %d %b %Y %T %z", $idlesecs, $tz);
 401                                         $rel = "<span class=\"hover\">" .
 402                                                 _rel_idle(time - $idlesecs) .
 403                                                 "<span class=\"nowrap\">$idle2822</span></span>";
 404                                 } else {
 405                                         $rel = "no commits";
 406                                 }
 407                                 $changecol .= substr(<<EOT, 0, -1);
 408 <td class="idle">$rel</td>
 409 EOT
 410                         }
 411                         $html .= <<EOT;
 412 <tr$trclass><td><a href="@{[url_path($Girocco::Config::gitweburl)]}/$projname"$target
 413 >@{[_escapeHTML($projname)]}</td>$typecol$changecol<td>@{[_escapeHTML($projdesc)]}</td></tr>
 414 EOT
 415                         $trclass = $trclass ? '' : ' class="odd"';
 416                         ++$count;
 417                 }
 418         }
 419         $html .= <<EOT;
 420 </table>
 421 EOT
 422         return ($count || (defined($options->{emptyok}) && $options->{emptyok})) ? $html : '';
 423 }
 424
 425 my %_month_names;
 426 BEGIN {
 427         %_month_names = (
 428                 jan => 0, feb => 1, mar => 2, apr => 3, may => 4, jun => 5,
 429                 jul => 6, aug => 7, sep => 8, oct => 9, nov => 10, dec => 11
 430         );
 431 }
 432
 433 # Should be in "date '+%a, %d %b %Y %T %z'" format as saved to lastgc, lastrefresh and lastchange
 434 # The leading "%a, " is optional, returns undef if unrecognized date.  This is also known as
 435 # RFC 2822 date format and git's '%cD', '%aD' and --date=rfc2822 format.
 436 # If the second argument is a SCALAR ref, its value will be set to the TZ offset in seconds
 437 sub parse_rfc2822_date {
 438         my $dstr = shift || '';
 439         my $tzoff = shift || '';
 440         $dstr = $1 if $dstr =~/^[^\s]+,\s*(.*)$/;
 441         return undef unless $dstr =~
 442                 /^\s*(\d{1,2})\s+([A-Za-z]{3})\s+(\d{4})\s+(\d{1,2}):(\d{2}):(\d{2})\s+([+-]\d{4})\s*$/;
 443         my ($d,$b,$Y,$H,$M,$S,$z) = ($1,$2,$3,$4,$5,$6,$7);
 444         my $m = $_month_names{lc($b)};
 445         return undef unless defined($m);
 446         my $seconds = timegm(0+$S, 0+$M, 0+$H, 0+$d, 0+$m, $Y-1900);
 447         my $offset = 60 * (60 * (0+substr($z,1,2)) + (0+substr($z,3,2)));
 448         $offset = -$offset if substr($z,0,1) eq '-';
 449         $$tzoff = $offset if ref($tzoff) eq 'SCALAR';
 450         return $seconds - $offset;
 451 }
 452
 453 # Will parse any supported date format.  Actually there are three formats
 454 # currently supported:
 455 #   1. RFC 2822 (uses parse_rfc2822_date)
 456 #   2. RFC 3339 / ISO 8601 (T may be ' ', 'Z' is optional, ':' optional in TZ)
 457 #   3. unix seconds since epoch with optional +/- trailing TZ (may not have a ':')
 458 # Returns undef if unsupported date.
 459 # If the second argument is a SCALAR ref, its value will be set to the TZ offset in seconds
 460 sub parse_any_date {
 461         my $dstr = shift || '';
 462         my $tzoff = shift || '';
 463         if ($dstr =~ /^\s*([-+]?\d+)(?:\s+([-+]\d{4}))?\s*$/) {
 464                 # Unix timestamp
 465                 my $ts = 0 + $1;
 466                 my $off = 0;
 467                 if ($2) {
 468                         my $z = $2;
 469                         $off = 60 * (60 * (0+substr($z,1,2)) + (0+substr($z,3,2)));
 470                         $off = -$off if substr($z,0,1) eq '-';
 471                 }
 472                 $$tzoff = $off if ref($tzoff) eq 'SCALAR';
 473                 return $ts;
 474         }
 475         if ($dstr =~ /^\s*(\d{4})-(\d{2})-(\d{2})[Tt ](\d{2}):(\d{2}):(\d{2})(?:[ ]([Zz]|(?:[-+]\d{2}:?\d{2})))?\s*$/) {
 476                 my ($Y,$m,$d,$H,$M,$S,$z) = ($1,$2,$3,$4,$5,$6,$7||'');
 477                 my $seconds = timegm(0+$S, 0+$M, 0+$H, 0+$d, $m-1, $Y-1900);
 478                 $z =~ s/://;
 479                 my $off = 0;
 480                 if (uc($z) ne 'Z') {
 481                         $off = 60 * (60 * (0+substr($z,1,2)) + (0+substr($z,3,2)));
 482                         $off = -$off if substr($z,0,1) eq '-';
 483                 }
 484                 $$tzoff = $off if ref($tzoff) eq 'SCALAR';
 485                 return $seconds - $off;
 486         }
 487         return parse_rfc2822_date($dstr, $tzoff);
 488 }
 489
 490 # Input is a number such as a minute interval
 491 # Return value is a random number between the input and 1.25*input
 492 # This can be used to randomize the update and gc operations a bit to avoid
 493 # having them all end up all clustered together
 494 sub rand_adjust {
 495         my $input = shift || 0;
 496         return $input unless $input;
 497         return $input + int(rand(0.25 * $input));
 498 }
 499
 500 # Open a pipe to a new sendmail process.  The '-i' option is always passed to
 501 # the new process followed by any addtional arguments passed in.  Note that
 502 # the sendmail process is only expected to understand the '-i', '-t' and '-f'
 503 # options.  Using any other options via this function is not guaranteed to work.
 504 # A list of recipients may follow the options.  Combining a list of recipients
 505 # with the '-t' option is not recommended.
 506 sub sendmail_pipe {
 507         return undef unless @_;
 508         die "\$Girocco::Config::sendmail_bin is unset or not executable!\n"
 509                 unless $Girocco::Config::sendmail_bin && -x $Girocco::Config::sendmail_bin;
 510         my $result = open(my $pipe, '|-', $Girocco::Config::sendmail_bin, '-i', @_);
 511         return $result ? $pipe : undef;
 512 }
 513
 514 # Open a pipe that works similarly to a mailer such as /usr/bin/mail in that
 515 # if the first argument is '-s', a subject line will be automatically added
 516 # (using the second argument as the subject).  Any remaining arguments are
 517 # expected to be recipient addresses that will be added to an explicit To:
 518 # line as well as passed on to sendmail_pipe.  In addition an
 519 # "Auto-Submitted: auto-generated" header is always added as well as a suitable
 520 # "From:" header.
 521 sub mailer_pipe {
 522         my $subject = undef;
 523         if (@_ >= 2 && $_[0] eq '-s') {
 524                 shift;
 525                 $subject = shift;
 526         }
 527         my $tolist = join(", ", @_);
 528         unshift(@_, '-f', $Girocco::Config::sender) if $Girocco::Config::sender;
 529         my $pipe = sendmail_pipe(@_);
 530         if ($pipe) {
 531                 print $pipe "From: \"$Girocco::Config::name\" ",
 532                         "($Girocco::Config::title) ",
 533                         "<$Girocco::Config::admin>\n";
 534                 print $pipe "To: $tolist\n";
 535                 print $pipe "Subject: $subject\n" if defined($subject);
 536                 print $pipe "Auto-Submitted: auto-generated\n";
 537                 print $pipe "\n";
 538         }
 539         return $pipe;
 540 }
 541
 542 1;